New URL for NEMO forge!   http://forge.nemo-ocean.eu

Since March 2022 along with NEMO 4.2 release, the code development moved to a self-hosted GitLab.
This present forge is now archived and remained online for history.
trcadv.F90 in branches/2015/dev_r5776_UKMO2_OBS_efficiency_improvs/NEMOGCM/NEMO/TOP_SRC/TRP – NEMO

source: branches/2015/dev_r5776_UKMO2_OBS_efficiency_improvs/NEMOGCM/NEMO/TOP_SRC/TRP/trcadv.F90 @ 6041

Last change on this file since 6041 was 6041, checked in by timgraham, 8 years ago

Merged head of trunk into branch

  • Property svn:keywords set to Id
File size: 15.6 KB
Line 
1MODULE trcadv
2   !!==============================================================================
3   !!                       ***  MODULE  trcadv  ***
4   !! Ocean passive tracers:  advection trend
5   !!==============================================================================
6   !! History :  2.0  !  2005-11  (G. Madec)  Original code
7   !!            3.0  !  2010-06  (C. Ethe)   Adapted to passive tracers
8   !!            3.7  !  2014-05  (G. Madec, C. Ethe)  Add 2nd/4th order cases for CEN and FCT schemes
9   !!----------------------------------------------------------------------
10#if defined key_top
11   !!----------------------------------------------------------------------
12   !!   'key_top'                                                TOP models
13   !!----------------------------------------------------------------------
14   !!   trc_adv       : compute ocean tracer advection trend
15   !!   trc_adv_ini   : control the different options of advection scheme
16   !!----------------------------------------------------------------------
17   USE oce_trc        ! ocean dynamics and active tracers
18   USE trc            ! ocean passive tracers variables
19   USE traadv_cen     ! centered scheme           (tra_adv_cen  routine)
20   USE traadv_fct     ! FCT      scheme           (tra_adv_fct  routine)
21   USE traadv_mus     ! MUSCL    scheme           (tra_adv_mus  routine)
22   USE traadv_ubs     ! UBS      scheme           (tra_adv_ubs  routine)
23   USE traadv_qck     ! QUICKEST scheme           (tra_adv_qck  routine)
24   USE traadv_mle     ! ML eddy induced velocity  (tra_adv_mle  routine)
25   USE ldftra         ! lateral diffusion coefficient on tracers
26   USE ldfslp         ! Lateral diffusion: slopes of neutral surfaces
27   !
28   USE prtctl_trc     ! Print control
29
30   IMPLICIT NONE
31   PRIVATE
32
33   PUBLIC   trc_adv       
34   PUBLIC   trc_adv_alloc 
35   PUBLIC   trc_adv_ini 
36
37   !                            !!* Namelist namtrc_adv *
38   LOGICAL ::   ln_trcadv_cen    ! centered scheme flag
39   INTEGER ::      nn_cen_h, nn_cen_v   ! =2/4 : horizontal and vertical choices of the order of CEN scheme
40   LOGICAL ::   ln_trcadv_fct    ! FCT scheme flag
41   INTEGER ::      nn_fct_h, nn_fct_v   ! =2/4 : horizontal and vertical choices of the order of FCT scheme
42   INTEGER ::      nn_fct_zts           ! >=1 : 2nd order FCT with vertical sub-timestepping
43   LOGICAL ::   ln_trcadv_mus    ! MUSCL scheme flag
44   LOGICAL ::      ln_mus_ups           ! use upstream scheme in vivcinity of river mouths
45   LOGICAL ::   ln_trcadv_ubs    ! UBS scheme flag
46   INTEGER ::      nn_ubs_v             ! =2/4 : vertical choice of the order of UBS scheme
47   LOGICAL ::   ln_trcadv_qck    ! QUICKEST scheme flag
48
49   !                                        ! choices of advection scheme:
50   INTEGER, PARAMETER ::   np_NO_adv  = 0   ! no T-S advection
51   INTEGER, PARAMETER ::   np_CEN     = 1   ! 2nd/4th order centered scheme
52   INTEGER, PARAMETER ::   np_FCT     = 2   ! 2nd/4th order Flux Corrected Transport scheme
53   INTEGER, PARAMETER ::   np_FCT_zts = 3   ! 2nd order FCT scheme with vertical sub-timestepping
54   INTEGER, PARAMETER ::   np_MUS     = 4   ! MUSCL scheme
55   INTEGER, PARAMETER ::   np_UBS     = 5   ! 3rd order Upstream Biased Scheme
56   INTEGER, PARAMETER ::   np_QCK     = 6   ! QUICK scheme
57
58   INTEGER ::              nadv             ! chosen advection scheme
59   !
60   REAL(wp), ALLOCATABLE, SAVE, DIMENSION(:) ::   r2dt  ! vertical profile time-step, = 2 rdttra
61   !                                                    ! except at nitrrc000 (=rdttra) if neuler=0
62
63   !! * Substitutions
64#  include "domzgr_substitute.h90"
65#  include "vectopt_loop_substitute.h90"
66   !!----------------------------------------------------------------------
67   !! NEMO/TOP 3.7 , NEMO Consortium (2015)
68   !! $Id$
69   !! Software governed by the CeCILL licence (NEMOGCM/NEMO_CeCILL.txt)
70   !!----------------------------------------------------------------------
71CONTAINS
72
73   INTEGER FUNCTION trc_adv_alloc()
74      !!----------------------------------------------------------------------
75      !!                  ***  ROUTINE trc_adv_alloc  ***
76      !!----------------------------------------------------------------------
77      !
78      ALLOCATE( r2dt(jpk), STAT=trc_adv_alloc )
79      !
80      IF( trc_adv_alloc /= 0 ) CALL ctl_warn('trc_adv_alloc : failed to allocate array.')
81      !
82   END FUNCTION trc_adv_alloc
83
84
85   SUBROUTINE trc_adv( kt )
86      !!----------------------------------------------------------------------
87      !!                  ***  ROUTINE trc_adv  ***
88      !!
89      !! ** Purpose :   compute the ocean tracer advection trend.
90      !!
91      !! ** Method  : - Update the tracer with the advection term following nadv
92      !!----------------------------------------------------------------------
93      INTEGER, INTENT(in) ::   kt   ! ocean time-step index
94      !
95      INTEGER ::   jk   ! dummy loop index
96      CHARACTER (len=22) ::   charout
97      REAL(wp), POINTER, DIMENSION(:,:,:) :: zun, zvn, zwn  ! effective velocity
98      !!----------------------------------------------------------------------
99      !
100      IF( nn_timing == 1 )   CALL timing_start('trc_adv')
101      !
102      CALL wrk_alloc( jpi,jpj,jpk,   zun, zvn, zwn )
103      !
104      IF( ( neuler == 0 .AND. kt == nittrc000 ) .OR. ln_top_euler ) THEN     ! at nittrc000
105         r2dt(:) =  rdttrc(:)           ! = rdttrc (use or restarting with Euler time stepping)
106      ELSEIF( kt <= nittrc000 + nn_dttrc ) THEN          ! at nittrc000 or nittrc000+1
107         r2dt(:) = 2. * rdttrc(:)       ! = 2 rdttrc (leapfrog)
108      ENDIF
109      !                                               !==  effective transport  ==!
110      DO jk = 1, jpkm1
111         zun(:,:,jk) = e2u  (:,:) * fse3u(:,:,jk) * un(:,:,jk)                   ! eulerian transport
112         zvn(:,:,jk) = e1v  (:,:) * fse3v(:,:,jk) * vn(:,:,jk)
113         zwn(:,:,jk) = e1e2t(:,:)                 * wn(:,:,jk)
114      END DO
115      !
116      IF( ln_vvl_ztilde .OR. ln_vvl_layer ) THEN                                 ! add z-tilde and/or vvl corrections
117         zun(:,:,:) = zun(:,:,:) + un_td(:,:,:)
118         zvn(:,:,:) = zvn(:,:,:) + vn_td(:,:,:)
119      ENDIF
120      !
121      IF( ln_ldfeiv .AND. .NOT. ln_traldf_triad )   & 
122         &              CALL ldf_eiv_trp( kt, nittrc000, zun, zvn, zwn, 'TRC' )  ! add the eiv transport
123      !
124      IF( ln_mle    )   CALL tra_adv_mle( kt, nittrc000, zun, zvn, zwn, 'TRC' )  ! add the mle transport
125      !
126      zun(:,:,jpk) = 0._wp                                                       ! no transport trough the bottom
127      zvn(:,:,jpk) = 0._wp
128      zwn(:,:,jpk) = 0._wp
129      !
130      !
131      SELECT CASE ( nadv )                      !==  compute advection trend and add it to general trend  ==!
132      !
133      CASE ( np_CEN )                                    ! Centered : 2nd / 4th order
134         CALL tra_adv_cen    ( kt, nittrc000,'TRC',       zun, zvn, zwn     , trn, tra, jptra, nn_cen_h, nn_cen_v )
135      CASE ( np_FCT )                                    ! FCT      : 2nd / 4th order
136         CALL tra_adv_fct    ( kt, nittrc000,'TRC', r2dt, zun, zvn, zwn, trb, trn, tra, jptra, nn_fct_h, nn_fct_v )
137      CASE ( np_FCT_zts )                                ! 2nd order FCT with vertical time-splitting
138         CALL tra_adv_fct_zts( kt, nittrc000,'TRC', r2dt, zun, zvn, zwn, trb, trn, tra, jptra        , nn_fct_zts )
139      CASE ( np_MUS )                                    ! MUSCL
140         CALL tra_adv_mus    ( kt, nittrc000,'TRC', r2dt, zun, zvn, zwn, trb,      tra, jptra        , ln_mus_ups ) 
141      CASE ( np_UBS )                                    ! UBS
142         CALL tra_adv_ubs    ( kt, nittrc000,'TRC', r2dt, zun, zvn, zwn, trb, trn, tra, jptra        , nn_ubs_v   )
143      CASE ( np_QCK )                                    ! QUICKEST
144         CALL tra_adv_qck    ( kt, nittrc000,'TRC', r2dt, zun, zvn, zwn, trb, trn, tra, jptra                     )
145      !
146      END SELECT
147      !                 
148      IF( ln_ctl )   THEN                             !== print mean trends (used for debugging)
149         WRITE(charout, FMT="('adv ')")  ;  CALL prt_ctl_trc_info(charout)
150                                            CALL prt_ctl_trc( tab4d=tra, mask=tmask, clinfo=ctrcnm, clinfo2='trd' )
151      END IF
152      !
153      CALL wrk_dealloc( jpi,jpj,jpk,   zun, zvn, zwn )
154      !
155      IF( nn_timing == 1 )  CALL timing_stop('trc_adv')
156      !
157   END SUBROUTINE trc_adv
158
159
160   SUBROUTINE trc_adv_ini
161      !!---------------------------------------------------------------------
162      !!                  ***  ROUTINE trc_adv_ini  ***
163      !!               
164      !! ** Purpose : Control the consistency between namelist options for
165      !!              passive tracer advection schemes and set nadv
166      !!----------------------------------------------------------------------
167      INTEGER ::   ioptio
168      INTEGER ::  ios                 ! Local integer output status for namelist read
169      !!
170      NAMELIST/namtrc_adv/ ln_trcadv_cen, nn_cen_h, nn_cen_v,               &   ! CEN
171         &                 ln_trcadv_fct, nn_fct_h, nn_fct_v, nn_fct_zts,   &   ! FCT
172         &                 ln_trcadv_mus,                     ln_mus_ups,   &   ! MUSCL
173         &                 ln_trcadv_ubs,           nn_ubs_v,               &   ! UBS
174         &                 ln_trcadv_qck                                        ! QCK
175      !!----------------------------------------------------------------------
176      !
177      REWIND( numnat_ref )              !  namtrc_adv in reference namelist
178      READ  ( numnat_ref, namtrc_adv, IOSTAT = ios, ERR = 901)
179901   IF( ios /= 0 ) CALL ctl_nam ( ios , 'namtrc_adv in reference namelist', lwp )
180
181      REWIND( numnat_cfg )              ! namtrc_adv in configuration namelist
182      READ  ( numnat_cfg, namtrc_adv, IOSTAT = ios, ERR = 902 )
183902   IF( ios /= 0 ) CALL ctl_nam ( ios , 'namtrc_adv in configuration namelist', lwp )
184      IF(lwm) WRITE ( numont, namtrc_adv )
185
186      IF(lwp) THEN                    ! Namelist print
187         WRITE(numout,*)
188         WRITE(numout,*) 'trc_adv_ini : choice/control of the tracer advection scheme'
189         WRITE(numout,*) '~~~~~~~~~~~'
190         WRITE(numout,*) '   Namelist namtrc_adv : chose a advection scheme for tracers'
191         WRITE(numout,*) '      centered scheme                           ln_trcadv_cen = ', ln_trcadv_cen
192         WRITE(numout,*) '            horizontal 2nd/4th order               nn_cen_h   = ', nn_fct_h
193         WRITE(numout,*) '            vertical   2nd/4th order               nn_cen_v   = ', nn_fct_v
194         WRITE(numout,*) '      Flux Corrected Transport scheme           ln_trcadv_fct = ', ln_trcadv_fct
195         WRITE(numout,*) '            horizontal 2nd/4th order               nn_fct_h   = ', nn_fct_h
196         WRITE(numout,*) '            vertical   2nd/4th order               nn_fct_v   = ', nn_fct_v
197         WRITE(numout,*) '            2nd order + vertical sub-timestepping  nn_fct_zts = ', nn_fct_zts
198         WRITE(numout,*) '      MUSCL scheme                              ln_trcadv_mus = ', ln_trcadv_mus
199         WRITE(numout,*) '            + upstream scheme near river mouths    ln_mus_ups = ', ln_mus_ups
200         WRITE(numout,*) '      UBS scheme                                ln_trcadv_ubs = ', ln_trcadv_ubs
201         WRITE(numout,*) '            vertical   2nd/4th order               nn_ubs_v   = ', nn_ubs_v
202         WRITE(numout,*) '      QUICKEST scheme                           ln_trcadv_qck = ', ln_trcadv_qck
203      ENDIF
204      !
205
206      ioptio = 0                       !==  Parameter control  ==!
207      IF( ln_trcadv_cen )   ioptio = ioptio + 1
208      IF( ln_trcadv_fct )   ioptio = ioptio + 1
209      IF( ln_trcadv_mus )   ioptio = ioptio + 1
210      IF( ln_trcadv_ubs )   ioptio = ioptio + 1
211      IF( ln_trcadv_qck )   ioptio = ioptio + 1
212
213      !
214      IF( ioptio == 0 ) THEN
215         nadv = np_NO_adv
216         CALL ctl_warn( 'trc_adv_init: You are running without tracer advection.' )
217      ENDIF
218      IF( ioptio /= 1 )   CALL ctl_stop( 'Choose ONE advection scheme in namelist namtrc_adv' )
219      !
220      IF( ln_trcadv_cen .AND. ( nn_cen_h /= 2 .AND. nn_cen_h /= 4 )   &
221                        .AND. ( nn_cen_v /= 2 .AND. nn_cen_v /= 4 )   ) THEN
222        CALL ctl_stop( 'trc_adv_init: CEN scheme, choose 2nd or 4th order' )
223      ENDIF
224      IF( ln_trcadv_fct .AND. ( nn_fct_h /= 2 .AND. nn_fct_h /= 4 )   &
225                        .AND. ( nn_fct_v /= 2 .AND. nn_fct_v /= 4 )   ) THEN
226        CALL ctl_stop( 'trc_adv_init: FCT scheme, choose 2nd or 4th order' )
227      ENDIF
228      IF( ln_trcadv_fct .AND. nn_fct_zts > 0 ) THEN
229         IF( nn_fct_h == 4 ) THEN
230            nn_fct_h = 2
231            CALL ctl_stop( 'trc_adv_init: force 2nd order FCT scheme, 4th order does not exist with sub-timestepping' )
232         ENDIF
233         IF( lk_vvl ) THEN
234            CALL ctl_stop( 'trc_adv_init: vertical sub-timestepping not allow in non-linear free surface' )
235         ENDIF
236         IF( nn_fct_zts == 1 )   CALL ctl_warn( 'trc_adv_init: FCT with ONE sub-timestep = FCT without sub-timestep' )
237      ENDIF
238      IF( ln_trcadv_ubs .AND. ( nn_ubs_v /= 2 .AND. nn_ubs_v /= 4 )   ) THEN
239        CALL ctl_stop( 'trc_adv_init: UBS scheme, choose 2nd or 4th order' )
240      ENDIF
241      IF( ln_trcadv_ubs .AND. nn_ubs_v == 4 ) THEN
242         CALL ctl_warn( 'trc_adv_init: UBS scheme, only 2nd FCT scheme available on the vertical. It will be used' )
243      ENDIF
244      IF( ln_isfcav ) THEN                                                       ! ice-shelf cavities
245         IF(  ln_trcadv_cen .AND. nn_cen_v /= 4    .OR.   &                            ! NO 4th order with ISF
246            & ln_trcadv_fct .AND. nn_fct_v /= 4   )   CALL ctl_stop( 'tra_adv_init: 4th order COMPACT scheme not allowed with ISF' )
247      ENDIF
248      !
249      !                                !==  used advection scheme  ==!
250      !                                      ! set nadv
251      IF( ln_trcadv_cen                      )   nadv = np_CEN
252      IF( ln_trcadv_fct                      )   nadv = np_FCT
253      IF( ln_trcadv_fct .AND. nn_fct_zts > 0 )   nadv = np_FCT_zts
254      IF( ln_trcadv_mus                      )   nadv = np_MUS
255      IF( ln_trcadv_ubs                      )   nadv = np_UBS
256      IF( ln_trcadv_qck                      )   nadv = np_QCK
257      !
258      IF(lwp) THEN                   ! Print the choice
259         WRITE(numout,*)
260         IF( nadv == np_NO_adv  )   WRITE(numout,*) '         NO passive tracer advection'
261         IF( nadv == np_CEN     )   WRITE(numout,*) '         CEN      scheme is used. Horizontal order: ', nn_cen_h,   &
262            &                                                                        ' Vertical   order: ', nn_cen_v
263         IF( nadv == np_FCT     )   WRITE(numout,*) '         FCT      scheme is used. Horizontal order: ', nn_fct_h,   &
264            &                                                                       ' Vertical   order: ', nn_fct_v
265         IF( nadv == np_FCT_zts )   WRITE(numout,*) '         use 2nd order FCT with ', nn_fct_zts,'vertical sub-timestepping'
266         IF( nadv == np_MUS     )   WRITE(numout,*) '         MUSCL    scheme is used'
267         IF( nadv == np_UBS     )   WRITE(numout,*) '         UBS      scheme is used'
268         IF( nadv == np_QCK     )   WRITE(numout,*) '         QUICKEST scheme is used'
269      ENDIF
270      !
271   END SUBROUTINE trc_adv_ini
272   
273#else
274   !!----------------------------------------------------------------------
275   !!   Default option                                         Empty module
276   !!----------------------------------------------------------------------
277CONTAINS
278   SUBROUTINE trc_adv( kt )
279      INTEGER, INTENT(in) :: kt
280      WRITE(*,*) 'trc_adv: You should not have seen this print! error?', kt
281   END SUBROUTINE trc_adv
282#endif
283
284  !!======================================================================
285END MODULE trcadv
Note: See TracBrowser for help on using the repository browser.