New URL for NEMO forge!   http://forge.nemo-ocean.eu

Since March 2022 along with NEMO 4.2 release, the code development moved to a self-hosted GitLab.
This present forge is now archived and remained online for history.
diaar5.F90 in branches/2015/dev_r5836_NOC3_vvl_by_default/NEMOGCM/NEMO/OPA_SRC/DIA – NEMO

source: branches/2015/dev_r5836_NOC3_vvl_by_default/NEMOGCM/NEMO/OPA_SRC/DIA/diaar5.F90 @ 6004

Last change on this file since 6004 was 6004, checked in by gm, 8 years ago

#1613: vvl by default, step III: Merge with the trunk (free surface simplification) (see wiki)
  • Property svn:keywords set to Id
File size: 12.6 KB
Line 
1MODULE diaar5
2   !!======================================================================
3   !!                       ***  MODULE  diaar5  ***
4   !! AR5 diagnostics
5   !!======================================================================
6   !! History :  3.2  !  2009-11  (S. Masson)  Original code
7   !!            3.3  !  2010-10  (C. Ethe, G. Madec) reorganisation of initialisation phase + merge TRC-TRA
8   !!----------------------------------------------------------------------
9#if defined key_diaar5
10   !!----------------------------------------------------------------------
11   !!   'key_diaar5'  :                           activate ar5 diagnotics
12   !!----------------------------------------------------------------------
13   !!   dia_ar5       : AR5 diagnostics
14   !!   dia_ar5_init  : initialisation of AR5 diagnostics
15   !!----------------------------------------------------------------------
16   USE oce            ! ocean dynamics and active tracers
17   USE dom_oce        ! ocean space and time domain
18   USE eosbn2         ! equation of state                (eos_bn2 routine)
19   USE lib_mpp        ! distribued memory computing library
20   USE iom            ! I/O manager library
21   USE timing         ! preformance summary
22   USE wrk_nemo       ! working arrays
23   USE fldread        ! type FLD_N
24   USE phycst         ! physical constant
25   USE in_out_manager  ! I/O manager
26
27   IMPLICIT NONE
28   PRIVATE
29
30   PUBLIC   dia_ar5        ! routine called in step.F90 module
31   PUBLIC   dia_ar5_init   ! routine called in opa.F90 module
32   PUBLIC   dia_ar5_alloc  ! routine called in nemogcm.F90 module
33
34   LOGICAL, PUBLIC, PARAMETER :: lk_diaar5 = .TRUE.   ! coupled flag
35
36   REAL(wp)                         ::   vol0         ! ocean volume (interior domain)
37   REAL(wp)                         ::   area_tot     ! total ocean surface (interior domain)
38   REAL(wp), ALLOCATABLE, SAVE, DIMENSION(:,:  ) ::   area         ! cell surface (interior domain)
39   REAL(wp), ALLOCATABLE, SAVE, DIMENSION(:,:  ) ::   thick0       ! ocean thickness (interior domain)
40   REAL(wp), ALLOCATABLE, SAVE, DIMENSION(:,:,:) ::   sn0          ! initial salinity
41     
42   !!----------------------------------------------------------------------
43   !! NEMO/OPA 3.3 , NEMO Consortium (2010)
44   !! $Id$
45   !! Software governed by the CeCILL licence     (NEMOGCM/NEMO_CeCILL.txt)
46   !!----------------------------------------------------------------------
47CONTAINS
48
49   FUNCTION dia_ar5_alloc()
50      !!----------------------------------------------------------------------
51      !!                    ***  ROUTINE dia_ar5_alloc  ***
52      !!----------------------------------------------------------------------
53      INTEGER :: dia_ar5_alloc
54      !!----------------------------------------------------------------------
55      !
56      ALLOCATE( area(jpi,jpj), thick0(jpi,jpj) , sn0(jpi,jpj,jpk) , STAT=dia_ar5_alloc )
57      !
58      IF( lk_mpp             )   CALL mpp_sum ( dia_ar5_alloc )
59      IF( dia_ar5_alloc /= 0 )   CALL ctl_warn('dia_ar5_alloc: failed to allocate arrays')
60      !
61   END FUNCTION dia_ar5_alloc
62
63
64   SUBROUTINE dia_ar5( kt )
65      !!----------------------------------------------------------------------
66      !!                    ***  ROUTINE dia_ar5  ***
67      !!
68      !! ** Purpose :   compute and output some AR5 diagnostics
69      !!----------------------------------------------------------------------
70      !
71      INTEGER, INTENT( in ) ::   kt   ! ocean time-step index
72      !
73      INTEGER  ::   ji, jj, jk                      ! dummy loop arguments
74      REAL(wp) ::   zvolssh, zvol, zssh_steric, zztmp, zarho, ztemp, zsal, zmass
75      !
76      REAL(wp), POINTER, DIMENSION(:,:)     :: zarea_ssh , zbotpres       ! 2D workspace
77      REAL(wp), POINTER, DIMENSION(:,:,:)   :: zrhd , zrhop               ! 3D workspace
78      REAL(wp), POINTER, DIMENSION(:,:,:,:) :: ztsn                       ! 4D workspace
79      !!--------------------------------------------------------------------
80      IF( nn_timing == 1 )   CALL timing_start('dia_ar5')
81 
82      CALL wrk_alloc( jpi , jpj              , zarea_ssh , zbotpres )
83      CALL wrk_alloc( jpi , jpj , jpk        , zrhd      , zrhop    )
84      CALL wrk_alloc( jpi , jpj , jpk , jpts , ztsn                 )
85
86      zarea_ssh(:,:) = area(:,:) * sshn(:,:)
87
88      !                                         ! total volume of liquid seawater
89      zvolssh = SUM( zarea_ssh(:,:) ) 
90      IF( lk_mpp )   CALL mpp_sum( zvolssh )
91      zvol = vol0 + zvolssh
92     
93      CALL iom_put( 'voltot', zvol               )
94      CALL iom_put( 'sshtot', zvolssh / area_tot )
95
96      !                     
97      ztsn(:,:,:,jp_tem) = tsn(:,:,:,jp_tem)                    ! thermosteric ssh
98      ztsn(:,:,:,jp_sal) = sn0(:,:,:)
99      CALL eos( ztsn, zrhd, gdept_n(:,:,:) )                       ! now in situ density using initial salinity
100      !
101      zbotpres(:,:) = 0._wp                        ! no atmospheric surface pressure, levitating sea-ice
102      DO jk = 1, jpkm1
103         zbotpres(:,:) = zbotpres(:,:) + e3t_n(:,:,jk) * zrhd(:,:,jk)
104      END DO
105      IF( ln_linssh ) THEN
106         IF( ln_isfcav ) THEN
107            DO ji=1,jpi
108               DO jj=1,jpj
109                  zbotpres(ji,jj) = zbotpres(ji,jj) + sshn(ji,jj) * zrhd(ji,jj,mikt(ji,jj)) + riceload(ji,jj)
110               END DO
111            END DO
112         ELSE
113            zbotpres(:,:) = zbotpres(:,:) + sshn(:,:) * zrhd(:,:,1)
114         END IF
115!!gm
116!!gm   riceload should be added in both ln_linssh=T or F, no?
117!!gm
118      END IF
119      !                                         
120      zarho = SUM( area(:,:) * zbotpres(:,:) ) 
121      IF( lk_mpp )   CALL mpp_sum( zarho )
122      zssh_steric = - zarho / area_tot
123      CALL iom_put( 'sshthster', zssh_steric )
124     
125      !                                         ! steric sea surface height
126      CALL eos( tsn, zrhd, zrhop, gdept_n(:,:,:) )                 ! now in situ and potential density
127      zrhop(:,:,jpk) = 0._wp
128      CALL iom_put( 'rhop', zrhop )
129      !
130      zbotpres(:,:) = 0._wp                        ! no atmospheric surface pressure, levitating sea-ice
131      DO jk = 1, jpkm1
132         zbotpres(:,:) = zbotpres(:,:) + e3t_n(:,:,jk) * zrhd(:,:,jk)
133      END DO
134      IF( ln_linssh ) THEN
135         IF ( ln_isfcav ) THEN
136            DO ji=1,jpi
137               DO jj=1,jpj
138                  zbotpres(ji,jj) = zbotpres(ji,jj) + sshn(ji,jj) * zrhd(ji,jj,mikt(ji,jj)) + riceload(ji,jj)
139               END DO
140            END DO
141         ELSE
142            zbotpres(:,:) = zbotpres(:,:) + sshn(:,:) * zrhd(:,:,1)
143         END IF
144      END IF
145      !   
146      zarho = SUM( area(:,:) * zbotpres(:,:) ) 
147      IF( lk_mpp )   CALL mpp_sum( zarho )
148      zssh_steric = - zarho / area_tot
149      CALL iom_put( 'sshsteric', zssh_steric )
150     
151      !                                         ! ocean bottom pressure
152      zztmp = rau0 * grav * 1.e-4_wp               ! recover pressure from pressure anomaly and cover to dbar = 1.e4 Pa
153      zbotpres(:,:) = zztmp * ( zbotpres(:,:) + sshn(:,:) + thick0(:,:) )
154      CALL iom_put( 'botpres', zbotpres )
155
156      !                                         ! Mean density anomalie, temperature and salinity
157      ztemp = 0._wp
158      zsal  = 0._wp
159      DO jk = 1, jpkm1
160         DO jj = 1, jpj
161            DO ji = 1, jpi
162               zztmp = area(ji,jj) * e3t_n(ji,jj,jk)
163               ztemp = ztemp + zztmp * tsn(ji,jj,jk,jp_tem)
164               zsal  = zsal  + zztmp * tsn(ji,jj,jk,jp_sal)
165            END DO
166         END DO
167      END DO
168      IF( ln_linssh ) THEN
169         IF( ln_isfcav ) THEN
170            DO ji=1,jpi
171               DO jj=1,jpj
172                  ztemp = ztemp + zarea_ssh(ji,jj) * tsn(ji,jj,mikt(ji,jj),jp_tem) 
173                  zsal  = zsal  + zarea_ssh(ji,jj) * tsn(ji,jj,mikt(ji,jj),jp_sal) 
174               END DO
175            END DO
176         ELSE
177            ztemp = ztemp + SUM( zarea_ssh(:,:) * tsn(:,:,1,jp_tem) )
178            zsal  = zsal  + SUM( zarea_ssh(:,:) * tsn(:,:,1,jp_sal) )
179         END IF
180      ENDIF
181      IF( lk_mpp ) THEN 
182         CALL mpp_sum( ztemp )
183         CALL mpp_sum( zsal  )
184      END IF
185      !
186      zmass = rau0 * ( zarho + zvol )                 ! total mass of liquid seawater
187      ztemp = ztemp / zvol                            ! potential temperature in liquid seawater
188      zsal  = zsal  / zvol                            ! Salinity of liquid seawater
189      !
190      CALL iom_put( 'masstot', zmass )
191      CALL iom_put( 'temptot', ztemp )
192      CALL iom_put( 'saltot' , zsal  )
193      !
194      CALL wrk_dealloc( jpi , jpj              , zarea_ssh , zbotpres )
195      CALL wrk_dealloc( jpi , jpj , jpk        , zrhd      , zrhop    )
196      CALL wrk_dealloc( jpi , jpj , jpk , jpts , ztsn                 )
197      !
198      IF( nn_timing == 1 )   CALL timing_stop('dia_ar5')
199      !
200   END SUBROUTINE dia_ar5
201
202
203   SUBROUTINE dia_ar5_init
204      !!----------------------------------------------------------------------
205      !!                  ***  ROUTINE dia_ar5_init  ***
206      !!                   
207      !! ** Purpose :   initialization for AR5 diagnostic computation
208      !!----------------------------------------------------------------------
209      INTEGER  ::   inum
210      INTEGER  ::   ik
211      INTEGER  ::   ji, jj, jk  ! dummy loop indices
212      REAL(wp) ::   zztmp 
213      REAL(wp), POINTER, DIMENSION(:,:,:,:) ::   zsaldta   ! Jan/Dec levitus salinity
214      ! reading initial file
215      LOGICAL  ::   ln_tsd_init      !: T & S data flag
216      LOGICAL  ::   ln_tsd_tradmp    !: internal damping toward input data flag
217      CHARACTER(len=100)            ::   cn_dir
218      TYPE(FLD_N)                   ::  sn_tem,sn_sal
219      INTEGER  ::   ios=0
220
221      NAMELIST/namtsd/ ln_tsd_init,ln_tsd_tradmp,cn_dir,sn_tem,sn_sal
222      !
223
224      REWIND( numnam_ref )              ! Namelist namtsd in reference namelist :
225      READ  ( numnam_ref, namtsd, IOSTAT = ios, ERR = 901)
226901   IF( ios /= 0 ) CALL ctl_nam ( ios , ' namtsd in reference namelist for dia_ar5', lwp )
227      REWIND( numnam_cfg )              ! Namelist namtsd in configuration namelist : Parameters of the run
228      READ  ( numnam_cfg, namtsd, IOSTAT = ios, ERR = 902 )
229902   IF( ios /= 0 ) CALL ctl_nam ( ios , ' namtsd in configuration namelist for dia_ar5', lwp )
230      IF(lwm) WRITE ( numond, namtsd )
231      !
232      !!----------------------------------------------------------------------
233      !
234      IF( nn_timing == 1 )   CALL timing_start('dia_ar5_init')
235      !
236      CALL wrk_alloc( jpi , jpj , jpk, jpts, zsaldta )
237      !                                      ! allocate dia_ar5 arrays
238      IF( dia_ar5_alloc() /= 0 )   CALL ctl_stop( 'STOP', 'dia_ar5_init : unable to allocate arrays' )
239
240      area(:,:) = e1e2t(:,:) * tmask_i(:,:)
241
242      area_tot = SUM( area(:,:) )   ;   IF( lk_mpp )   CALL mpp_sum( area_tot )
243
244      vol0        = 0._wp
245      thick0(:,:) = 0._wp
246      DO jk = 1, jpkm1
247         vol0        = vol0        + SUM( area (:,:) * tmask(:,:,jk) * e3t_0(:,:,jk) )
248         thick0(:,:) = thick0(:,:) +    tmask_i(:,:) * tmask(:,:,jk) * e3t_0(:,:,jk)
249      END DO
250      IF( lk_mpp )   CALL mpp_sum( vol0 )
251
252      CALL iom_open ( TRIM( cn_dir )//TRIM(sn_sal%clname), inum )
253      CALL iom_get  ( inum, jpdom_data, TRIM(sn_sal%clvar), zsaldta(:,:,:,1), 1  )
254      CALL iom_get  ( inum, jpdom_data, TRIM(sn_sal%clvar), zsaldta(:,:,:,2), 12 )
255      CALL iom_close( inum )
256      sn0(:,:,:) = 0.5_wp * ( zsaldta(:,:,:,1) + zsaldta(:,:,:,2) )       
257      sn0(:,:,:) = sn0(:,:,:) * tmask(:,:,:)
258      IF( ln_zps ) THEN               ! z-coord. partial steps
259         DO jj = 1, jpj               ! interpolation of salinity at the last ocean level (i.e. the partial step)
260            DO ji = 1, jpi
261               ik = mbkt(ji,jj)
262               IF( ik > 1 ) THEN
263                  zztmp = ( gdept_1d(ik) - gdept_0(ji,jj,ik) ) / ( gdept_1d(ik) - gdept_1d(ik-1) )
264                  sn0(ji,jj,ik) = ( 1._wp - zztmp ) * sn0(ji,jj,ik) + zztmp * sn0(ji,jj,ik-1)
265               ENDIF
266            END DO
267         END DO
268      ENDIF
269      !
270      CALL wrk_dealloc( jpi , jpj , jpk, jpts, zsaldta )
271      !
272      IF( nn_timing == 1 )   CALL timing_stop('dia_ar5_init')
273      !
274   END SUBROUTINE dia_ar5_init
275
276#else
277   !!----------------------------------------------------------------------
278   !!   Default option :                                         NO diaar5
279   !!----------------------------------------------------------------------
280   LOGICAL, PUBLIC, PARAMETER :: lk_diaar5 = .FALSE.   ! coupled flag
281CONTAINS
282   SUBROUTINE dia_ar5_init    ! Dummy routine
283   END SUBROUTINE dia_ar5_init
284   SUBROUTINE dia_ar5( kt )   ! Empty routine
285      INTEGER ::   kt
286      WRITE(*,*) 'dia_ar5: You should not have seen this print! error?', kt
287   END SUBROUTINE dia_ar5
288#endif
289
290   !!======================================================================
291END MODULE diaar5
Note: See TracBrowser for help on using the repository browser.