New URL for NEMO forge!   http://forge.nemo-ocean.eu

Since March 2022 along with NEMO 4.2 release, the code development moved to a self-hosted GitLab.
This present forge is now archived and remained online for history.
traldf_lap.F90 in branches/2015/dev_r5836_NOC3_vvl_by_default/NEMOGCM/NEMO/OPA_SRC/TRA – NEMO

source: branches/2015/dev_r5836_NOC3_vvl_by_default/NEMOGCM/NEMO/OPA_SRC/TRA/traldf_lap.F90 @ 5845

Last change on this file since 5845 was 5845, checked in by gm, 8 years ago

#1613: vvl by default: suppression of domzgr_substitute.h90

  • Property svn:keywords set to Id
File size: 8.8 KB
Line 
1MODULE traldf_lap
2   !!==============================================================================
3   !!                       ***  MODULE  traldf_lap  ***
4   !! Ocean tracers:  lateral diffusivity trend  (laplacian and bilaplacian)
5   !!==============================================================================
6   !! History :  OPA  ! 1987-06  (P. Andrich, D. L Hostis)  Original code
7   !!                 ! 1991-11  (G. Madec)
8   !!                 ! 1995-11  (G. Madec)  suppress volumetric scale factors
9   !!                 ! 1996-01  (G. Madec)  statement function for e3
10   !!            NEMO ! 2002-06  (G. Madec)  F90: Free form and module
11   !!            1.0  ! 2004-08  (C. Talandier) New trends organization
12   !!                 ! 2005-11  (G. Madec)  add zps case
13   !!            3.0  ! 2010-06  (C. Ethe, G. Madec) Merge TRA-TRC
14   !!            3.7  ! 2014-01  (G. Madec, S. Masson) re-entrant laplacian
15   !!----------------------------------------------------------------------
16
17   !!----------------------------------------------------------------------
18   !!   tra_ldf_lap : update the tracer trend with the lateral diffusion : iso-level laplacian operator
19   !!   tra_ldf_blp : update the tracer trend with the lateral diffusion : iso-level bilaplacian operator
20   !!----------------------------------------------------------------------
21   USE oce             ! ocean dynamics and active tracers
22   USE dom_oce         ! ocean space and time domain
23   USE ldftra          ! lateral physics: eddy diffusivity
24   USE diaptr          ! poleward transport diagnostics
25   USE trc_oce         ! share passive tracers/Ocean variables
26   USE zpshde          ! partial step: hor. derivative     (zps_hde routine)
27   !
28   USE in_out_manager  ! I/O manager
29   USE lbclnk          ! ocean lateral boundary conditions (or mpp link)
30   USE lib_mpp         ! distribued memory computing library
31   USE timing          ! Timing
32   USE wrk_nemo        ! Memory allocation
33
34   IMPLICIT NONE
35   PRIVATE
36
37   PUBLIC   tra_ldf_lap   ! routine called by traldf.F90
38
39   !! * Substitutions
40#  include "vectopt_loop_substitute.h90"
41   !!----------------------------------------------------------------------
42   !! NEMO/OPA 3.7 , NEMO Consortium (2014)
43   !! $Id$
44   !! Software governed by the CeCILL licence     (NEMOGCM/NEMO_CeCILL.txt)
45   !!----------------------------------------------------------------------
46CONTAINS
47
48   SUBROUTINE tra_ldf_lap( kt, kit000, cdtype, pahu, pahv, pgu , pgv ,   &
49      &                                                    pgui, pgvi,   &
50      &                                        ptb , pta , kjpt, kpass ) 
51      !!----------------------------------------------------------------------
52      !!                  ***  ROUTINE tra_ldf_lap  ***
53      !!                   
54      !! ** Purpose :   Compute the before horizontal tracer (t & s) diffusive
55      !!      trend and add it to the general trend of tracer equation.
56      !!
57      !! ** Method  :   Second order diffusive operator evaluated using before
58      !!      fields (forward time scheme). The horizontal diffusive trends of
59      !!      the tracer is given by:
60      !!          difft = 1/(e1e2t*e3t) {  di-1[ pahu e2u*e3u/e1u di(tb) ]
61      !!                                 + dj-1[ pahv e1v*e3v/e2v dj(tb) ] }
62      !!      Add this trend to the general tracer trend pta :
63      !!          pta = pta + difft
64      !!
65      !! ** Action  : - Update pta arrays with the before iso-level
66      !!                harmonic mixing trend.
67      !!----------------------------------------------------------------------
68      INTEGER                              , INTENT(in   ) ::   kt         ! ocean time-step index
69      INTEGER                              , INTENT(in   ) ::   kit000     ! first time step index
70      CHARACTER(len=3)                     , INTENT(in   ) ::   cdtype     ! =TRA or TRC (tracer indicator)
71      INTEGER                              , INTENT(in   ) ::   kjpt       ! number of tracers
72      INTEGER                              , INTENT(in   ) ::   kpass      ! =1/2 first or second passage
73      REAL(wp), DIMENSION(jpi,jpj,jpk)     , INTENT(in   ) ::   pahu, pahv ! eddy diffusivity at u- and v-points  [m2/s]
74      REAL(wp), DIMENSION(jpi,jpj    ,kjpt), INTENT(in   ) ::   pgu, pgv   ! tracer gradient at pstep levels
75      REAL(wp), DIMENSION(jpi,jpj,    kjpt), INTENT(in   ) ::   pgui, pgvi ! tracer gradient at top   levels
76      REAL(wp), DIMENSION(jpi,jpj,jpk,kjpt), INTENT(in   ) ::   ptb        ! before and now tracer fields
77      REAL(wp), DIMENSION(jpi,jpj,jpk,kjpt), INTENT(inout) ::   pta        ! tracer trend
78      !
79      INTEGER  ::   ji, jj, jk, jn   ! dummy loop indices
80      REAL(wp) ::   zsign            ! local scalars
81      REAL(wp), POINTER, DIMENSION(:,:,:) ::  ztu, ztv, zaheeu, zaheev
82      !!----------------------------------------------------------------------
83      !
84      IF( nn_timing == 1 )   CALL timing_start('tra_ldf_lap')
85      !
86      IF( kt == nit000 .AND. lwp )  THEN
87         WRITE(numout,*)
88         WRITE(numout,*) 'tra_ldf_lap : iso-level laplacian diffusion on ', cdtype, ', pass=', kpass
89         WRITE(numout,*) '~~~~~~~~~~~ '
90      ENDIF
91      !
92      CALL wrk_alloc( jpi,jpj,jpk,   ztu, ztv, zaheeu, zaheev ) 
93      !
94      !                                !==  Initialization of metric arrays used for all tracers  ==!
95      IF( kpass == 1 ) THEN   ;   zsign =  1._wp      ! bilaplacian operator require a minus sign (eddy diffusivity >0)
96      ELSE                    ;   zsign = -1._wp
97      ENDIF
98      DO jk = 1, jpkm1
99         DO jj = 1, jpjm1
100            DO ji = 1, fs_jpim1   ! vector opt.
101               zaheeu(ji,jj,jk) = zsign * pahu(ji,jj,jk) * e2_e1u(ji,jj) * e3u_n(ji,jj,jk)   !!gm   * umask(ji,jj,jk) pah masked!
102               zaheev(ji,jj,jk) = zsign * pahv(ji,jj,jk) * e1_e2v(ji,jj) * e3v_n(ji,jj,jk)   !!gm   * vmask(ji,jj,jk)
103            END DO
104         END DO
105      END DO
106      !
107      !                             ! =========== !
108      DO jn = 1, kjpt               ! tracer loop !
109         !                          ! =========== !   
110         !                               
111         DO jk = 1, jpkm1              !== First derivative (gradient)  ==!
112            DO jj = 1, jpjm1
113               DO ji = 1, fs_jpim1
114                  ztu(ji,jj,jk) = zaheeu(ji,jj,jk) * ( ptb(ji+1,jj  ,jk,jn) - ptb(ji,jj,jk,jn) )
115                  ztv(ji,jj,jk) = zaheev(ji,jj,jk) * ( ptb(ji  ,jj+1,jk,jn) - ptb(ji,jj,jk,jn) )
116               END DO
117            END DO
118         END DO 
119         IF( ln_zps ) THEN                ! set gradient at bottom/top ocean level
120            DO jj = 1, jpjm1                    ! bottom
121               DO ji = 1, fs_jpim1
122                  ztu(ji,jj,mbku(ji,jj)) = zaheeu(ji,jj,mbku(ji,jj)) * pgu(ji,jj,jn)
123                  ztv(ji,jj,mbkv(ji,jj)) = zaheev(ji,jj,mbkv(ji,jj)) * pgv(ji,jj,jn)
124               END DO
125            END DO 
126            IF( ln_isfcav ) THEN                ! top in ocean cavities only
127               DO jj = 1, jpjm1
128                  DO ji = 1, fs_jpim1   ! vector opt.
129                     IF( miku(ji,jj) > 1 )   ztu(ji,jj,miku(ji,jj)) = zaheeu(ji,jj,miku(ji,jj)) * pgui(ji,jj,jn) 
130                     IF( mikv(ji,jj) > 1 )   ztv(ji,jj,mikv(ji,jj)) = zaheev(ji,jj,mikv(ji,jj)) * pgvi(ji,jj,jn) 
131                  END DO
132               END DO
133            ENDIF
134         ENDIF
135         !
136         DO jk = 1, jpkm1              !== Second derivative (divergence) added to the general tracer trends  ==!
137            DO jj = 2, jpjm1
138               DO ji = fs_2, fs_jpim1
139                  pta(ji,jj,jk,jn) = pta(ji,jj,jk,jn) + (  ztu(ji,jj,jk) - ztu(ji-1,jj,jk)     &
140                     &                                   + ztv(ji,jj,jk) - ztv(ji,jj-1,jk) )   &
141                     &                                / ( e1e2t(ji,jj) * e3t_n(ji,jj,jk) )
142               END DO
143            END DO
144         END DO 
145         !
146         !                             !== "Poleward" diffusive heat or salt transports  ==!
147         IF( ( kpass == 1 .AND. .NOT.ln_traldf_blp ) .OR.  &     !==  first pass only (  laplacian)  ==!
148             ( kpass == 2 .AND.      ln_traldf_blp ) ) THEN      !==  2nd   pass only (bilaplacian)  ==!
149            IF( cdtype == 'TRA' .AND. ln_diaptr ) THEN
150               IF( jn  == jp_tem)   htr_ldf(:) = ptr_sj( -ztv(:,:,:) )
151               IF( jn  == jp_sal)   str_ldf(:) = ptr_sj( -ztv(:,:,:) )
152            ENDIF
153         ENDIF
154         !                          ! ==================
155      END DO                        ! end of tracer loop
156      !                             ! ==================
157      !
158      CALL wrk_dealloc( jpi,jpj,jpk,   ztu, ztv, zaheeu, zaheev ) 
159      !
160      IF( nn_timing == 1 )  CALL timing_stop('tra_ldf_lap')
161      !
162   END SUBROUTINE tra_ldf_lap
163   
164   !!==============================================================================
165END MODULE traldf_lap
Note: See TracBrowser for help on using the repository browser.