New URL for NEMO forge!   http://forge.nemo-ocean.eu

Since March 2022 along with NEMO 4.2 release, the code development moved to a self-hosted GitLab.
This present forge is now archived and remained online for history.
traadv_mus.F90 in branches/2015/dev_r5836_NOC3_vvl_by_default/NEMOGCM/NEMO/OPA_SRC/TRA – NEMO

source: branches/2015/dev_r5836_NOC3_vvl_by_default/NEMOGCM/NEMO/OPA_SRC/TRA/traadv_mus.F90 @ 5883

Last change on this file since 5883 was 5883, checked in by gm, 8 years ago

#1613: vvl by default: TRA/TRC remove optimization associated with linear free surface
  • Property svn:keywords set to Id
File size: 15.0 KB
Line 
1MODULE traadv_mus
2   !!======================================================================
3   !!                       ***  MODULE  traadv_mus  ***
4   !! Ocean  tracers:  horizontal & vertical advective trend
5   !!======================================================================
6   !! History :       !  2000-06  (A.Estublier)  for passive tracers
7   !!                 !  2001-08  (E.Durand, G.Madec)  adapted for T & S
8   !!   NEMO     1.0  !  2002-06  (G. Madec)  F90: Free form and module
9   !!            3.2  !  2010-05  (C. Ethe, G. Madec)  merge TRC-TRA + switch from velocity to transport
10   !!            3.4  !  2012-06  (P. Oddo, M. Vichi) include the upstream where needed
11   !!            3.7  !  2015-09  (G. Madec) add the ice-shelf cavities boundary condition
12   !!----------------------------------------------------------------------
13
14   !!----------------------------------------------------------------------
15   !!   tra_adv_mus   : update the tracer trend with the horizontal
16   !!                   and vertical advection trends using MUSCL scheme
17   !!----------------------------------------------------------------------
18   USE oce            ! ocean dynamics and active tracers
19   USE trc_oce        ! share passive tracers/Ocean variables
20   USE dom_oce        ! ocean space and time domain
21   USE trd_oce        ! trends: ocean variables
22   USE trdtra         ! tracers trends manager
23   USE dynspg_oce     ! choice/control of key cpp for surface pressure gradient
24   USE sbcrnf         ! river runoffs
25   USE diaptr         ! poleward transport diagnostics
26   !
27   USE wrk_nemo       ! Memory Allocation
28   USE timing         ! Timing
29   USE lib_fortran    ! Fortran utilities (allows no signed zero when 'key_nosignedzero' defined) 
30   USE in_out_manager ! I/O manager
31   USE lib_mpp        ! distribued memory computing
32   USE lbclnk         ! ocean lateral boundary condition (or mpp link)
33
34   IMPLICIT NONE
35   PRIVATE
36
37   PUBLIC   tra_adv_mus   ! routine called by traadv.F90
38   
39   REAL(wp), ALLOCATABLE, SAVE, DIMENSION(:,:)   ::   upsmsk   !: mixed upstream/centered scheme near some straits
40   !                                                           !  and in closed seas (orca 2 and 4 configurations)
41   REAL(wp), ALLOCATABLE, SAVE, DIMENSION(:,:,:) ::   xind     !: mixed upstream/centered index
42   
43   !! * Substitutions
44#  include "vectopt_loop_substitute.h90"
45   !!----------------------------------------------------------------------
46   !! NEMO/OPA 3.3 , NEMO Consortium (2010)
47   !! $Id$
48   !! Software governed by the CeCILL licence     (NEMOGCM/NEMO_CeCILL.txt)
49   !!----------------------------------------------------------------------
50CONTAINS
51
52   SUBROUTINE tra_adv_mus( kt, kit000, cdtype, p2dt, pun, pvn, pwn,             &
53      &                                              ptb, pta, kjpt, ld_msc_ups )
54      !!----------------------------------------------------------------------
55      !!                    ***  ROUTINE tra_adv_mus  ***
56      !!
57      !! ** Purpose :   Compute the now trend due to total advection of tracers
58      !!              using a MUSCL scheme (Monotone Upstream-centered Scheme for
59      !!              Conservation Laws) and add it to the general tracer trend.
60      !!
61      !! ** Method  : MUSCL scheme plus centered scheme at ocean boundaries
62      !!              ld_msc_ups=T :
63      !!
64      !! ** Action : - update pta  with the now advective tracer trends
65      !!             - send trends to trdtra module for further diagnostcs (l_trdtra=T)
66      !!             - htr_adv, str_adv : poleward advective heat and salt transport (ln_diaptr=T)
67      !!
68      !! References : Estubier, A., and M. Levy, Notes Techn. Pole de Modelisation
69      !!              IPSL, Sept. 2000 (http://www.lodyc.jussieu.fr/opa)
70      !!----------------------------------------------------------------------
71      INTEGER                              , INTENT(in   ) ::   kt              ! ocean time-step index
72      INTEGER                              , INTENT(in   ) ::   kit000          ! first time step index
73      CHARACTER(len=3)                     , INTENT(in   ) ::   cdtype          ! =TRA or TRC (tracer indicator)
74      INTEGER                              , INTENT(in   ) ::   kjpt            ! number of tracers
75      LOGICAL                              , INTENT(in   ) ::   ld_msc_ups      ! use upstream scheme within muscl
76      REAL(wp), DIMENSION(        jpk     ), INTENT(in   ) ::   p2dt            ! vertical profile of tracer time-step
77      REAL(wp), DIMENSION(jpi,jpj,jpk     ), INTENT(in   ) ::   pun, pvn, pwn   ! 3 ocean velocity components
78      REAL(wp), DIMENSION(jpi,jpj,jpk,kjpt), INTENT(in   ) ::   ptb             ! before tracer field
79      REAL(wp), DIMENSION(jpi,jpj,jpk,kjpt), INTENT(inout) ::   pta             ! tracer trend
80      !
81      INTEGER  ::   ji, jj, jk, jn       ! dummy loop indices
82      INTEGER  ::   ierr                 ! local integer
83      REAL(wp) ::   zu, z0u, zzwx, zw    ! local scalars
84      REAL(wp) ::   zv, z0v, zzwy, z0w   !   -      -
85      REAL(wp) ::   zdt, zalpha          !   -      -
86      REAL(wp), POINTER, DIMENSION(:,:,:) ::   zslpx, zslpy   ! 3D workspace
87      REAL(wp), POINTER, DIMENSION(:,:,:) ::   zwx  , zwy     ! -      -
88      !!----------------------------------------------------------------------
89      !
90      IF( nn_timing == 1 )  CALL timing_start('tra_adv_mus')
91      !
92      CALL wrk_alloc( jpi,jpj,jpk,   zslpx, zslpy, zwx, zwy )
93      !
94      IF( kt == kit000 )  THEN
95         IF(lwp) WRITE(numout,*)
96         IF(lwp) WRITE(numout,*) 'tra_adv : MUSCL advection scheme on ', cdtype
97         IF(lwp) WRITE(numout,*) '        : mixed up-stream           ', ld_msc_ups
98         IF(lwp) WRITE(numout,*) '~~~~~~~'
99         IF(lwp) WRITE(numout,*)
100         !
101         ! Upstream / MUSCL scheme indicator
102         !
103         ALLOCATE( xind(jpi,jpj,jpk), STAT=ierr )
104         xind(:,:,:) = 1._wp              ! set equal to 1 where up-stream is not needed
105         !
106         IF( ld_msc_ups ) THEN            ! define the upstream indicator (if asked)
107            ALLOCATE( upsmsk(jpi,jpj), STAT=ierr )
108            upsmsk(:,:) = 0._wp                             ! not upstream by default
109            !
110            DO jk = 1, jpkm1
111               xind(:,:,jk) = 1._wp                              &                 ! =>1 where up-stream is not needed
112                  &         - MAX ( rnfmsk(:,:) * rnfmsk_z(jk),  &                 ! =>0 near runoff mouths (& closed sea outflows)
113                  &                 upsmsk(:,:)                ) * tmask(:,:,jk)   ! =>0 in some user defined area
114            END DO
115         ENDIF 
116         !
117      ENDIF 
118      !     
119      DO jn = 1, kjpt            !==  loop over the tracers  ==!
120         !
121         !                          !* Horizontal advective fluxes
122         !
123         !                                !-- first guess of the slopes
124         zwx(:,:,jpk) = 0.e0                    ! bottom values
125         zwy(:,:,jpk) = 0._wp 
126         DO jk = 1, jpkm1                       ! interior values
127            DO jj = 1, jpjm1     
128               DO ji = 1, fs_jpim1   ! vector opt.
129                  zwx(ji,jj,jk) = umask(ji,jj,jk) * ( ptb(ji+1,jj,jk,jn) - ptb(ji,jj,jk,jn) )
130                  zwy(ji,jj,jk) = vmask(ji,jj,jk) * ( ptb(ji,jj+1,jk,jn) - ptb(ji,jj,jk,jn) )
131               END DO
132           END DO
133         END DO
134         CALL lbc_lnk( zwx, 'U', -1. )          ! lateral boundary conditions   (changed sign)
135         CALL lbc_lnk( zwy, 'V', -1. )
136         !                                !-- Slopes of tracer
137         zslpx(:,:,jpk) = 0._wp                  ! bottom values
138         zslpy(:,:,jpk) = 0._wp
139         DO jk = 1, jpkm1                        ! interior values
140            DO jj = 2, jpj
141               DO ji = fs_2, jpi   ! vector opt.
142                  zslpx(ji,jj,jk) =                    ( zwx(ji,jj,jk) + zwx(ji-1,jj  ,jk) )   &
143                     &            * ( 0.25 + SIGN( 0.25, zwx(ji,jj,jk) * zwx(ji-1,jj  ,jk) ) )
144                  zslpy(ji,jj,jk) =                    ( zwy(ji,jj,jk) + zwy(ji  ,jj-1,jk) )   &
145                     &            * ( 0.25 + SIGN( 0.25, zwy(ji,jj,jk) * zwy(ji  ,jj-1,jk) ) )
146               END DO
147            END DO
148         END DO
149         !
150         DO jk = 1, jpkm1                 !-- Slopes limitation
151            DO jj = 2, jpj
152               DO ji = fs_2, jpi   ! vector opt.
153                  zslpx(ji,jj,jk) = SIGN( 1., zslpx(ji,jj,jk) ) * MIN(    ABS( zslpx(ji  ,jj,jk) ),   &
154                     &                                                 2.*ABS( zwx  (ji-1,jj,jk) ),   &
155                     &                                                 2.*ABS( zwx  (ji  ,jj,jk) ) )
156                  zslpy(ji,jj,jk) = SIGN( 1., zslpy(ji,jj,jk) ) * MIN(    ABS( zslpy(ji,jj  ,jk) ),   &
157                     &                                                 2.*ABS( zwy  (ji,jj-1,jk) ),   &
158                     &                                                 2.*ABS( zwy  (ji,jj  ,jk) ) )
159               END DO
160           END DO
161         END DO
162         !
163         DO jk = 1, jpkm1                 !-- MUSCL horizontal advective fluxes
164            zdt  = p2dt(jk)
165            DO jj = 2, jpjm1
166               DO ji = fs_2, fs_jpim1   ! vector opt.
167                  ! MUSCL fluxes
168                  z0u = SIGN( 0.5, pun(ji,jj,jk) )
169                  zalpha = 0.5 - z0u
170                  zu  = z0u - 0.5 * pun(ji,jj,jk) * zdt / ( e1e2u(ji,jj) * e3u_n(ji,jj,jk) )
171                  zzwx = ptb(ji+1,jj,jk,jn) + xind(ji,jj,jk) * zu * zslpx(ji+1,jj,jk)
172                  zzwy = ptb(ji  ,jj,jk,jn) + xind(ji,jj,jk) * zu * zslpx(ji  ,jj,jk)
173                  zwx(ji,jj,jk) = pun(ji,jj,jk) * ( zalpha * zzwx + (1.-zalpha) * zzwy )
174                  !
175                  z0v = SIGN( 0.5, pvn(ji,jj,jk) )
176                  zalpha = 0.5 - z0v
177                  zv  = z0v - 0.5 * pvn(ji,jj,jk) * zdt / ( e1e2v(ji,jj) * e3v_n(ji,jj,jk) )
178                  zzwx = ptb(ji,jj+1,jk,jn) + xind(ji,jj,jk) * zv * zslpy(ji,jj+1,jk)
179                  zzwy = ptb(ji,jj  ,jk,jn) + xind(ji,jj,jk) * zv * zslpy(ji,jj  ,jk)
180                  zwy(ji,jj,jk) = pvn(ji,jj,jk) * ( zalpha * zzwx + (1.-zalpha) * zzwy )
181               END DO
182            END DO
183         END DO
184         CALL lbc_lnk( zwx, 'U', -1. )   ;   CALL lbc_lnk( zwy, 'V', -1. )   ! lateral boundary conditions   (changed sign)
185         !
186         DO jk = 1, jpkm1                 !-- Tracer advective trend
187            DO jj = 2, jpjm1     
188               DO ji = fs_2, fs_jpim1   ! vector opt.
189                  pta(ji,jj,jk,jn) = pta(ji,jj,jk,jn) - ( zwx(ji,jj,jk) - zwx(ji-1,jj  ,jk  )       &
190                  &                                     + zwy(ji,jj,jk) - zwy(ji  ,jj-1,jk  ) )     &
191                  &                                   / ( e1e2t(ji,jj) * e3t_n(ji,jj,jk) )
192               END DO
193           END DO
194         END DO       
195         !                                ! trend diagnostics
196         IF( ( cdtype == 'TRA' .AND. l_trdtra ) .OR.   &
197            &( cdtype == 'TRC' .AND. l_trdtrc )      )  THEN
198            CALL trd_tra( kt, cdtype, jn, jptra_xad, zwx, pun, ptb(:,:,:,jn) )
199            CALL trd_tra( kt, cdtype, jn, jptra_yad, zwy, pvn, ptb(:,:,:,jn) )
200         END IF
201         !                                ! "Poleward" heat and salt transports
202         IF( cdtype == 'TRA' .AND. ln_diaptr ) THEN 
203            IF( jn == jp_tem )  htr_adv(:) = ptr_sj( zwy(:,:,:) )
204            IF( jn == jp_sal )  str_adv(:) = ptr_sj( zwy(:,:,:) )
205         ENDIF
206         !
207         !                          !* Vertical advective fluxes
208         !
209         !                                !-- first guess of the slopes
210         zwx(:,:, 1 ) = 0._wp                   ! surface & bottom boundary conditions
211         zwx(:,:,jpk) = 0._wp
212         DO jk = 2, jpkm1                       ! interior values
213            zwx(:,:,jk) = tmask(:,:,jk) * ( ptb(:,:,jk-1,jn) - ptb(:,:,jk,jn) )
214         END DO
215         !                                !-- Slopes of tracer
216         zslpx(:,:,1) = 0._wp                   ! surface values
217         DO jk = 2, jpkm1                       ! interior value
218            DO jj = 1, jpj
219               DO ji = 1, jpi
220                  zslpx(ji,jj,jk) =                     ( zwx(ji,jj,jk) + zwx(ji,jj,jk+1) )  &
221                     &            * (  0.25 + SIGN( 0.25, zwx(ji,jj,jk) * zwx(ji,jj,jk+1) )  )
222               END DO
223            END DO
224         END DO
225         DO jk = 2, jpkm1                 !-- Slopes limitation
226            DO jj = 1, jpj                      ! interior values
227               DO ji = 1, jpi
228                  zslpx(ji,jj,jk) = SIGN( 1., zslpx(ji,jj,jk) ) * MIN(    ABS( zslpx(ji,jj,jk  ) ),   &
229                     &                                                 2.*ABS( zwx  (ji,jj,jk+1) ),   &
230                     &                                                 2.*ABS( zwx  (ji,jj,jk  ) )  )
231               END DO
232            END DO
233         END DO
234         DO jk = 1, jpk-2                 !-- vertical advective flux
235            zdt  = p2dt(jk)
236            DO jj = 2, jpjm1     
237               DO ji = fs_2, fs_jpim1   ! vector opt.
238                  z0w = SIGN( 0.5, pwn(ji,jj,jk+1) )
239                  zalpha = 0.5 + z0w
240                  zw  = z0w - 0.5 * pwn(ji,jj,jk+1) * zdt * r1_e1e2t(ji,jj) / e3w_n(ji,jj,jk+1)
241                  zzwx = ptb(ji,jj,jk+1,jn) + xind(ji,jj,jk) * zw * zslpx(ji,jj,jk+1)
242                  zzwy = ptb(ji,jj,jk  ,jn) + xind(ji,jj,jk) * zw * zslpx(ji,jj,jk  )
243                  zwx(ji,jj,jk+1) = pwn(ji,jj,jk+1) * ( zalpha * zzwx + (1.-zalpha) * zzwy ) * wmask(ji,jj,jk)
244               END DO
245            END DO
246         END DO
247         IF( ln_linssh ) THEN                   ! top values, linear free surface only
248            IF( ln_isfcav ) THEN                      ! ice-shelf cavities (top of the ocean)
249               DO jj = 1, jpj
250                  DO ji = 1, jpi
251                     zwx(ji,jj, mikt(ji,jj) ) = pwn(ji,jj,mikt(ji,jj)) * ptb(ji,jj,mikt(ji,jj),jn)
252                  END DO
253               END DO   
254            ELSE                                      ! no cavities: only at the ocean surface
255               zwx(:,:,1) = pwn(:,:,1) * ptb(:,:,1,jn)
256            ENDIF
257         ENDIF
258         !
259         DO jk = 1, jpkm1                 !-- vertical advective trend
260            DO jj = 2, jpjm1     
261               DO ji = fs_2, fs_jpim1   ! vector opt.
262                  pta(ji,jj,jk,jn) =  pta(ji,jj,jk,jn) - ( zwx(ji,jj,jk) - zwx(ji,jj,jk+1) ) * r1_e1e2t(ji,jj) / e3t_n(ji,jj,jk)
263               END DO
264            END DO
265         END DO
266         !                                ! send trends for diagnostic
267         IF( ( cdtype == 'TRA' .AND. l_trdtra ) .OR.     &
268            &( cdtype == 'TRC' .AND. l_trdtrc )      )   &
269            CALL trd_tra( kt, cdtype, jn, jptra_zad, zwx, pwn, ptb(:,:,:,jn) )
270         !
271      END DO                     ! end of tracer loop
272      !
273      CALL wrk_dealloc( jpi,jpj,jpk,   zslpx, zslpy, zwx, zwy )
274      !
275      IF( nn_timing == 1 )  CALL timing_stop('tra_adv_mus')
276      !
277   END SUBROUTINE tra_adv_mus
278
279   !!======================================================================
280END MODULE traadv_mus
Note: See TracBrowser for help on using the repository browser.