New URL for NEMO forge!   http://forge.nemo-ocean.eu

Since March 2022 along with NEMO 4.2 release, the code development moved to a self-hosted GitLab.
This present forge is now archived and remained online for history.
zpshde.F90 in branches/2015/dev_r5151_UKMO_ISF/NEMOGCM/NEMO/OPA_SRC/TRA – NEMO

source: branches/2015/dev_r5151_UKMO_ISF/NEMOGCM/NEMO/OPA_SRC/TRA/zpshde.F90 @ 5956

Last change on this file since 5956 was 5956, checked in by mathiot, 8 years ago

ISF : merged trunk (5936) into branch

  • Property svn:keywords set to Id
File size: 24.7 KB
Line 
1MODULE zpshde
2   !!======================================================================
3   !!                       ***  MODULE zpshde   ***
4   !! z-coordinate + partial step : Horizontal Derivative at ocean bottom level
5   !!======================================================================
6   !! History :  OPA  !  2002-04  (A. Bozec)  Original code
7   !!   NEMO     1.0  !  2002-08  (G. Madec E. Durand)  Optimization and Free form
8   !!             -   !  2004-03  (C. Ethe)  adapted for passive tracers
9   !!            3.3  !  2010-05  (C. Ethe, G. Madec)  merge TRC-TRA
10   !!            3.6  !  2014-11  (P. Mathiot) Add zps_hde_isf (needed to open a cavity)
11   !!======================================================================
12   
13   !!----------------------------------------------------------------------
14   !!   zps_hde      :  Horizontal DErivative of T, S and rd at the last
15   !!                   ocean level (Z-coord. with Partial Steps)
16   !!----------------------------------------------------------------------
17   USE oce             ! ocean: dynamics and tracers variables
18   USE dom_oce         ! domain: ocean variables
19   USE phycst          ! physical constants
20   USE eosbn2          ! ocean equation of state
21   USE in_out_manager  ! I/O manager
22   USE lbclnk          ! lateral boundary conditions (or mpp link)
23   USE lib_mpp         ! MPP library
24   USE wrk_nemo        ! Memory allocation
25   USE timing          ! Timing
26
27   IMPLICIT NONE
28   PRIVATE
29
30   PUBLIC   zps_hde     ! routine called by step.F90
31   PUBLIC   zps_hde_isf ! routine called by step.F90
32
33   !! * Substitutions
34#  include "domzgr_substitute.h90"
35#  include "vectopt_loop_substitute.h90"
36   !!----------------------------------------------------------------------
37   !! NEMO/OPA 3.3 , NEMO Consortium (2010)
38   !! $Id$
39   !! Software governed by the CeCILL licence     (NEMOGCM/NEMO_CeCILL.txt)
40   !!----------------------------------------------------------------------
41CONTAINS
42
43   SUBROUTINE zps_hde( kt, kjpt, pta, pgtu, pgtv,   &
44      &                          prd, pgru, pgrv    )
45      !!----------------------------------------------------------------------
46      !!                     ***  ROUTINE zps_hde  ***
47      !!                   
48      !! ** Purpose :   Compute the horizontal derivative of T, S and rho
49      !!      at u- and v-points with a linear interpolation for z-coordinate
50      !!      with partial steps.
51      !!
52      !! ** Method  :   In z-coord with partial steps, scale factors on last
53      !!      levels are different for each grid point, so that T, S and rd
54      !!      points are not at the same depth as in z-coord. To have horizontal
55      !!      gradients again, we interpolate T and S at the good depth :
56      !!      Linear interpolation of T, S   
57      !!         Computation of di(tb) and dj(tb) by vertical interpolation:
58      !!          di(t) = t~ - t(i,j,k) or t(i+1,j,k) - t~
59      !!          dj(t) = t~ - t(i,j,k) or t(i,j+1,k) - t~
60      !!         This formulation computes the two cases:
61      !!                 CASE 1                   CASE 2 
62      !!         k-1  ___ ___________   k-1   ___ ___________
63      !!                    Ti  T~                  T~  Ti+1
64      !!                  _____                        _____
65      !!         k        |   |Ti+1     k           Ti |   |
66      !!                  |   |____                ____|   |
67      !!              ___ |   |   |           ___  |   |   |
68      !!                 
69      !!      case 1->   e3w(i+1) >= e3w(i) ( and e3w(j+1) >= e3w(j) ) then
70      !!          t~ = t(i+1,j  ,k) + (e3w(i+1) - e3w(i)) * dk(Ti+1)/e3w(i+1)
71      !!        ( t~ = t(i  ,j+1,k) + (e3w(j+1) - e3w(j)) * dk(Tj+1)/e3w(j+1)  )
72      !!          or
73      !!      case 2->   e3w(i+1) <= e3w(i) ( and e3w(j+1) <= e3w(j) ) then
74      !!          t~ = t(i,j,k) + (e3w(i) - e3w(i+1)) * dk(Ti)/e3w(i )
75      !!        ( t~ = t(i,j,k) + (e3w(j) - e3w(j+1)) * dk(Tj)/e3w(j ) )
76      !!          Idem for di(s) and dj(s)         
77      !!
78      !!      For rho, we call eos which will compute rd~(t~,s~) at the right
79      !!      depth zh from interpolated T and S for the different formulations
80      !!      of the equation of state (eos).
81      !!      Gradient formulation for rho :
82      !!          di(rho) = rd~ - rd(i,j,k)   or   rd(i+1,j,k) - rd~
83      !!
84      !! ** Action  : compute for top interfaces
85      !!              - pgtu, pgtv: horizontal gradient of tracer at u- & v-points
86      !!              - pgru, pgrv: horizontal gradient of rho (if present) at u- & v-points
87      !!----------------------------------------------------------------------
88      INTEGER                              , INTENT(in   )           ::  kt          ! ocean time-step index
89      INTEGER                              , INTENT(in   )           ::  kjpt        ! number of tracers
90      REAL(wp), DIMENSION(jpi,jpj,jpk,kjpt), INTENT(in   )           ::  pta         ! 4D tracers fields
91      REAL(wp), DIMENSION(jpi,jpj,    kjpt), INTENT(  out)           ::  pgtu, pgtv  ! hor. grad. of ptra at u- & v-pts
92      REAL(wp), DIMENSION(jpi,jpj,jpk     ), INTENT(in   ), OPTIONAL ::  prd         ! 3D density anomaly fields
93      REAL(wp), DIMENSION(jpi,jpj         ), INTENT(  out), OPTIONAL ::  pgru, pgrv  ! hor. grad of prd at u- & v-pts (bottom)
94      !
95      INTEGER  ::   ji, jj, jn                  ! Dummy loop indices
96      INTEGER  ::   iku, ikv, ikum1, ikvm1      ! partial step level (ocean bottom level) at u- and v-points
97      REAL(wp) ::   ze3wu, ze3wv, zmaxu, zmaxv  ! local scalars
98      REAL(wp), DIMENSION(jpi,jpj)      ::   zri, zrj, zhi, zhj   ! NB: 3rd dim=1 to use eos
99      REAL(wp), DIMENSION(jpi,jpj,kjpt) ::   zti, ztj             !
100      !!----------------------------------------------------------------------
101      !
102      IF( nn_timing == 1 )   CALL timing_start( 'zps_hde')
103      !
104      pgtu(:,:,:)=0._wp   ;   zti (:,:,:)=0._wp   ;   zhi (:,:  )=0._wp
105      pgtv(:,:,:)=0._wp   ;   ztj (:,:,:)=0._wp   ;   zhj (:,:  )=0._wp
106      !
107      DO jn = 1, kjpt      !==   Interpolation of tracers at the last ocean level   ==!
108         !
109         DO jj = 1, jpjm1
110            DO ji = 1, jpim1
111               iku = mbku(ji,jj)   ;   ikum1 = MAX( iku - 1 , 1 )    ! last and before last ocean level at u- & v-points
112               ikv = mbkv(ji,jj)   ;   ikvm1 = MAX( ikv - 1 , 1 )    ! if level first is a p-step, ik.m1=1
113               ze3wu = fse3w(ji+1,jj  ,iku) - fse3w(ji,jj,iku)
114               ze3wv = fse3w(ji  ,jj+1,ikv) - fse3w(ji,jj,ikv)
115               !
116               ! i- direction
117               IF( ze3wu >= 0._wp ) THEN      ! case 1
118                  zmaxu =  ze3wu / fse3w(ji+1,jj,iku)
119                  ! interpolated values of tracers
120                  zti (ji,jj,jn) = pta(ji+1,jj,iku,jn) + zmaxu * ( pta(ji+1,jj,ikum1,jn) - pta(ji+1,jj,iku,jn) )
121                  ! gradient of  tracers
122                  pgtu(ji,jj,jn) = umask(ji,jj,1) * ( zti(ji,jj,jn) - pta(ji,jj,iku,jn) )
123               ELSE                           ! case 2
124                  zmaxu = -ze3wu / fse3w(ji,jj,iku)
125                  ! interpolated values of tracers
126                  zti (ji,jj,jn) = pta(ji,jj,iku,jn) + zmaxu * ( pta(ji,jj,ikum1,jn) - pta(ji,jj,iku,jn) )
127                  ! gradient of tracers
128                  pgtu(ji,jj,jn) = umask(ji,jj,1) * ( pta(ji+1,jj,iku,jn) - zti(ji,jj,jn) )
129               ENDIF
130               !
131               ! j- direction
132               IF( ze3wv >= 0._wp ) THEN      ! case 1
133                  zmaxv =  ze3wv / fse3w(ji,jj+1,ikv)
134                  ! interpolated values of tracers
135                  ztj (ji,jj,jn) = pta(ji,jj+1,ikv,jn) + zmaxv * ( pta(ji,jj+1,ikvm1,jn) - pta(ji,jj+1,ikv,jn) )
136                  ! gradient of tracers
137                  pgtv(ji,jj,jn) = vmask(ji,jj,1) * ( ztj(ji,jj,jn) - pta(ji,jj,ikv,jn) )
138               ELSE                           ! case 2
139                  zmaxv =  -ze3wv / fse3w(ji,jj,ikv)
140                  ! interpolated values of tracers
141                  ztj (ji,jj,jn) = pta(ji,jj,ikv,jn) + zmaxv * ( pta(ji,jj,ikvm1,jn) - pta(ji,jj,ikv,jn) )
142                  ! gradient of tracers
143                  pgtv(ji,jj,jn) = vmask(ji,jj,1) * ( pta(ji,jj+1,ikv,jn) - ztj(ji,jj,jn) )
144               ENDIF
145            END DO
146         END DO
147         CALL lbc_lnk( pgtu(:,:,jn), 'U', -1. )   ;   CALL lbc_lnk( pgtv(:,:,jn), 'V', -1. )   ! Lateral boundary cond.
148         !
149      END DO
150      !               
151      IF( PRESENT( prd ) ) THEN    !==  horizontal derivative of density anomalies (rd)  ==!    (optional part)
152         pgru(:,:) = 0._wp
153         pgrv(:,:) = 0._wp                ! depth of the partial step level
154         DO jj = 1, jpjm1
155            DO ji = 1, jpim1
156               iku = mbku(ji,jj)
157               ikv = mbkv(ji,jj)
158               ze3wu  = fse3w(ji+1,jj  ,iku) - fse3w(ji,jj,iku)
159               ze3wv  = fse3w(ji  ,jj+1,ikv) - fse3w(ji,jj,ikv)
160               IF( ze3wu >= 0._wp ) THEN   ;   zhi(ji,jj) = fsdept(ji  ,jj,iku)     ! i-direction: case 1
161               ELSE                        ;   zhi(ji,jj) = fsdept(ji+1,jj,iku)     ! -     -      case 2
162               ENDIF
163               IF( ze3wv >= 0._wp ) THEN   ;   zhj(ji,jj) = fsdept(ji,jj  ,ikv)     ! j-direction: case 1
164               ELSE                        ;   zhj(ji,jj) = fsdept(ji,jj+1,ikv)     ! -     -      case 2
165               ENDIF
166            END DO
167         END DO
168         !
169         CALL eos( zti, zhi, zri )        ! interpolated density from zti, ztj
170         CALL eos( ztj, zhj, zrj )        ! at the partial step depth output in  zri, zrj
171         !
172         DO jj = 1, jpjm1                 ! Gradient of density at the last level
173            DO ji = 1, jpim1
174               iku = mbku(ji,jj)
175               ikv = mbkv(ji,jj)
176               ze3wu  = fse3w(ji+1,jj  ,iku) - fse3w(ji,jj,iku)
177               ze3wv  = fse3w(ji  ,jj+1,ikv) - fse3w(ji,jj,ikv)
178               IF( ze3wu >= 0._wp ) THEN   ;   pgru(ji,jj) = umask(ji,jj,1) * ( zri(ji  ,jj    ) - prd(ji,jj,iku) )   ! i: 1
179               ELSE                        ;   pgru(ji,jj) = umask(ji,jj,1) * ( prd(ji+1,jj,iku) - zri(ji,jj    ) )   ! i: 2
180               ENDIF
181               IF( ze3wv >= 0._wp ) THEN   ;   pgrv(ji,jj) = vmask(ji,jj,1) * ( zrj(ji,jj      ) - prd(ji,jj,ikv) )   ! j: 1
182               ELSE                        ;   pgrv(ji,jj) = vmask(ji,jj,1) * ( prd(ji,jj+1,ikv) - zrj(ji,jj    ) )   ! j: 2
183               ENDIF
184            END DO
185         END DO
186         CALL lbc_lnk( pgru , 'U', -1. )   ;   CALL lbc_lnk( pgrv , 'V', -1. )   ! Lateral boundary conditions
187         !
188      END IF
189      !
190      IF( nn_timing == 1 )   CALL timing_stop( 'zps_hde')
191      !
192   END SUBROUTINE zps_hde
193   !
194   SUBROUTINE zps_hde_isf( kt, kjpt, pta, pgtu, pgtv, pgtui, pgtvi,  &
195      &                          prd, pgru, pgrv, pgrui, pgrvi )
196      !!----------------------------------------------------------------------
197      !!                     ***  ROUTINE zps_hde_isf  ***
198      !!                   
199      !! ** Purpose :   Compute the horizontal derivative of T, S and rho
200      !!      at u- and v-points with a linear interpolation for z-coordinate
201      !!      with partial steps for top (ice shelf) and bottom.
202      !!
203      !! ** Method  :   In z-coord with partial steps, scale factors on last
204      !!      levels are different for each grid point, so that T, S and rd
205      !!      points are not at the same depth as in z-coord. To have horizontal
206      !!      gradients again, we interpolate T and S at the good depth :
207      !!      For the bottom case:
208      !!      Linear interpolation of T, S   
209      !!         Computation of di(tb) and dj(tb) by vertical interpolation:
210      !!          di(t) = t~ - t(i,j,k) or t(i+1,j,k) - t~
211      !!          dj(t) = t~ - t(i,j,k) or t(i,j+1,k) - t~
212      !!         This formulation computes the two cases:
213      !!                 CASE 1                   CASE 2 
214      !!         k-1  ___ ___________   k-1   ___ ___________
215      !!                    Ti  T~                  T~  Ti+1
216      !!                  _____                        _____
217      !!         k        |   |Ti+1     k           Ti |   |
218      !!                  |   |____                ____|   |
219      !!              ___ |   |   |           ___  |   |   |
220      !!                 
221      !!      case 1->   e3w(i+1) >= e3w(i) ( and e3w(j+1) >= e3w(j) ) then
222      !!          t~ = t(i+1,j  ,k) + (e3w(i+1) - e3w(i)) * dk(Ti+1)/e3w(i+1)
223      !!        ( t~ = t(i  ,j+1,k) + (e3w(j+1) - e3w(j)) * dk(Tj+1)/e3w(j+1)  )
224      !!          or
225      !!      case 2->   e3w(i+1) <= e3w(i) ( and e3w(j+1) <= e3w(j) ) then
226      !!          t~ = t(i,j,k) + (e3w(i) - e3w(i+1)) * dk(Ti)/e3w(i )
227      !!        ( t~ = t(i,j,k) + (e3w(j) - e3w(j+1)) * dk(Tj)/e3w(j ) )
228      !!          Idem for di(s) and dj(s)         
229      !!
230      !!      For rho, we call eos which will compute rd~(t~,s~) at the right
231      !!      depth zh from interpolated T and S for the different formulations
232      !!      of the equation of state (eos).
233      !!      Gradient formulation for rho :
234      !!          di(rho) = rd~ - rd(i,j,k)   or   rd(i+1,j,k) - rd~
235      !!
236      !!      For the top case (ice shelf): As for the bottom case but upside down
237      !!
238      !! ** Action  : compute for top and bottom interfaces
239      !!              - pgtu, pgtv, pgtui, pgtvi: horizontal gradient of tracer at u- & v-points
240      !!              - pgru, pgrv, pgrui, pgtvi: horizontal gradient of rho (if present) at u- & v-points
241      !!----------------------------------------------------------------------
242      INTEGER                              , INTENT(in   )           ::  kt           ! ocean time-step index
243      INTEGER                              , INTENT(in   )           ::  kjpt         ! number of tracers
244      REAL(wp), DIMENSION(jpi,jpj,jpk,kjpt), INTENT(in   )           ::  pta          ! 4D tracers fields
245      REAL(wp), DIMENSION(jpi,jpj,    kjpt), INTENT(  out)           ::  pgtu, pgtv   ! hor. grad. of ptra at u- & v-pts
246      REAL(wp), DIMENSION(jpi,jpj,    kjpt), INTENT(  out)           ::  pgtui, pgtvi ! hor. grad. of stra at u- & v-pts (ISF)
247      REAL(wp), DIMENSION(jpi,jpj,jpk     ), INTENT(in   ), OPTIONAL ::  prd          ! 3D density anomaly fields
248      REAL(wp), DIMENSION(jpi,jpj         ), INTENT(  out), OPTIONAL ::  pgru, pgrv   ! hor. grad of prd at u- & v-pts (bottom)
249      REAL(wp), DIMENSION(jpi,jpj         ), INTENT(  out), OPTIONAL ::  pgrui, pgrvi ! hor. grad of prd at u- & v-pts (top)
250      !
251      INTEGER  ::   ji, jj, jn      ! Dummy loop indices
252      INTEGER  ::   iku, ikv, ikum1, ikvm1,ikup1, ikvp1   ! partial step level (ocean bottom level) at u- and v-points
253      REAL(wp) ::  ze3wu, ze3wv, zmaxu, zmaxv             ! temporary scalars
254      REAL(wp), DIMENSION(jpi,jpj)      ::  zri, zrj, zhi, zhj   ! NB: 3rd dim=1 to use eos
255      REAL(wp), DIMENSION(jpi,jpj,kjpt) ::  zti, ztj             !
256      !!----------------------------------------------------------------------
257      !
258      IF( nn_timing == 1 )  CALL timing_start( 'zps_hde_isf')
259      !
260      pgtu (:,:,:) = 0._wp   ;   pgtv (:,:,:) =0._wp
261      pgtui(:,:,:) = 0._wp   ;   pgtvi(:,:,:) =0._wp
262      zti  (:,:,:) = 0._wp   ;   ztj  (:,:,:) =0._wp
263      zhi  (:,:  ) = 0._wp   ;   zhj  (:,:  ) =0._wp
264      !
265      DO jn = 1, kjpt      !==   Interpolation of tracers at the last ocean level   ==!
266         !
267         DO jj = 1, jpjm1
268            DO ji = 1, jpim1
269
270               iku = mbku(ji,jj); ikum1 = MAX( iku - 1 , 1 )    ! last and before last ocean level at u- & v-points
271               ikv = mbkv(ji,jj); ikvm1 = MAX( ikv - 1 , 1 )    ! if level first is a p-step, ik.m1=1
272               ze3wu = fsdept_n(ji+1,jj,iku) - fsdept_n(ji,jj,iku)
273               ze3wv = fsdept_n(ji,jj+1,ikv) - fsdept_n(ji,jj,ikv)
274               !
275               ! i- direction
276               IF( ze3wu >= 0._wp ) THEN      ! case 1
277                  zmaxu =  ze3wu / fse3w(ji+1,jj,iku)
278                  ! interpolated values of tracers
279                  zti (ji,jj,jn) = pta(ji+1,jj,iku,jn) + zmaxu * ( pta(ji+1,jj,ikum1,jn) - pta(ji+1,jj,iku,jn) )
280                  ! gradient of  tracers
281                  pgtu(ji,jj,jn) = ssumask(ji,jj) * ( zti(ji,jj,jn) - pta(ji,jj,iku,jn) )
282               ELSE                           ! case 2
283                  zmaxu = -ze3wu / fse3w(ji,jj,iku)
284                  ! interpolated values of tracers
285                  zti (ji,jj,jn) = pta(ji,jj,iku,jn) + zmaxu * ( pta(ji,jj,ikum1,jn) - pta(ji,jj,iku,jn) )
286                  ! gradient of tracers
287                  pgtu(ji,jj,jn) = ssumask(ji,jj) * ( pta(ji+1,jj,iku,jn) - zti(ji,jj,jn) )
288               ENDIF
289               !
290               ! j- direction
291               IF( ze3wv >= 0._wp ) THEN      ! case 1
292                  zmaxv =  ze3wv / fse3w(ji,jj+1,ikv)
293                  ! interpolated values of tracers
294                  ztj (ji,jj,jn) = pta(ji,jj+1,ikv,jn) + zmaxv * ( pta(ji,jj+1,ikvm1,jn) - pta(ji,jj+1,ikv,jn) )
295                  ! gradient of tracers
296                  pgtv(ji,jj,jn) = ssvmask(ji,jj) * ( ztj(ji,jj,jn) - pta(ji,jj,ikv,jn) )
297               ELSE                           ! case 2
298                  zmaxv =  -ze3wv / fse3w(ji,jj,ikv)
299                  ! interpolated values of tracers
300                  ztj (ji,jj,jn) = pta(ji,jj,ikv,jn) + zmaxv * ( pta(ji,jj,ikvm1,jn) - pta(ji,jj,ikv,jn) )
301                  ! gradient of tracers
302                  pgtv(ji,jj,jn) = ssvmask(ji,jj) * ( pta(ji,jj+1,ikv,jn) - ztj(ji,jj,jn) )
303               ENDIF
304
305            END DO
306         END DO
307         CALL lbc_lnk( pgtu(:,:,jn), 'U', -1. )   ;   CALL lbc_lnk( pgtv(:,:,jn), 'V', -1. )   ! Lateral boundary cond.
308         !
309      END DO
310
311      ! horizontal derivative of density anomalies (rd)
312      IF( PRESENT( prd ) ) THEN         ! depth of the partial step level
313         pgru(:,:)=0.0_wp   ; pgrv(:,:)=0.0_wp ; 
314         !
315         DO jj = 1, jpjm1
316            DO ji = 1, jpim1
317
318               iku = mbku(ji,jj)
319               ikv = mbkv(ji,jj)
320               ze3wu = fsdept_n(ji+1,jj,iku) - fsdept_n(ji,jj,iku)
321               ze3wv = fsdept_n(ji,jj+1,ikv) - fsdept_n(ji,jj,ikv)
322               !
323               IF( ze3wu >= 0._wp ) THEN   ;   zhi(ji,jj) = fsdept(ji  ,jj,iku)    ! i-direction: case 1
324               ELSE                        ;   zhi(ji,jj) = fsdept(ji+1,jj,iku)    ! -     -      case 2
325               ENDIF
326               IF( ze3wv >= 0._wp ) THEN   ;   zhj(ji,jj) = fsdept(ji,jj  ,ikv)    ! j-direction: case 1
327               ELSE                        ;   zhj(ji,jj) = fsdept(ji,jj+1,ikv)    ! -     -      case 2
328               ENDIF
329
330            END DO
331         END DO
332
333         ! Compute interpolated rd from zti, ztj for the 2 cases at the depth of the partial
334         ! step and store it in  zri, zrj for each  case
335         CALL eos( zti, zhi, zri )
336         CALL eos( ztj, zhj, zrj )
337
338         DO jj = 1, jpjm1                 ! Gradient of density at the last level
339            DO ji = 1, jpim1
340
341               iku = mbku(ji,jj)
342               ikv = mbkv(ji,jj)
343               ze3wu = fsdept_n(ji+1,jj,iku) - fsdept_n(ji,jj,iku)
344               ze3wv = fsdept_n(ji,jj+1,ikv) - fsdept_n(ji,jj,ikv)
345
346               IF( ze3wu >= 0._wp ) THEN   ;   pgru(ji,jj) = ssumask(ji,jj) * ( zri(ji  ,jj    ) - prd(ji,jj,iku) )   ! i: 1
347               ELSE                        ;   pgru(ji,jj) = ssumask(ji,jj) * ( prd(ji+1,jj,iku) - zri(ji,jj    ) )   ! i: 2
348               ENDIF
349               IF( ze3wv >= 0._wp ) THEN   ;   pgrv(ji,jj) = ssvmask(ji,jj) * ( zrj(ji,jj      ) - prd(ji,jj,ikv) )   ! j: 1
350               ELSE                        ;   pgrv(ji,jj) = ssvmask(ji,jj) * ( prd(ji,jj+1,ikv) - zrj(ji,jj    ) )   ! j: 2
351               ENDIF
352
353            END DO
354         END DO
355
356         CALL lbc_lnk( pgru , 'U', -1. )   ;   CALL lbc_lnk( pgrv , 'V', -1. )   ! Lateral boundary conditions
357         !
358      END IF
359      !
360      !     !==  (ISH)  compute grui and gruvi  ==!
361      !
362      DO jn = 1, kjpt      !==   Interpolation of tracers at the last ocean level   ==!            !
363         DO jj = 1, jpjm1
364            DO ji = 1, jpim1
365               iku = miku(ji,jj); ikup1 = miku(ji,jj) + 1
366               ikv = mikv(ji,jj); ikvp1 = mikv(ji,jj) + 1
367               !
368               ! (ISF) case partial step top and bottom in adjacent cell in vertical
369               ! cannot used e3w because if 2 cell water column, we have ps at top and bottom
370               ! in this case e3w(i,j) - e3w(i,j+1) is not the distance between Tj~ and Tj
371               ! the only common depth between cells (i,j) and (i,j+1) is gdepw_0
372               ze3wu  =  fsdept_n(ji,jj,iku) - fsdept_n(ji+1,jj,iku)
373               ze3wv  =  fsdept_n(ji,jj,ikv) - fsdept_n(ji,jj+1,ikv) 
374
375               ! i- direction
376               IF( ze3wu >= 0._wp ) THEN      ! case 1
377                  zmaxu = ze3wu / fse3w(ji+1,jj,ikup1)
378                  ! interpolated values of tracers
379                  zti(ji,jj,jn) = pta(ji+1,jj,iku,jn) + zmaxu * ( pta(ji+1,jj,ikup1,jn) - pta(ji+1,jj,iku,jn) )
380                  ! gradient of tracers
381                  pgtui(ji,jj,jn) = ssumask(ji,jj) * ( zti(ji,jj,jn) - pta(ji,jj,iku,jn) )
382               ELSE                           ! case 2
383                  zmaxu = - ze3wu / fse3w(ji,jj,ikup1)
384                  ! interpolated values of tracers
385                  zti(ji,jj,jn) = pta(ji,jj,iku,jn) + zmaxu * ( pta(ji,jj,ikup1,jn) - pta(ji,jj,iku,jn) )
386                  ! gradient of  tracers
387                  pgtui(ji,jj,jn) = ssumask(ji,jj) * ( pta(ji+1,jj,iku,jn) - zti(ji,jj,jn) )
388               ENDIF
389               !
390               ! j- direction
391               IF( ze3wv >= 0._wp ) THEN      ! case 1
392                  zmaxv =  ze3wv / fse3w(ji,jj+1,ikvp1)
393                  ! interpolated values of tracers
394                  ztj(ji,jj,jn) = pta(ji,jj+1,ikv,jn) + zmaxv * ( pta(ji,jj+1,ikvp1,jn) - pta(ji,jj+1,ikv,jn) )
395                  ! gradient of tracers
396                  pgtvi(ji,jj,jn) = ssvmask(ji,jj) * ( ztj(ji,jj,jn) - pta(ji,jj,ikv,jn) )
397               ELSE                           ! case 2
398                  zmaxv =  - ze3wv / fse3w(ji,jj,ikvp1)
399                  ! interpolated values of tracers
400                  ztj(ji,jj,jn) = pta(ji,jj,ikv,jn) + zmaxv * ( pta(ji,jj,ikvp1,jn) - pta(ji,jj,ikv,jn) )
401                  ! gradient of tracers
402                  pgtvi(ji,jj,jn) = ssvmask(ji,jj) * ( pta(ji,jj+1,ikv,jn) - ztj(ji,jj,jn) )
403               ENDIF
404
405            END DO
406         END DO
407         CALL lbc_lnk( pgtui(:,:,jn), 'U', -1. ); CALL lbc_lnk( pgtvi(:,:,jn), 'V', -1. )   ! Lateral boundary cond.
408         !
409      END DO
410
411      IF( PRESENT( prd ) ) THEN    !==  horizontal derivative of density anomalies (rd)  ==!    (optional part)
412         !
413         pgrui(:,:)  =0.0_wp; pgrvi(:,:)  =0.0_wp;
414         DO jj = 1, jpjm1
415            DO ji = 1, jpim1
416
417               iku = miku(ji,jj)
418               ikv = mikv(ji,jj)
419               ze3wu  =  fsdept_n(ji,jj,iku) - fsdept_n(ji+1,jj,iku)
420               ze3wv  =  fsdept_n(ji,jj,ikv) - fsdept_n(ji,jj+1,ikv) 
421               !
422               IF( ze3wu >= 0._wp ) THEN   ;   zhi(ji,jj) = fsdept(ji  ,jj,iku)    ! i-direction: case 1
423               ELSE                        ;   zhi(ji,jj) = fsdept(ji+1,jj,iku)    ! -     -      case 2
424               ENDIF
425
426               IF( ze3wv >= 0._wp ) THEN   ;   zhj(ji,jj) = fsdept(ji,jj  ,ikv)    ! j-direction: case 1
427               ELSE                        ;   zhj(ji,jj) = fsdept(ji,jj+1,ikv)    ! -     -      case 2
428               ENDIF
429
430            END DO
431         END DO
432         !
433         CALL eos( zti, zhi, zri )        ! interpolated density from zti, ztj
434         CALL eos( ztj, zhj, zrj )        ! at the partial step depth output in  zri, zrj
435         !
436         DO jj = 1, jpjm1                 ! Gradient of density at the last level
437            DO ji = 1, jpim1
438
439               iku = miku(ji,jj) 
440               ikv = mikv(ji,jj) 
441               ze3wu  =  fsdept_n(ji,jj,iku) - fsdept_n(ji+1,jj,iku)
442               ze3wv  =  fsdept_n(ji,jj,ikv) - fsdept_n(ji,jj+1,ikv) 
443
444               IF( ze3wu >= 0._wp ) THEN ; pgrui(ji,jj) = ssumask(ji,jj) * ( zri(ji  ,jj      ) - prd(ji,jj,iku) ) ! i: 1
445               ELSE                      ; pgrui(ji,jj) = ssumask(ji,jj) * ( prd(ji+1,jj  ,iku) - zri(ji,jj    ) ) ! i: 2
446               ENDIF
447
448               IF( ze3wv >= 0._wp ) THEN ; pgrvi(ji,jj) = ssvmask(ji,jj) * ( zrj(ji  ,jj      ) - prd(ji,jj,ikv) ) ! j: 1
449               ELSE                      ; pgrvi(ji,jj) = ssvmask(ji,jj) * ( prd(ji  ,jj+1,ikv) - zrj(ji,jj    ) ) ! j: 2
450               ENDIF
451
452            END DO
453         END DO
454         CALL lbc_lnk( pgrui   , 'U', -1. ); CALL lbc_lnk( pgrvi   , 'V', -1. )   ! Lateral boundary conditions
455         !
456      END IF 
457      !
458      IF( nn_timing == 1 )   CALL timing_stop( 'zps_hde_isf')
459      !
460   END SUBROUTINE zps_hde_isf
461   !!======================================================================
462END MODULE zpshde
Note: See TracBrowser for help on using the repository browser.