New URL for NEMO forge!   http://forge.nemo-ocean.eu

Since March 2022 along with NEMO 4.2 release, the code development moved to a self-hosted GitLab.
This present forge is now archived and remained online for history.
traadv_fct.F90 in branches/2015/dev_r5836_NOC3_vvl_by_default/NEMOGCM/NEMO/OPA_SRC/TRA – NEMO

source: branches/2015/dev_r5836_NOC3_vvl_by_default/NEMOGCM/NEMO/OPA_SRC/TRA/traadv_fct.F90 @ 6004

Last change on this file since 6004 was 6004, checked in by gm, 8 years ago

#1613: vvl by default, step III: Merge with the trunk (free surface simplification) (see wiki)
  • Property svn:keywords set to Id
File size: 40.4 KB
Line 
1MODULE traadv_fct
2   !!==============================================================================
3   !!                       ***  MODULE  traadv_fct  ***
4   !! Ocean  tracers:  horizontal & vertical advective trend (2nd/4th order Flux Corrected Transport method)
5   !!==============================================================================
6   !! History :  3.7  !  2015-09  (L. Debreu, G. Madec)  original code (inspired from traadv_tvd.F90)
7   !!----------------------------------------------------------------------
8
9   !!----------------------------------------------------------------------
10   !!  tra_adv_fct    : update the tracer trend with a 3D advective trends using a 2nd or 4th order FCT scheme
11   !!  tra_adv_fct_zts: update the tracer trend with a 3D advective trends using a 2nd order FCT scheme
12   !!                   with sub-time-stepping in the vertical direction
13   !!  nonosc         : compute monotonic tracer fluxes by a non-oscillatory algorithm
14   !!  interp_4th_cpt : 4th order compact scheme for the vertical component of the advection
15   !!----------------------------------------------------------------------
16   USE oce            ! ocean dynamics and active tracers
17   USE dom_oce        ! ocean space and time domain
18   USE trc_oce        ! share passive tracers/Ocean variables
19   USE trd_oce        ! trends: ocean variables
20   USE trdtra         ! tracers trends
21   USE diaptr         ! poleward transport diagnostics
22   !
23   USE in_out_manager ! I/O manager
24   USE lib_mpp        ! MPP library
25   USE lbclnk         ! ocean lateral boundary condition (or mpp link)
26   USE lib_fortran    ! Fortran utilities (allows no signed zero when 'key_nosignedzero' defined) 
27   USE wrk_nemo       ! Memory Allocation
28   USE timing         ! Timing
29
30   IMPLICIT NONE
31   PRIVATE
32
33   PUBLIC   tra_adv_fct        ! routine called by traadv.F90
34   PUBLIC   tra_adv_fct_zts    ! routine called by traadv.F90
35   PUBLIC   interp_4th_cpt     ! routine called by traadv_cen.F90
36
37   LOGICAL  ::   l_trd   ! flag to compute trends
38   REAL(wp) ::   r1_6 = 1._wp / 6._wp   ! =1/6
39
40   !! * Substitutions
41#  include "vectopt_loop_substitute.h90"
42   !!----------------------------------------------------------------------
43   !! NEMO/OPA 3.7 , NEMO Consortium (2014)
44   !! $Id$
45   !! Software governed by the CeCILL licence     (NEMOGCM/NEMO_CeCILL.txt)
46   !!----------------------------------------------------------------------
47CONTAINS
48
49   SUBROUTINE tra_adv_fct( kt, kit000, cdtype, p2dt, pun, pvn, pwn,       &
50      &                                              ptb, ptn, pta, kjpt, kn_fct_h, kn_fct_v )
51      !!----------------------------------------------------------------------
52      !!                  ***  ROUTINE tra_adv_fct  ***
53      !!
54      !! **  Purpose :   Compute the now trend due to total advection of tracers
55      !!               and add it to the general trend of tracer equations
56      !!
57      !! **  Method  : - 2nd or 4th FCT scheme on the horizontal direction
58      !!               (choice through the value of kn_fct)
59      !!               - on the vertical the 4th order is a compact scheme
60      !!               - corrected flux (monotonic correction)
61      !!
62      !! ** Action : - update pta  with the now advective tracer trends
63      !!             - send trends to trdtra module for further diagnostcs (l_trdtra=T)
64      !!             - htr_adv, str_adv : poleward advective heat and salt transport (ln_diaptr=T)
65      !!----------------------------------------------------------------------
66      INTEGER                              , INTENT(in   ) ::   kt              ! ocean time-step index
67      INTEGER                              , INTENT(in   ) ::   kit000          ! first time step index
68      CHARACTER(len=3)                     , INTENT(in   ) ::   cdtype          ! =TRA or TRC (tracer indicator)
69      INTEGER                              , INTENT(in   ) ::   kjpt            ! number of tracers
70      INTEGER                              , INTENT(in   ) ::   kn_fct_h        ! order of the FCT scheme (=2 or 4)
71      INTEGER                              , INTENT(in   ) ::   kn_fct_v        ! order of the FCT scheme (=2 or 4)
72      REAL(wp), DIMENSION(        jpk     ), INTENT(in   ) ::   p2dt            ! vertical profile of tracer time-step
73      REAL(wp), DIMENSION(jpi,jpj,jpk     ), INTENT(in   ) ::   pun, pvn, pwn   ! 3 ocean velocity components
74      REAL(wp), DIMENSION(jpi,jpj,jpk,kjpt), INTENT(in   ) ::   ptb, ptn        ! before and now tracer fields
75      REAL(wp), DIMENSION(jpi,jpj,jpk,kjpt), INTENT(inout) ::   pta             ! tracer trend
76      !
77      INTEGER  ::   ji, jj, jk, jn                           ! dummy loop indices 
78      REAL(wp) ::   z2dtt, ztra                              ! local scalar
79      REAL(wp) ::   zfp_ui, zfp_vj, zfp_wk, zC2t_u, zC4t_u   !   -      -
80      REAL(wp) ::   zfm_ui, zfm_vj, zfm_wk, zC2t_v, zC4t_v   !   -      -
81      REAL(wp), POINTER, DIMENSION(:,:,:) ::   zwi, zwx, zwy, zwz, ztu, ztv, zltu, zltv, ztw
82      REAL(wp), POINTER, DIMENSION(:,:,:) ::   ztrdx, ztrdy, ztrdz
83      !!----------------------------------------------------------------------
84      !
85      IF( nn_timing == 1 )  CALL timing_start('tra_adv_fct')
86      !
87      CALL wrk_alloc( jpi,jpj,jpk,   zwi, zwx, zwy, zwz, ztu, ztv, zltu, zltv, ztw )
88      !
89      IF( kt == kit000 )  THEN
90         IF(lwp) WRITE(numout,*)
91         IF(lwp) WRITE(numout,*) 'tra_adv_fct : FCT advection scheme on ', cdtype
92         IF(lwp) WRITE(numout,*) '~~~~~~~~~~~'
93      ENDIF
94      !
95      l_trd = .FALSE.
96      IF( ( cdtype == 'TRA' .AND. l_trdtra ) .OR. ( cdtype == 'TRC' .AND. l_trdtrc ) )   l_trd = .TRUE.
97      !
98      IF( l_trd )  THEN
99         CALL wrk_alloc( jpi, jpj, jpk, ztrdx, ztrdy, ztrdz )
100         ztrdx(:,:,:) = 0._wp   ;    ztrdy(:,:,:) = 0._wp   ;   ztrdz(:,:,:) = 0._wp
101      ENDIF
102      !
103      !                          ! surface & bottom value : flux set to zero one for all
104      zwz(:,:, 1 ) = 0._wp           
105      zwx(:,:,jpk) = 0._wp   ;   zwy(:,:,jpk) = 0._wp    ;    zwz(:,:,jpk) = 0._wp
106      !
107      zwi(:,:,:) = 0._wp       
108      !
109      DO jn = 1, kjpt            !==  loop over the tracers  ==!
110         !
111         !        !==  upstream advection with initial mass fluxes & intermediate update  ==!
112         !                    !* upstream tracer flux in the i and j direction
113         DO jk = 1, jpkm1
114            DO jj = 1, jpjm1
115               DO ji = 1, fs_jpim1   ! vector opt.
116                  ! upstream scheme
117                  zfp_ui = pun(ji,jj,jk) + ABS( pun(ji,jj,jk) )
118                  zfm_ui = pun(ji,jj,jk) - ABS( pun(ji,jj,jk) )
119                  zfp_vj = pvn(ji,jj,jk) + ABS( pvn(ji,jj,jk) )
120                  zfm_vj = pvn(ji,jj,jk) - ABS( pvn(ji,jj,jk) )
121                  zwx(ji,jj,jk) = 0.5 * ( zfp_ui * ptb(ji,jj,jk,jn) + zfm_ui * ptb(ji+1,jj  ,jk,jn) )
122                  zwy(ji,jj,jk) = 0.5 * ( zfp_vj * ptb(ji,jj,jk,jn) + zfm_vj * ptb(ji  ,jj+1,jk,jn) )
123               END DO
124            END DO
125         END DO
126         !                    !* upstream tracer flux in the k direction *!
127         DO jk = 2, jpkm1        ! Interior value ( multiplied by wmask)
128            DO jj = 1, jpj
129               DO ji = 1, jpi
130                  zfp_wk = pwn(ji,jj,jk) + ABS( pwn(ji,jj,jk) )
131                  zfm_wk = pwn(ji,jj,jk) - ABS( pwn(ji,jj,jk) )
132                  zwz(ji,jj,jk) = 0.5 * ( zfp_wk * ptb(ji,jj,jk,jn) + zfm_wk * ptb(ji,jj,jk-1,jn) ) * wmask(ji,jj,jk)
133               END DO
134            END DO
135         END DO
136         IF( ln_linssh ) THEN    ! top ocean value (only in linear free surface as zwz has been w-masked)
137            IF( ln_isfcav ) THEN             ! top of the ice-shelf cavities and at the ocean surface
138               DO jj = 1, jpj
139                  DO ji = 1, jpi
140                     zwz(ji,jj, mikt(ji,jj) ) = pwn(ji,jj,mikt(ji,jj)) * ptb(ji,jj,mikt(ji,jj),jn)   ! linear free surface
141                  END DO
142               END DO   
143            ELSE                             ! no cavities: only at the ocean surface
144               zwz(:,:,1) = pwn(:,:,1) * ptb(:,:,1,jn)
145            ENDIF
146         ENDIF
147         !               
148         DO jk = 1, jpkm1     !* trend and after field with monotonic scheme
149            z2dtt = p2dt(jk)
150            DO jj = 2, jpjm1
151               DO ji = fs_2, fs_jpim1   ! vector opt.
152                  ! total intermediate advective trends
153                  ztra = - (  zwx(ji,jj,jk) - zwx(ji-1,jj  ,jk  )   &
154                     &      + zwy(ji,jj,jk) - zwy(ji  ,jj-1,jk  )   &
155                     &      + zwz(ji,jj,jk) - zwz(ji  ,jj  ,jk+1) ) * r1_e1e2t(ji,jj) / e3t_n(ji,jj,jk)
156                  ! update and guess with monotonic sheme
157!!gm why tmask added in the two following lines ???    the mask is done in tranxt !
158                  pta(ji,jj,jk,jn) =   pta(ji,jj,jk,jn)         + ztra   * tmask(ji,jj,jk)
159                  zwi(ji,jj,jk)    = ( ptb(ji,jj,jk,jn) + z2dtt * ztra ) * tmask(ji,jj,jk)
160               END DO
161            END DO
162         END DO
163         CALL lbc_lnk( zwi, 'T', 1. )  ! Lateral boundary conditions on zwi  (unchanged sign)
164         !               
165         IF( l_trd )  THEN             ! trend diagnostics (contribution of upstream fluxes)
166            ztrdx(:,:,:) = zwx(:,:,:)   ;    ztrdy(:,:,:) = zwy(:,:,:)  ;   ztrdz(:,:,:) = zwz(:,:,:)
167         END IF
168         !                             ! "Poleward" heat and salt transports (contribution of upstream fluxes)
169         IF( cdtype == 'TRA' .AND. ln_diaptr ) THEN 
170           IF( jn == jp_tem )  htr_adv(:) = ptr_sj( zwy(:,:,:) )
171           IF( jn == jp_sal )  str_adv(:) = ptr_sj( zwy(:,:,:) )
172         ENDIF
173         !
174         !        !==  anti-diffusive flux : high order minus low order  ==!
175         !
176         SELECT CASE( kn_fct_h )    !* horizontal anti-diffusive fluxes
177         !
178         CASE(  2  )                   !- 2nd order centered
179            DO jk = 1, jpkm1
180               DO jj = 1, jpjm1
181                  DO ji = 1, fs_jpim1   ! vector opt.
182                     zwx(ji,jj,jk) = 0.5_wp * pun(ji,jj,jk) * ( ptn(ji,jj,jk,jn) + ptn(ji+1,jj,jk,jn) ) - zwx(ji,jj,jk)
183                     zwy(ji,jj,jk) = 0.5_wp * pvn(ji,jj,jk) * ( ptn(ji,jj,jk,jn) + ptn(ji,jj+1,jk,jn) ) - zwy(ji,jj,jk)
184                  END DO
185               END DO
186            END DO
187            !
188         CASE(  4  )                   !- 4th order centered
189            zltu(:,:,jpk) = 0._wp            ! Bottom value : flux set to zero
190            zltv(:,:,jpk) = 0._wp
191            DO jk = 1, jpkm1                 ! Laplacian
192               DO jj = 1, jpjm1                    ! 1st derivative (gradient)
193                  DO ji = 1, fs_jpim1   ! vector opt.
194                     ztu(ji,jj,jk) = ( ptn(ji+1,jj  ,jk,jn) - ptn(ji,jj,jk,jn) ) * umask(ji,jj,jk)
195                     ztv(ji,jj,jk) = ( ptn(ji  ,jj+1,jk,jn) - ptn(ji,jj,jk,jn) ) * vmask(ji,jj,jk)
196                  END DO
197               END DO
198               DO jj = 2, jpjm1                    ! 2nd derivative * 1/ 6
199                  DO ji = fs_2, fs_jpim1   ! vector opt.
200                     zltu(ji,jj,jk) = (  ztu(ji,jj,jk) + ztu(ji-1,jj,jk)  ) * r1_6
201                     zltv(ji,jj,jk) = (  ztv(ji,jj,jk) + ztv(ji,jj-1,jk)  ) * r1_6
202                  END DO
203               END DO
204            END DO
205            CALL lbc_lnk( zltu, 'T', 1. )   ;    CALL lbc_lnk( zltv, 'T', 1. )   ! Lateral boundary cond. (unchanged sgn)
206            !
207            DO jk = 1, jpkm1                 ! Horizontal advective fluxes
208               DO jj = 1, jpjm1
209                  DO ji = 1, fs_jpim1   ! vector opt.
210                     zC2t_u = ptn(ji,jj,jk,jn) + ptn(ji+1,jj  ,jk,jn)   ! 2 x C2 interpolation of T at u- & v-points
211                     zC2t_v = ptn(ji,jj,jk,jn) + ptn(ji  ,jj+1,jk,jn)
212                     !                                                  ! C4 minus upstream advective fluxes
213                     zwx(ji,jj,jk) =  0.5_wp * pun(ji,jj,jk) * ( zC2t_u + zltu(ji,jj,jk) - zltu(ji+1,jj,jk) ) - zwx(ji,jj,jk)
214                     zwy(ji,jj,jk) =  0.5_wp * pvn(ji,jj,jk) * ( zC2t_v + zltv(ji,jj,jk) - zltv(ji,jj+1,jk) ) - zwy(ji,jj,jk)
215                  END DO
216               END DO
217            END DO         
218            !
219         CASE(  41 )                   !- 4th order centered       ==>>   !!gm coding attempt   need to be tested
220            ztu(:,:,jpk) = 0._wp             ! Bottom value : flux set to zero
221            ztv(:,:,jpk) = 0._wp
222            DO jk = 1, jpkm1                 ! 1st derivative (gradient)
223               DO jj = 1, jpjm1
224                  DO ji = 1, fs_jpim1   ! vector opt.
225                     ztu(ji,jj,jk) = ( ptn(ji+1,jj  ,jk,jn) - ptn(ji,jj,jk,jn) ) * umask(ji,jj,jk)
226                     ztv(ji,jj,jk) = ( ptn(ji  ,jj+1,jk,jn) - ptn(ji,jj,jk,jn) ) * vmask(ji,jj,jk)
227                  END DO
228               END DO
229            END DO
230            CALL lbc_lnk( ztu, 'U', -1. )   ;    CALL lbc_lnk( ztv, 'V', -1. )   ! Lateral boundary cond. (unchanged sgn)
231            !
232            DO jk = 1, jpkm1                 ! Horizontal advective fluxes
233               DO jj = 2, jpjm1
234                  DO ji = 2, fs_jpim1   ! vector opt.
235                     zC2t_u = ptn(ji,jj,jk,jn) + ptn(ji+1,jj  ,jk,jn)   ! 2 x C2 interpolation of T at u- & v-points (x2)
236                     zC2t_v = ptn(ji,jj,jk,jn) + ptn(ji  ,jj+1,jk,jn)
237                     !                                                  ! C4 interpolation of T at u- & v-points (x2)
238                     zC4t_u =  zC2t_u + r1_6 * ( ztu(ji-1,jj  ,jk) - ztu(ji+1,jj  ,jk) )
239                     zC4t_v =  zC2t_v + r1_6 * ( ztv(ji  ,jj-1,jk) - ztv(ji  ,jj+1,jk) )
240                     !                                                  ! C4 minus upstream advective fluxes
241                     zwx(ji,jj,jk) =  0.5_wp * pun(ji,jj,jk) * zC4t_u - zwx(ji,jj,jk)
242                     zwy(ji,jj,jk) =  0.5_wp * pvn(ji,jj,jk) * zC4t_v - zwy(ji,jj,jk)
243                  END DO
244               END DO
245            END DO
246            !
247         END SELECT
248         !                     
249         SELECT CASE( kn_fct_v )    !* vertical anti-diffusive fluxes (w-masked interior values)
250         !
251         CASE(  2  )                   !- 2nd order centered
252            DO jk = 2, jpkm1   
253               DO jj = 2, jpjm1
254                  DO ji = fs_2, fs_jpim1
255                     zwz(ji,jj,jk) =  (  pwn(ji,jj,jk) * 0.5_wp * ( ptn(ji,jj,jk,jn) + ptn(ji,jj,jk-1,jn) )   &
256                        &              - zwz(ji,jj,jk)  ) * wmask(ji,jj,jk)
257                  END DO
258               END DO
259            END DO
260            !
261         CASE(  4  )                   !- 4th order COMPACT
262            CALL interp_4th_cpt( ptn(:,:,:,jn) , ztw )   ! zwt = COMPACT interpolation of T at w-point
263            DO jk = 2, jpkm1
264               DO jj = 2, jpjm1
265                  DO ji = fs_2, fs_jpim1
266                     zwz(ji,jj,jk) = ( pwn(ji,jj,jk) * ztw(ji,jj,jk) - zwz(ji,jj,jk) ) * wmask(ji,jj,jk)
267                  END DO
268               END DO
269            END DO
270            !
271         END SELECT
272         IF( ln_linssh ) THEN    ! top ocean value: high order = upstream  ==>>  zwz=0
273            zwz(:,:,1) = 0._wp   ! only ocean surface as interior zwz values have been w-masked
274         ENDIF
275         !
276         CALL lbc_lnk( zwx, 'U', -1. )   ;   CALL lbc_lnk( zwy, 'V', -1. )         ! Lateral bondary conditions
277         CALL lbc_lnk( zwz, 'W',  1. )
278         !
279         !        !==  monotonicity algorithm  ==!
280         !
281         CALL nonosc( ptb(:,:,:,jn), zwx, zwy, zwz, zwi, p2dt )
282         !
283         !        !==  final trend with corrected fluxes  ==!
284         !
285         DO jk = 1, jpkm1
286            DO jj = 2, jpjm1
287               DO ji = fs_2, fs_jpim1   ! vector opt. 
288                  pta(ji,jj,jk,jn) = pta(ji,jj,jk,jn) - (  zwx(ji,jj,jk) - zwx(ji-1,jj  ,jk  )   &
289                     &                                   + zwy(ji,jj,jk) - zwy(ji  ,jj-1,jk  )   &
290                     &                                   + zwz(ji,jj,jk) - zwz(ji  ,jj  ,jk+1) ) &
291                     &                                * r1_e1e2t(ji,jj) / e3t_n(ji,jj,jk)
292               END DO
293            END DO
294         END DO
295         !
296         IF( l_trd ) THEN     ! trend diagnostics (contribution of upstream fluxes)
297            ztrdx(:,:,:) = ztrdx(:,:,:) + zwx(:,:,:)  ! <<< Add to previously computed
298            ztrdy(:,:,:) = ztrdy(:,:,:) + zwy(:,:,:)  ! <<< Add to previously computed
299            ztrdz(:,:,:) = ztrdz(:,:,:) + zwz(:,:,:)  ! <<< Add to previously computed
300            !
301            CALL trd_tra( kt, cdtype, jn, jptra_xad, ztrdx, pun, ptn(:,:,:,jn) )
302            CALL trd_tra( kt, cdtype, jn, jptra_yad, ztrdy, pvn, ptn(:,:,:,jn) )
303            CALL trd_tra( kt, cdtype, jn, jptra_zad, ztrdz, pwn, ptn(:,:,:,jn) )
304            !
305            CALL wrk_dealloc( jpi,jpj,jpk,   ztrdx, ztrdy, ztrdz )
306         END IF
307         !                    ! "Poleward" heat and salt transports (contribution of upstream fluxes)
308         IF( cdtype == 'TRA' .AND. ln_diaptr ) THEN 
309           IF( jn == jp_tem )   htr_adv(:) = htr_adv(:) + ptr_sj( zwy(:,:,:) )
310           IF( jn == jp_sal )   str_adv(:) = str_adv(:) + ptr_sj( zwy(:,:,:) )
311         ENDIF
312         !
313      END DO                     ! end of tracer loop
314      !
315      CALL wrk_dealloc( jpi,jpj,jpk,    zwi, zwx, zwy, zwz, ztu, ztv, zltu, zltv, ztw )
316      !
317      IF( nn_timing == 1 )  CALL timing_stop('tra_adv_fct')
318      !
319   END SUBROUTINE tra_adv_fct
320
321
322   SUBROUTINE tra_adv_fct_zts( kt, kit000, cdtype, p2dt, pun, pvn, pwn,      &
323      &                                                  ptb, ptn, pta, kjpt, kn_fct_zts )
324      !!----------------------------------------------------------------------
325      !!                  ***  ROUTINE tra_adv_fct_zts  ***
326      !!
327      !! **  Purpose :   Compute the now trend due to total advection of
328      !!       tracers and add it to the general trend of tracer equations
329      !!
330      !! **  Method  :   TVD ZTS scheme, i.e. 2nd order centered scheme with
331      !!       corrected flux (monotonic correction). This version use sub-
332      !!       timestepping for the vertical advection which increases stability
333      !!       when vertical metrics are small.
334      !!       note: - this advection scheme needs a leap-frog time scheme
335      !!
336      !! ** Action : - update (pta) with the now advective tracer trends
337      !!             - save the trends
338      !!----------------------------------------------------------------------
339      INTEGER                              , INTENT(in   ) ::   kt              ! ocean time-step index
340      INTEGER                              , INTENT(in   ) ::   kit000          ! first time step index
341      CHARACTER(len=3)                     , INTENT(in   ) ::   cdtype          ! =TRA or TRC (tracer indicator)
342      INTEGER                              , INTENT(in   ) ::   kjpt            ! number of tracers
343      INTEGER                              , INTENT(in   ) ::   kn_fct_zts      ! number of number of vertical sub-timesteps
344      REAL(wp), DIMENSION(        jpk     ), INTENT(in   ) ::   p2dt            ! vertical profile of tracer time-step
345      REAL(wp), DIMENSION(jpi,jpj,jpk     ), INTENT(in   ) ::   pun, pvn, pwn   ! 3 ocean velocity components
346      REAL(wp), DIMENSION(jpi,jpj,jpk,kjpt), INTENT(in   ) ::   ptb, ptn        ! before and now tracer fields
347      REAL(wp), DIMENSION(jpi,jpj,jpk,kjpt), INTENT(inout) ::   pta             ! tracer trend
348      !
349      REAL(wp), DIMENSION( jpk )                           ::   zts             ! length of sub-timestep for vertical advection
350      REAL(wp), DIMENSION( jpk )                           ::   zr_p2dt         ! reciprocal of tracer timestep
351      INTEGER  ::   ji, jj, jk, jl, jn       ! dummy loop indices 
352      INTEGER  ::   jtb, jtn, jta   ! sub timestep pointers for leap-frog/euler forward steps
353      INTEGER  ::   jtaken          ! toggle for collecting appropriate fluxes from sub timesteps
354      REAL(wp) ::   z_rzts          ! Fractional length of Euler forward sub-timestep for vertical advection
355      REAL(wp) ::   z2dtt, ztra              ! local scalar
356      REAL(wp) ::   zfp_ui, zfp_vj, zfp_wk   !   -      -
357      REAL(wp) ::   zfm_ui, zfm_vj, zfm_wk   !   -      -
358      REAL(wp), POINTER, DIMENSION(:,:  )   ::   zwx_sav , zwy_sav
359      REAL(wp), POINTER, DIMENSION(:,:,:)   ::   zwi, zwx, zwy, zwz, zhdiv, zwzts, zwz_sav
360      REAL(wp), POINTER, DIMENSION(:,:,:)   ::   ztrdx, ztrdy, ztrdz
361      REAL(wp), POINTER, DIMENSION(:,:,:,:) ::   ztrs
362      !!----------------------------------------------------------------------
363      !
364      IF( nn_timing == 1 )  CALL timing_start('tra_adv_fct_zts')
365      !
366      CALL wrk_alloc( jpi,jpj,             zwx_sav, zwy_sav )
367      CALL wrk_alloc( jpi,jpj, jpk,        zwx, zwy, zwz, zwi, zhdiv, zwzts, zwz_sav )
368      CALL wrk_alloc( jpi,jpj,jpk,kjpt+1,  ztrs )
369      !
370      IF( kt == kit000 )  THEN
371         IF(lwp) WRITE(numout,*)
372         IF(lwp) WRITE(numout,*) 'tra_adv_fct_zts : 2nd order FCT scheme with ', kn_fct_zts, ' vertical sub-timestep on ', cdtype
373         IF(lwp) WRITE(numout,*) '~~~~~~~~~~~'
374      ENDIF
375      !
376      l_trd = .FALSE.
377      IF( ( cdtype == 'TRA' .AND. l_trdtra ) .OR. ( cdtype == 'TRC' .AND. l_trdtrc ) )   l_trd = .TRUE.
378      !
379      IF( l_trd )  THEN
380         CALL wrk_alloc( jpi,jpj,jpk,   ztrdx, ztrdy, ztrdz )
381         ztrdx(:,:,:) = 0._wp  ;    ztrdy(:,:,:) = 0._wp  ;   ztrdz(:,:,:) = 0._wp
382      ENDIF
383      !
384      zwi(:,:,:) = 0._wp
385      z_rzts = 1._wp / REAL( kn_fct_zts, wp )
386      zr_p2dt(:) = 1._wp / p2dt(:)
387      !
388      ! surface & Bottom value : flux set to zero for all tracers
389      zwz(:,:, 1 ) = 0._wp
390      zwx(:,:,jpk) = 0._wp   ;    zwz(:,:,jpk) = 0._wp
391      zwy(:,:,jpk) = 0._wp   ;    zwi(:,:,jpk) = 0._wp
392      !
393      !                                                          ! ===========
394      DO jn = 1, kjpt                                            ! tracer loop
395         !                                                       ! ===========
396         !
397         ! Upstream advection with initial mass fluxes & intermediate update
398         DO jk = 1, jpkm1        ! upstream tracer flux in the i and j direction
399            DO jj = 1, jpjm1
400               DO ji = 1, fs_jpim1   ! vector opt.
401                  ! upstream scheme
402                  zfp_ui = pun(ji,jj,jk) + ABS( pun(ji,jj,jk) )
403                  zfm_ui = pun(ji,jj,jk) - ABS( pun(ji,jj,jk) )
404                  zfp_vj = pvn(ji,jj,jk) + ABS( pvn(ji,jj,jk) )
405                  zfm_vj = pvn(ji,jj,jk) - ABS( pvn(ji,jj,jk) )
406                  zwx(ji,jj,jk) = 0.5_wp * ( zfp_ui * ptb(ji,jj,jk,jn) + zfm_ui * ptb(ji+1,jj  ,jk,jn) )
407                  zwy(ji,jj,jk) = 0.5_wp * ( zfp_vj * ptb(ji,jj,jk,jn) + zfm_vj * ptb(ji  ,jj+1,jk,jn) )
408               END DO
409            END DO
410         END DO
411         !                       ! upstream tracer flux in the k direction
412         DO jk = 2, jpkm1              ! Interior value
413            DO jj = 1, jpj
414               DO ji = 1, jpi
415                  zfp_wk = pwn(ji,jj,jk) + ABS( pwn(ji,jj,jk) )
416                  zfm_wk = pwn(ji,jj,jk) - ABS( pwn(ji,jj,jk) )
417                  zwz(ji,jj,jk) = 0.5_wp * ( zfp_wk * ptb(ji,jj,jk,jn) + zfm_wk * ptb(ji,jj,jk-1,jn) ) * wmask(ji,jj,jk)
418               END DO
419            END DO
420         END DO
421         IF( ln_linssh ) THEN          ! top value : linear free surface case only (as zwz is multiplied by wmask)
422            IF( ln_isfcav ) THEN             ! ice-shelf cavities: top value
423               DO jj = 1, jpj
424                  DO ji = 1, jpi
425                     zwz(ji,jj, mikt(ji,jj) ) = pwn(ji,jj,mikt(ji,jj)) * ptb(ji,jj,mikt(ji,jj),jn) 
426                  END DO
427               END DO   
428            ELSE                             ! no cavities, surface value
429               zwz(:,:,1) = pwn(:,:,1) * ptb(:,:,1,jn)
430            ENDIF
431         ENDIF
432         !
433         DO jk = 1, jpkm1         ! total advective trend
434            z2dtt = p2dt(jk)
435            DO jj = 2, jpjm1
436               DO ji = fs_2, fs_jpim1   ! vector opt.
437                  !                             ! total intermediate advective trends
438                  ztra = - (  zwx(ji,jj,jk) - zwx(ji-1,jj  ,jk  )   &
439                     &      + zwy(ji,jj,jk) - zwy(ji  ,jj-1,jk  )   &
440                     &      + zwz(ji,jj,jk) - zwz(ji  ,jj  ,jk+1)   ) * r1_e1e2t(ji,jj) / e3t_n(ji,jj,jk)
441                  !                             ! update and guess with monotonic sheme
442                  pta(ji,jj,jk,jn) =   pta(ji,jj,jk,jn)         + ztra
443                  zwi(ji,jj,jk)    = ( ptb(ji,jj,jk,jn) + z2dtt * ztra ) * tmask(ji,jj,jk)
444               END DO
445            END DO
446         END DO
447         !                           
448         CALL lbc_lnk( zwi, 'T', 1. )     ! Lateral boundary conditions on zwi  (unchanged sign)
449         !               
450         IF( l_trd )  THEN                ! trend diagnostics (contribution of upstream fluxes)
451            ztrdx(:,:,:) = zwx(:,:,:)   ;    ztrdy(:,:,:) = zwy(:,:,:)  ;   ztrdz(:,:,:) = zwz(:,:,:)
452         END IF
453         !                                ! "Poleward" heat and salt transports (contribution of upstream fluxes)
454         IF( cdtype == 'TRA' .AND. ln_diaptr ) THEN 
455           IF( jn == jp_tem )  htr_adv(:) = ptr_sj( zwy(:,:,:) )
456           IF( jn == jp_sal )  str_adv(:) = ptr_sj( zwy(:,:,:) )
457         ENDIF
458
459         ! 3. anti-diffusive flux : high order minus low order
460         ! ---------------------------------------------------
461
462         DO jk = 1, jpkm1                    !* horizontal anti-diffusive fluxes
463            !
464            DO jj = 1, jpjm1
465               DO ji = 1, fs_jpim1   ! vector opt.
466                  zwx_sav(ji,jj) = zwx(ji,jj,jk)
467                  zwy_sav(ji,jj) = zwy(ji,jj,jk)
468                  !
469                  zwx(ji,jj,jk) = 0.5_wp * pun(ji,jj,jk) * ( ptn(ji,jj,jk,jn) + ptn(ji+1,jj,jk,jn) )
470                  zwy(ji,jj,jk) = 0.5_wp * pvn(ji,jj,jk) * ( ptn(ji,jj,jk,jn) + ptn(ji,jj+1,jk,jn) )
471               END DO
472            END DO
473            !
474            DO jj = 2, jpjm1                    ! partial horizontal divergence
475               DO ji = fs_2, fs_jpim1
476                  zhdiv(ji,jj,jk) = (  zwx(ji,jj,jk) - zwx(ji-1,jj  ,jk)   &
477                     &               + zwy(ji,jj,jk) - zwy(ji  ,jj-1,jk)  )
478               END DO
479            END DO
480            !
481            DO jj = 1, jpjm1
482               DO ji = 1, fs_jpim1   ! vector opt.
483                  zwx(ji,jj,jk) = zwx(ji,jj,jk) - zwx_sav(ji,jj)
484                  zwy(ji,jj,jk) = zwy(ji,jj,jk) - zwy_sav(ji,jj)
485               END DO
486            END DO
487         END DO
488         !
489         !                                !* vertical anti-diffusive flux
490         zwz_sav(:,:,:)   = zwz(:,:,:)
491         ztrs   (:,:,:,1) = ptb(:,:,:,jn)
492         zwzts  (:,:,:)   = 0._wp
493         !
494         DO jl = 1, kn_fct_zts                  ! Start of sub timestepping loop
495            !
496            IF( jl == 1 ) THEN                        ! Euler forward to kick things off
497               jtb = 1   ;   jtn = 1   ;   jta = 2
498               zts(:) = p2dt(:) * z_rzts
499               jtaken = MOD( kn_fct_zts + 1 , 2)            ! Toggle to collect every second flux
500               !                                            ! starting at jl =1 if kn_fct_zts is odd;
501               !                                            ! starting at jl =2 otherwise
502            ELSEIF( jl == 2 ) THEN                    ! First leapfrog step
503               jtb = 1   ;   jtn = 2   ;   jta = 3
504               zts(:) = 2._wp * p2dt(:) * z_rzts
505            ELSE                                      ! Shuffle pointers for subsequent leapfrog steps
506               jtb = MOD(jtb,3) + 1
507               jtn = MOD(jtn,3) + 1
508               jta = MOD(jta,3) + 1
509            ENDIF
510            DO jk = 2, jpkm1                          ! interior value
511               DO jj = 2, jpjm1
512                  DO ji = fs_2, fs_jpim1
513                     zwz(ji,jj,jk) = 0.5_wp * pwn(ji,jj,jk) * ( ztrs(ji,jj,jk,jtn) + ztrs(ji,jj,jk-1,jtn) ) * wmask(ji,jj,jk)
514                     IF( jtaken == 0 )   zwzts(ji,jj,jk) = zwzts(ji,jj,jk) + zwz(ji,jj,jk) * zts(jk)    ! Accumulate time-weighted vertcal flux
515                  END DO
516               END DO
517            END DO
518            IF( ln_linssh ) THEN                    ! top value (only in linear free surface case)
519               IF( ln_isfcav ) THEN                      ! ice-shelf cavities
520                  DO jj = 1, jpj
521                     DO ji = 1, jpi
522                        zwz(ji,jj, mikt(ji,jj) ) = pwn(ji,jj,mikt(ji,jj)) * ptb(ji,jj,mikt(ji,jj),jn)   ! linear free surface
523                     END DO
524                  END DO   
525               ELSE                                      ! no ocean cavities
526                  zwz(:,:,1) = pwn(:,:,1) * ptb(:,:,1,jn)
527               ENDIF
528            ENDIF
529            !
530            jtaken = MOD( jtaken + 1 , 2 )
531            !
532            DO jk = 2, jpkm1                             ! total advective trends
533               DO jj = 2, jpjm1
534                  DO ji = fs_2, fs_jpim1
535                     ztrs(ji,jj,jk,jta) = ztrs(ji,jj,jk,jtb)                                                 &
536                        &               - zts(jk) * (  zhdiv(ji,jj,jk) + zwz(ji,jj,jk) - zwz(ji,jj,jk+1) )   &
537                        &                         * r1_e1e2t(ji,jj) / e3t_n(ji,jj,jk)
538                  END DO
539               END DO
540            END DO
541            !
542         END DO
543
544         DO jk = 2, jpkm1          ! Anti-diffusive vertical flux using average flux from the sub-timestepping
545            DO jj = 2, jpjm1
546               DO ji = fs_2, fs_jpim1
547                  zwz(ji,jj,jk) = ( zwzts(ji,jj,jk) * zr_p2dt(jk) - zwz_sav(ji,jj,jk) ) * wmask(ji,jj,jk)
548               END DO
549            END DO
550         END DO
551         CALL lbc_lnk( zwx, 'U', -1. )   ;   CALL lbc_lnk( zwy, 'V', -1. )         ! Lateral bondary conditions
552         CALL lbc_lnk( zwz, 'W',  1. )
553
554         ! 4. monotonicity algorithm
555         ! -------------------------
556         CALL nonosc( ptb(:,:,:,jn), zwx, zwy, zwz, zwi, p2dt )
557
558
559         ! 5. final trend with corrected fluxes
560         ! ------------------------------------
561         DO jk = 1, jpkm1
562            DO jj = 2, jpjm1
563               DO ji = fs_2, fs_jpim1   ! vector opt. 
564                  pta(ji,jj,jk,jn) = pta(ji,jj,jk,jn) + (   zwy(ji,jj,jk) - zwy(ji  ,jj-1,jk  )       &
565                     &                                    + zwz(ji,jj,jk) - zwz(ji  ,jj  ,jk+1)   )   &
566                     &                                * r1_e1e2t(ji,jj) / e3t_n(ji,jj,jk)
567               END DO
568            END DO
569         END DO
570
571         !                                 ! trend diagnostics (contribution of upstream fluxes)
572         IF( l_trd )  THEN
573            ztrdx(:,:,:) = ztrdx(:,:,:) + zwx(:,:,:)  ! <<< Add to previously computed
574            ztrdy(:,:,:) = ztrdy(:,:,:) + zwy(:,:,:)  ! <<< Add to previously computed
575            ztrdz(:,:,:) = ztrdz(:,:,:) + zwz(:,:,:)  ! <<< Add to previously computed
576            !
577            CALL trd_tra( kt, cdtype, jn, jptra_xad, ztrdx, pun, ptn(:,:,:,jn) )   
578            CALL trd_tra( kt, cdtype, jn, jptra_yad, ztrdy, pvn, ptn(:,:,:,jn) ) 
579            CALL trd_tra( kt, cdtype, jn, jptra_zad, ztrdz, pwn, ptn(:,:,:,jn) ) 
580            !
581            CALL wrk_dealloc( jpi,jpj,jpk,   ztrdx, ztrdy, ztrdz )
582         END IF
583         !                                 ! "Poleward" heat and salt transports (contribution of upstream fluxes)
584         IF( cdtype == 'TRA' .AND. ln_diaptr ) THEN 
585           IF( jn == jp_tem )  htr_adv(:) = ptr_sj( zwy(:,:,:) ) + htr_adv(:)
586           IF( jn == jp_sal )  str_adv(:) = ptr_sj( zwy(:,:,:) ) + str_adv(:)
587         ENDIF
588         !
589      END DO
590      !
591      CALL wrk_alloc( jpi,jpj,             zwx_sav, zwy_sav )
592      CALL wrk_alloc( jpi,jpj, jpk,        zwx, zwy, zwz, zwi, zhdiv, zwzts, zwz_sav )
593      CALL wrk_alloc( jpi,jpj,jpk,kjpt+1,  ztrs )
594      !
595      IF( nn_timing == 1 )  CALL timing_stop('tra_adv_fct_zts')
596      !
597   END SUBROUTINE tra_adv_fct_zts
598
599
600   SUBROUTINE nonosc( pbef, paa, pbb, pcc, paft, p2dt )
601      !!---------------------------------------------------------------------
602      !!                    ***  ROUTINE nonosc  ***
603      !!     
604      !! **  Purpose :   compute monotonic tracer fluxes from the upstream
605      !!       scheme and the before field by a nonoscillatory algorithm
606      !!
607      !! **  Method  :   ... ???
608      !!       warning : pbef and paft must be masked, but the boundaries
609      !!       conditions on the fluxes are not necessary zalezak (1979)
610      !!       drange (1995) multi-dimensional forward-in-time and upstream-
611      !!       in-space based differencing for fluid
612      !!----------------------------------------------------------------------
613      REAL(wp), DIMENSION(jpk)         , INTENT(in   ) ::   p2dt            ! vertical profile of tracer time-step
614      REAL(wp), DIMENSION (jpi,jpj,jpk), INTENT(in   ) ::   pbef, paft      ! before & after field
615      REAL(wp), DIMENSION (jpi,jpj,jpk), INTENT(inout) ::   paa, pbb, pcc   ! monotonic fluxes in the 3 directions
616      !
617      INTEGER  ::   ji, jj, jk   ! dummy loop indices
618      INTEGER  ::   ikm1         ! local integer
619      REAL(wp) ::   zpos, zneg, zbt, za, zb, zc, zbig, zrtrn, z2dtt   ! local scalars
620      REAL(wp) ::   zau, zbu, zcu, zav, zbv, zcv, zup, zdo            !   -      -
621      REAL(wp), POINTER, DIMENSION(:,:,:) :: zbetup, zbetdo, zbup, zbdo
622      !!----------------------------------------------------------------------
623      !
624      IF( nn_timing == 1 )  CALL timing_start('nonosc')
625      !
626      CALL wrk_alloc( jpi, jpj, jpk, zbetup, zbetdo, zbup, zbdo )
627      !
628      zbig  = 1.e+40_wp
629      zrtrn = 1.e-15_wp
630      zbetup(:,:,:) = 0._wp   ;   zbetdo(:,:,:) = 0._wp
631
632      ! Search local extrema
633      ! --------------------
634      ! max/min of pbef & paft with large negative/positive value (-/+zbig) inside land
635      zbup = MAX( pbef * tmask - zbig * ( 1._wp - tmask ),   &
636         &        paft * tmask - zbig * ( 1._wp - tmask )  )
637      zbdo = MIN( pbef * tmask + zbig * ( 1._wp - tmask ),   &
638         &        paft * tmask + zbig * ( 1._wp - tmask )  )
639
640      DO jk = 1, jpkm1
641         ikm1 = MAX(jk-1,1)
642         z2dtt = p2dt(jk)
643         DO jj = 2, jpjm1
644            DO ji = fs_2, fs_jpim1   ! vector opt.
645
646               ! search maximum in neighbourhood
647               zup = MAX(  zbup(ji  ,jj  ,jk  ),   &
648                  &        zbup(ji-1,jj  ,jk  ), zbup(ji+1,jj  ,jk  ),   &
649                  &        zbup(ji  ,jj-1,jk  ), zbup(ji  ,jj+1,jk  ),   &
650                  &        zbup(ji  ,jj  ,ikm1), zbup(ji  ,jj  ,jk+1)  )
651
652               ! search minimum in neighbourhood
653               zdo = MIN(  zbdo(ji  ,jj  ,jk  ),   &
654                  &        zbdo(ji-1,jj  ,jk  ), zbdo(ji+1,jj  ,jk  ),   &
655                  &        zbdo(ji  ,jj-1,jk  ), zbdo(ji  ,jj+1,jk  ),   &
656                  &        zbdo(ji  ,jj  ,ikm1), zbdo(ji  ,jj  ,jk+1)  )
657
658               ! positive part of the flux
659               zpos = MAX( 0., paa(ji-1,jj  ,jk  ) ) - MIN( 0., paa(ji  ,jj  ,jk  ) )   &
660                  & + MAX( 0., pbb(ji  ,jj-1,jk  ) ) - MIN( 0., pbb(ji  ,jj  ,jk  ) )   &
661                  & + MAX( 0., pcc(ji  ,jj  ,jk+1) ) - MIN( 0., pcc(ji  ,jj  ,jk  ) )
662
663               ! negative part of the flux
664               zneg = MAX( 0., paa(ji  ,jj  ,jk  ) ) - MIN( 0., paa(ji-1,jj  ,jk  ) )   &
665                  & + MAX( 0., pbb(ji  ,jj  ,jk  ) ) - MIN( 0., pbb(ji  ,jj-1,jk  ) )   &
666                  & + MAX( 0., pcc(ji  ,jj  ,jk  ) ) - MIN( 0., pcc(ji  ,jj  ,jk+1) )
667
668               ! up & down beta terms
669               zbt = e1e2t(ji,jj) * e3t_n(ji,jj,jk) / z2dtt
670               zbetup(ji,jj,jk) = ( zup            - paft(ji,jj,jk) ) / ( zpos + zrtrn ) * zbt
671               zbetdo(ji,jj,jk) = ( paft(ji,jj,jk) - zdo            ) / ( zneg + zrtrn ) * zbt
672            END DO
673         END DO
674      END DO
675      CALL lbc_lnk( zbetup, 'T', 1. )   ;   CALL lbc_lnk( zbetdo, 'T', 1. )   ! lateral boundary cond. (unchanged sign)
676
677      ! 3. monotonic flux in the i & j direction (paa & pbb)
678      ! ----------------------------------------
679      DO jk = 1, jpkm1
680         DO jj = 2, jpjm1
681            DO ji = fs_2, fs_jpim1   ! vector opt.
682               zau = MIN( 1._wp, zbetdo(ji,jj,jk), zbetup(ji+1,jj,jk) )
683               zbu = MIN( 1._wp, zbetup(ji,jj,jk), zbetdo(ji+1,jj,jk) )
684               zcu =       ( 0.5  + SIGN( 0.5 , paa(ji,jj,jk) ) )
685               paa(ji,jj,jk) = paa(ji,jj,jk) * ( zcu * zau + ( 1._wp - zcu) * zbu )
686
687               zav = MIN( 1._wp, zbetdo(ji,jj,jk), zbetup(ji,jj+1,jk) )
688               zbv = MIN( 1._wp, zbetup(ji,jj,jk), zbetdo(ji,jj+1,jk) )
689               zcv =       ( 0.5  + SIGN( 0.5 , pbb(ji,jj,jk) ) )
690               pbb(ji,jj,jk) = pbb(ji,jj,jk) * ( zcv * zav + ( 1._wp - zcv) * zbv )
691
692      ! monotonic flux in the k direction, i.e. pcc
693      ! -------------------------------------------
694               za = MIN( 1., zbetdo(ji,jj,jk+1), zbetup(ji,jj,jk) )
695               zb = MIN( 1., zbetup(ji,jj,jk+1), zbetdo(ji,jj,jk) )
696               zc =       ( 0.5  + SIGN( 0.5 , pcc(ji,jj,jk+1) ) )
697               pcc(ji,jj,jk+1) = pcc(ji,jj,jk+1) * ( zc * za + ( 1._wp - zc) * zb )
698            END DO
699         END DO
700      END DO
701      CALL lbc_lnk( paa, 'U', -1. )   ;   CALL lbc_lnk( pbb, 'V', -1. )   ! lateral boundary condition (changed sign)
702      !
703      CALL wrk_dealloc( jpi, jpj, jpk, zbetup, zbetdo, zbup, zbdo )
704      !
705      IF( nn_timing == 1 )  CALL timing_stop('nonosc')
706      !
707   END SUBROUTINE nonosc
708
709
710   SUBROUTINE interp_4th_cpt( pt_in, pt_out )
711      !!----------------------------------------------------------------------
712      !!                  ***  ROUTINE interp_4th_cpt  ***
713      !!
714      !! **  Purpose :   Compute the interpolation of tracer at w-point
715      !!
716      !! **  Method  :   4th order compact interpolation
717      !!----------------------------------------------------------------------
718      REAL(wp),DIMENSION(jpi,jpj,jpk), INTENT(in   ) ::   pt_in    ! now tracer fields
719      REAL(wp),DIMENSION(jpi,jpj,jpk), INTENT(  out) ::   pt_out   ! now tracer field interpolated at w-pts
720      !
721      INTEGER :: ji, jj, jk   ! dummy loop integers
722      REAL(wp),DIMENSION(jpi,jpj,jpk) :: zwd, zwi, zws, zwrm, zwt
723      !!----------------------------------------------------------------------
724     
725      DO jk = 3, jpkm1        !==  build the three diagonal matrix  ==!
726         DO jj = 1, jpj
727            DO ji = 1, jpi
728               zwd (ji,jj,jk) = 4._wp
729               zwi (ji,jj,jk) = 1._wp
730               zws (ji,jj,jk) = 1._wp
731               zwrm(ji,jj,jk) = 3._wp * ( pt_in(ji,jj,jk-1) + pt_in(ji,jj,jk) )
732               !
733               IF( tmask(ji,jj,jk+1) == 0._wp) THEN   ! Switch to second order centered at bottom
734                  zwd (ji,jj,jk) = 1._wp
735                  zwi (ji,jj,jk) = 0._wp
736                  zws (ji,jj,jk) = 0._wp
737                  zwrm(ji,jj,jk) = 0.5 * ( pt_in(ji,jj,jk-1) + pt_in(ji,jj,jk) )   
738               ENDIF
739            END DO
740         END DO
741      END DO
742      !
743      jk=2                                            ! Switch to second order centered at top
744      DO jj=1,jpj
745         DO ji=1,jpi
746            zwd (ji,jj,jk) = 1._wp
747            zwi (ji,jj,jk) = 0._wp
748            zws (ji,jj,jk) = 0._wp
749            zwrm(ji,jj,jk) = 0.5 * ( pt_in(ji,jj,jk-1) + pt_in(ji,jj,jk) )
750         END DO
751      END DO   
752      !
753      !                       !==  tridiagonal solve  ==!
754      DO jj = 1, jpj                ! first recurrence
755         DO ji = 1, jpi
756            zwt(ji,jj,2) = zwd(ji,jj,2)
757         END DO
758      END DO
759      DO jk = 3, jpkm1
760         DO jj = 1, jpj
761            DO ji = 1, jpi
762               zwt(ji,jj,jk) = zwd(ji,jj,jk) - zwi(ji,jj,jk) * zws(ji,jj,jk-1) /zwt(ji,jj,jk-1)
763            END DO
764         END DO
765      END DO
766      !
767      DO jj = 1, jpj                ! second recurrence:    Zk = Yk - Ik / Tk-1  Zk-1
768         DO ji = 1, jpi
769            pt_out(ji,jj,2) = zwrm(ji,jj,2)
770         END DO
771      END DO
772      DO jk = 3, jpkm1
773         DO jj = 1, jpj
774            DO ji = 1, jpi
775               pt_out(ji,jj,jk) = zwrm(ji,jj,jk) - zwi(ji,jj,jk) / zwt(ji,jj,jk-1) *pt_out(ji,jj,jk-1)             
776            END DO
777         END DO
778      END DO
779
780      DO jj = 1, jpj                ! third recurrence: Xk = (Zk - Sk Xk+1 ) / Tk
781         DO ji = 1, jpi
782            pt_out(ji,jj,jpkm1) = pt_out(ji,jj,jpkm1) / zwt(ji,jj,jpkm1)
783         END DO
784      END DO
785      DO jk = jpk-2, 2, -1
786         DO jj = 1, jpj
787            DO ji = 1, jpi
788               pt_out(ji,jj,jk) = ( pt_out(ji,jj,jk) - zws(ji,jj,jk) * pt_out(ji,jj,jk+1) ) / zwt(ji,jj,jk)
789            END DO
790         END DO
791      END DO
792      !   
793   END SUBROUTINE interp_4th_cpt
794   
795   !!======================================================================
796END MODULE traadv_fct
Note: See TracBrowser for help on using the repository browser.