New URL for NEMO forge!   http://forge.nemo-ocean.eu

Since March 2022 along with NEMO 4.2 release, the code development moved to a self-hosted GitLab.
This present forge is now archived and remained online for history.
sbcwave.F90 in branches/2015/dev_r5836_NOC3_vvl_by_default/NEMOGCM/NEMO/OPA_SRC/SBC – NEMO

source: branches/2015/dev_r5836_NOC3_vvl_by_default/NEMOGCM/NEMO/OPA_SRC/SBC/sbcwave.F90 @ 5845

Last change on this file since 5845 was 5845, checked in by gm, 8 years ago

#1613: vvl by default: suppression of domzgr_substitute.h90

  • Property svn:keywords set to Id
File size: 9.3 KB
Line 
1MODULE sbcwave
2   !!======================================================================
3   !!                       ***  MODULE  sbcwave  ***
4   !! Wave module
5   !!======================================================================
6   !! History :  3.3  !   2011-09  (Adani M)  Original code: Drag Coefficient
7   !!         :  3.4  !   2012-10  (Adani M)                 Stokes Drift
8   !!----------------------------------------------------------------------
9
10   !!----------------------------------------------------------------------
11   !!   sbc_wave      : read drag coefficient from wave model in netcdf files
12   !!----------------------------------------------------------------------
13   USE oce            !
14   USE sbc_oce        ! Surface boundary condition: ocean fields
15   USE bdy_oce        !
16   USE domvvl         !
17   !
18   USE iom            ! I/O manager library
19   USE in_out_manager ! I/O manager
20   USE lib_mpp        ! distribued memory computing library
21   USE fldread        ! read input fields
22   USE wrk_nemo       !
23
24   IMPLICIT NONE
25   PRIVATE
26
27   PUBLIC   sbc_wave    ! routine called in sbc_blk_core or sbc_blk_mfs
28   
29   INTEGER , PARAMETER ::   jpfld  = 3   ! maximum number of files to read for srokes drift
30   INTEGER , PARAMETER ::   jp_usd = 1   ! index of stokes drift  (i-component) (m/s)    at T-point
31   INTEGER , PARAMETER ::   jp_vsd = 2   ! index of stokes drift  (j-component) (m/s)    at T-point
32   INTEGER , PARAMETER ::   jp_wn  = 3   ! index of wave number                 (1/m)    at T-point
33
34   TYPE(FLD), ALLOCATABLE, DIMENSION(:)  :: sf_cd    ! structure of input fields (file informations, fields read) Drag Coefficient
35   TYPE(FLD), ALLOCATABLE, DIMENSION(:)  :: sf_sd    ! structure of input fields (file informations, fields read) Stokes Drift
36
37   REAL(wp), PUBLIC, ALLOCATABLE, DIMENSION (:,:)   :: cdn_wave 
38   REAL(wp), PUBLIC, ALLOCATABLE, DIMENSION (:,:,:) :: usd3d, vsd3d, wsd3d 
39   REAL(wp),         ALLOCATABLE, DIMENSION (:,:)   :: usd2d, vsd2d, uwavenum, vwavenum 
40
41   !! * Substitutions
42#  include "vectopt_loop_substitute.h90"
43   !!----------------------------------------------------------------------
44   !! NEMO/OPA 3.7 , NEMO Consortium (2014)
45   !! $Id$
46   !! Software governed by the CeCILL licence     (NEMOGCM/NEMO_CeCILL.txt)
47   !!----------------------------------------------------------------------
48CONTAINS
49
50   SUBROUTINE sbc_wave( kt )
51      !!---------------------------------------------------------------------
52      !!                     ***  ROUTINE sbc_apr  ***
53      !!
54      !! ** Purpose :   read drag coefficient from wave model  in netcdf files.
55      !!
56      !! ** Method  : - Read namelist namsbc_wave
57      !!              - Read Cd_n10 fields in netcdf files
58      !!              - Read stokes drift 2d in netcdf files
59      !!              - Read wave number      in netcdf files
60      !!              - Compute 3d stokes drift using monochromatic
61      !! ** action  :   
62      !!---------------------------------------------------------------------
63      INTEGER, INTENT( in  ) ::   kt       ! ocean time step
64      !
65      INTEGER                ::   ierror   ! return error code
66      INTEGER                ::   ifpr, jj,ji,jk 
67      INTEGER                ::   ios     ! Local integer output status for namelist read
68      TYPE(FLD_N), DIMENSION(jpfld) ::   slf_i     ! array of namelist informations on the fields to read
69      CHARACTER(len=100)     ::  cn_dir                          ! Root directory for location of drag coefficient files
70      TYPE(FLD_N)            ::  sn_cdg, sn_usd, sn_vsd, sn_wn   ! informations about the fields to be read
71      REAL(wp), DIMENSION(:,:,:), POINTER ::   zusd_t, zvsd_t, ze3hdiv   ! 3D workspace
72      !!
73      NAMELIST/namsbc_wave/  sn_cdg, cn_dir, sn_usd, sn_vsd, sn_wn
74      !!---------------------------------------------------------------------
75      !
76      !                                         ! -------------------- !
77      IF( kt == nit000 ) THEN                   ! First call kt=nit000 !
78         !                                      ! -------------------- !
79         REWIND( numnam_ref )              ! Namelist namsbc_wave in reference namelist : File for drag coeff. from wave model
80         READ  ( numnam_ref, namsbc_wave, IOSTAT = ios, ERR = 901)
81901      IF( ios /= 0 ) CALL ctl_nam ( ios , 'namsbc_wave in reference namelist', lwp )
82
83         REWIND( numnam_cfg )              ! Namelist namsbc_wave in configuration namelist : File for drag coeff. from wave model
84         READ  ( numnam_cfg, namsbc_wave, IOSTAT = ios, ERR = 902 )
85902      IF( ios /= 0 ) CALL ctl_nam ( ios , 'namsbc_wave in configuration namelist', lwp )
86         IF(lwm) WRITE ( numond, namsbc_wave )
87         !
88         IF ( ln_cdgw ) THEN
89            ALLOCATE( sf_cd(1), STAT=ierror )           !* allocate and fill sf_wave with sn_cdg
90            IF( ierror > 0 )   CALL ctl_stop( 'STOP', 'sbc_wave: unable to allocate sf_wave structure' )
91            !
92                                   ALLOCATE( sf_cd(1)%fnow(jpi,jpj,1)   )
93            IF( sn_cdg%ln_tint )   ALLOCATE( sf_cd(1)%fdta(jpi,jpj,1,2) )
94            CALL fld_fill( sf_cd, (/ sn_cdg /), cn_dir, 'sbc_wave', 'Wave module ', 'namsbc_wave' )
95            ALLOCATE( cdn_wave(jpi,jpj) )
96            cdn_wave(:,:) = 0.0
97         ENDIF
98         IF ( ln_sdw ) THEN
99            slf_i(jp_usd) = sn_usd ; slf_i(jp_vsd) = sn_vsd; slf_i(jp_wn) = sn_wn
100            ALLOCATE( sf_sd(3), STAT=ierror )           !* allocate and fill sf_wave with sn_cdg
101            IF( ierror > 0 )   CALL ctl_stop( 'STOP', 'sbc_wave: unable to allocate sf_wave structure' )
102            !
103            DO ifpr= 1, jpfld
104               ALLOCATE( sf_sd(ifpr)%fnow(jpi,jpj,1) )
105               IF( slf_i(ifpr)%ln_tint )   ALLOCATE( sf_sd(ifpr)%fdta(jpi,jpj,1,2) )
106            END DO
107            CALL fld_fill( sf_sd, slf_i, cn_dir, 'sbc_wave', 'Wave module ', 'namsbc_wave' )
108            ALLOCATE( usd2d(jpi,jpj) , vsd2d(jpi,jpj) , uwavenum(jpi,jpj) , vwavenum(jpi,jpj) )
109            ALLOCATE( usd3d(jpi,jpj,jpk),vsd3d(jpi,jpj,jpk),wsd3d(jpi,jpj,jpk) )
110            usd3d(:,:,:) = 0._wp   ;   usd2d(:,:) = 0._wp   ;    uwavenum(:,:) = 0._wp
111            vsd3d(:,:,:) = 0._wp   ;   vsd2d(:,:) = 0._wp   ;    vwavenum(:,:) = 0._wp
112            wsd3d(:,:,:) = 0._wp
113         ENDIF
114      ENDIF
115      !
116      IF ( ln_cdgw ) THEN              !==  Neutral drag coefficient  ==!
117         CALL fld_read( kt, nn_fsbc, sf_cd )      ! read from external forcing
118         cdn_wave(:,:) = sf_cd(1)%fnow(:,:,1)
119      ENDIF
120      !
121      IF ( ln_sdw )  THEN              !==  Computation of the 3d Stokes Drift  ==!
122         !
123         CALL fld_read( kt, nn_fsbc, sf_sd )    !* read drag coefficient from external forcing
124         !
125         !
126         CALL wrk_alloc( jpi,jpj,jpk,   zusd_t, zvsd_t, ze3hdiv )
127         !                                      !* distribute it on the vertical
128         DO jk = 1, jpkm1
129            zusd_t(:,:,jk) = sf_sd(jp_usd)%fnow(:,:,1) * EXP( -2._wp * sf_sd(jp_wn)%fnow(:,:,1) * gdept_n(:,:,jk) )
130            zvsd_t(:,:,jk) = sf_sd(jp_vsd)%fnow(:,:,1) * EXP( -2._wp * sf_sd(jp_wn)%fnow(:,:,1) * gdept_n(:,:,jk) )
131         END DO
132         !                                      !* interpolate the stokes drift from t-point to u- and v-points
133         DO jk = 1, jpkm1
134            DO jj = 1, jpjm1
135               DO ji = 1, jpim1
136                   usd3d(ji,jj,jk) = 0.5_wp * ( zusd_t(ji  ,jj,jk) + zusd_t(ji+1,jj,jk) ) * umask(ji,jj,jk)
137                   vsd3d(ji,jj,jk) = 0.5_wp * ( zvsd_t(ji  ,jj,jk) + zvsd_t(ji,jj+1,jk) ) * vmask(ji,jj,jk)
138               END DO
139            END DO
140         END DO
141         CALL lbc_lnk( usd3d(:,:,:), 'U', -1. )
142         CALL lbc_lnk( vsd3d(:,:,:), 'V', -1. )
143         !
144         DO jk = 1, jpkm1                       !* e3t * Horizontal divergence  ==!
145            DO jj = 2, jpjm1
146               DO ji = fs_2, fs_jpim1   ! vector opt.
147                  ze3hdiv(ji,jj,jk) = (  e2u(ji  ,jj) * e3u_n(ji  ,jj,jk) * usd3d(ji  ,jj,jk)     &
148                     &                 - e2u(ji-1,jj) * e3u_n(ji-1,jj,jk) * usd3d(ji-1,jj,jk)     &
149                     &                 + e1v(ji,jj  ) * e3v_n(ji,jj  ,jk) * vsd3d(ji,jj  ,jk)     &
150                     &                 - e1v(ji,jj-1) * e3v_n(ji,jj-1,jk) * vsd3d(ji,jj-1,jk)   ) * r1_e1e2t(ji,jj)
151               END DO 
152            END DO 
153            IF( .NOT. AGRIF_Root() ) THEN
154               IF( nbondi ==  1 .OR. nbondi == 2 )   ze3hdiv(nlci-1,   :  ,jk) = 0._wp      ! east
155               IF( nbondi == -1 .OR. nbondi == 2 )   ze3hdiv(  2   ,   :  ,jk) = 0._wp      ! west
156               IF( nbondj ==  1 .OR. nbondj == 2 )   ze3hdiv(  :   ,nlcj-1,jk) = 0._wp      ! north
157               IF( nbondj == -1 .OR. nbondj == 2 )   ze3hdiv(  :   ,  2   ,jk) = 0._wp      ! south
158            ENDIF
159         END DO
160         CALL lbc_lnk( ze3hdiv, 'T', 1. ) 
161         !
162         DO jk = jpkm1, 1, -1                   !* integrate from the bottom the e3t * hor. divergence
163            wsd3d(:,:,jk) = wsd3d(:,:,jk+1) - ze3hdiv(:,:,jk)
164         END DO
165#if defined key_bdy
166         IF( lk_bdy ) THEN
167            DO jk = 1, jpkm1
168               wsd3d(:,:,jk) = wsd3d(:,:,jk) * bdytmask(:,:)
169            END DO
170         ENDIF
171#endif
172         CALL wrk_dealloc( jpi,jpj,jpk,   zusd_t, zvsd_t, ze3hdiv )
173         !
174      ENDIF
175      !
176   END SUBROUTINE sbc_wave
177     
178   !!======================================================================
179END MODULE sbcwave
Note: See TracBrowser for help on using the repository browser.