New URL for NEMO forge!   http://forge.nemo-ocean.eu

Since March 2022 along with NEMO 4.2 release, the code development moved to a self-hosted GitLab.
This present forge is now archived and remained online for history.
limthd.F90 in branches/2015/dev_r5218_CNRS17_coupling/NEMOGCM/NEMO/LIM_SRC_3 – NEMO

source: branches/2015/dev_r5218_CNRS17_coupling/NEMOGCM/NEMO/LIM_SRC_3/limthd.F90 @ 5299

Last change on this file since 5299 was 5299, checked in by smasson, 9 years ago

dev_r5218_CNRS17_coupling: bugfixes
  • Property svn:keywords set to Id
File size: 40.2 KB
Line 
1MODULE limthd
2   !!======================================================================
3   !!                  ***  MODULE limthd   ***
4   !!  LIM-3 :   ice thermodynamic
5   !!======================================================================
6   !! History :  LIM  ! 2000-01 (M.A. Morales Maqueda, H. Goosse, T. Fichefet) LIM-1
7   !!            2.0  ! 2002-07 (C. Ethe, G. Madec)  LIM-2 (F90 rewriting)
8   !!            3.0  ! 2005-11 (M. Vancoppenolle)  LIM-3 : Multi-layer thermodynamics + salinity variations
9   !!             -   ! 2007-04 (M. Vancoppenolle) add lim_thd_glohec, lim_thd_con_dh and lim_thd_con_dif
10   !!            3.2  ! 2009-07 (M. Vancoppenolle, Y. Aksenov, G. Madec) bug correction in wfx_snw
11   !!            3.3  ! 2010-11 (G. Madec) corrected snow melting heat (due to factor betas)
12   !!            4.0  ! 2011-02 (G. Madec) dynamical allocation
13   !!             -   ! 2012-05 (C. Rousset) add penetration solar flux
14   !!----------------------------------------------------------------------
15#if defined key_lim3
16   !!----------------------------------------------------------------------
17   !!   'key_lim3'                                      LIM3 sea-ice model
18   !!----------------------------------------------------------------------
19   !!   lim_thd       : thermodynamic of sea ice
20   !!   lim_thd_init  : initialisation of sea-ice thermodynamic
21   !!----------------------------------------------------------------------
22   USE phycst         ! physical constants
23   USE dom_oce        ! ocean space and time domain variables
24   USE oce     , ONLY : fraqsr_1lev 
25   USE ice            ! LIM: sea-ice variables
26   USE sbc_oce        ! Surface boundary condition: ocean fields
27   USE sbc_ice        ! Surface boundary condition: ice fields
28   USE thd_ice        ! LIM thermodynamic sea-ice variables
29   USE dom_ice        ! LIM sea-ice domain
30   USE limthd_dif     ! LIM: thermodynamics, vertical diffusion
31   USE limthd_dh      ! LIM: thermodynamics, ice and snow thickness variation
32   USE limthd_sal     ! LIM: thermodynamics, ice salinity
33   USE limthd_ent     ! LIM: thermodynamics, ice enthalpy redistribution
34   USE limthd_lac     ! LIM-3 lateral accretion
35   USE limitd_th      ! remapping thickness distribution
36   USE limtab         ! LIM: 1D <==> 2D transformation
37   USE limvar         ! LIM: sea-ice variables
38   USE lbclnk         ! lateral boundary condition - MPP links
39   USE lib_mpp        ! MPP library
40   USE wrk_nemo       ! work arrays
41   USE in_out_manager ! I/O manager
42   USE prtctl         ! Print control
43   USE lib_fortran    ! Fortran utilities (allows no signed zero when 'key_nosignedzero' defined) 
44   USE timing         ! Timing
45   USE limcons        ! conservation tests
46   USE limctl
47
48   IMPLICIT NONE
49   PRIVATE
50
51   PUBLIC   lim_thd        ! called by limstp module
52   PUBLIC   lim_thd_init   ! called by sbc_lim_init
53
54   !! * Substitutions
55#  include "domzgr_substitute.h90"
56#  include "vectopt_loop_substitute.h90"
57   !!----------------------------------------------------------------------
58   !! NEMO/LIM3 3.3 , UCL - NEMO Consortium (2010)
59   !! $Id$
60   !! Software governed by the CeCILL licence     (NEMOGCM/NEMO_CeCILL.txt)
61   !!----------------------------------------------------------------------
62CONTAINS
63
64   SUBROUTINE lim_thd( kt )
65      !!-------------------------------------------------------------------
66      !!                ***  ROUTINE lim_thd  ***       
67      !! 
68      !! ** Purpose : This routine manages ice thermodynamics
69      !!         
70      !! ** Action : - Initialisation of some variables
71      !!             - Some preliminary computation (oceanic heat flux
72      !!               at the ice base, snow acc.,heat budget of the leads)
73      !!             - selection of the icy points and put them in an array
74      !!             - call lim_thd_dif  for vertical heat diffusion
75      !!             - call lim_thd_dh   for vertical ice growth and melt
76      !!             - call lim_thd_ent  for enthalpy remapping
77      !!             - call lim_thd_sal  for ice desalination
78      !!             - call lim_thd_temp to  retrieve temperature from ice enthalpy
79      !!             - back to the geographic grid
80      !!     
81      !! ** References :
82      !!---------------------------------------------------------------------
83      INTEGER, INTENT(in) :: kt    ! number of iteration
84      !!
85      INTEGER  :: ji, jj, jk, jl   ! dummy loop indices
86      INTEGER  :: nbpb             ! nb of icy pts for vertical thermo calculations
87      INTEGER  :: ii, ij           ! temporary dummy loop index
88      REAL(wp) :: zfric_u, zqld, zqfr
89      REAL(wp) :: zvi_b, zsmv_b, zei_b, zfs_b, zfw_b, zft_b 
90      REAL(wp), PARAMETER :: zfric_umin = 0._wp           ! lower bound for the friction velocity (cice value=5.e-04)
91      REAL(wp), PARAMETER :: zch        = 0.0057_wp       ! heat transfer coefficient
92      !
93      REAL(wp), POINTER, DIMENSION(:,:) ::  zqsr, zqns
94      !!-------------------------------------------------------------------
95      CALL wrk_alloc( jpi,jpj, zqsr, zqns )
96
97      IF( nn_timing == 1 )  CALL timing_start('limthd')
98
99      ! conservation test
100      IF( ln_limdiahsb ) CALL lim_cons_hsm(0, 'limthd', zvi_b, zsmv_b, zei_b, zfw_b, zfs_b, zft_b)
101
102      CALL lim_var_glo2eqv
103      !------------------------------------------------------------------------!
104      ! 1) Initialization of some variables                                    !
105      !------------------------------------------------------------------------!
106      ftr_ice(:,:,:) = 0._wp  ! part of solar radiation transmitted through the ice
107
108      !--------------------
109      ! 1.2) Heat content   
110      !--------------------
111      ! Change the units of heat content; from J/m2 to J/m3
112      DO jl = 1, jpl
113         DO jk = 1, nlay_i
114            DO jj = 1, jpj
115               DO ji = 1, jpi
116                  !0 if no ice and 1 if yes
117                  rswitch = MAX(  0._wp , SIGN( 1._wp , v_i(ji,jj,jl) - epsi20 )  )
118                  !Energy of melting q(S,T) [J.m-3]
119                  e_i(ji,jj,jk,jl) = rswitch * e_i(ji,jj,jk,jl) / MAX( v_i(ji,jj,jl) , epsi20 ) * REAL( nlay_i )
120               END DO
121            END DO
122         END DO
123         DO jk = 1, nlay_s
124            DO jj = 1, jpj
125               DO ji = 1, jpi
126                  !0 if no ice and 1 if yes
127                  rswitch = MAX(  0._wp , SIGN( 1._wp , v_s(ji,jj,jl) - epsi20 )  )
128                  !Energy of melting q(S,T) [J.m-3]
129                  e_s(ji,jj,jk,jl) = rswitch * e_s(ji,jj,jk,jl) / MAX( v_s(ji,jj,jl) , epsi20 ) * REAL( nlay_s )
130               END DO
131            END DO
132         END DO
133      END DO
134
135      ! 2) Partial computation of forcing for the thermodynamic sea ice model.      !
136      !-----------------------------------------------------------------------------!
137
138      !--- Ocean solar and non solar fluxes to be used in zqld
139      IF ( .NOT. ln_cpl ) THEN   ! --- forced case, fluxes to the lead are the same as over the ocean
140         !
141         zqsr(:,:) = qsr(:,:)      ; zqns(:,:) = qns(:,:)
142         !
143      ELSE                       ! --- coupled case, fluxes to the lead are total - intercepted
144         !
145         zqsr(:,:) = qsr_tot(:,:)  ; zqns(:,:) = qns_tot(:,:)
146         !
147         DO jl = 1, jpl
148            DO jj = 1, jpj
149               DO ji = 1, jpi
150                  zqsr(ji,jj) = zqsr(ji,jj) - qsr_ice(ji,jj,jl) * a_i_b(ji,jj,jl)
151                  zqns(ji,jj) = zqns(ji,jj) - qns_ice(ji,jj,jl) * a_i_b(ji,jj,jl)
152               END DO
153            END DO
154         END DO
155         !
156      ENDIF
157
158      DO jj = 1, jpj
159         DO ji = 1, jpi
160            rswitch  = tmask(ji,jj,1) * MAX( 0._wp , SIGN( 1._wp , at_i(ji,jj) - epsi10 ) ) ! 0 if no ice
161            !
162            !           !  solar irradiance transmission at the mixed layer bottom and used in the lead heat budget
163            !           !  practically no "direct lateral ablation"
164            !           
165            !           !  net downward heat flux from the ice to the ocean, expressed as a function of ocean
166            !           !  temperature and turbulent mixing (McPhee, 1992)
167            !
168
169            ! --- Energy received in the lead, zqld is defined everywhere (J.m-2) --- !
170            ! REMARK valid at least in forced mode from clem
171            ! precip is included in qns but not in qns_ice
172            IF ( ln_cpl ) THEN
173               zqld =  tmask(ji,jj,1) * rdt_ice *  &
174                  &    (   zqsr(ji,jj) * fraqsr_1lev(ji,jj) + zqns(ji,jj)               &   ! pfrld already included in coupled mode
175                  &    + ( pfrld(ji,jj)**rn_betas - pfrld(ji,jj) ) * sprecip(ji,jj)  *     &   ! heat content of precip
176                  &      ( cpic * ( MIN( tatm_ice(ji,jj), rt0_snow ) - rt0 ) - lfus )   &
177                  &    + ( 1._wp - pfrld(ji,jj) ) * ( tprecip(ji,jj) - sprecip(ji,jj) ) * rcp * ( tatm_ice(ji,jj) - rt0 ) )
178            ELSE
179               zqld =  tmask(ji,jj,1) * rdt_ice *  &
180                  &      ( pfrld(ji,jj) * ( zqsr(ji,jj) * fraqsr_1lev(ji,jj) + zqns(ji,jj) )    &
181                  &    + ( pfrld(ji,jj)**rn_betas - pfrld(ji,jj) ) * sprecip(ji,jj)  *             &  ! heat content of precip
182                  &      ( cpic * ( MIN( tatm_ice(ji,jj), rt0_snow ) - rt0 ) - lfus )           &
183                  &    + ( 1._wp - pfrld(ji,jj) ) * ( tprecip(ji,jj) - sprecip(ji,jj) ) * rcp * ( tatm_ice(ji,jj) - rt0 ) )
184            ENDIF
185
186            ! --- Energy needed to bring ocean surface layer until its freezing (<0, J.m-2) --- !
187            zqfr = tmask(ji,jj,1) * rau0 * rcp * fse3t_m(ji,jj) * ( t_bo(ji,jj) - ( sst_m(ji,jj) + rt0 ) )
188
189            ! --- Energy from the turbulent oceanic heat flux (W/m2) --- !
190            zfric_u      = MAX( SQRT( ust2s(ji,jj) ), zfric_umin ) 
191            fhtur(ji,jj) = MAX( 0._wp, rswitch * rau0 * rcp * zch  * zfric_u * ( ( sst_m(ji,jj) + rt0 ) - t_bo(ji,jj) ) ) ! W.m-2
192            fhtur(ji,jj) = rswitch * MIN( fhtur(ji,jj), - zqfr * r1_rdtice / MAX( at_i(ji,jj), epsi10 ) )
193            ! upper bound for fhtur: the heat retrieved from the ocean must be smaller than the heat necessary to reach
194            !                        the freezing point, so that we do not have SST < T_freeze
195            !                        This implies: - ( fhtur(ji,jj) * at_i(ji,jj) * rtdice ) - zqfr >= 0
196
197            !-- Energy Budget of the leads (J.m-2). Must be < 0 to form ice
198            qlead(ji,jj) = MIN( 0._wp , zqld - ( fhtur(ji,jj) * at_i(ji,jj) * rdt_ice ) - zqfr )
199
200            ! If there is ice and leads are warming, then transfer energy from the lead budget and use it for bottom melting
201            IF( zqld > 0._wp ) THEN
202               fhld (ji,jj) = rswitch * zqld * r1_rdtice / MAX( at_i(ji,jj), epsi10 ) ! divided by at_i since this is (re)multiplied by a_i in limthd_dh.F90
203               qlead(ji,jj) = 0._wp
204            ELSE
205               fhld (ji,jj) = 0._wp
206            ENDIF
207            !
208            ! -----------------------------------------
209            ! Net heat flux on top of ice-ocean [W.m-2]
210            ! -----------------------------------------
211            !     heat flux at the ocean surface + precip
212            !   + heat flux at the ice   surface
213            hfx_in(ji,jj) = hfx_in(ji,jj)                                                                                         & 
214               ! heat flux above the ocean
215               &    +             pfrld(ji,jj)   * ( zqns(ji,jj) + zqsr(ji,jj) )                                                  &
216               ! latent heat of precip (note that precip is included in qns but not in qns_ice)
217               &    +   ( 1._wp - pfrld(ji,jj) ) * sprecip(ji,jj) * ( cpic * ( MIN( tatm_ice(ji,jj), rt0_snow ) - rt0 ) - lfus )  &
218               &    +   ( 1._wp - pfrld(ji,jj) ) * ( tprecip(ji,jj) - sprecip(ji,jj) ) * rcp * ( tatm_ice(ji,jj) - rt0 )          &
219               ! heat flux above the ice
220               &    +   SUM(    a_i_b(ji,jj,:)   * ( qns_ice(ji,jj,:) + qsr_ice(ji,jj,:) ) )
221
222            ! -----------------------------------------------------------------------------
223            ! Net heat flux that is retroceded to the ocean or taken from the ocean [W.m-2]
224            ! -----------------------------------------------------------------------------
225            !     First  step here              :  non solar + precip - qlead - qturb
226            !     Second step in limthd_dh      :  heat remaining if total melt (zq_rema)
227            !     Third  step in limsbc         :  heat from ice-ocean mass exchange (zf_mass) + solar
228            hfx_out(ji,jj) = hfx_out(ji,jj)                                                                                       & 
229               ! Non solar heat flux received by the ocean
230               &    +        pfrld(ji,jj) * zqns(ji,jj)                                                                            &
231               ! latent heat of precip (note that precip is included in qns but not in qns_ice)
232               &    +      ( pfrld(ji,jj)**rn_betas - pfrld(ji,jj) ) * sprecip(ji,jj)       &
233               &         * ( cpic * ( MIN( tatm_ice(ji,jj), rt0_snow ) - rt0 ) - lfus )  &
234               &    +      ( 1._wp - pfrld(ji,jj) ) * ( tprecip(ji,jj) - sprecip(ji,jj) ) * rcp * ( tatm_ice(ji,jj) - rt0 )       &
235               ! heat flux taken from the ocean where there is open water ice formation
236               &    -      qlead(ji,jj) * r1_rdtice                                                                               &
237               ! heat flux taken from the ocean during bottom growth/melt (fhld should be 0 while bott growth)
238               &    -      at_i(ji,jj) * fhtur(ji,jj)                                                                             &
239               &    -      at_i(ji,jj) *  fhld(ji,jj)
240
241         END DO
242      END DO
243
244      !------------------------------------------------------------------------------!
245      ! 3) Select icy points and fulfill arrays for the vectorial grid.           
246      !------------------------------------------------------------------------------!
247
248      DO jl = 1, jpl      !loop over ice categories
249
250         IF( kt == nit000 .AND. lwp ) THEN
251            WRITE(numout,*) ' lim_thd : transfer to 1D vectors. Category no : ', jl 
252            WRITE(numout,*) ' ~~~~~~~~'
253         ENDIF
254
255         nbpb = 0
256         DO jj = 1, jpj
257            DO ji = 1, jpi
258               IF ( a_i(ji,jj,jl) > epsi10 ) THEN     
259                  nbpb      = nbpb  + 1
260                  npb(nbpb) = (jj - 1) * jpi + ji
261               ENDIF
262            END DO
263         END DO
264
265         ! debug point to follow
266         jiindex_1d = 0
267         IF( ln_icectl ) THEN
268            DO ji = mi0(iiceprt), mi1(iiceprt)
269               DO jj = mj0(jiceprt), mj1(jiceprt)
270                  jiindex_1d = (jj - 1) * jpi + ji
271                  WRITE(numout,*) ' lim_thd : Category no : ', jl 
272               END DO
273            END DO
274         ENDIF
275
276         !------------------------------------------------------------------------------!
277         ! 4) Thermodynamic computation
278         !------------------------------------------------------------------------------!
279
280         IF( lk_mpp )   CALL mpp_ini_ice( nbpb , numout )
281
282         IF( nbpb > 0 ) THEN  ! If there is no ice, do nothing.
283
284            !-------------------------!
285            ! --- Move to 1D arrays ---
286            !-------------------------!
287            CALL lim_thd_1d2d( nbpb, jl, 1 )
288
289            !--------------------------------------!
290            ! --- Ice/Snow Temperature profile --- !
291            !--------------------------------------!
292            CALL lim_thd_dif( 1, nbpb )
293
294            !---------------------------------!
295            ! --- Ice/Snow thickness ---      !
296            !---------------------------------!
297            CALL lim_thd_dh( 1, nbpb )   
298
299            ! --- Ice enthalpy remapping --- !
300            CALL lim_thd_ent( 1, nbpb, q_i_1d(1:nbpb,:) ) 
301                                           
302            !---------------------------------!
303            ! --- Ice salinity ---            !
304            !---------------------------------!
305            CALL lim_thd_sal( 1, nbpb )   
306
307            !---------------------------------!
308            ! --- temperature update ---      !
309            !---------------------------------!
310            CALL lim_thd_temp( 1, nbpb )
311
312            !------------------------------------!
313            ! --- lateral melting if monocat --- !
314            !------------------------------------!
315            IF ( ( nn_monocat == 1 .OR. nn_monocat == 4 ) .AND. jpl == 1 ) THEN
316               CALL lim_thd_lam( 1, nbpb )
317            END IF
318
319            !-------------------------!
320            ! --- Move to 2D arrays ---
321            !-------------------------!
322            CALL lim_thd_1d2d( nbpb, jl, 2 )
323
324            !
325            IF( lk_mpp )   CALL mpp_comm_free( ncomm_ice ) !RB necessary ??
326         ENDIF
327         !
328      END DO !jl
329
330      !------------------------------------------------------------------------------!
331      ! 5) Global variables, diagnostics
332      !------------------------------------------------------------------------------!
333
334      !------------------------
335      ! Ice heat content             
336      !------------------------
337      ! Enthalpies are global variables we have to readjust the units (heat content in J/m2)
338      DO jl = 1, jpl
339         DO jk = 1, nlay_i
340            e_i(:,:,jk,jl) = e_i(:,:,jk,jl) * a_i(:,:,jl) * ht_i(:,:,jl) * r1_nlay_i
341         END DO
342      END DO
343
344      !------------------------
345      ! Snow heat content             
346      !------------------------
347      ! Enthalpies are global variables we have to readjust the units (heat content in J/m2)
348      DO jl = 1, jpl
349         DO jk = 1, nlay_s
350            e_s(:,:,jk,jl) = e_s(:,:,jk,jl) * a_i(:,:,jl) * ht_s(:,:,jl) * r1_nlay_s
351         END DO
352      END DO
353 
354      !----------------------------------
355      ! Change thickness to volume
356      !----------------------------------
357      v_i(:,:,:)   = ht_i(:,:,:) * a_i(:,:,:)
358      v_s(:,:,:)   = ht_s(:,:,:) * a_i(:,:,:)
359      smv_i(:,:,:) = sm_i(:,:,:) * v_i(:,:,:)
360
361      ! update ice age (in case a_i changed, i.e. becomes 0 or lateral melting in monocat)
362      DO jl  = 1, jpl
363         DO jj = 1, jpj
364            DO ji = 1, jpi
365               rswitch = MAX( 0._wp , SIGN( 1._wp, a_i_b(ji,jj,jl) - epsi10 ) )
366               oa_i(ji,jj,jl) = rswitch * oa_i(ji,jj,jl) * a_i(ji,jj,jl) / MAX( a_i_b(ji,jj,jl), epsi10 )
367            END DO
368         END DO
369      END DO
370
371      CALL lim_var_zapsmall
372
373      !--------------------------------------------
374      ! Diagnostic thermodynamic growth rates
375      !--------------------------------------------
376      IF( ln_icectl )   CALL lim_prt( kt, iiceprt, jiceprt, 1, ' - ice thermodyn. - ' )   ! control print
377
378      IF(ln_ctl) THEN            ! Control print
379         CALL prt_ctl_info(' ')
380         CALL prt_ctl_info(' - Cell values : ')
381         CALL prt_ctl_info('   ~~~~~~~~~~~~~ ')
382         CALL prt_ctl(tab2d_1=e12t , clinfo1=' lim_thd  : cell area :')
383         CALL prt_ctl(tab2d_1=at_i , clinfo1=' lim_thd  : at_i      :')
384         CALL prt_ctl(tab2d_1=vt_i , clinfo1=' lim_thd  : vt_i      :')
385         CALL prt_ctl(tab2d_1=vt_s , clinfo1=' lim_thd  : vt_s      :')
386         DO jl = 1, jpl
387            CALL prt_ctl_info(' ')
388            CALL prt_ctl_info(' - Category : ', ivar1=jl)
389            CALL prt_ctl_info('   ~~~~~~~~~~')
390            CALL prt_ctl(tab2d_1=a_i   (:,:,jl)   , clinfo1= ' lim_thd  : a_i      : ')
391            CALL prt_ctl(tab2d_1=ht_i  (:,:,jl)   , clinfo1= ' lim_thd  : ht_i     : ')
392            CALL prt_ctl(tab2d_1=ht_s  (:,:,jl)   , clinfo1= ' lim_thd  : ht_s     : ')
393            CALL prt_ctl(tab2d_1=v_i   (:,:,jl)   , clinfo1= ' lim_thd  : v_i      : ')
394            CALL prt_ctl(tab2d_1=v_s   (:,:,jl)   , clinfo1= ' lim_thd  : v_s      : ')
395            CALL prt_ctl(tab2d_1=e_s   (:,:,1,jl) , clinfo1= ' lim_thd  : e_s      : ')
396            CALL prt_ctl(tab2d_1=t_su  (:,:,jl)   , clinfo1= ' lim_thd  : t_su     : ')
397            CALL prt_ctl(tab2d_1=t_s   (:,:,1,jl) , clinfo1= ' lim_thd  : t_snow   : ')
398            CALL prt_ctl(tab2d_1=sm_i  (:,:,jl)   , clinfo1= ' lim_thd  : sm_i     : ')
399            CALL prt_ctl(tab2d_1=smv_i (:,:,jl)   , clinfo1= ' lim_thd  : smv_i    : ')
400            DO jk = 1, nlay_i
401               CALL prt_ctl_info(' ')
402               CALL prt_ctl_info(' - Layer : ', ivar1=jk)
403               CALL prt_ctl_info('   ~~~~~~~')
404               CALL prt_ctl(tab2d_1=t_i(:,:,jk,jl) , clinfo1= ' lim_thd  : t_i      : ')
405               CALL prt_ctl(tab2d_1=e_i(:,:,jk,jl) , clinfo1= ' lim_thd  : e_i      : ')
406            END DO
407         END DO
408      ENDIF
409      !
410      !
411      IF( ln_limdiahsb ) CALL lim_cons_hsm(1, 'limthd', zvi_b, zsmv_b, zei_b, zfw_b, zfs_b, zft_b)
412
413      CALL wrk_dealloc( jpi,jpj, zqsr, zqns )
414
415      !------------------------------------------------------------------------------|
416      !  6) Transport of ice between thickness categories.                           |
417      !------------------------------------------------------------------------------|
418      ! Given thermodynamic growth rates, transport ice between thickness categories.
419      IF( ln_limdiahsb ) CALL lim_cons_hsm(0, 'limitd_th_rem', zvi_b, zsmv_b, zei_b, zfw_b, zfs_b, zft_b)
420
421      IF( jpl > 1 )      CALL lim_itd_th_rem( 1, jpl, kt )
422
423      IF( ln_limdiahsb ) CALL lim_cons_hsm(1, 'limitd_th_rem', zvi_b, zsmv_b, zei_b, zfw_b, zfs_b, zft_b)
424
425      !------------------------------------------------------------------------------|
426      !  7) Add frazil ice growing in leads.
427      !------------------------------------------------------------------------------|
428      IF( ln_limdiahsb ) CALL lim_cons_hsm(0, 'limthd_lac', zvi_b, zsmv_b, zei_b, zfw_b, zfs_b, zft_b)
429
430      CALL lim_thd_lac
431     
432      IF( ln_limdiahsb ) CALL lim_cons_hsm(1, 'limthd_lac', zvi_b, zsmv_b, zei_b, zfw_b, zfs_b, zft_b)
433
434      ! Control print
435      IF(ln_ctl) THEN
436         CALL lim_var_glo2eqv
437
438         CALL prt_ctl_info(' ')
439         CALL prt_ctl_info(' - Cell values : ')
440         CALL prt_ctl_info('   ~~~~~~~~~~~~~ ')
441         CALL prt_ctl(tab2d_1=e12t , clinfo1=' lim_itd_th  : cell area :')
442         CALL prt_ctl(tab2d_1=at_i , clinfo1=' lim_itd_th  : at_i      :')
443         CALL prt_ctl(tab2d_1=vt_i , clinfo1=' lim_itd_th  : vt_i      :')
444         CALL prt_ctl(tab2d_1=vt_s , clinfo1=' lim_itd_th  : vt_s      :')
445         DO jl = 1, jpl
446            CALL prt_ctl_info(' ')
447            CALL prt_ctl_info(' - Category : ', ivar1=jl)
448            CALL prt_ctl_info('   ~~~~~~~~~~')
449            CALL prt_ctl(tab2d_1=a_i   (:,:,jl)   , clinfo1= ' lim_itd_th  : a_i      : ')
450            CALL prt_ctl(tab2d_1=ht_i  (:,:,jl)   , clinfo1= ' lim_itd_th  : ht_i     : ')
451            CALL prt_ctl(tab2d_1=ht_s  (:,:,jl)   , clinfo1= ' lim_itd_th  : ht_s     : ')
452            CALL prt_ctl(tab2d_1=v_i   (:,:,jl)   , clinfo1= ' lim_itd_th  : v_i      : ')
453            CALL prt_ctl(tab2d_1=v_s   (:,:,jl)   , clinfo1= ' lim_itd_th  : v_s      : ')
454            CALL prt_ctl(tab2d_1=e_s   (:,:,1,jl) , clinfo1= ' lim_itd_th  : e_s      : ')
455            CALL prt_ctl(tab2d_1=t_su  (:,:,jl)   , clinfo1= ' lim_itd_th  : t_su     : ')
456            CALL prt_ctl(tab2d_1=t_s   (:,:,1,jl) , clinfo1= ' lim_itd_th  : t_snow   : ')
457            CALL prt_ctl(tab2d_1=sm_i  (:,:,jl)   , clinfo1= ' lim_itd_th  : sm_i     : ')
458            CALL prt_ctl(tab2d_1=smv_i (:,:,jl)   , clinfo1= ' lim_itd_th  : smv_i    : ')
459            DO jk = 1, nlay_i
460               CALL prt_ctl_info(' ')
461               CALL prt_ctl_info(' - Layer : ', ivar1=jk)
462               CALL prt_ctl_info('   ~~~~~~~')
463               CALL prt_ctl(tab2d_1=t_i(:,:,jk,jl) , clinfo1= ' lim_itd_th  : t_i      : ')
464               CALL prt_ctl(tab2d_1=e_i(:,:,jk,jl) , clinfo1= ' lim_itd_th  : e_i      : ')
465            END DO
466         END DO
467      ENDIF
468      !
469      IF( nn_timing == 1 )  CALL timing_stop('limthd')
470
471   END SUBROUTINE lim_thd 
472
473   SUBROUTINE lim_thd_temp( kideb, kiut )
474      !!-----------------------------------------------------------------------
475      !!                   ***  ROUTINE lim_thd_temp ***
476      !!                 
477      !! ** Purpose :   Computes sea ice temperature (Kelvin) from enthalpy
478      !!
479      !! ** Method  :   Formula (Bitz and Lipscomb, 1999)
480      !!-------------------------------------------------------------------
481      INTEGER, INTENT(in) ::   kideb, kiut   ! bounds for the spatial loop
482      !!
483      INTEGER  ::   ji, jk   ! dummy loop indices
484      REAL(wp) ::   ztmelts, zaaa, zbbb, zccc, zdiscrim  ! local scalar
485      !!-------------------------------------------------------------------
486      ! Recover ice temperature
487      DO jk = 1, nlay_i
488         DO ji = kideb, kiut
489            ztmelts       =  -tmut * s_i_1d(ji,jk) + rt0
490            ! Conversion q(S,T) -> T (second order equation)
491            zaaa          =  cpic
492            zbbb          =  ( rcp - cpic ) * ( ztmelts - rt0 ) + q_i_1d(ji,jk) * r1_rhoic - lfus
493            zccc          =  lfus * ( ztmelts - rt0 )
494            zdiscrim      =  SQRT( MAX( zbbb * zbbb - 4._wp * zaaa * zccc, 0._wp ) )
495            t_i_1d(ji,jk) =  rt0 - ( zbbb + zdiscrim ) / ( 2._wp * zaaa )
496           
497            ! mask temperature
498            rswitch       =  1._wp - MAX( 0._wp , SIGN( 1._wp , - ht_i_1d(ji) ) ) 
499            t_i_1d(ji,jk) =  rswitch * t_i_1d(ji,jk) + ( 1._wp - rswitch ) * rt0
500         END DO
501      END DO
502
503   END SUBROUTINE lim_thd_temp
504
505   SUBROUTINE lim_thd_lam( kideb, kiut )
506      !!-----------------------------------------------------------------------
507      !!                   ***  ROUTINE lim_thd_lam ***
508      !!                 
509      !! ** Purpose :   Lateral melting in case monocategory
510      !!                          ( dA = A/2h dh )
511      !!-----------------------------------------------------------------------
512      INTEGER, INTENT(in) ::   kideb, kiut        ! bounds for the spatial loop
513      INTEGER             ::   ji                 ! dummy loop indices
514      REAL(wp)            ::   zhi_bef            ! ice thickness before thermo
515      REAL(wp)            ::   zdh_mel, zda_mel   ! net melting
516      REAL(wp)            ::   zvi, zvs           ! ice/snow volumes
517
518      DO ji = kideb, kiut
519         zdh_mel = MIN( 0._wp, dh_i_surf(ji) + dh_i_bott(ji) + dh_snowice(ji) )
520         IF( zdh_mel < 0._wp .AND. a_i_1d(ji) > 0._wp )  THEN
521            zvi          = a_i_1d(ji) * ht_i_1d(ji)
522            zvs          = a_i_1d(ji) * ht_s_1d(ji)
523            ! lateral melting = concentration change
524            zhi_bef     = ht_i_1d(ji) - zdh_mel
525            rswitch     = MAX( 0._wp , SIGN( 1._wp , zhi_bef - epsi20 ) )
526            zda_mel     = rswitch * a_i_1d(ji) * zdh_mel / ( 2._wp * MAX( zhi_bef, epsi20 ) )
527            a_i_1d(ji)  = MAX( epsi20, a_i_1d(ji) + zda_mel ) 
528             ! adjust thickness
529            ht_i_1d(ji) = zvi / a_i_1d(ji)           
530            ht_s_1d(ji) = zvs / a_i_1d(ji)           
531            ! retrieve total concentration
532            at_i_1d(ji) = a_i_1d(ji)
533         END IF
534      END DO
535     
536   END SUBROUTINE lim_thd_lam
537
538   SUBROUTINE lim_thd_1d2d( nbpb, jl, kn )
539      !!-----------------------------------------------------------------------
540      !!                   ***  ROUTINE lim_thd_1d2d ***
541      !!                 
542      !! ** Purpose :   move arrays from 1d to 2d and the reverse
543      !!-----------------------------------------------------------------------
544      INTEGER, INTENT(in) ::   kn       ! 1= from 2D to 1D
545                                        ! 2= from 1D to 2D
546      INTEGER, INTENT(in) ::   nbpb     ! size of 1D arrays
547      INTEGER, INTENT(in) ::   jl       ! ice cat
548      INTEGER             ::   jk       ! dummy loop indices
549
550      SELECT CASE( kn )
551
552      CASE( 1 )
553
554         CALL tab_2d_1d( nbpb, at_i_1d     (1:nbpb), at_i            , jpi, jpj, npb(1:nbpb) )
555         CALL tab_2d_1d( nbpb, a_i_1d      (1:nbpb), a_i(:,:,jl)     , jpi, jpj, npb(1:nbpb) )
556         CALL tab_2d_1d( nbpb, ht_i_1d     (1:nbpb), ht_i(:,:,jl)    , jpi, jpj, npb(1:nbpb) )
557         CALL tab_2d_1d( nbpb, ht_s_1d     (1:nbpb), ht_s(:,:,jl)    , jpi, jpj, npb(1:nbpb) )
558         
559         CALL tab_2d_1d( nbpb, t_su_1d     (1:nbpb), t_su(:,:,jl)    , jpi, jpj, npb(1:nbpb) )
560         CALL tab_2d_1d( nbpb, sm_i_1d     (1:nbpb), sm_i(:,:,jl)    , jpi, jpj, npb(1:nbpb) )
561         DO jk = 1, nlay_s
562            CALL tab_2d_1d( nbpb, t_s_1d(1:nbpb,jk), t_s(:,:,jk,jl)  , jpi, jpj, npb(1:nbpb) )
563            CALL tab_2d_1d( nbpb, q_s_1d(1:nbpb,jk), e_s(:,:,jk,jl)  , jpi, jpj, npb(1:nbpb) )
564         END DO
565         DO jk = 1, nlay_i
566            CALL tab_2d_1d( nbpb, t_i_1d(1:nbpb,jk), t_i(:,:,jk,jl)  , jpi, jpj, npb(1:nbpb) )
567            CALL tab_2d_1d( nbpb, q_i_1d(1:nbpb,jk), e_i(:,:,jk,jl)  , jpi, jpj, npb(1:nbpb) )
568            CALL tab_2d_1d( nbpb, s_i_1d(1:nbpb,jk), s_i(:,:,jk,jl)  , jpi, jpj, npb(1:nbpb) )
569         END DO
570         
571         CALL tab_2d_1d( nbpb, tatm_ice_1d(1:nbpb), tatm_ice(:,:)   , jpi, jpj, npb(1:nbpb) )
572         CALL tab_2d_1d( nbpb, qsr_ice_1d (1:nbpb), qsr_ice(:,:,jl) , jpi, jpj, npb(1:nbpb) )
573         CALL tab_2d_1d( nbpb, fr1_i0_1d  (1:nbpb), fr1_i0          , jpi, jpj, npb(1:nbpb) )
574         CALL tab_2d_1d( nbpb, fr2_i0_1d  (1:nbpb), fr2_i0          , jpi, jpj, npb(1:nbpb) )
575         CALL tab_2d_1d( nbpb, qns_ice_1d (1:nbpb), qns_ice(:,:,jl) , jpi, jpj, npb(1:nbpb) )
576         CALL tab_2d_1d( nbpb, ftr_ice_1d (1:nbpb), ftr_ice(:,:,jl) , jpi, jpj, npb(1:nbpb) )
577         IF( .NOT. ln_cpl ) THEN
578            CALL tab_2d_1d( nbpb, qla_ice_1d (1:nbpb), qla_ice(:,:,jl) , jpi, jpj, npb(1:nbpb) )
579            CALL tab_2d_1d( nbpb, dqla_ice_1d(1:nbpb), dqla_ice(:,:,jl), jpi, jpj, npb(1:nbpb) )
580         ENDIF
581         CALL tab_2d_1d( nbpb, dqns_ice_1d(1:nbpb), dqns_ice(:,:,jl), jpi, jpj, npb(1:nbpb) )
582         CALL tab_2d_1d( nbpb, t_bo_1d     (1:nbpb), t_bo            , jpi, jpj, npb(1:nbpb) )
583         CALL tab_2d_1d( nbpb, sprecip_1d (1:nbpb), sprecip         , jpi, jpj, npb(1:nbpb) ) 
584         CALL tab_2d_1d( nbpb, fhtur_1d   (1:nbpb), fhtur           , jpi, jpj, npb(1:nbpb) )
585         CALL tab_2d_1d( nbpb, qlead_1d   (1:nbpb), qlead           , jpi, jpj, npb(1:nbpb) )
586         CALL tab_2d_1d( nbpb, fhld_1d    (1:nbpb), fhld            , jpi, jpj, npb(1:nbpb) )
587         
588         CALL tab_2d_1d( nbpb, wfx_snw_1d (1:nbpb), wfx_snw         , jpi, jpj, npb(1:nbpb) )
589         CALL tab_2d_1d( nbpb, wfx_sub_1d (1:nbpb), wfx_sub         , jpi, jpj, npb(1:nbpb) )
590         
591         CALL tab_2d_1d( nbpb, wfx_bog_1d (1:nbpb), wfx_bog         , jpi, jpj, npb(1:nbpb) )
592         CALL tab_2d_1d( nbpb, wfx_bom_1d (1:nbpb), wfx_bom         , jpi, jpj, npb(1:nbpb) )
593         CALL tab_2d_1d( nbpb, wfx_sum_1d (1:nbpb), wfx_sum         , jpi, jpj, npb(1:nbpb) )
594         CALL tab_2d_1d( nbpb, wfx_sni_1d (1:nbpb), wfx_sni         , jpi, jpj, npb(1:nbpb) )
595         CALL tab_2d_1d( nbpb, wfx_res_1d (1:nbpb), wfx_res         , jpi, jpj, npb(1:nbpb) )
596         CALL tab_2d_1d( nbpb, wfx_spr_1d (1:nbpb), wfx_spr         , jpi, jpj, npb(1:nbpb) )
597         
598         CALL tab_2d_1d( nbpb, sfx_bog_1d (1:nbpb), sfx_bog         , jpi, jpj, npb(1:nbpb) )
599         CALL tab_2d_1d( nbpb, sfx_bom_1d (1:nbpb), sfx_bom         , jpi, jpj, npb(1:nbpb) )
600         CALL tab_2d_1d( nbpb, sfx_sum_1d (1:nbpb), sfx_sum         , jpi, jpj, npb(1:nbpb) )
601         CALL tab_2d_1d( nbpb, sfx_sni_1d (1:nbpb), sfx_sni         , jpi, jpj, npb(1:nbpb) )
602         CALL tab_2d_1d( nbpb, sfx_bri_1d (1:nbpb), sfx_bri         , jpi, jpj, npb(1:nbpb) )
603         CALL tab_2d_1d( nbpb, sfx_res_1d (1:nbpb), sfx_res         , jpi, jpj, npb(1:nbpb) )
604         
605         CALL tab_2d_1d( nbpb, hfx_thd_1d (1:nbpb), hfx_thd         , jpi, jpj, npb(1:nbpb) )
606         CALL tab_2d_1d( nbpb, hfx_spr_1d (1:nbpb), hfx_spr         , jpi, jpj, npb(1:nbpb) )
607         CALL tab_2d_1d( nbpb, hfx_sum_1d (1:nbpb), hfx_sum         , jpi, jpj, npb(1:nbpb) )
608         CALL tab_2d_1d( nbpb, hfx_bom_1d (1:nbpb), hfx_bom         , jpi, jpj, npb(1:nbpb) )
609         CALL tab_2d_1d( nbpb, hfx_bog_1d (1:nbpb), hfx_bog         , jpi, jpj, npb(1:nbpb) )
610         CALL tab_2d_1d( nbpb, hfx_dif_1d (1:nbpb), hfx_dif         , jpi, jpj, npb(1:nbpb) )
611         CALL tab_2d_1d( nbpb, hfx_opw_1d (1:nbpb), hfx_opw         , jpi, jpj, npb(1:nbpb) )
612         CALL tab_2d_1d( nbpb, hfx_snw_1d (1:nbpb), hfx_snw         , jpi, jpj, npb(1:nbpb) )
613         CALL tab_2d_1d( nbpb, hfx_sub_1d (1:nbpb), hfx_sub         , jpi, jpj, npb(1:nbpb) )
614         CALL tab_2d_1d( nbpb, hfx_err_1d (1:nbpb), hfx_err         , jpi, jpj, npb(1:nbpb) )
615         CALL tab_2d_1d( nbpb, hfx_res_1d (1:nbpb), hfx_res         , jpi, jpj, npb(1:nbpb) )
616         CALL tab_2d_1d( nbpb, hfx_err_dif_1d (1:nbpb), hfx_err_dif , jpi, jpj, npb(1:nbpb) )
617         CALL tab_2d_1d( nbpb, hfx_err_rem_1d (1:nbpb), hfx_err_rem , jpi, jpj, npb(1:nbpb) )
618
619      CASE( 2 )
620
621         CALL tab_1d_2d( nbpb, at_i          , npb, at_i_1d    (1:nbpb)   , jpi, jpj )
622         CALL tab_1d_2d( nbpb, ht_i(:,:,jl)  , npb, ht_i_1d    (1:nbpb)   , jpi, jpj )
623         CALL tab_1d_2d( nbpb, ht_s(:,:,jl)  , npb, ht_s_1d    (1:nbpb)   , jpi, jpj )
624         CALL tab_1d_2d( nbpb, a_i (:,:,jl)  , npb, a_i_1d     (1:nbpb)   , jpi, jpj )
625         CALL tab_1d_2d( nbpb, t_su(:,:,jl)  , npb, t_su_1d    (1:nbpb)   , jpi, jpj )
626         CALL tab_1d_2d( nbpb, sm_i(:,:,jl)  , npb, sm_i_1d    (1:nbpb)   , jpi, jpj )
627         DO jk = 1, nlay_s
628            CALL tab_1d_2d( nbpb, t_s(:,:,jk,jl), npb, t_s_1d     (1:nbpb,jk), jpi, jpj)
629            CALL tab_1d_2d( nbpb, e_s(:,:,jk,jl), npb, q_s_1d     (1:nbpb,jk), jpi, jpj)
630         END DO
631         DO jk = 1, nlay_i
632            CALL tab_1d_2d( nbpb, t_i(:,:,jk,jl), npb, t_i_1d     (1:nbpb,jk), jpi, jpj)
633            CALL tab_1d_2d( nbpb, e_i(:,:,jk,jl), npb, q_i_1d     (1:nbpb,jk), jpi, jpj)
634            CALL tab_1d_2d( nbpb, s_i(:,:,jk,jl), npb, s_i_1d     (1:nbpb,jk), jpi, jpj)
635         END DO
636         CALL tab_1d_2d( nbpb, qlead         , npb, qlead_1d  (1:nbpb)   , jpi, jpj )
637         
638         CALL tab_1d_2d( nbpb, wfx_snw       , npb, wfx_snw_1d(1:nbpb)   , jpi, jpj )
639         CALL tab_1d_2d( nbpb, wfx_sub       , npb, wfx_sub_1d(1:nbpb)   , jpi, jpj )
640         
641         CALL tab_1d_2d( nbpb, wfx_bog       , npb, wfx_bog_1d(1:nbpb)   , jpi, jpj )
642         CALL tab_1d_2d( nbpb, wfx_bom       , npb, wfx_bom_1d(1:nbpb)   , jpi, jpj )
643         CALL tab_1d_2d( nbpb, wfx_sum       , npb, wfx_sum_1d(1:nbpb)   , jpi, jpj )
644         CALL tab_1d_2d( nbpb, wfx_sni       , npb, wfx_sni_1d(1:nbpb)   , jpi, jpj )
645         CALL tab_1d_2d( nbpb, wfx_res       , npb, wfx_res_1d(1:nbpb)   , jpi, jpj )
646         CALL tab_1d_2d( nbpb, wfx_spr       , npb, wfx_spr_1d(1:nbpb)   , jpi, jpj )
647         
648         CALL tab_1d_2d( nbpb, sfx_bog       , npb, sfx_bog_1d(1:nbpb)   , jpi, jpj )
649         CALL tab_1d_2d( nbpb, sfx_bom       , npb, sfx_bom_1d(1:nbpb)   , jpi, jpj )
650         CALL tab_1d_2d( nbpb, sfx_sum       , npb, sfx_sum_1d(1:nbpb)   , jpi, jpj )
651         CALL tab_1d_2d( nbpb, sfx_sni       , npb, sfx_sni_1d(1:nbpb)   , jpi, jpj )
652         CALL tab_1d_2d( nbpb, sfx_res       , npb, sfx_res_1d(1:nbpb)   , jpi, jpj )
653         CALL tab_1d_2d( nbpb, sfx_bri       , npb, sfx_bri_1d(1:nbpb)   , jpi, jpj )
654         
655         CALL tab_1d_2d( nbpb, hfx_thd       , npb, hfx_thd_1d(1:nbpb)   , jpi, jpj )
656         CALL tab_1d_2d( nbpb, hfx_spr       , npb, hfx_spr_1d(1:nbpb)   , jpi, jpj )
657         CALL tab_1d_2d( nbpb, hfx_sum       , npb, hfx_sum_1d(1:nbpb)   , jpi, jpj )
658         CALL tab_1d_2d( nbpb, hfx_bom       , npb, hfx_bom_1d(1:nbpb)   , jpi, jpj )
659         CALL tab_1d_2d( nbpb, hfx_bog       , npb, hfx_bog_1d(1:nbpb)   , jpi, jpj )
660         CALL tab_1d_2d( nbpb, hfx_dif       , npb, hfx_dif_1d(1:nbpb)   , jpi, jpj )
661         CALL tab_1d_2d( nbpb, hfx_opw       , npb, hfx_opw_1d(1:nbpb)   , jpi, jpj )
662         CALL tab_1d_2d( nbpb, hfx_snw       , npb, hfx_snw_1d(1:nbpb)   , jpi, jpj )
663         CALL tab_1d_2d( nbpb, hfx_sub       , npb, hfx_sub_1d(1:nbpb)   , jpi, jpj )
664         CALL tab_1d_2d( nbpb, hfx_err       , npb, hfx_err_1d(1:nbpb)   , jpi, jpj )
665         CALL tab_1d_2d( nbpb, hfx_res       , npb, hfx_res_1d(1:nbpb)   , jpi, jpj )
666         CALL tab_1d_2d( nbpb, hfx_err_rem   , npb, hfx_err_rem_1d(1:nbpb), jpi, jpj )
667         CALL tab_1d_2d( nbpb, hfx_err_dif   , npb, hfx_err_dif_1d(1:nbpb), jpi, jpj )
668         !
669         CALL tab_1d_2d( nbpb, qns_ice(:,:,jl), npb, qns_ice_1d(1:nbpb) , jpi, jpj)
670         CALL tab_1d_2d( nbpb, ftr_ice(:,:,jl), npb, ftr_ice_1d(1:nbpb) , jpi, jpj )
671                 
672      END SELECT
673
674   END SUBROUTINE lim_thd_1d2d
675
676
677   SUBROUTINE lim_thd_init
678      !!-----------------------------------------------------------------------
679      !!                   ***  ROUTINE lim_thd_init ***
680      !!                 
681      !! ** Purpose :   Physical constants and parameters linked to the ice
682      !!              thermodynamics
683      !!
684      !! ** Method  :   Read the namicethd namelist and check the ice-thermo
685      !!              parameter values called at the first timestep (nit000)
686      !!
687      !! ** input   :   Namelist namicether
688      !!-------------------------------------------------------------------
689      INTEGER  ::   ios                 ! Local integer output status for namelist read
690      NAMELIST/namicethd/ rn_hnewice, ln_frazil, rn_maxfrazb, rn_vfrazb, rn_Cfrazb,                       &
691         &                rn_himin, rn_betas, rn_kappa_i, nn_conv_dif, rn_terr_dif, nn_ice_thcon, &
692         &                nn_monocat, ln_it_qnsice
693      !!-------------------------------------------------------------------
694      !
695      IF(lwp) THEN
696         WRITE(numout,*)
697         WRITE(numout,*) 'lim_thd : Ice Thermodynamics'
698         WRITE(numout,*) '~~~~~~~'
699      ENDIF
700      !
701      REWIND( numnam_ice_ref )              ! Namelist namicethd in reference namelist : Ice thermodynamics
702      READ  ( numnam_ice_ref, namicethd, IOSTAT = ios, ERR = 901)
703901   IF( ios /= 0 ) CALL ctl_nam ( ios , 'namicethd in reference namelist', lwp )
704
705      REWIND( numnam_ice_cfg )              ! Namelist namicethd in configuration namelist : Ice thermodynamics
706      READ  ( numnam_ice_cfg, namicethd, IOSTAT = ios, ERR = 902 )
707902   IF( ios /= 0 ) CALL ctl_nam ( ios , 'namicethd in configuration namelist', lwp )
708      IF(lwm) WRITE ( numoni, namicethd )
709      !
710      IF ( ( jpl > 1 ) .AND. ( nn_monocat == 1 ) ) THEN
711         nn_monocat = 0
712         IF(lwp) WRITE(numout, *) '   nn_monocat must be 0 in multi-category case '
713      ENDIF
714
715      !
716      IF(lwp) THEN                          ! control print
717         WRITE(numout,*)
718         WRITE(numout,*)'   Namelist of ice parameters for ice thermodynamic computation '
719         WRITE(numout,*)'      ice thick. for lateral accretion                        rn_hnewice   = ', rn_hnewice
720         WRITE(numout,*)'      Frazil ice thickness as a function of wind or not       ln_frazil    = ', ln_frazil
721         WRITE(numout,*)'      Maximum proportion of frazil ice collecting at bottom   rn_maxfrazb  = ', rn_maxfrazb
722         WRITE(numout,*)'      Thresold relative drift speed for collection of frazil  rn_vfrazb    = ', rn_vfrazb
723         WRITE(numout,*)'      Squeezing coefficient for collection of frazil          rn_Cfrazb    = ', rn_Cfrazb
724         WRITE(numout,*)'      minimum ice thickness                                   rn_himin     = ', rn_himin 
725         WRITE(numout,*)'      numerical carac. of the scheme for diffusion in ice '
726         WRITE(numout,*)'      coefficient for ice-lead partition of snowfall          rn_betas     = ', rn_betas
727         WRITE(numout,*)'      extinction radiation parameter in sea ice               rn_kappa_i   = ', rn_kappa_i
728         WRITE(numout,*)'      maximal n. of iter. for heat diffusion computation      nn_conv_dif  = ', nn_conv_dif
729         WRITE(numout,*)'      maximal err. on T for heat diffusion computation        rn_terr_dif  = ', rn_terr_dif
730         WRITE(numout,*)'      switch for comp. of thermal conductivity in the ice     nn_ice_thcon = ', nn_ice_thcon
731         WRITE(numout,*)'      check heat conservation in the ice/snow                 con_i        = ', con_i
732         WRITE(numout,*)'      virtual ITD mono-category parameterizations (1) or not  nn_monocat   = ', nn_monocat
733         WRITE(numout,*)'      iterate the surface non-solar flux (T) or not (F)       ln_it_qnsice = ', ln_it_qnsice
734      ENDIF
735      !
736   END SUBROUTINE lim_thd_init
737
738#else
739   !!----------------------------------------------------------------------
740   !!   Default option         Dummy module          NO  LIM3 sea-ice model
741   !!----------------------------------------------------------------------
742#endif
743
744   !!======================================================================
745END MODULE limthd
Note: See TracBrowser for help on using the repository browser.