New URL for NEMO forge!   http://forge.nemo-ocean.eu

Since March 2022 along with NEMO 4.2 release, the code development moved to a self-hosted GitLab.
This present forge is now archived and remained online for history.
sbcssm.F90 in branches/2015/dev_r5836_NOC3_vvl_by_default/NEMOGCM/NEMO/OPA_SRC/SBC – NEMO

source: branches/2015/dev_r5836_NOC3_vvl_by_default/NEMOGCM/NEMO/OPA_SRC/SBC/sbcssm.F90 @ 5845

Last change on this file since 5845 was 5845, checked in by gm, 8 years ago

#1613: vvl by default: suppression of domzgr_substitute.h90

  • Property svn:keywords set to Id
File size: 13.2 KB
Line 
1MODULE sbcssm
2   !!======================================================================
3   !!                       ***  MODULE  sbcssm  ***
4   !! Surface module :  provide time-mean ocean surface variables
5   !!======================================================================
6   !! History :  9.0  ! 2006-07  (G. Madec)  Original code
7   !!            3.3  ! 2010-10  (C. Bricaud, G. Madec)  add the Patm forcing for sea-ice
8   !!----------------------------------------------------------------------
9
10   !!----------------------------------------------------------------------
11   !!   sbc_ssm        : calculate sea surface mean currents, temperature, 
12   !!                    and salinity over nn_fsbc time-step
13   !!----------------------------------------------------------------------
14   USE oce             ! ocean dynamics and tracers
15   USE dom_oce         ! ocean space and time domain
16   USE sbc_oce         ! surface boundary condition: ocean fields
17   USE sbcapr          ! surface boundary condition: atmospheric pressure
18   USE eosbn2          ! equation of state and related derivatives
19   !
20   USE in_out_manager  ! I/O manager
21   USE prtctl          ! Print control
22   USE iom             ! IOM library
23
24   IMPLICIT NONE
25   PRIVATE
26
27   PUBLIC   sbc_ssm         ! routine called by step.F90
28   PUBLIC   sbc_ssm_init    ! routine called by sbcmod.F90
29
30   LOGICAL, SAVE  ::   l_ssm_mean = .FALSE.       ! keep track of whether means have been read from restart file
31   
32   !!----------------------------------------------------------------------
33   !! NEMO/OPA 3.3 , NEMO Consortium (2010)
34   !! $Id$
35   !! Software governed by the CeCILL licence     (NEMOGCM/NEMO_CeCILL.txt)
36   !!----------------------------------------------------------------------
37CONTAINS
38
39   SUBROUTINE sbc_ssm( kt )
40      !!---------------------------------------------------------------------
41      !!                     ***  ROUTINE sbc_oce  ***
42      !!                     
43      !! ** Purpose :   provide ocean surface variable to sea-surface boundary
44      !!                condition computation
45      !!               
46      !! ** Method  :   compute mean surface velocity (2 components at U and
47      !!      V-points) [m/s], temperature [Celcius] and salinity [psu] over
48      !!      the periode (kt - nn_fsbc) to kt
49      !!         Note that the inverse barometer ssh (i.e. ssh associated with Patm)
50      !!      is add to ssh_m when ln_apr_dyn = T. Required for sea-ice dynamics.
51      !!---------------------------------------------------------------------
52      INTEGER, INTENT(in) ::   kt   ! ocean time step
53      !
54      INTEGER  ::   ji, jj               ! loop index
55      REAL(wp) ::   zcoef, zf_sbc       ! local scalar
56      REAL(wp), DIMENSION(jpi,jpj,jpts) :: zts
57      !!---------------------------------------------------------------------
58
59      !                                        !* surface T-, U-, V- ocean level variables (T, S, depth, velocity)
60      DO jj = 1, jpj
61         DO ji = 1, jpi
62            zts(ji,jj,jp_tem) = tsn(ji,jj,mikt(ji,jj),jp_tem)
63            zts(ji,jj,jp_sal) = tsn(ji,jj,mikt(ji,jj),jp_sal)
64         END DO
65      END DO
66      !
67      IF( nn_fsbc == 1 ) THEN                             !   Instantaneous surface fields        !
68         !                                                ! ---------------------------------------- !
69         ssu_m(:,:) = ub(:,:,1)
70         ssv_m(:,:) = vb(:,:,1)
71         IF( ln_useCT )  THEN    ;   sst_m(:,:) = eos_pt_from_ct( zts(:,:,jp_tem), zts(:,:,jp_sal) )
72         ELSE                    ;   sst_m(:,:) = zts(:,:,jp_tem)
73         ENDIF
74         sss_m(:,:) = zts(:,:,jp_sal)
75         !                          ! removed inverse barometer ssh when Patm forcing is used (for sea-ice dynamics)
76         IF( ln_apr_dyn ) THEN   ;   ssh_m(:,:) = sshn(:,:) - 0.5 * ( ssh_ib(:,:) + ssh_ibb(:,:) )
77         ELSE                    ;   ssh_m(:,:) = sshn(:,:)
78         ENDIF
79         !
80         IF( lk_vvl )   e3t_m(:,:) = e3t_n(:,:,1)
81         !
82         frq_m(:,:) = fraqsr_1lev(:,:)
83         !
84      ELSE
85         !                                                ! ----------------------------------------------- !
86         IF( kt == nit000 .AND. .NOT. l_ssm_mean ) THEN   !   Initialisation: 1st time-step, no input means !
87            !                                             ! ----------------------------------------------- !
88            IF(lwp) WRITE(numout,*)
89            IF(lwp) WRITE(numout,*) '~~~~~~~   mean fields initialised to instantaneous values'
90            zcoef = REAL( nn_fsbc - 1, wp )
91            ssu_m(:,:) = zcoef * ub(:,:,1)
92            ssv_m(:,:) = zcoef * vb(:,:,1)
93            IF( ln_useCT )  THEN    ;   sst_m(:,:) = zcoef * eos_pt_from_ct( zts(:,:,jp_tem), zts(:,:,jp_sal) )
94            ELSE                    ;   sst_m(:,:) = zcoef * zts(:,:,jp_tem)
95            ENDIF
96            sss_m(:,:) = zcoef * zts(:,:,jp_sal)
97            !                          ! removed inverse barometer ssh when Patm forcing is used (for sea-ice dynamics)
98            IF( ln_apr_dyn ) THEN   ;   ssh_m(:,:) = zcoef * ( sshn(:,:) - 0.5 * ( ssh_ib(:,:) + ssh_ibb(:,:) ) )
99            ELSE                    ;   ssh_m(:,:) = zcoef * sshn(:,:)
100            ENDIF
101            !
102            IF( lk_vvl )   e3t_m(:,:) = zcoef * e3t_n(:,:,1)
103            !
104            frq_m(:,:) = zcoef * fraqsr_1lev(:,:)
105            !                                             ! ---------------------------------------- !
106         ELSEIF( MOD( kt - 2 , nn_fsbc ) == 0 ) THEN      !   Initialisation: New mean computation   !
107            !                                             ! ---------------------------------------- !
108            ssu_m(:,:) = 0.e0      ! reset to zero ocean mean sbc fields
109            ssv_m(:,:) = 0.e0
110            sst_m(:,:) = 0.e0
111            sss_m(:,:) = 0.e0
112            ssh_m(:,:) = 0.e0
113            IF( lk_vvl )   e3t_m(:,:) = 0.e0
114            frq_m(:,:) = 0.e0
115         ENDIF
116         !                                                ! ---------------------------------------- !
117         !                                                !        Cumulate at each time step        !
118         !                                                ! ---------------------------------------- !
119         ssu_m(:,:) = ssu_m(:,:) + ub(:,:,1)
120         ssv_m(:,:) = ssv_m(:,:) + vb(:,:,1)
121         IF( ln_useCT )  THEN    ;   sst_m(:,:) = sst_m(:,:) + eos_pt_from_ct( zts(:,:,jp_tem), zts(:,:,jp_sal) )
122         ELSE                    ;   sst_m(:,:) = sst_m(:,:) + zts(:,:,jp_tem)
123         ENDIF
124         sss_m(:,:) = sss_m(:,:) + zts(:,:,jp_sal)
125         !                          ! removed inverse barometer ssh when Patm forcing is used (for sea-ice dynamics)
126         IF( ln_apr_dyn ) THEN   ;   ssh_m(:,:) = ssh_m(:,:) + sshn(:,:) - 0.5 * ( ssh_ib(:,:) + ssh_ibb(:,:) )
127         ELSE                    ;   ssh_m(:,:) = ssh_m(:,:) + sshn(:,:)
128         ENDIF
129         !
130         IF( lk_vvl )   e3t_m(:,:) = e3t_m(:,:) + e3t_n(:,:,1)
131         !
132         frq_m(:,:) =   frq_m(:,:) + fraqsr_1lev(:,:)
133
134         !                                                ! ---------------------------------------- !
135         IF( MOD( kt - 1 , nn_fsbc ) == 0 ) THEN          !   Mean value at each nn_fsbc time-step   !
136            !                                             ! ---------------------------------------- !
137            zcoef = 1. / REAL( nn_fsbc, wp )
138            sst_m(:,:) = sst_m(:,:) * zcoef           ! mean SST             [Celcius]
139            sss_m(:,:) = sss_m(:,:) * zcoef           ! mean SSS             [psu]
140            ssu_m(:,:) = ssu_m(:,:) * zcoef           ! mean suface current  [m/s]
141            ssv_m(:,:) = ssv_m(:,:) * zcoef           !
142            ssh_m(:,:) = ssh_m(:,:) * zcoef           ! mean SSH             [m]
143            IF( lk_vvl )   e3t_m(:,:) = e3t_m(:,:) * zcoef   ! mean vertical scale factor [m]
144            frq_m(:,:) = frq_m(:,:) * zcoef   ! mean fraction of solar net radiation absorbed in the 1st T level [-]
145            !
146         ENDIF
147         !                                                ! ---------------------------------------- !
148         IF( lrst_oce ) THEN                              !      Write in the ocean restart file     !
149            !                                             ! ---------------------------------------- !
150            IF(lwp) WRITE(numout,*)
151            IF(lwp) WRITE(numout,*) 'sbc_ssm : sea surface mean fields written in ocean restart file ',   &
152               &                    'at it= ', kt,' date= ', ndastp
153            IF(lwp) WRITE(numout,*) '~~~~~~~'
154            zf_sbc = REAL( nn_fsbc, wp )
155            CALL iom_rstput( kt, nitrst, numrow, 'nn_fsbc', zf_sbc )    ! sbc frequency
156            CALL iom_rstput( kt, nitrst, numrow, 'ssu_m'  , ssu_m  )    ! sea surface mean fields
157            CALL iom_rstput( kt, nitrst, numrow, 'ssv_m'  , ssv_m  )
158            CALL iom_rstput( kt, nitrst, numrow, 'sst_m'  , sst_m  )
159            CALL iom_rstput( kt, nitrst, numrow, 'sss_m'  , sss_m  )
160            CALL iom_rstput( kt, nitrst, numrow, 'ssh_m'  , ssh_m  )
161            IF( lk_vvl )   CALL iom_rstput( kt, nitrst, numrow, 'e3t_m'  , e3t_m  )
162            CALL iom_rstput( kt, nitrst, numrow, 'frq_m'  , frq_m  )
163            !
164         ENDIF
165         !
166      ENDIF
167      !
168      IF( MOD( kt - 1 , nn_fsbc ) == 0 ) THEN          !   Mean value at each nn_fsbc time-step   !
169         CALL iom_put( 'ssu_m', ssu_m )
170         CALL iom_put( 'ssv_m', ssv_m )
171         CALL iom_put( 'sst_m', sst_m )
172         CALL iom_put( 'sss_m', sss_m )
173         CALL iom_put( 'ssh_m', ssh_m )
174         IF( lk_vvl )   CALL iom_put( 'e3t_m', e3t_m )
175         CALL iom_put( 'frq_m', frq_m )
176      ENDIF
177      !
178   END SUBROUTINE sbc_ssm
179
180   SUBROUTINE sbc_ssm_init
181      !!----------------------------------------------------------------------
182      !!                  ***  ROUTINE sbc_ssm_init  ***
183      !!
184      !! ** Purpose :   Initialisation of the sbc data
185      !!
186      !! ** Action  : - read parameters
187      !!----------------------------------------------------------------------
188      REAL(wp) ::   zcoef, zf_sbc       ! local scalar
189      !!----------------------------------------------------------------------
190
191      IF( nn_fsbc == 1 ) THEN
192         !
193         IF(lwp) WRITE(numout,*)
194         IF(lwp) WRITE(numout,*) 'sbc_ssm : sea surface mean fields, nn_fsbc=1 : instantaneous values'
195         IF(lwp) WRITE(numout,*) '~~~~~~~ '
196         !
197      ELSE
198         !               
199         IF(lwp) WRITE(numout,*)
200         IF(lwp) WRITE(numout,*) 'sbc_ssm : sea surface mean fields'
201         IF(lwp) WRITE(numout,*) '~~~~~~~ '
202         !
203         IF( ln_rstart .AND. iom_varid( numror, 'nn_fsbc', ldstop = .FALSE. ) > 0 ) THEN
204            l_ssm_mean = .TRUE.
205            CALL iom_get( numror               , 'nn_fsbc', zf_sbc )   ! sbc frequency of previous run
206            CALL iom_get( numror, jpdom_autoglo, 'ssu_m'  , ssu_m  )   ! sea surface mean velocity    (T-point)
207            CALL iom_get( numror, jpdom_autoglo, 'ssv_m'  , ssv_m  )   !   "         "    velocity    (V-point)
208            CALL iom_get( numror, jpdom_autoglo, 'sst_m'  , sst_m  )   !   "         "    temperature (T-point)
209            CALL iom_get( numror, jpdom_autoglo, 'sss_m'  , sss_m  )   !   "         "    salinity    (T-point)
210            CALL iom_get( numror, jpdom_autoglo, 'ssh_m'  , ssh_m  )   !   "         "    height      (T-point)
211            IF( lk_vvl ) CALL iom_get( numror, jpdom_autoglo, 'e3t_m', e3t_m )
212            ! fraction of solar net radiation absorbed in 1st T level
213            IF( iom_varid( numror, 'frq_m', ldstop = .FALSE. ) > 0 ) THEN
214               CALL iom_get( numror, jpdom_autoglo, 'frq_m'  , frq_m  )
215            ELSE
216               frq_m(:,:) = 1._wp   ! default definition
217            ENDIF
218            !
219            IF( zf_sbc /= REAL( nn_fsbc, wp ) ) THEN      ! nn_fsbc has changed between 2 runs
220               IF(lwp) WRITE(numout,*) '~~~~~~~   restart with a change in the frequency of mean ',   &
221                  &                    'from ', zf_sbc, ' to ', nn_fsbc 
222               zcoef = REAL( nn_fsbc - 1, wp ) / zf_sbc 
223               ssu_m(:,:) = zcoef * ssu_m(:,:) 
224               ssv_m(:,:) = zcoef * ssv_m(:,:)
225               sst_m(:,:) = zcoef * sst_m(:,:)
226               sss_m(:,:) = zcoef * sss_m(:,:)
227               ssh_m(:,:) = zcoef * ssh_m(:,:)
228               IF( lk_vvl )   e3t_m(:,:) = zcoef * e3t_m(:,:)
229               frq_m(:,:) = zcoef * frq_m(:,:)
230            ELSE
231               IF(lwp) WRITE(numout,*) '~~~~~~~   mean fields read in the ocean restart file'
232            ENDIF
233         ENDIF
234      ENDIF
235      !
236      IF( .NOT. l_ssm_mean ) THEN   ! default initialisation. needed by lim_istate
237         !
238         IF(lwp) WRITE(numout,*) '          default initialisation of ss?_m arrays'
239         ssu_m(:,:) = ub(:,:,1)
240         ssv_m(:,:) = vb(:,:,1)
241         IF( ln_useCT )  THEN    ;   sst_m(:,:) = eos_pt_from_ct( tsn(:,:,1,jp_tem), tsn(:,:,1,jp_sal) )
242         ELSE                    ;   sst_m(:,:) = tsn(:,:,1,jp_tem)
243         ENDIF
244         sss_m(:,:) = tsn(:,:,1,jp_sal)
245         ssh_m(:,:) = sshn(:,:)
246         IF( lk_vvl )   e3t_m(:,:) = e3t_n(:,:,1)
247         frq_m(:,:) = 1._wp
248         !
249      ENDIF
250      !
251   END SUBROUTINE sbc_ssm_init
252
253   !!======================================================================
254END MODULE sbcssm
Note: See TracBrowser for help on using the repository browser.