New URL for NEMO forge!   http://forge.nemo-ocean.eu

Since March 2022 along with NEMO 4.2 release, the code development moved to a self-hosted GitLab.
This present forge is now archived and remained online for history.
nemogcm.F90 in branches/2015/dev_r5151_UKMO_ISF/NEMOGCM/NEMO/OPA_SRC – NEMO

source: branches/2015/dev_r5151_UKMO_ISF/NEMOGCM/NEMO/OPA_SRC/nemogcm.F90 @ 5956

Last change on this file since 5956 was 5956, checked in by mathiot, 8 years ago

ISF : merged trunk (5936) into branch

  • Property svn:keywords set to Id
File size: 39.9 KB
Line 
1MODULE nemogcm
2   !!======================================================================
3   !!                       ***  MODULE nemogcm   ***
4   !! Ocean system   : NEMO GCM (ocean dynamics, on-line tracers, biochemistry and sea-ice)
5   !!======================================================================
6   !! History :  OPA  ! 1990-10  (C. Levy, G. Madec)  Original code
7   !!            7.0  ! 1991-11  (M. Imbard, C. Levy, G. Madec)
8   !!            7.1  ! 1993-03  (M. Imbard, C. Levy, G. Madec, O. Marti, M. Guyon, A. Lazar,
9   !!                             P. Delecluse, C. Perigaud, G. Caniaux, B. Colot, C. Maes) release 7.1
10   !!             -   ! 1992-06  (L.Terray)  coupling implementation
11   !!             -   ! 1993-11  (M.A. Filiberti) IGLOO sea-ice
12   !!            8.0  ! 1996-03  (M. Imbard, C. Levy, G. Madec, O. Marti, M. Guyon, A. Lazar,
13   !!                             P. Delecluse, L.Terray, M.A. Filiberti, J. Vialar, A.M. Treguier, M. Levy) release 8.0
14   !!            8.1  ! 1997-06  (M. Imbard, G. Madec)
15   !!            8.2  ! 1999-11  (M. Imbard, H. Goosse)  LIM sea-ice model
16   !!                 ! 1999-12  (V. Thierry, A-M. Treguier, M. Imbard, M-A. Foujols)  OPEN-MP
17   !!                 ! 2000-07  (J-M Molines, M. Imbard)  Open Boundary Conditions  (CLIPPER)
18   !!   NEMO     1.0  ! 2002-08  (G. Madec)  F90: Free form and modules
19   !!             -   ! 2004-06  (R. Redler, NEC CCRLE, Germany) add OASIS[3/4] coupled interfaces
20   !!             -   ! 2004-08  (C. Talandier) New trends organization
21   !!             -   ! 2005-06  (C. Ethe) Add the 1D configuration possibility
22   !!             -   ! 2005-11  (V. Garnier) Surface pressure gradient organization
23   !!             -   ! 2006-03  (L. Debreu, C. Mazauric)  Agrif implementation
24   !!             -   ! 2006-04  (G. Madec, R. Benshila)  Step reorganization
25   !!             -   ! 2007-07  (J. Chanut, A. Sellar) Unstructured open boundaries (BDY)
26   !!            3.2  ! 2009-08  (S. Masson)  open/write in the listing file in mpp
27   !!            3.3  ! 2010-05  (K. Mogensen, A. Weaver, M. Martin, D. Lea) Assimilation interface
28   !!             -   ! 2010-10  (C. Ethe, G. Madec) reorganisation of initialisation phase
29   !!            3.3.1! 2011-01  (A. R. Porter, STFC Daresbury) dynamical allocation
30   !!            3.4  ! 2011-10  (A. C. Coward, NOCS & J. Donners, PRACE) add nemo_northcomms
31   !!             -   ! 2011-11  (C. Harris) decomposition changes for running with CICE
32   !!            3.6  ! 2012-05  (C. Calone, J. Simeon, G. Madec, C. Ethe) Add grid coarsening
33   !!             -   ! 2013-06  (I. Epicoco, S. Mocavero, CMCC) nemo_northcomms: setup avoiding MPI communication
34   !!             -   ! 2014-12  (G. Madec) remove KPP scheme and cross-land advection (cla)
35   !!----------------------------------------------------------------------
36
37   !!----------------------------------------------------------------------
38   !!   nemo_gcm       : solve ocean dynamics, tracer, biogeochemistry and/or sea-ice
39   !!   nemo_init      : initialization of the NEMO system
40   !!   nemo_ctl       : initialisation of the contol print
41   !!   nemo_closefile : close remaining open files
42   !!   nemo_alloc     : dynamical allocation
43   !!   nemo_partition : calculate MPP domain decomposition
44   !!   factorise      : calculate the factors of the no. of MPI processes
45   !!----------------------------------------------------------------------
46   USE step_oce        ! module used in the ocean time stepping module (step.F90)
47   USE domcfg          ! domain configuration               (dom_cfg routine)
48   USE mppini          ! shared/distributed memory setting (mpp_init routine)
49   USE domain          ! domain initialization             (dom_init routine)
50#if defined key_nemocice_decomp
51   USE ice_domain_size, only: nx_global, ny_global
52#endif
53   USE tideini         ! tidal components initialization   (tide_ini routine)
54   USE bdyini          ! open boundary cond. setting       (bdy_init routine)
55   USE bdydta          ! open boundary cond. setting   (bdy_dta_init routine)
56   USE bdytides        ! open boundary cond. setting   (bdytide_init routine)
57   USE istate          ! initial state setting          (istate_init routine)
58   USE ldfdyn          ! lateral viscosity setting      (ldfdyn_init routine)
59   USE ldftra          ! lateral diffusivity setting    (ldftra_init routine)
60   USE zdfini          ! vertical physics setting          (zdf_init routine)
61   USE phycst          ! physical constant                  (par_cst routine)
62   USE trdini          ! dyn/tra trends initialization     (trd_init routine)
63   USE asminc          ! assimilation increments     
64   USE asmbkg          ! writing out state trajectory
65   USE diaptr          ! poleward transports           (dia_ptr_init routine)
66   USE diadct          ! sections transports           (dia_dct_init routine)
67   USE diaobs          ! Observation diagnostics       (dia_obs_init routine)
68   USE lib_fortran     ! Fortran utilities (allows no signed zero when 'key_nosignedzero' defined)
69   USE step            ! NEMO time-stepping                 (stp     routine)
70   USE icbini          ! handle bergs, initialisation
71   USE icbstp          ! handle bergs, calving, themodynamics and transport
72   USE cpl_oasis3      ! OASIS3 coupling
73   USE c1d             ! 1D configuration
74   USE step_c1d        ! Time stepping loop for the 1D configuration
75   USE dyndmp          ! Momentum damping
76#if defined key_top
77   USE trcini          ! passive tracer initialisation
78#endif
79   USE lib_mpp         ! distributed memory computing
80#if defined key_iomput
81   USE xios            ! xIOserver
82#endif
83   USE sbctide, ONLY   : lk_tide
84   USE crsini          ! initialise grid coarsening utility
85   USE lbcnfd , ONLY   : isendto, nsndto, nfsloop, nfeloop   ! Setup of north fold exchanges
86   USE sbc_oce, ONLY   : lk_oasis
87   USE stopar
88   USE stopts
89
90   IMPLICIT NONE
91   PRIVATE
92
93   PUBLIC   nemo_gcm    ! called by model.F90
94   PUBLIC   nemo_init   ! needed by AGRIF
95   PUBLIC   nemo_alloc  ! needed by TAM
96
97   CHARACTER(lc) ::   cform_aaa="( /, 'AAAAAAAA', / ) "     ! flag for output listing
98
99   !!----------------------------------------------------------------------
100   !! NEMO/OPA 3.7 , NEMO Consortium (2015)
101   !! $Id$
102   !! Software governed by the CeCILL licence     (NEMOGCM/NEMO_CeCILL.txt)
103   !!----------------------------------------------------------------------
104CONTAINS
105
106   SUBROUTINE nemo_gcm
107      !!----------------------------------------------------------------------
108      !!                     ***  ROUTINE nemo_gcm  ***
109      !!
110      !! ** Purpose :   NEMO solves the primitive equations on an orthogonal
111      !!              curvilinear mesh on the sphere.
112      !!
113      !! ** Method  : - model general initialization
114      !!              - launch the time-stepping (stp routine)
115      !!              - finalize the run by closing files and communications
116      !!
117      !! References : Madec, Delecluse, Imbard, and Levy, 1997:  internal report, IPSL.
118      !!              Madec, 2008, internal report, IPSL.
119      !!----------------------------------------------------------------------
120      INTEGER ::   istp       ! time step index
121      !!----------------------------------------------------------------------
122      !
123#if defined key_agrif
124      CALL Agrif_Init_Grids()      ! AGRIF: set the meshes
125#endif
126
127      !                            !-----------------------!
128      CALL nemo_init               !==  Initialisations  ==!
129      !                            !-----------------------!
130#if defined key_agrif
131      CALL Agrif_Declare_Var_dom   ! AGRIF: set the meshes for DOM
132      CALL Agrif_Declare_Var       !  "      "   "   "      "  DYN/TRA
133# if defined key_top
134      CALL Agrif_Declare_Var_top   !  "      "   "   "      "  TOP
135# endif
136# if defined key_lim2
137      CALL Agrif_Declare_Var_lim2  !  "      "   "   "      "  LIM
138# endif
139#endif
140      ! check that all process are still there... If some process have an error,
141      ! they will never enter in step and other processes will wait until the end of the cpu time!
142      IF( lk_mpp )   CALL mpp_max( nstop )
143
144      IF(lwp) WRITE(numout,cform_aaa)   ! Flag AAAAAAA
145
146      !                            !-----------------------!
147      !                            !==   time stepping   ==!
148      !                            !-----------------------!
149      istp = nit000
150#if defined key_c1d
151         DO WHILE ( istp <= nitend .AND. nstop == 0 )
152            CALL stp_c1d( istp )
153            istp = istp + 1
154         END DO
155#else
156          IF( lk_asminc ) THEN
157             IF( ln_bkgwri ) CALL asm_bkg_wri( nit000 - 1 )    ! Output background fields
158             IF( ln_asmdin ) THEN                        ! Direct initialization
159                IF( ln_trainc ) CALL tra_asm_inc( nit000 - 1 )    ! Tracers
160                IF( ln_dyninc ) CALL dyn_asm_inc( nit000 - 1 )    ! Dynamics
161                IF( ln_sshinc ) CALL ssh_asm_inc( nit000 - 1 )    ! SSH
162             ENDIF
163          ENDIF
164
165#if defined key_agrif
166          CALL Agrif_Regrid()
167#endif
168
169         DO WHILE ( istp <= nitend .AND. nstop == 0 )
170#if defined key_agrif
171            CALL stp                         ! AGRIF: time stepping
172#else
173            CALL stp( istp )                 ! standard time stepping
174#endif
175            istp = istp + 1
176            IF( lk_mpp )   CALL mpp_max( nstop )
177         END DO
178#endif
179
180      IF( lk_diaobs   )   CALL dia_obs_wri
181      !
182      IF( ln_icebergs )   CALL icb_end( nitend )
183
184      !                            !------------------------!
185      !                            !==  finalize the run  ==!
186      !                            !------------------------!
187      IF(lwp) WRITE(numout,cform_aaa)   ! Flag AAAAAAA
188      !
189      IF( nstop /= 0 .AND. lwp ) THEN   ! error print
190         WRITE(numout,cform_err)
191         WRITE(numout,*) nstop, ' error have been found'
192      ENDIF
193      !
194#if defined key_agrif
195      IF(.NOT.Agrif_Root() ) THEN
196                                CALL Agrif_ParentGrid_To_ChildGrid()
197         IF( lk_diaobs )        CALL dia_obs_wri
198         IF( nn_timing == 1 )   CALL timing_finalize
199                                CALL Agrif_ChildGrid_To_ParentGrid()
200      ENDIF
201#endif
202      IF( nn_timing == 1 )   CALL timing_finalize
203      !
204      CALL nemo_closefile
205      !
206#if defined key_iomput
207      CALL xios_finalize                  ! end mpp communications with xios
208      IF( lk_oasis )   CALL cpl_finalize  ! end coupling and mpp communications with OASIS
209#else
210      IF( lk_oasis ) THEN
211         CALL cpl_finalize              ! end coupling and mpp communications with OASIS
212      ELSE
213         IF( lk_mpp )   CALL mppstop    ! end mpp communications
214      ENDIF
215#endif
216      !
217   END SUBROUTINE nemo_gcm
218
219
220   SUBROUTINE nemo_init
221      !!----------------------------------------------------------------------
222      !!                     ***  ROUTINE nemo_init  ***
223      !!
224      !! ** Purpose :   initialization of the NEMO GCM
225      !!----------------------------------------------------------------------
226      INTEGER ::   ji            ! dummy loop indices
227      INTEGER ::   ilocal_comm   ! local integer
228      INTEGER ::   ios
229      CHARACTER(len=80), DIMENSION(16) ::   cltxt
230      !
231      NAMELIST/namctl/ ln_ctl  , nn_print, nn_ictls, nn_ictle,   &
232         &             nn_isplt, nn_jsplt, nn_jctls, nn_jctle,   &
233         &             nn_bench, nn_timing
234      NAMELIST/namcfg/ cp_cfg, cp_cfz, jp_cfg, jpidta, jpjdta, jpkdta, jpiglo, jpjglo, &
235         &             jpizoom, jpjzoom, jperio, ln_use_jattr
236      !!----------------------------------------------------------------------
237      !
238      cltxt = ''
239      cxios_context = 'nemo'
240      !
241      !                             ! Open reference namelist and configuration namelist files
242      CALL ctl_opn( numnam_ref, 'namelist_ref', 'OLD', 'FORMATTED', 'SEQUENTIAL', -1, 6, .FALSE. )
243      CALL ctl_opn( numnam_cfg, 'namelist_cfg', 'OLD', 'FORMATTED', 'SEQUENTIAL', -1, 6, .FALSE. )
244      !
245      REWIND( numnam_ref )              ! Namelist namctl in reference namelist : Control prints & Benchmark
246      READ  ( numnam_ref, namctl, IOSTAT = ios, ERR = 901 )
247901   IF( ios /= 0 ) CALL ctl_nam ( ios , 'namctl in reference namelist', .TRUE. )
248
249      REWIND( numnam_cfg )              ! Namelist namctl in confguration namelist : Control prints & Benchmark
250      READ  ( numnam_cfg, namctl, IOSTAT = ios, ERR = 902 )
251902   IF( ios /= 0 ) CALL ctl_nam ( ios , 'namctl in configuration namelist', .TRUE. )
252
253      !
254      REWIND( numnam_ref )              ! Namelist namcfg in reference namelist : Control prints & Benchmark
255      READ  ( numnam_ref, namcfg, IOSTAT = ios, ERR = 903 )
256903   IF( ios /= 0 ) CALL ctl_nam ( ios , 'namcfg in reference namelist', .TRUE. )
257
258      REWIND( numnam_cfg )              ! Namelist namcfg in confguration namelist : Control prints & Benchmark
259      READ  ( numnam_cfg, namcfg, IOSTAT = ios, ERR = 904 )
260904   IF( ios /= 0 ) CALL ctl_nam ( ios , 'namcfg in configuration namelist', .TRUE. )   
261
262! Force values for AGRIF zoom (cf. agrif_user.F90)
263#if defined key_agrif
264   IF( .NOT. Agrif_Root() ) THEN
265      jpiglo  = nbcellsx + 2 + 2*nbghostcells
266      jpjglo  = nbcellsy + 2 + 2*nbghostcells
267      jpi     = ( jpiglo-2*jpreci + (jpni-1+0) ) / jpni + 2*jpreci
268      jpj     = ( jpjglo-2*jprecj + (jpnj-1+0) ) / jpnj + 2*jprecj
269      jpidta  = jpiglo
270      jpjdta  = jpjglo
271      jpizoom = 1
272      jpjzoom = 1
273      nperio  = 0
274      jperio  = 0
275      ln_use_jattr = .false.
276   ENDIF
277#endif
278      !
279      !                             !--------------------------------------------!
280      !                             !  set communicator & select the local node  !
281      !                             !  NB: mynode also opens output.namelist.dyn !
282      !                             !      on unit number numond on first proc   !
283      !                             !--------------------------------------------!
284#if defined key_iomput
285      IF( Agrif_Root() ) THEN
286         IF( lk_oasis ) THEN
287            CALL cpl_init( "oceanx", ilocal_comm )                     ! nemo local communicator given by oasis
288            CALL xios_initialize( "not used",local_comm=ilocal_comm )    ! send nemo communicator to xios
289         ELSE
290            CALL  xios_initialize( "for_xios_mpi_id",return_comm=ilocal_comm )    ! nemo local communicator given by xios
291         ENDIF
292      ENDIF
293      ! Nodes selection (control print return in cltxt)
294      narea = mynode( cltxt, 'output.namelist.dyn', numnam_ref, numnam_cfg, numond , nstop, ilocal_comm )
295#else
296      IF( lk_oasis ) THEN
297         IF( Agrif_Root() ) THEN
298            CALL cpl_init( "oceanx", ilocal_comm )                      ! nemo local communicator given by oasis
299         ENDIF
300         ! Nodes selection (control print return in cltxt)
301         narea = mynode( cltxt, 'output.namelist.dyn', numnam_ref, numnam_cfg, numond , nstop, ilocal_comm )
302      ELSE
303         ilocal_comm = 0
304         ! Nodes selection (control print return in cltxt)
305         narea = mynode( cltxt, 'output.namelist.dyn', numnam_ref, numnam_cfg, numond , nstop )
306      ENDIF
307#endif
308      narea = narea + 1                                     ! mynode return the rank of proc (0 --> jpnij -1 )
309
310      lwm = (narea == 1)                                    ! control of output namelists
311      lwp = (narea == 1) .OR. ln_ctl                        ! control of all listing output print
312
313      IF(lwm) THEN
314         ! write merged namelists from earlier to output namelist now that the
315         ! file has been opened in call to mynode. nammpp has already been
316         ! written in mynode (if lk_mpp_mpi)
317         WRITE( numond, namctl )
318         WRITE( numond, namcfg )
319      ENDIF
320
321      ! If dimensions of processor grid weren't specified in the namelist file
322      ! then we calculate them here now that we have our communicator size
323      IF( jpni < 1 .OR. jpnj < 1 ) THEN
324#if   defined key_mpp_mpi
325         IF( Agrif_Root() )   CALL nemo_partition( mppsize )
326#else
327         jpni  = 1
328         jpnj  = 1
329         jpnij = jpni*jpnj
330#endif
331      ENDIF
332
333      ! Calculate domain dimensions given calculated jpni and jpnj
334      ! This used to be done in par_oce.F90 when they were parameters rather than variables
335      IF( Agrif_Root() ) THEN
336#if defined key_nemocice_decomp
337         jpi = ( nx_global+2-2*jpreci + (jpni-1) ) / jpni + 2*jpreci    ! first  dim.
338         jpj = ( ny_global+2-2*jprecj + (jpnj-1) ) / jpnj + 2*jprecj    ! second dim.
339#else
340         jpi = ( jpiglo     -2*jpreci + (jpni-1) ) / jpni + 2*jpreci    ! first  dim.
341         jpj = ( jpjglo     -2*jprecj + (jpnj-1) ) / jpnj + 2*jprecj    ! second dim.
342#endif
343      ENDIF         
344         jpk = jpkdta                                             ! third dim
345#if defined key_agrif
346         ! simple trick to use same vertical grid as parent but different number of levels:
347         ! Save maximum number of levels in jpkdta, then define all vertical grids with this number.
348         ! Suppress once vertical online interpolation is ok
349         IF(.NOT.Agrif_Root())   jpkdta = Agrif_Parent( jpkdta )
350#endif
351         jpim1 = jpi-1                                            ! inner domain indices
352         jpjm1 = jpj-1                                            !   "           "
353         jpkm1 = jpk-1                                            !   "           "
354         jpij  = jpi*jpj                                          !  jpi x j
355
356      IF(lwp) THEN                            ! open listing units
357         !
358         CALL ctl_opn( numout, 'ocean.output', 'REPLACE', 'FORMATTED', 'SEQUENTIAL', -1, 6, .FALSE., narea )
359         !
360         WRITE(numout,*)
361         WRITE(numout,*) '   CNRS - NERC - Met OFFICE - MERCATOR-ocean - INGV - CMCC'
362         WRITE(numout,*) '                       NEMO team'
363         WRITE(numout,*) '            Ocean General Circulation Model'
364         WRITE(numout,*) '                  version 3.7  (2015) '
365         WRITE(numout,*)
366         WRITE(numout,*)
367         DO ji = 1, SIZE(cltxt)
368            IF( TRIM(cltxt(ji)) /= '' )   WRITE(numout,*) cltxt(ji)      ! control print of mynode
369         END DO
370         WRITE(numout,cform_aaa)                                         ! Flag AAAAAAA
371         !
372      ENDIF
373
374      ! Now we know the dimensions of the grid and numout has been set we can
375      ! allocate arrays
376      CALL nemo_alloc()
377
378      !                             !-------------------------------!
379      !                             !  NEMO general initialization  !
380      !                             !-------------------------------!
381
382      CALL nemo_ctl                          ! Control prints & Benchmark
383
384      !                                      ! Domain decomposition
385      IF( jpni*jpnj == jpnij ) THEN   ;   CALL mpp_init      ! standard cutting out
386      ELSE                            ;   CALL mpp_init2     ! eliminate land processors
387      ENDIF
388      !
389      IF( nn_timing == 1 )  CALL timing_init
390      !
391      !                                      ! General initialization
392                            CALL     phy_cst    ! Physical constants
393                            CALL     eos_init   ! Equation of state
394      IF( lk_c1d        )   CALL     c1d_init   ! 1D column configuration
395                            CALL     dom_cfg    ! Domain configuration
396                            CALL     dom_init   ! Domain
397      IF( ln_crs        )   CALL     crs_init   ! coarsened grid: domain initialization
398      IF( ln_nnogather )    CALL nemo_northcomms! northfold neighbour lists (must be done after the masks are defined)
399      IF( ln_ctl        )   CALL prt_ctl_init   ! Print control
400                            CALL  istate_init   ! ocean initial state (Dynamics and tracers)
401
402      !                                      ! external forcing
403!!gm to be added : creation and call of sbc_apr_init
404      IF( lk_tide       )   CALL    tide_init( nit000 )    ! tidal harmonics
405                            CALL     sbc_init   ! surface boundary conditions (including sea-ice)
406!!gm ==>> bdy_init should call bdy_dta_init and bdytide_init  NOT in nemogcm !!!
407      IF( lk_bdy        )   CALL     bdy_init   ! Open boundaries initialisation
408      IF( lk_bdy        )   CALL bdy_dta_init   ! Open boundaries initialisation of external data arrays
409      IF( lk_bdy .AND. lk_tide )   &
410         &                  CALL bdytide_init   ! Open boundaries initialisation of tidal harmonic forcing
411         
412      !                                      ! Ocean physics
413      !                                         ! Vertical physics
414                            CALL     zdf_init      ! namelist read
415                            CALL zdf_bfr_init      ! bottom friction
416      IF( lk_zdfric     )   CALL zdf_ric_init      ! Richardson number dependent Kz
417      IF( lk_zdftke     )   CALL zdf_tke_init      ! TKE closure scheme
418      IF( lk_zdfgls     )   CALL zdf_gls_init      ! GLS closure scheme
419      IF( lk_zdftmx     )   CALL zdf_tmx_init      ! tidal vertical mixing
420      IF( lk_zdfddm     )   CALL zdf_ddm_init      ! double diffusive mixing
421         
422      !                                         ! Lateral physics
423                            CALL ldf_tra_init      ! Lateral ocean tracer physics
424                            CALL ldf_eiv_init      ! eddy induced velocity param.
425                            CALL ldf_dyn_init      ! Lateral ocean momentum physics
426
427      !                                         ! Active tracers
428                            CALL tra_qsr_init      ! penetrative solar radiation qsr
429                            CALL tra_bbc_init      ! bottom heat flux
430      IF( lk_trabbl     )   CALL tra_bbl_init      ! advective (and/or diffusive) bottom boundary layer scheme
431                            CALL tra_dmp_init      ! internal tracer damping
432                            CALL tra_adv_init      ! horizontal & vertical advection
433                            CALL tra_ldf_init      ! lateral mixing
434                            CALL tra_zdf_init      ! vertical mixing and after tracer fields
435
436      !                                         ! Dynamics
437      IF( lk_c1d        )   CALL dyn_dmp_init      ! internal momentum damping
438                            CALL dyn_adv_init      ! advection (vector or flux form)
439                            CALL dyn_vor_init      ! vorticity term including Coriolis
440                            CALL dyn_ldf_init      ! lateral mixing
441                            CALL dyn_hpg_init      ! horizontal gradient of Hydrostatic pressure
442                            CALL dyn_zdf_init      ! vertical diffusion
443                            CALL dyn_spg_init      ! surface pressure gradient
444
445#if defined key_top
446      !                                      ! Passive tracers
447                            CALL     trc_init
448#endif
449      IF( l_ldfslp      )   CALL ldf_slp_init   ! slope of lateral mixing
450
451      !                                      ! Icebergs
452                            CALL icb_init( rdt, nit000)   ! initialise icebergs instance
453
454      !                                      ! Misc. options
455                            CALL sto_par_init   ! Stochastic parametrization
456      IF( ln_sto_eos     )  CALL sto_pts_init   ! RRandom T/S fluctuations
457     
458      !                                      ! Diagnostics
459      IF( lk_floats     )   CALL     flo_init   ! drifting Floats
460      IF( lk_diaar5     )   CALL dia_ar5_init   ! ar5 diag
461                            CALL dia_ptr_init   ! Poleward TRansports initialization
462      IF( lk_diadct     )   CALL dia_dct_init   ! Sections tranports
463                            CALL dia_hsb_init   ! heat content, salt content and volume budgets
464                            CALL     trd_init   ! Mixed-layer/Vorticity/Integral constraints trends
465      IF( lk_diaobs     ) THEN                  ! Observation & model comparison
466                            CALL dia_obs_init            ! Initialize observational data
467                            CALL dia_obs( nit000 - 1 )   ! Observation operator for restart
468      ENDIF
469      !                                      ! Assimilation increments
470      IF( lk_asminc     )   CALL asm_inc_init   ! Initialize assimilation increments
471      IF(lwp) WRITE(numout,*) 'Euler time step switch is ', neuler
472      !
473   END SUBROUTINE nemo_init
474
475
476   SUBROUTINE nemo_ctl
477      !!----------------------------------------------------------------------
478      !!                     ***  ROUTINE nemo_ctl  ***
479      !!
480      !! ** Purpose :   control print setting
481      !!
482      !! ** Method  : - print namctl information and check some consistencies
483      !!----------------------------------------------------------------------
484      !
485      IF(lwp) THEN                  ! control print
486         WRITE(numout,*)
487         WRITE(numout,*) 'nemo_ctl: Control prints & Benchmark'
488         WRITE(numout,*) '~~~~~~~ '
489         WRITE(numout,*) '   Namelist namctl'
490         WRITE(numout,*) '      run control (for debugging)     ln_ctl     = ', ln_ctl
491         WRITE(numout,*) '      level of print                  nn_print   = ', nn_print
492         WRITE(numout,*) '      Start i indice for SUM control  nn_ictls   = ', nn_ictls
493         WRITE(numout,*) '      End i indice for SUM control    nn_ictle   = ', nn_ictle
494         WRITE(numout,*) '      Start j indice for SUM control  nn_jctls   = ', nn_jctls
495         WRITE(numout,*) '      End j indice for SUM control    nn_jctle   = ', nn_jctle
496         WRITE(numout,*) '      number of proc. following i     nn_isplt   = ', nn_isplt
497         WRITE(numout,*) '      number of proc. following j     nn_jsplt   = ', nn_jsplt
498         WRITE(numout,*) '      benchmark parameter (0/1)       nn_bench   = ', nn_bench
499         WRITE(numout,*) '      timing activated    (0/1)       nn_timing  = ', nn_timing
500      ENDIF
501      !
502      nprint    = nn_print          ! convert DOCTOR namelist names into OLD names
503      nictls    = nn_ictls
504      nictle    = nn_ictle
505      njctls    = nn_jctls
506      njctle    = nn_jctle
507      isplt     = nn_isplt
508      jsplt     = nn_jsplt
509      nbench    = nn_bench
510
511      IF(lwp) THEN                  ! control print
512         WRITE(numout,*)
513         WRITE(numout,*) 'namcfg  : configuration initialization through namelist read'
514         WRITE(numout,*) '~~~~~~~ '
515         WRITE(numout,*) '   Namelist namcfg'
516         WRITE(numout,*) '      configuration name                               cp_cfg  = ', TRIM(cp_cfg)
517         WRITE(numout,*) '      configuration zoom name                          cp_cfz  = ', TRIM(cp_cfz)
518         WRITE(numout,*) '      configuration resolution                         jp_cfg  = ', jp_cfg
519         WRITE(numout,*) '      1st lateral dimension ( >= jpiglo )              jpidta  = ', jpidta
520         WRITE(numout,*) '      2nd    "         "    ( >= jpjglo )              jpjdta  = ', jpjdta
521         WRITE(numout,*) '      3nd    "         "                               jpkdta  = ', jpkdta
522         WRITE(numout,*) '      1st dimension of global domain in i              jpiglo  = ', jpiglo
523         WRITE(numout,*) '      2nd    -                  -    in j              jpjglo  = ', jpjglo
524         WRITE(numout,*) '      left bottom i index of the zoom (in data domain) jpizoom = ', jpizoom
525         WRITE(numout,*) '      left bottom j index of the zoom (in data domain) jpizoom = ', jpjzoom
526         WRITE(numout,*) '      lateral cond. type (between 0 and 6)             jperio  = ', jperio   
527         WRITE(numout,*) '      use file attribute if exists as i/p j-start ln_use_jattr = ', ln_use_jattr
528      ENDIF
529      !                             ! Parameter control
530      !
531      IF( ln_ctl ) THEN                 ! sub-domain area indices for the control prints
532         IF( lk_mpp .AND. jpnij > 1 ) THEN
533            isplt = jpni   ;   jsplt = jpnj   ;   ijsplt = jpni*jpnj   ! the domain is forced to the real split domain
534         ELSE
535            IF( isplt == 1 .AND. jsplt == 1  ) THEN
536               CALL ctl_warn( ' - isplt & jsplt are equal to 1',   &
537                  &           ' - the print control will be done over the whole domain' )
538            ENDIF
539            ijsplt = isplt * jsplt            ! total number of processors ijsplt
540         ENDIF
541         IF(lwp) WRITE(numout,*)'          - The total number of processors over which the'
542         IF(lwp) WRITE(numout,*)'            print control will be done is ijsplt : ', ijsplt
543         !
544         !                              ! indices used for the SUM control
545         IF( nictls+nictle+njctls+njctle == 0 )   THEN    ! print control done over the default area
546            lsp_area = .FALSE.
547         ELSE                                             ! print control done over a specific  area
548            lsp_area = .TRUE.
549            IF( nictls < 1 .OR. nictls > jpiglo )   THEN
550               CALL ctl_warn( '          - nictls must be 1<=nictls>=jpiglo, it is forced to 1' )
551               nictls = 1
552            ENDIF
553            IF( nictle < 1 .OR. nictle > jpiglo )   THEN
554               CALL ctl_warn( '          - nictle must be 1<=nictle>=jpiglo, it is forced to jpiglo' )
555               nictle = jpiglo
556            ENDIF
557            IF( njctls < 1 .OR. njctls > jpjglo )   THEN
558               CALL ctl_warn( '          - njctls must be 1<=njctls>=jpjglo, it is forced to 1' )
559               njctls = 1
560            ENDIF
561            IF( njctle < 1 .OR. njctle > jpjglo )   THEN
562               CALL ctl_warn( '          - njctle must be 1<=njctle>=jpjglo, it is forced to jpjglo' )
563               njctle = jpjglo
564            ENDIF
565         ENDIF
566      ENDIF
567      !
568      IF( nbench == 1 ) THEN              ! Benchmark
569         SELECT CASE ( cp_cfg )
570         CASE ( 'gyre' )   ;   CALL ctl_warn( ' The Benchmark is activated ' )
571         CASE DEFAULT      ;   CALL ctl_stop( ' The Benchmark is based on the GYRE configuration:',   &
572            &                                 ' cp_cfg = "gyre" in namelist &namcfg or set nbench = 0' )
573         END SELECT
574      ENDIF
575      !
576      IF( 1_wp /= SIGN(1._wp,-0._wp)  )   CALL ctl_stop( 'nemo_ctl: The intrinsec SIGN function follows ',  &
577         &                                               'f2003 standard. '                              ,  &
578         &                                               'Compile with key_nosignedzero enabled' )
579      !
580   END SUBROUTINE nemo_ctl
581
582
583   SUBROUTINE nemo_closefile
584      !!----------------------------------------------------------------------
585      !!                     ***  ROUTINE nemo_closefile  ***
586      !!
587      !! ** Purpose :   Close the files
588      !!----------------------------------------------------------------------
589      !
590      IF( lk_mpp )   CALL mppsync
591      !
592      CALL iom_close                                 ! close all input/output files managed by iom_*
593      !
594      IF( numstp          /= -1 )   CLOSE( numstp          )   ! time-step file
595      IF( numsol          /= -1 )   CLOSE( numsol          )   ! solver file
596      IF( numnam_ref      /= -1 )   CLOSE( numnam_ref      )   ! oce reference namelist
597      IF( numnam_cfg      /= -1 )   CLOSE( numnam_cfg      )   ! oce configuration namelist
598      IF( lwm.AND.numond  /= -1 )   CLOSE( numond          )   ! oce output namelist
599      IF( numnam_ice_ref  /= -1 )   CLOSE( numnam_ice_ref  )   ! ice reference namelist
600      IF( numnam_ice_cfg  /= -1 )   CLOSE( numnam_ice_cfg  )   ! ice configuration namelist
601      IF( lwm.AND.numoni  /= -1 )   CLOSE( numoni          )   ! ice output namelist
602      IF( numevo_ice      /= -1 )   CLOSE( numevo_ice      )   ! ice variables (temp. evolution)
603      IF( numout          /=  6 )   CLOSE( numout          )   ! standard model output file
604      IF( numdct_vol      /= -1 )   CLOSE( numdct_vol      )   ! volume transports
605      IF( numdct_heat     /= -1 )   CLOSE( numdct_heat     )   ! heat transports
606      IF( numdct_salt     /= -1 )   CLOSE( numdct_salt     )   ! salt transports
607      !
608      numout = 6                                     ! redefine numout in case it is used after this point...
609      !
610   END SUBROUTINE nemo_closefile
611
612
613   SUBROUTINE nemo_alloc
614      !!----------------------------------------------------------------------
615      !!                     ***  ROUTINE nemo_alloc  ***
616      !!
617      !! ** Purpose :   Allocate all the dynamic arrays of the OPA modules
618      !!
619      !! ** Method  :
620      !!----------------------------------------------------------------------
621      USE diawri    , ONLY: dia_wri_alloc
622      USE dom_oce   , ONLY: dom_oce_alloc
623      USE trc_oce   , ONLY: trc_oce_alloc
624#if defined key_diadct 
625      USE diadct    , ONLY: diadct_alloc 
626#endif 
627#if defined key_bdy
628      USE bdy_oce   , ONLY: bdy_oce_alloc
629#endif
630      !
631      INTEGER :: ierr
632      !!----------------------------------------------------------------------
633      !
634      ierr =        oce_alloc       ()          ! ocean
635      ierr = ierr + dia_wri_alloc   ()
636      ierr = ierr + dom_oce_alloc   ()          ! ocean domain
637      ierr = ierr + zdf_oce_alloc   ()          ! ocean vertical physics
638      !
639      ierr = ierr + trc_oce_alloc   ()          ! shared TRC / TRA arrays
640      !
641#if defined key_diadct 
642      ierr = ierr + diadct_alloc    ()          !
643#endif 
644#if defined key_bdy
645      ierr = ierr + bdy_oce_alloc   ()          ! bdy masks (incl. initialization)
646#endif
647      !
648      IF( lk_mpp    )   CALL mpp_sum( ierr )
649      IF( ierr /= 0 )   CALL ctl_stop( 'STOP', 'nemo_alloc : unable to allocate standard ocean arrays' )
650      !
651   END SUBROUTINE nemo_alloc
652
653
654   SUBROUTINE nemo_partition( num_pes )
655      !!----------------------------------------------------------------------
656      !!                 ***  ROUTINE nemo_partition  ***
657      !!
658      !! ** Purpose :
659      !!
660      !! ** Method  :
661      !!----------------------------------------------------------------------
662      INTEGER, INTENT(in) ::   num_pes   ! The number of MPI processes we have
663      !
664      INTEGER, PARAMETER :: nfactmax = 20
665      INTEGER :: nfact ! The no. of factors returned
666      INTEGER :: ierr  ! Error flag
667      INTEGER :: ji
668      INTEGER :: idiff, mindiff, imin ! For choosing pair of factors that are closest in value
669      INTEGER, DIMENSION(nfactmax) :: ifact ! Array of factors
670      !!----------------------------------------------------------------------
671      !
672      ierr = 0
673      !
674      CALL factorise( ifact, nfactmax, nfact, num_pes, ierr )
675      !
676      IF( nfact <= 1 ) THEN
677         WRITE (numout, *) 'WARNING: factorisation of number of PEs failed'
678         WRITE (numout, *) '       : using grid of ',num_pes,' x 1'
679         jpnj = 1
680         jpni = num_pes
681      ELSE
682         ! Search through factors for the pair that are closest in value
683         mindiff = 1000000
684         imin    = 1
685         DO ji = 1, nfact-1, 2
686            idiff = ABS( ifact(ji) - ifact(ji+1) )
687            IF( idiff < mindiff ) THEN
688               mindiff = idiff
689               imin = ji
690            ENDIF
691         END DO
692         jpnj = ifact(imin)
693         jpni = ifact(imin + 1)
694      ENDIF
695      !
696      jpnij = jpni*jpnj
697      !
698   END SUBROUTINE nemo_partition
699
700
701   SUBROUTINE factorise( kfax, kmaxfax, knfax, kn, kerr )
702      !!----------------------------------------------------------------------
703      !!                     ***  ROUTINE factorise  ***
704      !!
705      !! ** Purpose :   return the prime factors of n.
706      !!                knfax factors are returned in array kfax which is of
707      !!                maximum dimension kmaxfax.
708      !! ** Method  :
709      !!----------------------------------------------------------------------
710      INTEGER                    , INTENT(in   ) ::   kn, kmaxfax
711      INTEGER                    , INTENT(  out) ::   kerr, knfax
712      INTEGER, DIMENSION(kmaxfax), INTENT(  out) ::   kfax
713      !
714      INTEGER :: ifac, jl, inu
715      INTEGER, PARAMETER :: ntest = 14
716      INTEGER, DIMENSION(ntest) ::   ilfax
717      !!----------------------------------------------------------------------
718      !
719      ! lfax contains the set of allowed factors.
720      ilfax(:) = (/(2**jl,jl=ntest,1,-1)/)
721      !
722      ! Clear the error flag and initialise output vars
723      kerr  = 0
724      kfax  = 1
725      knfax = 0
726      !
727      ! Find the factors of n.
728      IF( kn == 1 )   GOTO 20
729
730      ! nu holds the unfactorised part of the number.
731      ! knfax holds the number of factors found.
732      ! l points to the allowed factor list.
733      ! ifac holds the current factor.
734      !
735      inu   = kn
736      knfax = 0
737      !
738      DO jl = ntest, 1, -1
739         !
740         ifac = ilfax(jl)
741         IF( ifac > inu )   CYCLE
742
743         ! Test whether the factor will divide.
744
745         IF( MOD(inu,ifac) == 0 ) THEN
746            !
747            knfax = knfax + 1            ! Add the factor to the list
748            IF( knfax > kmaxfax ) THEN
749               kerr = 6
750               write (*,*) 'FACTOR: insufficient space in factor array ', knfax
751               return
752            ENDIF
753            kfax(knfax) = ifac
754            ! Store the other factor that goes with this one
755            knfax = knfax + 1
756            kfax(knfax) = inu / ifac
757            !WRITE (*,*) 'ARPDBG, factors ',knfax-1,' & ',knfax,' are ', kfax(knfax-1),' and ',kfax(knfax)
758         ENDIF
759         !
760      END DO
761      !
762   20 CONTINUE      ! Label 20 is the exit point from the factor search loop.
763      !
764   END SUBROUTINE factorise
765
766#if defined key_mpp_mpi
767
768   SUBROUTINE nemo_northcomms
769      !!----------------------------------------------------------------------
770      !!                     ***  ROUTINE  nemo_northcomms  ***
771      !! ** Purpose :   Setup for north fold exchanges with explicit
772      !!                point-to-point messaging
773      !!
774      !! ** Method :   Initialization of the northern neighbours lists.
775      !!----------------------------------------------------------------------
776      !!    1.0  ! 2011-10  (A. C. Coward, NOCS & J. Donners, PRACE)
777      !!    2.0  ! 2013-06 Setup avoiding MPI communication (I. Epicoco, S. Mocavero, CMCC)
778      !!----------------------------------------------------------------------
779      INTEGER  ::   sxM, dxM, sxT, dxT, jn
780      INTEGER  ::   njmppmax
781      !!----------------------------------------------------------------------
782      !
783      njmppmax = MAXVAL( njmppt )
784      !
785      !initializes the north-fold communication variables
786      isendto(:) = 0
787      nsndto     = 0
788      !
789      !if I am a process in the north
790      IF ( njmpp == njmppmax ) THEN
791          !sxM is the first point (in the global domain) needed to compute the
792          !north-fold for the current process
793          sxM = jpiglo - nimppt(narea) - nlcit(narea) + 1
794          !dxM is the last point (in the global domain) needed to compute the
795          !north-fold for the current process
796          dxM = jpiglo - nimppt(narea) + 2
797
798          !loop over the other north-fold processes to find the processes
799          !managing the points belonging to the sxT-dxT range
800 
801          DO jn = 1, jpni
802                !sxT is the first point (in the global domain) of the jn
803                !process
804                sxT = nfiimpp(jn, jpnj)
805                !dxT is the last point (in the global domain) of the jn
806                !process
807                dxT = nfiimpp(jn, jpnj) + nfilcit(jn, jpnj) - 1
808                IF ((sxM .gt. sxT) .AND. (sxM .lt. dxT)) THEN
809                   nsndto = nsndto + 1
810                     isendto(nsndto) = jn
811                ELSEIF ((sxM .le. sxT) .AND. (dxM .ge. dxT)) THEN
812                   nsndto = nsndto + 1
813                     isendto(nsndto) = jn
814                ELSEIF ((dxM .lt. dxT) .AND. (sxT .lt. dxM)) THEN
815                   nsndto = nsndto + 1
816                     isendto(nsndto) = jn
817                END IF
818          END DO
819          nfsloop = 1
820          nfeloop = nlci
821          DO jn = 2,jpni-1
822           IF(nfipproc(jn,jpnj) .eq. (narea - 1)) THEN
823              IF (nfipproc(jn - 1 ,jpnj) .eq. -1) THEN
824                 nfsloop = nldi
825              ENDIF
826              IF (nfipproc(jn + 1,jpnj) .eq. -1) THEN
827                 nfeloop = nlei
828              ENDIF
829           ENDIF
830        END DO
831
832      ENDIF
833      l_north_nogather = .TRUE.
834   END SUBROUTINE nemo_northcomms
835
836#else
837   SUBROUTINE nemo_northcomms      ! Dummy routine
838      WRITE(*,*) 'nemo_northcomms: You should not have seen this print! error?'
839   END SUBROUTINE nemo_northcomms
840#endif
841
842   !!======================================================================
843END MODULE nemogcm
844
Note: See TracBrowser for help on using the repository browser.