New URL for NEMO forge!   http://forge.nemo-ocean.eu

Since March 2022 along with NEMO 4.2 release, the code development moved to a self-hosted GitLab.
This present forge is now archived and remained online for history.
traldf_iso.F90 in branches/2015/dev_r5836_NOC3_vvl_by_default/NEMOGCM/NEMO/OPA_SRC/TRA – NEMO

source: branches/2015/dev_r5836_NOC3_vvl_by_default/NEMOGCM/NEMO/OPA_SRC/TRA/traldf_iso.F90 @ 5845

Last change on this file since 5845 was 5845, checked in by gm, 8 years ago

#1613: vvl by default: suppression of domzgr_substitute.h90

  • Property svn:keywords set to Id
File size: 23.5 KB
Line 
1MODULE traldf_iso
2   !!======================================================================
3   !!                   ***  MODULE  traldf_iso  ***
4   !! Ocean  tracers:  horizontal component of the lateral tracer mixing trend
5   !!======================================================================
6   !! History :  OPA  ! 1994-08  (G. Madec, M. Imbard)
7   !!            8.0  ! 1997-05  (G. Madec)  split into traldf and trazdf
8   !!            NEMO ! 2002-08  (G. Madec)  Free form, F90
9   !!            1.0  ! 2005-11  (G. Madec)  merge traldf and trazdf :-)
10   !!            3.3  ! 2010-09  (C. Ethe, G. Madec) Merge TRA-TRC
11   !!            3.7  ! 2014-01  (G. Madec, S. Masson)  restructuration/simplification of aht/aeiv specification
12   !!             -   ! 2014-02  (F. Lemarie, G. Madec)  triad operator (Griffies) + Method of Stabilizing Correction
13   !!----------------------------------------------------------------------
14
15   !!----------------------------------------------------------------------
16   !!   tra_ldf_iso  : update the tracer trend with the horizontal component of a iso-neutral laplacian operator
17   !!                  and with the vertical part of the isopycnal or geopotential s-coord. operator
18   !!----------------------------------------------------------------------
19   USE oce             ! ocean dynamics and active tracers
20   USE dom_oce         ! ocean space and time domain
21   USE trc_oce         ! share passive tracers/Ocean variables
22   USE zdf_oce         ! ocean vertical physics
23   USE ldftra          ! lateral diffusion: tracer eddy coefficients
24   USE ldfslp          ! iso-neutral slopes
25   USE diaptr          ! poleward transport diagnostics
26   !
27   USE in_out_manager  ! I/O manager
28   USE iom             ! I/O library
29   USE phycst          ! physical constants
30   USE lbclnk          ! ocean lateral boundary conditions (or mpp link)
31   USE wrk_nemo        ! Memory Allocation
32   USE timing          ! Timing
33
34   IMPLICIT NONE
35   PRIVATE
36
37   PUBLIC   tra_ldf_iso   ! routine called by step.F90
38
39   !! * Substitutions
40#  include "vectopt_loop_substitute.h90"
41   !!----------------------------------------------------------------------
42   !! NEMO/OPA 3.7 , NEMO Consortium (2015)
43   !! $Id$
44   !! Software governed by the CeCILL licence     (NEMOGCM/NEMO_CeCILL.txt)
45   !!----------------------------------------------------------------------
46CONTAINS
47
48  SUBROUTINE tra_ldf_iso( kt, kit000, cdtype, pahu, pahv, pgu , pgv ,   &
49      &                                                   pgui, pgvi,   &
50      &                                       ptb , ptbb, pta , kjpt, kpass )
51      !!----------------------------------------------------------------------
52      !!                  ***  ROUTINE tra_ldf_iso  ***
53      !!
54      !! ** Purpose :   Compute the before horizontal tracer (t & s) diffusive
55      !!      trend for a laplacian tensor (ezxcept the dz[ dz[.] ] term) and
56      !!      add it to the general trend of tracer equation.
57      !!
58      !! ** Method  :   The horizontal component of the lateral diffusive trends
59      !!      is provided by a 2nd order operator rotated along neural or geopo-
60      !!      tential surfaces to which an eddy induced advection can be added
61      !!      It is computed using before fields (forward in time) and isopyc-
62      !!      nal or geopotential slopes computed in routine ldfslp.
63      !!
64      !!      1st part :  masked horizontal derivative of T  ( di[ t ] )
65      !!      ========    with partial cell update if ln_zps=T
66      !!                  with top     cell update if ln_isfcav
67      !!
68      !!      2nd part :  horizontal fluxes of the lateral mixing operator
69      !!      ========   
70      !!         zftu =  pahu e2u*e3u/e1u di[ tb ]
71      !!               - pahu e2u*uslp    dk[ mi(mk(tb)) ]
72      !!         zftv =  pahv e1v*e3v/e2v dj[ tb ]
73      !!               - pahv e2u*vslp    dk[ mj(mk(tb)) ]
74      !!      take the horizontal divergence of the fluxes:
75      !!         difft = 1/(e1e2t*e3t) {  di-1[ zftu ] +  dj-1[ zftv ]  }
76      !!      Add this trend to the general trend (ta,sa):
77      !!         ta = ta + difft
78      !!
79      !!      3rd part: vertical trends of the lateral mixing operator
80      !!      ========  (excluding the vertical flux proportional to dk[t] )
81      !!      vertical fluxes associated with the rotated lateral mixing:
82      !!         zftw = - {  mi(mk(pahu)) * e2t*wslpi di[ mi(mk(tb)) ]
83      !!                   + mj(mk(pahv)) * e1t*wslpj dj[ mj(mk(tb)) ]  }
84      !!      take the horizontal divergence of the fluxes:
85      !!         difft = 1/(e1e2t*e3t) dk[ zftw ]
86      !!      Add this trend to the general trend (ta,sa):
87      !!         pta = pta + difft
88      !!
89      !! ** Action :   Update pta arrays with the before rotated diffusion
90      !!----------------------------------------------------------------------
91      INTEGER                              , INTENT(in   ) ::   kt         ! ocean time-step index
92      INTEGER                              , INTENT(in   ) ::   kit000     ! first time step index
93      CHARACTER(len=3)                     , INTENT(in   ) ::   cdtype     ! =TRA or TRC (tracer indicator)
94      INTEGER                              , INTENT(in   ) ::   kjpt       ! number of tracers
95      INTEGER                              , INTENT(in   ) ::   kpass      ! =1/2 first or second passage
96      REAL(wp), DIMENSION(jpi,jpj,jpk)     , INTENT(in   ) ::   pahu, pahv ! eddy diffusivity at u- and v-points  [m2/s]
97      REAL(wp), DIMENSION(jpi,jpj    ,kjpt), INTENT(in   ) ::   pgu, pgv   ! tracer gradient at pstep levels
98      REAL(wp), DIMENSION(jpi,jpj,    kjpt), INTENT(in   ) ::   pgui, pgvi ! tracer gradient at top   levels
99      REAL(wp), DIMENSION(jpi,jpj,jpk,kjpt), INTENT(in   ) ::   ptb        ! tracer (kpass=1) or laplacian of tracer (kpass=2)
100      REAL(wp), DIMENSION(jpi,jpj,jpk,kjpt), INTENT(in   ) ::   ptbb       ! tracer (only used in kpass=2)
101      REAL(wp), DIMENSION(jpi,jpj,jpk,kjpt), INTENT(inout) ::   pta        ! tracer trend
102      !
103      INTEGER  ::  ji, jj, jk, jn   ! dummy loop indices
104      INTEGER  ::  ierr             ! local integer
105      REAL(wp) ::  zmsku, zahu_w, zabe1, zcof1, zcoef3   ! local scalars
106      REAL(wp) ::  zmskv, zahv_w, zabe2, zcof2, zcoef4   !   -      -
107      REAL(wp) ::  zcoef0, ze3w_2, zsign, z2dt, z1_2dt   !   -      -
108#if defined key_diaar5
109      REAL(wp) ::   zztmp   ! local scalar
110#endif
111      REAL(wp), POINTER, DIMENSION(:,:)   ::   zdkt, zdk1t, z2d
112      REAL(wp), POINTER, DIMENSION(:,:,:) ::   zdit, zdjt, zftu, zftv, ztfw 
113      !!----------------------------------------------------------------------
114      !
115      IF( nn_timing == 1 )  CALL timing_start('tra_ldf_iso')
116      !
117      CALL wrk_alloc( jpi,jpj,       zdkt, zdk1t, z2d ) 
118      CALL wrk_alloc( jpi,jpj,jpk,   zdit, zdjt , zftu, zftv, ztfw  ) 
119      !
120      IF( kt == kit000 )  THEN
121         IF(lwp) WRITE(numout,*)
122         IF(lwp) WRITE(numout,*) 'tra_ldf_iso : rotated laplacian diffusion operator on ', cdtype
123         IF(lwp) WRITE(numout,*) '~~~~~~~~~~~'
124         !
125         akz     (:,:,:) = 0._wp     
126         ah_wslp2(:,:,:) = 0._wp
127      ENDIF
128      !
129      !                                               ! set time step size (Euler/Leapfrog)
130      IF( neuler == 0 .AND. kt == nit000 ) THEN   ;   z2dt =     rdttra(1)      ! at nit000   (Euler)
131      ELSE                                        ;   z2dt = 2.* rdttra(1)      !             (Leapfrog)
132      ENDIF
133      z1_2dt = 1._wp / z2dt
134      !
135      IF( kpass == 1 ) THEN   ;   zsign =  1._wp      ! bilaplacian operator require a minus sign (eddy diffusivity >0)
136      ELSE                    ;   zsign = -1._wp
137      ENDIF
138         
139         
140      !!----------------------------------------------------------------------
141      !!   0 - calculate  ah_wslp2 and akz
142      !!----------------------------------------------------------------------
143      !
144      IF( kpass == 1 ) THEN                  !==  first pass only  ==!
145         !
146         DO jk = 2, jpkm1
147            DO jj = 2, jpjm1
148               DO ji = fs_2, fs_jpim1   ! vector opt.
149                  !
150                  zmsku = tmask(ji,jj,jk) / MAX(   umask(ji  ,jj,jk-1) + umask(ji-1,jj,jk)          &
151                     &                           + umask(ji-1,jj,jk-1) + umask(ji  ,jj,jk) , 1._wp  )
152                  zmskv = tmask(ji,jj,jk) / MAX(   vmask(ji,jj  ,jk-1) + vmask(ji,jj-1,jk)          &
153                     &                           + vmask(ji,jj-1,jk-1) + vmask(ji,jj  ,jk) , 1._wp  )
154                     !
155                  zahu_w = (   pahu(ji  ,jj,jk-1) + pahu(ji-1,jj,jk)    &
156                     &       + pahu(ji-1,jj,jk-1) + pahu(ji  ,jj,jk)  ) * zmsku
157                  zahv_w = (   pahv(ji,jj  ,jk-1) + pahv(ji,jj-1,jk)    &
158                     &       + pahv(ji,jj-1,jk-1) + pahv(ji,jj  ,jk)  ) * zmskv
159                     !
160                  ah_wslp2(ji,jj,jk) = zahu_w * wslpi(ji,jj,jk) * wslpi(ji,jj,jk)   &
161                     &               + zahv_w * wslpj(ji,jj,jk) * wslpj(ji,jj,jk)
162               END DO
163            END DO
164         END DO
165         !
166         IF( ln_traldf_msc ) THEN                ! stabilizing vertical diffusivity coefficient
167            DO jk = 2, jpkm1
168               DO jj = 2, jpjm1
169                  DO ji = fs_2, fs_jpim1
170                     akz(ji,jj,jk) = 0.25_wp * (                                                                     &
171                        &              ( pahu(ji  ,jj,jk) + pahu(ji  ,jj,jk-1) ) / ( e1u(ji  ,jj) * e1u(ji  ,jj) )   &
172                        &            + ( pahu(ji-1,jj,jk) + pahu(ji-1,jj,jk-1) ) / ( e1u(ji-1,jj) * e1u(ji-1,jj) )   &
173                        &            + ( pahv(ji,jj  ,jk) + pahv(ji,jj  ,jk-1) ) / ( e2v(ji,jj  ) * e2v(ji,jj  ) )   &
174                        &            + ( pahv(ji,jj-1,jk) + pahv(ji,jj-1,jk-1) ) / ( e2v(ji,jj-1) * e2v(ji,jj-1) )   )
175                  END DO
176               END DO
177            END DO
178            !
179            IF( ln_traldf_blp ) THEN                ! bilaplacian operator
180               DO jk = 2, jpkm1
181                  DO jj = 1, jpjm1
182                     DO ji = 1, fs_jpim1
183                        akz(ji,jj,jk) = 16._wp * ah_wslp2(ji,jj,jk)   &
184                           &          * (  akz(ji,jj,jk) + ah_wslp2(ji,jj,jk) / ( e3w_n(ji,jj,jk) * e3w_n(ji,jj,jk) )  )
185                     END DO
186                  END DO
187               END DO
188            ELSEIF( ln_traldf_lap ) THEN              ! laplacian operator
189               DO jk = 2, jpkm1
190                  DO jj = 1, jpjm1
191                     DO ji = 1, fs_jpim1
192                        ze3w_2 = e3w_n(ji,jj,jk) * e3w_n(ji,jj,jk)
193                        zcoef0 = z2dt * (  akz(ji,jj,jk) + ah_wslp2(ji,jj,jk) / ze3w_2  )
194                        akz(ji,jj,jk) = MAX( zcoef0 - 0.5_wp , 0._wp ) * ze3w_2 * z1_2dt
195                     END DO
196                  END DO
197               END DO
198           ENDIF
199           !
200         ELSE                                    ! 33 flux set to zero with akz=ah_wslp2 ==>> computed in full implicit
201            akz(:,:,:) = ah_wslp2(:,:,:)     
202         ENDIF
203      ENDIF
204      !
205      !                                                          ! ===========
206      DO jn = 1, kjpt                                            ! tracer loop
207         !                                                       ! ===========
208         !                                               
209         !!----------------------------------------------------------------------
210         !!   I - masked horizontal derivative
211         !!----------------------------------------------------------------------
212!!gm : bug.... why (x,:,:)?   (1,jpj,:) and (jpi,1,:) should be sufficient....
213         zdit (1,:,:) = 0._wp     ;     zdit (jpi,:,:) = 0._wp
214         zdjt (1,:,:) = 0._wp     ;     zdjt (jpi,:,:) = 0._wp
215         !!end
216
217         ! Horizontal tracer gradient
218         DO jk = 1, jpkm1
219            DO jj = 1, jpjm1
220               DO ji = 1, fs_jpim1   ! vector opt.
221                  zdit(ji,jj,jk) = ( ptb(ji+1,jj  ,jk,jn) - ptb(ji,jj,jk,jn) ) * umask(ji,jj,jk)
222                  zdjt(ji,jj,jk) = ( ptb(ji  ,jj+1,jk,jn) - ptb(ji,jj,jk,jn) ) * vmask(ji,jj,jk)
223               END DO
224            END DO
225         END DO
226         IF( ln_zps ) THEN      ! botton and surface ocean correction of the horizontal gradient
227            DO jj = 1, jpjm1              ! bottom correction (partial bottom cell)
228               DO ji = 1, fs_jpim1   ! vector opt.
229!!gm  the following anonymous remark is to considered: ! IF useless if zpshde defines pgu everywhere
230                  zdit(ji,jj,mbku(ji,jj)) = pgu(ji,jj,jn)         
231                  zdjt(ji,jj,mbkv(ji,jj)) = pgv(ji,jj,jn)
232               END DO
233            END DO
234            IF( ln_isfcav ) THEN      ! first wet level beneath a cavity
235               DO jj = 1, jpjm1
236                  DO ji = 1, fs_jpim1   ! vector opt.
237                     IF( miku(ji,jj) > 1 )   zdit(ji,jj,miku(ji,jj)) = pgui(ji,jj,jn)         
238                     IF( mikv(ji,jj) > 1 )   zdjt(ji,jj,mikv(ji,jj)) = pgvi(ji,jj,jn)     
239                  END DO
240               END DO
241            ENDIF
242         ENDIF
243
244         !!----------------------------------------------------------------------
245         !!   II - horizontal trend  (full)
246         !!----------------------------------------------------------------------
247         !
248         DO jk = 1, jpkm1                                 ! Horizontal slab
249            !
250            !                             !== Vertical tracer gradient
251            zdk1t(:,:) = ( ptb(:,:,jk,jn) - ptb(:,:,jk+1,jn) ) * wmask(:,:,jk+1)     ! level jk+1
252            !
253            IF( jk == 1 ) THEN   ;   zdkt(:,:) = zdk1t(:,:)                          ! surface: zdkt(jk=1)=zdkt(jk=2)
254            ELSE                 ;   zdkt(:,:) = ( ptb(:,:,jk-1,jn) - ptb(:,:,jk,jn) ) * wmask(:,:,jk)
255            ENDIF
256!!gm I don't understand why we should need this.... since wmask is used instead of tmask
257!         IF ( ln_isfcav ) THEN
258!            DO jj = 1, jpj
259!               DO ji = 1, jpi   ! vector opt.
260!                  ikt = mikt(ji,jj) ! surface level
261!                  zdk1t(ji,jj,ikt) = ( ptb(ji,jj,ikt,jn  ) - ptb(ji,jj,ikt+1,jn) ) * wmask(ji,jj,ikt+1)
262!                  zdkt (ji,jj,ikt) = zdk1t(ji,jj,ikt)
263!               END DO
264!            END DO
265!         END IF
266!!gm
267
268            DO jj = 1 , jpjm1            !==  Horizontal fluxes
269               DO ji = 1, fs_jpim1   ! vector opt.
270                  zabe1 = pahu(ji,jj,jk) * e2_e1u(ji,jj) * e3u_n(ji,jj,jk)
271                  zabe2 = pahv(ji,jj,jk) * e1_e2v(ji,jj) * e3v_n(ji,jj,jk)
272                  !
273                  zmsku = 1. / MAX(  tmask(ji+1,jj,jk  ) + tmask(ji,jj,jk+1)   &
274                     &             + tmask(ji+1,jj,jk+1) + tmask(ji,jj,jk  ), 1. )
275                  !
276                  zmskv = 1. / MAX(  tmask(ji,jj+1,jk  ) + tmask(ji,jj,jk+1)   &
277                     &             + tmask(ji,jj+1,jk+1) + tmask(ji,jj,jk  ), 1. )
278                  !
279                  zcof1 = - pahu(ji,jj,jk) * e2u(ji,jj) * uslp(ji,jj,jk) * zmsku
280                  zcof2 = - pahv(ji,jj,jk) * e1v(ji,jj) * vslp(ji,jj,jk) * zmskv
281                  !
282                  zftu(ji,jj,jk ) = (  zabe1 * zdit(ji,jj,jk)   &
283                     &               + zcof1 * (  zdkt (ji+1,jj) + zdk1t(ji,jj)      &
284                     &                          + zdk1t(ji+1,jj) + zdkt (ji,jj)  )  ) * umask(ji,jj,jk)
285                  zftv(ji,jj,jk) = (  zabe2 * zdjt(ji,jj,jk)   &
286                     &               + zcof2 * (  zdkt (ji,jj+1) + zdk1t(ji,jj)      &
287                     &                          + zdk1t(ji,jj+1) + zdkt (ji,jj)  )  ) * vmask(ji,jj,jk)                 
288               END DO
289            END DO
290            !
291            DO jj = 2 , jpjm1          !== horizontal divergence and add to pta
292               DO ji = fs_2, fs_jpim1   ! vector opt.
293                  pta(ji,jj,jk,jn) = pta(ji,jj,jk,jn) + zsign * (  zftu(ji,jj,jk) - zftu(ji-1,jj,jk)      &
294                     &                                           + zftv(ji,jj,jk) - zftv(ji,jj-1,jk)  )   &
295                     &                                        / (  e1e2t(ji,jj) * e3t_n(ji,jj,jk)  )
296               END DO
297            END DO
298         END DO                                        !   End of slab 
299
300
301         !!----------------------------------------------------------------------
302         !!   III - vertical trend (full)
303         !!----------------------------------------------------------------------
304         
305         ztfw(1,:,:) = 0._wp     ;     ztfw(jpi,:,:) = 0._wp
306         
307         ! Vertical fluxes
308         ! ---------------
309         
310         ! Surface and bottom vertical fluxes set to zero
311         ztfw(:,:, 1 ) = 0._wp      ;      ztfw(:,:,jpk) = 0._wp
312         
313         ! interior (2=<jk=<jpk-1)
314         DO jk = 2, jpkm1
315            DO jj = 2, jpjm1
316               DO ji = fs_2, fs_jpim1   ! vector opt.
317                  !
318                  zmsku = tmask(ji,jj,jk) / MAX(   umask(ji  ,jj,jk-1) + umask(ji-1,jj,jk)          &
319                     &                           + umask(ji-1,jj,jk-1) + umask(ji  ,jj,jk) , 1._wp  )
320                  zmskv = tmask(ji,jj,jk) / MAX(   vmask(ji,jj  ,jk-1) + vmask(ji,jj-1,jk)          &
321                     &                           + vmask(ji,jj-1,jk-1) + vmask(ji,jj  ,jk) , 1._wp  )
322                     !
323                  zahu_w = (   pahu(ji  ,jj,jk-1) + pahu(ji-1,jj,jk)    &
324                     &       + pahu(ji-1,jj,jk-1) + pahu(ji  ,jj,jk)  ) * zmsku
325                  zahv_w = (   pahv(ji,jj  ,jk-1) + pahv(ji,jj-1,jk)    &
326                     &       + pahv(ji,jj-1,jk-1) + pahv(ji,jj  ,jk)  ) * zmskv
327                     !
328                  zcoef3 = - zahu_w * e2t(ji,jj) * zmsku * wslpi (ji,jj,jk)   !wslpi & j are already w-masked
329                  zcoef4 = - zahv_w * e1t(ji,jj) * zmskv * wslpj (ji,jj,jk)
330                  !
331                  ztfw(ji,jj,jk) = zcoef3 * (   zdit(ji  ,jj  ,jk-1) + zdit(ji-1,jj  ,jk)      &
332                     &                        + zdit(ji-1,jj  ,jk-1) + zdit(ji  ,jj  ,jk)  )   &
333                     &           + zcoef4 * (   zdjt(ji  ,jj  ,jk-1) + zdjt(ji  ,jj-1,jk)      &
334                     &                        + zdjt(ji  ,jj-1,jk-1) + zdjt(ji  ,jj  ,jk)  )
335               END DO
336            END DO
337         END DO
338         !
339         !                                !==  add the vertical 33 flux  ==!
340         IF( ln_traldf_lap ) THEN               ! laplacian case: eddy coef = ah_wslp2 - akz
341            DO jk = 2, jpkm1       
342               DO jj = 1, jpjm1
343                  DO ji = fs_2, fs_jpim1
344                     ztfw(ji,jj,jk) = ztfw(ji,jj,jk) + e1e2t(ji,jj) / e3w_n(ji,jj,jk) * tmask(ji,jj,jk)   &
345                        &                            * ( ah_wslp2(ji,jj,jk) - akz(ji,jj,jk) )             &
346                        &                            * ( ptb(ji,jj,jk-1,jn) - ptb(ji,jj,jk,jn) )
347                  END DO
348               END DO
349            END DO
350            !
351         ELSE                                   ! bilaplacian
352            SELECT CASE( kpass )
353            CASE(  1  )                            ! 1st pass : eddy coef = ah_wslp2
354               DO jk = 2, jpkm1 
355                  DO jj = 1, jpjm1
356                     DO ji = fs_2, fs_jpim1
357                        ztfw(ji,jj,jk) = ztfw(ji,jj,jk)    &
358                           &           + ah_wslp2(ji,jj,jk) * e1e2t(ji,jj)   &
359                           &           * ( ptb(ji,jj,jk-1,jn) - ptb(ji,jj,jk,jn) ) * tmask(ji,jj,jk) / e3w_n(ji,jj,jk)
360                     END DO
361                  END DO
362               END DO
363            CASE(  2  )                         ! 2nd pass : eddy flux = ah_wslp2 and akz applied on ptb  and ptbb gradients, resp.
364               DO jk = 2, jpkm1 
365                  DO jj = 1, jpjm1
366                     DO ji = fs_2, fs_jpim1
367                        ztfw(ji,jj,jk) = ztfw(ji,jj,jk) + e1e2t(ji,jj) / e3w_n(ji,jj,jk) * tmask(ji,jj,jk)                      &
368                           &                            * (  ah_wslp2(ji,jj,jk) * ( ptb (ji,jj,jk-1,jn) - ptb (ji,jj,jk,jn) )   &
369                           &                               + akz     (ji,jj,jk) * ( ptbb(ji,jj,jk-1,jn) - ptbb(ji,jj,jk,jn) )   )
370                     END DO
371                  END DO
372               END DO
373            END SELECT
374         ENDIF
375         !         
376         DO jk = 1, jpkm1                 !==  Divergence of vertical fluxes added to pta  ==!
377            DO jj = 2, jpjm1
378               DO ji = fs_2, fs_jpim1   ! vector opt.
379                  pta(ji,jj,jk,jn) = pta(ji,jj,jk,jn) + zsign * (  ztfw (ji,jj,jk) - ztfw(ji,jj,jk+1)  )   &
380                     &                                        / (  e1e2t(ji,jj) * e3t_n(ji,jj,jk)  )
381               END DO
382            END DO
383         END DO
384         !
385         IF( ( kpass == 1 .AND. ln_traldf_lap ) .OR.  &     !==  first pass only (  laplacian)  ==!
386             ( kpass == 2 .AND. ln_traldf_blp ) ) THEN      !==  2nd   pass      (bilaplacian)  ==!
387            !
388            !                             ! "Poleward" diffusive heat or salt transports (T-S case only)
389            IF( cdtype == 'TRA' .AND. ln_diaptr ) THEN
390               ! note sign is reversed to give down-gradient diffusive transports (#1043)
391               IF( jn == jp_tem)   htr_ldf(:) = ptr_sj( -zftv(:,:,:) )
392               IF( jn == jp_sal)   str_ldf(:) = ptr_sj( -zftv(:,:,:) )
393            ENDIF
394            !
395            IF( iom_use("udiff_heattr") .OR. iom_use("vdiff_heattr") ) THEN
396              !
397              IF( cdtype == 'TRA' .AND. jn == jp_tem  ) THEN
398                  z2d(:,:) = zftu(ji,jj,1) 
399                  DO jk = 2, jpkm1
400                     DO jj = 2, jpjm1
401                        DO ji = fs_2, fs_jpim1   ! vector opt.
402                           z2d(ji,jj) = z2d(ji,jj) + zftu(ji,jj,jk) 
403                        END DO
404                     END DO
405                  END DO
406!!gm CAUTION I think there is an error of sign when using BLP operator....
407!!gm         a multiplication by zsign is required (to be checked twice !)
408                  z2d(:,:) = - rau0_rcp * z2d(:,:)     ! note sign is reversed to give down-gradient diffusive transports (#1043)
409                  CALL lbc_lnk( z2d, 'U', -1. )
410                  CALL iom_put( "udiff_heattr", z2d )                  ! heat transport in i-direction
411                  !
412                  z2d(:,:) = zftv(ji,jj,1) 
413                  DO jk = 2, jpkm1
414                     DO jj = 2, jpjm1
415                        DO ji = fs_2, fs_jpim1   ! vector opt.
416                           z2d(ji,jj) = z2d(ji,jj) + zftv(ji,jj,jk) 
417                        END DO
418                     END DO
419                  END DO
420                  z2d(:,:) = - rau0_rcp * z2d(:,:)     ! note sign is reversed to give down-gradient diffusive transports (#1043)
421                  CALL lbc_lnk( z2d, 'V', -1. )
422                  CALL iom_put( "vdiff_heattr", z2d )                  !  heat transport in i-direction
423               END IF
424               !
425            ENDIF
426            !
427         ENDIF                                                    !== end pass selection  ==!
428         !
429         !                                                        ! ===============
430      END DO                                                      ! end tracer loop
431      !                                                           ! ===============
432      !
433      CALL wrk_dealloc( jpi, jpj,      zdkt, zdk1t, z2d ) 
434      CALL wrk_dealloc( jpi, jpj, jpk, zdit, zdjt , zftu, zftv, ztfw  ) 
435      !
436      IF( nn_timing == 1 )  CALL timing_stop('tra_ldf_iso')
437      !
438   END SUBROUTINE tra_ldf_iso
439
440   !!==============================================================================
441END MODULE traldf_iso
Note: See TracBrowser for help on using the repository browser.