New URL for NEMO forge!   http://forge.nemo-ocean.eu

Since March 2022 along with NEMO 4.2 release, the code development moved to a self-hosted GitLab.
This present forge is now archived and remained online for history.
limsbc.F90 in branches/2015/dev_r5218_CNRS17_coupling/NEMOGCM/NEMO/LIM_SRC_3 – NEMO

source: branches/2015/dev_r5218_CNRS17_coupling/NEMOGCM/NEMO/LIM_SRC_3/limsbc.F90 @ 5352

Last change on this file since 5352 was 5352, checked in by smasson, 9 years ago

dev_r5218_CNRS17_coupling: update for fraqsr

  • Property svn:keywords set to Id
File size: 22.7 KB
Line 
1MODULE limsbc
2   !!======================================================================
3   !!                       ***  MODULE limsbc   ***
4   !!           computation of the flux at the sea ice/ocean interface
5   !!======================================================================
6   !! History :   -   ! 2006-07 (M. Vancoppelle)  LIM3 original code
7   !!            3.0  ! 2008-03 (C. Tallandier)  surface module
8   !!             -   ! 2008-04 (C. Tallandier)  split in 2 + new ice-ocean coupling
9   !!            3.3  ! 2010-05 (G. Madec) decrease ocean & ice reference salinities in the Baltic sea
10   !!                 !                  + simplification of the ice-ocean stress calculation
11   !!            3.4  ! 2011-02 (G. Madec) dynamical allocation
12   !!             -   ! 2012    (D. Iovino) salt flux change
13   !!             -   ! 2012-05 (C. Rousset) add penetration solar flux
14   !!            3.5  ! 2012-10 (A. Coward, G. Madec) salt fluxes ; ice+snow mass
15   !!----------------------------------------------------------------------
16#if defined key_lim3
17   !!----------------------------------------------------------------------
18   !!   'key_lim3'                                    LIM 3.0 sea-ice model
19   !!----------------------------------------------------------------------
20   !!   lim_sbc_alloc : allocate the limsbc arrays
21   !!   lim_sbc_init  : initialisation
22   !!   lim_sbc_flx   : updates mass, heat and salt fluxes at the ocean surface
23   !!   lim_sbc_tau   : update i- and j-stresses, and its modulus at the ocean surface
24   !!----------------------------------------------------------------------
25   USE par_oce          ! ocean parameters
26   USE phycst           ! physical constants
27   USE dom_oce          ! ocean domain
28   USE ice              ! LIM sea-ice variables
29   USE sbc_ice          ! Surface boundary condition: sea-ice fields
30   USE sbc_oce          ! Surface boundary condition: ocean fields
31   USE sbccpl
32   USE oce       , ONLY : sshn, sshb, snwice_mass, snwice_mass_b, snwice_fmass
33   USE albedo           ! albedo parameters
34   USE lbclnk           ! ocean lateral boundary condition - MPP exchanges
35   USE lib_mpp          ! MPP library
36   USE wrk_nemo         ! work arrays
37   USE in_out_manager   ! I/O manager
38   USE prtctl           ! Print control
39   USE lib_fortran      ! Fortran utilities (allows no signed zero when 'key_nosignedzero' defined) 
40   USE traqsr           ! add penetration of solar flux in the calculation of heat budget
41   USE iom
42   USE domvvl           ! Variable volume
43   USE limctl
44   USE limcons
45
46   IMPLICIT NONE
47   PRIVATE
48
49   PUBLIC   lim_sbc_init   ! called by sbc_lim_init
50   PUBLIC   lim_sbc_flx    ! called by sbc_ice_lim
51   PUBLIC   lim_sbc_tau    ! called by sbc_ice_lim
52
53   REAL(wp), ALLOCATABLE, SAVE, DIMENSION(:,:) ::   utau_oce, vtau_oce   ! air-ocean surface i- & j-stress     [N/m2]
54   REAL(wp), ALLOCATABLE, SAVE, DIMENSION(:,:) ::   tmod_io              ! modulus of the ice-ocean velocity   [m/s]
55   REAL(wp), ALLOCATABLE, SAVE, DIMENSION(:,:) ::   soce_0  , sice_0     ! cst SSS and ice salinity (levitating sea-ice)
56
57   !! * Substitutions
58#  include "vectopt_loop_substitute.h90"
59#  include "domzgr_substitute.h90"
60   !!----------------------------------------------------------------------
61   !! NEMO/LIM3 4.0 , UCL - NEMO Consortium (2011)
62   !! $Id$
63   !! Software governed by the CeCILL licence     (NEMOGCM/NEMO_CeCILL.txt)
64   !!----------------------------------------------------------------------
65CONTAINS
66
67   INTEGER FUNCTION lim_sbc_alloc()
68      !!-------------------------------------------------------------------
69      !!             ***  ROUTINE lim_sbc_alloc ***
70      !!-------------------------------------------------------------------
71      ALLOCATE( soce_0(jpi,jpj) , utau_oce(jpi,jpj) ,                       &
72         &      sice_0(jpi,jpj) , vtau_oce(jpi,jpj) , tmod_io(jpi,jpj), STAT=lim_sbc_alloc)
73         !
74      IF( lk_mpp             )   CALL mpp_sum( lim_sbc_alloc )
75      IF( lim_sbc_alloc /= 0 )   CALL ctl_warn('lim_sbc_alloc: failed to allocate arrays')
76   END FUNCTION lim_sbc_alloc
77
78
79   SUBROUTINE lim_sbc_flx( kt )
80      !!-------------------------------------------------------------------
81      !!                ***  ROUTINE lim_sbc_flx ***
82      !! 
83      !! ** Purpose :   Update the surface ocean boundary condition for heat
84      !!              salt and mass over areas where sea-ice is non-zero
85      !!         
86      !! ** Action  : - computes the heat and freshwater/salt fluxes
87      !!              at the ice-ocean interface.
88      !!              - Update the ocean sbc
89      !!     
90      !! ** Outputs : - qsr     : sea heat flux:     solar
91      !!              - qns     : sea heat flux: non solar
92      !!              - emp     : freshwater budget: volume flux
93      !!              - sfx     : salt flux
94      !!              - fr_i    : ice fraction
95      !!              - tn_ice  : sea-ice surface temperature
96      !!              - alb_ice : sea-ice albedo (ln_cpl=T)
97      !!
98      !! References : Goosse, H. et al. 1996, Bul. Soc. Roy. Sc. Liege, 65, 87-90.
99      !!              Tartinville et al. 2001 Ocean Modelling, 3, 95-108.
100      !!              These refs are now obsolete since everything has been revised
101      !!              The ref should be Rousset et al., 2015
102      !!---------------------------------------------------------------------
103      INTEGER, INTENT(in) ::   kt                                   ! number of iteration
104      INTEGER  ::   ji, jj, jl, jk                                  ! dummy loop indices
105      REAL(wp) ::   zemp                                            ! local scalars
106      REAL(wp) ::   zf_mass                                         ! Heat flux associated with mass exchange ice->ocean (W.m-2)
107      REAL(wp) ::   zfcm1                                           ! New solar flux received by the ocean
108      !
109      REAL(wp), POINTER, DIMENSION(:,:,:) ::   zalb_cs, zalb_os     ! 2D/3D workspace
110      !!---------------------------------------------------------------------
111
112      ! make calls for heat fluxes before it is modified
113      IF( iom_use('qsr_oce') )   CALL iom_put( "qsr_oce" , qsr(:,:) * pfrld(:,:) )   !     solar flux at ocean surface
114      IF( iom_use('qns_oce') )   CALL iom_put( "qns_oce" , qns(:,:) * pfrld(:,:) )   ! non-solar flux at ocean surface
115      IF( iom_use('qsr_ice') )   CALL iom_put( "qsr_ice" , SUM( qsr_ice(:,:,:) * a_i_b(:,:,:), dim=3 ) ) !     solar flux at ice surface
116      IF( iom_use('qns_ice') )   CALL iom_put( "qns_ice" , SUM( qns_ice(:,:,:) * a_i_b(:,:,:), dim=3 ) ) ! non-solar flux at ice surface
117      IF( iom_use('qtr_ice') )   CALL iom_put( "qtr_ice" , SUM( ftr_ice(:,:,:) * a_i_b(:,:,:), dim=3 ) ) !     solar flux transmitted thru ice
118      IF( iom_use('qt_oce' ) )   CALL iom_put( "qt_oce"  , ( qsr(:,:) + qns(:,:) ) * pfrld(:,:) ) 
119      IF( iom_use('qt_ice' ) )   CALL iom_put( "qt_ice"  , SUM( ( qns_ice(:,:,:) + qsr_ice(:,:,:) ) * a_i_b(:,:,:), dim=3 ) )
120
121      ! pfrld is the lead fraction at the previous time step (actually between TRP and THD)
122      DO jj = 1, jpj
123         DO ji = 1, jpi
124
125            !------------------------------------------!
126            !      heat flux at the ocean surface      !
127            !------------------------------------------!
128            ! Solar heat flux reaching the ocean = zfcm1 (W.m-2)
129            !---------------------------------------------------
130            IF( ln_cpl ) THEN 
131               !!! LIM2 version zqsr = qsr_tot(ji,jj) + ( fstric(ji,jj) - qsr_ice(ji,jj,1) ) * ( 1.0 - pfrld(ji,jj) )
132               zfcm1 = qsr_tot(ji,jj)
133               DO jl = 1, jpl
134                  zfcm1 = zfcm1 + ( ftr_ice(ji,jj,jl) - qsr_ice(ji,jj,jl) ) * a_i_b(ji,jj,jl)
135               END DO
136            ELSE
137               !!! LIM2 version zqsr = pfrld(ji,jj) * qsr(ji,jj)  + ( 1.  - pfrld(ji,jj) ) * fstric(ji,jj)
138               zfcm1   = pfrld(ji,jj) * qsr(ji,jj)
139               DO jl = 1, jpl
140                  zfcm1   = zfcm1 + a_i_b(ji,jj,jl) * ftr_ice(ji,jj,jl)
141               END DO
142            ENDIF
143
144            ! Total heat flux reaching the ocean = hfx_out (W.m-2)
145            !---------------------------------------------------
146            zf_mass        = hfx_thd(ji,jj) + hfx_dyn(ji,jj) + hfx_res(ji,jj) ! heat flux from snow is 0 (T=0 degC)
147            hfx_out(ji,jj) = hfx_out(ji,jj) + zf_mass + zfcm1
148
149            ! Add the residual from heat diffusion equation (W.m-2)
150            !-------------------------------------------------------
151            hfx_out(ji,jj) = hfx_out(ji,jj) + hfx_err_dif(ji,jj)
152
153            ! New qsr and qns used to compute the oceanic heat flux at the next time step
154            !---------------------------------------------------
155            qsr(ji,jj) = zfcm1                                     
156            qns(ji,jj) = hfx_out(ji,jj) - zfcm1             
157
158            !------------------------------------------!
159            !      mass flux at the ocean surface      !
160            !------------------------------------------!
161            !  case of realistic freshwater flux (Tartinville et al., 2001) (presently ACTIVATED)
162            !  -------------------------------------------------------------------------------------
163            !  The idea of this approach is that the system that we consider is the ICE-OCEAN system
164            !  Thus  FW  flux  =  External ( E-P+snow melt)
165            !       Salt flux  =  Exchanges in the ice-ocean system then converted into FW
166            !                     Associated to Ice formation AND Ice melting
167            !                     Even if i see Ice melting as a FW and SALT flux
168            !       
169            !  computing freshwater exchanges at the ice/ocean interface
170            IF( ln_cpl ) THEN
171                zemp =   emp_tot(ji,jj)                                    &   ! net mass flux over grid cell
172                   &   - emp_ice(ji,jj) * ( 1._wp - pfrld(ji,jj) )         &   ! minus the mass flux intercepted by sea ice
173                   &   + sprecip(ji,jj) * ( pfrld(ji,jj) - pfrld(ji,jj)**rn_betas )   !
174            ELSE
175               zemp =   emp(ji,jj)     *           pfrld(ji,jj)            &   ! evaporation over oceanic fraction
176                  &   - tprecip(ji,jj) * ( 1._wp - pfrld(ji,jj) )          &   ! all precipitation reach the ocean
177                  &   + sprecip(ji,jj) * ( 1._wp - pfrld(ji,jj)**rn_betas )       ! except solid precip intercepted by sea-ice
178            ENDIF
179
180            ! mass flux from ice/ocean
181            wfx_ice(ji,jj) = wfx_bog(ji,jj) + wfx_bom(ji,jj) + wfx_sum(ji,jj) + wfx_sni(ji,jj)   &
182                           + wfx_opw(ji,jj) + wfx_dyn(ji,jj) + wfx_res(ji,jj)
183
184            ! mass flux at the ocean/ice interface
185            fmmflx(ji,jj) = - ( wfx_ice(ji,jj) + wfx_snw(ji,jj) ) * r1_rdtice  ! F/M mass flux save at least for biogeochemical model
186            emp(ji,jj)    = zemp - wfx_ice(ji,jj) - wfx_snw(ji,jj)             ! mass flux + F/M mass flux (always ice/ocean mass exchange)
187           
188         END DO
189      END DO
190
191      !------------------------------------------!
192      !      salt flux at the ocean surface      !
193      !------------------------------------------!
194      sfx(:,:) = sfx_bog(:,:) + sfx_bom(:,:) + sfx_sum(:,:) + sfx_sni(:,:) + sfx_opw(:,:)   &
195         &     + sfx_res(:,:) + sfx_dyn(:,:) + sfx_bri(:,:)
196
197      !-------------------------------------------------------------!
198      !   mass of snow and ice per unit area for embedded sea-ice   !
199      !-------------------------------------------------------------!
200      IF( nn_ice_embd /= 0 ) THEN
201         ! save mass from the previous ice time step
202         snwice_mass_b(:,:) = snwice_mass(:,:)                 
203         ! new mass per unit area
204         snwice_mass  (:,:) = tmask(:,:,1) * ( rhosn * vt_s(:,:) + rhoic * vt_i(:,:)  ) 
205         ! time evolution of snow+ice mass
206         snwice_fmass (:,:) = ( snwice_mass(:,:) - snwice_mass_b(:,:) ) * r1_rdtice
207      ENDIF
208
209      !-----------------------------------------------!
210      !   Storing the transmitted variables           !
211      !-----------------------------------------------!
212      fr_i  (:,:)   = at_i(:,:)             ! Sea-ice fraction           
213      tn_ice(:,:,:) = t_su(:,:,:)           ! Ice surface temperature                     
214
215      !------------------------------------------------!
216      !    Snow/ice albedo (only if sent to coupler)   !
217      !------------------------------------------------!
218      IF( ln_cpl ) THEN          ! coupled case
219
220            CALL wrk_alloc( jpi, jpj, jpl, zalb_cs, zalb_os )
221
222            CALL albedo_ice( t_su, ht_i, ht_s, zalb_cs, zalb_os )  ! cloud-sky and overcast-sky ice albedos
223
224            alb_ice(:,:,:) = ( 1. - cldf_ice ) * zalb_cs(:,:,:) + cldf_ice * zalb_os(:,:,:)
225
226            CALL wrk_dealloc( jpi, jpj, jpl, zalb_cs, zalb_os )
227
228      ENDIF
229
230      ! conservation test
231      IF( ln_limdiahsb ) CALL lim_cons_final( 'limsbc' )
232
233      ! control prints
234      IF( ln_icectl )   CALL lim_prt( kt, iiceprt, jiceprt, 3, ' - Final state lim_sbc - ' )
235
236      IF(ln_ctl) THEN
237         CALL prt_ctl( tab2d_1=qsr   , clinfo1=' lim_sbc: qsr    : ', tab2d_2=qns , clinfo2=' qns     : ' )
238         CALL prt_ctl( tab2d_1=emp   , clinfo1=' lim_sbc: emp    : ', tab2d_2=sfx , clinfo2=' sfx     : ' )
239         CALL prt_ctl( tab2d_1=fr_i  , clinfo1=' lim_sbc: fr_i   : ' )
240         CALL prt_ctl( tab3d_1=tn_ice, clinfo1=' lim_sbc: tn_ice : ', kdim=jpl )
241      ENDIF
242
243   END SUBROUTINE lim_sbc_flx
244
245
246   SUBROUTINE lim_sbc_tau( kt , pu_oce, pv_oce )
247      !!-------------------------------------------------------------------
248      !!                ***  ROUTINE lim_sbc_tau ***
249      !! 
250      !! ** Purpose : Update the ocean surface stresses due to the ice
251      !!         
252      !! ** Action  : * at each ice time step (every nn_fsbc time step):
253      !!                - compute the modulus of ice-ocean relative velocity
254      !!                  (*rho*Cd) at T-point (C-grid) or I-point (B-grid)
255      !!                      tmod_io = rhoco * | U_ice-U_oce |
256      !!                - update the modulus of stress at ocean surface
257      !!                      taum = frld * taum + (1-frld) * tmod_io * | U_ice-U_oce |
258      !!              * at each ocean time step (every kt):
259      !!                  compute linearized ice-ocean stresses as
260      !!                      Utau = tmod_io * | U_ice - pU_oce |
261      !!                using instantaneous current ocean velocity (usually before)
262      !!
263      !!    NB: - ice-ocean rotation angle no more allowed
264      !!        - here we make an approximation: taum is only computed every ice time step
265      !!          This avoids mutiple average to pass from T -> U,V grids and next from U,V grids
266      !!          to T grid. taum is used in TKE and GLS, which should not be too sensitive to this approximaton...
267      !!
268      !! ** Outputs : - utau, vtau   : surface ocean i- and j-stress (u- & v-pts) updated with ice-ocean fluxes
269      !!              - taum         : modulus of the surface ocean stress (T-point) updated with ice-ocean fluxes
270      !!---------------------------------------------------------------------
271      INTEGER ,                     INTENT(in) ::   kt               ! ocean time-step index
272      REAL(wp), DIMENSION(jpi,jpj), INTENT(in) ::   pu_oce, pv_oce   ! surface ocean currents
273      !!
274      INTEGER  ::   ji, jj   ! dummy loop indices
275      REAL(wp) ::   zat_u, zutau_ice, zu_t, zmodt   ! local scalar
276      REAL(wp) ::   zat_v, zvtau_ice, zv_t          !   -      -
277      !!---------------------------------------------------------------------
278      !
279      IF( MOD( kt-1, nn_fsbc ) == 0 ) THEN     !==  Ice time-step only  ==!   (i.e. surface module time-step)
280         DO jj = 2, jpjm1                             !* update the modulus of stress at ocean surface (T-point)
281            DO ji = fs_2, fs_jpim1
282               !                                               ! 2*(U_ice-U_oce) at T-point
283               zu_t = u_ice(ji,jj) + u_ice(ji-1,jj) - u_oce(ji,jj) - u_oce(ji-1,jj)   
284               zv_t = v_ice(ji,jj) + v_ice(ji,jj-1) - v_oce(ji,jj) - v_oce(ji,jj-1) 
285               !                                              ! |U_ice-U_oce|^2
286               zmodt =  0.25_wp * (  zu_t * zu_t + zv_t * zv_t  )
287               !                                               ! update the ocean stress modulus
288               taum(ji,jj) = ( 1._wp - at_i(ji,jj) ) * taum(ji,jj) + at_i(ji,jj) * rhoco * zmodt
289               tmod_io(ji,jj) = rhoco * SQRT( zmodt )          ! rhoco * |U_ice-U_oce| at T-point
290            END DO
291         END DO
292         CALL lbc_lnk( taum, 'T', 1. )   ;   CALL lbc_lnk( tmod_io, 'T', 1. )
293         !
294         utau_oce(:,:) = utau(:,:)                    !* save the air-ocean stresses at ice time-step
295         vtau_oce(:,:) = vtau(:,:)
296         !
297      ENDIF
298      !
299      !                                      !==  every ocean time-step  ==!
300      !
301      DO jj = 2, jpjm1                                !* update the stress WITHOUT a ice-ocean rotation angle
302         DO ji = fs_2, fs_jpim1   ! Vect. Opt.
303            zat_u  = ( at_i(ji,jj) + at_i(ji+1,jj) ) * 0.5_wp   ! ice area at u and V-points
304            zat_v  = ( at_i(ji,jj) + at_i(ji,jj+1) ) * 0.5_wp
305            !                                                   ! linearized quadratic drag formulation
306            zutau_ice   = 0.5_wp * ( tmod_io(ji,jj) + tmod_io(ji+1,jj) ) * ( u_ice(ji,jj) - pu_oce(ji,jj) )
307            zvtau_ice   = 0.5_wp * ( tmod_io(ji,jj) + tmod_io(ji,jj+1) ) * ( v_ice(ji,jj) - pv_oce(ji,jj) )
308            !                                                   ! stresses at the ocean surface
309            utau(ji,jj) = ( 1._wp - zat_u ) * utau_oce(ji,jj) + zat_u * zutau_ice
310            vtau(ji,jj) = ( 1._wp - zat_v ) * vtau_oce(ji,jj) + zat_v * zvtau_ice
311         END DO
312      END DO
313      CALL lbc_lnk( utau, 'U', -1. )   ;   CALL lbc_lnk( vtau, 'V', -1. )   ! lateral boundary condition
314      !
315      IF(ln_ctl)   CALL prt_ctl( tab2d_1=utau, clinfo1=' lim_sbc: utau   : ', mask1=umask,   &
316         &                       tab2d_2=vtau, clinfo2=' vtau    : '        , mask2=vmask )
317     
318   END SUBROUTINE lim_sbc_tau
319
320
321   SUBROUTINE lim_sbc_init
322      !!-------------------------------------------------------------------
323      !!                  ***  ROUTINE lim_sbc_init  ***
324      !!             
325      !! ** Purpose : Preparation of the file ice_evolu for the output of
326      !!      the temporal evolution of key variables
327      !!
328      !! ** input   : Namelist namicedia
329      !!-------------------------------------------------------------------
330      INTEGER  ::   ji, jj, jk                       ! dummy loop indices
331      REAL(wp) ::   zcoefu, zcoefv, zcoeff          ! local scalar
332      IF(lwp) WRITE(numout,*)
333      IF(lwp) WRITE(numout,*) 'lim_sbc_init : LIM-3 sea-ice - surface boundary condition'
334      IF(lwp) WRITE(numout,*) '~~~~~~~~~~~~~   '
335
336      !                                      ! allocate lim_sbc array
337      IF( lim_sbc_alloc() /= 0 )   CALL ctl_stop( 'STOP', 'lim_sbc_init : unable to allocate standard arrays' )
338      !
339      soce_0(:,:) = soce                     ! constant SSS and ice salinity used in levitating sea-ice case
340      sice_0(:,:) = sice
341      !
342      IF( cp_cfg == "orca" ) THEN            ! decrease ocean & ice reference salinities in the Baltic sea
343         WHERE( 14._wp <= glamt(:,:) .AND. glamt(:,:) <= 32._wp .AND.   &
344            &   54._wp <= gphit(:,:) .AND. gphit(:,:) <= 66._wp         ) 
345            soce_0(:,:) = 4._wp
346            sice_0(:,:) = 2._wp
347         END WHERE
348      ENDIF
349      !
350      IF( .NOT. ln_rstart ) THEN
351         !                                      ! embedded sea ice
352         IF( nn_ice_embd /= 0 ) THEN            ! mass exchanges between ice and ocean (case 1 or 2) set the snow+ice mass
353            snwice_mass  (:,:) = tmask(:,:,1) * ( rhosn * vt_s(:,:) + rhoic * vt_i(:,:)  )
354            snwice_mass_b(:,:) = snwice_mass(:,:)
355         ELSE
356            snwice_mass  (:,:) = 0.0_wp         ! no mass exchanges
357            snwice_mass_b(:,:) = 0.0_wp         ! no mass exchanges
358         ENDIF
359         IF( nn_ice_embd == 2 ) THEN            ! full embedment (case 2) deplete the initial ssh below sea-ice area
360            sshn(:,:) = sshn(:,:) - snwice_mass(:,:) * r1_rau0
361            sshb(:,:) = sshb(:,:) - snwice_mass(:,:) * r1_rau0
362#if defined key_vvl           
363           ! key_vvl necessary? clem: yes for compilation purpose
364            DO jk = 1,jpkm1                     ! adjust initial vertical scale factors
365               fse3t_n(:,:,jk) = e3t_0(:,:,jk)*( 1._wp + sshn(:,:)*tmask(:,:,1)/(ht_0(:,:) + 1.0 - tmask(:,:,1)) )
366               fse3t_b(:,:,jk) = e3t_0(:,:,jk)*( 1._wp + sshb(:,:)*tmask(:,:,1)/(ht_0(:,:) + 1.0 - tmask(:,:,1)) )
367            ENDDO
368            fse3t_a(:,:,:) = fse3t_b(:,:,:)
369            ! Reconstruction of all vertical scale factors at now and before time
370            ! steps
371            ! =============================================================================
372            ! Horizontal scale factor interpolations
373            ! --------------------------------------
374            CALL dom_vvl_interpol( fse3t_b(:,:,:), fse3u_b(:,:,:), 'U' )
375            CALL dom_vvl_interpol( fse3t_b(:,:,:), fse3v_b(:,:,:), 'V' )
376            CALL dom_vvl_interpol( fse3t_n(:,:,:), fse3u_n(:,:,:), 'U' )
377            CALL dom_vvl_interpol( fse3t_n(:,:,:), fse3v_n(:,:,:), 'V' )
378            CALL dom_vvl_interpol( fse3u_n(:,:,:), fse3f_n(:,:,:), 'F' )
379            ! Vertical scale factor interpolations
380            ! ------------------------------------
381            CALL dom_vvl_interpol( fse3t_n(:,:,:), fse3w_n (:,:,:), 'W'  )
382            CALL dom_vvl_interpol( fse3u_n(:,:,:), fse3uw_n(:,:,:), 'UW' )
383            CALL dom_vvl_interpol( fse3v_n(:,:,:), fse3vw_n(:,:,:), 'VW' )
384            CALL dom_vvl_interpol( fse3u_b(:,:,:), fse3uw_b(:,:,:), 'UW' )
385            CALL dom_vvl_interpol( fse3v_b(:,:,:), fse3vw_b(:,:,:), 'VW' )
386            ! t- and w- points depth
387            ! ----------------------
388            fsdept_n(:,:,1) = 0.5_wp * fse3w_n(:,:,1)
389            fsdepw_n(:,:,1) = 0.0_wp
390            fsde3w_n(:,:,1) = fsdept_n(:,:,1) - sshn(:,:)
391            DO jk = 2, jpk
392               fsdept_n(:,:,jk) = fsdept_n(:,:,jk-1) + fse3w_n(:,:,jk)
393               fsdepw_n(:,:,jk) = fsdepw_n(:,:,jk-1) + fse3t_n(:,:,jk-1)
394               fsde3w_n(:,:,jk) = fsdept_n(:,:,jk  ) - sshn   (:,:)
395            END DO
396#endif
397         ENDIF
398      ENDIF ! .NOT. ln_rstart
399      !
400
401   END SUBROUTINE lim_sbc_init
402
403#else
404   !!----------------------------------------------------------------------
405   !!   Default option :        Dummy module       NO LIM 3.0 sea-ice model
406   !!----------------------------------------------------------------------
407CONTAINS
408   SUBROUTINE lim_sbc           ! Dummy routine
409   END SUBROUTINE lim_sbc
410#endif 
411
412   !!======================================================================
413END MODULE limsbc
Note: See TracBrowser for help on using the repository browser.