New URL for NEMO forge!   http://forge.nemo-ocean.eu

Since March 2022 along with NEMO 4.2 release, the code development moved to a self-hosted GitLab.
This present forge is now archived and remained online for history.
sbcssm.F90 in branches/2015/dev_r5218_CNRS17_coupling/NEMOGCM/NEMO/SAS_SRC – NEMO

source: branches/2015/dev_r5218_CNRS17_coupling/NEMOGCM/NEMO/SAS_SRC/sbcssm.F90 @ 5343

Last change on this file since 5343 was 5343, checked in by smasson, 9 years ago

dev_r5218_CNRS17_coupling: update and bugfix (mainly) for SAS
  • Property svn:keywords set to Id
File size: 12.9 KB
Line 
1MODULE sbcssm
2   !!======================================================================
3   !!                       ***  MODULE  sbcssm  ***
4   !! Off-line : interpolation of the physical fields
5   !!======================================================================
6   !! History :
7   !!   NEMO         3.4  ! 2012-03 First version by S. Alderson
8   !!                     !         Heavily derived from Christian's dtadyn routine
9   !!                     !         in OFF_SRC
10   !!----------------------------------------------------------------------
11
12   !!----------------------------------------------------------------------
13   !!   sbc_ssm_init : initialization, namelist read, and SAVEs control
14   !!   sbc_ssm      : Interpolation of the fields
15   !!----------------------------------------------------------------------
16   USE oce             ! ocean dynamics and tracers variables
17   USE c1d             ! 1D configuration: lk_c1d
18   USE dom_oce         ! ocean domain: variables
19   USE zdf_oce         ! ocean vertical physics: variables
20   USE sbc_oce         ! surface module: variables
21   USE phycst          ! physical constants
22   USE eosbn2          ! equation of state - Brunt Vaisala frequency
23   USE lbclnk          ! ocean lateral boundary conditions (or mpp link)
24   USE zpshde          ! z-coord. with partial steps: horizontal derivatives
25   USE in_out_manager  ! I/O manager
26   USE iom             ! I/O library
27   USE lib_mpp         ! distributed memory computing library
28   USE prtctl          ! print control
29   USE fldread         ! read input fields
30   USE timing          ! Timing
31
32   IMPLICIT NONE
33   PRIVATE
34
35   PUBLIC   sbc_ssm_init   ! called by sbc_init
36   PUBLIC   sbc_ssm        ! called by sbc
37
38   CHARACTER(len=100)   ::   cn_dir      !: Root directory for location of ssm files
39   LOGICAL              ::   ln_3d_uve   !: specify whether input velocity data is 3D
40   INTEGER     ::   nfld_3d
41   INTEGER     ::   nfld_2d
42
43   INTEGER     ::   jf_tem         ! index of temperature
44   INTEGER     ::   jf_sal         ! index of salinity
45   INTEGER     ::   jf_usp         ! index of u velocity component
46   INTEGER     ::   jf_vsp         ! index of v velocity component
47   INTEGER     ::   jf_ssh         ! index of sea surface height
48   INTEGER     ::   jf_e3t         ! index of first T level thickness
49
50   TYPE(FLD), ALLOCATABLE, DIMENSION(:) :: sf_ssm_3d  ! structure of input fields (file information, fields read)
51   TYPE(FLD), ALLOCATABLE, DIMENSION(:) :: sf_ssm_2d  ! structure of input fields (file information, fields read)
52
53   !!----------------------------------------------------------------------
54   !! NEMO/OFF 3.3 , NEMO Consortium (2010)
55   !! $Id$
56   !! Software governed by the CeCILL licence     (NEMOGCM/NEMO_CeCILL.txt)
57   !!----------------------------------------------------------------------
58CONTAINS
59
60   SUBROUTINE sbc_ssm( kt )
61      !!----------------------------------------------------------------------
62      !!                  ***  ROUTINE sbc_ssm  ***
63      !!
64      !! ** Purpose :  Prepares dynamics and physics fields from a NEMO run
65      !!               for an off-line simulation using surface processes only
66      !!
67      !! ** Method : calculates the position of data
68      !!             - interpolates data if needed
69      !!----------------------------------------------------------------------
70      !
71      INTEGER, INTENT(in) ::   kt   ! ocean time-step index
72      !
73      INTEGER  ::   ji, jj     ! dummy loop indices
74      REAL(wp) ::   ztinta     ! ratio applied to after  records when doing time interpolation
75      REAL(wp) ::   ztintb     ! ratio applied to before records when doing time interpolation
76      !!----------------------------------------------------------------------
77     
78      !
79      IF( nn_timing == 1 )  CALL timing_start( 'sbc_ssm')
80
81      IF( nfld_3d > 0 ) CALL fld_read( kt, 1, sf_ssm_3d )      !==   read data at kt time step   ==!
82      IF( nfld_2d > 0 ) CALL fld_read( kt, 1, sf_ssm_2d )      !==   read data at kt time step   ==!
83      !
84      IF( ln_3d_uve ) THEN
85         ssu_m(:,:) = sf_ssm_3d(jf_usp)%fnow(:,:,1) * umask(:,:,1)    ! u-velocity
86         ssv_m(:,:) = sf_ssm_3d(jf_vsp)%fnow(:,:,1) * vmask(:,:,1)    ! v-velocity
87         IF( lk_vvl )   e3t_m(:,:) = sf_ssm_3d(jf_e3t)%fnow(:,:,1) * tmask(:,:,1)    ! v-velocity
88      ELSE
89         ssu_m(:,:) = sf_ssm_2d(jf_usp)%fnow(:,:,1) * umask(:,:,1)    ! u-velocity
90         ssv_m(:,:) = sf_ssm_2d(jf_vsp)%fnow(:,:,1) * vmask(:,:,1)    ! v-velocity
91         IF( lk_vvl )   e3t_m(:,:) = sf_ssm_2d(jf_e3t)%fnow(:,:,1) * tmask(:,:,1)    ! v-velocity
92      ENDIF
93      !
94      sst_m(:,:) = sf_ssm_2d(jf_tem)%fnow(:,:,1) * tmask(:,:,1)    ! temperature
95      sss_m(:,:) = sf_ssm_2d(jf_sal)%fnow(:,:,1) * tmask(:,:,1)    ! salinity
96      ssh_m(:,:) = sf_ssm_2d(jf_ssh)%fnow(:,:,1) * tmask(:,:,1)    ! sea surface height
97      !
98      tsn(:,:,1,jp_tem) = sst_m(:,:)
99      tsn(:,:,1,jp_sal) = sss_m(:,:)
100      IF ( nn_ice == 1 ) THEN
101         tsb(:,:,1,jp_tem) = sst_m(:,:)
102         tsb(:,:,1,jp_sal) = sss_m(:,:)
103      ENDIF
104      ub (:,:,1) = ssu_m(:,:)
105      vb (:,:,1) = ssv_m(:,:)
106
107      IF(ln_ctl) THEN                  ! print control
108         CALL prt_ctl(tab2d_1=sst_m, clinfo1=' sst_m   - : ', mask1=tmask, ovlap=1   )
109         CALL prt_ctl(tab2d_1=sss_m, clinfo1=' sss_m   - : ', mask1=tmask, ovlap=1   )
110         CALL prt_ctl(tab2d_1=ssu_m, clinfo1=' ssu_m   - : ', mask1=umask, ovlap=1   )
111         CALL prt_ctl(tab2d_1=ssv_m, clinfo1=' ssv_m   - : ', mask1=vmask, ovlap=1   )
112         CALL prt_ctl(tab2d_1=ssh_m, clinfo1=' ssh_m   - : ', mask1=tmask, ovlap=1   )
113         IF( lk_vvl )   CALL prt_ctl(tab2d_1=ssh_m, clinfo1=' e3t_m   - : ', mask1=tmask, ovlap=1   )
114      ENDIF
115      !
116      IF( nn_timing == 1 )  CALL timing_stop( 'sbc_ssm')
117      !
118   END SUBROUTINE sbc_ssm
119
120
121   SUBROUTINE sbc_ssm_init
122      !!----------------------------------------------------------------------
123      !!                  ***  ROUTINE sbc_ssm_init  ***
124      !!
125      !! ** Purpose :   Initialisation of the dynamical data     
126      !! ** Method  : - read the data namsbc_ssm namelist
127      !!
128      !! ** Action  : - read parameters
129      !!----------------------------------------------------------------------
130      INTEGER  :: ierr, ierr0, ierr1, ierr2, ierr3   ! return error code
131      INTEGER  :: ifpr                               ! dummy loop indice
132      INTEGER  :: inum, idv, idimv, jpm              ! local integer
133      INTEGER  ::   ios                              ! Local integer output status for namelist read
134      !!
135      CHARACTER(len=100)                     ::  cn_dir       ! Root directory for location of core files
136      TYPE(FLD_N), ALLOCATABLE, DIMENSION(:) ::  slf_3d       ! array of namelist information on the fields to read
137      TYPE(FLD_N), ALLOCATABLE, DIMENSION(:) ::  slf_2d       ! array of namelist information on the fields to read
138      TYPE(FLD_N) :: sn_tem, sn_sal                     ! information about the fields to be read
139      TYPE(FLD_N) :: sn_usp, sn_vsp
140      TYPE(FLD_N) :: sn_ssh, sn_e3t
141      !
142      NAMELIST/namsbc_sas/cn_dir, ln_3d_uve, sn_tem, sn_sal, sn_usp, sn_vsp, sn_ssh, sn_e3t
143      !!----------------------------------------------------------------------
144     
145      REWIND( numnam_ref )              ! Namelist namsbc_sas in reference namelist : Input fields
146      READ  ( numnam_ref, namsbc_sas, IOSTAT = ios, ERR = 901)
147901   IF( ios /= 0 ) CALL ctl_nam ( ios , 'namsbc_sas in reference namelist', lwp )
148
149      REWIND( numnam_cfg )              ! Namelist namsbc_sas in configuration namelist : Input fields
150      READ  ( numnam_cfg, namsbc_sas, IOSTAT = ios, ERR = 902 )
151902   IF( ios /= 0 ) CALL ctl_nam ( ios , 'namsbc_sas in configuration namelist', lwp )
152      IF(lwm) WRITE ( numond, namsbc_sas )
153
154      !                                         ! store namelist information in an array
155      !                                         ! Control print
156      IF(lwp) THEN
157         WRITE(numout,*)
158         WRITE(numout,*) 'sbc_sas : standalone surface scheme '
159         WRITE(numout,*) '~~~~~~~~~~~ '
160         WRITE(numout,*) '   Namelist namsbc_sas'
161         WRITE(numout,*)
162      ENDIF
163     
164      !
165      !! switch off stuff that isn't sensible with a standalone module
166      !! note that we need sbc_ssm called first in sbc
167      !
168      IF( ln_apr_dyn ) THEN
169         IF( lwp ) WRITE(numout,*) 'No atmospheric gradient needed with StandAlone Surface scheme'
170         ln_apr_dyn = .FALSE.
171      ENDIF
172      IF( ln_dm2dc ) THEN
173         IF( lwp ) WRITE(numout,*) 'No diurnal cycle needed with StandAlone Surface scheme'
174         ln_dm2dc = .FALSE.
175      ENDIF
176      IF( ln_rnf ) THEN
177         IF( lwp ) WRITE(numout,*) 'No runoff needed with StandAlone Surface scheme'
178         ln_rnf = .FALSE.
179      ENDIF
180      IF( ln_ssr ) THEN
181         IF( lwp ) WRITE(numout,*) 'No surface relaxation needed with StandAlone Surface scheme'
182         ln_ssr = .FALSE.
183      ENDIF
184      IF( nn_fwb > 0 ) THEN
185         IF( lwp ) WRITE(numout,*) 'No freshwater budget adjustment needed with StandAlone Surface scheme'
186         nn_fwb = 0
187      ENDIF
188      IF( nn_closea > 0 ) THEN
189         IF( lwp ) WRITE(numout,*) 'No closed seas adjustment needed with StandAlone Surface scheme'
190         nn_closea = 0
191      ENDIF
192
193      !
194      !! following code is a bit messy, but distinguishes between when u,v are 3d arrays and
195      !! when we have other 3d arrays that we need to read in
196      !! so if a new field is added i.e. jf_new, just give it the next integer in sequence
197      !! for the corresponding dimension (currently if ln_3d_uve is true, 4 for 2d and 3 for 3d,
198      !! alternatively if ln_3d_uve is false, 6 for 2d and 1 for 3d), reset nfld_3d, nfld_2d,
199      !! and the rest of the logic should still work
200      !
201      jf_tem = 1 ; jf_sal = 2 ; jf_ssh = 3
202      !
203      IF( ln_3d_uve ) THEN
204         jf_usp = 1 ; jf_vsp = 2 ; jf_e3t = 3
205         nfld_3d  = 2 + COUNT( (/lk_vvl/) )
206         nfld_2d  = 3
207      ELSE
208         jf_usp = 4 ; jf_vsp = 5 ; jf_e3t = 6
209         nfld_3d  = 0
210         nfld_2d  = 5 + COUNT( (/lk_vvl/) )
211      ENDIF
212
213      IF( nfld_3d > 0 ) THEN
214         ALLOCATE( slf_3d(nfld_3d), STAT=ierr )         ! set slf structure
215         IF( ierr > 0 ) THEN
216            CALL ctl_stop( 'sbc_ssm_init: unable to allocate slf 3d structure' )   ;   RETURN
217         ENDIF
218         slf_3d(jf_usp) = sn_usp
219         slf_3d(jf_vsp) = sn_vsp
220         IF( lk_vvl )   slf_3d(jf_e3t) = sn_e3t
221      ENDIF
222
223      IF( nfld_2d > 0 ) THEN
224         ALLOCATE( slf_2d(nfld_2d), STAT=ierr )         ! set slf structure
225         IF( ierr > 0 ) THEN
226            CALL ctl_stop( 'sbc_ssm_init: unable to allocate slf 2d structure' )   ;   RETURN
227         ENDIF
228         slf_2d(jf_tem) = sn_tem ; slf_2d(jf_sal) = sn_sal ; slf_2d(jf_ssh) = sn_ssh
229         IF( .NOT. ln_3d_uve ) THEN
230            slf_2d(jf_usp) = sn_usp ; slf_2d(jf_vsp) = sn_vsp
231            IF( lk_vvl )   slf_2d(jf_e3t) = sn_e3t
232         ENDIF
233      ENDIF
234      !
235      ierr1 = 0    ! default definition if slf_?d(ifpr)%ln_tint = .false.
236      IF( nfld_3d > 0 ) THEN
237         ALLOCATE( sf_ssm_3d(nfld_3d), STAT=ierr )         ! set sf structure
238         IF( ierr > 0 ) THEN
239            CALL ctl_stop( 'sbc_ssm_init: unable to allocate sf structure' )   ;   RETURN
240         ENDIF
241         DO ifpr = 1, nfld_3d
242                                       ALLOCATE( sf_ssm_3d(ifpr)%fnow(jpi,jpj,jpk)    , STAT=ierr0 )
243            IF( slf_3d(ifpr)%ln_tint ) ALLOCATE( sf_ssm_3d(ifpr)%fdta(jpi,jpj,jpk,2)  , STAT=ierr1 )
244            IF( ierr0 + ierr1 > 0 ) THEN
245               CALL ctl_stop( 'sbc_ssm_init : unable to allocate sf_ssm_3d array structure' )   ;   RETURN
246            ENDIF
247         END DO
248         !                                         ! fill sf with slf_i and control print
249         CALL fld_fill( sf_ssm_3d, slf_3d, cn_dir, 'sbc_ssm_init', '3D Data in file', 'namsbc_ssm' )
250      ENDIF
251
252      IF( nfld_2d > 0 ) THEN
253         ALLOCATE( sf_ssm_2d(nfld_2d), STAT=ierr )         ! set sf structure
254         IF( ierr > 0 ) THEN
255            CALL ctl_stop( 'sbc_ssm_init: unable to allocate sf 2d structure' )   ;   RETURN
256         ENDIF
257         DO ifpr = 1, nfld_2d
258                                       ALLOCATE( sf_ssm_2d(ifpr)%fnow(jpi,jpj,1)    , STAT=ierr0 )
259            IF( slf_2d(ifpr)%ln_tint ) ALLOCATE( sf_ssm_2d(ifpr)%fdta(jpi,jpj,1,2)  , STAT=ierr1 )
260            IF( ierr0 + ierr1 > 0 ) THEN
261               CALL ctl_stop( 'sbc_ssm_init : unable to allocate sf_ssm_2d array structure' )   ;   RETURN
262            ENDIF
263         END DO
264         !
265         CALL fld_fill( sf_ssm_2d, slf_2d, cn_dir, 'sbc_ssm_init', '2D Data in file', 'namsbc_ssm' )
266      ENDIF
267      !
268      ! finally tidy up
269
270      IF( nfld_3d > 0 ) DEALLOCATE( slf_3d, STAT=ierr )
271      IF( nfld_2d > 0 ) DEALLOCATE( slf_2d, STAT=ierr )
272
273      call sbc_ssm( nit000 )   ! need to define ss?_m arrays used in limistate
274      !
275   END SUBROUTINE sbc_ssm_init
276
277   !!======================================================================
278END MODULE sbcssm
Note: See TracBrowser for help on using the repository browser.