New URL for NEMO forge!   http://forge.nemo-ocean.eu

Since March 2022 along with NEMO 4.2 release, the code development moved to a self-hosted GitLab.
This present forge is now archived and remained online for history.
traadv_fct.F90 in branches/2015/dev_r5836_NOC3_vvl_by_default/NEMOGCM/NEMO/OPA_SRC/TRA – NEMO

source: branches/2015/dev_r5836_NOC3_vvl_by_default/NEMOGCM/NEMO/OPA_SRC/TRA/traadv_fct.F90 @ 5883

Last change on this file since 5883 was 5883, checked in by gm, 8 years ago

#1613: vvl by default: TRA/TRC remove optimization associated with linear free surface

  • Property svn:keywords set to Id
File size: 40.4 KB
Line 
1MODULE traadv_fct
2   !!==============================================================================
3   !!                       ***  MODULE  traadv_fct  ***
4   !! Ocean  tracers:  horizontal & vertical advective trend (2nd/4th order Flux Corrected Transport method)
5   !!==============================================================================
6   !! History :  3.7  !  2015-09  (L. Debreu, G. Madec)  original code (inspired from traadv_tvd.F90)
7   !!----------------------------------------------------------------------
8
9   !!----------------------------------------------------------------------
10   !!  tra_adv_fct    : update the tracer trend with a 3D advective trends using a 2nd or 4th order FCT scheme
11   !!  tra_adv_fct_zts: update the tracer trend with a 3D advective trends using a 2nd order FCT scheme
12   !!                   with sub-time-stepping in the vertical direction
13   !!  nonosc         : compute monotonic tracer fluxes by a non-oscillatory algorithm
14   !!  interp_4th_cpt : 4th order compact scheme for the vertical component of the advection
15   !!----------------------------------------------------------------------
16   USE oce            ! ocean dynamics and active tracers
17   USE dom_oce        ! ocean space and time domain
18   USE trc_oce        ! share passive tracers/Ocean variables
19   USE trd_oce        ! trends: ocean variables
20   USE trdtra         ! tracers trends
21   USE dynspg_oce     ! choice/control of key cpp for surface pressure gradient
22   USE diaptr         ! poleward transport diagnostics
23   !
24   USE in_out_manager ! I/O manager
25   USE lib_mpp        ! MPP library
26   USE lbclnk         ! ocean lateral boundary condition (or mpp link)
27   USE lib_fortran    ! Fortran utilities (allows no signed zero when 'key_nosignedzero' defined) 
28   USE wrk_nemo       ! Memory Allocation
29   USE timing         ! Timing
30
31   IMPLICIT NONE
32   PRIVATE
33
34   PUBLIC   tra_adv_fct        ! routine called by traadv.F90
35   PUBLIC   tra_adv_fct_zts    ! routine called by traadv.F90
36   PUBLIC   interp_4th_cpt     ! routine called by traadv_cen.F90
37
38   LOGICAL  ::   l_trd   ! flag to compute trends
39   REAL(wp) ::   r1_6 = 1._wp / 6._wp   ! =1/6
40
41   !! * Substitutions
42#  include "vectopt_loop_substitute.h90"
43   !!----------------------------------------------------------------------
44   !! NEMO/OPA 3.7 , NEMO Consortium (2014)
45   !! $Id$
46   !! Software governed by the CeCILL licence     (NEMOGCM/NEMO_CeCILL.txt)
47   !!----------------------------------------------------------------------
48CONTAINS
49
50   SUBROUTINE tra_adv_fct( kt, kit000, cdtype, p2dt, pun, pvn, pwn,       &
51      &                                              ptb, ptn, pta, kjpt, kn_fct_h, kn_fct_v )
52      !!----------------------------------------------------------------------
53      !!                  ***  ROUTINE tra_adv_fct  ***
54      !!
55      !! **  Purpose :   Compute the now trend due to total advection of tracers
56      !!               and add it to the general trend of tracer equations
57      !!
58      !! **  Method  : - 2nd or 4th FCT scheme on the horizontal direction
59      !!               (choice through the value of kn_fct)
60      !!               - on the vertical the 4th order is a compact scheme
61      !!               - corrected flux (monotonic correction)
62      !!
63      !! ** Action : - update pta  with the now advective tracer trends
64      !!             - send trends to trdtra module for further diagnostcs (l_trdtra=T)
65      !!             - htr_adv, str_adv : poleward advective heat and salt transport (ln_diaptr=T)
66      !!----------------------------------------------------------------------
67      INTEGER                              , INTENT(in   ) ::   kt              ! ocean time-step index
68      INTEGER                              , INTENT(in   ) ::   kit000          ! first time step index
69      CHARACTER(len=3)                     , INTENT(in   ) ::   cdtype          ! =TRA or TRC (tracer indicator)
70      INTEGER                              , INTENT(in   ) ::   kjpt            ! number of tracers
71      INTEGER                              , INTENT(in   ) ::   kn_fct_h        ! order of the FCT scheme (=2 or 4)
72      INTEGER                              , INTENT(in   ) ::   kn_fct_v        ! order of the FCT scheme (=2 or 4)
73      REAL(wp), DIMENSION(        jpk     ), INTENT(in   ) ::   p2dt            ! vertical profile of tracer time-step
74      REAL(wp), DIMENSION(jpi,jpj,jpk     ), INTENT(in   ) ::   pun, pvn, pwn   ! 3 ocean velocity components
75      REAL(wp), DIMENSION(jpi,jpj,jpk,kjpt), INTENT(in   ) ::   ptb, ptn        ! before and now tracer fields
76      REAL(wp), DIMENSION(jpi,jpj,jpk,kjpt), INTENT(inout) ::   pta             ! tracer trend
77      !
78      INTEGER  ::   ji, jj, jk, jn                           ! dummy loop indices 
79      REAL(wp) ::   z2dtt, ztra                              ! local scalar
80      REAL(wp) ::   zfp_ui, zfp_vj, zfp_wk, zC2t_u, zC4t_u   !   -      -
81      REAL(wp) ::   zfm_ui, zfm_vj, zfm_wk, zC2t_v, zC4t_v   !   -      -
82      REAL(wp), POINTER, DIMENSION(:,:,:) ::   zwi, zwx, zwy, zwz, ztu, ztv, zltu, zltv, ztw
83      REAL(wp), POINTER, DIMENSION(:,:,:) ::   ztrdx, ztrdy, ztrdz
84      !!----------------------------------------------------------------------
85      !
86      IF( nn_timing == 1 )  CALL timing_start('tra_adv_fct')
87      !
88      CALL wrk_alloc( jpi,jpj,jpk,   zwi, zwx, zwy, zwz, ztu, ztv, zltu, zltv, ztw )
89      !
90      IF( kt == kit000 )  THEN
91         IF(lwp) WRITE(numout,*)
92         IF(lwp) WRITE(numout,*) 'tra_adv_fct : FCT advection scheme on ', cdtype
93         IF(lwp) WRITE(numout,*) '~~~~~~~~~~~'
94      ENDIF
95      !
96      l_trd = .FALSE.
97      IF( ( cdtype == 'TRA' .AND. l_trdtra ) .OR. ( cdtype == 'TRC' .AND. l_trdtrc ) )   l_trd = .TRUE.
98      !
99      IF( l_trd )  THEN
100         CALL wrk_alloc( jpi, jpj, jpk, ztrdx, ztrdy, ztrdz )
101         ztrdx(:,:,:) = 0._wp   ;    ztrdy(:,:,:) = 0._wp   ;   ztrdz(:,:,:) = 0._wp
102      ENDIF
103      !
104      !                          ! surface & bottom value : flux set to zero one for all
105      zwz(:,:, 1 ) = 0._wp           
106      zwx(:,:,jpk) = 0._wp   ;   zwy(:,:,jpk) = 0._wp    ;    zwz(:,:,jpk) = 0._wp
107      !
108      zwi(:,:,:) = 0._wp       
109      !
110      DO jn = 1, kjpt            !==  loop over the tracers  ==!
111         !
112         !        !==  upstream advection with initial mass fluxes & intermediate update  ==!
113         !                    !* upstream tracer flux in the i and j direction
114         DO jk = 1, jpkm1
115            DO jj = 1, jpjm1
116               DO ji = 1, fs_jpim1   ! vector opt.
117                  ! upstream scheme
118                  zfp_ui = pun(ji,jj,jk) + ABS( pun(ji,jj,jk) )
119                  zfm_ui = pun(ji,jj,jk) - ABS( pun(ji,jj,jk) )
120                  zfp_vj = pvn(ji,jj,jk) + ABS( pvn(ji,jj,jk) )
121                  zfm_vj = pvn(ji,jj,jk) - ABS( pvn(ji,jj,jk) )
122                  zwx(ji,jj,jk) = 0.5 * ( zfp_ui * ptb(ji,jj,jk,jn) + zfm_ui * ptb(ji+1,jj  ,jk,jn) )
123                  zwy(ji,jj,jk) = 0.5 * ( zfp_vj * ptb(ji,jj,jk,jn) + zfm_vj * ptb(ji  ,jj+1,jk,jn) )
124               END DO
125            END DO
126         END DO
127         !                    !* upstream tracer flux in the k direction *!
128         DO jk = 2, jpkm1        ! Interior value ( multiplied by wmask)
129            DO jj = 1, jpj
130               DO ji = 1, jpi
131                  zfp_wk = pwn(ji,jj,jk) + ABS( pwn(ji,jj,jk) )
132                  zfm_wk = pwn(ji,jj,jk) - ABS( pwn(ji,jj,jk) )
133                  zwz(ji,jj,jk) = 0.5 * ( zfp_wk * ptb(ji,jj,jk,jn) + zfm_wk * ptb(ji,jj,jk-1,jn) ) * wmask(ji,jj,jk)
134               END DO
135            END DO
136         END DO
137         IF( ln_linssh ) THEN    ! top ocean value (only in linear free surface as zwz has been w-masked)
138            IF( ln_isfcav ) THEN             ! top of the ice-shelf cavities and at the ocean surface
139               DO jj = 1, jpj
140                  DO ji = 1, jpi
141                     zwz(ji,jj, mikt(ji,jj) ) = pwn(ji,jj,mikt(ji,jj)) * ptb(ji,jj,mikt(ji,jj),jn)   ! linear free surface
142                  END DO
143               END DO   
144            ELSE                             ! no cavities: only at the ocean surface
145               zwz(:,:,1) = pwn(:,:,1) * ptb(:,:,1,jn)
146            ENDIF
147         ENDIF
148         !               
149         DO jk = 1, jpkm1     !* trend and after field with monotonic scheme
150            z2dtt = p2dt(jk)
151            DO jj = 2, jpjm1
152               DO ji = fs_2, fs_jpim1   ! vector opt.
153                  ! total intermediate advective trends
154                  ztra = - (  zwx(ji,jj,jk) - zwx(ji-1,jj  ,jk  )   &
155                     &      + zwy(ji,jj,jk) - zwy(ji  ,jj-1,jk  )   &
156                     &      + zwz(ji,jj,jk) - zwz(ji  ,jj  ,jk+1) ) * r1_e1e2t(ji,jj) / e3t_n(ji,jj,jk)
157                  ! update and guess with monotonic sheme
158!!gm why tmask added in the two following lines ???    the mask is done in tranxt !
159                  pta(ji,jj,jk,jn) =   pta(ji,jj,jk,jn)         + ztra   * tmask(ji,jj,jk)
160                  zwi(ji,jj,jk)    = ( ptb(ji,jj,jk,jn) + z2dtt * ztra ) * tmask(ji,jj,jk)
161               END DO
162            END DO
163         END DO
164         CALL lbc_lnk( zwi, 'T', 1. )  ! Lateral boundary conditions on zwi  (unchanged sign)
165         !               
166         IF( l_trd )  THEN             ! trend diagnostics (contribution of upstream fluxes)
167            ztrdx(:,:,:) = zwx(:,:,:)   ;    ztrdy(:,:,:) = zwy(:,:,:)  ;   ztrdz(:,:,:) = zwz(:,:,:)
168         END IF
169         !                             ! "Poleward" heat and salt transports (contribution of upstream fluxes)
170         IF( cdtype == 'TRA' .AND. ln_diaptr ) THEN 
171           IF( jn == jp_tem )  htr_adv(:) = ptr_sj( zwy(:,:,:) )
172           IF( jn == jp_sal )  str_adv(:) = ptr_sj( zwy(:,:,:) )
173         ENDIF
174         !
175         !        !==  anti-diffusive flux : high order minus low order  ==!
176         !
177         SELECT CASE( kn_fct_h )    !* horizontal anti-diffusive fluxes
178         !
179         CASE(  2  )                   !- 2nd order centered
180            DO jk = 1, jpkm1
181               DO jj = 1, jpjm1
182                  DO ji = 1, fs_jpim1   ! vector opt.
183                     zwx(ji,jj,jk) = 0.5_wp * pun(ji,jj,jk) * ( ptn(ji,jj,jk,jn) + ptn(ji+1,jj,jk,jn) ) - zwx(ji,jj,jk)
184                     zwy(ji,jj,jk) = 0.5_wp * pvn(ji,jj,jk) * ( ptn(ji,jj,jk,jn) + ptn(ji,jj+1,jk,jn) ) - zwy(ji,jj,jk)
185                  END DO
186               END DO
187            END DO
188            !
189         CASE(  4  )                   !- 4th order centered
190            zltu(:,:,jpk) = 0._wp            ! Bottom value : flux set to zero
191            zltv(:,:,jpk) = 0._wp
192            DO jk = 1, jpkm1                 ! Laplacian
193               DO jj = 1, jpjm1                    ! 1st derivative (gradient)
194                  DO ji = 1, fs_jpim1   ! vector opt.
195                     ztu(ji,jj,jk) = ( ptn(ji+1,jj  ,jk,jn) - ptn(ji,jj,jk,jn) ) * umask(ji,jj,jk)
196                     ztv(ji,jj,jk) = ( ptn(ji  ,jj+1,jk,jn) - ptn(ji,jj,jk,jn) ) * vmask(ji,jj,jk)
197                  END DO
198               END DO
199               DO jj = 2, jpjm1                    ! 2nd derivative * 1/ 6
200                  DO ji = fs_2, fs_jpim1   ! vector opt.
201                     zltu(ji,jj,jk) = (  ztu(ji,jj,jk) + ztu(ji-1,jj,jk)  ) * r1_6
202                     zltv(ji,jj,jk) = (  ztv(ji,jj,jk) + ztv(ji,jj-1,jk)  ) * r1_6
203                  END DO
204               END DO
205            END DO
206            CALL lbc_lnk( zltu, 'T', 1. )   ;    CALL lbc_lnk( zltv, 'T', 1. )   ! Lateral boundary cond. (unchanged sgn)
207            !
208            DO jk = 1, jpkm1                 ! Horizontal advective fluxes
209               DO jj = 1, jpjm1
210                  DO ji = 1, fs_jpim1   ! vector opt.
211                     zC2t_u = ptn(ji,jj,jk,jn) + ptn(ji+1,jj  ,jk,jn)   ! 2 x C2 interpolation of T at u- & v-points
212                     zC2t_v = ptn(ji,jj,jk,jn) + ptn(ji  ,jj+1,jk,jn)
213                     !                                                  ! C4 minus upstream advective fluxes
214                     zwx(ji,jj,jk) =  0.5_wp * pun(ji,jj,jk) * ( zC2t_u + zltu(ji,jj,jk) - zltu(ji+1,jj,jk) ) - zwx(ji,jj,jk)
215                     zwy(ji,jj,jk) =  0.5_wp * pvn(ji,jj,jk) * ( zC2t_v + zltv(ji,jj,jk) - zltv(ji,jj+1,jk) ) - zwy(ji,jj,jk)
216                  END DO
217               END DO
218            END DO         
219            !
220         CASE(  41 )                   !- 4th order centered       ==>>   !!gm coding attempt   need to be tested
221            ztu(:,:,jpk) = 0._wp             ! Bottom value : flux set to zero
222            ztv(:,:,jpk) = 0._wp
223            DO jk = 1, jpkm1                 ! 1st derivative (gradient)
224               DO jj = 1, jpjm1
225                  DO ji = 1, fs_jpim1   ! vector opt.
226                     ztu(ji,jj,jk) = ( ptn(ji+1,jj  ,jk,jn) - ptn(ji,jj,jk,jn) ) * umask(ji,jj,jk)
227                     ztv(ji,jj,jk) = ( ptn(ji  ,jj+1,jk,jn) - ptn(ji,jj,jk,jn) ) * vmask(ji,jj,jk)
228                  END DO
229               END DO
230            END DO
231            CALL lbc_lnk( ztu, 'U', -1. )   ;    CALL lbc_lnk( ztv, 'V', -1. )   ! Lateral boundary cond. (unchanged sgn)
232            !
233            DO jk = 1, jpkm1                 ! Horizontal advective fluxes
234               DO jj = 2, jpjm1
235                  DO ji = 2, fs_jpim1   ! vector opt.
236                     zC2t_u = ptn(ji,jj,jk,jn) + ptn(ji+1,jj  ,jk,jn)   ! 2 x C2 interpolation of T at u- & v-points (x2)
237                     zC2t_v = ptn(ji,jj,jk,jn) + ptn(ji  ,jj+1,jk,jn)
238                     !                                                  ! C4 interpolation of T at u- & v-points (x2)
239                     zC4t_u =  zC2t_u + r1_6 * ( ztu(ji-1,jj  ,jk) - ztu(ji+1,jj  ,jk) )
240                     zC4t_v =  zC2t_v + r1_6 * ( ztv(ji  ,jj-1,jk) - ztv(ji  ,jj+1,jk) )
241                     !                                                  ! C4 minus upstream advective fluxes
242                     zwx(ji,jj,jk) =  0.5_wp * pun(ji,jj,jk) * zC4t_u - zwx(ji,jj,jk)
243                     zwy(ji,jj,jk) =  0.5_wp * pvn(ji,jj,jk) * zC4t_v - zwy(ji,jj,jk)
244                  END DO
245               END DO
246            END DO
247            !
248         END SELECT
249         !                     
250         SELECT CASE( kn_fct_v )    !* vertical anti-diffusive fluxes (w-masked interior values)
251         !
252         CASE(  2  )                   !- 2nd order centered
253            DO jk = 2, jpkm1   
254               DO jj = 2, jpjm1
255                  DO ji = fs_2, fs_jpim1
256                     zwz(ji,jj,jk) =  (  pwn(ji,jj,jk) * 0.5_wp * ( ptn(ji,jj,jk,jn) + ptn(ji,jj,jk-1,jn) )   &
257                        &              - zwz(ji,jj,jk)  ) * wmask(ji,jj,jk)
258                  END DO
259               END DO
260            END DO
261            !
262         CASE(  4  )                   !- 4th order COMPACT
263            CALL interp_4th_cpt( ptn(:,:,:,jn) , ztw )   ! zwt = COMPACT interpolation of T at w-point
264            DO jk = 2, jpkm1
265               DO jj = 2, jpjm1
266                  DO ji = fs_2, fs_jpim1
267                     zwz(ji,jj,jk) = ( pwn(ji,jj,jk) * ztw(ji,jj,jk) - zwz(ji,jj,jk) ) * wmask(ji,jj,jk)
268                  END DO
269               END DO
270            END DO
271            !
272         END SELECT
273         IF( ln_linssh ) THEN    ! top ocean value: high order = upstream  ==>>  zwz=0
274            zwz(:,:,1) = 0._wp   ! only ocean surface as interior zwz values have been w-masked
275         ENDIF
276         !
277         CALL lbc_lnk( zwx, 'U', -1. )   ;   CALL lbc_lnk( zwy, 'V', -1. )         ! Lateral bondary conditions
278         CALL lbc_lnk( zwz, 'W',  1. )
279         !
280         !        !==  monotonicity algorithm  ==!
281         !
282         CALL nonosc( ptb(:,:,:,jn), zwx, zwy, zwz, zwi, p2dt )
283         !
284         !        !==  final trend with corrected fluxes  ==!
285         !
286         DO jk = 1, jpkm1
287            DO jj = 2, jpjm1
288               DO ji = fs_2, fs_jpim1   ! vector opt. 
289                  pta(ji,jj,jk,jn) = pta(ji,jj,jk,jn) - (  zwx(ji,jj,jk) - zwx(ji-1,jj  ,jk  )   &
290                     &                                   + zwy(ji,jj,jk) - zwy(ji  ,jj-1,jk  )   &
291                     &                                   + zwz(ji,jj,jk) - zwz(ji  ,jj  ,jk+1) ) &
292                     &                                / ( e1e2t(ji,jj) * e3t_n(ji,jj,jk) )
293               END DO
294            END DO
295         END DO
296         !
297         IF( l_trd ) THEN     ! trend diagnostics (contribution of upstream fluxes)
298            ztrdx(:,:,:) = ztrdx(:,:,:) + zwx(:,:,:)  ! <<< Add to previously computed
299            ztrdy(:,:,:) = ztrdy(:,:,:) + zwy(:,:,:)  ! <<< Add to previously computed
300            ztrdz(:,:,:) = ztrdz(:,:,:) + zwz(:,:,:)  ! <<< Add to previously computed
301            !
302            CALL trd_tra( kt, cdtype, jn, jptra_xad, ztrdx, pun, ptn(:,:,:,jn) )
303            CALL trd_tra( kt, cdtype, jn, jptra_yad, ztrdy, pvn, ptn(:,:,:,jn) )
304            CALL trd_tra( kt, cdtype, jn, jptra_zad, ztrdz, pwn, ptn(:,:,:,jn) )
305            !
306            CALL wrk_dealloc( jpi,jpj,jpk,   ztrdx, ztrdy, ztrdz )
307         END IF
308         !                    ! "Poleward" heat and salt transports (contribution of upstream fluxes)
309         IF( cdtype == 'TRA' .AND. ln_diaptr ) THEN 
310           IF( jn == jp_tem )  htr_adv(:) = htr_adv(:) + ptr_sj( zwy(:,:,:) )
311           IF( jn == jp_sal )  str_adv(:) = str_adv(:) + ptr_sj( zwy(:,:,:) )
312         ENDIF
313         !
314      END DO                     ! end of tracer loop
315      !
316      CALL wrk_dealloc( jpi,jpj,jpk,    zwi, zwx, zwy, zwz, ztu, ztv, zltu, zltv, ztw )
317      !
318      IF( nn_timing == 1 )  CALL timing_stop('tra_adv_fct')
319      !
320   END SUBROUTINE tra_adv_fct
321
322
323   SUBROUTINE tra_adv_fct_zts( kt, kit000, cdtype, p2dt, pun, pvn, pwn,      &
324      &                                                  ptb, ptn, pta, kjpt, kn_fct_zts )
325      !!----------------------------------------------------------------------
326      !!                  ***  ROUTINE tra_adv_fct_zts  ***
327      !!
328      !! **  Purpose :   Compute the now trend due to total advection of
329      !!       tracers and add it to the general trend of tracer equations
330      !!
331      !! **  Method  :   TVD ZTS scheme, i.e. 2nd order centered scheme with
332      !!       corrected flux (monotonic correction). This version use sub-
333      !!       timestepping for the vertical advection which increases stability
334      !!       when vertical metrics are small.
335      !!       note: - this advection scheme needs a leap-frog time scheme
336      !!
337      !! ** Action : - update (pta) with the now advective tracer trends
338      !!             - save the trends
339      !!----------------------------------------------------------------------
340      INTEGER                              , INTENT(in   ) ::   kt              ! ocean time-step index
341      INTEGER                              , INTENT(in   ) ::   kit000          ! first time step index
342      CHARACTER(len=3)                     , INTENT(in   ) ::   cdtype          ! =TRA or TRC (tracer indicator)
343      INTEGER                              , INTENT(in   ) ::   kjpt            ! number of tracers
344      INTEGER                              , INTENT(in   ) ::   kn_fct_zts      ! number of number of vertical sub-timesteps
345      REAL(wp), DIMENSION(        jpk     ), INTENT(in   ) ::   p2dt            ! vertical profile of tracer time-step
346      REAL(wp), DIMENSION(jpi,jpj,jpk     ), INTENT(in   ) ::   pun, pvn, pwn   ! 3 ocean velocity components
347      REAL(wp), DIMENSION(jpi,jpj,jpk,kjpt), INTENT(in   ) ::   ptb, ptn        ! before and now tracer fields
348      REAL(wp), DIMENSION(jpi,jpj,jpk,kjpt), INTENT(inout) ::   pta             ! tracer trend
349      !
350      REAL(wp), DIMENSION( jpk )                           ::   zts             ! length of sub-timestep for vertical advection
351      REAL(wp), DIMENSION( jpk )                           ::   zr_p2dt         ! reciprocal of tracer timestep
352      INTEGER  ::   ji, jj, jk, jl, jn       ! dummy loop indices 
353      INTEGER  ::   jtb, jtn, jta   ! sub timestep pointers for leap-frog/euler forward steps
354      INTEGER  ::   jtaken          ! toggle for collecting appropriate fluxes from sub timesteps
355      REAL(wp) ::   z_rzts          ! Fractional length of Euler forward sub-timestep for vertical advection
356      REAL(wp) ::   z2dtt, ztra              ! local scalar
357      REAL(wp) ::   zfp_ui, zfp_vj, zfp_wk   !   -      -
358      REAL(wp) ::   zfm_ui, zfm_vj, zfm_wk   !   -      -
359      REAL(wp), POINTER, DIMENSION(:,:  )   ::   zwx_sav , zwy_sav
360      REAL(wp), POINTER, DIMENSION(:,:,:)   ::   zwi, zwx, zwy, zwz, zhdiv, zwzts, zwz_sav
361      REAL(wp), POINTER, DIMENSION(:,:,:)   ::   ztrdx, ztrdy, ztrdz
362      REAL(wp), POINTER, DIMENSION(:,:,:,:) ::   ztrs
363      !!----------------------------------------------------------------------
364      !
365      IF( nn_timing == 1 )  CALL timing_start('tra_adv_fct_zts')
366      !
367      CALL wrk_alloc( jpi,jpj,             zwx_sav, zwy_sav )
368      CALL wrk_alloc( jpi,jpj, jpk,        zwx, zwy, zwz, zwi, zhdiv, zwzts, zwz_sav )
369      CALL wrk_alloc( jpi,jpj,jpk,kjpt+1,  ztrs )
370      !
371      IF( kt == kit000 )  THEN
372         IF(lwp) WRITE(numout,*)
373         IF(lwp) WRITE(numout,*) 'tra_adv_fct_zts : 2nd order FCT scheme with ', kn_fct_zts, ' vertical sub-timestep on ', cdtype
374         IF(lwp) WRITE(numout,*) '~~~~~~~~~~~'
375      ENDIF
376      !
377      l_trd = .FALSE.
378      IF( ( cdtype == 'TRA' .AND. l_trdtra ) .OR. ( cdtype == 'TRC' .AND. l_trdtrc ) )   l_trd = .TRUE.
379      !
380      IF( l_trd )  THEN
381         CALL wrk_alloc( jpi,jpj,jpk,   ztrdx, ztrdy, ztrdz )
382         ztrdx(:,:,:) = 0._wp  ;    ztrdy(:,:,:) = 0._wp  ;   ztrdz(:,:,:) = 0._wp
383      ENDIF
384      !
385      zwi(:,:,:) = 0._wp
386      z_rzts = 1._wp / REAL( kn_fct_zts, wp )
387      zr_p2dt(:) = 1._wp / p2dt(:)
388      !
389      ! surface & Bottom value : flux set to zero for all tracers
390      zwz(:,:, 1 ) = 0._wp
391      zwx(:,:,jpk) = 0._wp   ;    zwz(:,:,jpk) = 0._wp
392      zwy(:,:,jpk) = 0._wp   ;    zwi(:,:,jpk) = 0._wp
393      !
394      !                                                          ! ===========
395      DO jn = 1, kjpt                                            ! tracer loop
396         !                                                       ! ===========
397         !
398         ! Upstream advection with initial mass fluxes & intermediate update
399         DO jk = 1, jpkm1        ! upstream tracer flux in the i and j direction
400            DO jj = 1, jpjm1
401               DO ji = 1, fs_jpim1   ! vector opt.
402                  ! upstream scheme
403                  zfp_ui = pun(ji,jj,jk) + ABS( pun(ji,jj,jk) )
404                  zfm_ui = pun(ji,jj,jk) - ABS( pun(ji,jj,jk) )
405                  zfp_vj = pvn(ji,jj,jk) + ABS( pvn(ji,jj,jk) )
406                  zfm_vj = pvn(ji,jj,jk) - ABS( pvn(ji,jj,jk) )
407                  zwx(ji,jj,jk) = 0.5_wp * ( zfp_ui * ptb(ji,jj,jk,jn) + zfm_ui * ptb(ji+1,jj  ,jk,jn) )
408                  zwy(ji,jj,jk) = 0.5_wp * ( zfp_vj * ptb(ji,jj,jk,jn) + zfm_vj * ptb(ji  ,jj+1,jk,jn) )
409               END DO
410            END DO
411         END DO
412         !                       ! upstream tracer flux in the k direction
413         DO jk = 2, jpkm1              ! Interior value
414            DO jj = 1, jpj
415               DO ji = 1, jpi
416                  zfp_wk = pwn(ji,jj,jk) + ABS( pwn(ji,jj,jk) )
417                  zfm_wk = pwn(ji,jj,jk) - ABS( pwn(ji,jj,jk) )
418                  zwz(ji,jj,jk) = 0.5_wp * ( zfp_wk * ptb(ji,jj,jk,jn) + zfm_wk * ptb(ji,jj,jk-1,jn) ) * wmask(ji,jj,jk)
419               END DO
420            END DO
421         END DO
422         IF( ln_linssh ) THEN          ! top value : linear free surface case only (as zwz is multiplied by wmask)
423            IF( ln_isfcav ) THEN             ! ice-shelf cavities: top value
424               DO jj = 1, jpj
425                  DO ji = 1, jpi
426                     zwz(ji,jj, mikt(ji,jj) ) = pwn(ji,jj,mikt(ji,jj)) * ptb(ji,jj,mikt(ji,jj),jn) 
427                  END DO
428               END DO   
429            ELSE                             ! no cavities, surface value
430               zwz(:,:,1) = pwn(:,:,1) * ptb(:,:,1,jn)
431            ENDIF
432         ENDIF
433         !
434         DO jk = 1, jpkm1         ! total advective trend
435            z2dtt = p2dt(jk)
436            DO jj = 2, jpjm1
437               DO ji = fs_2, fs_jpim1   ! vector opt.
438                  !                             ! total intermediate advective trends
439                  ztra = - (  zwx(ji,jj,jk) - zwx(ji-1,jj  ,jk  )   &
440                     &      + zwy(ji,jj,jk) - zwy(ji  ,jj-1,jk  )   &
441                     &      + zwz(ji,jj,jk) - zwz(ji  ,jj  ,jk+1)   ) * r1_e1e2t(ji,jj) / e3t_n(ji,jj,jk)
442                  !                             ! update and guess with monotonic sheme
443                  pta(ji,jj,jk,jn) =   pta(ji,jj,jk,jn)         + ztra
444                  zwi(ji,jj,jk)    = ( ptb(ji,jj,jk,jn) + z2dtt * ztra ) * tmask(ji,jj,jk)
445               END DO
446            END DO
447         END DO
448         !                           
449         CALL lbc_lnk( zwi, 'T', 1. )     ! Lateral boundary conditions on zwi  (unchanged sign)
450         !               
451         IF( l_trd )  THEN                ! trend diagnostics (contribution of upstream fluxes)
452            ztrdx(:,:,:) = zwx(:,:,:)   ;    ztrdy(:,:,:) = zwy(:,:,:)  ;   ztrdz(:,:,:) = zwz(:,:,:)
453         END IF
454         !                                ! "Poleward" heat and salt transports (contribution of upstream fluxes)
455         IF( cdtype == 'TRA' .AND. ln_diaptr ) THEN 
456           IF( jn == jp_tem )  htr_adv(:) = ptr_sj( zwy(:,:,:) )
457           IF( jn == jp_sal )  str_adv(:) = ptr_sj( zwy(:,:,:) )
458         ENDIF
459
460         ! 3. anti-diffusive flux : high order minus low order
461         ! ---------------------------------------------------
462
463         DO jk = 1, jpkm1                    !* horizontal anti-diffusive fluxes
464            !
465            DO jj = 1, jpjm1
466               DO ji = 1, fs_jpim1   ! vector opt.
467                  zwx_sav(ji,jj) = zwx(ji,jj,jk)
468                  zwy_sav(ji,jj) = zwy(ji,jj,jk)
469                  !
470                  zwx(ji,jj,jk) = 0.5_wp * pun(ji,jj,jk) * ( ptn(ji,jj,jk,jn) + ptn(ji+1,jj,jk,jn) )
471                  zwy(ji,jj,jk) = 0.5_wp * pvn(ji,jj,jk) * ( ptn(ji,jj,jk,jn) + ptn(ji,jj+1,jk,jn) )
472               END DO
473            END DO
474            !
475            DO jj = 2, jpjm1                    ! partial horizontal divergence
476               DO ji = fs_2, fs_jpim1
477                  zhdiv(ji,jj,jk) = (  zwx(ji,jj,jk) - zwx(ji-1,jj  ,jk)   &
478                     &               + zwy(ji,jj,jk) - zwy(ji  ,jj-1,jk)  )
479               END DO
480            END DO
481            !
482            DO jj = 1, jpjm1
483               DO ji = 1, fs_jpim1   ! vector opt.
484                  zwx(ji,jj,jk) = zwx(ji,jj,jk) - zwx_sav(ji,jj)
485                  zwy(ji,jj,jk) = zwy(ji,jj,jk) - zwy_sav(ji,jj)
486               END DO
487            END DO
488         END DO
489         !
490         !                                !* vertical anti-diffusive flux
491         zwz_sav(:,:,:)   = zwz(:,:,:)
492         ztrs   (:,:,:,1) = ptb(:,:,:,jn)
493         zwzts  (:,:,:)   = 0._wp
494         !
495         DO jl = 1, kn_fct_zts                  ! Start of sub timestepping loop
496            !
497            IF( jl == 1 ) THEN                        ! Euler forward to kick things off
498               jtb = 1   ;   jtn = 1   ;   jta = 2
499               zts(:) = p2dt(:) * z_rzts
500               jtaken = MOD( kn_fct_zts + 1 , 2)            ! Toggle to collect every second flux
501               !                                            ! starting at jl =1 if kn_fct_zts is odd;
502               !                                            ! starting at jl =2 otherwise
503            ELSEIF( jl == 2 ) THEN                    ! First leapfrog step
504               jtb = 1   ;   jtn = 2   ;   jta = 3
505               zts(:) = 2._wp * p2dt(:) * z_rzts
506            ELSE                                      ! Shuffle pointers for subsequent leapfrog steps
507               jtb = MOD(jtb,3) + 1
508               jtn = MOD(jtn,3) + 1
509               jta = MOD(jta,3) + 1
510            ENDIF
511            DO jk = 2, jpkm1                          ! interior value
512               DO jj = 2, jpjm1
513                  DO ji = fs_2, fs_jpim1
514                     zwz(ji,jj,jk) = 0.5_wp * pwn(ji,jj,jk) * ( ztrs(ji,jj,jk,jtn) + ztrs(ji,jj,jk-1,jtn) ) * wmask(ji,jj,jk)
515                     IF( jtaken == 0 )   zwzts(ji,jj,jk) = zwzts(ji,jj,jk) + zwz(ji,jj,jk) * zts(jk)    ! Accumulate time-weighted vertcal flux
516                  END DO
517               END DO
518            END DO
519            IF( ln_linssh ) THEN                    ! top value (only in linear free surface case)
520               IF( ln_isfcav ) THEN                      ! ice-shelf cavities
521                  DO jj = 1, jpj
522                     DO ji = 1, jpi
523                        zwz(ji,jj, mikt(ji,jj) ) = pwn(ji,jj,mikt(ji,jj)) * ptb(ji,jj,mikt(ji,jj),jn)   ! linear free surface
524                     END DO
525                  END DO   
526               ELSE                                      ! no ocean cavities
527                  zwz(:,:,1) = pwn(:,:,1) * ptb(:,:,1,jn)
528               ENDIF
529            ENDIF
530            !
531            jtaken = MOD( jtaken + 1 , 2 )
532            !
533            DO jk = 2, jpkm1                             ! total advective trends
534               DO jj = 2, jpjm1
535                  DO ji = fs_2, fs_jpim1
536                     ztrs(ji,jj,jk,jta) = ztrs(ji,jj,jk,jtb)                                                 &
537                        &               - zts(jk) * (  zhdiv(ji,jj,jk) + zwz(ji,jj,jk) - zwz(ji,jj,jk+1) )   &
538                        &                         / ( e1e2t(ji,jj) * e3t_n(ji,jj,jk) )
539                  END DO
540               END DO
541            END DO
542            !
543         END DO
544
545         DO jk = 2, jpkm1          ! Anti-diffusive vertical flux using average flux from the sub-timestepping
546            DO jj = 2, jpjm1
547               DO ji = fs_2, fs_jpim1
548                  zwz(ji,jj,jk) = ( zwzts(ji,jj,jk) * zr_p2dt(jk) - zwz_sav(ji,jj,jk) ) * wmask(ji,jj,jk)
549               END DO
550            END DO
551         END DO
552         CALL lbc_lnk( zwx, 'U', -1. )   ;   CALL lbc_lnk( zwy, 'V', -1. )         ! Lateral bondary conditions
553         CALL lbc_lnk( zwz, 'W',  1. )
554
555         ! 4. monotonicity algorithm
556         ! -------------------------
557         CALL nonosc( ptb(:,:,:,jn), zwx, zwy, zwz, zwi, p2dt )
558
559
560         ! 5. final trend with corrected fluxes
561         ! ------------------------------------
562         DO jk = 1, jpkm1
563            DO jj = 2, jpjm1
564               DO ji = fs_2, fs_jpim1   ! vector opt. 
565                  pta(ji,jj,jk,jn) = pta(ji,jj,jk,jn) + (   zwy(ji,jj,jk) - zwy(ji  ,jj-1,jk  )       &
566                     &                                    + zwz(ji,jj,jk) - zwz(ji  ,jj  ,jk+1)   )   &
567                     &                                / ( e1e2t(ji,jj) * e3t_n(ji,jj,jk) )
568               END DO
569            END DO
570         END DO
571
572         !                                 ! trend diagnostics (contribution of upstream fluxes)
573         IF( l_trd )  THEN
574            ztrdx(:,:,:) = ztrdx(:,:,:) + zwx(:,:,:)  ! <<< Add to previously computed
575            ztrdy(:,:,:) = ztrdy(:,:,:) + zwy(:,:,:)  ! <<< Add to previously computed
576            ztrdz(:,:,:) = ztrdz(:,:,:) + zwz(:,:,:)  ! <<< Add to previously computed
577            !
578            CALL trd_tra( kt, cdtype, jn, jptra_xad, ztrdx, pun, ptn(:,:,:,jn) )   
579            CALL trd_tra( kt, cdtype, jn, jptra_yad, ztrdy, pvn, ptn(:,:,:,jn) ) 
580            CALL trd_tra( kt, cdtype, jn, jptra_zad, ztrdz, pwn, ptn(:,:,:,jn) ) 
581            !
582            CALL wrk_dealloc( jpi,jpj,jpk,   ztrdx, ztrdy, ztrdz )
583         END IF
584         !                                 ! "Poleward" heat and salt transports (contribution of upstream fluxes)
585         IF( cdtype == 'TRA' .AND. ln_diaptr ) THEN 
586           IF( jn == jp_tem )  htr_adv(:) = ptr_sj( zwy(:,:,:) ) + htr_adv(:)
587           IF( jn == jp_sal )  str_adv(:) = ptr_sj( zwy(:,:,:) ) + str_adv(:)
588         ENDIF
589         !
590      END DO
591      !
592      CALL wrk_alloc( jpi,jpj,             zwx_sav, zwy_sav )
593      CALL wrk_alloc( jpi,jpj, jpk,        zwx, zwy, zwz, zwi, zhdiv, zwzts, zwz_sav )
594      CALL wrk_alloc( jpi,jpj,jpk,kjpt+1,  ztrs )
595      !
596      IF( nn_timing == 1 )  CALL timing_stop('tra_adv_fct_zts')
597      !
598   END SUBROUTINE tra_adv_fct_zts
599
600
601   SUBROUTINE nonosc( pbef, paa, pbb, pcc, paft, p2dt )
602      !!---------------------------------------------------------------------
603      !!                    ***  ROUTINE nonosc  ***
604      !!     
605      !! **  Purpose :   compute monotonic tracer fluxes from the upstream
606      !!       scheme and the before field by a nonoscillatory algorithm
607      !!
608      !! **  Method  :   ... ???
609      !!       warning : pbef and paft must be masked, but the boundaries
610      !!       conditions on the fluxes are not necessary zalezak (1979)
611      !!       drange (1995) multi-dimensional forward-in-time and upstream-
612      !!       in-space based differencing for fluid
613      !!----------------------------------------------------------------------
614      REAL(wp), DIMENSION(jpk)         , INTENT(in   ) ::   p2dt            ! vertical profile of tracer time-step
615      REAL(wp), DIMENSION (jpi,jpj,jpk), INTENT(in   ) ::   pbef, paft      ! before & after field
616      REAL(wp), DIMENSION (jpi,jpj,jpk), INTENT(inout) ::   paa, pbb, pcc   ! monotonic fluxes in the 3 directions
617      !
618      INTEGER  ::   ji, jj, jk   ! dummy loop indices
619      INTEGER  ::   ikm1         ! local integer
620      REAL(wp) ::   zpos, zneg, zbt, za, zb, zc, zbig, zrtrn, z2dtt   ! local scalars
621      REAL(wp) ::   zau, zbu, zcu, zav, zbv, zcv, zup, zdo            !   -      -
622      REAL(wp), POINTER, DIMENSION(:,:,:) :: zbetup, zbetdo, zbup, zbdo
623      !!----------------------------------------------------------------------
624      !
625      IF( nn_timing == 1 )  CALL timing_start('nonosc')
626      !
627      CALL wrk_alloc( jpi, jpj, jpk, zbetup, zbetdo, zbup, zbdo )
628      !
629      zbig  = 1.e+40_wp
630      zrtrn = 1.e-15_wp
631      zbetup(:,:,:) = 0._wp   ;   zbetdo(:,:,:) = 0._wp
632
633      ! Search local extrema
634      ! --------------------
635      ! max/min of pbef & paft with large negative/positive value (-/+zbig) inside land
636      zbup = MAX( pbef * tmask - zbig * ( 1._wp - tmask ),   &
637         &        paft * tmask - zbig * ( 1._wp - tmask )  )
638      zbdo = MIN( pbef * tmask + zbig * ( 1._wp - tmask ),   &
639         &        paft * tmask + zbig * ( 1._wp - tmask )  )
640
641      DO jk = 1, jpkm1
642         ikm1 = MAX(jk-1,1)
643         z2dtt = p2dt(jk)
644         DO jj = 2, jpjm1
645            DO ji = fs_2, fs_jpim1   ! vector opt.
646
647               ! search maximum in neighbourhood
648               zup = MAX(  zbup(ji  ,jj  ,jk  ),   &
649                  &        zbup(ji-1,jj  ,jk  ), zbup(ji+1,jj  ,jk  ),   &
650                  &        zbup(ji  ,jj-1,jk  ), zbup(ji  ,jj+1,jk  ),   &
651                  &        zbup(ji  ,jj  ,ikm1), zbup(ji  ,jj  ,jk+1)  )
652
653               ! search minimum in neighbourhood
654               zdo = MIN(  zbdo(ji  ,jj  ,jk  ),   &
655                  &        zbdo(ji-1,jj  ,jk  ), zbdo(ji+1,jj  ,jk  ),   &
656                  &        zbdo(ji  ,jj-1,jk  ), zbdo(ji  ,jj+1,jk  ),   &
657                  &        zbdo(ji  ,jj  ,ikm1), zbdo(ji  ,jj  ,jk+1)  )
658
659               ! positive part of the flux
660               zpos = MAX( 0., paa(ji-1,jj  ,jk  ) ) - MIN( 0., paa(ji  ,jj  ,jk  ) )   &
661                  & + MAX( 0., pbb(ji  ,jj-1,jk  ) ) - MIN( 0., pbb(ji  ,jj  ,jk  ) )   &
662                  & + MAX( 0., pcc(ji  ,jj  ,jk+1) ) - MIN( 0., pcc(ji  ,jj  ,jk  ) )
663
664               ! negative part of the flux
665               zneg = MAX( 0., paa(ji  ,jj  ,jk  ) ) - MIN( 0., paa(ji-1,jj  ,jk  ) )   &
666                  & + MAX( 0., pbb(ji  ,jj  ,jk  ) ) - MIN( 0., pbb(ji  ,jj-1,jk  ) )   &
667                  & + MAX( 0., pcc(ji  ,jj  ,jk  ) ) - MIN( 0., pcc(ji  ,jj  ,jk+1) )
668
669               ! up & down beta terms
670               zbt = e1t(ji,jj) * e2t(ji,jj) * e3t_n(ji,jj,jk) / z2dtt
671               zbetup(ji,jj,jk) = ( zup            - paft(ji,jj,jk) ) / ( zpos + zrtrn ) * zbt
672               zbetdo(ji,jj,jk) = ( paft(ji,jj,jk) - zdo            ) / ( zneg + zrtrn ) * zbt
673            END DO
674         END DO
675      END DO
676      CALL lbc_lnk( zbetup, 'T', 1. )   ;   CALL lbc_lnk( zbetdo, 'T', 1. )   ! lateral boundary cond. (unchanged sign)
677
678      ! 3. monotonic flux in the i & j direction (paa & pbb)
679      ! ----------------------------------------
680      DO jk = 1, jpkm1
681         DO jj = 2, jpjm1
682            DO ji = fs_2, fs_jpim1   ! vector opt.
683               zau = MIN( 1._wp, zbetdo(ji,jj,jk), zbetup(ji+1,jj,jk) )
684               zbu = MIN( 1._wp, zbetup(ji,jj,jk), zbetdo(ji+1,jj,jk) )
685               zcu =       ( 0.5  + SIGN( 0.5 , paa(ji,jj,jk) ) )
686               paa(ji,jj,jk) = paa(ji,jj,jk) * ( zcu * zau + ( 1._wp - zcu) * zbu )
687
688               zav = MIN( 1._wp, zbetdo(ji,jj,jk), zbetup(ji,jj+1,jk) )
689               zbv = MIN( 1._wp, zbetup(ji,jj,jk), zbetdo(ji,jj+1,jk) )
690               zcv =       ( 0.5  + SIGN( 0.5 , pbb(ji,jj,jk) ) )
691               pbb(ji,jj,jk) = pbb(ji,jj,jk) * ( zcv * zav + ( 1._wp - zcv) * zbv )
692
693      ! monotonic flux in the k direction, i.e. pcc
694      ! -------------------------------------------
695               za = MIN( 1., zbetdo(ji,jj,jk+1), zbetup(ji,jj,jk) )
696               zb = MIN( 1., zbetup(ji,jj,jk+1), zbetdo(ji,jj,jk) )
697               zc =       ( 0.5  + SIGN( 0.5 , pcc(ji,jj,jk+1) ) )
698               pcc(ji,jj,jk+1) = pcc(ji,jj,jk+1) * ( zc * za + ( 1._wp - zc) * zb )
699            END DO
700         END DO
701      END DO
702      CALL lbc_lnk( paa, 'U', -1. )   ;   CALL lbc_lnk( pbb, 'V', -1. )   ! lateral boundary condition (changed sign)
703      !
704      CALL wrk_dealloc( jpi, jpj, jpk, zbetup, zbetdo, zbup, zbdo )
705      !
706      IF( nn_timing == 1 )  CALL timing_stop('nonosc')
707      !
708   END SUBROUTINE nonosc
709
710
711   SUBROUTINE interp_4th_cpt( pt_in, pt_out )
712      !!----------------------------------------------------------------------
713      !!                  ***  ROUTINE interp_4th_cpt  ***
714      !!
715      !! **  Purpose :   Compute the interpolation of tracer at w-point
716      !!
717      !! **  Method  :   4th order compact interpolation
718      !!----------------------------------------------------------------------
719      REAL(wp),DIMENSION(jpi,jpj,jpk), INTENT(in   ) ::   pt_in    ! now tracer fields
720      REAL(wp),DIMENSION(jpi,jpj,jpk), INTENT(  out) ::   pt_out   ! now tracer field interpolated at w-pts
721      !
722      INTEGER :: ji, jj, jk   ! dummy loop integers
723      REAL(wp),DIMENSION(jpi,jpj,jpk) :: zwd, zwi, zws, zwrm, zwt
724      !!----------------------------------------------------------------------
725     
726      DO jk = 3, jpkm1        !==  build the three diagonal matrix  ==!
727         DO jj = 1, jpj
728            DO ji = 1, jpi
729               zwd (ji,jj,jk) = 4._wp
730               zwi (ji,jj,jk) = 1._wp
731               zws (ji,jj,jk) = 1._wp
732               zwrm(ji,jj,jk) = 3._wp * ( pt_in(ji,jj,jk-1) + pt_in(ji,jj,jk) )
733               !
734               IF( tmask(ji,jj,jk+1) == 0._wp) THEN   ! Switch to second order centered at bottom
735                  zwd (ji,jj,jk) = 1._wp
736                  zwi (ji,jj,jk) = 0._wp
737                  zws (ji,jj,jk) = 0._wp
738                  zwrm(ji,jj,jk) = 0.5 * ( pt_in(ji,jj,jk-1) + pt_in(ji,jj,jk) )   
739               ENDIF
740            END DO
741         END DO
742      END DO
743      !
744      jk=2                                            ! Switch to second order centered at top
745      DO jj=1,jpj
746         DO ji=1,jpi
747            zwd (ji,jj,jk) = 1._wp
748            zwi (ji,jj,jk) = 0._wp
749            zws (ji,jj,jk) = 0._wp
750            zwrm(ji,jj,jk) = 0.5 * ( pt_in(ji,jj,jk-1) + pt_in(ji,jj,jk) )
751         END DO
752      END DO   
753      !
754      !                       !==  tridiagonal solve  ==!
755      DO jj = 1, jpj                ! first recurrence
756         DO ji = 1, jpi
757            zwt(ji,jj,2) = zwd(ji,jj,2)
758         END DO
759      END DO
760      DO jk = 3, jpkm1
761         DO jj = 1, jpj
762            DO ji = 1, jpi
763               zwt(ji,jj,jk) = zwd(ji,jj,jk) - zwi(ji,jj,jk) * zws(ji,jj,jk-1) /zwt(ji,jj,jk-1)
764            END DO
765         END DO
766      END DO
767      !
768      DO jj = 1, jpj                ! second recurrence:    Zk = Yk - Ik / Tk-1  Zk-1
769         DO ji = 1, jpi
770            pt_out(ji,jj,2) = zwrm(ji,jj,2)
771         END DO
772      END DO
773      DO jk = 3, jpkm1
774         DO jj = 1, jpj
775            DO ji = 1, jpi
776               pt_out(ji,jj,jk) = zwrm(ji,jj,jk) - zwi(ji,jj,jk) / zwt(ji,jj,jk-1) *pt_out(ji,jj,jk-1)             
777            END DO
778         END DO
779      END DO
780
781      DO jj = 1, jpj                ! third recurrence: Xk = (Zk - Sk Xk+1 ) / Tk
782         DO ji = 1, jpi
783            pt_out(ji,jj,jpkm1) = pt_out(ji,jj,jpkm1) / zwt(ji,jj,jpkm1)
784         END DO
785      END DO
786      DO jk = jpk-2, 2, -1
787         DO jj = 1, jpj
788            DO ji = 1, jpi
789               pt_out(ji,jj,jk) = ( pt_out(ji,jj,jk) - zws(ji,jj,jk) * pt_out(ji,jj,jk+1) ) / zwt(ji,jj,jk)
790            END DO
791         END DO
792      END DO
793      !   
794   END SUBROUTINE interp_4th_cpt
795   
796   !!======================================================================
797END MODULE traadv_fct
Note: See TracBrowser for help on using the repository browser.