New URL for NEMO forge!   http://forge.nemo-ocean.eu

Since March 2022 along with NEMO 4.2 release, the code development moved to a self-hosted GitLab.
This present forge is now archived and remained online for history.
sbcice_lim_2.F90 in branches/2015/dev_r5204_CNRS_PISCES_dcy/NEMOGCM/NEMO/OPA_SRC/SBC – NEMO

source: branches/2015/dev_r5204_CNRS_PISCES_dcy/NEMOGCM/NEMO/OPA_SRC/SBC/sbcice_lim_2.F90 @ 5236

Last change on this file since 5236 was 5236, checked in by cetlod, 9 years ago

NEMOGCM_dev_r5204_CNRS_PISCES_dcy : update routines according to the new strategy, see ticket #1484

  • Property svn:keywords set to Id
File size: 14.0 KB
Line 
1MODULE sbcice_lim_2
2   !!======================================================================
3   !!                       ***  MODULE  sbcice_lim_2  ***
4   !! Surface module :  update surface ocean boundary condition over ice covered area using LIM sea-ice model
5   !! Sea-Ice model  :  LIM-2 Sea ice model time-stepping
6   !!======================================================================
7   !! History :  1.0   !  06-2006  (G. Madec)  from icestp_2.F90
8   !!            3.0   !  08-2008  (S. Masson, E. .... ) coupled interface
9   !!            3.3   !  05-2009  (G.Garric) addition of the lim2_evp case
10   !!----------------------------------------------------------------------
11#if defined key_lim2
12   !!----------------------------------------------------------------------
13   !!   'key_lim2' :                                    LIM-2 sea-ice model
14   !!----------------------------------------------------------------------
15   !!   sbc_ice_lim_2   : sea-ice model time-stepping and update ocean sbc over ice-covered area
16   !!----------------------------------------------------------------------
17   USE oce              ! ocean dynamics and tracers
18   USE dom_oce          ! ocean space and time domain
19   USE ice_2
20   USE par_ice_2
21   USE iceini_2
22   USE dom_ice_2
23
24   USE sbc_oce          ! Surface boundary condition: ocean fields
25   USE sbc_ice          ! Surface boundary condition: ice   fields
26   USE sbcblk_core      ! Surface boundary condition: CORE bulk
27   USE sbcblk_clio      ! Surface boundary condition: CLIO bulk
28   USE sbccpl           ! Surface boundary condition: coupled interface
29   USE albedo
30
31   USE phycst           ! Define parameters for the routines
32   USE eosbn2           ! equation of state
33   USE limdyn_2
34   USE limtrp_2
35   USE limdmp_2
36   USE limthd_2
37   USE limsbc_2         ! sea surface boundary condition
38   USE limdia_2
39   USE limwri_2
40   USE limrst_2
41
42   USE c1d              ! 1D vertical configuration
43
44   USE lbclnk           ! lateral boundary condition - MPP link
45   USE lib_mpp          ! MPP library
46   USE wrk_nemo         ! work arrays
47   USE iom              ! I/O manager library
48   USE in_out_manager   ! I/O manager
49   USE prtctl           ! Print control
50
51# if defined key_agrif
52   USE agrif_ice
53   USE agrif_lim2_update
54# endif
55
56#if defined key_bdy 
57   USE bdyice_lim       ! unstructured open boundary data  (bdy_ice_lim routine)
58#endif
59
60   IMPLICIT NONE
61   PRIVATE
62
63   PUBLIC sbc_ice_lim_2 ! routine called by sbcmod.F90
64
65   !! * Substitutions
66#  include "domzgr_substitute.h90"
67#  include "vectopt_loop_substitute.h90"
68   !!----------------------------------------------------------------------
69   !! NEMO/OPA 3.3 , NEMO Consortium (2010)
70   !! $Id$
71   !! Software governed by the CeCILL licence     (NEMOGCM/NEMO_CeCILL.txt)
72   !!----------------------------------------------------------------------
73CONTAINS
74
75   SUBROUTINE sbc_ice_lim_2( kt, ksbc )
76      !!---------------------------------------------------------------------
77      !!                  ***  ROUTINE sbc_ice_lim_2  ***
78      !!                   
79      !! ** Purpose :   update the ocean surface boundary condition via the
80      !!                Louvain la Neuve Sea Ice Model time stepping
81      !!
82      !! ** Method  :   ice model time stepping
83      !!              - call the ice dynamics routine
84      !!              - call the ice advection/diffusion routine
85      !!              - call the ice thermodynamics routine
86      !!              - call the routine that computes mass and
87      !!                heat fluxes at the ice/ocean interface
88      !!              - save the outputs
89      !!              - save the outputs for restart when necessary
90      !!
91      !! ** Action  : - time evolution of the LIM sea-ice model
92      !!              - update all sbc variables below sea-ice:
93      !!                utau, vtau, taum, wndm, qns , qsr, emp , sfx
94      !!---------------------------------------------------------------------
95      INTEGER, INTENT(in) ::   kt      ! ocean time step
96      INTEGER, INTENT(in) ::   ksbc    ! type of sbc ( =3 CLIO bulk ; =4 CORE bulk ; =5 coupled )
97      !!
98      INTEGER  ::   ji, jj   ! dummy loop indices
99      REAL(wp), DIMENSION(:,:,:), POINTER :: zalb_os   ! ice albedo under overcast sky
100      REAL(wp), DIMENSION(:,:,:), POINTER :: zalb_cs   ! ice albedo under clear sky
101      REAL(wp), DIMENSION(:,:,:), POINTER :: zalb_ice  ! mean ice albedo
102      REAL(wp), DIMENSION(:,:,:), POINTER :: zsist     ! ice surface temperature (K)
103      !!----------------------------------------------------------------------
104
105      CALL wrk_alloc( jpi,jpj,1, zalb_os, zalb_cs, zalb_ice, zsist )
106
107      IF( kt == nit000 ) THEN
108         IF(lwp) WRITE(numout,*)
109         IF(lwp) WRITE(numout,*) 'sbc_ice_lim_2 : update ocean surface boudary condition' 
110         IF(lwp) WRITE(numout,*) '~~~~~~~~~~~~~   via Louvain la Neuve Ice Model (LIM) time stepping'
111         !
112         CALL ice_init_2
113         !
114# if defined key_agrif
115         IF( .NOT. Agrif_Root() ) CALL Agrif_InitValues_cont_lim2   ! AGRIF: set the meshes
116# endif
117      ENDIF
118
119      !                                        !----------------------!
120      IF( MOD( kt-1, nn_fsbc ) == 0 ) THEN     !  Ice time-step only  !
121         !                                     !----------------------!
122# if defined key_agrif
123         IF( .NOT. Agrif_Root() ) lim_nbstep = MOD(lim_nbstep,Agrif_rhot()&
124         &*Agrif_PArent(nn_fsbc)/REAL(nn_fsbc)) + 1
125# endif
126         !  Bulk Formulea !
127         !----------------!
128         ! ... mean surface ocean current at ice dynamics point
129         SELECT CASE( cp_ice_msh )
130         CASE( 'I' )                  !== B-grid ice dynamics :   I-point (i.e. F-point with sea-ice indexation)
131            DO jj = 2, jpj
132               DO ji = 2, jpi   ! NO vector opt. possible
133                  u_oce(ji,jj) = 0.5_wp * ( ssu_m(ji-1,jj  ) * umask(ji-1,jj  ,1) &
134                     &           + ssu_m(ji-1,jj-1) * umask(ji-1,jj-1,1) ) * tmu(ji,jj)
135                  v_oce(ji,jj) = 0.5_wp * ( ssv_m(ji  ,jj-1) * vmask(ji  ,jj-1,1) &
136                     &           + ssv_m(ji-1,jj-1) * vmask(ji-1,jj-1,1) ) * tmu(ji,jj)
137               END DO
138            END DO
139            CALL lbc_lnk( u_oce, 'I', -1. )   ! I-point (i.e. F-point with ice indices)
140            CALL lbc_lnk( v_oce, 'I', -1. )   ! I-point (i.e. F-point with ice indices)
141            !
142         CASE( 'C' )                  !== C-grid ice dynamics :   U & V-points (same as ocean)
143            u_oce(:,:) = ssu_m(:,:) * umask(:,:,1)                     ! mean surface ocean current at ice velocity point
144            v_oce(:,:) = ssv_m(:,:) * vmask(:,:,1)
145            !
146         END SELECT
147
148         ! ... masked sea surface freezing temperature [Kelvin] (set to rt0 over land)
149         tfu(:,:) = eos_fzp( sss_m ) +  rt0 
150
151         zsist (:,:,1) = sist (:,:) + rt0 * ( 1. - tmask(:,:,1) )
152
153         ! Ice albedo
154
155         CALL albedo_ice( zsist, reshape( hicif, (/jpi,jpj,1/) ), &
156                                 reshape( hsnif, (/jpi,jpj,1/) ), &
157                          zalb_cs, zalb_os )
158
159         SELECT CASE( ksbc )
160         CASE( jp_core , jp_cpl )   ! CORE and COUPLED bulk formulations
161
162            ! albedo depends on cloud fraction because of non-linear spectral effects
163            zalb_ice(:,:,:) = ( 1. - cldf_ice ) * zalb_cs(:,:,:) + cldf_ice * zalb_os(:,:,:)
164            ! In CLIO the cloud fraction is read in the climatology and the all-sky albedo
165            ! (zalb_ice) is computed within the bulk routine
166
167         END SELECT
168
169         ! ... Sea-ice surface boundary conditions output from bulk formulae :
170         !     - utau_ice   ! surface ice stress i-component (I-point)   [N/m2]
171         !     - vtau_ice   ! surface ice stress j-component (I-point)   [N/m2]
172         !     - qns_ice    ! non solar heat flux over ice   (T-point)   [W/m2]
173         !     - qsr_ice    !     solar heat flux over ice   (T-point)   [W/m2]
174         !     - qla_ice    ! latent    heat flux over ice   (T-point)   [W/m2]
175         !     - dqns_ice   ! non solar heat sensistivity    (T-point)   [W/m2]
176         !     - dqla_ice   ! latent    heat sensistivity    (T-point)   [W/m2]
177         !     - tprecip    ! total precipitation            (T-point)   [Kg/m2/s]
178         !     - sprecip    ! solid precipitation            (T-point)   [Kg/m2/s]
179         !     - fr1_i0     ! 1sr fraction of qsr penetration in ice     [%]
180         !     - fr2_i0     ! 2nd fraction of qsr penetration in ice     [%]
181         !
182         SELECT CASE( ksbc )
183         CASE( jp_clio )           ! CLIO bulk formulation
184            CALL blk_ice_clio( zsist, zalb_cs    , zalb_os    , zalb_ice   ,            &
185               &                      utau_ice   , vtau_ice   , qns_ice    , qsr_ice,   &
186               &                      qla_ice    , dqns_ice   , dqla_ice   ,            &
187               &                      tprecip    , sprecip    ,                         &
188               &                      fr1_i0     , fr2_i0     , cp_ice_msh , jpl  )
189
190         CASE( jp_core )           ! CORE bulk formulation
191            CALL blk_ice_core( zsist, u_ice      , v_ice      , zalb_ice   ,            &
192               &                      utau_ice   , vtau_ice   , qns_ice    , qsr_ice,   &
193               &                      qla_ice    , dqns_ice   , dqla_ice   ,            &
194               &                      tprecip    , sprecip    ,                         &
195               &                      fr1_i0     , fr2_i0     , cp_ice_msh , jpl  )
196
197         CASE( jp_cpl )            ! Coupled formulation : atmosphere-ice stress only (fluxes provided after ice dynamics)
198            CALL sbc_cpl_ice_tau( utau_ice , vtau_ice )
199         END SELECT
200
201         CALL iom_put( 'utau_ice', utau_ice )     ! Wind stress over ice along i-axis at I-point
202         CALL iom_put( 'vtau_ice', vtau_ice )     ! Wind stress over ice along j-axis at I-point
203
204         IF(ln_ctl) THEN         ! print mean trends (used for debugging)
205            CALL prt_ctl_info( 'Ice Forcings ' )
206            CALL prt_ctl( tab2d_1=tprecip ,clinfo1=' sbc_ice_lim: precip  : ', tab2d_2=sprecip , clinfo2=' Snow    : ' )
207            CALL prt_ctl( tab2d_1=utau_ice,clinfo1=' sbc_ice_lim: utau_ice: ', tab2d_2=vtau_ice, clinfo2=' vtau_ice: ' )
208            CALL prt_ctl( tab2d_1=sst_m   ,clinfo1=' sbc_ice_lim: sst     : ', tab2d_2=sss_m   , clinfo2=' sss     : ' )
209            CALL prt_ctl( tab2d_1=u_oce   ,clinfo1=' sbc_ice_lim: u_io    : ', tab2d_2=v_oce   , clinfo2=' v_io    : ' )
210            CALL prt_ctl( tab2d_1=hsnif   ,clinfo1=' sbc_ice_lim: hsnif  1: ', tab2d_2=hicif   , clinfo2=' hicif   : ' )
211            CALL prt_ctl( tab2d_1=frld    ,clinfo1=' sbc_ice_lim: frld   1: ', tab2d_2=sist    , clinfo2=' sist    : ' )
212         ENDIF
213
214         ! ---------------- !
215         !  Ice model step  !
216         ! ---------------- !
217         numit = numit + nn_fsbc                           ! Ice model time step
218
219                           CALL lim_rst_opn_2  ( kt )  ! Open Ice restart file
220         IF( .NOT. lk_c1d ) THEN                       ! Ice dynamics & transport (except in 1D case)
221                           CALL lim_dyn_2      ( kt )      ! Ice dynamics    ( rheology/dynamics )
222                           CALL lim_trp_2      ( kt )      ! Ice transport   ( Advection/diffusion )
223           IF( ln_limdmp ) CALL lim_dmp_2      ( kt )      ! Ice damping
224#if defined key_bdy
225                           CALL bdy_ice_lim( kt ) ! bdy ice thermo
226#endif
227         END IF
228         !                                             ! Ice surface fluxes in coupled mode
229         IF( ksbc == jp_cpl )   THEN
230            a_i(:,:,1)=fr_i
231            CALL sbc_cpl_ice_flx( frld,                                              &
232            !                                optional arguments, used only in 'mixed oce-ice' case
233            &                                             kt=kt, palbi=zalb_ice, psst=sst_m, pist=zsist )
234            sprecip(:,:) = - emp_ice(:,:)   ! Ugly patch, WARNING, in coupled mode, sublimation included in snow (parsub = 0.)
235         ENDIF
236                           CALL lim_thd_2      ( kt )      ! Ice thermodynamics
237                           CALL lim_sbc_flx_2  ( kt )      ! update surface ocean mass, heat & salt fluxes
238
239         IF(  .NOT. lk_mpp )THEN
240            IF( MOD( kt+nn_fsbc-1, ninfo ) == 0 .OR. ntmoy == 1 )   &
241            &              CALL lim_dia_2      ( kt )      ! Ice Diagnostics
242         ENDIF
243# if ! defined key_iomput
244                           CALL lim_wri_2      ( kt )      ! Ice outputs
245# endif
246         IF( lrst_ice  )   CALL lim_rst_write_2( kt )      ! Ice restart file
247         !
248# if defined key_agrif && defined key_lim2
249         IF( .NOT. Agrif_Root() )   CALL agrif_update_lim2( kt )
250# endif
251         !
252      ENDIF                                    ! End sea-ice time step only
253      !
254      !                                        !--------------------------!
255      !                                        !  at all ocean time step  !
256      !                                        !--------------------------!
257      !                                               
258      !                                              ! Update surface ocean stresses (only in ice-dynamic case)
259      !                                                   ! otherwise the atm.-ocean stresses are used everywhere
260      IF( ln_limdyn    )   CALL lim_sbc_tau_2( kt, ub(:,:,1), vb(:,:,1) )  ! using before instantaneous surf. currents
261      !
262      CALL wrk_dealloc( jpi,jpj,1, zalb_os, zalb_cs, zalb_ice, zsist )
263      !
264   END SUBROUTINE sbc_ice_lim_2
265
266#else
267   !!----------------------------------------------------------------------
268   !!   Default option           Dummy module      NO LIM 2.0 sea-ice model
269   !!----------------------------------------------------------------------
270CONTAINS
271   SUBROUTINE sbc_ice_lim_2 ( kt, ksbc )     ! Dummy routine
272      INTEGER, INTENT(in) ::   kt, ksbc   
273      WRITE(*,*) 'sbc_ice_lim_2: You should not have seen this print! error?', kt, ksbc
274   END SUBROUTINE sbc_ice_lim_2
275#endif
276
277   !!======================================================================
278END MODULE sbcice_lim_2
Note: See TracBrowser for help on using the repository browser.