New URL for NEMO forge!   http://forge.nemo-ocean.eu

Since March 2022 along with NEMO 4.2 release, the code development moved to a self-hosted GitLab.
This present forge is now archived and remained online for history.
traldf_iso.F90 in branches/2015/dev_r5836_NOC3_vvl_by_default/NEMOGCM/NEMO/OPA_SRC/TRA – NEMO

source: branches/2015/dev_r5836_NOC3_vvl_by_default/NEMOGCM/NEMO/OPA_SRC/TRA/traldf_iso.F90 @ 5883

Last change on this file since 5883 was 5883, checked in by gm, 8 years ago

#1613: vvl by default: TRA/TRC remove optimization associated with linear free surface
  • Property svn:keywords set to Id
File size: 23.5 KB
Line 
1MODULE traldf_iso
2   !!======================================================================
3   !!                   ***  MODULE  traldf_iso  ***
4   !! Ocean  tracers:  horizontal component of the lateral tracer mixing trend
5   !!======================================================================
6   !! History :  OPA  ! 1994-08  (G. Madec, M. Imbard)
7   !!            8.0  ! 1997-05  (G. Madec)  split into traldf and trazdf
8   !!            NEMO ! 2002-08  (G. Madec)  Free form, F90
9   !!            1.0  ! 2005-11  (G. Madec)  merge traldf and trazdf :-)
10   !!            3.3  ! 2010-09  (C. Ethe, G. Madec) Merge TRA-TRC
11   !!            3.7  ! 2014-01  (G. Madec, S. Masson)  restructuration/simplification of aht/aeiv specification
12   !!             -   ! 2014-02  (F. Lemarie, G. Madec)  triad operator (Griffies) + Method of Stabilizing Correction
13   !!----------------------------------------------------------------------
14
15   !!----------------------------------------------------------------------
16   !!   tra_ldf_iso   : update the tracer trend with the horizontal component of a iso-neutral laplacian operator
17   !!                   and with the vertical part of the isopycnal or geopotential s-coord. operator
18   !!----------------------------------------------------------------------
19   USE oce            ! ocean dynamics and active tracers
20   USE dom_oce        ! ocean space and time domain
21   USE trc_oce        ! share passive tracers/Ocean variables
22   USE zdf_oce        ! ocean vertical physics
23   USE ldftra         ! lateral diffusion: tracer eddy coefficients
24   USE ldfslp         ! iso-neutral slopes
25   USE diaptr         ! poleward transport diagnostics
26   !
27   USE in_out_manager ! I/O manager
28   USE iom            ! I/O library
29   USE phycst         ! physical constants
30   USE lbclnk         ! ocean lateral boundary conditions (or mpp link)
31   USE wrk_nemo       ! Memory Allocation
32   USE timing         ! Timing
33
34   IMPLICIT NONE
35   PRIVATE
36
37   PUBLIC   tra_ldf_iso   ! routine called by step.F90
38
39   !! * Substitutions
40#  include "vectopt_loop_substitute.h90"
41   !!----------------------------------------------------------------------
42   !! NEMO/OPA 3.7 , NEMO Consortium (2015)
43   !! $Id$
44   !! Software governed by the CeCILL licence     (NEMOGCM/NEMO_CeCILL.txt)
45   !!----------------------------------------------------------------------
46CONTAINS
47
48  SUBROUTINE tra_ldf_iso( kt, kit000, cdtype, pahu, pahv, pgu , pgv ,   &
49      &                                                   pgui, pgvi,   &
50      &                                       ptb , ptbb, pta , kjpt, kpass )
51      !!----------------------------------------------------------------------
52      !!                  ***  ROUTINE tra_ldf_iso  ***
53      !!
54      !! ** Purpose :   Compute the before horizontal tracer (t & s) diffusive
55      !!      trend for a laplacian tensor (ezxcept the dz[ dz[.] ] term) and
56      !!      add it to the general trend of tracer equation.
57      !!
58      !! ** Method  :   The horizontal component of the lateral diffusive trends
59      !!      is provided by a 2nd order operator rotated along neural or geopo-
60      !!      tential surfaces to which an eddy induced advection can be added
61      !!      It is computed using before fields (forward in time) and isopyc-
62      !!      nal or geopotential slopes computed in routine ldfslp.
63      !!
64      !!      1st part :  masked horizontal derivative of T  ( di[ t ] )
65      !!      ========    with partial cell update if ln_zps=T
66      !!                  with top     cell update if ln_isfcav
67      !!
68      !!      2nd part :  horizontal fluxes of the lateral mixing operator
69      !!      ========   
70      !!         zftu =  pahu e2u*e3u/e1u di[ tb ]
71      !!               - pahu e2u*uslp    dk[ mi(mk(tb)) ]
72      !!         zftv =  pahv e1v*e3v/e2v dj[ tb ]
73      !!               - pahv e2u*vslp    dk[ mj(mk(tb)) ]
74      !!      take the horizontal divergence of the fluxes:
75      !!         difft = 1/(e1e2t*e3t) {  di-1[ zftu ] +  dj-1[ zftv ]  }
76      !!      Add this trend to the general trend (ta,sa):
77      !!         ta = ta + difft
78      !!
79      !!      3rd part: vertical trends of the lateral mixing operator
80      !!      ========  (excluding the vertical flux proportional to dk[t] )
81      !!      vertical fluxes associated with the rotated lateral mixing:
82      !!         zftw = - {  mi(mk(pahu)) * e2t*wslpi di[ mi(mk(tb)) ]
83      !!                   + mj(mk(pahv)) * e1t*wslpj dj[ mj(mk(tb)) ]  }
84      !!      take the horizontal divergence of the fluxes:
85      !!         difft = 1/(e1e2t*e3t) dk[ zftw ]
86      !!      Add this trend to the general trend (ta,sa):
87      !!         pta = pta + difft
88      !!
89      !! ** Action :   Update pta arrays with the before rotated diffusion
90      !!----------------------------------------------------------------------
91      INTEGER                              , INTENT(in   ) ::   kt         ! ocean time-step index
92      INTEGER                              , INTENT(in   ) ::   kit000     ! first time step index
93      CHARACTER(len=3)                     , INTENT(in   ) ::   cdtype     ! =TRA or TRC (tracer indicator)
94      INTEGER                              , INTENT(in   ) ::   kjpt       ! number of tracers
95      INTEGER                              , INTENT(in   ) ::   kpass      ! =1/2 first or second passage
96      REAL(wp), DIMENSION(jpi,jpj,jpk)     , INTENT(in   ) ::   pahu, pahv ! eddy diffusivity at u- and v-points  [m2/s]
97      REAL(wp), DIMENSION(jpi,jpj    ,kjpt), INTENT(in   ) ::   pgu, pgv   ! tracer gradient at pstep levels
98      REAL(wp), DIMENSION(jpi,jpj,    kjpt), INTENT(in   ) ::   pgui, pgvi ! tracer gradient at top   levels
99      REAL(wp), DIMENSION(jpi,jpj,jpk,kjpt), INTENT(in   ) ::   ptb        ! tracer (kpass=1) or laplacian of tracer (kpass=2)
100      REAL(wp), DIMENSION(jpi,jpj,jpk,kjpt), INTENT(in   ) ::   ptbb       ! tracer (only used in kpass=2)
101      REAL(wp), DIMENSION(jpi,jpj,jpk,kjpt), INTENT(inout) ::   pta        ! tracer trend
102      !
103      INTEGER  ::  ji, jj, jk, jn   ! dummy loop indices
104      INTEGER  ::  ierr             ! local integer
105      REAL(wp) ::  zmsku, zahu_w, zabe1, zcof1, zcoef3   ! local scalars
106      REAL(wp) ::  zmskv, zahv_w, zabe2, zcof2, zcoef4   !   -      -
107      REAL(wp) ::  zcoef0, ze3w_2, zsign, z2dt, z1_2dt   !   -      -
108#if defined key_diaar5
109      REAL(wp) ::   zztmp   ! local scalar
110#endif
111      REAL(wp), POINTER, DIMENSION(:,:)   ::   zdkt, zdk1t, z2d
112      REAL(wp), POINTER, DIMENSION(:,:,:) ::   zdit, zdjt, zftu, zftv, ztfw 
113      !!----------------------------------------------------------------------
114      !
115      IF( nn_timing == 1 )  CALL timing_start('tra_ldf_iso')
116      !
117      CALL wrk_alloc( jpi,jpj,       zdkt, zdk1t, z2d ) 
118      CALL wrk_alloc( jpi,jpj,jpk,   zdit, zdjt , zftu, zftv, ztfw  ) 
119      !
120      IF( kt == kit000 )  THEN
121         IF(lwp) WRITE(numout,*)
122         IF(lwp) WRITE(numout,*) 'tra_ldf_iso : rotated laplacian diffusion operator on ', cdtype
123         IF(lwp) WRITE(numout,*) '~~~~~~~~~~~'
124         !
125         akz     (:,:,:) = 0._wp     
126         ah_wslp2(:,:,:) = 0._wp
127      ENDIF
128      !                                               ! set time step size (Euler/Leapfrog)
129      IF( neuler == 0 .AND. kt == nit000 ) THEN   ;   z2dt =     rdttra(1)      ! at nit000   (Euler)
130      ELSE                                        ;   z2dt = 2.* rdttra(1)      !             (Leapfrog)
131      ENDIF
132      z1_2dt = 1._wp / z2dt
133      !
134      IF( kpass == 1 ) THEN   ;   zsign =  1._wp      ! bilaplacian operator require a minus sign (eddy diffusivity >0)
135      ELSE                    ;   zsign = -1._wp
136      ENDIF
137         
138      !!----------------------------------------------------------------------
139      !!   0 - calculate  ah_wslp2 and akz
140      !!----------------------------------------------------------------------
141      !
142      IF( kpass == 1 ) THEN                  !==  first pass only  ==!
143         !
144         DO jk = 2, jpkm1
145            DO jj = 2, jpjm1
146               DO ji = fs_2, fs_jpim1   ! vector opt.
147                  !
148                  zmsku = tmask(ji,jj,jk) / MAX(   umask(ji  ,jj,jk-1) + umask(ji-1,jj,jk)          &
149                     &                           + umask(ji-1,jj,jk-1) + umask(ji  ,jj,jk) , 1._wp  )
150                  zmskv = tmask(ji,jj,jk) / MAX(   vmask(ji,jj  ,jk-1) + vmask(ji,jj-1,jk)          &
151                     &                           + vmask(ji,jj-1,jk-1) + vmask(ji,jj  ,jk) , 1._wp  )
152                     !
153                  zahu_w = (   pahu(ji  ,jj,jk-1) + pahu(ji-1,jj,jk)    &
154                     &       + pahu(ji-1,jj,jk-1) + pahu(ji  ,jj,jk)  ) * zmsku
155                  zahv_w = (   pahv(ji,jj  ,jk-1) + pahv(ji,jj-1,jk)    &
156                     &       + pahv(ji,jj-1,jk-1) + pahv(ji,jj  ,jk)  ) * zmskv
157                     !
158                  ah_wslp2(ji,jj,jk) = zahu_w * wslpi(ji,jj,jk) * wslpi(ji,jj,jk)   &
159                     &               + zahv_w * wslpj(ji,jj,jk) * wslpj(ji,jj,jk)
160               END DO
161            END DO
162         END DO
163         !
164         IF( ln_traldf_msc ) THEN                ! stabilizing vertical diffusivity coefficient
165            DO jk = 2, jpkm1
166               DO jj = 2, jpjm1
167                  DO ji = fs_2, fs_jpim1
168                     akz(ji,jj,jk) = 0.25_wp * (                                                                     &
169                        &              ( pahu(ji  ,jj,jk) + pahu(ji  ,jj,jk-1) ) / ( e1u(ji  ,jj) * e1u(ji  ,jj) )   &
170                        &            + ( pahu(ji-1,jj,jk) + pahu(ji-1,jj,jk-1) ) / ( e1u(ji-1,jj) * e1u(ji-1,jj) )   &
171                        &            + ( pahv(ji,jj  ,jk) + pahv(ji,jj  ,jk-1) ) / ( e2v(ji,jj  ) * e2v(ji,jj  ) )   &
172                        &            + ( pahv(ji,jj-1,jk) + pahv(ji,jj-1,jk-1) ) / ( e2v(ji,jj-1) * e2v(ji,jj-1) )   )
173                  END DO
174               END DO
175            END DO
176            !
177            IF( ln_traldf_blp ) THEN                ! bilaplacian operator
178               DO jk = 2, jpkm1
179                  DO jj = 1, jpjm1
180                     DO ji = 1, fs_jpim1
181                        akz(ji,jj,jk) = 16._wp * ah_wslp2(ji,jj,jk)   &
182                           &          * (  akz(ji,jj,jk) + ah_wslp2(ji,jj,jk) / ( e3w_n(ji,jj,jk) * e3w_n(ji,jj,jk) )  )
183                     END DO
184                  END DO
185               END DO
186            ELSEIF( ln_traldf_lap ) THEN              ! laplacian operator
187               DO jk = 2, jpkm1
188                  DO jj = 1, jpjm1
189                     DO ji = 1, fs_jpim1
190                        ze3w_2 = e3w_n(ji,jj,jk) * e3w_n(ji,jj,jk)
191                        zcoef0 = z2dt * (  akz(ji,jj,jk) + ah_wslp2(ji,jj,jk) / ze3w_2  )
192                        akz(ji,jj,jk) = MAX( zcoef0 - 0.5_wp , 0._wp ) * ze3w_2 * z1_2dt
193                     END DO
194                  END DO
195               END DO
196           ENDIF
197           !
198         ELSE                                    ! 33 flux set to zero with akz=ah_wslp2 ==>> computed in full implicit
199            akz(:,:,:) = ah_wslp2(:,:,:)     
200         ENDIF
201      ENDIF
202      !
203      !                                                          ! ===========
204      DO jn = 1, kjpt                                            ! tracer loop
205         !                                                       ! ===========
206         !                                               
207         !!----------------------------------------------------------------------
208         !!   I - masked horizontal derivative
209         !!----------------------------------------------------------------------
210!!gm : bug.... why (x,:,:)?   (1,jpj,:) and (jpi,1,:) should be sufficient....
211         zdit (1,:,:) = 0._wp     ;     zdit (jpi,:,:) = 0._wp
212         zdjt (1,:,:) = 0._wp     ;     zdjt (jpi,:,:) = 0._wp
213         !!end
214
215         ! Horizontal tracer gradient
216         DO jk = 1, jpkm1
217            DO jj = 1, jpjm1
218               DO ji = 1, fs_jpim1   ! vector opt.
219                  zdit(ji,jj,jk) = ( ptb(ji+1,jj  ,jk,jn) - ptb(ji,jj,jk,jn) ) * umask(ji,jj,jk)
220                  zdjt(ji,jj,jk) = ( ptb(ji  ,jj+1,jk,jn) - ptb(ji,jj,jk,jn) ) * vmask(ji,jj,jk)
221               END DO
222            END DO
223         END DO
224         IF( ln_zps ) THEN      ! botton and surface ocean correction of the horizontal gradient
225            DO jj = 1, jpjm1              ! bottom correction (partial bottom cell)
226               DO ji = 1, fs_jpim1   ! vector opt.
227!!gm  the following anonymous remark is to considered: ! IF useless if zpshde defines pgu everywhere
228                  zdit(ji,jj,mbku(ji,jj)) = pgu(ji,jj,jn)         
229                  zdjt(ji,jj,mbkv(ji,jj)) = pgv(ji,jj,jn)
230               END DO
231            END DO
232            IF( ln_isfcav ) THEN      ! first wet level beneath a cavity
233               DO jj = 1, jpjm1
234                  DO ji = 1, fs_jpim1   ! vector opt.
235                     IF( miku(ji,jj) > 1 )   zdit(ji,jj,miku(ji,jj)) = pgui(ji,jj,jn)         
236                     IF( mikv(ji,jj) > 1 )   zdjt(ji,jj,mikv(ji,jj)) = pgvi(ji,jj,jn)     
237                  END DO
238               END DO
239            ENDIF
240         ENDIF
241         !
242         !!----------------------------------------------------------------------
243         !!   II - horizontal trend  (full)
244         !!----------------------------------------------------------------------
245         !
246         DO jk = 1, jpkm1                                 ! Horizontal slab
247            !
248            !                             !== Vertical tracer gradient
249            zdk1t(:,:) = ( ptb(:,:,jk,jn) - ptb(:,:,jk+1,jn) ) * wmask(:,:,jk+1)     ! level jk+1
250            !
251            IF( jk == 1 ) THEN   ;   zdkt(:,:) = zdk1t(:,:)                          ! surface: zdkt(jk=1)=zdkt(jk=2)
252            ELSE                 ;   zdkt(:,:) = ( ptb(:,:,jk-1,jn) - ptb(:,:,jk,jn) ) * wmask(:,:,jk)
253            ENDIF
254!!gm I don't understand why we should need this.... since wmask is used instead of tmask
255!         IF ( ln_isfcav ) THEN
256!            DO jj = 1, jpj
257!               DO ji = 1, jpi   ! vector opt.
258!                  ikt = mikt(ji,jj) ! surface level
259!                  zdk1t(ji,jj,ikt) = ( ptb(ji,jj,ikt,jn  ) - ptb(ji,jj,ikt+1,jn) ) * wmask(ji,jj,ikt+1)
260!                  zdkt (ji,jj,ikt) = zdk1t(ji,jj,ikt)
261!               END DO
262!            END DO
263!         END IF
264!!gm
265            DO jj = 1 , jpjm1            !==  Horizontal fluxes
266               DO ji = 1, fs_jpim1   ! vector opt.
267                  zabe1 = pahu(ji,jj,jk) * e2_e1u(ji,jj) * e3u_n(ji,jj,jk)
268                  zabe2 = pahv(ji,jj,jk) * e1_e2v(ji,jj) * e3v_n(ji,jj,jk)
269                  !
270                  zmsku = 1. / MAX(  tmask(ji+1,jj,jk  ) + tmask(ji,jj,jk+1)   &
271                     &             + tmask(ji+1,jj,jk+1) + tmask(ji,jj,jk  ), 1. )
272                  !
273                  zmskv = 1. / MAX(  tmask(ji,jj+1,jk  ) + tmask(ji,jj,jk+1)   &
274                     &             + tmask(ji,jj+1,jk+1) + tmask(ji,jj,jk  ), 1. )
275                  !
276                  zcof1 = - pahu(ji,jj,jk) * e2u(ji,jj) * uslp(ji,jj,jk) * zmsku
277                  zcof2 = - pahv(ji,jj,jk) * e1v(ji,jj) * vslp(ji,jj,jk) * zmskv
278                  !
279                  zftu(ji,jj,jk ) = (  zabe1 * zdit(ji,jj,jk)   &
280                     &               + zcof1 * (  zdkt (ji+1,jj) + zdk1t(ji,jj)      &
281                     &                          + zdk1t(ji+1,jj) + zdkt (ji,jj)  )  ) * umask(ji,jj,jk)
282                  zftv(ji,jj,jk) = (  zabe2 * zdjt(ji,jj,jk)   &
283                     &               + zcof2 * (  zdkt (ji,jj+1) + zdk1t(ji,jj)      &
284                     &                          + zdk1t(ji,jj+1) + zdkt (ji,jj)  )  ) * vmask(ji,jj,jk)                 
285               END DO
286            END DO
287            !
288            DO jj = 2 , jpjm1          !== horizontal divergence and add to pta
289               DO ji = fs_2, fs_jpim1   ! vector opt.
290                  pta(ji,jj,jk,jn) = pta(ji,jj,jk,jn) + zsign * (  zftu(ji,jj,jk) - zftu(ji-1,jj,jk)      &
291                     &                                           + zftv(ji,jj,jk) - zftv(ji,jj-1,jk)  )   &
292                     &                                        / (  e1e2t(ji,jj) * e3t_n(ji,jj,jk)  )
293               END DO
294            END DO
295         END DO                                        !   End of slab 
296
297         !!----------------------------------------------------------------------
298         !!   III - vertical trend (full)
299         !!----------------------------------------------------------------------
300         !
301         ztfw(1,:,:) = 0._wp     ;     ztfw(jpi,:,:) = 0._wp
302         !
303         ! Vertical fluxes
304         ! ---------------
305         !                          ! Surface and bottom vertical fluxes set to zero
306         ztfw(:,:, 1 ) = 0._wp      ;      ztfw(:,:,jpk) = 0._wp
307         
308         DO jk = 2, jpkm1           ! interior (2=<jk=<jpk-1)
309            DO jj = 2, jpjm1
310               DO ji = fs_2, fs_jpim1   ! vector opt.
311                  !
312                  zmsku = tmask(ji,jj,jk) / MAX(   umask(ji  ,jj,jk-1) + umask(ji-1,jj,jk)          &
313                     &                           + umask(ji-1,jj,jk-1) + umask(ji  ,jj,jk) , 1._wp  )
314                  zmskv = tmask(ji,jj,jk) / MAX(   vmask(ji,jj  ,jk-1) + vmask(ji,jj-1,jk)          &
315                     &                           + vmask(ji,jj-1,jk-1) + vmask(ji,jj  ,jk) , 1._wp  )
316                     !
317                  zahu_w = (   pahu(ji  ,jj,jk-1) + pahu(ji-1,jj,jk)    &
318                     &       + pahu(ji-1,jj,jk-1) + pahu(ji  ,jj,jk)  ) * zmsku
319                  zahv_w = (   pahv(ji,jj  ,jk-1) + pahv(ji,jj-1,jk)    &
320                     &       + pahv(ji,jj-1,jk-1) + pahv(ji,jj  ,jk)  ) * zmskv
321                     !
322                  zcoef3 = - zahu_w * e2t(ji,jj) * zmsku * wslpi (ji,jj,jk)   !wslpi & j are already w-masked
323                  zcoef4 = - zahv_w * e1t(ji,jj) * zmskv * wslpj (ji,jj,jk)
324                  !
325                  ztfw(ji,jj,jk) = zcoef3 * (   zdit(ji  ,jj  ,jk-1) + zdit(ji-1,jj  ,jk)      &
326                     &                        + zdit(ji-1,jj  ,jk-1) + zdit(ji  ,jj  ,jk)  )   &
327                     &           + zcoef4 * (   zdjt(ji  ,jj  ,jk-1) + zdjt(ji  ,jj-1,jk)      &
328                     &                        + zdjt(ji  ,jj-1,jk-1) + zdjt(ji  ,jj  ,jk)  )
329               END DO
330            END DO
331         END DO
332         !                                !==  add the vertical 33 flux  ==!
333         IF( ln_traldf_lap ) THEN               ! laplacian case: eddy coef = ah_wslp2 - akz
334            DO jk = 2, jpkm1       
335               DO jj = 1, jpjm1
336                  DO ji = fs_2, fs_jpim1
337                     ztfw(ji,jj,jk) = ztfw(ji,jj,jk) + e1e2t(ji,jj) / e3w_n(ji,jj,jk) * tmask(ji,jj,jk)   &
338                        &                            * ( ah_wslp2(ji,jj,jk) - akz(ji,jj,jk) )             &
339                        &                            * ( ptb(ji,jj,jk-1,jn) - ptb(ji,jj,jk,jn) )
340                  END DO
341               END DO
342            END DO
343            !
344         ELSE                                   ! bilaplacian
345            SELECT CASE( kpass )
346            CASE(  1  )                            ! 1st pass : eddy coef = ah_wslp2
347               DO jk = 2, jpkm1 
348                  DO jj = 1, jpjm1
349                     DO ji = fs_2, fs_jpim1
350                        ztfw(ji,jj,jk) = ztfw(ji,jj,jk)    &
351                           &           + ah_wslp2(ji,jj,jk) * e1e2t(ji,jj)   &
352                           &           * ( ptb(ji,jj,jk-1,jn) - ptb(ji,jj,jk,jn) ) * tmask(ji,jj,jk) / e3w_n(ji,jj,jk)
353                     END DO
354                  END DO
355               END DO
356            CASE(  2  )                         ! 2nd pass : eddy flux = ah_wslp2 and akz applied on ptb  and ptbb gradients, resp.
357               DO jk = 2, jpkm1 
358                  DO jj = 1, jpjm1
359                     DO ji = fs_2, fs_jpim1
360                        ztfw(ji,jj,jk) = ztfw(ji,jj,jk) + e1e2t(ji,jj) / e3w_n(ji,jj,jk) * tmask(ji,jj,jk)                      &
361                           &                            * (  ah_wslp2(ji,jj,jk) * ( ptb (ji,jj,jk-1,jn) - ptb (ji,jj,jk,jn) )   &
362                           &                               + akz     (ji,jj,jk) * ( ptbb(ji,jj,jk-1,jn) - ptbb(ji,jj,jk,jn) )   )
363                     END DO
364                  END DO
365               END DO
366            END SELECT
367         ENDIF
368         !         
369         DO jk = 1, jpkm1                 !==  Divergence of vertical fluxes added to pta  ==!
370            DO jj = 2, jpjm1
371               DO ji = fs_2, fs_jpim1   ! vector opt.
372                  pta(ji,jj,jk,jn) = pta(ji,jj,jk,jn) + zsign * (  ztfw (ji,jj,jk) - ztfw(ji,jj,jk+1)  )   &
373                     &                                        / (  e1e2t(ji,jj) * e3t_n(ji,jj,jk)  )
374               END DO
375            END DO
376         END DO
377         !
378         IF( ( kpass == 1 .AND. ln_traldf_lap ) .OR.  &     !==  first pass only (  laplacian)  ==!
379             ( kpass == 2 .AND. ln_traldf_blp ) ) THEN      !==  2nd   pass      (bilaplacian)  ==!
380            !
381            !                             ! "Poleward" diffusive heat or salt transports (T-S case only)
382            IF( cdtype == 'TRA' .AND. ln_diaptr ) THEN
383               ! note sign is reversed to give down-gradient diffusive transports (#1043)
384               IF( jn == jp_tem)   htr_ldf(:) = ptr_sj( -zftv(:,:,:) )
385               IF( jn == jp_sal)   str_ldf(:) = ptr_sj( -zftv(:,:,:) )
386            ENDIF
387            !
388            IF( iom_use("udiff_heattr") .OR. iom_use("vdiff_heattr") ) THEN
389              !
390              IF( cdtype == 'TRA' .AND. jn == jp_tem  ) THEN
391                  z2d(:,:) = zftu(ji,jj,1) 
392                  DO jk = 2, jpkm1
393                     DO jj = 2, jpjm1
394                        DO ji = fs_2, fs_jpim1   ! vector opt.
395                           z2d(ji,jj) = z2d(ji,jj) + zftu(ji,jj,jk) 
396                        END DO
397                     END DO
398                  END DO
399!!gm CAUTION I think there is an error of sign when using BLP operator....
400!!gm         a multiplication by zsign is required (to be checked twice !)
401                  z2d(:,:) = - rau0_rcp * z2d(:,:)     ! note sign is reversed to give down-gradient diffusive transports (#1043)
402                  CALL lbc_lnk( z2d, 'U', -1. )
403                  CALL iom_put( "udiff_heattr", z2d )                  ! heat transport in i-direction
404                  !
405                  z2d(:,:) = zftv(ji,jj,1) 
406                  DO jk = 2, jpkm1
407                     DO jj = 2, jpjm1
408                        DO ji = fs_2, fs_jpim1   ! vector opt.
409                           z2d(ji,jj) = z2d(ji,jj) + zftv(ji,jj,jk) 
410                        END DO
411                     END DO
412                  END DO
413                  z2d(:,:) = - rau0_rcp * z2d(:,:)     ! note sign is reversed to give down-gradient diffusive transports (#1043)
414                  CALL lbc_lnk( z2d, 'V', -1. )
415                  CALL iom_put( "vdiff_heattr", z2d )                  !  heat transport in i-direction
416               END IF
417               !
418            ENDIF
419            !
420         ENDIF                                                    !== end pass selection  ==!
421         !
422         !                                                        ! ===============
423      END DO                                                      ! end tracer loop
424      !                                                           ! ===============
425      !
426      CALL wrk_dealloc( jpi, jpj,      zdkt, zdk1t, z2d ) 
427      CALL wrk_dealloc( jpi, jpj, jpk, zdit, zdjt , zftu, zftv, ztfw  ) 
428      !
429      IF( nn_timing == 1 )  CALL timing_stop('tra_ldf_iso')
430      !
431   END SUBROUTINE tra_ldf_iso
432
433   !!==============================================================================
434END MODULE traldf_iso
Note: See TracBrowser for help on using the repository browser.