New URL for NEMO forge!   http://forge.nemo-ocean.eu

Since March 2022 along with NEMO 4.2 release, the code development moved to a self-hosted GitLab.
This present forge is now archived and remained online for history.
trasbc.F90 in branches/2015/dev_r5803_UKMO_AGRIF_Vert_interp/NEMOGCM/NEMO/OPA_SRC/TRA – NEMO

source: branches/2015/dev_r5803_UKMO_AGRIF_Vert_interp/NEMOGCM/NEMO/OPA_SRC/TRA/trasbc.F90 @ 5819

Last change on this file since 5819 was 5819, checked in by timgraham, 8 years ago

Deleted fcm keywords

File size: 15.9 KB
Line 
1MODULE trasbc
2   !!==============================================================================
3   !!                       ***  MODULE  trasbc  ***
4   !! Ocean active tracers:  surface boundary condition
5   !!==============================================================================
6   !! History :  OPA  !  1998-10  (G. Madec, G. Roullet, M. Imbard)  Original code
7   !!            8.2  !  2001-02  (D. Ludicone)  sea ice and free surface
8   !!  NEMO      1.0  !  2002-06  (G. Madec)  F90: Free form and module
9   !!            3.3  !  2010-04  (M. Leclair, G. Madec)  Forcing averaged over 2 time steps
10   !!             -   !  2010-09  (C. Ethe, G. Madec) Merge TRA-TRC
11   !!            3.6  !  2014-11  (P. Mathiot) isf melting forcing
12   !!----------------------------------------------------------------------
13
14   !!----------------------------------------------------------------------
15   !!   tra_sbc      : update the tracer trend at ocean surface
16   !!----------------------------------------------------------------------
17   USE oce             ! ocean dynamics and active tracers
18   USE sbc_oce         ! surface boundary condition: ocean
19   USE dom_oce         ! ocean space domain variables
20   USE phycst          ! physical constant
21   USE sbcmod          ! ln_rnf 
22   USE sbcrnf          ! River runoff 
23   USE sbcisf          ! Ice shelf   
24   USE traqsr          ! solar radiation penetration
25   USE trd_oce         ! trends: ocean variables
26   USE trdtra          ! trends manager: tracers
27   !
28   USE in_out_manager  ! I/O manager
29   USE prtctl          ! Print control
30   USE iom
31   USE lbclnk          ! ocean lateral boundary conditions (or mpp link)
32   USE wrk_nemo        ! Memory Allocation
33   USE timing          ! Timing
34   USE eosbn2
35
36   IMPLICIT NONE
37   PRIVATE
38
39   PUBLIC   tra_sbc    ! routine called by step.F90
40
41   !! * Substitutions
42#  include "domzgr_substitute.h90"
43#  include "vectopt_loop_substitute.h90"
44   !!----------------------------------------------------------------------
45   !! NEMO/OPA 3.7 , NEMO Consortium (2014)
46   !! $Id$
47   !! Software governed by the CeCILL licence     (NEMOGCM/NEMO_CeCILL.txt)
48   !!----------------------------------------------------------------------
49CONTAINS
50
51   SUBROUTINE tra_sbc ( kt )
52      !!----------------------------------------------------------------------
53      !!                  ***  ROUTINE tra_sbc  ***
54      !!                   
55      !! ** Purpose :   Compute the tracer surface boundary condition trend of
56      !!      (flux through the interface, concentration/dilution effect)
57      !!      and add it to the general trend of tracer equations.
58      !!
59      !! ** Method :
60      !!      Following Roullet and Madec (2000), the air-sea flux can be divided
61      !!      into three effects: (1) Fext, external forcing;
62      !!      (2) Fwi, concentration/dilution effect due to water exchanged
63      !!         at the surface by evaporation, precipitations and runoff (E-P-R);
64      !!      (3) Fwe, tracer carried with the water that is exchanged.
65      !!            - salinity    : salt flux only due to freezing/melting
66      !!            sa = sa +  sfx / rau0 / e3t  for k=1
67      !!
68      !!      Fext, flux through the air-sea interface for temperature and salt:
69      !!            - temperature : heat flux q (w/m2). If penetrative solar
70      !!         radiation q is only the non solar part of the heat flux, the
71      !!         solar part is added in traqsr.F routine.
72      !!            ta = ta + q /(rau0 rcp e3t)  for k=1
73      !!            - salinity    : no salt flux
74      !!
75      !!      The formulation for Fwb and Fwi vary according to the free
76      !!      surface formulation (linear or variable volume).
77      !!      * Linear free surface
78      !!            The surface freshwater flux modifies the ocean volume
79      !!         and thus the concentration of a tracer and the temperature.
80      !!         First order of the effect of surface freshwater exchange
81      !!         for salinity, it can be neglected on temperature (especially
82      !!         as the temperature of precipitations and runoffs is usually
83      !!         unknown).
84      !!            - temperature : we assume that the temperature of both
85      !!         precipitations and runoffs is equal to the SST, thus there
86      !!         is no additional flux since in this case, the concentration
87      !!         dilution effect is balanced by the net heat flux associated
88      !!         to the freshwater exchange (Fwe+Fwi=0):
89      !!            (Tp P - Te E) + SST (P-E) = 0 when Tp=Te=SST
90      !!            - salinity    : evaporation, precipitation and runoff
91      !!         water has a zero salinity  but there is a salt flux due to
92      !!         freezing/melting, thus:
93      !!            sa = sa + emp * sn / rau0 / e3t   for k=1
94      !!                    + sfx    / rau0 / e3t
95      !!         where emp, the surface freshwater budget (evaporation minus
96      !!         precipitation minus runoff) given in kg/m2/s is divided
97      !!         by rau0 (density of sea water) to obtain m/s.   
98      !!         Note: even though Fwe does not appear explicitly for
99      !!         temperature in this routine, the heat carried by the water
100      !!         exchanged through the surface is part of the total heat flux
101      !!         forcing and must be taken into account in the global heat
102      !!         balance).
103      !!      * nonlinear free surface (variable volume, lk_vvl)
104      !!         contrary to the linear free surface case, Fwi is properly
105      !!         taken into account by using the true layer thicknesses to       
106      !!         calculate tracer content and advection. There is no need to
107      !!         deal with it in this routine.
108      !!           - temperature: Fwe=SST (P-E+R) is added to Fext.
109      !!           - salinity:  Fwe = 0, there is no surface flux of salt.
110      !!
111      !! ** Action  : - Update the 1st level of (ta,sa) with the trend associated
112      !!                with the tracer surface boundary condition
113      !!              - send trends to trdtra module (l_trdtra=T)
114      !!----------------------------------------------------------------------
115      INTEGER, INTENT(in) ::   kt   ! ocean time-step index
116      !!
117      INTEGER  ::   ji, jj, jk, jn           ! dummy loop indices 
118      INTEGER  ::   ikt, ikb 
119      INTEGER  ::   nk_isf
120      REAL(wp) ::   zfact, z1_e3t, zdep
121      REAL(wp) ::   zalpha, zhk
122      REAL(wp), POINTER, DIMENSION(:,:,:) ::  ztrdt, ztrds
123      !!----------------------------------------------------------------------
124      !
125      IF( nn_timing == 1 )  CALL timing_start('tra_sbc')
126      !
127      IF( kt == nit000 ) THEN
128         IF(lwp) WRITE(numout,*)
129         IF(lwp) WRITE(numout,*) 'tra_sbc : TRAcer Surface Boundary Condition'
130         IF(lwp) WRITE(numout,*) '~~~~~~~ '
131      ENDIF
132
133      IF( l_trdtra ) THEN                    !* Save ta and sa trends
134         CALL wrk_alloc( jpi, jpj, jpk, ztrdt, ztrds ) 
135         ztrdt(:,:,:) = tsa(:,:,:,jp_tem)
136         ztrds(:,:,:) = tsa(:,:,:,jp_sal)
137      ENDIF
138
139!!gm      IF( .NOT.ln_traqsr )   qsr(:,:) = 0.e0   ! no solar radiation penetration
140      IF( .NOT.ln_traqsr ) THEN     ! no solar radiation penetration
141         qns(:,:) = qns(:,:) + qsr(:,:)      ! total heat flux in qns
142         qsr(:,:) = 0.e0                     ! qsr set to zero
143      ENDIF
144
145      !----------------------------------------
146      !        EMP, SFX and QNS effects
147      !----------------------------------------
148      !                                          Set before sbc tracer content fields
149      !                                          ************************************
150      IF( kt == nit000 ) THEN                      ! Set the forcing field at nit000 - 1
151         !                                         ! -----------------------------------
152         IF( ln_rstart .AND.    &                     ! Restart: read in restart file
153              & iom_varid( numror, 'sbc_hc_b', ldstop = .FALSE. ) > 0 ) THEN
154            IF(lwp) WRITE(numout,*) '          nit000-1 surface tracer content forcing fields red in the restart file'
155            zfact = 0.5_wp
156            CALL iom_get( numror, jpdom_autoglo, 'sbc_hc_b', sbc_tsc_b(:,:,jp_tem) )   ! before heat content sbc trend
157            CALL iom_get( numror, jpdom_autoglo, 'sbc_sc_b', sbc_tsc_b(:,:,jp_sal) )   ! before salt content sbc trend
158         ELSE                                         ! No restart or restart not found: Euler forward time stepping
159            zfact = 1._wp
160            sbc_tsc_b(:,:,:) = 0._wp
161         ENDIF
162      ELSE                                         ! Swap of forcing fields
163         !                                         ! ----------------------
164         zfact = 0.5_wp
165         sbc_tsc_b(:,:,:) = sbc_tsc(:,:,:)
166      ENDIF
167      !                                          Compute now sbc tracer content fields
168      !                                          *************************************
169
170                                                   ! Concentration dilution effect on (t,s) due to 
171                                                   ! evaporation, precipitation and qns, but not river runoff
172                                               
173      IF( lk_vvl ) THEN                            ! Variable Volume case  ==>> heat content of mass flux is in qns
174         DO jj = 1, jpj
175            DO ji = 1, jpi 
176               sbc_tsc(ji,jj,jp_tem) = r1_rau0_rcp * qns(ji,jj)                              ! non solar heat flux
177               sbc_tsc(ji,jj,jp_sal) = r1_rau0     * sfx(ji,jj)                              ! salt flux due to freezing/melting
178            END DO
179         END DO
180      ELSE                                         ! Constant Volume case ==>> Concentration dilution effect
181         DO jj = 2, jpj
182            DO ji = fs_2, fs_jpim1   ! vector opt.
183               ! temperature : heat flux
184               sbc_tsc(ji,jj,jp_tem) = r1_rau0_rcp * qns(ji,jj)                          &   ! non solar heat flux
185                  &                  + r1_rau0     * emp(ji,jj)  * tsn(ji,jj,1,jp_tem)       ! concent./dilut. effect
186               ! salinity    : salt flux + concent./dilut. effect (both in sfx)
187               sbc_tsc(ji,jj,jp_sal) = r1_rau0  * (  sfx(ji,jj)                          &   ! salt flux (freezing/melting)
188                  &                                + emp(ji,jj) * tsn(ji,jj,1,jp_sal) )      ! concent./dilut. effect
189            END DO
190         END DO
191         IF( iom_use('emp_x_sst') )   CALL iom_put( "emp_x_sst", emp (:,:) * tsn(:,:,1,jp_tem) )   ! c/d term on sst
192         IF( iom_use('emp_x_sss') )   CALL iom_put( "emp_x_sss", emp (:,:) * tsn(:,:,1,jp_sal) )   ! c/d term on sss
193      ENDIF
194      ! Concentration dilution effect on (t,s) due to evapouration, precipitation and qns, but not river runoff 
195      DO jn = 1, jpts
196         DO jj = 2, jpj
197            DO ji = fs_2, fs_jpim1   ! vector opt.
198               z1_e3t = zfact / fse3t(ji,jj,1)
199               tsa(ji,jj,1,jn) = tsa(ji,jj,1,jn) + ( sbc_tsc_b(ji,jj,jn) + sbc_tsc(ji,jj,jn) ) * z1_e3t
200            END DO
201         END DO
202      END DO
203      !                                          Write in the ocean restart file
204      !                                          *******************************
205      IF( lrst_oce ) THEN
206         IF(lwp) WRITE(numout,*)
207         IF(lwp) WRITE(numout,*) 'sbc : ocean surface tracer content forcing fields written in ocean restart file ',   &
208            &                    'at it= ', kt,' date= ', ndastp
209         IF(lwp) WRITE(numout,*) '~~~~'
210         CALL iom_rstput( kt, nitrst, numrow, 'sbc_hc_b', sbc_tsc(:,:,jp_tem) )
211         CALL iom_rstput( kt, nitrst, numrow, 'sbc_sc_b', sbc_tsc(:,:,jp_sal) )
212      ENDIF
213      !
214      !
215      !----------------------------------------
216      !       Ice Shelf effects (ISF)
217      !     tbl treated as in Losh (2008) JGR
218      !----------------------------------------
219      !
220      IF( nn_isf > 0 ) THEN
221         zfact = 0.5e0
222         DO jj = 2, jpj
223            DO ji = fs_2, fs_jpim1
224         
225               ikt = misfkt(ji,jj)
226               ikb = misfkb(ji,jj)
227   
228               ! level fully include in the ice shelf boundary layer
229               ! if isfdiv, we have to remove heat flux due to inflow at 0oC (as in rnf when you add rnf at sst)
230               ! sign - because fwf sign of evapo (rnf sign of precip)
231               DO jk = ikt, ikb - 1
232               ! compute tfreez for the temperature correction (we add water at freezing temperature)
233               ! compute trend
234                  tsa(ji,jj,jk,jp_tem) = tsa(ji,jj,jk,jp_tem)                                          &
235                     &           + zfact * (risf_tsc_b(ji,jj,jp_tem) + risf_tsc(ji,jj,jp_tem)) * r1_hisf_tbl(ji,jj)
236                  tsa(ji,jj,jk,jp_sal) = tsa(ji,jj,jk,jp_sal)                                          &
237                     &           + zfact * (risf_tsc_b(ji,jj,jp_sal) + risf_tsc(ji,jj,jp_sal)) * r1_hisf_tbl(ji,jj)
238               END DO
239   
240               ! level partially include in ice shelf boundary layer
241               ! compute tfreez for the temperature correction (we add water at freezing temperature)
242               ! compute trend
243               tsa(ji,jj,ikb,jp_tem) = tsa(ji,jj,ikb,jp_tem)                                           &
244                  &              + zfact * (risf_tsc_b(ji,jj,jp_tem) + risf_tsc(ji,jj,jp_tem)) * r1_hisf_tbl(ji,jj) * ralpha(ji,jj)
245               tsa(ji,jj,ikb,jp_sal) = tsa(ji,jj,ikb,jp_sal)                                           &
246                  &              + zfact * (risf_tsc_b(ji,jj,jp_sal) + risf_tsc(ji,jj,jp_sal)) * r1_hisf_tbl(ji,jj) * ralpha(ji,jj) 
247            END DO
248         END DO
249         IF( lrst_oce ) THEN
250            IF(lwp) WRITE(numout,*)
251            IF(lwp) WRITE(numout,*) 'sbc : isf surface tracer content forcing fields written in ocean restart file ',   &
252               &                    'at it= ', kt,' date= ', ndastp
253            IF(lwp) WRITE(numout,*) '~~~~'
254            CALL iom_rstput( kt, nitrst, numrow, 'fwf_isf_b', fwfisf(:,:)          )
255            CALL iom_rstput( kt, nitrst, numrow, 'isf_hc_b' , risf_tsc(:,:,jp_tem) )
256            CALL iom_rstput( kt, nitrst, numrow, 'isf_sc_b' , risf_tsc(:,:,jp_sal) )
257         ENDIF
258      END IF
259      !
260      !----------------------------------------
261      !        River Runoff effects
262      !----------------------------------------
263      !
264      IF( ln_rnf ) THEN         ! input of heat and salt due to river runoff
265         zfact = 0.5_wp
266         DO jj = 2, jpj 
267            DO ji = fs_2, fs_jpim1
268               IF( rnf(ji,jj) /= 0._wp ) THEN
269                  zdep = zfact / h_rnf(ji,jj)
270                  DO jk = 1, nk_rnf(ji,jj)
271                                        tsa(ji,jj,jk,jp_tem) = tsa(ji,jj,jk,jp_tem)   &
272                                          &               +  ( rnf_tsc_b(ji,jj,jp_tem) + rnf_tsc(ji,jj,jp_tem) ) * zdep
273                     IF( ln_rnf_sal )   tsa(ji,jj,jk,jp_sal) = tsa(ji,jj,jk,jp_sal)   &
274                                          &               +  ( rnf_tsc_b(ji,jj,jp_sal) + rnf_tsc(ji,jj,jp_sal) ) * zdep 
275                  END DO
276               ENDIF
277            END DO 
278         END DO 
279      ENDIF
280 
281      IF( l_trdtra )   THEN                      ! send trends for further diagnostics
282         ztrdt(:,:,:) = tsa(:,:,:,jp_tem) - ztrdt(:,:,:)
283         ztrds(:,:,:) = tsa(:,:,:,jp_sal) - ztrds(:,:,:)
284         CALL trd_tra( kt, 'TRA', jp_tem, jptra_nsr, ztrdt )
285         CALL trd_tra( kt, 'TRA', jp_sal, jptra_nsr, ztrds )
286         CALL wrk_dealloc( jpi, jpj, jpk, ztrdt, ztrds ) 
287      ENDIF
288      !
289      IF(ln_ctl)   CALL prt_ctl( tab3d_1=tsa(:,:,:,jp_tem), clinfo1=' sbc  - Ta: ', mask1=tmask,   &
290         &                       tab3d_2=tsa(:,:,:,jp_sal), clinfo2=       ' Sa: ', mask2=tmask, clinfo3='tra' )
291      !
292      IF( nn_timing == 1 )  CALL timing_stop('tra_sbc')
293      !
294   END SUBROUTINE tra_sbc
295
296   !!======================================================================
297END MODULE trasbc
Note: See TracBrowser for help on using the repository browser.