New URL for NEMO forge!   http://forge.nemo-ocean.eu

Since March 2022 along with NEMO 4.2 release, the code development moved to a self-hosted GitLab.
This present forge is now archived and remained online for history.
limthd.F90 in branches/2015/dev_r5836_NOC3_vvl_by_default/NEMOGCM/NEMO/LIM_SRC_3 – NEMO

source: branches/2015/dev_r5836_NOC3_vvl_by_default/NEMOGCM/NEMO/LIM_SRC_3/limthd.F90 @ 6004

Last change on this file since 6004 was 6004, checked in by gm, 8 years ago

#1613: vvl by default, step III: Merge with the trunk (free surface simplification) (see wiki)

  • Property svn:keywords set to Id
File size: 36.3 KB
Line 
1MODULE limthd
2   !!======================================================================
3   !!                  ***  MODULE limthd   ***
4   !!  LIM-3 :   ice thermodynamic
5   !!======================================================================
6   !! History :  LIM  ! 2000-01 (M.A. Morales Maqueda, H. Goosse, T. Fichefet) LIM-1
7   !!            2.0  ! 2002-07 (C. Ethe, G. Madec)  LIM-2 (F90 rewriting)
8   !!            3.0  ! 2005-11 (M. Vancoppenolle)  LIM-3 : Multi-layer thermodynamics + salinity variations
9   !!             -   ! 2007-04 (M. Vancoppenolle) add lim_thd_glohec, lim_thd_con_dh and lim_thd_con_dif
10   !!            3.2  ! 2009-07 (M. Vancoppenolle, Y. Aksenov, G. Madec) bug correction in wfx_snw
11   !!            3.3  ! 2010-11 (G. Madec) corrected snow melting heat (due to factor betas)
12   !!            4.0  ! 2011-02 (G. Madec) dynamical allocation
13   !!             -   ! 2012-05 (C. Rousset) add penetration solar flux
14   !!----------------------------------------------------------------------
15#if defined key_lim3
16   !!----------------------------------------------------------------------
17   !!   'key_lim3'                                      LIM3 sea-ice model
18   !!----------------------------------------------------------------------
19   !!   lim_thd       : thermodynamic of sea ice
20   !!   lim_thd_init  : initialisation of sea-ice thermodynamic
21   !!----------------------------------------------------------------------
22   USE phycst         ! physical constants
23   USE dom_oce        ! ocean space and time domain variables
24   USE ice            ! LIM: sea-ice variables
25   USE sbc_oce        ! Surface boundary condition: ocean fields
26   USE sbc_ice        ! Surface boundary condition: ice fields
27   USE dom_ice        ! LIM: sea-ice domain
28   USE thd_ice        ! LIM: thermodynamic sea-ice variables
29   USE limthd_dif     ! LIM: thermodynamics, vertical diffusion
30   USE limthd_dh      ! LIM: thermodynamics, ice and snow thickness variation
31   USE limthd_sal     ! LIM: thermodynamics, ice salinity
32   USE limthd_ent     ! LIM: thermodynamics, ice enthalpy redistribution
33   USE limthd_lac     ! LIM: lateral accretion
34   USE limitd_th      ! LIM: remapping thickness distribution
35   USE limtab         ! LIM: 1D <==> 2D transformation
36   USE limvar         ! LIM: sea-ice variables
37   USE limcons        ! LIM: conservation tests
38   USE limctl         ! LIM: control print
39   !
40   USE in_out_manager ! I/O manager
41   USE prtctl         ! Print control
42   USE lbclnk         ! lateral boundary condition - MPP links
43   USE lib_mpp        ! MPP library
44   USE wrk_nemo       ! work arrays
45   USE lib_fortran    ! Fortran utilities (allows no signed zero when 'key_nosignedzero' defined) 
46   USE timing         ! Timing
47
48   IMPLICIT NONE
49   PRIVATE
50
51   PUBLIC   lim_thd         ! called by limstp module
52   PUBLIC   lim_thd_init    ! called by sbc_lim_init
53
54   !! * Substitutions
55#  include "vectopt_loop_substitute.h90"
56   !!----------------------------------------------------------------------
57   !! NEMO/LIM3 3.3 , UCL - NEMO Consortium (2010)
58   !! $Id$
59   !! Software governed by the CeCILL licence     (NEMOGCM/NEMO_CeCILL.txt)
60   !!----------------------------------------------------------------------
61CONTAINS
62
63   SUBROUTINE lim_thd( kt )
64      !!-------------------------------------------------------------------
65      !!                ***  ROUTINE lim_thd  ***       
66      !! 
67      !! ** Purpose : This routine manages ice thermodynamics
68      !!         
69      !! ** Action : - Initialisation of some variables
70      !!             - Some preliminary computation (oceanic heat flux
71      !!               at the ice base, snow acc.,heat budget of the leads)
72      !!             - selection of the icy points and put them in an array
73      !!             - call lim_thd_dif  for vertical heat diffusion
74      !!             - call lim_thd_dh   for vertical ice growth and melt
75      !!             - call lim_thd_ent  for enthalpy remapping
76      !!             - call lim_thd_sal  for ice desalination
77      !!             - call lim_thd_temp to  retrieve temperature from ice enthalpy
78      !!             - back to the geographic grid
79      !!     
80      !! ** References :
81      !!---------------------------------------------------------------------
82      INTEGER, INTENT(in) :: kt    ! number of iteration
83      !
84      INTEGER  :: ji, jj, jk, jl   ! dummy loop indices
85      INTEGER  :: nbpb             ! nb of icy pts for vertical thermo calculations
86      REAL(wp) :: zfric_u, zqld, zqfr
87      REAL(wp) :: zvi_b, zsmv_b, zei_b, zfs_b, zfw_b, zft_b 
88      REAL(wp), PARAMETER :: zfric_umin = 0._wp           ! lower bound for the friction velocity (cice value=5.e-04)
89      REAL(wp), PARAMETER :: zch        = 0.0057_wp       ! heat transfer coefficient
90      !!-------------------------------------------------------------------
91
92      IF( nn_timing == 1 )   CALL timing_start('limthd')
93
94      ! conservation test
95      IF( ln_limdiahsb )   CALL lim_cons_hsm( 0, 'limthd', zvi_b, zsmv_b, zei_b, zfw_b, zfs_b, zft_b )
96
97      CALL lim_var_glo2eqv
98      !------------------------------------------------------------------------!
99      ! 1) Initialization of some variables                                    !
100      !------------------------------------------------------------------------!
101      ftr_ice(:,:,:) = 0._wp  ! part of solar radiation transmitted through the ice
102
103      !--------------------
104      ! 1.2) Heat content   
105      !--------------------
106      ! Change the units of heat content; from J/m2 to J/m3
107      DO jl = 1, jpl
108         DO jk = 1, nlay_i
109            DO jj = 1, jpj
110               DO ji = 1, jpi
111                  !0 if no ice and 1 if yes
112                  rswitch = MAX(  0._wp , SIGN( 1._wp , v_i(ji,jj,jl) - epsi20 )  )
113                  !Energy of melting q(S,T) [J.m-3]
114                  e_i(ji,jj,jk,jl) = rswitch * e_i(ji,jj,jk,jl) / MAX( v_i(ji,jj,jl) , epsi20 ) * REAL( nlay_i )
115               END DO
116            END DO
117         END DO
118         DO jk = 1, nlay_s
119            DO jj = 1, jpj
120               DO ji = 1, jpi
121                  !0 if no ice and 1 if yes
122                  rswitch = MAX(  0._wp , SIGN( 1._wp , v_s(ji,jj,jl) - epsi20 )  )
123                  !Energy of melting q(S,T) [J.m-3]
124                  e_s(ji,jj,jk,jl) = rswitch * e_s(ji,jj,jk,jl) / MAX( v_s(ji,jj,jl) , epsi20 ) * REAL( nlay_s )
125               END DO
126            END DO
127         END DO
128      END DO
129
130      ! 2) Partial computation of forcing for the thermodynamic sea ice model.      !
131      !-----------------------------------------------------------------------------!
132      DO jj = 1, jpj
133         DO ji = 1, jpi
134            rswitch  = tmask(ji,jj,1) * MAX( 0._wp , SIGN( 1._wp , at_i(ji,jj) - epsi10 ) ) ! 0 if no ice
135            !
136            !           !  solar irradiance transmission at the mixed layer bottom and used in the lead heat budget
137            !           !  practically no "direct lateral ablation"
138            !           
139            !           !  net downward heat flux from the ice to the ocean, expressed as a function of ocean
140            !           !  temperature and turbulent mixing (McPhee, 1992)
141            !
142            ! --- Energy received in the lead, zqld is defined everywhere (J.m-2) --- !
143            zqld =  tmask(ji,jj,1) * rdt_ice *  &
144               &    ( pfrld(ji,jj) * qsr_oce(ji,jj) * frq_m(ji,jj) + pfrld(ji,jj) * qns_oce(ji,jj) + qemp_oce(ji,jj) )
145
146            ! --- Energy needed to bring ocean surface layer until its freezing (<0, J.m-2) --- !
147            zqfr = tmask(ji,jj,1) * rau0 * rcp * e3t_m(ji,jj) * ( t_bo(ji,jj) - ( sst_m(ji,jj) + rt0 ) )
148
149            ! --- Energy from the turbulent oceanic heat flux (W/m2) --- !
150            zfric_u      = MAX( SQRT( ust2s(ji,jj) ), zfric_umin ) 
151            fhtur(ji,jj) = MAX( 0._wp, rswitch * rau0 * rcp * zch  * zfric_u * ( ( sst_m(ji,jj) + rt0 ) - t_bo(ji,jj) ) ) ! W.m-2
152            fhtur(ji,jj) = rswitch * MIN( fhtur(ji,jj), - zqfr * r1_rdtice / MAX( at_i(ji,jj), epsi10 ) )
153            ! upper bound for fhtur: the heat retrieved from the ocean must be smaller than the heat necessary to reach
154            !                        the freezing point, so that we do not have SST < T_freeze
155            !                        This implies: - ( fhtur(ji,jj) * at_i(ji,jj) * rtdice ) - zqfr >= 0
156
157            !-- Energy Budget of the leads (J.m-2). Must be < 0 to form ice
158            qlead(ji,jj) = MIN( 0._wp , zqld - ( fhtur(ji,jj) * at_i(ji,jj) * rdt_ice ) - zqfr )
159
160            ! If there is ice and leads are warming, then transfer energy from the lead budget and use it for bottom melting
161            IF( zqld > 0._wp ) THEN
162               fhld (ji,jj) = rswitch * zqld * r1_rdtice / MAX( at_i(ji,jj), epsi10 ) ! divided by at_i since this is (re)multiplied by a_i in limthd_dh.F90
163               qlead(ji,jj) = 0._wp
164            ELSE
165               fhld (ji,jj) = 0._wp
166            ENDIF
167            !
168            ! -----------------------------------------
169            ! Net heat flux on top of ice-ocean [W.m-2]
170            ! -----------------------------------------
171            hfx_in(ji,jj) = qns_tot(ji,jj) + qsr_tot(ji,jj) 
172
173            ! -----------------------------------------------------------------------------
174            ! Net heat flux on top of the ocean after ice thermo (1st step) [W.m-2]
175            ! -----------------------------------------------------------------------------
176            !     First  step here              :  non solar + precip - qlead - qturb
177            !     Second step in limthd_dh      :  heat remaining if total melt (zq_rema)
178            !     Third  step in limsbc         :  heat from ice-ocean mass exchange (zf_mass) + solar
179            hfx_out(ji,jj) =   pfrld(ji,jj) * qns_oce(ji,jj) + qemp_oce(ji,jj)  &  ! Non solar heat flux received by the ocean               
180               &             - qlead(ji,jj) * r1_rdtice                         &  ! heat flux taken from the ocean where there is open water ice formation
181               &             - at_i(ji,jj) * fhtur(ji,jj)                       &  ! heat flux taken by turbulence
182               &             - at_i(ji,jj) *  fhld(ji,jj)                          ! heat flux taken during bottom growth/melt
183                                                                                   !    (fhld should be 0 while bott growth)
184         END DO
185      END DO
186
187      !------------------------------------------------------------------------------!
188      ! 3) Select icy points and fulfill arrays for the vectorial grid.           
189      !------------------------------------------------------------------------------!
190
191      DO jl = 1, jpl      !loop over ice categories
192
193         IF( kt == nit000 .AND. lwp ) THEN
194            WRITE(numout,*) ' lim_thd : transfer to 1D vectors. Category no : ', jl 
195            WRITE(numout,*) ' ~~~~~~~~'
196         ENDIF
197
198         nbpb = 0
199         DO jj = 1, jpj
200            DO ji = 1, jpi
201               IF ( a_i(ji,jj,jl) > epsi10 ) THEN     
202                  nbpb      = nbpb  + 1
203                  npb(nbpb) = (jj - 1) * jpi + ji
204               ENDIF
205            END DO
206         END DO
207
208         ! debug point to follow
209         jiindex_1d = 0
210         IF( ln_icectl ) THEN
211            DO ji = mi0(iiceprt), mi1(iiceprt)
212               DO jj = mj0(jiceprt), mj1(jiceprt)
213                  jiindex_1d = (jj - 1) * jpi + ji
214                  WRITE(numout,*) ' lim_thd : Category no : ', jl 
215               END DO
216            END DO
217         ENDIF
218
219         !------------------------------------------------------------------------------!
220         ! 4) Thermodynamic computation
221         !------------------------------------------------------------------------------!
222
223         IF( lk_mpp )   CALL mpp_ini_ice( nbpb , numout )
224
225         IF( nbpb > 0 ) THEN  ! If there is no ice, do nothing.
226            !
227            CALL lim_thd_1d2d( nbpb, jl, 1 )                ! --- Move to 1D arrays ---!
228            !
229            CALL lim_thd_dif ( 1, nbpb )                    ! --- Ice/Snow Temperature profile --- !
230            !
231            CALL lim_thd_dh  ( 1, nbpb )                    ! --- Ice/Snow thickness ---!
232            !
233            CALL lim_thd_ent ( 1, nbpb, q_i_1d(1:nbpb,:) )  ! --- Ice enthalpy remapping --- !
234            !
235            CALL lim_thd_sal ( 1, nbpb )                    ! --- Ice salinity ---            !
236            !
237            CALL lim_thd_temp( 1, nbpb )                    ! --- temperature update ---      !
238            !
239            !                                               ! --- lateral melting if monocat --- !
240            IF ( ( nn_monocat == 1 .OR. nn_monocat == 4 ) .AND. jpl == 1 ) THEN
241               CALL lim_thd_lam( 1, nbpb )
242            END IF
243            !
244            CALL lim_thd_1d2d( nbpb, jl, 2 )                ! --- Move to 2D arrays ---
245            !
246            IF( lk_mpp )   CALL mpp_comm_free( ncomm_ice )  !RB necessary ??
247         ENDIF
248         !
249      END DO !jl
250
251      !------------------------------------------------------------------------------!
252      ! 5) Global variables, diagnostics
253      !------------------------------------------------------------------------------!
254
255      !------------------------
256      ! Ice heat content             
257      !------------------------
258      ! Enthalpies are global variables we have to readjust the units (heat content in J/m2)
259      DO jl = 1, jpl
260         DO jk = 1, nlay_i
261            e_i(:,:,jk,jl) = e_i(:,:,jk,jl) * a_i(:,:,jl) * ht_i(:,:,jl) * r1_nlay_i
262         END DO
263      END DO
264
265      !------------------------
266      ! Snow heat content             
267      !------------------------
268      ! Enthalpies are global variables we have to readjust the units (heat content in J/m2)
269      DO jl = 1, jpl
270         DO jk = 1, nlay_s
271            e_s(:,:,jk,jl) = e_s(:,:,jk,jl) * a_i(:,:,jl) * ht_s(:,:,jl) * r1_nlay_s
272         END DO
273      END DO
274 
275      !----------------------------------
276      ! Change thickness to volume
277      !----------------------------------
278      v_i(:,:,:)   = ht_i(:,:,:) * a_i(:,:,:)
279      v_s(:,:,:)   = ht_s(:,:,:) * a_i(:,:,:)
280      smv_i(:,:,:) = sm_i(:,:,:) * v_i(:,:,:)
281
282      ! update ice age (in case a_i changed, i.e. becomes 0 or lateral melting in monocat)
283      DO jl  = 1, jpl
284         DO jj = 1, jpj
285            DO ji = 1, jpi
286               rswitch = MAX( 0._wp , SIGN( 1._wp, a_i_b(ji,jj,jl) - epsi10 ) )
287               oa_i(ji,jj,jl) = rswitch * oa_i(ji,jj,jl) * a_i(ji,jj,jl) / MAX( a_i_b(ji,jj,jl), epsi10 )
288            END DO
289         END DO
290      END DO
291
292      CALL lim_var_zapsmall
293
294      !--------------------------------------------
295      ! Diagnostic thermodynamic growth rates
296      !--------------------------------------------
297      IF( ln_icectl )   CALL lim_prt( kt, iiceprt, jiceprt, 1, ' - ice thermodyn. - ' )   ! control print
298
299      IF(ln_ctl) THEN            ! Control print
300         CALL prt_ctl_info(' ')
301         CALL prt_ctl_info(' - Cell values : ')
302         CALL prt_ctl_info('   ~~~~~~~~~~~~~ ')
303         CALL prt_ctl(tab2d_1=e1e2t, clinfo1=' lim_thd  : cell area :')
304         CALL prt_ctl(tab2d_1=at_i , clinfo1=' lim_thd  : at_i      :')
305         CALL prt_ctl(tab2d_1=vt_i , clinfo1=' lim_thd  : vt_i      :')
306         CALL prt_ctl(tab2d_1=vt_s , clinfo1=' lim_thd  : vt_s      :')
307         DO jl = 1, jpl
308            CALL prt_ctl_info(' ')
309            CALL prt_ctl_info(' - Category : ', ivar1=jl)
310            CALL prt_ctl_info('   ~~~~~~~~~~')
311            CALL prt_ctl(tab2d_1=a_i   (:,:,jl)   , clinfo1= ' lim_thd  : a_i      : ')
312            CALL prt_ctl(tab2d_1=ht_i  (:,:,jl)   , clinfo1= ' lim_thd  : ht_i     : ')
313            CALL prt_ctl(tab2d_1=ht_s  (:,:,jl)   , clinfo1= ' lim_thd  : ht_s     : ')
314            CALL prt_ctl(tab2d_1=v_i   (:,:,jl)   , clinfo1= ' lim_thd  : v_i      : ')
315            CALL prt_ctl(tab2d_1=v_s   (:,:,jl)   , clinfo1= ' lim_thd  : v_s      : ')
316            CALL prt_ctl(tab2d_1=e_s   (:,:,1,jl) , clinfo1= ' lim_thd  : e_s      : ')
317            CALL prt_ctl(tab2d_1=t_su  (:,:,jl)   , clinfo1= ' lim_thd  : t_su     : ')
318            CALL prt_ctl(tab2d_1=t_s   (:,:,1,jl) , clinfo1= ' lim_thd  : t_snow   : ')
319            CALL prt_ctl(tab2d_1=sm_i  (:,:,jl)   , clinfo1= ' lim_thd  : sm_i     : ')
320            CALL prt_ctl(tab2d_1=smv_i (:,:,jl)   , clinfo1= ' lim_thd  : smv_i    : ')
321            DO jk = 1, nlay_i
322               CALL prt_ctl_info(' ')
323               CALL prt_ctl_info(' - Layer : ', ivar1=jk)
324               CALL prt_ctl_info('   ~~~~~~~')
325               CALL prt_ctl(tab2d_1=t_i(:,:,jk,jl) , clinfo1= ' lim_thd  : t_i      : ')
326               CALL prt_ctl(tab2d_1=e_i(:,:,jk,jl) , clinfo1= ' lim_thd  : e_i      : ')
327            END DO
328         END DO
329      ENDIF
330      !
331      !
332      IF( ln_limdiahsb ) CALL lim_cons_hsm(1, 'limthd', zvi_b, zsmv_b, zei_b, zfw_b, zfs_b, zft_b)
333
334      !------------------------------------------------------------------------------|
335      !  6) Transport of ice between thickness categories.                           |
336      !------------------------------------------------------------------------------|
337      ! Given thermodynamic growth rates, transport ice between thickness categories.
338      IF( ln_limdiahsb ) CALL lim_cons_hsm(0, 'limitd_th_rem', zvi_b, zsmv_b, zei_b, zfw_b, zfs_b, zft_b)
339
340      IF( jpl > 1 )      CALL lim_itd_th_rem( 1, jpl, kt )
341
342      IF( ln_limdiahsb ) CALL lim_cons_hsm(1, 'limitd_th_rem', zvi_b, zsmv_b, zei_b, zfw_b, zfs_b, zft_b)
343
344      !------------------------------------------------------------------------------|
345      !  7) Add frazil ice growing in leads.
346      !------------------------------------------------------------------------------|
347      IF( ln_limdiahsb ) CALL lim_cons_hsm(0, 'limthd_lac', zvi_b, zsmv_b, zei_b, zfw_b, zfs_b, zft_b)
348
349      CALL lim_thd_lac
350     
351      IF( ln_limdiahsb ) CALL lim_cons_hsm(1, 'limthd_lac', zvi_b, zsmv_b, zei_b, zfw_b, zfs_b, zft_b)
352
353      ! Control print
354      IF(ln_ctl) THEN
355         CALL lim_var_glo2eqv
356
357         CALL prt_ctl_info(' ')
358         CALL prt_ctl_info(' - Cell values : ')
359         CALL prt_ctl_info('   ~~~~~~~~~~~~~ ')
360         CALL prt_ctl(tab2d_1=e1e2t, clinfo1=' lim_itd_th  : cell area :')
361         CALL prt_ctl(tab2d_1=at_i , clinfo1=' lim_itd_th  : at_i      :')
362         CALL prt_ctl(tab2d_1=vt_i , clinfo1=' lim_itd_th  : vt_i      :')
363         CALL prt_ctl(tab2d_1=vt_s , clinfo1=' lim_itd_th  : vt_s      :')
364         DO jl = 1, jpl
365            CALL prt_ctl_info(' ')
366            CALL prt_ctl_info(' - Category : ', ivar1=jl)
367            CALL prt_ctl_info('   ~~~~~~~~~~')
368            CALL prt_ctl(tab2d_1=a_i   (:,:,jl)   , clinfo1= ' lim_itd_th  : a_i      : ')
369            CALL prt_ctl(tab2d_1=ht_i  (:,:,jl)   , clinfo1= ' lim_itd_th  : ht_i     : ')
370            CALL prt_ctl(tab2d_1=ht_s  (:,:,jl)   , clinfo1= ' lim_itd_th  : ht_s     : ')
371            CALL prt_ctl(tab2d_1=v_i   (:,:,jl)   , clinfo1= ' lim_itd_th  : v_i      : ')
372            CALL prt_ctl(tab2d_1=v_s   (:,:,jl)   , clinfo1= ' lim_itd_th  : v_s      : ')
373            CALL prt_ctl(tab2d_1=e_s   (:,:,1,jl) , clinfo1= ' lim_itd_th  : e_s      : ')
374            CALL prt_ctl(tab2d_1=t_su  (:,:,jl)   , clinfo1= ' lim_itd_th  : t_su     : ')
375            CALL prt_ctl(tab2d_1=t_s   (:,:,1,jl) , clinfo1= ' lim_itd_th  : t_snow   : ')
376            CALL prt_ctl(tab2d_1=sm_i  (:,:,jl)   , clinfo1= ' lim_itd_th  : sm_i     : ')
377            CALL prt_ctl(tab2d_1=smv_i (:,:,jl)   , clinfo1= ' lim_itd_th  : smv_i    : ')
378            DO jk = 1, nlay_i
379               CALL prt_ctl_info(' ')
380               CALL prt_ctl_info(' - Layer : ', ivar1=jk)
381               CALL prt_ctl_info('   ~~~~~~~')
382               CALL prt_ctl(tab2d_1=t_i(:,:,jk,jl) , clinfo1= ' lim_itd_th  : t_i      : ')
383               CALL prt_ctl(tab2d_1=e_i(:,:,jk,jl) , clinfo1= ' lim_itd_th  : e_i      : ')
384            END DO
385         END DO
386      ENDIF
387      !
388      IF( nn_timing == 1 )   CALL timing_stop('limthd')
389      !
390   END SUBROUTINE lim_thd 
391
392 
393   SUBROUTINE lim_thd_temp( kideb, kiut )
394      !!-----------------------------------------------------------------------
395      !!                   ***  ROUTINE lim_thd_temp ***
396      !!                 
397      !! ** Purpose :   Computes sea ice temperature (Kelvin) from enthalpy
398      !!
399      !! ** Method  :   Formula (Bitz and Lipscomb, 1999)
400      !!-------------------------------------------------------------------
401      INTEGER, INTENT(in) ::   kideb, kiut   ! bounds for the spatial loop
402      !
403      INTEGER  ::   ji, jk   ! dummy loop indices
404      REAL(wp) ::   ztmelts, zaaa, zbbb, zccc, zdiscrim  ! local scalar
405      !!-------------------------------------------------------------------
406      ! Recover ice temperature
407      DO jk = 1, nlay_i
408         DO ji = kideb, kiut
409            ztmelts       =  -tmut * s_i_1d(ji,jk) + rt0
410            ! Conversion q(S,T) -> T (second order equation)
411            zaaa          =  cpic
412            zbbb          =  ( rcp - cpic ) * ( ztmelts - rt0 ) + q_i_1d(ji,jk) * r1_rhoic - lfus
413            zccc          =  lfus * ( ztmelts - rt0 )
414            zdiscrim      =  SQRT( MAX( zbbb * zbbb - 4._wp * zaaa * zccc, 0._wp ) )
415            t_i_1d(ji,jk) =  rt0 - ( zbbb + zdiscrim ) / ( 2._wp * zaaa )
416           
417            ! mask temperature
418            rswitch       =  1._wp - MAX( 0._wp , SIGN( 1._wp , - ht_i_1d(ji) ) ) 
419            t_i_1d(ji,jk) =  rswitch * t_i_1d(ji,jk) + ( 1._wp - rswitch ) * rt0
420         END DO
421      END DO 
422      !
423   END SUBROUTINE lim_thd_temp
424
425
426   SUBROUTINE lim_thd_lam( kideb, kiut )
427      !!-----------------------------------------------------------------------
428      !!                   ***  ROUTINE lim_thd_lam ***
429      !!                 
430      !! ** Purpose :   Lateral melting in case monocategory
431      !!                          ( dA = A/2h dh )
432      !!-----------------------------------------------------------------------
433      INTEGER, INTENT(in) ::   kideb, kiut        ! bounds for the spatial loop
434      !
435      INTEGER  ::   ji                 ! dummy loop indices
436      REAL(wp) ::   zhi_bef            ! ice thickness before thermo
437      REAL(wp) ::   zdh_mel, zda_mel   ! net melting
438      REAL(wp) ::   zvi, zvs           ! ice/snow volumes
439      !!-----------------------------------------------------------------------
440      !
441      DO ji = kideb, kiut
442         zdh_mel = MIN( 0._wp, dh_i_surf(ji) + dh_i_bott(ji) + dh_snowice(ji) )
443         IF( zdh_mel < 0._wp .AND. a_i_1d(ji) > 0._wp )  THEN
444            zvi          = a_i_1d(ji) * ht_i_1d(ji)
445            zvs          = a_i_1d(ji) * ht_s_1d(ji)
446            ! lateral melting = concentration change
447            zhi_bef     = ht_i_1d(ji) - zdh_mel
448            rswitch     = MAX( 0._wp , SIGN( 1._wp , zhi_bef - epsi20 ) )
449            zda_mel     = rswitch * a_i_1d(ji) * zdh_mel / ( 2._wp * MAX( zhi_bef, epsi20 ) )
450            a_i_1d(ji)  = MAX( epsi20, a_i_1d(ji) + zda_mel ) 
451             ! adjust thickness
452            ht_i_1d(ji) = zvi / a_i_1d(ji)           
453            ht_s_1d(ji) = zvs / a_i_1d(ji)           
454            ! retrieve total concentration
455            at_i_1d(ji) = a_i_1d(ji)
456         END IF
457      END DO
458      !
459   END SUBROUTINE lim_thd_lam
460
461
462   SUBROUTINE lim_thd_1d2d( nbpb, jl, kn )
463      !!-----------------------------------------------------------------------
464      !!                   ***  ROUTINE lim_thd_1d2d ***
465      !!                 
466      !! ** Purpose :   move arrays from 1d to 2d and the reverse
467      !!-----------------------------------------------------------------------
468      INTEGER, INTENT(in) ::   kn       ! 1= from 2D to 1D   ;   2= from 1D to 2D
469      INTEGER, INTENT(in) ::   nbpb     ! size of 1D arrays
470      INTEGER, INTENT(in) ::   jl       ! ice cat
471      !
472      INTEGER             ::   jk       ! dummy loop indices
473      !!-----------------------------------------------------------------------
474      !
475      SELECT CASE( kn )
476      !
477      CASE( 1 )            ! from 2D to 1D
478         !
479         CALL tab_2d_1d( nbpb, at_i_1d     (1:nbpb), at_i            , jpi, jpj, npb(1:nbpb) )
480         CALL tab_2d_1d( nbpb, a_i_1d      (1:nbpb), a_i(:,:,jl)     , jpi, jpj, npb(1:nbpb) )
481         CALL tab_2d_1d( nbpb, ht_i_1d     (1:nbpb), ht_i(:,:,jl)    , jpi, jpj, npb(1:nbpb) )
482         CALL tab_2d_1d( nbpb, ht_s_1d     (1:nbpb), ht_s(:,:,jl)    , jpi, jpj, npb(1:nbpb) )
483         !
484         CALL tab_2d_1d( nbpb, t_su_1d     (1:nbpb), t_su(:,:,jl)    , jpi, jpj, npb(1:nbpb) )
485         CALL tab_2d_1d( nbpb, sm_i_1d     (1:nbpb), sm_i(:,:,jl)    , jpi, jpj, npb(1:nbpb) )
486         DO jk = 1, nlay_s
487            CALL tab_2d_1d( nbpb, t_s_1d(1:nbpb,jk), t_s(:,:,jk,jl)  , jpi, jpj, npb(1:nbpb) )
488            CALL tab_2d_1d( nbpb, q_s_1d(1:nbpb,jk), e_s(:,:,jk,jl)  , jpi, jpj, npb(1:nbpb) )
489         END DO
490         DO jk = 1, nlay_i
491            CALL tab_2d_1d( nbpb, t_i_1d(1:nbpb,jk), t_i(:,:,jk,jl)  , jpi, jpj, npb(1:nbpb) )
492            CALL tab_2d_1d( nbpb, q_i_1d(1:nbpb,jk), e_i(:,:,jk,jl)  , jpi, jpj, npb(1:nbpb) )
493            CALL tab_2d_1d( nbpb, s_i_1d(1:nbpb,jk), s_i(:,:,jk,jl)  , jpi, jpj, npb(1:nbpb) )
494         END DO
495         !
496         CALL tab_2d_1d( nbpb, qprec_ice_1d(1:nbpb), qprec_ice(:,:) , jpi, jpj, npb(1:nbpb) )
497         CALL tab_2d_1d( nbpb, qsr_ice_1d (1:nbpb), qsr_ice(:,:,jl) , jpi, jpj, npb(1:nbpb) )
498         CALL tab_2d_1d( nbpb, fr1_i0_1d  (1:nbpb), fr1_i0          , jpi, jpj, npb(1:nbpb) )
499         CALL tab_2d_1d( nbpb, fr2_i0_1d  (1:nbpb), fr2_i0          , jpi, jpj, npb(1:nbpb) )
500         CALL tab_2d_1d( nbpb, qns_ice_1d (1:nbpb), qns_ice(:,:,jl) , jpi, jpj, npb(1:nbpb) )
501         CALL tab_2d_1d( nbpb, ftr_ice_1d (1:nbpb), ftr_ice(:,:,jl) , jpi, jpj, npb(1:nbpb) )
502         CALL tab_2d_1d( nbpb, evap_ice_1d (1:nbpb), evap_ice(:,:,jl), jpi, jpj, npb(1:nbpb) )
503         CALL tab_2d_1d( nbpb, dqns_ice_1d(1:nbpb), dqns_ice(:,:,jl), jpi, jpj, npb(1:nbpb) )
504         CALL tab_2d_1d( nbpb, t_bo_1d     (1:nbpb), t_bo            , jpi, jpj, npb(1:nbpb) )
505         CALL tab_2d_1d( nbpb, sprecip_1d (1:nbpb), sprecip         , jpi, jpj, npb(1:nbpb) ) 
506         CALL tab_2d_1d( nbpb, fhtur_1d   (1:nbpb), fhtur           , jpi, jpj, npb(1:nbpb) )
507         CALL tab_2d_1d( nbpb, qlead_1d   (1:nbpb), qlead           , jpi, jpj, npb(1:nbpb) )
508         CALL tab_2d_1d( nbpb, fhld_1d    (1:nbpb), fhld            , jpi, jpj, npb(1:nbpb) )
509         !
510         CALL tab_2d_1d( nbpb, wfx_snw_1d (1:nbpb), wfx_snw         , jpi, jpj, npb(1:nbpb) )
511         CALL tab_2d_1d( nbpb, wfx_sub_1d (1:nbpb), wfx_sub         , jpi, jpj, npb(1:nbpb) )
512         !
513         CALL tab_2d_1d( nbpb, wfx_bog_1d (1:nbpb), wfx_bog         , jpi, jpj, npb(1:nbpb) )
514         CALL tab_2d_1d( nbpb, wfx_bom_1d (1:nbpb), wfx_bom         , jpi, jpj, npb(1:nbpb) )
515         CALL tab_2d_1d( nbpb, wfx_sum_1d (1:nbpb), wfx_sum         , jpi, jpj, npb(1:nbpb) )
516         CALL tab_2d_1d( nbpb, wfx_sni_1d (1:nbpb), wfx_sni         , jpi, jpj, npb(1:nbpb) )
517         CALL tab_2d_1d( nbpb, wfx_res_1d (1:nbpb), wfx_res         , jpi, jpj, npb(1:nbpb) )
518         CALL tab_2d_1d( nbpb, wfx_spr_1d (1:nbpb), wfx_spr         , jpi, jpj, npb(1:nbpb) )
519         !
520         CALL tab_2d_1d( nbpb, sfx_bog_1d (1:nbpb), sfx_bog         , jpi, jpj, npb(1:nbpb) )
521         CALL tab_2d_1d( nbpb, sfx_bom_1d (1:nbpb), sfx_bom         , jpi, jpj, npb(1:nbpb) )
522         CALL tab_2d_1d( nbpb, sfx_sum_1d (1:nbpb), sfx_sum         , jpi, jpj, npb(1:nbpb) )
523         CALL tab_2d_1d( nbpb, sfx_sni_1d (1:nbpb), sfx_sni         , jpi, jpj, npb(1:nbpb) )
524         CALL tab_2d_1d( nbpb, sfx_bri_1d (1:nbpb), sfx_bri         , jpi, jpj, npb(1:nbpb) )
525         CALL tab_2d_1d( nbpb, sfx_res_1d (1:nbpb), sfx_res         , jpi, jpj, npb(1:nbpb) )
526         !
527         CALL tab_2d_1d( nbpb, hfx_thd_1d (1:nbpb), hfx_thd         , jpi, jpj, npb(1:nbpb) )
528         CALL tab_2d_1d( nbpb, hfx_spr_1d (1:nbpb), hfx_spr         , jpi, jpj, npb(1:nbpb) )
529         CALL tab_2d_1d( nbpb, hfx_sum_1d (1:nbpb), hfx_sum         , jpi, jpj, npb(1:nbpb) )
530         CALL tab_2d_1d( nbpb, hfx_bom_1d (1:nbpb), hfx_bom         , jpi, jpj, npb(1:nbpb) )
531         CALL tab_2d_1d( nbpb, hfx_bog_1d (1:nbpb), hfx_bog         , jpi, jpj, npb(1:nbpb) )
532         CALL tab_2d_1d( nbpb, hfx_dif_1d (1:nbpb), hfx_dif         , jpi, jpj, npb(1:nbpb) )
533         CALL tab_2d_1d( nbpb, hfx_opw_1d (1:nbpb), hfx_opw         , jpi, jpj, npb(1:nbpb) )
534         CALL tab_2d_1d( nbpb, hfx_snw_1d (1:nbpb), hfx_snw         , jpi, jpj, npb(1:nbpb) )
535         CALL tab_2d_1d( nbpb, hfx_sub_1d (1:nbpb), hfx_sub         , jpi, jpj, npb(1:nbpb) )
536         CALL tab_2d_1d( nbpb, hfx_err_1d (1:nbpb), hfx_err         , jpi, jpj, npb(1:nbpb) )
537         CALL tab_2d_1d( nbpb, hfx_res_1d (1:nbpb), hfx_res         , jpi, jpj, npb(1:nbpb) )
538         CALL tab_2d_1d( nbpb, hfx_err_dif_1d (1:nbpb), hfx_err_dif , jpi, jpj, npb(1:nbpb) )
539         CALL tab_2d_1d( nbpb, hfx_err_rem_1d (1:nbpb), hfx_err_rem , jpi, jpj, npb(1:nbpb) )
540         !
541      CASE( 2 )            ! from 1D to 2D
542         !
543         CALL tab_1d_2d( nbpb, at_i          , npb, at_i_1d    (1:nbpb)   , jpi, jpj )
544         CALL tab_1d_2d( nbpb, ht_i(:,:,jl)  , npb, ht_i_1d    (1:nbpb)   , jpi, jpj )
545         CALL tab_1d_2d( nbpb, ht_s(:,:,jl)  , npb, ht_s_1d    (1:nbpb)   , jpi, jpj )
546         CALL tab_1d_2d( nbpb, a_i (:,:,jl)  , npb, a_i_1d     (1:nbpb)   , jpi, jpj )
547         CALL tab_1d_2d( nbpb, t_su(:,:,jl)  , npb, t_su_1d    (1:nbpb)   , jpi, jpj )
548         CALL tab_1d_2d( nbpb, sm_i(:,:,jl)  , npb, sm_i_1d    (1:nbpb)   , jpi, jpj )
549         DO jk = 1, nlay_s
550            CALL tab_1d_2d( nbpb, t_s(:,:,jk,jl), npb, t_s_1d     (1:nbpb,jk), jpi, jpj)
551            CALL tab_1d_2d( nbpb, e_s(:,:,jk,jl), npb, q_s_1d     (1:nbpb,jk), jpi, jpj)
552         END DO
553         DO jk = 1, nlay_i
554            CALL tab_1d_2d( nbpb, t_i(:,:,jk,jl), npb, t_i_1d     (1:nbpb,jk), jpi, jpj)
555            CALL tab_1d_2d( nbpb, e_i(:,:,jk,jl), npb, q_i_1d     (1:nbpb,jk), jpi, jpj)
556            CALL tab_1d_2d( nbpb, s_i(:,:,jk,jl), npb, s_i_1d     (1:nbpb,jk), jpi, jpj)
557         END DO
558         CALL tab_1d_2d( nbpb, qlead         , npb, qlead_1d  (1:nbpb)   , jpi, jpj )
559         !
560         CALL tab_1d_2d( nbpb, wfx_snw       , npb, wfx_snw_1d(1:nbpb)   , jpi, jpj )
561         CALL tab_1d_2d( nbpb, wfx_sub       , npb, wfx_sub_1d(1:nbpb)   , jpi, jpj )
562         !
563         CALL tab_1d_2d( nbpb, wfx_bog       , npb, wfx_bog_1d(1:nbpb)   , jpi, jpj )
564         CALL tab_1d_2d( nbpb, wfx_bom       , npb, wfx_bom_1d(1:nbpb)   , jpi, jpj )
565         CALL tab_1d_2d( nbpb, wfx_sum       , npb, wfx_sum_1d(1:nbpb)   , jpi, jpj )
566         CALL tab_1d_2d( nbpb, wfx_sni       , npb, wfx_sni_1d(1:nbpb)   , jpi, jpj )
567         CALL tab_1d_2d( nbpb, wfx_res       , npb, wfx_res_1d(1:nbpb)   , jpi, jpj )
568         CALL tab_1d_2d( nbpb, wfx_spr       , npb, wfx_spr_1d(1:nbpb)   , jpi, jpj )
569         !
570         CALL tab_1d_2d( nbpb, sfx_bog       , npb, sfx_bog_1d(1:nbpb)   , jpi, jpj )
571         CALL tab_1d_2d( nbpb, sfx_bom       , npb, sfx_bom_1d(1:nbpb)   , jpi, jpj )
572         CALL tab_1d_2d( nbpb, sfx_sum       , npb, sfx_sum_1d(1:nbpb)   , jpi, jpj )
573         CALL tab_1d_2d( nbpb, sfx_sni       , npb, sfx_sni_1d(1:nbpb)   , jpi, jpj )
574         CALL tab_1d_2d( nbpb, sfx_res       , npb, sfx_res_1d(1:nbpb)   , jpi, jpj )
575         CALL tab_1d_2d( nbpb, sfx_bri       , npb, sfx_bri_1d(1:nbpb)   , jpi, jpj )
576         !
577         CALL tab_1d_2d( nbpb, hfx_thd       , npb, hfx_thd_1d(1:nbpb)   , jpi, jpj )
578         CALL tab_1d_2d( nbpb, hfx_spr       , npb, hfx_spr_1d(1:nbpb)   , jpi, jpj )
579         CALL tab_1d_2d( nbpb, hfx_sum       , npb, hfx_sum_1d(1:nbpb)   , jpi, jpj )
580         CALL tab_1d_2d( nbpb, hfx_bom       , npb, hfx_bom_1d(1:nbpb)   , jpi, jpj )
581         CALL tab_1d_2d( nbpb, hfx_bog       , npb, hfx_bog_1d(1:nbpb)   , jpi, jpj )
582         CALL tab_1d_2d( nbpb, hfx_dif       , npb, hfx_dif_1d(1:nbpb)   , jpi, jpj )
583         CALL tab_1d_2d( nbpb, hfx_opw       , npb, hfx_opw_1d(1:nbpb)   , jpi, jpj )
584         CALL tab_1d_2d( nbpb, hfx_snw       , npb, hfx_snw_1d(1:nbpb)   , jpi, jpj )
585         CALL tab_1d_2d( nbpb, hfx_sub       , npb, hfx_sub_1d(1:nbpb)   , jpi, jpj )
586         CALL tab_1d_2d( nbpb, hfx_err       , npb, hfx_err_1d(1:nbpb)   , jpi, jpj )
587         CALL tab_1d_2d( nbpb, hfx_res       , npb, hfx_res_1d(1:nbpb)   , jpi, jpj )
588         CALL tab_1d_2d( nbpb, hfx_err_rem   , npb, hfx_err_rem_1d(1:nbpb), jpi, jpj )
589         CALL tab_1d_2d( nbpb, hfx_err_dif   , npb, hfx_err_dif_1d(1:nbpb), jpi, jpj )
590         !
591         CALL tab_1d_2d( nbpb, qns_ice(:,:,jl), npb, qns_ice_1d(1:nbpb) , jpi, jpj)
592         CALL tab_1d_2d( nbpb, ftr_ice(:,:,jl), npb, ftr_ice_1d(1:nbpb) , jpi, jpj )
593         !         
594      END SELECT
595      !
596   END SUBROUTINE lim_thd_1d2d
597
598
599   SUBROUTINE lim_thd_init
600      !!-----------------------------------------------------------------------
601      !!                   ***  ROUTINE lim_thd_init ***
602      !!                 
603      !! ** Purpose :   Physical constants and parameters linked to the ice
604      !!              thermodynamics
605      !!
606      !! ** Method  :   Read the namicethd namelist and check the ice-thermo
607      !!              parameter values called at the first timestep (nit000)
608      !!
609      !! ** input   :   Namelist namicether
610      !!-------------------------------------------------------------------
611      INTEGER  ::   ios                 ! Local integer output status for namelist read
612      !!
613      NAMELIST/namicethd/ rn_hnewice, ln_frazil, rn_maxfrazb, rn_vfrazb, rn_Cfrazb,                &
614         &                rn_himin, rn_betas, rn_kappa_i, nn_conv_dif, rn_terr_dif, nn_ice_thcon,  &
615         &                nn_monocat, ln_it_qnsice
616      !!-------------------------------------------------------------------
617      !
618      IF(lwp) THEN
619         WRITE(numout,*)
620         WRITE(numout,*) 'lim_thd : Ice Thermodynamics'
621         WRITE(numout,*) '~~~~~~~'
622      ENDIF
623      !
624      REWIND( numnam_ice_ref )              ! Namelist namicethd in reference namelist : Ice thermodynamics
625      READ  ( numnam_ice_ref, namicethd, IOSTAT = ios, ERR = 901)
626901   IF( ios /= 0 ) CALL ctl_nam ( ios , 'namicethd in reference namelist', lwp )
627
628      REWIND( numnam_ice_cfg )              ! Namelist namicethd in configuration namelist : Ice thermodynamics
629      READ  ( numnam_ice_cfg, namicethd, IOSTAT = ios, ERR = 902 )
630902   IF( ios /= 0 ) CALL ctl_nam ( ios , 'namicethd in configuration namelist', lwp )
631      IF(lwm) WRITE ( numoni, namicethd )
632      !
633      IF ( ( jpl > 1 ) .AND. ( nn_monocat == 1 ) ) THEN
634         nn_monocat = 0
635         IF(lwp) WRITE(numout, *) '   nn_monocat must be 0 in multi-category case '
636      ENDIF
637
638      !
639      IF(lwp) THEN                          ! control print
640         WRITE(numout,*)
641         WRITE(numout,*)'   Namelist of ice parameters for ice thermodynamic computation '
642         WRITE(numout,*)'      ice thick. for lateral accretion                        rn_hnewice   = ', rn_hnewice
643         WRITE(numout,*)'      Frazil ice thickness as a function of wind or not       ln_frazil    = ', ln_frazil
644         WRITE(numout,*)'      Maximum proportion of frazil ice collecting at bottom   rn_maxfrazb  = ', rn_maxfrazb
645         WRITE(numout,*)'      Thresold relative drift speed for collection of frazil  rn_vfrazb    = ', rn_vfrazb
646         WRITE(numout,*)'      Squeezing coefficient for collection of frazil          rn_Cfrazb    = ', rn_Cfrazb
647         WRITE(numout,*)'      minimum ice thickness                                   rn_himin     = ', rn_himin 
648         WRITE(numout,*)'      numerical carac. of the scheme for diffusion in ice '
649         WRITE(numout,*)'      coefficient for ice-lead partition of snowfall          rn_betas     = ', rn_betas
650         WRITE(numout,*)'      extinction radiation parameter in sea ice               rn_kappa_i   = ', rn_kappa_i
651         WRITE(numout,*)'      maximal n. of iter. for heat diffusion computation      nn_conv_dif  = ', nn_conv_dif
652         WRITE(numout,*)'      maximal err. on T for heat diffusion computation        rn_terr_dif  = ', rn_terr_dif
653         WRITE(numout,*)'      switch for comp. of thermal conductivity in the ice     nn_ice_thcon = ', nn_ice_thcon
654         WRITE(numout,*)'      check heat conservation in the ice/snow                 con_i        = ', con_i
655         WRITE(numout,*)'      virtual ITD mono-category parameterizations (1) or not  nn_monocat   = ', nn_monocat
656         WRITE(numout,*)'      iterate the surface non-solar flux (T) or not (F)       ln_it_qnsice = ', ln_it_qnsice
657      ENDIF
658      !
659   END SUBROUTINE lim_thd_init
660
661#else
662   !!----------------------------------------------------------------------
663   !!   Default option         Dummy module          NO  LIM3 sea-ice model
664   !!----------------------------------------------------------------------
665#endif
666
667   !!======================================================================
668END MODULE limthd
Note: See TracBrowser for help on using the repository browser.