New URL for NEMO forge!   http://forge.nemo-ocean.eu

Since March 2022 along with NEMO 4.2 release, the code development moved to a self-hosted GitLab.
This present forge is now archived and remained online for history.
dynhpg.F90 in branches/2015/dev_r5836_NOC3_vvl_by_default/NEMOGCM/NEMO/OPA_SRC/DYN – NEMO

source: branches/2015/dev_r5836_NOC3_vvl_by_default/NEMOGCM/NEMO/OPA_SRC/DYN/dynhpg.F90 @ 6004

Last change on this file since 6004 was 6004, checked in by gm, 8 years ago

#1613: vvl by default, step III: Merge with the trunk (free surface simplification) (see wiki)
  • Property svn:keywords set to Id
File size: 70.4 KB
Line 
1MODULE dynhpg
2   !!======================================================================
3   !!                       ***  MODULE  dynhpg  ***
4   !! Ocean dynamics:  hydrostatic pressure gradient trend
5   !!======================================================================
6   !! History :  OPA  !  1987-09  (P. Andrich, M.-A. Foujols)  hpg_zco: Original code
7   !!            5.0  !  1991-11  (G. Madec)
8   !!            7.0  !  1996-01  (G. Madec)  hpg_sco: Original code for s-coordinates
9   !!            8.0  !  1997-05  (G. Madec)  split dynber into dynkeg and dynhpg
10   !!            8.5  !  2002-07  (G. Madec)  F90: Free form and module
11   !!            8.5  !  2002-08  (A. Bozec)  hpg_zps: Original code
12   !!   NEMO     1.0  !  2005-10  (A. Beckmann, B.W. An)  various s-coordinate options
13   !!                 !         Original code for hpg_ctl, hpg_hel hpg_wdj, hpg_djc, hpg_rot
14   !!             -   !  2005-11  (G. Madec) style & small optimisation
15   !!            3.3  !  2010-10  (C. Ethe, G. Madec) reorganisation of initialisation phase
16   !!            3.4  !  2011-11  (H. Liu) hpg_prj: Original code for s-coordinates
17   !!                 !           (A. Coward) suppression of hel, wdj and rot options
18   !!            3.6  !  2014-11  (P. Mathiot) hpg_isf: original code for ice shelf cavity
19   !!----------------------------------------------------------------------
20
21   !!----------------------------------------------------------------------
22   !!   dyn_hpg      : update the momentum trend with the now horizontal
23   !!                  gradient of the hydrostatic pressure
24   !!   dyn_hpg_init : initialisation and control of options
25   !!       hpg_zco  : z-coordinate scheme
26   !!       hpg_zps  : z-coordinate plus partial steps (interpolation)
27   !!       hpg_sco  : s-coordinate (standard jacobian formulation)
28   !!       hpg_isf  : s-coordinate (sco formulation) adapted to ice shelf
29   !!       hpg_djc  : s-coordinate (Density Jacobian with Cubic polynomial)
30   !!       hpg_prj  : s-coordinate (Pressure Jacobian with Cubic polynomial)
31   !!----------------------------------------------------------------------
32   USE oce             ! ocean dynamics and tracers
33   USE sbc_oce         ! surface variable (only for the flag with ice shelf)
34   USE dom_oce         ! ocean space and time domain
35   USE phycst          ! physical constants
36   USE trd_oce         ! trends: ocean variables
37   USE trddyn          ! trend manager: dynamics
38!jc   USE zpshde          ! partial step: hor. derivative     (zps_hde routine)
39   !
40   USE in_out_manager  ! I/O manager
41   USE prtctl          ! Print control
42   USE lbclnk          ! lateral boundary condition
43   USE lib_mpp         ! MPP library
44   USE eosbn2          ! compute density
45   USE wrk_nemo        ! Memory Allocation
46   USE timing          ! Timing
47
48   IMPLICIT NONE
49   PRIVATE
50
51   PUBLIC   dyn_hpg        ! routine called by step module
52   PUBLIC   dyn_hpg_init   ! routine called by opa module
53
54   !                                 !!* Namelist namdyn_hpg : hydrostatic pressure gradient
55   LOGICAL , PUBLIC ::   ln_hpg_zco   !: z-coordinate - full steps
56   LOGICAL , PUBLIC ::   ln_hpg_zps   !: z-coordinate - partial steps (interpolation)
57   LOGICAL , PUBLIC ::   ln_hpg_sco   !: s-coordinate (standard jacobian formulation)
58   LOGICAL , PUBLIC ::   ln_hpg_djc   !: s-coordinate (Density Jacobian with Cubic polynomial)
59   LOGICAL , PUBLIC ::   ln_hpg_prj   !: s-coordinate (Pressure Jacobian scheme)
60   LOGICAL , PUBLIC ::   ln_hpg_isf   !: s-coordinate similar to sco modify for isf
61
62   INTEGER , PUBLIC ::   nhpg  =  0   ! = 0 to 7, type of pressure gradient scheme used ! (deduced from ln_hpg_... flags) (PUBLIC for TAM)
63
64   !! * Substitutions
65#  include "vectopt_loop_substitute.h90"
66   !!----------------------------------------------------------------------
67   !! NEMO/OPA 3.3 , NEMO Consortium (2010)
68   !! $Id$
69   !! Software governed by the CeCILL licence     (NEMOGCM/NEMO_CeCILL.txt)
70   !!----------------------------------------------------------------------
71CONTAINS
72
73   SUBROUTINE dyn_hpg( kt )
74      !!---------------------------------------------------------------------
75      !!                  ***  ROUTINE dyn_hpg  ***
76      !!
77      !! ** Method  :   Call the hydrostatic pressure gradient routine
78      !!              using the scheme defined in the namelist
79      !!
80      !! ** Action : - Update (ua,va) with the now hydrastatic pressure trend
81      !!             - send trends to trd_dyn for futher diagnostics (l_trddyn=T)
82      !!----------------------------------------------------------------------
83      INTEGER, INTENT(in) ::   kt   ! ocean time-step index
84      REAL(wp), POINTER, DIMENSION(:,:,:) ::  ztrdu, ztrdv
85      !!----------------------------------------------------------------------
86      !
87      IF( nn_timing == 1 )  CALL timing_start('dyn_hpg')
88      !
89      IF( l_trddyn ) THEN                    ! Temporary saving of ua and va trends (l_trddyn)
90         CALL wrk_alloc( jpi,jpj,jpk, ztrdu, ztrdv )
91         ztrdu(:,:,:) = ua(:,:,:)
92         ztrdv(:,:,:) = va(:,:,:)
93      ENDIF
94      !
95      SELECT CASE ( nhpg )      ! Hydrostatic pressure gradient computation
96      CASE (  0 )   ;   CALL hpg_zco    ( kt )      ! z-coordinate
97      CASE (  1 )   ;   CALL hpg_zps    ( kt )      ! z-coordinate plus partial steps (interpolation)
98      CASE (  2 )   ;   CALL hpg_sco    ( kt )      ! s-coordinate (standard jacobian formulation)
99      CASE (  3 )   ;   CALL hpg_djc    ( kt )      ! s-coordinate (Density Jacobian with Cubic polynomial)
100      CASE (  4 )   ;   CALL hpg_prj    ( kt )      ! s-coordinate (Pressure Jacobian scheme)
101      CASE (  5 )   ;   CALL hpg_isf    ( kt )      ! s-coordinate similar to sco modify for ice shelf
102      END SELECT
103      !
104      IF( l_trddyn ) THEN      ! save the hydrostatic pressure gradient trends for momentum trend diagnostics
105         ztrdu(:,:,:) = ua(:,:,:) - ztrdu(:,:,:)
106         ztrdv(:,:,:) = va(:,:,:) - ztrdv(:,:,:)
107         CALL trd_dyn( ztrdu, ztrdv, jpdyn_hpg, kt )
108         CALL wrk_dealloc( jpi,jpj,jpk, ztrdu, ztrdv )
109      ENDIF
110      !
111      IF(ln_ctl)   CALL prt_ctl( tab3d_1=ua, clinfo1=' hpg  - Ua: ', mask1=umask,   &
112         &                       tab3d_2=va, clinfo2=       ' Va: ', mask2=vmask, clinfo3='dyn' )
113      !
114      IF( nn_timing == 1 )  CALL timing_stop('dyn_hpg')
115      !
116   END SUBROUTINE dyn_hpg
117
118
119   SUBROUTINE dyn_hpg_init
120      !!----------------------------------------------------------------------
121      !!                 ***  ROUTINE dyn_hpg_init  ***
122      !!
123      !! ** Purpose :   initializations for the hydrostatic pressure gradient
124      !!              computation and consistency control
125      !!
126      !! ** Action  :   Read the namelist namdyn_hpg and check the consistency
127      !!      with the type of vertical coordinate used (zco, zps, sco)
128      !!----------------------------------------------------------------------
129      INTEGER ::   ioptio = 0      ! temporary integer
130      INTEGER ::   ios             ! Local integer output status for namelist read
131      !!
132      NAMELIST/namdyn_hpg/ ln_hpg_zco, ln_hpg_zps, ln_hpg_sco,     &
133         &                 ln_hpg_djc, ln_hpg_prj, ln_hpg_isf
134      !!----------------------------------------------------------------------
135      !
136      REWIND( numnam_ref )              ! Namelist namdyn_hpg in reference namelist : Hydrostatic pressure gradient
137      READ  ( numnam_ref, namdyn_hpg, IOSTAT = ios, ERR = 901)
138901   IF( ios /= 0 )   CALL ctl_nam ( ios , 'namdyn_hpg in reference namelist', lwp )
139      !
140      REWIND( numnam_cfg )              ! Namelist namdyn_hpg in configuration namelist : Hydrostatic pressure gradient
141      READ  ( numnam_cfg, namdyn_hpg, IOSTAT = ios, ERR = 902 )
142902   IF( ios /= 0 )   CALL ctl_nam ( ios , 'namdyn_hpg in configuration namelist', lwp )
143      IF(lwm) WRITE ( numond, namdyn_hpg )
144      !
145      IF(lwp) THEN                   ! Control print
146         WRITE(numout,*)
147         WRITE(numout,*) 'dyn_hpg_init : hydrostatic pressure gradient initialisation'
148         WRITE(numout,*) '~~~~~~~~~~~~'
149         WRITE(numout,*) '   Namelist namdyn_hpg : choice of hpg scheme'
150         WRITE(numout,*) '      z-coord. - full steps                             ln_hpg_zco    = ', ln_hpg_zco
151         WRITE(numout,*) '      z-coord. - partial steps (interpolation)          ln_hpg_zps    = ', ln_hpg_zps
152         WRITE(numout,*) '      s-coord. (standard jacobian formulation)          ln_hpg_sco    = ', ln_hpg_sco
153         WRITE(numout,*) '      s-coord. (standard jacobian formulation) for isf  ln_hpg_isf    = ', ln_hpg_isf
154         WRITE(numout,*) '      s-coord. (Density Jacobian: Cubic polynomial)     ln_hpg_djc    = ', ln_hpg_djc
155         WRITE(numout,*) '      s-coord. (Pressure Jacobian: Cubic polynomial)    ln_hpg_prj    = ', ln_hpg_prj
156      ENDIF
157      !
158      IF( ln_hpg_djc )   &
159         &   CALL ctl_stop('dyn_hpg_init : Density Jacobian: Cubic polynominal method &
160                           & currently disabled (bugs under investigation). Please select &
161                           & either  ln_hpg_sco or  ln_hpg_prj instead')
162      !
163      IF( .NOT.ln_linssh .AND. .NOT.(ln_hpg_sco.OR.ln_hpg_prj.OR.ln_hpg_isf) )        &
164         &   CALL ctl_stop('dyn_hpg_init : non-linear free surface requires either ', &
165         &                 '   the standard jacobian formulation hpg_sco    or '    , &
166         &                 '   the pressure jacobian formulation hpg_prj'            )
167
168      IF(       ln_hpg_isf .AND. .NOT. ln_isfcav )   &
169         &   CALL ctl_stop( ' hpg_isf not available if ln_isfcav = false ' )
170      IF( .NOT. ln_hpg_isf .AND.       ln_isfcav )   &
171         &   CALL ctl_stop( 'Only hpg_isf has been corrected to work with ice shelf cavity.' )
172      !
173      !                               ! Set nhpg from ln_hpg_... flags
174      IF( ln_hpg_zco )   nhpg = 0
175      IF( ln_hpg_zps )   nhpg = 1
176      IF( ln_hpg_sco )   nhpg = 2
177      IF( ln_hpg_djc )   nhpg = 3
178      IF( ln_hpg_prj )   nhpg = 4
179      IF( ln_hpg_isf )   nhpg = 5
180      !
181      !                               ! Consistency check
182      ioptio = 0
183      IF( ln_hpg_zco )   ioptio = ioptio + 1
184      IF( ln_hpg_zps )   ioptio = ioptio + 1
185      IF( ln_hpg_sco )   ioptio = ioptio + 1
186      IF( ln_hpg_djc )   ioptio = ioptio + 1
187      IF( ln_hpg_prj )   ioptio = ioptio + 1
188      IF( ln_hpg_isf )   ioptio = ioptio + 1
189      IF( ioptio /= 1 )   CALL ctl_stop( 'NO or several hydrostatic pressure gradient options used' )
190      !
191      ! initialisation of ice load
192      riceload(:,:)=0.0
193      !
194   END SUBROUTINE dyn_hpg_init
195
196
197   SUBROUTINE hpg_zco( kt )
198      !!---------------------------------------------------------------------
199      !!                  ***  ROUTINE hpg_zco  ***
200      !!
201      !! ** Method  :   z-coordinate case, levels are horizontal surfaces.
202      !!      The now hydrostatic pressure gradient at a given level, jk,
203      !!      is computed by taking the vertical integral of the in-situ
204      !!      density gradient along the model level from the suface to that
205      !!      level:    zhpi = grav .....
206      !!                zhpj = grav .....
207      !!      add it to the general momentum trend (ua,va).
208      !!            ua = ua - 1/e1u * zhpi
209      !!            va = va - 1/e2v * zhpj
210      !!
211      !! ** Action : - Update (ua,va) with the now hydrastatic pressure trend
212      !!----------------------------------------------------------------------
213      INTEGER, INTENT(in) ::   kt    ! ocean time-step index
214      !
215      INTEGER  ::   ji, jj, jk       ! dummy loop indices
216      REAL(wp) ::   zcoef0, zcoef1   ! temporary scalars
217      REAL(wp), POINTER, DIMENSION(:,:,:) ::  zhpi, zhpj
218      !!----------------------------------------------------------------------
219      !
220      CALL wrk_alloc( jpi,jpj,jpk,   zhpi, zhpj )
221      !
222      IF( kt == nit000 ) THEN
223         IF(lwp) WRITE(numout,*)
224         IF(lwp) WRITE(numout,*) 'dyn:hpg_zco : hydrostatic pressure gradient trend'
225         IF(lwp) WRITE(numout,*) '~~~~~~~~~~~   z-coordinate case '
226      ENDIF
227
228      zcoef0 = - grav * 0.5_wp      ! Local constant initialization
229
230      ! Surface value
231      DO jj = 2, jpjm1
232         DO ji = fs_2, fs_jpim1   ! vector opt.
233            zcoef1 = zcoef0 * e3w_n(ji,jj,1)
234            ! hydrostatic pressure gradient
235            zhpi(ji,jj,1) = zcoef1 * ( rhd(ji+1,jj,1) - rhd(ji,jj,1) ) * r1_e1u(ji,jj)
236            zhpj(ji,jj,1) = zcoef1 * ( rhd(ji,jj+1,1) - rhd(ji,jj,1) ) * r1_e2v(ji,jj)
237            ! add to the general momentum trend
238            ua(ji,jj,1) = ua(ji,jj,1) + zhpi(ji,jj,1)
239            va(ji,jj,1) = va(ji,jj,1) + zhpj(ji,jj,1)
240         END DO
241      END DO
242
243      !
244      ! interior value (2=<jk=<jpkm1)
245      DO jk = 2, jpkm1
246         DO jj = 2, jpjm1
247            DO ji = fs_2, fs_jpim1   ! vector opt.
248               zcoef1 = zcoef0 * e3w_n(ji,jj,jk)
249               ! hydrostatic pressure gradient
250               zhpi(ji,jj,jk) = zhpi(ji,jj,jk-1)   &
251                  &           + zcoef1 * (  ( rhd(ji+1,jj,jk)+rhd(ji+1,jj,jk-1) )    &
252                  &                       - ( rhd(ji  ,jj,jk)+rhd(ji  ,jj,jk-1) )  ) * r1_e1u(ji,jj)
253
254               zhpj(ji,jj,jk) = zhpj(ji,jj,jk-1)   &
255                  &           + zcoef1 * (  ( rhd(ji,jj+1,jk)+rhd(ji,jj+1,jk-1) )    &
256                  &                       - ( rhd(ji,jj,  jk)+rhd(ji,jj  ,jk-1) )  ) * r1_e2v(ji,jj)
257               ! add to the general momentum trend
258               ua(ji,jj,jk) = ua(ji,jj,jk) + zhpi(ji,jj,jk)
259               va(ji,jj,jk) = va(ji,jj,jk) + zhpj(ji,jj,jk)
260            END DO
261         END DO
262      END DO
263      !
264      CALL wrk_dealloc( jpi,jpj,jpk,   zhpi, zhpj )
265      !
266   END SUBROUTINE hpg_zco
267
268
269   SUBROUTINE hpg_zps( kt )
270      !!---------------------------------------------------------------------
271      !!                 ***  ROUTINE hpg_zps  ***
272      !!
273      !! ** Method  :   z-coordinate plus partial steps case.  blahblah...
274      !!
275      !! ** Action  : - Update (ua,va) with the now hydrastatic pressure trend
276      !!----------------------------------------------------------------------
277      INTEGER, INTENT(in) ::   kt    ! ocean time-step index
278      !!
279      INTEGER  ::   ji, jj, jk                       ! dummy loop indices
280      INTEGER  ::   iku, ikv                         ! temporary integers
281      REAL(wp) ::   zcoef0, zcoef1, zcoef2, zcoef3   ! temporary scalars
282      REAL(wp), POINTER, DIMENSION(:,:,:) ::  zhpi, zhpj
283      !!----------------------------------------------------------------------
284      !
285      CALL wrk_alloc( jpi,jpj,jpk,   zhpi, zhpj )
286      !
287      IF( kt == nit000 ) THEN
288         IF(lwp) WRITE(numout,*)
289         IF(lwp) WRITE(numout,*) 'dyn:hpg_zps : hydrostatic pressure gradient trend'
290         IF(lwp) WRITE(numout,*) '~~~~~~~~~~~   z-coordinate with partial steps - vector optimization'
291      ENDIF
292
293      ! Partial steps: bottom before horizontal gradient of t, s, rd at the last ocean level
294!jc      CALL zps_hde    ( kt, jpts, tsn, gtsu, gtsv, rhd, gru , grv )
295
296      ! Local constant initialization
297      zcoef0 = - grav * 0.5_wp
298
299      !  Surface value (also valid in partial step case)
300      DO jj = 2, jpjm1
301         DO ji = fs_2, fs_jpim1   ! vector opt.
302            zcoef1 = zcoef0 * e3w_n(ji,jj,1)
303            ! hydrostatic pressure gradient
304            zhpi(ji,jj,1) = zcoef1 * ( rhd(ji+1,jj  ,1) - rhd(ji,jj,1) ) * r1_e1u(ji,jj)
305            zhpj(ji,jj,1) = zcoef1 * ( rhd(ji  ,jj+1,1) - rhd(ji,jj,1) ) * r1_e2v(ji,jj)
306            ! add to the general momentum trend
307            ua(ji,jj,1) = ua(ji,jj,1) + zhpi(ji,jj,1)
308            va(ji,jj,1) = va(ji,jj,1) + zhpj(ji,jj,1)
309         END DO
310      END DO
311
312      ! interior value (2=<jk=<jpkm1)
313      DO jk = 2, jpkm1
314         DO jj = 2, jpjm1
315            DO ji = fs_2, fs_jpim1   ! vector opt.
316               zcoef1 = zcoef0 * e3w_n(ji,jj,jk)
317               ! hydrostatic pressure gradient
318               zhpi(ji,jj,jk) = zhpi(ji,jj,jk-1)   &
319                  &           + zcoef1 * (  ( rhd(ji+1,jj,jk) + rhd(ji+1,jj,jk-1) )   &
320                  &                       - ( rhd(ji  ,jj,jk) + rhd(ji  ,jj,jk-1) )  ) * r1_e1u(ji,jj)
321
322               zhpj(ji,jj,jk) = zhpj(ji,jj,jk-1)   &
323                  &           + zcoef1 * (  ( rhd(ji,jj+1,jk) + rhd(ji,jj+1,jk-1) )   &
324                  &                       - ( rhd(ji,jj,  jk) + rhd(ji,jj  ,jk-1) )  ) * r1_e2v(ji,jj)
325               ! add to the general momentum trend
326               ua(ji,jj,jk) = ua(ji,jj,jk) + zhpi(ji,jj,jk)
327               va(ji,jj,jk) = va(ji,jj,jk) + zhpj(ji,jj,jk)
328            END DO
329         END DO
330      END DO
331
332      ! partial steps correction at the last level  (use gru & grv computed in zpshde.F90)
333      DO jj = 2, jpjm1
334         DO ji = 2, jpim1
335            iku = mbku(ji,jj)
336            ikv = mbkv(ji,jj)
337            zcoef2 = zcoef0 * MIN( e3w_n(ji,jj,iku), e3w_n(ji+1,jj  ,iku) )
338            zcoef3 = zcoef0 * MIN( e3w_n(ji,jj,ikv), e3w_n(ji  ,jj+1,ikv) )
339            IF( iku > 1 ) THEN            ! on i-direction (level 2 or more)
340               ua  (ji,jj,iku) = ua(ji,jj,iku) - zhpi(ji,jj,iku)         ! subtract old value
341               zhpi(ji,jj,iku) = zhpi(ji,jj,iku-1)                   &   ! compute the new one
342                  &            + zcoef2 * ( rhd(ji+1,jj,iku-1) - rhd(ji,jj,iku-1) + gru(ji,jj) ) * r1_e1u(ji,jj)
343               ua  (ji,jj,iku) = ua(ji,jj,iku) + zhpi(ji,jj,iku)         ! add the new one to the general momentum trend
344            ENDIF
345            IF( ikv > 1 ) THEN            ! on j-direction (level 2 or more)
346               va  (ji,jj,ikv) = va(ji,jj,ikv) - zhpj(ji,jj,ikv)         ! subtract old value
347               zhpj(ji,jj,ikv) = zhpj(ji,jj,ikv-1)                   &   ! compute the new one
348                  &            + zcoef3 * ( rhd(ji,jj+1,ikv-1) - rhd(ji,jj,ikv-1) + grv(ji,jj) ) * r1_e2v(ji,jj)
349               va  (ji,jj,ikv) = va(ji,jj,ikv) + zhpj(ji,jj,ikv)         ! add the new one to the general momentum trend
350            ENDIF
351         END DO
352      END DO
353      !
354      CALL wrk_dealloc( jpi,jpj,jpk,   zhpi, zhpj )
355      !
356   END SUBROUTINE hpg_zps
357
358
359   SUBROUTINE hpg_sco( kt )
360      !!---------------------------------------------------------------------
361      !!                  ***  ROUTINE hpg_sco  ***
362      !!
363      !! ** Method  :   s-coordinate case. Jacobian scheme.
364      !!      The now hydrostatic pressure gradient at a given level, jk,
365      !!      is computed by taking the vertical integral of the in-situ
366      !!      density gradient along the model level from the suface to that
367      !!      level. s-coordinates (ln_sco): a corrective term is added
368      !!      to the horizontal pressure gradient :
369      !!         zhpi = grav .....  + 1/e1u mi(rhd) di[ grav dep3w ]
370      !!         zhpj = grav .....  + 1/e2v mj(rhd) dj[ grav dep3w ]
371      !!      add it to the general momentum trend (ua,va).
372      !!         ua = ua - 1/e1u * zhpi
373      !!         va = va - 1/e2v * zhpj
374      !!
375      !! ** Action : - Update (ua,va) with the now hydrastatic pressure trend
376      !!----------------------------------------------------------------------
377      INTEGER, INTENT(in) ::   kt    ! ocean time-step index
378      !!
379      INTEGER  ::   ji, jj, jk                 ! dummy loop indices
380      REAL(wp) ::   zcoef0, zuap, zvap, znad   ! temporary scalars
381      REAL(wp), POINTER, DIMENSION(:,:,:) ::  zhpi, zhpj
382      !!----------------------------------------------------------------------
383      !
384      CALL wrk_alloc( jpi,jpj,jpk, zhpi, zhpj )
385      !
386      IF( kt == nit000 ) THEN
387         IF(lwp) WRITE(numout,*)
388         IF(lwp) WRITE(numout,*) 'dyn:hpg_sco : hydrostatic pressure gradient trend'
389         IF(lwp) WRITE(numout,*) '~~~~~~~~~~~   s-coordinate case, OPA original scheme used'
390      ENDIF
391      !
392      zcoef0 = - grav * 0.5_wp
393      IF ( ln_linssh ) THEN   ;   znad = 0._wp         ! Fixed    volume: density anomaly
394      ELSE                    ;   znad = 1._wp         ! Variable volume: density
395      ENDIF
396      !
397      ! Surface value
398      DO jj = 2, jpjm1
399         DO ji = fs_2, fs_jpim1   ! vector opt.
400            ! hydrostatic pressure gradient along s-surfaces
401            zhpi(ji,jj,1) = zcoef0 * (  e3w_n(ji+1,jj  ,1) * ( znad + rhd(ji+1,jj  ,1) )    &
402               &                      - e3w_n(ji  ,jj  ,1) * ( znad + rhd(ji  ,jj  ,1) )  ) * r1_e1u(ji,jj)
403            zhpj(ji,jj,1) = zcoef0 * (  e3w_n(ji  ,jj+1,1) * ( znad + rhd(ji  ,jj+1,1) )    &
404               &                      - e3w_n(ji  ,jj  ,1) * ( znad + rhd(ji  ,jj  ,1) )  ) * r1_e2v(ji,jj)
405            ! s-coordinate pressure gradient correction
406            zuap = -zcoef0 * ( rhd    (ji+1,jj,1) + rhd    (ji,jj,1) + 2._wp * znad )   &
407               &           * ( gde3w_n(ji+1,jj,1) - gde3w_n(ji,jj,1) ) * r1_e1u(ji,jj)
408            zvap = -zcoef0 * ( rhd    (ji,jj+1,1) + rhd    (ji,jj,1) + 2._wp * znad )   &
409               &           * ( gde3w_n(ji,jj+1,1) - gde3w_n(ji,jj,1) ) * r1_e2v(ji,jj)
410            ! add to the general momentum trend
411            ua(ji,jj,1) = ua(ji,jj,1) + zhpi(ji,jj,1) + zuap
412            va(ji,jj,1) = va(ji,jj,1) + zhpj(ji,jj,1) + zvap
413         END DO
414      END DO
415
416      ! interior value (2=<jk=<jpkm1)
417      DO jk = 2, jpkm1
418         DO jj = 2, jpjm1
419            DO ji = fs_2, fs_jpim1   ! vector opt.
420               ! hydrostatic pressure gradient along s-surfaces
421               zhpi(ji,jj,jk) = zhpi(ji,jj,jk-1) + zcoef0 * r1_e1u(ji,jj)   &
422                  &           * (  e3w_n(ji+1,jj,jk) * ( rhd(ji+1,jj,jk) + rhd(ji+1,jj,jk-1) + 2*znad )   &
423                  &              - e3w_n(ji  ,jj,jk) * ( rhd(ji  ,jj,jk) + rhd(ji  ,jj,jk-1) + 2*znad )  )
424               zhpj(ji,jj,jk) = zhpj(ji,jj,jk-1) + zcoef0 * r1_e2v(ji,jj)   &
425                  &           * (  e3w_n(ji,jj+1,jk) * ( rhd(ji,jj+1,jk) + rhd(ji,jj+1,jk-1) + 2*znad )   &
426                  &              - e3w_n(ji,jj  ,jk) * ( rhd(ji,jj,  jk) + rhd(ji,jj  ,jk-1) + 2*znad )  )
427               ! s-coordinate pressure gradient correction
428               zuap = -zcoef0 * ( rhd    (ji+1,jj  ,jk) + rhd    (ji,jj,jk) + 2._wp * znad )   &
429                  &           * ( gde3w_n(ji+1,jj  ,jk) - gde3w_n(ji,jj,jk) ) * r1_e1u(ji,jj)
430               zvap = -zcoef0 * ( rhd    (ji  ,jj+1,jk) + rhd    (ji,jj,jk) + 2._wp * znad )   &
431                  &           * ( gde3w_n(ji  ,jj+1,jk) - gde3w_n(ji,jj,jk) ) * r1_e2v(ji,jj)
432               ! add to the general momentum trend
433               ua(ji,jj,jk) = ua(ji,jj,jk) + zhpi(ji,jj,jk) + zuap
434               va(ji,jj,jk) = va(ji,jj,jk) + zhpj(ji,jj,jk) + zvap
435            END DO
436         END DO
437      END DO
438      !
439      CALL wrk_dealloc( jpi,jpj,jpk, zhpi, zhpj )
440      !
441   END SUBROUTINE hpg_sco
442
443
444   SUBROUTINE hpg_isf( kt )
445      !!---------------------------------------------------------------------
446      !!                  ***  ROUTINE hpg_sco  ***
447      !!
448      !! ** Method  :   s-coordinate case. Jacobian scheme.
449      !!      The now hydrostatic pressure gradient at a given level, jk,
450      !!      is computed by taking the vertical integral of the in-situ
451      !!      density gradient along the model level from the suface to that
452      !!      level. s-coordinates (ln_sco): a corrective term is added
453      !!      to the horizontal pressure gradient :
454      !!         zhpi = grav .....  + 1/e1u mi(rhd) di[ grav dep3w ]
455      !!         zhpj = grav .....  + 1/e2v mj(rhd) dj[ grav dep3w ]
456      !!      add it to the general momentum trend (ua,va).
457      !!         ua = ua - 1/e1u * zhpi
458      !!         va = va - 1/e2v * zhpj
459      !!      iceload is added and partial cell case are added to the top and bottom
460      !!     
461      !! ** Action : - Update (ua,va) with the now hydrastatic pressure trend
462      !!----------------------------------------------------------------------
463      INTEGER, INTENT(in) ::   kt    ! ocean time-step index
464      !!
465      INTEGER  ::   ji, jj, jk, iku, ikv, ikt, iktp1i, iktp1j                 ! dummy loop indices
466      REAL(wp) ::   zcoef0, zuap, zvap, znad, ze3wu, ze3wv, zuapint, zvapint, zhpjint, zhpiint, zdzwt, zdzwtjp1, zdzwtip1             ! temporary scalars
467      REAL(wp), POINTER, DIMENSION(:,:,:)   ::  zhpi, zhpj, zrhd
468      REAL(wp), POINTER, DIMENSION(:,:,:)   ::  ztstop
469      REAL(wp), POINTER, DIMENSION(:,:)     ::  ze3w, zp, zrhdtop_isf, zrhdtop_oce, ziceload, zdept, zpshpi, zpshpj
470      !!----------------------------------------------------------------------
471      !
472      CALL wrk_alloc( jpi,jpj,  2,   ztstop ) 
473      CALL wrk_alloc( jpi,jpj,jpk,   zhpi, zhpj, zrhd)
474      CALL wrk_alloc( jpi,jpj,       ze3w, zp, zrhdtop_isf, zrhdtop_oce, ziceload, zdept, zpshpi, zpshpj ) 
475      !
476      IF( kt == nit000 ) THEN
477         IF(lwp) WRITE(numout,*)
478         IF(lwp) WRITE(numout,*) 'dyn:hpg_isf : hydrostatic pressure gradient trend for ice shelf'
479         IF(lwp) WRITE(numout,*) '~~~~~~~~~~~   s-coordinate case, OPA original scheme used'
480      ENDIF
481      !
482      zcoef0 = - grav * 0.5_wp
483      IF( ln_linssh ) THEN   ;   znad = 0._wp      ! Fixed    volume: density anomaly
484      ELSE                   ;   znad = 1._wp      ! Variable volume: density
485      ENDIF
486      zhpi(:,:,:) = 0._wp
487      zhpj(:,:,:) = 0._wp
488
489!==================================================================================     
490!=====Compute iceload and contribution of the half first wet layer =================
491!===================================================================================
492
493      ! assume water displaced by the ice shelf is at T=-1.9 and S=34.4 (rude)
494      ztstop(:,:,jp_tem) = -1.9_wp
495      ztstop(:,:,jp_sal) = 34.4_wp
496
497!!gm I have the feeling that a much simplier and faster computation can be performed...
498!!gm     ====>>>>   We have to discuss !
499
500!!gm below, faster to compute the ISF density in zrhd and remplace rhd value where tmask=0
501!!gm        furthermore, this calculation does not depends on time :  do it at the first time-step only....
502
503      ! compute density of the water displaced by the ice shelf
504      zrhd(:,:,:) = rhd(:,:,:)     ! save rhd
505      DO jk = 1, jpk
506         zdept(:,:) = gdept_1d(jk)
507         CALL eos( ztstop(:,:,:), zdept(:,:), rhd(:,:,jk) )
508      END DO
509      WHERE( tmask(:,:,:) == 1._wp )
510        rhd(:,:,:) = zrhd(:,:,:) ! replace wet cell by the saved rhd
511      END WHERE
512     
513      ! compute rhd at the ice/oce interface (ice shelf side)
514      CALL eos( ztstop, risfdep, zrhdtop_isf )
515
516      ! compute rhd at the ice/oce interface (ocean side)
517      DO ji = 1, jpi
518        DO jj = 1, jpj
519          ikt = mikt(ji,jj)
520          ztstop(ji,jj,jp_tem) = tsn(ji,jj,ikt,jp_tem)
521          ztstop(ji,jj,jp_sal) = tsn(ji,jj,ikt,jp_sal)
522        END DO
523      END DO
524      CALL eos( ztstop, risfdep, zrhdtop_oce )
525      !
526      ! Surface value + ice shelf gradient
527      ! compute pressure due to ice shelf load (used to compute hpgi/j for all the level from 1 to miku/v)
528      ziceload = 0._wp
529      DO jj = 1, jpj
530         DO ji = 1, jpi   ! vector opt.
531            ikt = mikt(ji,jj)
532            ziceload(ji,jj) = ziceload(ji,jj) + (znad + rhd(ji,jj,1) ) * e3w_n(ji,jj,1) * (1._wp - tmask(ji,jj,1))
533            DO jk = 2, ikt-1
534               ziceload(ji,jj) = ziceload(ji,jj) + (2._wp * znad + rhd(ji,jj,jk-1) + rhd(ji,jj,jk)) * e3w_n(ji,jj,jk) &
535                  &                              * (1._wp - tmask(ji,jj,jk))
536            END DO
537            IF( ikt >= 2 )   ziceload(ji,jj) = ziceload(ji,jj) + (2._wp * znad + zrhdtop_isf(ji,jj) + rhd(ji,jj,ikt-1)) &
538               &                                               * ( risfdep(ji,jj) - gdept_1d(ikt-1) )
539         END DO
540      END DO
541      riceload(:,:) = 0._wp   ;   riceload(:,:) = ziceload(:,:)   ! need to be saved for diaar5
542      ! compute zp from z=0 to first T wet point (correction due to zps not yet applied)
543      DO jj = 2, jpjm1
544         DO ji = fs_2, fs_jpim1   ! vector opt.
545            ikt    = mikt(ji,jj)
546            iktp1i = mikt(ji+1,jj)
547            iktp1j = mikt(ji,jj+1)
548            ! hydrostatic pressure gradient along s-surfaces and ice shelf pressure
549            ! we assume ISF is in isostatic equilibrium
550            zhpi(ji,jj,1) = zcoef0 * (                                    &
551               &            0.5_wp * e3w_n(ji+1,jj,iktp1i) * ( 2._wp * znad + rhd(ji+1,jj,iktp1i) + zrhdtop_oce(ji+1,jj) )   &
552               &          - 0.5_wp * e3w_n(ji  ,jj,ikt   ) * ( 2._wp * znad + rhd(ji  ,jj,ikt   ) + zrhdtop_oce(ji  ,jj) )   &
553               &          + ( ziceload(ji+1,jj) - ziceload(ji,jj) )       ) * r1_e1u(ji,jj)
554            zhpj(ji,jj,1) = zcoef0 * (                                    &
555               &            0.5_wp * e3w_n(ji,jj+1,iktp1j) * ( 2._wp * znad + rhd(ji,jj+1,iktp1j) + zrhdtop_oce(ji,jj+1) )   &
556               &          - 0.5_wp * e3w_n(ji,jj  ,ikt   ) * ( 2._wp * znad + rhd(ji,jj  ,ikt   ) + zrhdtop_oce(ji,jj  ) )   &
557               &          + ( ziceload(ji,jj+1) - ziceload(ji,jj) )       ) * r1_e2v(ji,jj)
558            ! s-coordinate pressure gradient correction (=0 if z coordinate)
559            zuap = -zcoef0 * ( rhd    (ji+1,jj,1) + rhd    (ji,jj,1) + 2._wp * znad )   &
560               &           * ( gde3w_n(ji+1,jj,1) - gde3w_n(ji,jj,1) ) * r1_e1u(ji,jj)
561            zvap = -zcoef0 * ( rhd    (ji,jj+1,1) + rhd    (ji,jj,1) + 2._wp * znad )   &
562               &           * ( gde3w_n(ji,jj+1,1) - gde3w_n(ji,jj,1) ) * r1_e2v(ji,jj)
563            ! add to the general momentum trend
564            ua(ji,jj,1) = ua(ji,jj,1) + (zhpi(ji,jj,1) + zuap) * umask(ji,jj,1)
565            va(ji,jj,1) = va(ji,jj,1) + (zhpj(ji,jj,1) + zvap) * vmask(ji,jj,1)
566         END DO
567      END DO
568!==================================================================================     
569!===== Compute partial cell contribution for the top cell =========================
570!==================================================================================
571      DO jj = 2, jpjm1
572         DO ji = fs_2, fs_jpim1   ! vector opt.
573            iku = miku(ji,jj)
574            zpshpi(ji,jj) = 0._wp
575            zpshpj(ji,jj) = 0._wp
576            ze3wu  = (gdepw_0(ji+1,jj,iku+1) - gdept_0(ji+1,jj,iku)) - (gdepw_0(ji,jj,iku+1) - gdept_0(ji,jj,iku))
577            ! u direction
578            IF( iku > 1 ) THEN
579               ! case iku
580               zhpi(ji,jj,iku) = zcoef0 * r1_e1u(ji,jj) * ze3wu                             &
581                  &                     * ( rhd(ji+1,jj,iku) + rhd(ji,jj,iku)               &
582                  &                        + SIGN(1._wp,ze3wu) * grui(ji,jj) + 2._wp * znad )
583               ! corrective term ( = 0 if z coordinate )
584               zuap = -zcoef0 * ( arui(ji,jj) + 2._wp * znad ) * gzui(ji,jj) * r1_e1u(ji,jj)
585               ! zhpi will be added in interior loop
586               ua(ji,jj,iku) = ua(ji,jj,iku) + zuap
587               ! in case of 2 cell water column, need to save the pressure gradient to compute the bottom pressure 
588               IF( mbku(ji,jj) == iku + 1 )   zpshpi(ji,jj) = zhpi(ji,jj,iku)
589
590               ! case iku + 1 (remove the zphi term added in the interior loop and compute the one corrected for zps)
591               zhpiint = zcoef0 * r1_e1u(ji,jj)                                                              &   
592                  &    * (  e3w_n(ji+1,jj  ,iku+1) * (  (rhd(ji+1,jj,iku+1) + znad)                          &
593                  &                                   + (rhd(ji+1,jj,iku  ) + znad) ) * tmask(ji+1,jj,iku)   &
594                  &       - e3w_n(ji  ,jj  ,iku+1) * (  (rhd(ji  ,jj,iku+1) + znad)                          &
595                  &                                   + (rhd(ji  ,jj,iku  ) + znad) ) * tmask(ji  ,jj,iku)   )
596               zhpi(ji,jj,iku+1) = zcoef0 * r1_e1u(ji,jj) * ge3rui(ji,jj) - zhpiint 
597            END IF
598               
599            ! v direction
600            ikv = mikv(ji,jj)
601            ze3wv  = (gdepw_0(ji,jj+1,ikv+1) - gdept_0(ji,jj+1,ikv)) - (gdepw_0(ji,jj,ikv+1) - gdept_0(ji,jj,ikv))
602            IF( ikv > 1 ) THEN
603               ! case ikv
604               zhpj(ji,jj,ikv) =  zcoef0 * r1_e2v(ji,jj) * ze3wv                             &
605                  &                      * ( rhd(ji,jj+1,ikv) + rhd(ji,jj,ikv)               &
606                  &                         + SIGN(1._wp,ze3wv) * grvi(ji,jj) + 2._wp * znad )
607               ! corrective term ( = 0 if z coordinate )
608               zvap = -zcoef0 * ( arvi(ji,jj) + 2._wp * znad ) * gzvi(ji,jj) * r1_e2v(ji,jj)
609               ! zhpi will be added in interior loop
610               va(ji,jj,ikv) = va(ji,jj,ikv) + zvap
611               ! in case of 2 cell water column, need to save the pressure gradient to compute the bottom pressure 
612               IF( mbkv(ji,jj) == ikv + 1 )   zpshpj(ji,jj) = zhpj(ji,jj,ikv) 
613               
614               ! case ikv + 1 (remove the zphj term added in the interior loop and compute the one corrected for zps)
615               zhpjint =  zcoef0 * r1_e2v(ji,jj)                                                            &
616                  &    * (  e3w_n(ji  ,jj+1,ikv+1) * (  (rhd(ji,jj+1,ikv+1) + znad)                         &
617                  &                                   + (rhd(ji,jj+1,ikv  ) + znad) ) * tmask(ji,jj+1,ikv)  &
618                  &       - e3w_n(ji  ,jj  ,ikv+1) * (  (rhd(ji,jj  ,ikv+1) + znad)                         &
619                  &                                   + (rhd(ji,jj  ,ikv  ) + znad) ) * tmask(ji,jj  ,ikv)  )
620               zhpj(ji,jj,ikv+1) =  zcoef0 * r1_e2v(ji,jj) * ge3rvi(ji,jj) - zhpjint
621            ENDIF
622         END DO
623      END DO
624
625!==================================================================================     
626!===== Compute interior value =====================================================
627!==================================================================================
628
629      DO jj = 2, jpjm1
630         DO ji = fs_2, fs_jpim1   ! vector opt.
631            DO jk = 2, jpkm1
632               ! hydrostatic pressure gradient along s-surfaces
633               ! zhpi is masked for the first wet cell  (contribution already done in the upper bloc)
634               zhpi(ji,jj,jk) = zhpi(ji,jj,jk) + zhpi(ji,jj,jk-1)                                                     &
635                  &           + zcoef0 * r1_e1u(ji,jj)                                                                &
636                  &                    * ( e3w_n(ji+1,jj,jk) * ( (rhd(ji+1,jj,jk  ) + znad)                           &
637                  &                                            + (rhd(ji+1,jj,jk-1) + znad) ) * tmask(ji+1,jj,jk-1)   &
638                  &                      - e3w_n(ji  ,jj,jk) * ( (rhd(ji  ,jj,jk  ) + znad)                           &
639                  &                                            + (rhd(ji  ,jj,jk-1) + znad) ) * tmask(ji  ,jj,jk-1)   ) 
640               ! s-coordinate pressure gradient correction
641               ! corrective term, we mask this term for the first wet level beneath the ice shelf (contribution done in the upper bloc)
642               zuap = - zcoef0 * ( rhd    (ji+1,jj  ,jk) + rhd    (ji,jj,jk) + 2._wp * znad )                    &
643                  &            * ( gde3w_n(ji+1,jj  ,jk) - gde3w_n(ji,jj,jk) ) * r1_e1u(ji,jj) * umask(ji,jj,jk-1)
644               ua(ji,jj,jk) = ua(ji,jj,jk) + ( zhpi(ji,jj,jk) + zuap) * umask(ji,jj,jk)
645
646               ! hydrostatic pressure gradient along s-surfaces
647               ! zhpi is masked for the first wet cell  (contribution already done in the upper bloc)
648               zhpj(ji,jj,jk) = zhpj(ji,jj,jk) + zhpj(ji,jj,jk-1)                                                     &
649                  &           + zcoef0 * r1_e2v(ji,jj)                                                                &
650                  &                    * ( e3w_n(ji  ,jj+1,jk) * ( (rhd(ji,jj+1,jk  ) + znad)                           &
651                  &                                              + (rhd(ji,jj+1,jk-1) + znad) ) * tmask(ji,jj+1,jk-1)   &
652                  &                      - e3w_n(ji  ,jj  ,jk) * ( (rhd(ji,jj  ,jk  ) + znad)                           &
653                  &                                              + (rhd(ji,jj  ,jk-1) + znad) ) * tmask(ji,jj  ,jk-1)   )
654               ! s-coordinate pressure gradient correction
655               ! corrective term, we mask this term for the first wet level beneath the ice shelf (contribution done in the upper bloc)
656               zvap = - zcoef0 * ( rhd    (ji  ,jj+1,jk) + rhd    (ji,jj,jk) + 2._wp * znad )                    &
657                  &            * ( gde3w_n(ji  ,jj+1,jk) - gde3w_n(ji,jj,jk) ) * r1_e2v(ji,jj) * vmask(ji,jj,jk-1)
658               ! add to the general momentum trend
659               va(ji,jj,jk) = va(ji,jj,jk) + ( zhpj(ji,jj,jk) + zvap ) * vmask(ji,jj,jk)
660            END DO
661         END DO
662      END DO
663
664!==================================================================================     
665!===== Compute bottom cell contribution (partial cell) ============================
666!==================================================================================
667
668      DO jj = 2, jpjm1
669         DO ji = 2, jpim1
670            iku = mbku(ji,jj)
671            ikv = mbkv(ji,jj)
672
673            IF (iku .GT. 1) THEN
674               ! remove old value (interior case)
675               zuap            = -zcoef0 * ( rhd    (ji+1,jj  ,iku) + rhd    (ji,jj,iku) + 2._wp * znad )   &
676                     &                   * ( gde3w_n(ji+1,jj  ,iku) - gde3w_n(ji,jj,iku) ) * r1_e1u(ji,jj)
677               ua(ji,jj,iku)   = ua(ji,jj,iku) - zhpi(ji,jj,iku) - zuap
678               ! put new value
679               ! -zpshpi to avoid double contribution of the partial step in the top layer
680               zuap            = -zcoef0 * ( aru(ji,jj) + 2._wp * znad ) * gzu(ji,jj)  * r1_e1u(ji,jj)
681               zhpi(ji,jj,iku) =  zhpi(ji,jj,iku-1) + zcoef0 * r1_e1u(ji,jj) * ge3ru(ji,jj) - zpshpi(ji,jj) 
682               ua(ji,jj,iku)   =  ua(ji,jj,iku) + zhpi(ji,jj,iku) + zuap
683            END IF
684            ! v direction
685            IF (ikv .GT. 1) THEN
686               ! remove old value (interior case)
687               zvap            = -zcoef0 * ( rhd    (ji  ,jj+1,ikv) + rhd    (ji,jj,ikv) + 2._wp * znad )   &
688                     &                   * ( gde3w_n(ji  ,jj+1,ikv) - gde3w_n(ji,jj,ikv) ) * r1_e2v(ji,jj)
689               va(ji,jj,ikv)   = va(ji,jj,ikv) - zhpj(ji,jj,ikv) - zvap
690               ! put new value
691               ! -zpshpj to avoid double contribution of the partial step in the top layer
692               zvap            = -zcoef0 * ( arv(ji,jj) + 2._wp * znad ) * gzv(ji,jj) * r1_e2v(ji,jj)
693               zhpj(ji,jj,ikv) =  zhpj(ji,jj,ikv-1) + zcoef0 * r1_e2v(ji,jj) * ge3rv(ji,jj) - zpshpj(ji,jj)   
694               va(ji,jj,ikv)   =  va(ji,jj,ikv) + zhpj(ji,jj,ikv) + zvap
695            END IF
696         END DO
697      END DO
698     
699      ! set back to original density value into the ice shelf cell (maybe useless because it is masked)
700      rhd = zrhd
701      !
702      CALL wrk_dealloc( jpi,jpj,2, ztstop)
703      CALL wrk_dealloc( jpi,jpj,jpk, zhpi, zhpj, zrhd)
704      CALL wrk_dealloc( jpi,jpj, ze3w, zp, zrhdtop_isf, zrhdtop_oce, ziceload, zdept, zpshpi, zpshpj)
705      !
706   END SUBROUTINE hpg_isf
707
708
709   SUBROUTINE hpg_djc( kt )
710      !!---------------------------------------------------------------------
711      !!                  ***  ROUTINE hpg_djc  ***
712      !!
713      !! ** Method  :   Density Jacobian with Cubic polynomial scheme
714      !!
715      !! Reference: Shchepetkin and McWilliams, J. Geophys. Res., 108(C3), 3090, 2003
716      !!----------------------------------------------------------------------
717      INTEGER, INTENT(in) ::   kt    ! ocean time-step index
718      !!
719      INTEGER  ::   ji, jj, jk          ! dummy loop indices
720      REAL(wp) ::   zcoef0, zep, cffw   ! temporary scalars
721      REAL(wp) ::   z1_10, cffu, cffx   !    "         "
722      REAL(wp) ::   z1_12, cffv, cffy   !    "         "
723      REAL(wp), POINTER, DIMENSION(:,:,:) ::  zhpi, zhpj
724      REAL(wp), POINTER, DIMENSION(:,:,:) ::  dzx, dzy, dzz, dzu, dzv, dzw
725      REAL(wp), POINTER, DIMENSION(:,:,:) ::  drhox, drhoy, drhoz, drhou, drhov, drhow
726      REAL(wp), POINTER, DIMENSION(:,:,:) ::  rho_i, rho_j, rho_k
727      !!----------------------------------------------------------------------
728      !
729      CALL wrk_alloc( jpi, jpj, jpk, dzx  , dzy  , dzz  , dzu  , dzv  , dzw   )
730      CALL wrk_alloc( jpi, jpj, jpk, drhox, drhoy, drhoz, drhou, drhov, drhow )
731      CALL wrk_alloc( jpi, jpj, jpk, rho_i, rho_j, rho_k,  zhpi,  zhpj        )
732      !
733
734      IF( kt == nit000 ) THEN
735         IF(lwp) WRITE(numout,*)
736         IF(lwp) WRITE(numout,*) 'dyn:hpg_djc : hydrostatic pressure gradient trend'
737         IF(lwp) WRITE(numout,*) '~~~~~~~~~~~   s-coordinate case, density Jacobian with cubic polynomial scheme'
738      ENDIF
739
740      ! Local constant initialization
741      zcoef0 = - grav * 0.5_wp
742      z1_10  = 1._wp / 10._wp
743      z1_12  = 1._wp / 12._wp
744
745      !----------------------------------------------------------------------------------------
746      !  compute and store in provisional arrays elementary vertical and horizontal differences
747      !----------------------------------------------------------------------------------------
748
749!!bug gm   Not a true bug, but... dzz=e3w  for dzx, dzy verify what it is really
750
751      DO jk = 2, jpkm1
752         DO jj = 2, jpjm1
753            DO ji = fs_2, fs_jpim1   ! vector opt.
754               drhoz(ji,jj,jk) = rhd    (ji  ,jj  ,jk) - rhd    (ji,jj,jk-1)
755               dzz  (ji,jj,jk) = gde3w_n(ji  ,jj  ,jk) - gde3w_n(ji,jj,jk-1)
756               drhox(ji,jj,jk) = rhd    (ji+1,jj  ,jk) - rhd    (ji,jj,jk  )
757               dzx  (ji,jj,jk) = gde3w_n(ji+1,jj  ,jk) - gde3w_n(ji,jj,jk  )
758               drhoy(ji,jj,jk) = rhd    (ji  ,jj+1,jk) - rhd    (ji,jj,jk  )
759               dzy  (ji,jj,jk) = gde3w_n(ji  ,jj+1,jk) - gde3w_n(ji,jj,jk  )
760            END DO
761         END DO
762      END DO
763
764      !-------------------------------------------------------------------------
765      ! compute harmonic averages using eq. 5.18
766      !-------------------------------------------------------------------------
767      zep = 1.e-15
768
769!!bug  gm  drhoz not defined at level 1 and used (jk-1 with jk=2)
770!!bug  gm  idem for drhox, drhoy et ji=jpi and jj=jpj
771
772      DO jk = 2, jpkm1
773         DO jj = 2, jpjm1
774            DO ji = fs_2, fs_jpim1   ! vector opt.
775               cffw = 2._wp * drhoz(ji  ,jj  ,jk) * drhoz(ji,jj,jk-1)
776
777               cffu = 2._wp * drhox(ji+1,jj  ,jk) * drhox(ji,jj,jk  )
778               cffx = 2._wp * dzx  (ji+1,jj  ,jk) * dzx  (ji,jj,jk  )
779
780               cffv = 2._wp * drhoy(ji  ,jj+1,jk) * drhoy(ji,jj,jk  )
781               cffy = 2._wp * dzy  (ji  ,jj+1,jk) * dzy  (ji,jj,jk  )
782
783               IF( cffw > zep) THEN
784                  drhow(ji,jj,jk) = 2._wp *   drhoz(ji,jj,jk) * drhoz(ji,jj,jk-1)   &
785                     &                    / ( drhoz(ji,jj,jk) + drhoz(ji,jj,jk-1) )
786               ELSE
787                  drhow(ji,jj,jk) = 0._wp
788               ENDIF
789
790               dzw(ji,jj,jk) = 2._wp *   dzz(ji,jj,jk) * dzz(ji,jj,jk-1)   &
791                  &                  / ( dzz(ji,jj,jk) + dzz(ji,jj,jk-1) )
792
793               IF( cffu > zep ) THEN
794                  drhou(ji,jj,jk) = 2._wp *   drhox(ji+1,jj,jk) * drhox(ji,jj,jk)   &
795                     &                    / ( drhox(ji+1,jj,jk) + drhox(ji,jj,jk) )
796               ELSE
797                  drhou(ji,jj,jk ) = 0._wp
798               ENDIF
799
800               IF( cffx > zep ) THEN
801                  dzu(ji,jj,jk) = 2._wp *   dzx(ji+1,jj,jk) * dzx(ji,jj,jk)   &
802                     &                  / ( dzx(ji+1,jj,jk) + dzx(ji,jj,jk) )
803               ELSE
804                  dzu(ji,jj,jk) = 0._wp
805               ENDIF
806
807               IF( cffv > zep ) THEN
808                  drhov(ji,jj,jk) = 2._wp *   drhoy(ji,jj+1,jk) * drhoy(ji,jj,jk)   &
809                     &                    / ( drhoy(ji,jj+1,jk) + drhoy(ji,jj,jk) )
810               ELSE
811                  drhov(ji,jj,jk) = 0._wp
812               ENDIF
813
814               IF( cffy > zep ) THEN
815                  dzv(ji,jj,jk) = 2._wp *   dzy(ji,jj+1,jk) * dzy(ji,jj,jk)   &
816                     &                  / ( dzy(ji,jj+1,jk) + dzy(ji,jj,jk) )
817               ELSE
818                  dzv(ji,jj,jk) = 0._wp
819               ENDIF
820
821            END DO
822         END DO
823      END DO
824
825      !----------------------------------------------------------------------------------
826      ! apply boundary conditions at top and bottom using 5.36-5.37
827      !----------------------------------------------------------------------------------
828      drhow(:,:, 1 ) = 1.5_wp * ( drhoz(:,:, 2 ) - drhoz(:,:,  1  ) ) - 0.5_wp * drhow(:,:,  2  )
829      drhou(:,:, 1 ) = 1.5_wp * ( drhox(:,:, 2 ) - drhox(:,:,  1  ) ) - 0.5_wp * drhou(:,:,  2  )
830      drhov(:,:, 1 ) = 1.5_wp * ( drhoy(:,:, 2 ) - drhoy(:,:,  1  ) ) - 0.5_wp * drhov(:,:,  2  )
831
832      drhow(:,:,jpk) = 1.5_wp * ( drhoz(:,:,jpk) - drhoz(:,:,jpkm1) ) - 0.5_wp * drhow(:,:,jpkm1)
833      drhou(:,:,jpk) = 1.5_wp * ( drhox(:,:,jpk) - drhox(:,:,jpkm1) ) - 0.5_wp * drhou(:,:,jpkm1)
834      drhov(:,:,jpk) = 1.5_wp * ( drhoy(:,:,jpk) - drhoy(:,:,jpkm1) ) - 0.5_wp * drhov(:,:,jpkm1)
835
836
837      !--------------------------------------------------------------
838      ! Upper half of top-most grid box, compute and store
839      !-------------------------------------------------------------
840
841!!bug gm   :  e3w-gde3w = 0.5*e3w  ....  and gde3w(2)-gde3w(1)=e3w(2) ....   to be verified
842!          true if gde3w is really defined as the sum of the e3w scale factors as, it seems to me, it should be
843
844      DO jj = 2, jpjm1
845         DO ji = fs_2, fs_jpim1   ! vector opt.
846            rho_k(ji,jj,1) = -grav * ( e3w_n(ji,jj,1) - gde3w_n(ji,jj,1) )               &
847               &                   * (  rhd(ji,jj,1)                                     &
848               &                     + 0.5_wp * ( rhd    (ji,jj,2) - rhd    (ji,jj,1) )  &
849               &                              * ( e3w_n  (ji,jj,1) - gde3w_n(ji,jj,1) )  &
850               &                              / ( gde3w_n(ji,jj,2) - gde3w_n(ji,jj,1) )  )
851         END DO
852      END DO
853
854!!bug gm    : here also, simplification is possible
855!!bug gm    : optimisation: 1/10 and 1/12 the division should be done before the loop
856
857      DO jk = 2, jpkm1
858         DO jj = 2, jpjm1
859            DO ji = fs_2, fs_jpim1   ! vector opt.
860
861               rho_k(ji,jj,jk) = zcoef0 * ( rhd    (ji,jj,jk) + rhd    (ji,jj,jk-1) )                                   &
862                  &                     * ( gde3w_n(ji,jj,jk) - gde3w_n(ji,jj,jk-1) )                                   &
863                  &            - grav * z1_10 * (                                                                   &
864                  &     ( drhow  (ji,jj,jk) - drhow  (ji,jj,jk-1) )                                                     &
865                  &   * ( gde3w_n(ji,jj,jk) - gde3w_n(ji,jj,jk-1) - z1_12 * ( dzw  (ji,jj,jk) + dzw  (ji,jj,jk-1) ) )   &
866                  &   - ( dzw    (ji,jj,jk) - dzw    (ji,jj,jk-1) )                                                     &
867                  &   * ( rhd    (ji,jj,jk) - rhd    (ji,jj,jk-1) - z1_12 * ( drhow(ji,jj,jk) + drhow(ji,jj,jk-1) ) )   &
868                  &                             )
869
870               rho_i(ji,jj,jk) = zcoef0 * ( rhd    (ji+1,jj,jk) + rhd    (ji,jj,jk) )                                   &
871                  &                     * ( gde3w_n(ji+1,jj,jk) - gde3w_n(ji,jj,jk) )                                   &
872                  &            - grav* z1_10 * (                                                                    &
873                  &     ( drhou  (ji+1,jj,jk) - drhou  (ji,jj,jk) )                                                     &
874                  &   * ( gde3w_n(ji+1,jj,jk) - gde3w_n(ji,jj,jk) - z1_12 * ( dzu  (ji+1,jj,jk) + dzu  (ji,jj,jk) ) )   &
875                  &   - ( dzu    (ji+1,jj,jk) - dzu    (ji,jj,jk) )                                                     &
876                  &   * ( rhd    (ji+1,jj,jk) - rhd    (ji,jj,jk) - z1_12 * ( drhou(ji+1,jj,jk) + drhou(ji,jj,jk) ) )   &
877                  &                            )
878
879               rho_j(ji,jj,jk) = zcoef0 * ( rhd    (ji,jj+1,jk) + rhd    (ji,jj,jk) )                                 &
880                  &                     * ( gde3w_n(ji,jj+1,jk) - gde3w_n(ji,jj,jk) )                                   &
881                  &            - grav* z1_10 * (                                                                    &
882                  &     ( drhov  (ji,jj+1,jk) - drhov  (ji,jj,jk) )                                                     &
883                  &   * ( gde3w_n(ji,jj+1,jk) - gde3w_n(ji,jj,jk) - z1_12 * ( dzv  (ji,jj+1,jk) + dzv  (ji,jj,jk) ) )   &
884                  &   - ( dzv    (ji,jj+1,jk) - dzv    (ji,jj,jk) )                                                     &
885                  &   * ( rhd    (ji,jj+1,jk) - rhd    (ji,jj,jk) - z1_12 * ( drhov(ji,jj+1,jk) + drhov(ji,jj,jk) ) )   &
886                  &                            )
887
888            END DO
889         END DO
890      END DO
891      CALL lbc_lnk(rho_k,'W',1.)
892      CALL lbc_lnk(rho_i,'U',1.)
893      CALL lbc_lnk(rho_j,'V',1.)
894
895
896      ! ---------------
897      !  Surface value
898      ! ---------------
899      DO jj = 2, jpjm1
900         DO ji = fs_2, fs_jpim1   ! vector opt.
901            zhpi(ji,jj,1) = ( rho_k(ji+1,jj  ,1) - rho_k(ji,jj,1) - rho_i(ji,jj,1) ) * r1_e1u(ji,jj)
902            zhpj(ji,jj,1) = ( rho_k(ji  ,jj+1,1) - rho_k(ji,jj,1) - rho_j(ji,jj,1) ) * r1_e2v(ji,jj)
903            ! add to the general momentum trend
904            ua(ji,jj,1) = ua(ji,jj,1) + zhpi(ji,jj,1)
905            va(ji,jj,1) = va(ji,jj,1) + zhpj(ji,jj,1)
906         END DO
907      END DO
908
909      ! ----------------
910      !  interior value   (2=<jk=<jpkm1)
911      ! ----------------
912      DO jk = 2, jpkm1
913         DO jj = 2, jpjm1
914            DO ji = fs_2, fs_jpim1   ! vector opt.
915               ! hydrostatic pressure gradient along s-surfaces
916               zhpi(ji,jj,jk) = zhpi(ji,jj,jk-1)                                &
917                  &           + (  ( rho_k(ji+1,jj,jk) - rho_k(ji,jj,jk  ) )    &
918                  &              - ( rho_i(ji  ,jj,jk) - rho_i(ji,jj,jk-1) )  ) * r1_e1u(ji,jj)
919               zhpj(ji,jj,jk) = zhpj(ji,jj,jk-1)                                &
920                  &           + (  ( rho_k(ji,jj+1,jk) - rho_k(ji,jj,jk  ) )    &
921                  &               -( rho_j(ji,jj  ,jk) - rho_j(ji,jj,jk-1) )  ) * r1_e2v(ji,jj)
922               ! add to the general momentum trend
923               ua(ji,jj,jk) = ua(ji,jj,jk) + zhpi(ji,jj,jk)
924               va(ji,jj,jk) = va(ji,jj,jk) + zhpj(ji,jj,jk)
925            END DO
926         END DO
927      END DO
928      !
929      CALL wrk_dealloc( jpi, jpj, jpk, dzx  , dzy  , dzz  , dzu  , dzv  , dzw   )
930      CALL wrk_dealloc( jpi, jpj, jpk, drhox, drhoy, drhoz, drhou, drhov, drhow )
931      CALL wrk_dealloc( jpi, jpj, jpk, rho_i, rho_j, rho_k,  zhpi,  zhpj        )
932      !
933   END SUBROUTINE hpg_djc
934
935
936   SUBROUTINE hpg_prj( kt )
937      !!---------------------------------------------------------------------
938      !!                  ***  ROUTINE hpg_prj  ***
939      !!
940      !! ** Method  :   s-coordinate case.
941      !!      A Pressure-Jacobian horizontal pressure gradient method
942      !!      based on the constrained cubic-spline interpolation for
943      !!      all vertical coordinate systems
944      !!
945      !! ** Action : - Update (ua,va) with the now hydrastatic pressure trend
946      !!----------------------------------------------------------------------
947      INTEGER, PARAMETER  :: polynomial_type = 1    ! 1: cubic spline, 2: linear
948      INTEGER, INTENT(in) ::   kt                   ! ocean time-step index
949      !!
950      INTEGER  ::   ji, jj, jk, jkk                 ! dummy loop indices
951      REAL(wp) ::   zcoef0, znad                    ! local scalars
952      !
953      !! The local variables for the correction term
954      INTEGER  :: jk1, jis, jid, jjs, jjd
955      REAL(wp) :: zuijk, zvijk, zpwes, zpwed, zpnss, zpnsd, zdeps
956      REAL(wp) :: zrhdt1
957      REAL(wp) :: zdpdx1, zdpdx2, zdpdy1, zdpdy2
958      REAL(wp), POINTER, DIMENSION(:,:,:) ::   zdept, zrhh
959      REAL(wp), POINTER, DIMENSION(:,:,:) ::   zhpi, zu, zv, fsp, xsp, asp, bsp, csp, dsp
960      REAL(wp), POINTER, DIMENSION(:,:)   ::   zsshu_n, zsshv_n
961      !!----------------------------------------------------------------------
962      !
963      CALL wrk_alloc( jpi,jpj,jpk,   zhpi, zu, zv, fsp, xsp, asp, bsp, csp, dsp )
964      CALL wrk_alloc( jpi,jpj,jpk,   zdept, zrhh )
965      CALL wrk_alloc( jpi,jpj,       zsshu_n, zsshv_n )
966      !
967      IF( kt == nit000 ) THEN
968         IF(lwp) WRITE(numout,*)
969         IF(lwp) WRITE(numout,*) 'dyn:hpg_prj : hydrostatic pressure gradient trend'
970         IF(lwp) WRITE(numout,*) '~~~~~~~~~~~   s-coordinate case, cubic spline pressure Jacobian'
971      ENDIF
972
973      ! Local constant initialization
974      zcoef0 = - grav
975      znad = 1._wp
976      IF( ln_linssh )   znad = 0._wp
977
978      ! Clean 3-D work arrays
979      zhpi(:,:,:) = 0._wp
980      zrhh(:,:,:) = rhd(:,:,:)
981
982      ! Preparing vertical density profile "zrhh(:,:,:)" for hybrid-sco coordinate
983      DO jj = 1, jpj
984        DO ji = 1, jpi
985          jk = mbathy(ji,jj)
986          IF(     jk <=  0   ) THEN   ;   zrhh(ji,jj,    :   ) = 0._wp
987          ELSEIF( jk ==  1   ) THEN   ;   zrhh(ji,jj,jk+1:jpk) = rhd(ji,jj,jk)
988          ELSEIF( jk < jpkm1 ) THEN
989             DO jkk = jk+1, jpk
990                zrhh(ji,jj,jkk) = interp1(gde3w_n(ji,jj,jkk  ), gde3w_n(ji,jj,jkk-1),   &
991                   &                      gde3w_n(ji,jj,jkk-2), rhd    (ji,jj,jkk-1), rhd(ji,jj,jkk-2))
992             END DO
993          ENDIF
994        END DO
995      END DO
996
997      ! Transfer the depth of "T(:,:,:)" to vertical coordinate "zdept(:,:,:)"
998      DO jj = 1, jpj
999         DO ji = 1, jpi
1000            zdept(ji,jj,1) = 0.5_wp * e3w_n(ji,jj,1) - sshn(ji,jj) * znad
1001         END DO
1002      END DO
1003
1004      DO jk = 2, jpk
1005         DO jj = 1, jpj
1006            DO ji = 1, jpi
1007               zdept(ji,jj,jk) = zdept(ji,jj,jk-1) + e3w_n(ji,jj,jk)
1008            END DO
1009         END DO
1010      END DO
1011
1012      fsp(:,:,:) = zrhh (:,:,:)
1013      xsp(:,:,:) = zdept(:,:,:)
1014
1015      ! Construct the vertical density profile with the
1016      ! constrained cubic spline interpolation
1017      ! rho(z) = asp + bsp*z + csp*z^2 + dsp*z^3
1018      CALL cspline( fsp, xsp, asp, bsp, csp, dsp, polynomial_type )
1019
1020      ! Integrate the hydrostatic pressure "zhpi(:,:,:)" at "T(ji,jj,1)"
1021      DO jj = 2, jpj
1022        DO ji = 2, jpi
1023          zrhdt1 = zrhh(ji,jj,1) - interp3( zdept(ji,jj,1), asp(ji,jj,1), bsp(ji,jj,1),  &
1024             &                                              csp(ji,jj,1), dsp(ji,jj,1) ) * 0.25_wp * e3w_n(ji,jj,1)
1025
1026          ! assuming linear profile across the top half surface layer
1027          zhpi(ji,jj,1) =  0.5_wp * e3w_n(ji,jj,1) * zrhdt1
1028        END DO
1029      END DO
1030
1031      ! Calculate the pressure "zhpi(:,:,:)" at "T(ji,jj,2:jpkm1)"
1032      DO jk = 2, jpkm1
1033        DO jj = 2, jpj
1034          DO ji = 2, jpi
1035            zhpi(ji,jj,jk) = zhpi(ji,jj,jk-1) +                                  &
1036               &             integ_spline( zdept(ji,jj,jk-1), zdept(ji,jj,jk),   &
1037               &                           asp  (ji,jj,jk-1), bsp  (ji,jj,jk-1), &
1038               &                           csp  (ji,jj,jk-1), dsp  (ji,jj,jk-1)  )
1039          END DO
1040        END DO
1041      END DO
1042
1043      ! Z coordinate of U(ji,jj,1:jpkm1) and V(ji,jj,1:jpkm1)
1044
1045      ! Prepare zsshu_n and zsshv_n
1046      DO jj = 2, jpjm1
1047        DO ji = 2, jpim1
1048!!gm BUG ?    if it is ssh at u- & v-point then it should be:
1049!          zsshu_n(ji,jj) = (e1e2t(ji,jj) * sshn(ji,jj) + e1e2t(ji+1,jj) * sshn(ji+1,jj)) * &
1050!                         & r1_e1e2u(ji,jj) * umask(ji,jj,1) * 0.5_wp
1051!          zsshv_n(ji,jj) = (e1e2t(ji,jj) * sshn(ji,jj) + e1e2t(ji,jj+1) * sshn(ji,jj+1)) * &
1052!                         & r1_e1e2v(ji,jj) * vmask(ji,jj,1) * 0.5_wp
1053!!gm not this:
1054          zsshu_n(ji,jj) = (e1e2u(ji,jj) * sshn(ji,jj) + e1e2u(ji+1, jj) * sshn(ji+1,jj)) * &
1055                         & r1_e1e2u(ji,jj) * umask(ji,jj,1) * 0.5_wp 
1056          zsshv_n(ji,jj) = (e1e2v(ji,jj) * sshn(ji,jj) + e1e2v(ji+1, jj) * sshn(ji,jj+1)) * &
1057                         & r1_e1e2v(ji,jj) * vmask(ji,jj,1) * 0.5_wp 
1058        END DO
1059      END DO
1060
1061      DO jj = 2, jpjm1
1062        DO ji = 2, jpim1
1063          zu(ji,jj,1) = - ( e3u_n(ji,jj,1) - zsshu_n(ji,jj) * znad) 
1064          zv(ji,jj,1) = - ( e3v_n(ji,jj,1) - zsshv_n(ji,jj) * znad)
1065        END DO
1066      END DO
1067
1068      DO jk = 2, jpkm1
1069        DO jj = 2, jpjm1
1070          DO ji = 2, jpim1
1071            zu(ji,jj,jk) = zu(ji,jj,jk-1) - e3u_n(ji,jj,jk)
1072            zv(ji,jj,jk) = zv(ji,jj,jk-1) - e3v_n(ji,jj,jk)
1073          END DO
1074        END DO
1075      END DO
1076
1077      DO jk = 1, jpkm1
1078        DO jj = 2, jpjm1
1079          DO ji = 2, jpim1
1080            zu(ji,jj,jk) = zu(ji,jj,jk) + 0.5_wp * e3u_n(ji,jj,jk)
1081            zv(ji,jj,jk) = zv(ji,jj,jk) + 0.5_wp * e3v_n(ji,jj,jk)
1082          END DO
1083        END DO
1084      END DO
1085
1086      DO jk = 1, jpkm1
1087        DO jj = 2, jpjm1
1088          DO ji = 2, jpim1
1089            zu(ji,jj,jk) = MIN(  zu(ji,jj,jk) , MAX( -zdept(ji,jj,jk) , -zdept(ji+1,jj,jk) )  )
1090            zu(ji,jj,jk) = MAX(  zu(ji,jj,jk) , MIN( -zdept(ji,jj,jk) , -zdept(ji+1,jj,jk) )  )
1091            zv(ji,jj,jk) = MIN(  zv(ji,jj,jk) , MAX( -zdept(ji,jj,jk) , -zdept(ji,jj+1,jk) )  )
1092            zv(ji,jj,jk) = MAX(  zv(ji,jj,jk) , MIN( -zdept(ji,jj,jk) , -zdept(ji,jj+1,jk) )  )
1093          END DO
1094        END DO
1095      END DO
1096
1097
1098      DO jk = 1, jpkm1
1099        DO jj = 2, jpjm1
1100          DO ji = 2, jpim1
1101            zpwes = 0._wp; zpwed = 0._wp
1102            zpnss = 0._wp; zpnsd = 0._wp
1103            zuijk = zu(ji,jj,jk)
1104            zvijk = zv(ji,jj,jk)
1105
1106            !!!!!     for u equation
1107            IF( jk <= mbku(ji,jj) ) THEN
1108               IF( -zdept(ji+1,jj,jk) >= -zdept(ji,jj,jk) ) THEN
1109                 jis = ji + 1; jid = ji
1110               ELSE
1111                 jis = ji;     jid = ji +1
1112               ENDIF
1113
1114               ! integrate the pressure on the shallow side
1115               jk1 = jk
1116               DO WHILE ( -zdept(jis,jj,jk1) > zuijk )
1117                 IF( jk1 == mbku(ji,jj) ) THEN
1118                   zuijk = -zdept(jis,jj,jk1)
1119                   EXIT
1120                 ENDIF
1121                 zdeps = MIN(zdept(jis,jj,jk1+1), -zuijk)
1122                 zpwes = zpwes +                                    &
1123                      integ_spline(zdept(jis,jj,jk1), zdeps,            &
1124                             asp(jis,jj,jk1),    bsp(jis,jj,jk1), &
1125                             csp(jis,jj,jk1),    dsp(jis,jj,jk1))
1126                 jk1 = jk1 + 1
1127               END DO
1128
1129               ! integrate the pressure on the deep side
1130               jk1 = jk
1131               DO WHILE ( -zdept(jid,jj,jk1) < zuijk )
1132                 IF( jk1 == 1 ) THEN
1133                   zdeps = zdept(jid,jj,1) + MIN(zuijk, sshn(jid,jj)*znad)
1134                   zrhdt1 = zrhh(jid,jj,1) - interp3(zdept(jid,jj,1), asp(jid,jj,1), &
1135                                                     bsp(jid,jj,1),   csp(jid,jj,1), &
1136                                                     dsp(jid,jj,1)) * zdeps
1137                   zpwed  = zpwed + 0.5_wp * (zrhh(jid,jj,1) + zrhdt1) * zdeps
1138                   EXIT
1139                 ENDIF
1140                 zdeps = MAX(zdept(jid,jj,jk1-1), -zuijk)
1141                 zpwed = zpwed +                                        &
1142                        integ_spline(zdeps,              zdept(jid,jj,jk1), &
1143                               asp(jid,jj,jk1-1), bsp(jid,jj,jk1-1),  &
1144                               csp(jid,jj,jk1-1), dsp(jid,jj,jk1-1) )
1145                 jk1 = jk1 - 1
1146               END DO
1147
1148               ! update the momentum trends in u direction
1149
1150               zdpdx1 = zcoef0 * r1_e1u(ji,jj) * ( zhpi(ji+1,jj,jk) - zhpi(ji,jj,jk) )
1151               IF( .NOT.ln_linssh ) THEN
1152                 zdpdx2 = zcoef0 * r1_e1u(ji,jj) * &
1153                    &    ( REAL(jis-jid, wp) * (zpwes + zpwed) + (sshn(ji+1,jj)-sshn(ji,jj)) )
1154                ELSE
1155                 zdpdx2 = zcoef0 * r1_e1u(ji,jj) * REAL(jis-jid, wp) * (zpwes + zpwed)
1156               ENDIF
1157!!gm  Since umask(ji,:,:) = tmask(ji,:,:) * tmask(ji+1,:,:)  by definition
1158!!gm      in the line below only * umask(ji,jj,jk)  is needed !!
1159               ua(ji,jj,jk) = ua(ji,jj,jk) + (zdpdx1 + zdpdx2) * umask(ji,jj,jk) * tmask(ji,jj,jk) * tmask(ji+1,jj,jk)
1160            ENDIF
1161
1162            !!!!!     for v equation
1163            IF( jk <= mbkv(ji,jj) ) THEN
1164               IF( -zdept(ji,jj+1,jk) >= -zdept(ji,jj,jk) ) THEN
1165                 jjs = jj + 1; jjd = jj
1166               ELSE
1167                 jjs = jj    ; jjd = jj + 1
1168               ENDIF
1169
1170               ! integrate the pressure on the shallow side
1171               jk1 = jk
1172               DO WHILE ( -zdept(ji,jjs,jk1) > zvijk )
1173                 IF( jk1 == mbkv(ji,jj) ) THEN
1174                   zvijk = -zdept(ji,jjs,jk1)
1175                   EXIT
1176                 ENDIF
1177                 zdeps = MIN(zdept(ji,jjs,jk1+1), -zvijk)
1178                 zpnss = zpnss +                                      &
1179                        integ_spline(zdept(ji,jjs,jk1), zdeps,            &
1180                               asp(ji,jjs,jk1),    bsp(ji,jjs,jk1), &
1181                               csp(ji,jjs,jk1),    dsp(ji,jjs,jk1) )
1182                 jk1 = jk1 + 1
1183               END DO
1184
1185               ! integrate the pressure on the deep side
1186               jk1 = jk
1187               DO WHILE ( -zdept(ji,jjd,jk1) < zvijk )
1188                 IF( jk1 == 1 ) THEN
1189                   zdeps = zdept(ji,jjd,1) + MIN(zvijk, sshn(ji,jjd)*znad)
1190                   zrhdt1 = zrhh(ji,jjd,1) - interp3(zdept(ji,jjd,1), asp(ji,jjd,1), &
1191                                                     bsp(ji,jjd,1),   csp(ji,jjd,1), &
1192                                                     dsp(ji,jjd,1) ) * zdeps
1193                   zpnsd  = zpnsd + 0.5_wp * (zrhh(ji,jjd,1) + zrhdt1) * zdeps
1194                   EXIT
1195                 ENDIF
1196                 zdeps = MAX(zdept(ji,jjd,jk1-1), -zvijk)
1197                 zpnsd = zpnsd +                                        &
1198                        integ_spline(zdeps,              zdept(ji,jjd,jk1), &
1199                               asp(ji,jjd,jk1-1), bsp(ji,jjd,jk1-1), &
1200                               csp(ji,jjd,jk1-1), dsp(ji,jjd,jk1-1) )
1201                 jk1 = jk1 - 1
1202               END DO
1203
1204
1205               ! update the momentum trends in v direction
1206
1207               zdpdy1 = zcoef0 * r1_e2v(ji,jj) * ( zhpi(ji,jj+1,jk) - zhpi(ji,jj,jk) )
1208               IF( .NOT.ln_linssh ) THEN
1209                  zdpdy2 = zcoef0 * r1_e2v(ji,jj) * &
1210                          ( REAL(jjs-jjd, wp) * (zpnss + zpnsd) + (sshn(ji,jj+1)-sshn(ji,jj)) )
1211               ELSE
1212                  zdpdy2 = zcoef0 * r1_e2v(ji,jj) * REAL(jjs-jjd, wp) * (zpnss + zpnsd )
1213               ENDIF
1214!!gm  Since vmask(:,jj,:) = tmask(:,jj,:) * tmask(:,jj+1,:)  by definition
1215!!gm      in the line below only * vmask(ji,jj,jk)  is needed !!
1216               va(ji,jj,jk) = va(ji,jj,jk) + ( zdpdy1 + zdpdy2 ) * vmask(ji,jj,jk)*tmask(ji,jj,jk)*tmask(ji,jj+1,jk)
1217            ENDIF
1218               !
1219            END DO
1220         END DO
1221      END DO
1222      !
1223      CALL wrk_dealloc( jpi,jpj,jpk,   zhpi, zu, zv, fsp, xsp, asp, bsp, csp, dsp )
1224      CALL wrk_dealloc( jpi,jpj,jpk,   zdept, zrhh )
1225      CALL wrk_dealloc( jpi,jpj,       zsshu_n, zsshv_n )
1226      !
1227   END SUBROUTINE hpg_prj
1228
1229
1230   SUBROUTINE cspline( fsp, xsp, asp, bsp, csp, dsp, polynomial_type )
1231      !!----------------------------------------------------------------------
1232      !!                 ***  ROUTINE cspline  ***
1233      !!
1234      !! ** Purpose :   constrained cubic spline interpolation
1235      !!
1236      !! ** Method  :   f(x) = asp + bsp*x + csp*x^2 + dsp*x^3
1237      !!
1238      !! Reference: CJC Kruger, Constrained Cubic Spline Interpoltation
1239      !!----------------------------------------------------------------------
1240      REAL(wp), DIMENSION(:,:,:), INTENT(in   ) ::   fsp, xsp           ! value and coordinate
1241      REAL(wp), DIMENSION(:,:,:), INTENT(  out) ::   asp, bsp, csp, dsp ! coefficients of the interpoated function
1242      INTEGER                   , INTENT(in   ) ::   polynomial_type    ! 1: cubic spline   ;   2: Linear
1243      !
1244      INTEGER  ::   ji, jj, jk                 ! dummy loop indices
1245      INTEGER  ::   jpi, jpj, jpkm1
1246      REAL(wp) ::   zdf1, zdf2, zddf1, zddf2, ztmp1, ztmp2, zdxtmp
1247      REAL(wp) ::   zdxtmp1, zdxtmp2, zalpha
1248      REAL(wp) ::   zdf(size(fsp,3))
1249      !!----------------------------------------------------------------------
1250      !
1251!!gm  WHAT !!!!!   THIS IS VERY DANGEROUS !!!!! 
1252      jpi   = size(fsp,1)
1253      jpj   = size(fsp,2)
1254      jpkm1 = size(fsp,3) - 1
1255      !
1256      IF (polynomial_type == 1) THEN     ! Constrained Cubic Spline
1257         DO ji = 1, jpi
1258            DO jj = 1, jpj
1259           !!Fritsch&Butland's method, 1984 (preferred, but more computation)
1260           !    DO jk = 2, jpkm1-1
1261           !       zdxtmp1 = xsp(ji,jj,jk)   - xsp(ji,jj,jk-1)
1262           !       zdxtmp2 = xsp(ji,jj,jk+1) - xsp(ji,jj,jk)
1263           !       zdf1    = ( fsp(ji,jj,jk)   - fsp(ji,jj,jk-1) ) / zdxtmp1
1264           !       zdf2    = ( fsp(ji,jj,jk+1) - fsp(ji,jj,jk)   ) / zdxtmp2
1265           !
1266           !       zalpha = ( zdxtmp1 + 2._wp * zdxtmp2 ) / ( zdxtmp1 + zdxtmp2 ) / 3._wp
1267           !
1268           !       IF(zdf1 * zdf2 <= 0._wp) THEN
1269           !           zdf(jk) = 0._wp
1270           !       ELSE
1271           !         zdf(jk) = zdf1 * zdf2 / ( ( 1._wp - zalpha ) * zdf1 + zalpha * zdf2 )
1272           !       ENDIF
1273           !    END DO
1274
1275           !!Simply geometric average
1276               DO jk = 2, jpkm1-1
1277                  zdf1 = (fsp(ji,jj,jk) - fsp(ji,jj,jk-1)) / (xsp(ji,jj,jk) - xsp(ji,jj,jk-1))
1278                  zdf2 = (fsp(ji,jj,jk+1) - fsp(ji,jj,jk)) / (xsp(ji,jj,jk+1) - xsp(ji,jj,jk))
1279
1280                  IF(zdf1 * zdf2 <= 0._wp) THEN
1281                     zdf(jk) = 0._wp
1282                  ELSE
1283                     zdf(jk) = 2._wp * zdf1 * zdf2 / (zdf1 + zdf2)
1284                  ENDIF
1285               END DO
1286
1287               zdf(1)     = 1.5_wp * ( fsp(ji,jj,2) - fsp(ji,jj,1) ) / &
1288                          &          ( xsp(ji,jj,2) - xsp(ji,jj,1) )           -  0.5_wp * zdf(2)
1289               zdf(jpkm1) = 1.5_wp * ( fsp(ji,jj,jpkm1) - fsp(ji,jj,jpkm1-1) ) / &
1290                          &          ( xsp(ji,jj,jpkm1) - xsp(ji,jj,jpkm1-1) ) - 0.5_wp * zdf(jpkm1 - 1)
1291
1292               DO jk = 1, jpkm1 - 1
1293                 zdxtmp = xsp(ji,jj,jk+1) - xsp(ji,jj,jk)
1294                 ztmp1  = (zdf(jk+1) + 2._wp * zdf(jk)) / zdxtmp
1295                 ztmp2  =  6._wp * (fsp(ji,jj,jk+1) - fsp(ji,jj,jk)) / zdxtmp / zdxtmp
1296                 zddf1  = -2._wp * ztmp1 + ztmp2
1297                 ztmp1  = (2._wp * zdf(jk+1) + zdf(jk)) / zdxtmp
1298                 zddf2  =  2._wp * ztmp1 - ztmp2
1299
1300                 dsp(ji,jj,jk) = (zddf2 - zddf1) / 6._wp / zdxtmp
1301                 csp(ji,jj,jk) = ( xsp(ji,jj,jk+1) * zddf1 - xsp(ji,jj,jk)*zddf2 ) / 2._wp / zdxtmp
1302                 bsp(ji,jj,jk) = ( fsp(ji,jj,jk+1) - fsp(ji,jj,jk) ) / zdxtmp - &
1303                               & csp(ji,jj,jk) * ( xsp(ji,jj,jk+1) + xsp(ji,jj,jk) ) - &
1304                               & dsp(ji,jj,jk) * ((xsp(ji,jj,jk+1) + xsp(ji,jj,jk))**2 - &
1305                               &                   xsp(ji,jj,jk+1) * xsp(ji,jj,jk))
1306                 asp(ji,jj,jk) = fsp(ji,jj,jk) - xsp(ji,jj,jk) * (bsp(ji,jj,jk) + &
1307                               &                (xsp(ji,jj,jk) * (csp(ji,jj,jk) + &
1308                               &                 dsp(ji,jj,jk) * xsp(ji,jj,jk))))
1309               END DO
1310            END DO
1311         END DO
1312
1313      ELSEIF ( polynomial_type == 2 ) THEN     ! Linear
1314         DO ji = 1, jpi
1315            DO jj = 1, jpj
1316               DO jk = 1, jpkm1-1
1317                  zdxtmp =xsp(ji,jj,jk+1) - xsp(ji,jj,jk)
1318                  ztmp1 = fsp(ji,jj,jk+1) - fsp(ji,jj,jk)
1319
1320                  dsp(ji,jj,jk) = 0._wp
1321                  csp(ji,jj,jk) = 0._wp
1322                  bsp(ji,jj,jk) = ztmp1 / zdxtmp
1323                  asp(ji,jj,jk) = fsp(ji,jj,jk) - bsp(ji,jj,jk) * xsp(ji,jj,jk)
1324               END DO
1325            END DO
1326         END DO
1327
1328      ELSE
1329           CALL ctl_stop( 'invalid polynomial type in cspline' )
1330      ENDIF
1331
1332   END SUBROUTINE cspline
1333
1334
1335   FUNCTION interp1(x, xl, xr, fl, fr)  RESULT(f)
1336      !!----------------------------------------------------------------------
1337      !!                 ***  ROUTINE interp1  ***
1338      !!
1339      !! ** Purpose :   1-d linear interpolation
1340      !!
1341      !! ** Method  :   interpolation is straight forward
1342      !!                extrapolation is also permitted (no value limit)
1343      !!----------------------------------------------------------------------
1344      REAL(wp), INTENT(in) ::  x, xl, xr, fl, fr
1345      REAL(wp)             ::  f ! result of the interpolation (extrapolation)
1346      REAL(wp)             ::  zdeltx
1347      !!----------------------------------------------------------------------
1348      !
1349      zdeltx = xr - xl
1350      IF( abs(zdeltx) <= 10._wp * EPSILON(x) ) THEN
1351         f = 0.5_wp * (fl + fr)
1352      ELSE
1353         f = ( (x - xl ) * fr - ( x - xr ) * fl ) / zdeltx
1354      ENDIF
1355      !
1356   END FUNCTION interp1
1357
1358
1359   FUNCTION interp2( x, a, b, c, d )  RESULT(f)
1360      !!----------------------------------------------------------------------
1361      !!                 ***  ROUTINE interp1  ***
1362      !!
1363      !! ** Purpose :   1-d constrained cubic spline interpolation
1364      !!
1365      !! ** Method  :  cubic spline interpolation
1366      !!
1367      !!----------------------------------------------------------------------
1368      REAL(wp), INTENT(in) ::  x, a, b, c, d
1369      REAL(wp)             ::  f ! value from the interpolation
1370      !!----------------------------------------------------------------------
1371      !
1372      f = a + x* ( b + x * ( c + d * x ) )
1373      !
1374   END FUNCTION interp2
1375
1376
1377   FUNCTION interp3( x, a, b, c, d )  RESULT(f)
1378      !!----------------------------------------------------------------------
1379      !!                 ***  ROUTINE interp1  ***
1380      !!
1381      !! ** Purpose :   Calculate the first order of deriavtive of
1382      !!                a cubic spline function y=a+b*x+c*x^2+d*x^3
1383      !!
1384      !! ** Method  :   f=dy/dx=b+2*c*x+3*d*x^2
1385      !!
1386      !!----------------------------------------------------------------------
1387      REAL(wp), INTENT(in) ::  x, a, b, c, d
1388      REAL(wp)             ::  f ! value from the interpolation
1389      !!----------------------------------------------------------------------
1390      !
1391      f = b + x * ( 2._wp * c + 3._wp * d * x)
1392      !
1393   END FUNCTION interp3
1394
1395
1396   FUNCTION integ_spline( xl, xr, a, b, c, d )  RESULT(f)
1397      !!----------------------------------------------------------------------
1398      !!                 ***  ROUTINE interp1  ***
1399      !!
1400      !! ** Purpose :   1-d constrained cubic spline integration
1401      !!
1402      !! ** Method  :  integrate polynomial a+bx+cx^2+dx^3 from xl to xr
1403      !!
1404      !!----------------------------------------------------------------------
1405      REAL(wp), INTENT(in) ::  xl, xr, a, b, c, d
1406      REAL(wp)             ::  za1, za2, za3
1407      REAL(wp)             ::  f                   ! integration result
1408      !!----------------------------------------------------------------------
1409      !
1410      za1 = 0.5_wp * b
1411      za2 = c / 3.0_wp
1412      za3 = 0.25_wp * d
1413      !
1414      f  = xr * ( a + xr * ( za1 + xr * ( za2 + za3 * xr ) ) ) - &
1415         & xl * ( a + xl * ( za1 + xl * ( za2 + za3 * xl ) ) )
1416      !
1417   END FUNCTION integ_spline
1418
1419   !!======================================================================
1420END MODULE dynhpg
1421
Note: See TracBrowser for help on using the repository browser.