New URL for NEMO forge! http://forge.nemo-ocean.eu

Since March 2022 along with NEMO 4.2 release, the code development moved to a self-hosted GitLab.
This present forge is now archived and remained online for history.

dynhpg.F90 in branches/2015/dev_r5803_NOC_WAD/NEMOGCM/NEMO/OPA_SRC/DYN – NEMO

Context Navigation

source: branches/2015/dev_r5803_NOC_WAD/NEMOGCM/NEMO/OPA_SRC/DYN/dynhpg.F90 @ 5842

Last change on this file since 5842 was 5842, checked in by hliu, 8 years ago
Wetting and Drying update based on r:5803
Property svn:keywords set to `Id`
File size: 77.7 KB

Line
1	MODULE dynhpg
2	!!======================================================================
3	!! * MODULE dynhpg *
4	!! Ocean dynamics: hydrostatic pressure gradient trend
5	!!======================================================================
6	!! History : OPA ! 1987-09 (P. Andrich, M.-A. Foujols) hpg_zco: Original code
7	!! 5.0 ! 1991-11 (G. Madec)
8	!! 7.0 ! 1996-01 (G. Madec) hpg_sco: Original code for s-coordinates
9	!! 8.0 ! 1997-05 (G. Madec) split dynber into dynkeg and dynhpg
10	!! 8.5 ! 2002-07 (G. Madec) F90: Free form and module
11	!! 8.5 ! 2002-08 (A. Bozec) hpg_zps: Original code
12	!! NEMO 1.0 ! 2005-10 (A. Beckmann, B.W. An) various s-coordinate options
13	!! ! Original code for hpg_ctl, hpg_hel hpg_wdj, hpg_djc, hpg_rot
14	!! - ! 2005-11 (G. Madec) style & small optimisation
15	!! 3.3 ! 2010-10 (C. Ethe, G. Madec) reorganisation of initialisation phase
16	!! 3.4 ! 2011-11 (H. Liu) hpg_prj: Original code for s-coordinates
17	!! ! (A. Coward) suppression of hel, wdj and rot options
18	!! 3.6 ! 2014-11 (P. Mathiot) hpg_isf: original code for ice shelf cavity
19	!! 3.6? ! 2015-11 (H. Liu) add Wetting/Drying pressure filter
20	!!----------------------------------------------------------------------
21
22	!!----------------------------------------------------------------------
23	!! dyn_hpg : update the momentum trend with the now horizontal
24	!! gradient of the hydrostatic pressure
25	!! dyn_hpg_init : initialisation and control of options
26	!! hpg_zco : z-coordinate scheme
27	!! hpg_zps : z-coordinate plus partial steps (interpolation)
28	!! hpg_sco : s-coordinate (standard jacobian formulation)
29	!! hpg_isf : s-coordinate (sco formulation) adapted to ice shelf
30	!! hpg_djc : s-coordinate (Density Jacobian with Cubic polynomial)
31	!! hpg_prj : s-coordinate (Pressure Jacobian with Cubic polynomial)
32	!!----------------------------------------------------------------------
33	USE oce ! ocean dynamics and tracers
34	USE sbc_oce ! surface variable (only for the flag with ice shelf)
35	USE dom_oce ! ocean space and time domain
36	USE phycst ! physical constants
37	USE trd_oce ! trends: ocean variables
38	USE trddyn ! trend manager: dynamics
39	!
40	USE in_out_manager ! I/O manager
41	USE prtctl ! Print control
42	USE lbclnk ! lateral boundary condition
43	USE lib_mpp ! MPP library
44	USE eosbn2 ! compute density
45	USE wrk_nemo ! Memory Allocation
46	USE timing ! Timing
47
48	IMPLICIT NONE
49	PRIVATE
50
51	PUBLIC dyn_hpg ! routine called by step module
52	PUBLIC dyn_hpg_init ! routine called by opa module
53
54	! !!* Namelist namdyn_hpg : hydrostatic pressure gradient
55	LOGICAL , PUBLIC :: ln_hpg_zco !: z-coordinate - full steps
56	LOGICAL , PUBLIC :: ln_hpg_zps !: z-coordinate - partial steps (interpolation)
57	LOGICAL , PUBLIC :: ln_hpg_sco !: s-coordinate (standard jacobian formulation)
58	LOGICAL , PUBLIC :: ln_hpg_djc !: s-coordinate (Density Jacobian with Cubic polynomial)
59	LOGICAL , PUBLIC :: ln_hpg_prj !: s-coordinate (Pressure Jacobian scheme)
60	LOGICAL , PUBLIC :: ln_hpg_isf !: s-coordinate similar to sco modify for isf
61	LOGICAL , PUBLIC :: ln_dynhpg_imp !: semi-implicite hpg flag
62
63	INTEGER , PUBLIC :: nhpg = 0 ! = 0 to 7, type of pressure gradient scheme used ! (deduced from ln_hpg_... flags) (PUBLIC for TAM)
64
65	!! * Substitutions
66	# include "domzgr_substitute.h90"
67	# include "vectopt_loop_substitute.h90"
68	!!----------------------------------------------------------------------
69	!! NEMO/OPA 3.3 , NEMO Consortium (2010)
70	!! $Id$
71	!! Software governed by the CeCILL licence (NEMOGCM/NEMO_CeCILL.txt)
72	!!----------------------------------------------------------------------
73	CONTAINS
74
75	SUBROUTINE dyn_hpg( kt )
76	!!---------------------------------------------------------------------
77	!! * ROUTINE dyn_hpg *
78	!!
79	!! ** Method : Call the hydrostatic pressure gradient routine
80	!! using the scheme defined in the namelist
81	!!
82	!! ** Action : - Update (ua,va) with the now hydrastatic pressure trend
83	!! - send trends to trd_dyn for futher diagnostics (l_trddyn=T)
84	!!----------------------------------------------------------------------
85	INTEGER, INTENT(in) :: kt ! ocean time-step index
86	REAL(wp), POINTER, DIMENSION(:,:,:) :: ztrdu, ztrdv
87	!!----------------------------------------------------------------------
88	!
89	IF( nn_timing == 1 ) CALL timing_start('dyn_hpg')
90	!
91	IF( l_trddyn ) THEN ! Temporary saving of ua and va trends (l_trddyn)
92	CALL wrk_alloc( jpi,jpj,jpk, ztrdu, ztrdv )
93	ztrdu(:,:,:) = ua(:,:,:)
94	ztrdv(:,:,:) = va(:,:,:)
95	ENDIF
96	!
97	SELECT CASE ( nhpg ) ! Hydrostatic pressure gradient computation
98	CASE ( 0 ) ; CALL hpg_zco ( kt ) ! z-coordinate
99	CASE ( 1 ) ; CALL hpg_zps ( kt ) ! z-coordinate plus partial steps (interpolation)
100	CASE ( 2 ) ; CALL hpg_sco ( kt ) ! s-coordinate (standard jacobian formulation)
101	CASE ( 3 ) ; CALL hpg_djc ( kt ) ! s-coordinate (Density Jacobian with Cubic polynomial)
102	CASE ( 4 ) ; CALL hpg_prj ( kt ) ! s-coordinate (Pressure Jacobian scheme)
103	CASE ( 5 ) ; CALL hpg_isf ( kt ) ! s-coordinate similar to sco modify for ice shelf
104	END SELECT
105	!
106	IF( l_trddyn ) THEN ! save the hydrostatic pressure gradient trends for momentum trend diagnostics
107	ztrdu(:,:,:) = ua(:,:,:) - ztrdu(:,:,:)
108	ztrdv(:,:,:) = va(:,:,:) - ztrdv(:,:,:)
109	CALL trd_dyn( ztrdu, ztrdv, jpdyn_hpg, kt )
110	CALL wrk_dealloc( jpi,jpj,jpk, ztrdu, ztrdv )
111	ENDIF
112	!
113	IF(ln_ctl) CALL prt_ctl( tab3d_1=ua, clinfo1=' hpg - Ua: ', mask1=umask, &
114	& tab3d_2=va, clinfo2= ' Va: ', mask2=vmask, clinfo3='dyn' )
115	!
116	IF( nn_timing == 1 ) CALL timing_stop('dyn_hpg')
117	!
118	END SUBROUTINE dyn_hpg
119
120
121	SUBROUTINE dyn_hpg_init
122	!!----------------------------------------------------------------------
123	!! * ROUTINE dyn_hpg_init *
124	!!
125	!! ** Purpose : initializations for the hydrostatic pressure gradient
126	!! computation and consistency control
127	!!
128	!! ** Action : Read the namelist namdyn_hpg and check the consistency
129	!! with the type of vertical coordinate used (zco, zps, sco)
130	!!----------------------------------------------------------------------
131	INTEGER :: ioptio = 0 ! temporary integer
132	INTEGER :: ios ! Local integer output status for namelist read
133	!!
134	NAMELIST/namdyn_hpg/ ln_hpg_zco, ln_hpg_zps, ln_hpg_sco, &
135	& ln_hpg_djc, ln_hpg_prj, ln_hpg_isf, ln_dynhpg_imp
136	!!----------------------------------------------------------------------
137	!
138	REWIND( numnam_ref ) ! Namelist namdyn_hpg in reference namelist : Hydrostatic pressure gradient
139	READ ( numnam_ref, namdyn_hpg, IOSTAT = ios, ERR = 901)
140	901 IF( ios /= 0 ) CALL ctl_nam ( ios , 'namdyn_hpg in reference namelist', lwp )
141
142	REWIND( numnam_cfg ) ! Namelist namdyn_hpg in configuration namelist : Hydrostatic pressure gradient
143	READ ( numnam_cfg, namdyn_hpg, IOSTAT = ios, ERR = 902 )
144	902 IF( ios /= 0 ) CALL ctl_nam ( ios , 'namdyn_hpg in configuration namelist', lwp )
145	IF(lwm) WRITE ( numond, namdyn_hpg )
146	!
147	IF(lwp) THEN ! Control print
148	WRITE(numout,*)
149	WRITE(numout,*) 'dyn_hpg_init : hydrostatic pressure gradient initialisation'
150	WRITE(numout,*) '~~~~~~~~~~~~'
151	WRITE(numout,*) ' Namelist namdyn_hpg : choice of hpg scheme'
152	WRITE(numout,*) ' z-coord. - full steps ln_hpg_zco = ', ln_hpg_zco
153	WRITE(numout,*) ' z-coord. - partial steps (interpolation) ln_hpg_zps = ', ln_hpg_zps
154	WRITE(numout,*) ' s-coord. (standard jacobian formulation) ln_hpg_sco = ', ln_hpg_sco
155	WRITE(numout,*) ' s-coord. (standard jacobian formulation) for isf ln_hpg_isf = ', ln_hpg_isf
156	WRITE(numout,*) ' s-coord. (Density Jacobian: Cubic polynomial) ln_hpg_djc = ', ln_hpg_djc
157	WRITE(numout,*) ' s-coord. (Pressure Jacobian: Cubic polynomial) ln_hpg_prj = ', ln_hpg_prj
158	WRITE(numout,*) ' time stepping: centered (F) or semi-implicit (T) ln_dynhpg_imp = ', ln_dynhpg_imp
159	ENDIF
160	!
161	IF( ln_hpg_djc ) &
162	& CALL ctl_stop('dyn_hpg_init : Density Jacobian: Cubic polynominal method &
163	& currently disabled (bugs under investigation). Please select &
164	& either ln_hpg_sco or ln_hpg_prj instead')
165	!
166	IF( lk_vvl .AND. .NOT. (ln_hpg_sco.OR.ln_hpg_prj.OR.ln_hpg_isf) ) &
167	& CALL ctl_stop('dyn_hpg_init : variable volume key_vvl requires:&
168	& the standard jacobian formulation hpg_sco or &
169	& the pressure jacobian formulation hpg_prj')
170
171	IF( ln_hpg_isf .AND. .NOT. ln_isfcav ) &
172	& CALL ctl_stop( ' hpg_isf not available if ln_isfcav = false ' )
173	IF( .NOT. ln_hpg_isf .AND. ln_isfcav ) &
174	& CALL ctl_stop( 'Only hpg_isf has been corrected to work with ice shelf cavity.' )
175	!
176	! ! Set nhpg from ln_hpg_... flags
177	IF( ln_hpg_zco ) nhpg = 0
178	IF( ln_hpg_zps ) nhpg = 1
179	IF( ln_hpg_sco ) nhpg = 2
180	IF( ln_hpg_djc ) nhpg = 3
181	IF( ln_hpg_prj ) nhpg = 4
182	IF( ln_hpg_isf ) nhpg = 5
183	!
184	! ! Consistency check
185	ioptio = 0
186	IF( ln_hpg_zco ) ioptio = ioptio + 1
187	IF( ln_hpg_zps ) ioptio = ioptio + 1
188	IF( ln_hpg_sco ) ioptio = ioptio + 1
189	IF( ln_hpg_djc ) ioptio = ioptio + 1
190	IF( ln_hpg_prj ) ioptio = ioptio + 1
191	IF( ln_hpg_isf ) ioptio = ioptio + 1
192	IF( ioptio /= 1 ) CALL ctl_stop( 'NO or several hydrostatic pressure gradient options used' )
193	!
194	! initialisation of ice load
195	riceload(:,:)=0.0
196	!
197	END SUBROUTINE dyn_hpg_init
198
199
200	SUBROUTINE hpg_zco( kt )
201	!!---------------------------------------------------------------------
202	!! * ROUTINE hpg_zco *
203	!!
204	!! ** Method : z-coordinate case, levels are horizontal surfaces.
205	!! The now hydrostatic pressure gradient at a given level, jk,
206	!! is computed by taking the vertical integral of the in-situ
207	!! density gradient along the model level from the suface to that
208	!! level: zhpi = grav .....
209	!! zhpj = grav .....
210	!! add it to the general momentum trend (ua,va).
211	!! ua = ua - 1/e1u * zhpi
212	!! va = va - 1/e2v * zhpj
213	!!
214	!! ** Action : - Update (ua,va) with the now hydrastatic pressure trend
215	!!----------------------------------------------------------------------
216	INTEGER, INTENT(in) :: kt ! ocean time-step index
217	!!
218	INTEGER :: ji, jj, jk ! dummy loop indices
219	REAL(wp) :: zcoef0, zcoef1 ! temporary scalars
220	REAL(wp), POINTER, DIMENSION(:,:,:) :: zhpi, zhpj
221	!!----------------------------------------------------------------------
222	!
223	CALL wrk_alloc( jpi,jpj,jpk, zhpi, zhpj )
224	!
225	IF( kt == nit000 ) THEN
226	IF(lwp) WRITE(numout,*)
227	IF(lwp) WRITE(numout,*) 'dyn:hpg_zco : hydrostatic pressure gradient trend'
228	IF(lwp) WRITE(numout,*) '~~~~~~~~~~~ z-coordinate case '
229	ENDIF
230
231	zcoef0 = - grav * 0.5_wp ! Local constant initialization
232
233	! Surface value
234	DO jj = 2, jpjm1
235	DO ji = fs_2, fs_jpim1 ! vector opt.
236	zcoef1 = zcoef0 * fse3w(ji,jj,1)
237	! hydrostatic pressure gradient
238	zhpi(ji,jj,1) = zcoef1 * ( rhd(ji+1,jj,1) - rhd(ji,jj,1) ) / e1u(ji,jj)
239	zhpj(ji,jj,1) = zcoef1 * ( rhd(ji,jj+1,1) - rhd(ji,jj,1) ) / e2v(ji,jj)
240	! add to the general momentum trend
241	ua(ji,jj,1) = ua(ji,jj,1) + zhpi(ji,jj,1)
242	va(ji,jj,1) = va(ji,jj,1) + zhpj(ji,jj,1)
243	END DO
244	END DO
245
246	!
247	! interior value (2=<jk=<jpkm1)
248	DO jk = 2, jpkm1
249	DO jj = 2, jpjm1
250	DO ji = fs_2, fs_jpim1 ! vector opt.
251	zcoef1 = zcoef0 * fse3w(ji,jj,jk)
252	! hydrostatic pressure gradient
253	zhpi(ji,jj,jk) = zhpi(ji,jj,jk-1) &
254	& + zcoef1 * ( ( rhd(ji+1,jj,jk)+rhd(ji+1,jj,jk-1) ) &
255	& - ( rhd(ji ,jj,jk)+rhd(ji ,jj,jk-1) ) ) / e1u(ji,jj)
256
257	zhpj(ji,jj,jk) = zhpj(ji,jj,jk-1) &
258	& + zcoef1 * ( ( rhd(ji,jj+1,jk)+rhd(ji,jj+1,jk-1) ) &
259	& - ( rhd(ji,jj, jk)+rhd(ji,jj ,jk-1) ) ) / e2v(ji,jj)
260	! add to the general momentum trend
261	ua(ji,jj,jk) = ua(ji,jj,jk) + zhpi(ji,jj,jk)
262	va(ji,jj,jk) = va(ji,jj,jk) + zhpj(ji,jj,jk)
263	END DO
264	END DO
265	END DO
266	!
267	CALL wrk_dealloc( jpi,jpj,jpk, zhpi, zhpj )
268	!
269	END SUBROUTINE hpg_zco
270
271
272	SUBROUTINE hpg_zps( kt )
273	!!---------------------------------------------------------------------
274	!! * ROUTINE hpg_zps *
275	!!
276	!! ** Method : z-coordinate plus partial steps case. blahblah...
277	!!
278	!! ** Action : - Update (ua,va) with the now hydrastatic pressure trend
279	!!----------------------------------------------------------------------
280	INTEGER, INTENT(in) :: kt ! ocean time-step index
281	!!
282	INTEGER :: ji, jj, jk ! dummy loop indices
283	INTEGER :: iku, ikv ! temporary integers
284	REAL(wp) :: zcoef0, zcoef1, zcoef2, zcoef3 ! temporary scalars
285	REAL(wp), POINTER, DIMENSION(:,:,:) :: zhpi, zhpj
286	!!----------------------------------------------------------------------
287	!
288	CALL wrk_alloc( jpi,jpj,jpk, zhpi, zhpj )
289	!
290	IF( kt == nit000 ) THEN
291	IF(lwp) WRITE(numout,*)
292	IF(lwp) WRITE(numout,*) 'dyn:hpg_zps : hydrostatic pressure gradient trend'
293	IF(lwp) WRITE(numout,*) '~~~~~~~~~~~ z-coordinate with partial steps - vector optimization'
294	ENDIF
295
296
297	! Local constant initialization
298	zcoef0 = - grav * 0.5_wp
299
300	! Surface value (also valid in partial step case)
301	DO jj = 2, jpjm1
302	DO ji = fs_2, fs_jpim1 ! vector opt.
303	zcoef1 = zcoef0 * fse3w(ji,jj,1)
304	! hydrostatic pressure gradient
305	zhpi(ji,jj,1) = zcoef1 * ( rhd(ji+1,jj ,1) - rhd(ji,jj,1) ) / e1u(ji,jj)
306	zhpj(ji,jj,1) = zcoef1 * ( rhd(ji ,jj+1,1) - rhd(ji,jj,1) ) / e2v(ji,jj)
307	! add to the general momentum trend
308	ua(ji,jj,1) = ua(ji,jj,1) + zhpi(ji,jj,1)
309	va(ji,jj,1) = va(ji,jj,1) + zhpj(ji,jj,1)
310	END DO
311	END DO
312
313
314	! interior value (2=<jk=<jpkm1)
315	DO jk = 2, jpkm1
316	DO jj = 2, jpjm1
317	DO ji = fs_2, fs_jpim1 ! vector opt.
318	zcoef1 = zcoef0 * fse3w(ji,jj,jk)
319	! hydrostatic pressure gradient
320	zhpi(ji,jj,jk) = zhpi(ji,jj,jk-1) &
321	& + zcoef1 * ( ( rhd(ji+1,jj,jk) + rhd(ji+1,jj,jk-1) ) &
322	& - ( rhd(ji ,jj,jk) + rhd(ji ,jj,jk-1) ) ) / e1u(ji,jj)
323
324	zhpj(ji,jj,jk) = zhpj(ji,jj,jk-1) &
325	& + zcoef1 * ( ( rhd(ji,jj+1,jk) + rhd(ji,jj+1,jk-1) ) &
326	& - ( rhd(ji,jj, jk) + rhd(ji,jj ,jk-1) ) ) / e2v(ji,jj)
327	! add to the general momentum trend
328	ua(ji,jj,jk) = ua(ji,jj,jk) + zhpi(ji,jj,jk)
329	va(ji,jj,jk) = va(ji,jj,jk) + zhpj(ji,jj,jk)
330	END DO
331	END DO
332	END DO
333
334
335	! partial steps correction at the last level (use gru & grv computed in zpshde.F90)
336	DO jj = 2, jpjm1
337	DO ji = 2, jpim1
338	iku = mbku(ji,jj)
339	ikv = mbkv(ji,jj)
340	zcoef2 = zcoef0 * MIN( fse3w(ji,jj,iku), fse3w(ji+1,jj ,iku) )
341	zcoef3 = zcoef0 * MIN( fse3w(ji,jj,ikv), fse3w(ji ,jj+1,ikv) )
342	IF( iku > 1 ) THEN ! on i-direction (level 2 or more)
343	ua (ji,jj,iku) = ua(ji,jj,iku) - zhpi(ji,jj,iku) ! subtract old value
344	zhpi(ji,jj,iku) = zhpi(ji,jj,iku-1) & ! compute the new one
345	& + zcoef2 * ( rhd(ji+1,jj,iku-1) - rhd(ji,jj,iku-1) + gru(ji,jj) ) / e1u(ji,jj)
346	ua (ji,jj,iku) = ua(ji,jj,iku) + zhpi(ji,jj,iku) ! add the new one to the general momentum trend
347	ENDIF
348	IF( ikv > 1 ) THEN ! on j-direction (level 2 or more)
349	va (ji,jj,ikv) = va(ji,jj,ikv) - zhpj(ji,jj,ikv) ! subtract old value
350	zhpj(ji,jj,ikv) = zhpj(ji,jj,ikv-1) & ! compute the new one
351	& + zcoef3 * ( rhd(ji,jj+1,ikv-1) - rhd(ji,jj,ikv-1) + grv(ji,jj) ) / e2v(ji,jj)
352	va (ji,jj,ikv) = va(ji,jj,ikv) + zhpj(ji,jj,ikv) ! add the new one to the general momentum trend
353	ENDIF
354	END DO
355	END DO
356	!
357	CALL wrk_dealloc( jpi,jpj,jpk, zhpi, zhpj )
358	!
359	END SUBROUTINE hpg_zps
360
361	SUBROUTINE hpg_sco( kt )
362	!!---------------------------------------------------------------------
363	!! * ROUTINE hpg_sco *
364	!!
365	!! ** Method : s-coordinate case. Jacobian scheme.
366	!! The now hydrostatic pressure gradient at a given level, jk,
367	!! is computed by taking the vertical integral of the in-situ
368	!! density gradient along the model level from the suface to that
369	!! level. s-coordinates (ln_sco): a corrective term is added
370	!! to the horizontal pressure gradient :
371	!! zhpi = grav ..... + 1/e1u mi(rhd) di[ grav dep3w ]
372	!! zhpj = grav ..... + 1/e2v mj(rhd) dj[ grav dep3w ]
373	!! add it to the general momentum trend (ua,va).
374	!! ua = ua - 1/e1u * zhpi
375	!! va = va - 1/e2v * zhpj
376	!!
377	!! ** Action : - Update (ua,va) with the now hydrastatic pressure trend
378	!!----------------------------------------------------------------------
379	INTEGER, INTENT(in) :: kt ! ocean time-step index
380	!!
381	INTEGER :: ji, jj, jk, jii, jjj ! dummy loop indices
382	REAL(wp) :: zcoef0, zuap, zvap, znad, ztmp ! temporary scalars
383	LOGICAL :: ll_tmp1, ll_tmp2, ll_tmp3 ! local logical variables
384	REAL(wp), POINTER, DIMENSION(:,:,:) :: zhpi, zhpj
385	REAL(wp), POINTER, DIMENSION(:,:) :: zcpx, zcpy !W/D pressure filter
386	!!----------------------------------------------------------------------
387	!
388	CALL wrk_alloc( jpi,jpj,jpk, zhpi, zhpj )
389	IF(ln_wd) CALL wrk_alloc( jpi,jpj, zcpx, zcpy )
390	!
391	IF( kt == nit000 ) THEN
392	IF(lwp) WRITE(numout,*)
393	IF(lwp) WRITE(numout,*) 'dyn:hpg_sco : hydrostatic pressure gradient trend'
394	IF(lwp) WRITE(numout,*) '~~~~~~~~~~~ s-coordinate case, OPA original scheme used'
395	ENDIF
396
397	! Local constant initialization
398	zcoef0 = - grav * 0.5_wp
399	! To use density and not density anomaly
400	IF ( lk_vvl ) THEN ; znad = 1._wp ! Variable volume
401	ELSE ; znad = 0._wp ! Fixed volume
402	ENDIF
403
404	IF(ln_wd) THEN
405	DO jj = 2, jpjm1
406	DO ji = 2, jpim1
407	ll_tmp1 = MIN(sshn(ji,jj), sshn(ji+1,jj)) > MAX(-bathy(ji,jj), -bathy(ji+1,jj))
408	ll_tmp2 = MAX(sshn(ji,jj) + bathy(ji,jj), sshn(ji+1,jj) + bathy(ji+1,jj)) > rn_wdmin1 + rn_wdmin2
409	ll_tmp3 = MAX(sshn(ji,jj), sshn(ji+1,jj)) > MAX(-bathy(ji,jj), -bathy(ji+1,jj)) + &
410	& rn_wdmin1 + rn_wdmin2
411
412	IF(ll_tmp1.AND.ll_tmp2) THEN
413	zcpx(ji,jj) = 1.0_wp
414	wduflt(ji,jj) = 1.0_wp
415	ELSE IF(ll_tmp3) THEN
416	! no worries about sshn(ji+1,jj)-sshn(ji,jj) = 0, it won't happen ! here
417	zcpx(ji,jj) = ABS((sshn(ji+1,jj) + bathy(ji+1,jj) - sshn(ji,jj) - bathy(ji,jj)) / &
418	& (sshn(ji+1,jj) - sshn(ji,jj)))
419	wduflt(ji,jj) = 1.0_wp
420	ELSE
421	zcpx(ji,jj) = 0._wp
422	wduflt(ji,jj) = 0.0_wp
423	END IF
424
425	ll_tmp1 = MIN(sshn(ji,jj), sshn(ji,jj+1)) > MAX(-bathy(ji,jj), -bathy(ji,jj+1))
426	ll_tmp2 = MAX(sshn(ji,jj) + bathy(ji,jj), sshn(ji,jj+1) + bathy(ji,jj+1)) > rn_wdmin1 + rn_wdmin2
427	ll_tmp3 = MAX(sshn(ji,jj), sshn(ji,jj+1)) > MAX(-bathy(ji,jj), -bathy(ji,jj+1)) + &
428	& rn_wdmin1 + rn_wdmin2
429
430	IF(ll_tmp1.AND.ll_tmp2) THEN
431	zcpy(ji,jj) = 1.0_wp
432	wdvflt(ji,jj) = 1.0_wp
433	ELSE IF(ll_tmp3) THEN
434	! no worries about sshn(ji,jj+1)-sshn(ji,jj) = 0, it won't happen ! here
435	zcpy(ji,jj) = ABS((sshn(ji,jj+1) + bathy(ji,jj+1) - sshn(ji,jj) - bathy(ji,jj)) / &
436	& (sshn(ji,jj+1) - sshn(ji,jj)))
437	wdvflt(ji,jj) = 1.0_wp
438	ELSE
439	zcpy(ji,jj) = 0._wp
440	wdvflt(ji,jj) = 0.0_wp
441	END IF
442	END DO
443	END DO
444	CALL lbc_lnk( zcpx, 'U', 1._wp ) ; CALL lbc_lnk( zcpy, 'V', 1._wp )
445	ENDIF
446
447
448	!jii=jidbg-nimpp+1;jjj=jjdbg-njmpp+1
449
450	! Surface value
451	DO jj = 2, jpjm1
452	DO ji = fs_2, fs_jpim1 ! vector opt.
453	! hydrostatic pressure gradient along s-surfaces
454	zhpi(ji,jj,1) = zcoef0 / e1u(ji,jj) * ( fse3w(ji+1,jj ,1) * ( znad + rhd(ji+1,jj ,1) ) &
455	& - fse3w(ji ,jj ,1) * ( znad + rhd(ji ,jj ,1) ) )
456	zhpj(ji,jj,1) = zcoef0 / e2v(ji,jj) * ( fse3w(ji ,jj+1,1) * ( znad + rhd(ji ,jj+1,1) ) &
457	& - fse3w(ji ,jj ,1) * ( znad + rhd(ji ,jj ,1) ) )
458	! s-coordinate pressure gradient correction
459	zuap = -zcoef0 * ( rhd (ji+1,jj,1) + rhd (ji,jj,1) + 2._wp * znad ) &
460	& * ( fsde3w(ji+1,jj,1) - fsde3w(ji,jj,1) ) / e1u(ji,jj)
461	zvap = -zcoef0 * ( rhd (ji,jj+1,1) + rhd (ji,jj,1) + 2._wp * znad ) &
462	& * ( fsde3w(ji,jj+1,1) - fsde3w(ji,jj,1) ) / e2v(ji,jj)
463
464
465	IF(ln_wd) THEN
466
467	zhpi(ji,jj,1) = zhpi(ji,jj,1) * zcpx(ji,jj)
468	zhpj(ji,jj,1) = zhpj(ji,jj,1) * zcpy(ji,jj)
469	zuap = zuap * zcpx(ji,jj)
470	zvap = zvap * zcpy(ji,jj)
471	ENDIF
472
473	! add to the general momentum trend
474	ua(ji,jj,1) = ua(ji,jj,1) + zhpi(ji,jj,1) + zuap
475	va(ji,jj,1) = va(ji,jj,1) + zhpj(ji,jj,1) + zvap
476	END DO
477	END DO
478
479	! interior value (2=<jk=<jpkm1)
480	DO jk = 2, jpkm1
481	DO jj = 2, jpjm1
482	DO ji = fs_2, fs_jpim1 ! vector opt.
483	! hydrostatic pressure gradient along s-surfaces
484	zhpi(ji,jj,jk) = zhpi(ji,jj,jk-1) + zcoef0 / e1u(ji,jj) &
485	& * ( fse3w(ji+1,jj,jk) * ( rhd(ji+1,jj,jk) + rhd(ji+1,jj,jk-1) + 2*znad ) &
486	& - fse3w(ji ,jj,jk) * ( rhd(ji ,jj,jk) + rhd(ji ,jj,jk-1) + 2*znad ) )
487	zhpj(ji,jj,jk) = zhpj(ji,jj,jk-1) + zcoef0 / e2v(ji,jj) &
488	& * ( fse3w(ji,jj+1,jk) * ( rhd(ji,jj+1,jk) + rhd(ji,jj+1,jk-1) + 2*znad ) &
489	& - fse3w(ji,jj ,jk) * ( rhd(ji,jj, jk) + rhd(ji,jj ,jk-1) + 2*znad ) )
490	! s-coordinate pressure gradient correction
491	zuap = -zcoef0 * ( rhd (ji+1,jj ,jk) + rhd (ji,jj,jk) + 2._wp * znad ) &
492	& * ( fsde3w(ji+1,jj ,jk) - fsde3w(ji,jj,jk) ) / e1u(ji,jj)
493	zvap = -zcoef0 * ( rhd (ji ,jj+1,jk) + rhd (ji,jj,jk) + 2._wp * znad ) &
494	& * ( fsde3w(ji ,jj+1,jk) - fsde3w(ji,jj,jk) ) / e2v(ji,jj)
495
496	IF(ln_wd) THEN
497	zhpi(ji,jj,jk) = zhpi(ji,jj,jk) * zcpx(ji,jj)
498	zhpj(ji,jj,jk) = zhpj(ji,jj,jk) * zcpy(ji,jj)
499	zuap = zuap * zcpx(ji,jj)
500	zvap = zvap * zcpy(ji,jj)
501	ENDIF
502
503	! add to the general momentum trend
504	ua(ji,jj,jk) = ua(ji,jj,jk) + zhpi(ji,jj,jk) + zuap
505	va(ji,jj,jk) = va(ji,jj,jk) + zhpj(ji,jj,jk) + zvap
506	END DO
507	END DO
508	END DO
509	!
510	CALL wrk_dealloc( jpi,jpj,jpk, zhpi, zhpj )
511	IF(ln_wd) CALL wrk_dealloc( jpi,jpj, zcpx, zcpy )
512	!
513	END SUBROUTINE hpg_sco
514
515	SUBROUTINE hpg_isf( kt )
516	!!---------------------------------------------------------------------
517	!! * ROUTINE hpg_sco *
518	!!
519	!! ** Method : s-coordinate case. Jacobian scheme.
520	!! The now hydrostatic pressure gradient at a given level, jk,
521	!! is computed by taking the vertical integral of the in-situ
522	!! density gradient along the model level from the suface to that
523	!! level. s-coordinates (ln_sco): a corrective term is added
524	!! to the horizontal pressure gradient :
525	!! zhpi = grav ..... + 1/e1u mi(rhd) di[ grav dep3w ]
526	!! zhpj = grav ..... + 1/e2v mj(rhd) dj[ grav dep3w ]
527	!! add it to the general momentum trend (ua,va).
528	!! ua = ua - 1/e1u * zhpi
529	!! va = va - 1/e2v * zhpj
530	!! iceload is added and partial cell case are added to the top and bottom
531	!!
532	!! ** Action : - Update (ua,va) with the now hydrastatic pressure trend
533	!!----------------------------------------------------------------------
534	INTEGER, INTENT(in) :: kt ! ocean time-step index
535	!!
536	INTEGER :: ji, jj, jk, iku, ikv, ikt, iktp1i, iktp1j ! dummy loop indices
537	REAL(wp) :: zcoef0, zuap, zvap, znad, ze3wu, ze3wv, zuapint, zvapint, zhpjint, zhpiint, zdzwt, zdzwtjp1, zdzwtip1 ! temporary scalars
538	REAL(wp), POINTER, DIMENSION(:,:,:) :: zhpi, zhpj, zrhd
539	REAL(wp), POINTER, DIMENSION(:,:,:) :: ztstop
540	REAL(wp), POINTER, DIMENSION(:,:) :: ze3w, zp, zrhdtop_isf, zrhdtop_oce, ziceload, zdept, zpshpi, zpshpj
541	!!----------------------------------------------------------------------
542	!
543	CALL wrk_alloc( jpi,jpj, 2, ztstop)
544	CALL wrk_alloc( jpi,jpj,jpk, zhpi, zhpj, zrhd)
545	CALL wrk_alloc( jpi,jpj, ze3w, zp, zrhdtop_isf, zrhdtop_oce, ziceload, zdept, zpshpi, zpshpj)
546	!
547	IF( kt == nit000 ) THEN
548	IF(lwp) WRITE(numout,*)
549	IF(lwp) WRITE(numout,*) 'dyn:hpg_isf : hydrostatic pressure gradient trend for ice shelf'
550	IF(lwp) WRITE(numout,*) '~~~~~~~~~~~ s-coordinate case, OPA original scheme used'
551	ENDIF
552
553	! Local constant initialization
554	zcoef0 = - grav * 0.5_wp
555	! To use density and not density anomaly
556	! IF ( lk_vvl ) THEN ; znad = 1._wp ! Variable volume
557	! ELSE ; znad = 0._wp ! Fixed volume
558	! ENDIF
559	znad=1._wp
560	! iniitialised to 0. zhpi zhpi
561	zhpi(:,:,:)=0._wp ; zhpj(:,:,:)=0._wp
562
563	!==================================================================================
564	!=====Compute iceload and contribution of the half first wet layer =================
565	!===================================================================================
566
567	! assume water displaced by the ice shelf is at T=-1.9 and S=34.4 (rude)
568	ztstop(:,:,1)=-1.9_wp ; ztstop(:,:,2)=34.4_wp
569
570	! compute density of the water displaced by the ice shelf
571	zrhd = rhd ! save rhd
572	DO jk = 1, jpk
573	zdept(:,:)=gdept_1d(jk)
574	CALL eos(ztstop(:,:,:),zdept(:,:),rhd(:,:,jk))
575	END DO
576	WHERE ( tmask(:,:,:) == 1._wp)
577	rhd(:,:,:) = zrhd(:,:,:) ! replace wet cell by the saved rhd
578	END WHERE
579
580	! compute rhd at the ice/oce interface (ice shelf side)
581	CALL eos(ztstop,risfdep,zrhdtop_isf)
582
583	! compute rhd at the ice/oce interface (ocean side)
584	DO ji=1,jpi
585	DO jj=1,jpj
586	ikt=mikt(ji,jj)
587	ztstop(ji,jj,1)=tsn(ji,jj,ikt,1)
588	ztstop(ji,jj,2)=tsn(ji,jj,ikt,2)
589	END DO
590	END DO
591	CALL eos(ztstop,risfdep,zrhdtop_oce)
592	!
593	! Surface value + ice shelf gradient
594	! compute pressure due to ice shelf load (used to compute hpgi/j for all the level from 1 to miku/v)
595	ziceload = 0._wp
596	DO jj = 1, jpj
597	DO ji = 1, jpi ! vector opt.
598	ikt=mikt(ji,jj)
599	ziceload(ji,jj) = ziceload(ji,jj) + (znad + rhd(ji,jj,1) ) * fse3w(ji,jj,1) * (1._wp - tmask(ji,jj,1))
600	DO jk=2,ikt-1
601	ziceload(ji,jj) = ziceload(ji,jj) + (2._wp * znad + rhd(ji,jj,jk-1) + rhd(ji,jj,jk)) * fse3w(ji,jj,jk) &
602	& * (1._wp - tmask(ji,jj,jk))
603	END DO
604	IF (ikt .GE. 2) ziceload(ji,jj) = ziceload(ji,jj) + (2._wp * znad + zrhdtop_isf(ji,jj) + rhd(ji,jj,ikt-1)) &
605	& * ( risfdep(ji,jj) - gdept_1d(ikt-1) )
606	END DO
607	END DO
608	riceload(:,:) = 0.0_wp ; riceload(:,:)=ziceload(:,:) ! need to be saved for diaar5
609	! compute zp from z=0 to first T wet point (correction due to zps not yet applied)
610	DO jj = 2, jpjm1
611	DO ji = fs_2, fs_jpim1 ! vector opt.
612	ikt=mikt(ji,jj) ; iktp1i=mikt(ji+1,jj); iktp1j=mikt(ji,jj+1)
613	! hydrostatic pressure gradient along s-surfaces and ice shelf pressure
614	! we assume ISF is in isostatic equilibrium
615	zhpi(ji,jj,1) = zcoef0 / e1u(ji,jj) * ( 0.5_wp * fse3w(ji+1,jj ,iktp1i) &
616	& * ( 2._wp * znad + rhd(ji+1,jj ,iktp1i) + zrhdtop_oce(ji+1,jj ) ) &
617	& - 0.5_wp * fse3w(ji ,jj ,ikt ) &
618	& * ( 2._wp * znad + rhd(ji ,jj ,ikt ) + zrhdtop_oce(ji ,jj ) ) &
619	& + ( ziceload(ji+1,jj) - ziceload(ji,jj)) )
620	zhpj(ji,jj,1) = zcoef0 / e2v(ji,jj) * ( 0.5_wp * fse3w(ji ,jj+1,iktp1j) &
621	& * ( 2._wp * znad + rhd(ji ,jj+1,iktp1j) + zrhdtop_oce(ji ,jj+1) ) &
622	& - 0.5_wp * fse3w(ji ,jj ,ikt ) &
623	& * ( 2._wp * znad + rhd(ji ,jj ,ikt ) + zrhdtop_oce(ji ,jj ) ) &
624	& + ( ziceload(ji,jj+1) - ziceload(ji,jj) ) )
625	! s-coordinate pressure gradient correction (=0 if z coordinate)
626	zuap = -zcoef0 * ( rhd (ji+1,jj,1) + rhd (ji,jj,1) + 2._wp * znad ) &
627	& * ( fsde3w(ji+1,jj,1) - fsde3w(ji,jj,1) ) / e1u(ji,jj)
628	zvap = -zcoef0 * ( rhd (ji,jj+1,1) + rhd (ji,jj,1) + 2._wp * znad ) &
629	& * ( fsde3w(ji,jj+1,1) - fsde3w(ji,jj,1) ) / e2v(ji,jj)
630	! add to the general momentum trend
631	ua(ji,jj,1) = ua(ji,jj,1) + (zhpi(ji,jj,1) + zuap) * umask(ji,jj,1)
632	va(ji,jj,1) = va(ji,jj,1) + (zhpj(ji,jj,1) + zvap) * vmask(ji,jj,1)
633	END DO
634	END DO
635	!==================================================================================
636	!===== Compute partial cell contribution for the top cell =========================
637	!==================================================================================
638	DO jj = 2, jpjm1
639	DO ji = fs_2, fs_jpim1 ! vector opt.
640	iku = miku(ji,jj) ;
641	zpshpi(ji,jj)=0.0_wp ; zpshpj(ji,jj)=0.0_wp
642	ze3wu = (gdepw_0(ji+1,jj,iku+1) - gdept_0(ji+1,jj,iku)) - (gdepw_0(ji,jj,iku+1) - gdept_0(ji,jj,iku))
643	! u direction
644	IF ( iku .GT. 1 ) THEN
645	! case iku
646	zhpi(ji,jj,iku) = zcoef0 / e1u(ji,jj) * ze3wu &
647	& * ( rhd (ji+1,jj,iku) + rhd (ji,jj,iku) &
648	& + SIGN(1._wp,ze3wu) * grui(ji,jj) + 2._wp * znad )
649	! corrective term ( = 0 if z coordinate )
650	zuap = -zcoef0 * ( arui(ji,jj) + 2._wp * znad ) * gzui(ji,jj) / e1u(ji,jj)
651	! zhpi will be added in interior loop
652	ua(ji,jj,iku) = ua(ji,jj,iku) + zuap
653	! in case of 2 cell water column, need to save the pressure gradient to compute the bottom pressure
654	IF (mbku(ji,jj) == iku + 1) zpshpi(ji,jj) = zhpi(ji,jj,iku)
655
656	! case iku + 1 (remove the zphi term added in the interior loop and compute the one corrected for zps)
657	zhpiint = zcoef0 / e1u(ji,jj) &
658	& * ( fse3w(ji+1,jj ,iku+1) * ( (rhd(ji+1,jj,iku+1) + znad) &
659	& + (rhd(ji+1,jj,iku ) + znad) ) * tmask(ji+1,jj,iku) &
660	& - fse3w(ji ,jj ,iku+1) * ( (rhd(ji ,jj,iku+1) + znad) &
661	& + (rhd(ji ,jj,iku ) + znad) ) * tmask(ji ,jj,iku) )
662	zhpi(ji,jj,iku+1) = zcoef0 / e1u(ji,jj) * ge3rui(ji,jj) - zhpiint
663	END IF
664
665	! v direction
666	ikv = mikv(ji,jj)
667	ze3wv = (gdepw_0(ji,jj+1,ikv+1) - gdept_0(ji,jj+1,ikv)) - (gdepw_0(ji,jj,ikv+1) - gdept_0(ji,jj,ikv))
668	IF ( ikv .GT. 1 ) THEN
669	! case ikv
670	zhpj(ji,jj,ikv) = zcoef0 / e2v(ji,jj) * ze3wv &
671	& * ( rhd(ji,jj+1,ikv) + rhd (ji,jj,ikv) &
672	& + SIGN(1._wp,ze3wv) * grvi(ji,jj) + 2._wp * znad )
673	! corrective term ( = 0 if z coordinate )
674	zvap = -zcoef0 * ( arvi(ji,jj) + 2._wp * znad ) * gzvi(ji,jj) / e2v(ji,jj)
675	! zhpi will be added in interior loop
676	va(ji,jj,ikv) = va(ji,jj,ikv) + zvap
677	! in case of 2 cell water column, need to save the pressure gradient to compute the bottom pressure
678	IF (mbkv(ji,jj) == ikv + 1) zpshpj(ji,jj) = zhpj(ji,jj,ikv)
679
680	! case ikv + 1 (remove the zphj term added in the interior loop and compute the one corrected for zps)
681	zhpjint = zcoef0 / e2v(ji,jj) &
682	& * ( fse3w(ji ,jj+1,ikv+1) * ( (rhd(ji,jj+1,ikv+1) + znad) &
683	& + (rhd(ji,jj+1,ikv ) + znad) ) * tmask(ji,jj+1,ikv) &
684	& - fse3w(ji ,jj ,ikv+1) * ( (rhd(ji,jj ,ikv+1) + znad) &
685	& + (rhd(ji,jj ,ikv ) + znad) ) * tmask(ji,jj ,ikv) )
686	zhpj(ji,jj,ikv+1) = zcoef0 / e2v(ji,jj) * ge3rvi(ji,jj) - zhpjint
687	END IF
688	END DO
689	END DO
690
691	!==================================================================================
692	!===== Compute interior value =====================================================
693	!==================================================================================
694
695	DO jj = 2, jpjm1
696	DO ji = fs_2, fs_jpim1 ! vector opt.
697	iku=miku(ji,jj); ikv=mikv(ji,jj)
698	DO jk = 2, jpkm1
699	! hydrostatic pressure gradient along s-surfaces
700	! zhpi is masked for the first wet cell (contribution already done in the upper bloc)
701	zhpi(ji,jj,jk) = zhpi(ji,jj,jk) + zhpi(ji,jj,jk-1) &
702	& + zcoef0 / e1u(ji,jj) &
703	& * ( fse3w(ji+1,jj ,jk) * ( (rhd(ji+1,jj,jk ) + znad) &
704	& + (rhd(ji+1,jj,jk-1) + znad) ) * tmask(ji+1,jj,jk-1) &
705	& - fse3w(ji ,jj ,jk) * ( (rhd(ji ,jj,jk ) + znad) &
706	& + (rhd(ji ,jj,jk-1) + znad) ) * tmask(ji ,jj,jk-1) )
707	! s-coordinate pressure gradient correction
708	! corrective term, we mask this term for the first wet level beneath the ice shelf (contribution done in the upper bloc)
709	zuap = - zcoef0 * ( rhd (ji+1,jj ,jk) + rhd (ji,jj,jk) + 2._wp * znad ) &
710	& * ( fsde3w(ji+1,jj ,jk) - fsde3w(ji,jj,jk) ) / e1u(ji,jj) * umask(ji,jj,jk-1)
711	ua(ji,jj,jk) = ua(ji,jj,jk) + ( zhpi(ji,jj,jk) + zuap) * umask(ji,jj,jk)
712
713	! hydrostatic pressure gradient along s-surfaces
714	! zhpi is masked for the first wet cell (contribution already done in the upper bloc)
715	zhpj(ji,jj,jk) = zhpj(ji,jj,jk) + zhpj(ji,jj,jk-1) &
716	& + zcoef0 / e2v(ji,jj) &
717	& * ( fse3w(ji ,jj+1,jk) * ( (rhd(ji,jj+1,jk ) + znad) &
718	& + (rhd(ji,jj+1,jk-1) + znad) ) * tmask(ji,jj+1,jk-1) &
719	& - fse3w(ji ,jj ,jk) * ( (rhd(ji,jj ,jk ) + znad) &
720	& + (rhd(ji,jj ,jk-1) + znad) ) * tmask(ji,jj ,jk-1) )
721	! s-coordinate pressure gradient correction
722	! corrective term, we mask this term for the first wet level beneath the ice shelf (contribution done in the upper bloc)
723	zvap = - zcoef0 * ( rhd (ji ,jj+1,jk) + rhd (ji,jj,jk) + 2._wp * znad ) &
724	& * ( fsde3w(ji ,jj+1,jk) - fsde3w(ji,jj,jk) ) / e2v(ji,jj) * vmask(ji,jj,jk-1)
725	! add to the general momentum trend
726	va(ji,jj,jk) = va(ji,jj,jk) + ( zhpj(ji,jj,jk) + zvap ) * vmask(ji,jj,jk)
727	END DO
728	END DO
729	END DO
730
731	!==================================================================================
732	!===== Compute bottom cell contribution (partial cell) ============================
733	!==================================================================================
734
735	DO jj = 2, jpjm1
736	DO ji = 2, jpim1
737	iku = mbku(ji,jj)
738	ikv = mbkv(ji,jj)
739
740	IF (iku .GT. 1) THEN
741	! remove old value (interior case)
742	zuap = -zcoef0 * ( rhd (ji+1,jj ,iku) + rhd (ji,jj,iku) + 2._wp * znad ) &
743	& * ( fsde3w(ji+1,jj ,iku) - fsde3w(ji,jj,iku) ) / e1u(ji,jj)
744	ua(ji,jj,iku) = ua(ji,jj,iku) - zhpi(ji,jj,iku) - zuap
745	! put new value
746	! -zpshpi to avoid double contribution of the partial step in the top layer
747	zuap = -zcoef0 * ( aru(ji,jj) + 2._wp * znad ) * gzu(ji,jj) / e1u(ji,jj)
748	zhpi(ji,jj,iku) = zhpi(ji,jj,iku-1) + zcoef0 / e1u(ji,jj) * ge3ru(ji,jj) - zpshpi(ji,jj)
749	ua(ji,jj,iku) = ua(ji,jj,iku) + zhpi(ji,jj,iku) + zuap
750	END IF
751	! v direction
752	IF (ikv .GT. 1) THEN
753	! remove old value (interior case)
754	zvap = -zcoef0 * ( rhd (ji ,jj+1,ikv) + rhd (ji,jj,ikv) + 2._wp * znad ) &
755	& * ( fsde3w(ji ,jj+1,ikv) - fsde3w(ji,jj,ikv) ) / e2v(ji,jj)
756	va(ji,jj,ikv) = va(ji,jj,ikv) - zhpj(ji,jj,ikv) - zvap
757	! put new value
758	! -zpshpj to avoid double contribution of the partial step in the top layer
759	zvap = -zcoef0 * ( arv(ji,jj) + 2._wp * znad ) * gzv(ji,jj) / e2v(ji,jj)
760	zhpj(ji,jj,ikv) = zhpj(ji,jj,ikv-1) + zcoef0 / e2v(ji,jj) * ge3rv(ji,jj) - zpshpj(ji,jj)
761	va(ji,jj,ikv) = va(ji,jj,ikv) + zhpj(ji,jj,ikv) + zvap
762	END IF
763	END DO
764	END DO
765
766	! set back to original density value into the ice shelf cell (maybe useless because it is masked)
767	rhd = zrhd
768	!
769	CALL wrk_dealloc( jpi,jpj,2, ztstop)
770	CALL wrk_dealloc( jpi,jpj,jpk, zhpi, zhpj, zrhd)
771	CALL wrk_dealloc( jpi,jpj, ze3w, zp, zrhdtop_isf, zrhdtop_oce, ziceload, zdept, zpshpi, zpshpj)
772	!
773	END SUBROUTINE hpg_isf
774
775
776	SUBROUTINE hpg_djc( kt )
777	!!---------------------------------------------------------------------
778	!! * ROUTINE hpg_djc *
779	!!
780	!! ** Method : Density Jacobian with Cubic polynomial scheme
781	!!
782	!! Reference: Shchepetkin and McWilliams, J. Geophys. Res., 108(C3), 3090, 2003
783	!!----------------------------------------------------------------------
784	INTEGER, INTENT(in) :: kt ! ocean time-step index
785	!!
786	INTEGER :: ji, jj, jk ! dummy loop indices
787	REAL(wp) :: zcoef0, zep, cffw ! temporary scalars
788	REAL(wp) :: z1_10, cffu, cffx ! " "
789	REAL(wp) :: z1_12, cffv, cffy ! " "
790	LOGICAL :: ll_tmp1, ll_tmp2 ! local logical variables
791	REAL(wp), POINTER, DIMENSION(:,:,:) :: zhpi, zhpj
792	REAL(wp), POINTER, DIMENSION(:,:,:) :: dzx, dzy, dzz, dzu, dzv, dzw
793	REAL(wp), POINTER, DIMENSION(:,:,:) :: drhox, drhoy, drhoz, drhou, drhov, drhow
794	REAL(wp), POINTER, DIMENSION(:,:,:) :: rho_i, rho_j, rho_k
795	REAL(wp), POINTER, DIMENSION(:,:) :: zcpx, zcpy !W/D pressure filter
796	!!----------------------------------------------------------------------
797	!
798	CALL wrk_alloc( jpi, jpj, jpk, dzx , dzy , dzz , dzu , dzv , dzw )
799	CALL wrk_alloc( jpi, jpj, jpk, drhox, drhoy, drhoz, drhou, drhov, drhow )
800	CALL wrk_alloc( jpi, jpj, jpk, rho_i, rho_j, rho_k, zhpi, zhpj )
801	IF(ln_wd) CALL wrk_alloc( jpi,jpj, zcpx, zcpy )
802	!
803	!!----------------------------------------------------------------------
804	!
805	!
806	IF(ln_wd) THEN
807	DO jj = 2, jpjm1
808	DO ji = 2, jpim1
809	ll_tmp1 = MIN(sshn(ji,jj), sshn(ji+1,jj)) > MAX(-bathy(ji,jj), -bathy(ji+1,jj)) &
810	& .and. MAX(sshn(ji,jj) + bathy(ji,jj), sshn(ji+1,jj) + bathy(ji+1,jj)) &
811	& > rn_wdmin1 + rn_wdmin2
812	ll_tmp2 = MAX(sshn(ji,jj), sshn(ji+1,jj)) > MAX(-bathy(ji,jj), -bathy(ji+1,jj)) +&
813	& rn_wdmin1 + rn_wdmin2
814
815	IF(ll_tmp1) THEN
816	zcpx(ji,jj) = 1.0_wp
817	ELSE IF(ll_tmp2) THEN
818	! no worries about sshn(ji+1,jj)-sshn(ji,jj) = 0, it won't happen ! here
819	zcpx(ji,jj) = ABS((sshn(ji+1,jj) + bathy(ji+1,jj) - sshn(ji,jj) - bathy(ji,jj)) /&
820	& (sshn(ji+1,jj) - sshn(ji,jj)))
821	ELSE
822	zcpx(ji,jj) = 0._wp
823	END IF
824
825	ll_tmp1 = MIN(sshn(ji,jj), sshn(ji,jj+1)) > MAX(-bathy(ji,jj), -bathy(ji,jj+1)) &
826	& .and. MAX(sshn(ji,jj) + bathy(ji,jj), sshn(ji,jj+1) + bathy(ji,jj+1)) &
827	& > rn_wdmin1 + rn_wdmin2
828	ll_tmp2 = MAX(sshn(ji,jj), sshn(ji,jj+1)) > MAX(-bathy(ji,jj), -bathy(ji,jj+1)) +&
829	& rn_wdmin1 + rn_wdmin2
830
831	IF(ll_tmp1) THEN
832	zcpy(ji,jj) = 1.0_wp
833	ELSE IF(ll_tmp2) THEN
834	! no worries about sshn(ji,jj+1)-sshn(ji,jj) = 0, it won't happen ! here
835	zcpy(ji,jj) = ABS((sshn(ji,jj+1) + bathy(ji,jj+1) - sshn(ji,jj) - bathy(ji,jj)) /&
836	& (sshn(ji,jj+1) - sshn(ji,jj)))
837	ELSE
838	zcpy(ji,jj) = 0._wp
839	END IF
840	END DO
841	END DO
842	CALL lbc_lnk( zcpx, 'U', 1._wp ) ; CALL lbc_lnk( zcpy, 'V', 1._wp )
843	ENDIF
844
845
846	IF( kt == nit000 ) THEN
847	IF(lwp) WRITE(numout,*)
848	IF(lwp) WRITE(numout,*) 'dyn:hpg_djc : hydrostatic pressure gradient trend'
849	IF(lwp) WRITE(numout,*) '~~~~~~~~~~~ s-coordinate case, density Jacobian with cubic polynomial scheme'
850	ENDIF
851
852	! Local constant initialization
853	zcoef0 = - grav * 0.5_wp
854	z1_10 = 1._wp / 10._wp
855	z1_12 = 1._wp / 12._wp
856
857	!----------------------------------------------------------------------------------------
858	! compute and store in provisional arrays elementary vertical and horizontal differences
859	!----------------------------------------------------------------------------------------
860
861	!!bug gm Not a true bug, but... dzz=e3w for dzx, dzy verify what it is really
862
863	DO jk = 2, jpkm1
864	DO jj = 2, jpjm1
865	DO ji = fs_2, fs_jpim1 ! vector opt.
866	drhoz(ji,jj,jk) = rhd (ji ,jj ,jk) - rhd (ji,jj,jk-1)
867	dzz (ji,jj,jk) = fsde3w(ji ,jj ,jk) - fsde3w(ji,jj,jk-1)
868	drhox(ji,jj,jk) = rhd (ji+1,jj ,jk) - rhd (ji,jj,jk )
869	dzx (ji,jj,jk) = fsde3w(ji+1,jj ,jk) - fsde3w(ji,jj,jk )
870	drhoy(ji,jj,jk) = rhd (ji ,jj+1,jk) - rhd (ji,jj,jk )
871	dzy (ji,jj,jk) = fsde3w(ji ,jj+1,jk) - fsde3w(ji,jj,jk )
872	END DO
873	END DO
874	END DO
875
876	!-------------------------------------------------------------------------
877	! compute harmonic averages using eq. 5.18
878	!-------------------------------------------------------------------------
879	zep = 1.e-15
880
881	!!bug gm drhoz not defined at level 1 and used (jk-1 with jk=2)
882	!!bug gm idem for drhox, drhoy et ji=jpi and jj=jpj
883
884	DO jk = 2, jpkm1
885	DO jj = 2, jpjm1
886	DO ji = fs_2, fs_jpim1 ! vector opt.
887	cffw = 2._wp * drhoz(ji ,jj ,jk) * drhoz(ji,jj,jk-1)
888
889	cffu = 2._wp * drhox(ji+1,jj ,jk) * drhox(ji,jj,jk )
890	cffx = 2._wp * dzx (ji+1,jj ,jk) * dzx (ji,jj,jk )
891
892	cffv = 2._wp * drhoy(ji ,jj+1,jk) * drhoy(ji,jj,jk )
893	cffy = 2._wp * dzy (ji ,jj+1,jk) * dzy (ji,jj,jk )
894
895	IF( cffw > zep) THEN
896	drhow(ji,jj,jk) = 2._wp * drhoz(ji,jj,jk) * drhoz(ji,jj,jk-1) &
897	& / ( drhoz(ji,jj,jk) + drhoz(ji,jj,jk-1) )
898	ELSE
899	drhow(ji,jj,jk) = 0._wp
900	ENDIF
901
902	dzw(ji,jj,jk) = 2._wp * dzz(ji,jj,jk) * dzz(ji,jj,jk-1) &
903	& / ( dzz(ji,jj,jk) + dzz(ji,jj,jk-1) )
904
905	IF( cffu > zep ) THEN
906	drhou(ji,jj,jk) = 2._wp * drhox(ji+1,jj,jk) * drhox(ji,jj,jk) &
907	& / ( drhox(ji+1,jj,jk) + drhox(ji,jj,jk) )
908	ELSE
909	drhou(ji,jj,jk ) = 0._wp
910	ENDIF
911
912	IF( cffx > zep ) THEN
913	dzu(ji,jj,jk) = 2._wp * dzx(ji+1,jj,jk) * dzx(ji,jj,jk) &
914	& / ( dzx(ji+1,jj,jk) + dzx(ji,jj,jk) )
915	ELSE
916	dzu(ji,jj,jk) = 0._wp
917	ENDIF
918
919	IF( cffv > zep ) THEN
920	drhov(ji,jj,jk) = 2._wp * drhoy(ji,jj+1,jk) * drhoy(ji,jj,jk) &
921	& / ( drhoy(ji,jj+1,jk) + drhoy(ji,jj,jk) )
922	ELSE
923	drhov(ji,jj,jk) = 0._wp
924	ENDIF
925
926	IF( cffy > zep ) THEN
927	dzv(ji,jj,jk) = 2._wp * dzy(ji,jj+1,jk) * dzy(ji,jj,jk) &
928	& / ( dzy(ji,jj+1,jk) + dzy(ji,jj,jk) )
929	ELSE
930	dzv(ji,jj,jk) = 0._wp
931	ENDIF
932
933	END DO
934	END DO
935	END DO
936
937	!----------------------------------------------------------------------------------
938	! apply boundary conditions at top and bottom using 5.36-5.37
939	!----------------------------------------------------------------------------------
940	drhow(:,:, 1 ) = 1.5_wp * ( drhoz(:,:, 2 ) - drhoz(:,:, 1 ) ) - 0.5_wp * drhow(:,:, 2 )
941	drhou(:,:, 1 ) = 1.5_wp * ( drhox(:,:, 2 ) - drhox(:,:, 1 ) ) - 0.5_wp * drhou(:,:, 2 )
942	drhov(:,:, 1 ) = 1.5_wp * ( drhoy(:,:, 2 ) - drhoy(:,:, 1 ) ) - 0.5_wp * drhov(:,:, 2 )
943
944	drhow(:,:,jpk) = 1.5_wp * ( drhoz(:,:,jpk) - drhoz(:,:,jpkm1) ) - 0.5_wp * drhow(:,:,jpkm1)
945	drhou(:,:,jpk) = 1.5_wp * ( drhox(:,:,jpk) - drhox(:,:,jpkm1) ) - 0.5_wp * drhou(:,:,jpkm1)
946	drhov(:,:,jpk) = 1.5_wp * ( drhoy(:,:,jpk) - drhoy(:,:,jpkm1) ) - 0.5_wp * drhov(:,:,jpkm1)
947
948
949	!--------------------------------------------------------------
950	! Upper half of top-most grid box, compute and store
951	!-------------------------------------------------------------
952
953	!!bug gm : e3w-de3w = 0.5*e3w .... and de3w(2)-de3w(1)=e3w(2) .... to be verified
954	! true if de3w is really defined as the sum of the e3w scale factors as, it seems to me, it should be
955
956	DO jj = 2, jpjm1
957	DO ji = fs_2, fs_jpim1 ! vector opt.
958	rho_k(ji,jj,1) = -grav * ( fse3w(ji,jj,1) - fsde3w(ji,jj,1) ) &
959	& * ( rhd(ji,jj,1) &
960	& + 0.5_wp * ( rhd(ji,jj,2) - rhd(ji,jj,1) ) &
961	& * ( fse3w (ji,jj,1) - fsde3w(ji,jj,1) ) &
962	& / ( fsde3w(ji,jj,2) - fsde3w(ji,jj,1) ) )
963	END DO
964	END DO
965
966	!!bug gm : here also, simplification is possible
967	!!bug gm : optimisation: 1/10 and 1/12 the division should be done before the loop
968
969	DO jk = 2, jpkm1
970	DO jj = 2, jpjm1
971	DO ji = fs_2, fs_jpim1 ! vector opt.
972
973	rho_k(ji,jj,jk) = zcoef0 * ( rhd (ji,jj,jk) + rhd (ji,jj,jk-1) ) &
974	& * ( fsde3w(ji,jj,jk) - fsde3w(ji,jj,jk-1) ) &
975	& - grav * z1_10 * ( &
976	& ( drhow (ji,jj,jk) - drhow (ji,jj,jk-1) ) &
977	& * ( fsde3w(ji,jj,jk) - fsde3w(ji,jj,jk-1) - z1_12 * ( dzw (ji,jj,jk) + dzw (ji,jj,jk-1) ) ) &
978	& - ( dzw (ji,jj,jk) - dzw (ji,jj,jk-1) ) &
979	& * ( rhd (ji,jj,jk) - rhd (ji,jj,jk-1) - z1_12 * ( drhow(ji,jj,jk) + drhow(ji,jj,jk-1) ) ) &
980	& )
981
982	rho_i(ji,jj,jk) = zcoef0 * ( rhd (ji+1,jj,jk) + rhd (ji,jj,jk) ) &
983	& * ( fsde3w(ji+1,jj,jk) - fsde3w(ji,jj,jk) ) &
984	& - grav* z1_10 * ( &
985	& ( drhou (ji+1,jj,jk) - drhou (ji,jj,jk) ) &
986	& * ( fsde3w(ji+1,jj,jk) - fsde3w(ji,jj,jk) - z1_12 * ( dzu (ji+1,jj,jk) + dzu (ji,jj,jk) ) ) &
987	& - ( dzu (ji+1,jj,jk) - dzu (ji,jj,jk) ) &
988	& * ( rhd (ji+1,jj,jk) - rhd (ji,jj,jk) - z1_12 * ( drhou(ji+1,jj,jk) + drhou(ji,jj,jk) ) ) &
989	& )
990
991	rho_j(ji,jj,jk) = zcoef0 * ( rhd (ji,jj+1,jk) + rhd (ji,jj,jk) ) &
992	& * ( fsde3w(ji,jj+1,jk) - fsde3w(ji,jj,jk) ) &
993	& - grav* z1_10 * ( &
994	& ( drhov (ji,jj+1,jk) - drhov (ji,jj,jk) ) &
995	& * ( fsde3w(ji,jj+1,jk) - fsde3w(ji,jj,jk) - z1_12 * ( dzv (ji,jj+1,jk) + dzv (ji,jj,jk) ) ) &
996	& - ( dzv (ji,jj+1,jk) - dzv (ji,jj,jk) ) &
997	& * ( rhd (ji,jj+1,jk) - rhd (ji,jj,jk) - z1_12 * ( drhov(ji,jj+1,jk) + drhov(ji,jj,jk) ) ) &
998	& )
999
1000	END DO
1001	END DO
1002	END DO
1003	CALL lbc_lnk(rho_k,'W',1.)
1004	CALL lbc_lnk(rho_i,'U',1.)
1005	CALL lbc_lnk(rho_j,'V',1.)
1006
1007
1008	! ---------------
1009	! Surface value
1010	! ---------------
1011	DO jj = 2, jpjm1
1012	DO ji = fs_2, fs_jpim1 ! vector opt.
1013	zhpi(ji,jj,1) = ( rho_k(ji+1,jj ,1) - rho_k(ji,jj,1) - rho_i(ji,jj,1) ) / e1u(ji,jj)
1014	zhpj(ji,jj,1) = ( rho_k(ji ,jj+1,1) - rho_k(ji,jj,1) - rho_j(ji,jj,1) ) / e2v(ji,jj)
1015	IF(ln_wd) THEN
1016	zhpi(ji,jj,1) = zhpi(ji,jj,1) * zcpx(ji,jj)
1017	zhpj(ji,jj,1) = zhpj(ji,jj,1) * zcpy(ji,jj)
1018	ENDIF
1019	! add to the general momentum trend
1020	ua(ji,jj,1) = ua(ji,jj,1) + zhpi(ji,jj,1)
1021	va(ji,jj,1) = va(ji,jj,1) + zhpj(ji,jj,1)
1022	END DO
1023	END DO
1024
1025	! ----------------
1026	! interior value (2=<jk=<jpkm1)
1027	! ----------------
1028	DO jk = 2, jpkm1
1029	DO jj = 2, jpjm1
1030	DO ji = fs_2, fs_jpim1 ! vector opt.
1031	! hydrostatic pressure gradient along s-surfaces
1032	zhpi(ji,jj,jk) = zhpi(ji,jj,jk-1) &
1033	& + ( ( rho_k(ji+1,jj,jk) - rho_k(ji,jj,jk ) ) &
1034	& - ( rho_i(ji ,jj,jk) - rho_i(ji,jj,jk-1) ) ) / e1u(ji,jj)
1035	zhpj(ji,jj,jk) = zhpj(ji,jj,jk-1) &
1036	& + ( ( rho_k(ji,jj+1,jk) - rho_k(ji,jj,jk ) ) &
1037	& -( rho_j(ji,jj ,jk) - rho_j(ji,jj,jk-1) ) ) / e2v(ji,jj)
1038	IF(ln_wd) THEN
1039	zhpi(ji,jj,jk) = zhpi(ji,jj,jk) * zcpx(ji,jj)
1040	zhpj(ji,jj,jk) = zhpj(ji,jj,jk) * zcpy(ji,jj)
1041	ENDIF
1042	! add to the general momentum trend
1043	ua(ji,jj,jk) = ua(ji,jj,jk) + zhpi(ji,jj,jk)
1044	va(ji,jj,jk) = va(ji,jj,jk) + zhpj(ji,jj,jk)
1045	END DO
1046	END DO
1047	END DO
1048	!
1049	CALL wrk_dealloc( jpi, jpj, jpk, dzx , dzy , dzz , dzu , dzv , dzw )
1050	CALL wrk_dealloc( jpi, jpj, jpk, drhox, drhoy, drhoz, drhou, drhov, drhow )
1051	CALL wrk_dealloc( jpi, jpj, jpk, rho_i, rho_j, rho_k, zhpi, zhpj )
1052	IF(ln_wd) CALL wrk_dealloc( jpi,jpj, zcpx, zcpy )
1053	!
1054	END SUBROUTINE hpg_djc
1055
1056
1057	SUBROUTINE hpg_prj( kt )
1058	!!---------------------------------------------------------------------
1059	!! * ROUTINE hpg_prj *
1060	!!
1061	!! ** Method : s-coordinate case.
1062	!! A Pressure-Jacobian horizontal pressure gradient method
1063	!! based on the constrained cubic-spline interpolation for
1064	!! all vertical coordinate systems
1065	!!
1066	!! ** Action : - Update (ua,va) with the now hydrastatic pressure trend
1067	!!----------------------------------------------------------------------
1068	INTEGER, PARAMETER :: polynomial_type = 1 ! 1: cubic spline, 2: linear
1069	INTEGER, INTENT(in) :: kt ! ocean time-step index
1070	!!
1071	INTEGER :: ji, jj, jk, jkk ! dummy loop indices
1072	REAL(wp) :: zcoef0, znad ! temporary scalars
1073	!!
1074	!! The local variables for the correction term
1075	INTEGER :: jk1, jis, jid, jjs, jjd
1076	LOGICAL :: ll_tmp1, ll_tmp2 ! local logical variables
1077	REAL(wp) :: zuijk, zvijk, zpwes, zpwed, zpnss, zpnsd, zdeps
1078	REAL(wp) :: zrhdt1
1079	REAL(wp) :: zdpdx1, zdpdx2, zdpdy1, zdpdy2
1080	REAL(wp), POINTER, DIMENSION(:,:,:) :: zdept, zrhh
1081	REAL(wp), POINTER, DIMENSION(:,:,:) :: zhpi, zu, zv, fsp, xsp, asp, bsp, csp, dsp
1082	REAL(wp), POINTER, DIMENSION(:,:) :: zsshu_n, zsshv_n
1083	REAL(wp), POINTER, DIMENSION(:,:) :: zcpx, zcpy !W/D pressure filter
1084	!!----------------------------------------------------------------------
1085	!
1086	CALL wrk_alloc( jpi,jpj,jpk, zhpi, zu, zv, fsp, xsp, asp, bsp, csp, dsp )
1087	CALL wrk_alloc( jpi,jpj,jpk, zdept, zrhh )
1088	CALL wrk_alloc( jpi,jpj, zsshu_n, zsshv_n )
1089	IF(ln_wd) CALL wrk_alloc( jpi,jpj, zcpx, zcpy )
1090	!
1091	IF( kt == nit000 ) THEN
1092	IF(lwp) WRITE(numout,*)
1093	IF(lwp) WRITE(numout,*) 'dyn:hpg_prj : hydrostatic pressure gradient trend'
1094	IF(lwp) WRITE(numout,*) '~~~~~~~~~~~ s-coordinate case, cubic spline pressure Jacobian'
1095	ENDIF
1096
1097	!!----------------------------------------------------------------------
1098	! Local constant initialization
1099	zcoef0 = - grav
1100	znad = 0.0_wp
1101	IF( lk_vvl ) znad = 1._wp
1102
1103	IF(ln_wd) THEN
1104	DO jj = 2, jpjm1
1105	DO ji = 2, jpim1
1106	ll_tmp1 = MIN(sshn(ji,jj), sshn(ji+1,jj)) > MAX(-bathy(ji,jj), -bathy(ji+1,jj)) &
1107	& .and. MAX(sshn(ji,jj) + bathy(ji,jj), sshn(ji+1,jj) + bathy(ji+1,jj)) &
1108	& > rn_wdmin1 + rn_wdmin2
1109	ll_tmp2 = MAX(sshn(ji,jj), sshn(ji+1,jj)) > MAX(-bathy(ji,jj), -bathy(ji+1,jj)) +&
1110	& rn_wdmin1 + rn_wdmin2
1111
1112	IF(ll_tmp1) THEN
1113	zcpx(ji,jj) = 1.0_wp
1114	ELSE IF(ll_tmp2) THEN
1115	! no worries about sshn(ji+1,jj)-sshn(ji,jj) = 0, it won't happen ! here
1116	zcpx(ji,jj) = ABS((sshn(ji+1,jj) + bathy(ji+1,jj) - sshn(ji,jj) - bathy(ji,jj)) /&
1117	& (sshn(ji+1,jj) - sshn(ji,jj)))
1118	ELSE
1119	zcpx(ji,jj) = 0._wp
1120	END IF
1121
1122	ll_tmp1 = MIN(sshn(ji,jj), sshn(ji,jj+1)) > MAX(-bathy(ji,jj), -bathy(ji,jj+1)) &
1123	& .and. MAX(sshn(ji,jj) + bathy(ji,jj), sshn(ji,jj+1) + bathy(ji,jj+1)) &
1124	& > rn_wdmin1 + rn_wdmin2
1125	ll_tmp2 = MAX(sshn(ji,jj), sshn(ji,jj+1)) > MAX(-bathy(ji,jj), -bathy(ji,jj+1)) +&
1126	& rn_wdmin1 + rn_wdmin2
1127
1128	IF(ll_tmp1.OR.ll_tmp2) THEN
1129	zcpy(ji,jj) = 1.0_wp
1130	ELSE IF(ll_tmp2) THEN
1131	! no worries about sshn(ji,jj+1)-sshn(ji,jj) = 0, it won't happen ! here
1132	zcpy(ji,jj) = ABS((sshn(ji,jj+1) + bathy(ji,jj+1) - sshn(ji,jj) - bathy(ji,jj)) /&
1133	& (sshn(ji,jj+1) - sshn(ji,jj)))
1134	ELSE
1135	zcpy(ji,jj) = 0._wp
1136	END IF
1137	END DO
1138	END DO
1139	CALL lbc_lnk( zcpx, 'U', 1._wp ) ; CALL lbc_lnk( zcpy, 'V', 1._wp )
1140	ENDIF
1141
1142	! Clean 3-D work arrays
1143	zhpi(:,:,:) = 0._wp
1144	zrhh(:,:,:) = rhd(:,:,:)
1145
1146	! Preparing vertical density profile "zrhh(:,:,:)" for hybrid-sco coordinate
1147	DO jj = 1, jpj
1148	DO ji = 1, jpi
1149	jk = mbathy(ji,jj)
1150	IF( jk <= 0 ) THEN; zrhh(ji,jj,:) = 0._wp
1151	ELSE IF(jk == 1) THEN; zrhh(ji,jj, jk+1:jpk) = rhd(ji,jj,jk)
1152	ELSE IF(jk < jpkm1) THEN
1153	DO jkk = jk+1, jpk
1154	zrhh(ji,jj,jkk) = interp1(fsde3w(ji,jj,jkk), fsde3w(ji,jj,jkk-1), &
1155	fsde3w(ji,jj,jkk-2), rhd(ji,jj,jkk-1), rhd(ji,jj,jkk-2))
1156	END DO
1157	ENDIF
1158	END DO
1159	END DO
1160
1161	! Transfer the depth of "T(:,:,:)" to vertical coordinate "zdept(:,:,:)"
1162	DO jj = 1, jpj
1163	DO ji = 1, jpi
1164	zdept(ji,jj,1) = 0.5_wp * fse3w(ji,jj,1) - sshn(ji,jj) * znad
1165	END DO
1166	END DO
1167
1168	DO jk = 2, jpk
1169	DO jj = 1, jpj
1170	DO ji = 1, jpi
1171	zdept(ji,jj,jk) = zdept(ji,jj,jk-1) + fse3w(ji,jj,jk)
1172	END DO
1173	END DO
1174	END DO
1175
1176	fsp(:,:,:) = zrhh (:,:,:)
1177	xsp(:,:,:) = zdept(:,:,:)
1178
1179	! Construct the vertical density profile with the
1180	! constrained cubic spline interpolation
1181	! rho(z) = asp + bspz + cspz^2 + dsp*z^3
1182	CALL cspline(fsp,xsp,asp,bsp,csp,dsp,polynomial_type)
1183
1184	! Integrate the hydrostatic pressure "zhpi(:,:,:)" at "T(ji,jj,1)"
1185	DO jj = 2, jpj
1186	DO ji = 2, jpi
1187	zrhdt1 = zrhh(ji,jj,1) - interp3(zdept(ji,jj,1),asp(ji,jj,1), &
1188	bsp(ji,jj,1), csp(ji,jj,1), &
1189	dsp(ji,jj,1) ) * 0.25_wp * fse3w(ji,jj,1)
1190
1191	! assuming linear profile across the top half surface layer
1192	zhpi(ji,jj,1) = 0.5_wp * fse3w(ji,jj,1) * zrhdt1
1193	END DO
1194	END DO
1195
1196	! Calculate the pressure "zhpi(:,:,:)" at "T(ji,jj,2:jpkm1)"
1197	DO jk = 2, jpkm1
1198	DO jj = 2, jpj
1199	DO ji = 2, jpi
1200	zhpi(ji,jj,jk) = zhpi(ji,jj,jk-1) + &
1201	integ_spline(zdept(ji,jj,jk-1), zdept(ji,jj,jk),&
1202	asp(ji,jj,jk-1), bsp(ji,jj,jk-1), &
1203	csp(ji,jj,jk-1), dsp(ji,jj,jk-1))
1204	END DO
1205	END DO
1206	END DO
1207
1208	! Z coordinate of U(ji,jj,1:jpkm1) and V(ji,jj,1:jpkm1)
1209
1210	! Prepare zsshu_n and zsshv_n
1211	DO jj = 2, jpjm1
1212	DO ji = 2, jpim1
1213	zsshu_n(ji,jj) = (e12u(ji,jj) * sshn(ji,jj) + e12u(ji+1, jj) * sshn(ji+1,jj)) * &
1214	& r1_e12u(ji,jj) * umask(ji,jj,1) * 0.5_wp
1215	zsshv_n(ji,jj) = (e12v(ji,jj) * sshn(ji,jj) + e12v(ji+1, jj) * sshn(ji,jj+1)) * &
1216	& r1_e12v(ji,jj) * vmask(ji,jj,1) * 0.5_wp
1217	END DO
1218	END DO
1219
1220	CALL lbc_lnk (zsshu_n, 'U', 1.)
1221	CALL lbc_lnk (zsshv_n, 'V', 1.)
1222
1223	DO jj = 2, jpjm1
1224	DO ji = 2, jpim1
1225	zu(ji,jj,1) = - ( fse3u(ji,jj,1) - zsshu_n(ji,jj) * znad)
1226	zv(ji,jj,1) = - ( fse3v(ji,jj,1) - zsshv_n(ji,jj) * znad)
1227	END DO
1228	END DO
1229
1230	DO jk = 2, jpkm1
1231	DO jj = 2, jpjm1
1232	DO ji = 2, jpim1
1233	zu(ji,jj,jk) = zu(ji,jj,jk-1)- fse3u(ji,jj,jk)
1234	zv(ji,jj,jk) = zv(ji,jj,jk-1)- fse3v(ji,jj,jk)
1235	END DO
1236	END DO
1237	END DO
1238
1239	DO jk = 1, jpkm1
1240	DO jj = 2, jpjm1
1241	DO ji = 2, jpim1
1242	zu(ji,jj,jk) = zu(ji,jj,jk) + 0.5_wp * fse3u(ji,jj,jk)
1243	zv(ji,jj,jk) = zv(ji,jj,jk) + 0.5_wp * fse3v(ji,jj,jk)
1244	END DO
1245	END DO
1246	END DO
1247
1248	DO jk = 1, jpkm1
1249	DO jj = 2, jpjm1
1250	DO ji = 2, jpim1
1251	zu(ji,jj,jk) = min(zu(ji,jj,jk), max(-zdept(ji,jj,jk), -zdept(ji+1,jj,jk)))
1252	zu(ji,jj,jk) = max(zu(ji,jj,jk), min(-zdept(ji,jj,jk), -zdept(ji+1,jj,jk)))
1253	zv(ji,jj,jk) = min(zv(ji,jj,jk), max(-zdept(ji,jj,jk), -zdept(ji,jj+1,jk)))
1254	zv(ji,jj,jk) = max(zv(ji,jj,jk), min(-zdept(ji,jj,jk), -zdept(ji,jj+1,jk)))
1255	END DO
1256	END DO
1257	END DO
1258
1259
1260	DO jk = 1, jpkm1
1261	DO jj = 2, jpjm1
1262	DO ji = 2, jpim1
1263	zpwes = 0._wp; zpwed = 0._wp
1264	zpnss = 0._wp; zpnsd = 0._wp
1265	zuijk = zu(ji,jj,jk)
1266	zvijk = zv(ji,jj,jk)
1267
1268	!!!!! for u equation
1269	IF( jk <= mbku(ji,jj) ) THEN
1270	IF( -zdept(ji+1,jj,jk) >= -zdept(ji,jj,jk) ) THEN
1271	jis = ji + 1; jid = ji
1272	ELSE
1273	jis = ji; jid = ji +1
1274	ENDIF
1275
1276	! integrate the pressure on the shallow side
1277	jk1 = jk
1278	DO WHILE ( -zdept(jis,jj,jk1) > zuijk )
1279	IF( jk1 == mbku(ji,jj) ) THEN
1280	zuijk = -zdept(jis,jj,jk1)
1281	EXIT
1282	ENDIF
1283	zdeps = MIN(zdept(jis,jj,jk1+1), -zuijk)
1284	zpwes = zpwes + &
1285	integ_spline(zdept(jis,jj,jk1), zdeps, &
1286	asp(jis,jj,jk1), bsp(jis,jj,jk1), &
1287	csp(jis,jj,jk1), dsp(jis,jj,jk1))
1288	jk1 = jk1 + 1
1289	END DO
1290
1291	! integrate the pressure on the deep side
1292	jk1 = jk
1293	DO WHILE ( -zdept(jid,jj,jk1) < zuijk )
1294	IF( jk1 == 1 ) THEN
1295	zdeps = zdept(jid,jj,1) + MIN(zuijk, sshn(jid,jj)*znad)
1296	zrhdt1 = zrhh(jid,jj,1) - interp3(zdept(jid,jj,1), asp(jid,jj,1), &
1297	bsp(jid,jj,1), csp(jid,jj,1), &
1298	dsp(jid,jj,1)) * zdeps
1299	zpwed = zpwed + 0.5_wp * (zrhh(jid,jj,1) + zrhdt1) * zdeps
1300	EXIT
1301	ENDIF
1302	zdeps = MAX(zdept(jid,jj,jk1-1), -zuijk)
1303	zpwed = zpwed + &
1304	integ_spline(zdeps, zdept(jid,jj,jk1), &
1305	asp(jid,jj,jk1-1), bsp(jid,jj,jk1-1), &
1306	csp(jid,jj,jk1-1), dsp(jid,jj,jk1-1) )
1307	jk1 = jk1 - 1
1308	END DO
1309
1310	! update the momentum trends in u direction
1311
1312	zdpdx1 = zcoef0 / e1u(ji,jj) * (zhpi(ji+1,jj,jk) - zhpi(ji,jj,jk))
1313	IF( lk_vvl ) THEN
1314	zdpdx2 = zcoef0 / e1u(ji,jj) * &
1315	( REAL(jis-jid, wp) * (zpwes + zpwed) + (sshn(ji+1,jj)-sshn(ji,jj)) )
1316	ELSE
1317	zdpdx2 = zcoef0 / e1u(ji,jj) * REAL(jis-jid, wp) * (zpwes + zpwed)
1318	ENDIF
1319
1320	IF(ln_wd) THEN
1321	zdpdx1 = zdpdx1 * zcpx(ji,jj)
1322	zdpdx2 = zdpdx2 * zcpx(ji,jj)
1323	ENDIF
1324	ua(ji,jj,jk) = ua(ji,jj,jk) + (zdpdx1 + zdpdx2) * umask(ji,jj,jk)
1325	ENDIF
1326
1327	!!!!! for v equation
1328	IF( jk <= mbkv(ji,jj) ) THEN
1329	IF( -zdept(ji,jj+1,jk) >= -zdept(ji,jj,jk) ) THEN
1330	jjs = jj + 1; jjd = jj
1331	ELSE
1332	jjs = jj ; jjd = jj + 1
1333	ENDIF
1334
1335	! integrate the pressure on the shallow side
1336	jk1 = jk
1337	DO WHILE ( -zdept(ji,jjs,jk1) > zvijk )
1338	IF( jk1 == mbkv(ji,jj) ) THEN
1339	zvijk = -zdept(ji,jjs,jk1)
1340	EXIT
1341	ENDIF
1342	zdeps = MIN(zdept(ji,jjs,jk1+1), -zvijk)
1343	zpnss = zpnss + &
1344	integ_spline(zdept(ji,jjs,jk1), zdeps, &
1345	asp(ji,jjs,jk1), bsp(ji,jjs,jk1), &
1346	csp(ji,jjs,jk1), dsp(ji,jjs,jk1) )
1347	jk1 = jk1 + 1
1348	END DO
1349
1350	! integrate the pressure on the deep side
1351	jk1 = jk
1352	DO WHILE ( -zdept(ji,jjd,jk1) < zvijk )
1353	IF( jk1 == 1 ) THEN
1354	zdeps = zdept(ji,jjd,1) + MIN(zvijk, sshn(ji,jjd)*znad)
1355	zrhdt1 = zrhh(ji,jjd,1) - interp3(zdept(ji,jjd,1), asp(ji,jjd,1), &
1356	bsp(ji,jjd,1), csp(ji,jjd,1), &
1357	dsp(ji,jjd,1) ) * zdeps
1358	zpnsd = zpnsd + 0.5_wp * (zrhh(ji,jjd,1) + zrhdt1) * zdeps
1359	EXIT
1360	ENDIF
1361	zdeps = MAX(zdept(ji,jjd,jk1-1), -zvijk)
1362	zpnsd = zpnsd + &
1363	integ_spline(zdeps, zdept(ji,jjd,jk1), &
1364	asp(ji,jjd,jk1-1), bsp(ji,jjd,jk1-1), &
1365	csp(ji,jjd,jk1-1), dsp(ji,jjd,jk1-1) )
1366	jk1 = jk1 - 1
1367	END DO
1368
1369
1370	! update the momentum trends in v direction
1371
1372	zdpdy1 = zcoef0 / e2v(ji,jj) * (zhpi(ji,jj+1,jk) - zhpi(ji,jj,jk))
1373	IF( lk_vvl ) THEN
1374	zdpdy2 = zcoef0 / e2v(ji,jj) * &
1375	( REAL(jjs-jjd, wp) * (zpnss + zpnsd) + (sshn(ji,jj+1)-sshn(ji,jj)) )
1376	ELSE
1377	zdpdy2 = zcoef0 / e2v(ji,jj) * REAL(jjs-jjd, wp) * (zpnss + zpnsd )
1378	ENDIF
1379
1380	IF(ln_wd) THEN
1381	zdpdy1 = zdpdy1 * zcpy(ji,jj)
1382	zdpdy2 = zdpdy2 * zcpy(ji,jj)
1383	ENDIF
1384
1385	va(ji,jj,jk) = va(ji,jj,jk) + (zdpdy1 + zdpdy2) * vmask(ji,jj,jk)
1386	ENDIF
1387
1388
1389	END DO
1390	END DO
1391	END DO
1392	!
1393	CALL wrk_dealloc( jpi,jpj,jpk, zhpi, zu, zv, fsp, xsp, asp, bsp, csp, dsp )
1394	CALL wrk_dealloc( jpi,jpj,jpk, zdept, zrhh )
1395	CALL wrk_dealloc( jpi,jpj, zsshu_n, zsshv_n )
1396	IF(ln_wd) CALL wrk_dealloc( jpi,jpj, zcpx, zcpy )
1397	!
1398	END SUBROUTINE hpg_prj
1399
1400
1401	SUBROUTINE cspline(fsp, xsp, asp, bsp, csp, dsp, polynomial_type)
1402	!!----------------------------------------------------------------------
1403	!! * ROUTINE cspline *
1404	!!
1405	!! ** Purpose : constrained cubic spline interpolation
1406	!!
1407	!! ** Method : f(x) = asp + bspx + cspx^2 + dsp*x^3
1408	!!
1409	!! Reference: CJC Kruger, Constrained Cubic Spline Interpoltation
1410	!!----------------------------------------------------------------------
1411	IMPLICIT NONE
1412	REAL(wp), DIMENSION(:,:,:), INTENT(in) :: fsp, xsp ! value and coordinate
1413	REAL(wp), DIMENSION(:,:,:), INTENT(out) :: asp, bsp, csp, dsp ! coefficients of
1414	! the interpoated function
1415	INTEGER, INTENT(in) :: polynomial_type ! 1: cubic spline
1416	! 2: Linear
1417	!
1418	INTEGER :: ji, jj, jk ! dummy loop indices
1419	INTEGER :: jpi, jpj, jpkm1
1420	REAL(wp) :: zdf1, zdf2, zddf1, zddf2, ztmp1, ztmp2, zdxtmp
1421	REAL(wp) :: zdxtmp1, zdxtmp2, zalpha
1422	REAL(wp) :: zdf(size(fsp,3))
1423	!!----------------------------------------------------------------------
1424
1425	jpi = size(fsp,1)
1426	jpj = size(fsp,2)
1427	jpkm1 = size(fsp,3) - 1
1428
1429
1430	IF (polynomial_type == 1) THEN ! Constrained Cubic Spline
1431	DO ji = 1, jpi
1432	DO jj = 1, jpj
1433	!!Fritsch&Butland's method, 1984 (preferred, but more computation)
1434	! DO jk = 2, jpkm1-1
1435	! zdxtmp1 = xsp(ji,jj,jk) - xsp(ji,jj,jk-1)
1436	! zdxtmp2 = xsp(ji,jj,jk+1) - xsp(ji,jj,jk)
1437	! zdf1 = ( fsp(ji,jj,jk) - fsp(ji,jj,jk-1) ) / zdxtmp1
1438	! zdf2 = ( fsp(ji,jj,jk+1) - fsp(ji,jj,jk) ) / zdxtmp2
1439	!
1440	! zalpha = ( zdxtmp1 + 2._wp * zdxtmp2 ) / ( zdxtmp1 + zdxtmp2 ) / 3._wp
1441	!
1442	! IF(zdf1 * zdf2 <= 0._wp) THEN
1443	! zdf(jk) = 0._wp
1444	! ELSE
1445	! zdf(jk) = zdf1 * zdf2 / ( ( 1._wp - zalpha ) * zdf1 + zalpha * zdf2 )
1446	! ENDIF
1447	! END DO
1448
1449	!!Simply geometric average
1450	DO jk = 2, jpkm1-1
1451	zdf1 = (fsp(ji,jj,jk) - fsp(ji,jj,jk-1)) / (xsp(ji,jj,jk) - xsp(ji,jj,jk-1))
1452	zdf2 = (fsp(ji,jj,jk+1) - fsp(ji,jj,jk)) / (xsp(ji,jj,jk+1) - xsp(ji,jj,jk))
1453
1454	IF(zdf1 * zdf2 <= 0._wp) THEN
1455	zdf(jk) = 0._wp
1456	ELSE
1457	zdf(jk) = 2._wp * zdf1 * zdf2 / (zdf1 + zdf2)
1458	ENDIF
1459	END DO
1460
1461	zdf(1) = 1.5_wp * ( fsp(ji,jj,2) - fsp(ji,jj,1) ) / &
1462	& ( xsp(ji,jj,2) - xsp(ji,jj,1) ) - 0.5_wp * zdf(2)
1463	zdf(jpkm1) = 1.5_wp * ( fsp(ji,jj,jpkm1) - fsp(ji,jj,jpkm1-1) ) / &
1464	& ( xsp(ji,jj,jpkm1) - xsp(ji,jj,jpkm1-1) ) - &
1465	& 0.5_wp * zdf(jpkm1 - 1)
1466
1467	DO jk = 1, jpkm1 - 1
1468	zdxtmp = xsp(ji,jj,jk+1) - xsp(ji,jj,jk)
1469	ztmp1 = (zdf(jk+1) + 2._wp * zdf(jk)) / zdxtmp
1470	ztmp2 = 6._wp * (fsp(ji,jj,jk+1) - fsp(ji,jj,jk)) / zdxtmp / zdxtmp
1471	zddf1 = -2._wp * ztmp1 + ztmp2
1472	ztmp1 = (2._wp * zdf(jk+1) + zdf(jk)) / zdxtmp
1473	zddf2 = 2._wp * ztmp1 - ztmp2
1474
1475	dsp(ji,jj,jk) = (zddf2 - zddf1) / 6._wp / zdxtmp
1476	csp(ji,jj,jk) = ( xsp(ji,jj,jk+1) * zddf1 - xsp(ji,jj,jk)*zddf2 ) / 2._wp / zdxtmp
1477	bsp(ji,jj,jk) = ( fsp(ji,jj,jk+1) - fsp(ji,jj,jk) ) / zdxtmp - &
1478	& csp(ji,jj,jk) * ( xsp(ji,jj,jk+1) + xsp(ji,jj,jk) ) - &
1479	& dsp(ji,jj,jk) * ((xsp(ji,jj,jk+1) + xsp(ji,jj,jk))**2 - &
1480	& xsp(ji,jj,jk+1) * xsp(ji,jj,jk))
1481	asp(ji,jj,jk) = fsp(ji,jj,jk) - xsp(ji,jj,jk) * (bsp(ji,jj,jk) + &
1482	& (xsp(ji,jj,jk) * (csp(ji,jj,jk) + &
1483	& dsp(ji,jj,jk) * xsp(ji,jj,jk))))
1484	END DO
1485	END DO
1486	END DO
1487
1488	ELSE IF (polynomial_type == 2) THEN ! Linear
1489	DO ji = 1, jpi
1490	DO jj = 1, jpj
1491	DO jk = 1, jpkm1-1
1492	zdxtmp =xsp(ji,jj,jk+1) - xsp(ji,jj,jk)
1493	ztmp1 = fsp(ji,jj,jk+1) - fsp(ji,jj,jk)
1494
1495	dsp(ji,jj,jk) = 0._wp
1496	csp(ji,jj,jk) = 0._wp
1497	bsp(ji,jj,jk) = ztmp1 / zdxtmp
1498	asp(ji,jj,jk) = fsp(ji,jj,jk) - bsp(ji,jj,jk) * xsp(ji,jj,jk)
1499	END DO
1500	END DO
1501	END DO
1502
1503	ELSE
1504	CALL ctl_stop( 'invalid polynomial type in cspline' )
1505	ENDIF
1506
1507	END SUBROUTINE cspline
1508
1509
1510	FUNCTION interp1(x, xl, xr, fl, fr) RESULT(f)
1511	!!----------------------------------------------------------------------
1512	!! * ROUTINE interp1 *
1513	!!
1514	!! ** Purpose : 1-d linear interpolation
1515	!!
1516	!! ** Method : interpolation is straight forward
1517	!! extrapolation is also permitted (no value limit)
1518	!!----------------------------------------------------------------------
1519	IMPLICIT NONE
1520	REAL(wp), INTENT(in) :: x, xl, xr, fl, fr
1521	REAL(wp) :: f ! result of the interpolation (extrapolation)
1522	REAL(wp) :: zdeltx
1523	!!----------------------------------------------------------------------
1524
1525	zdeltx = xr - xl
1526	IF(abs(zdeltx) <= 10._wp * EPSILON(x)) THEN
1527	f = 0.5_wp * (fl + fr)
1528	ELSE
1529	f = ( (x - xl ) * fr - ( x - xr ) * fl ) / zdeltx
1530	ENDIF
1531
1532	END FUNCTION interp1
1533
1534
1535	FUNCTION interp2(x, a, b, c, d) RESULT(f)
1536	!!----------------------------------------------------------------------
1537	!! * ROUTINE interp1 *
1538	!!
1539	!! ** Purpose : 1-d constrained cubic spline interpolation
1540	!!
1541	!! ** Method : cubic spline interpolation
1542	!!
1543	!!----------------------------------------------------------------------
1544	IMPLICIT NONE
1545	REAL(wp), INTENT(in) :: x, a, b, c, d
1546	REAL(wp) :: f ! value from the interpolation
1547	!!----------------------------------------------------------------------
1548
1549	f = a + x* ( b + x * ( c + d * x ) )
1550
1551	END FUNCTION interp2
1552
1553
1554	FUNCTION interp3(x, a, b, c, d) RESULT(f)
1555	!!----------------------------------------------------------------------
1556	!! * ROUTINE interp1 *
1557	!!
1558	!! ** Purpose : Calculate the first order of deriavtive of
1559	!! a cubic spline function y=a+bx+cx^2+d*x^3
1560	!!
1561	!! ** Method : f=dy/dx=b+2cx+3dx^2
1562	!!
1563	!!----------------------------------------------------------------------
1564	IMPLICIT NONE
1565	REAL(wp), INTENT(in) :: x, a, b, c, d
1566	REAL(wp) :: f ! value from the interpolation
1567	!!----------------------------------------------------------------------
1568
1569	f = b + x * ( 2._wp * c + 3._wp * d * x)
1570
1571	END FUNCTION interp3
1572
1573
1574	FUNCTION integ_spline(xl, xr, a, b, c, d) RESULT(f)
1575	!!----------------------------------------------------------------------
1576	!! * ROUTINE interp1 *
1577	!!
1578	!! ** Purpose : 1-d constrained cubic spline integration
1579	!!
1580	!! ** Method : integrate polynomial a+bx+cx^2+dx^3 from xl to xr
1581	!!
1582	!!----------------------------------------------------------------------
1583	IMPLICIT NONE
1584	REAL(wp), INTENT(in) :: xl, xr, a, b, c, d
1585	REAL(wp) :: za1, za2, za3
1586	REAL(wp) :: f ! integration result
1587	!!----------------------------------------------------------------------
1588
1589	za1 = 0.5_wp * b
1590	za2 = c / 3.0_wp
1591	za3 = 0.25_wp * d
1592
1593	f = xr * ( a + xr * ( za1 + xr * ( za2 + za3 * xr ) ) ) - &
1594	& xl * ( a + xl * ( za1 + xl * ( za2 + za3 * xl ) ) )
1595
1596	END FUNCTION integ_spline
1597
1598	!!======================================================================
1599	END MODULE dynhpg
1600

Note: See TracBrowser for help on using the repository browser.

Download in other formats: