| 1 | MODULE traldf_triad |
|---|
| 2 | !!====================================================================== |
|---|
| 3 | !! *** MODULE traldf_triad *** |
|---|
| 4 | !! Ocean tracers: horizontal component of the lateral tracer mixing trend |
|---|
| 5 | !!====================================================================== |
|---|
| 6 | !! History : 3.3 ! 2010-10 (G. Nurser, C. Harris, G. Madec) Griffies operator (original code) |
|---|
| 7 | !! 3.7 ! 2013-12 (F. Lemarie, G. Madec) triad operator (Griffies) + Method of Stabilizing Correction |
|---|
| 8 | !!---------------------------------------------------------------------- |
|---|
| 9 | |
|---|
| 10 | !!---------------------------------------------------------------------- |
|---|
| 11 | !! tra_ldf_triad : update the tracer trend with the iso-neutral laplacian triad-operator |
|---|
| 12 | !!---------------------------------------------------------------------- |
|---|
| 13 | USE oce ! ocean dynamics and active tracers |
|---|
| 14 | USE dom_oce ! ocean space and time domain |
|---|
| 15 | USE phycst ! physical constants |
|---|
| 16 | USE trc_oce ! share passive tracers/Ocean variables |
|---|
| 17 | USE zdf_oce ! ocean vertical physics |
|---|
| 18 | USE ldftra ! lateral physics: eddy diffusivity |
|---|
| 19 | USE ldfslp ! lateral physics: iso-neutral slopes |
|---|
| 20 | USE traldf_iso ! lateral diffusion (Madec operator) (tra_ldf_iso routine) |
|---|
| 21 | USE diaptr ! poleward transport diagnostics |
|---|
| 22 | USE zpshde ! partial step: hor. derivative (zps_hde routine) |
|---|
| 23 | ! |
|---|
| 24 | USE in_out_manager ! I/O manager |
|---|
| 25 | USE iom ! I/O library |
|---|
| 26 | USE lbclnk ! ocean lateral boundary conditions (or mpp link) |
|---|
| 27 | USE lib_mpp ! MPP library |
|---|
| 28 | USE wrk_nemo ! Memory Allocation |
|---|
| 29 | USE timing ! Timing |
|---|
| 30 | |
|---|
| 31 | IMPLICIT NONE |
|---|
| 32 | PRIVATE |
|---|
| 33 | |
|---|
| 34 | PUBLIC tra_ldf_triad ! routine called by traldf.F90 |
|---|
| 35 | |
|---|
| 36 | REAL(wp), DIMENSION(:,:,:), ALLOCATABLE, SAVE :: zdkt3d !: vertical tracer gradient at 2 levels |
|---|
| 37 | |
|---|
| 38 | !! * Substitutions |
|---|
| 39 | # include "vectopt_loop_substitute.h90" |
|---|
| 40 | !!---------------------------------------------------------------------- |
|---|
| 41 | !! NEMO/OPA 3.7 , NEMO Consortium (2015) |
|---|
| 42 | !! $Id$ |
|---|
| 43 | !! Software governed by the CeCILL licence (NEMOGCM/NEMO_CeCILL.txt) |
|---|
| 44 | !!---------------------------------------------------------------------- |
|---|
| 45 | CONTAINS |
|---|
| 46 | |
|---|
| 47 | SUBROUTINE tra_ldf_triad( kt, kit000, cdtype, pahu, pahv, pgu , pgv , & |
|---|
| 48 | & pgui, pgvi, & |
|---|
| 49 | & ptb , ptbb, pta , kjpt, kpass ) |
|---|
| 50 | !!---------------------------------------------------------------------- |
|---|
| 51 | !! *** ROUTINE tra_ldf_triad *** |
|---|
| 52 | !! |
|---|
| 53 | !! ** Purpose : Compute the before horizontal tracer (t & s) diffusive |
|---|
| 54 | !! trend for a laplacian tensor (ezxcept the dz[ dz[.] ] term) and |
|---|
| 55 | !! add it to the general trend of tracer equation. |
|---|
| 56 | !! |
|---|
| 57 | !! ** Method : The horizontal component of the lateral diffusive trends |
|---|
| 58 | !! is provided by a 2nd order operator rotated along neural or geopo- |
|---|
| 59 | !! tential surfaces to which an eddy induced advection can be added |
|---|
| 60 | !! It is computed using before fields (forward in time) and isopyc- |
|---|
| 61 | !! nal or geopotential slopes computed in routine ldfslp. |
|---|
| 62 | !! |
|---|
| 63 | !! see documentation for the desciption |
|---|
| 64 | !! |
|---|
| 65 | !! ** Action : pta updated with the before rotated diffusion |
|---|
| 66 | !! ah_wslp2 .... |
|---|
| 67 | !! akz stabilizing vertical diffusivity coefficient (used in trazdf_imp) |
|---|
| 68 | !!---------------------------------------------------------------------- |
|---|
| 69 | INTEGER , INTENT(in ) :: kt ! ocean time-step index |
|---|
| 70 | INTEGER , INTENT(in ) :: kit000 ! first time step index |
|---|
| 71 | CHARACTER(len=3) , INTENT(in ) :: cdtype ! =TRA or TRC (tracer indicator) |
|---|
| 72 | INTEGER , INTENT(in ) :: kjpt ! number of tracers |
|---|
| 73 | INTEGER , INTENT(in ) :: kpass ! =1/2 first or second passage |
|---|
| 74 | REAL(wp), DIMENSION(jpi,jpj,jpk) , INTENT(in ) :: pahu, pahv ! eddy diffusivity at u- and v-points [m2/s] |
|---|
| 75 | REAL(wp), DIMENSION(jpi,jpj ,kjpt), INTENT(in ) :: pgu , pgv ! tracer gradient at pstep levels |
|---|
| 76 | REAL(wp), DIMENSION(jpi,jpj, kjpt), INTENT(in ) :: pgui, pgvi ! tracer gradient at top levels |
|---|
| 77 | REAL(wp), DIMENSION(jpi,jpj,jpk,kjpt), INTENT(in ) :: ptb ! tracer (kpass=1) or laplacian of tracer (kpass=2) |
|---|
| 78 | REAL(wp), DIMENSION(jpi,jpj,jpk,kjpt), INTENT(in ) :: ptbb ! tracer (only used in kpass=2) |
|---|
| 79 | REAL(wp), DIMENSION(jpi,jpj,jpk,kjpt), INTENT(inout) :: pta ! tracer trend |
|---|
| 80 | ! |
|---|
| 81 | INTEGER :: ji, jj, jk, jn ! dummy loop indices |
|---|
| 82 | INTEGER :: ip,jp,kp ! dummy loop indices |
|---|
| 83 | INTEGER :: ierr ! local integer |
|---|
| 84 | REAL(wp) :: zmsku, zabe1, zcof1, zcoef3 ! local scalars |
|---|
| 85 | REAL(wp) :: zmskv, zabe2, zcof2, zcoef4 ! - - |
|---|
| 86 | REAL(wp) :: zcoef0, ze3w_2, zsign, z2dt, z1_2dt ! - - |
|---|
| 87 | ! |
|---|
| 88 | REAL(wp) :: zslope_skew, zslope_iso, zslope2, zbu, zbv |
|---|
| 89 | REAL(wp) :: ze1ur, ze2vr, ze3wr, zdxt, zdyt, zdzt |
|---|
| 90 | REAL(wp) :: zah, zah_slp, zaei_slp |
|---|
| 91 | #if defined key_diaar5 |
|---|
| 92 | REAL(wp) :: zztmp ! local scalar |
|---|
| 93 | #endif |
|---|
| 94 | REAL(wp), POINTER, DIMENSION(:,: ) :: z2d ! 2D workspace |
|---|
| 95 | REAL(wp), POINTER, DIMENSION(:,:,:) :: zdit, zdjt, zftu, zftv, ztfw, zpsi_uw, zpsi_vw ! 3D - |
|---|
| 96 | !!---------------------------------------------------------------------- |
|---|
| 97 | ! |
|---|
| 98 | IF( nn_timing == 1 ) CALL timing_start('tra_ldf_triad') |
|---|
| 99 | ! |
|---|
| 100 | CALL wrk_alloc( jpi,jpj, z2d ) |
|---|
| 101 | CALL wrk_alloc( jpi,jpj,jpk, zdit, zdjt, zftu, zftv, ztfw, zpsi_uw, zpsi_vw ) |
|---|
| 102 | ! |
|---|
| 103 | IF( .NOT.ALLOCATED(zdkt3d) ) THEN |
|---|
| 104 | ALLOCATE( zdkt3d(jpi,jpj,0:1) , STAT=ierr ) |
|---|
| 105 | IF( lk_mpp ) CALL mpp_sum ( ierr ) |
|---|
| 106 | IF( ierr > 0 ) CALL ctl_stop('STOP', 'tra_ldf_triad: unable to allocate arrays') |
|---|
| 107 | ENDIF |
|---|
| 108 | ! |
|---|
| 109 | IF( kpass == 1 .AND. kt == kit000 ) THEN |
|---|
| 110 | IF(lwp) WRITE(numout,*) |
|---|
| 111 | IF(lwp) WRITE(numout,*) 'tra_ldf_triad : rotated laplacian diffusion operator on ', cdtype |
|---|
| 112 | IF(lwp) WRITE(numout,*) '~~~~~~~~~~~~~' |
|---|
| 113 | ENDIF |
|---|
| 114 | ! ! set time step size (Euler/Leapfrog) |
|---|
| 115 | IF( neuler == 0 .AND. kt == kit000 ) THEN ; z2dt = rdttra(1) ! at nit000 (Euler) |
|---|
| 116 | ELSE ; z2dt = 2.* rdttra(1) ! (Leapfrog) |
|---|
| 117 | ENDIF |
|---|
| 118 | z1_2dt = 1._wp / z2dt |
|---|
| 119 | ! |
|---|
| 120 | IF( kpass == 1 ) THEN ; zsign = 1._wp ! bilaplacian operator require a minus sign (eddy diffusivity >0) |
|---|
| 121 | ELSE ; zsign = -1._wp |
|---|
| 122 | ENDIF |
|---|
| 123 | ! |
|---|
| 124 | !!---------------------------------------------------------------------- |
|---|
| 125 | !! 0 - calculate ah_wslp2, akz, and optionally zpsi_uw, zpsi_vw |
|---|
| 126 | !!---------------------------------------------------------------------- |
|---|
| 127 | ! |
|---|
| 128 | IF( kpass == 1 ) THEN !== first pass only and whatever the tracer is ==! |
|---|
| 129 | ! |
|---|
| 130 | akz (:,:,:) = 0._wp |
|---|
| 131 | ah_wslp2(:,:,:) = 0._wp |
|---|
| 132 | IF( ln_ldfeiv_dia ) THEN |
|---|
| 133 | zpsi_uw(:,:,:) = 0._wp |
|---|
| 134 | zpsi_vw(:,:,:) = 0._wp |
|---|
| 135 | ENDIF |
|---|
| 136 | ! |
|---|
| 137 | DO ip = 0, 1 ! i-k triads |
|---|
| 138 | DO kp = 0, 1 |
|---|
| 139 | DO jk = 1, jpkm1 |
|---|
| 140 | DO jj = 1, jpjm1 |
|---|
| 141 | DO ji = 1, fs_jpim1 |
|---|
| 142 | ze3wr = 1._wp / e3w_n(ji+ip,jj,jk+kp) |
|---|
| 143 | zbu = e1e2u(ji,jj) * e3u_n(ji,jj,jk) |
|---|
| 144 | zah = 0.25_wp * pahu(ji,jj,jk) |
|---|
| 145 | zslope_skew = triadi_g(ji+ip,jj,jk,1-ip,kp) |
|---|
| 146 | ! Subtract s-coordinate slope at t-points to give slope rel to s-surfaces (do this by *adding* gradient of depth) |
|---|
| 147 | zslope2 = zslope_skew + ( gdept_n(ji+1,jj,jk) - gdept_n(ji,jj,jk) ) * r1_e1u(ji,jj) * umask(ji,jj,jk+kp) |
|---|
| 148 | zslope2 = zslope2 *zslope2 |
|---|
| 149 | ah_wslp2(ji+ip,jj,jk+kp) = ah_wslp2(ji+ip,jj,jk+kp) + zah * zbu * ze3wr * r1_e1e2t(ji+ip,jj) * zslope2 |
|---|
| 150 | akz (ji+ip,jj,jk+kp) = akz (ji+ip,jj,jk+kp) + zah * r1_e1u(ji,jj) & |
|---|
| 151 | & * r1_e1u(ji,jj) * umask(ji,jj,jk+kp) |
|---|
| 152 | ! |
|---|
| 153 | IF( ln_ldfeiv_dia ) zpsi_uw(ji,jj,jk+kp) = zpsi_uw(ji,jj,jk+kp) & |
|---|
| 154 | & + 0.25_wp * aeiu(ji,jj,jk) * e2u(ji,jj) * zslope_skew |
|---|
| 155 | END DO |
|---|
| 156 | END DO |
|---|
| 157 | END DO |
|---|
| 158 | END DO |
|---|
| 159 | END DO |
|---|
| 160 | ! |
|---|
| 161 | DO jp = 0, 1 ! j-k triads |
|---|
| 162 | DO kp = 0, 1 |
|---|
| 163 | DO jk = 1, jpkm1 |
|---|
| 164 | DO jj = 1, jpjm1 |
|---|
| 165 | DO ji = 1, fs_jpim1 |
|---|
| 166 | ze3wr = 1.0_wp / e3w_n(ji,jj+jp,jk+kp) |
|---|
| 167 | zbv = e1e2v(ji,jj) * e3v_n(ji,jj,jk) |
|---|
| 168 | zah = 0.25_wp * pahv(ji,jj,jk) |
|---|
| 169 | zslope_skew = triadj_g(ji,jj+jp,jk,1-jp,kp) |
|---|
| 170 | ! Subtract s-coordinate slope at t-points to give slope rel to s surfaces |
|---|
| 171 | ! (do this by *adding* gradient of depth) |
|---|
| 172 | zslope2 = zslope_skew + ( gdept_n(ji,jj+1,jk) - gdept_n(ji,jj,jk) ) * r1_e2v(ji,jj) * vmask(ji,jj,jk+kp) |
|---|
| 173 | zslope2 = zslope2 * zslope2 |
|---|
| 174 | ah_wslp2(ji,jj+jp,jk+kp) = ah_wslp2(ji,jj+jp,jk+kp) + zah * zbv * ze3wr * r1_e1e2t(ji,jj+jp) * zslope2 |
|---|
| 175 | akz (ji,jj+jp,jk+kp) = akz (ji,jj+jp,jk+kp) + zah * r1_e2v(ji,jj) & |
|---|
| 176 | & * r1_e2v(ji,jj) * vmask(ji,jj,jk+kp) |
|---|
| 177 | ! |
|---|
| 178 | IF( ln_ldfeiv_dia ) zpsi_vw(ji,jj,jk+kp) = zpsi_vw(ji,jj,jk+kp) & |
|---|
| 179 | & + 0.25 * aeiv(ji,jj,jk) * e1v(ji,jj) * zslope_skew |
|---|
| 180 | END DO |
|---|
| 181 | END DO |
|---|
| 182 | END DO |
|---|
| 183 | END DO |
|---|
| 184 | END DO |
|---|
| 185 | ! |
|---|
| 186 | IF( ln_traldf_msc ) THEN ! stabilizing vertical diffusivity coefficient |
|---|
| 187 | ! |
|---|
| 188 | IF( ln_traldf_blp ) THEN ! bilaplacian operator |
|---|
| 189 | DO jk = 2, jpkm1 |
|---|
| 190 | DO jj = 1, jpjm1 |
|---|
| 191 | DO ji = 1, fs_jpim1 |
|---|
| 192 | akz(ji,jj,jk) = 16._wp * ah_wslp2(ji,jj,jk) & |
|---|
| 193 | & * ( akz(ji,jj,jk) + ah_wslp2(ji,jj,jk) / ( e3w_n(ji,jj,jk) * e3w_n(ji,jj,jk) ) ) |
|---|
| 194 | END DO |
|---|
| 195 | END DO |
|---|
| 196 | END DO |
|---|
| 197 | ELSEIF( ln_traldf_lap ) THEN ! laplacian operator |
|---|
| 198 | DO jk = 2, jpkm1 |
|---|
| 199 | DO jj = 1, jpjm1 |
|---|
| 200 | DO ji = 1, fs_jpim1 |
|---|
| 201 | ze3w_2 = e3w_n(ji,jj,jk) * e3w_n(ji,jj,jk) |
|---|
| 202 | zcoef0 = z2dt * ( akz(ji,jj,jk) + ah_wslp2(ji,jj,jk) / ze3w_2 ) |
|---|
| 203 | akz(ji,jj,jk) = MAX( zcoef0 - 0.5_wp , 0._wp ) * ze3w_2 * z1_2dt |
|---|
| 204 | END DO |
|---|
| 205 | END DO |
|---|
| 206 | END DO |
|---|
| 207 | ENDIF |
|---|
| 208 | ! |
|---|
| 209 | ELSE ! 33 flux set to zero with akz=ah_wslp2 ==>> computed in full implicit |
|---|
| 210 | akz(:,:,:) = ah_wslp2(:,:,:) |
|---|
| 211 | ENDIF |
|---|
| 212 | ! |
|---|
| 213 | IF( ln_ldfeiv_dia .AND. cdtype == 'TRA' ) CALL ldf_eiv_dia( zpsi_uw, zpsi_vw ) |
|---|
| 214 | ! |
|---|
| 215 | ENDIF !== end 1st pass only ==! |
|---|
| 216 | ! |
|---|
| 217 | ! ! =========== |
|---|
| 218 | DO jn = 1, kjpt ! tracer loop |
|---|
| 219 | ! ! =========== |
|---|
| 220 | ! Zero fluxes for each tracer |
|---|
| 221 | !!gm this should probably be done outside the jn loop |
|---|
| 222 | ztfw(:,:,:) = 0._wp |
|---|
| 223 | zftu(:,:,:) = 0._wp |
|---|
| 224 | zftv(:,:,:) = 0._wp |
|---|
| 225 | ! |
|---|
| 226 | DO jk = 1, jpkm1 !== before lateral T & S gradients at T-level jk ==! |
|---|
| 227 | DO jj = 1, jpjm1 |
|---|
| 228 | DO ji = 1, fs_jpim1 ! vector opt. |
|---|
| 229 | zdit(ji,jj,jk) = ( ptb(ji+1,jj ,jk,jn) - ptb(ji,jj,jk,jn) ) * umask(ji,jj,jk) |
|---|
| 230 | zdjt(ji,jj,jk) = ( ptb(ji ,jj+1,jk,jn) - ptb(ji,jj,jk,jn) ) * vmask(ji,jj,jk) |
|---|
| 231 | END DO |
|---|
| 232 | END DO |
|---|
| 233 | END DO |
|---|
| 234 | IF( ln_zps .AND. l_grad_zps ) THEN ! partial steps: correction at top/bottom ocean level |
|---|
| 235 | DO jj = 1, jpjm1 ! bottom level |
|---|
| 236 | DO ji = 1, fs_jpim1 ! vector opt. |
|---|
| 237 | zdit(ji,jj,mbku(ji,jj)) = pgu(ji,jj,jn) |
|---|
| 238 | zdjt(ji,jj,mbkv(ji,jj)) = pgv(ji,jj,jn) |
|---|
| 239 | END DO |
|---|
| 240 | END DO |
|---|
| 241 | IF( ln_isfcav ) THEN ! top level (ocean cavities only) |
|---|
| 242 | DO jj = 1, jpjm1 |
|---|
| 243 | DO ji = 1, fs_jpim1 ! vector opt. |
|---|
| 244 | IF( miku(ji,jj) > 1 ) zdit(ji,jj,miku(ji,jj) ) = pgui(ji,jj,jn) |
|---|
| 245 | IF( mikv(ji,jj) > 1 ) zdjt(ji,jj,mikv(ji,jj) ) = pgvi(ji,jj,jn) |
|---|
| 246 | END DO |
|---|
| 247 | END DO |
|---|
| 248 | ENDIF |
|---|
| 249 | ENDIF |
|---|
| 250 | ! |
|---|
| 251 | !!---------------------------------------------------------------------- |
|---|
| 252 | !! II - horizontal trend (full) |
|---|
| 253 | !!---------------------------------------------------------------------- |
|---|
| 254 | ! |
|---|
| 255 | DO jk = 1, jpkm1 |
|---|
| 256 | ! !== Vertical tracer gradient at level jk and jk+1 |
|---|
| 257 | zdkt3d(:,:,1) = ( ptb(:,:,jk,jn) - ptb(:,:,jk+1,jn) ) * tmask(:,:,jk+1) |
|---|
| 258 | ! |
|---|
| 259 | ! ! surface boundary condition: zdkt3d(jk=0)=zdkt3d(jk=1) |
|---|
| 260 | IF( jk == 1 ) THEN ; zdkt3d(:,:,0) = zdkt3d(:,:,1) |
|---|
| 261 | ELSE ; zdkt3d(:,:,0) = ( ptb(:,:,jk-1,jn) - ptb(:,:,jk,jn) ) * tmask(:,:,jk) |
|---|
| 262 | ENDIF |
|---|
| 263 | ! |
|---|
| 264 | zaei_slp = 0._wp |
|---|
| 265 | ! |
|---|
| 266 | IF( ln_botmix_triad ) THEN |
|---|
| 267 | DO ip = 0, 1 !== Horizontal & vertical fluxes |
|---|
| 268 | DO kp = 0, 1 |
|---|
| 269 | DO jj = 1, jpjm1 |
|---|
| 270 | DO ji = 1, fs_jpim1 |
|---|
| 271 | ze1ur = r1_e1u(ji,jj) |
|---|
| 272 | zdxt = zdit(ji,jj,jk) * ze1ur |
|---|
| 273 | ze3wr = 1._wp / e3w_n(ji+ip,jj,jk+kp) |
|---|
| 274 | zdzt = zdkt3d(ji+ip,jj,kp) * ze3wr |
|---|
| 275 | zslope_skew = triadi_g(ji+ip,jj,jk,1-ip,kp) |
|---|
| 276 | zslope_iso = triadi (ji+ip,jj,jk,1-ip,kp) |
|---|
| 277 | ! |
|---|
| 278 | zbu = 0.25_wp * e1e2u(ji,jj) * e3u_n(ji,jj,jk) |
|---|
| 279 | ! ln_botmix_triad is .T. don't mask zah for bottom half cells !!gm ????? ahu is masked.... |
|---|
| 280 | zah = pahu(ji,jj,jk) |
|---|
| 281 | zah_slp = zah * zslope_iso |
|---|
| 282 | IF( ln_ldfeiv ) zaei_slp = aeiu(ji,jj,jk) * zslope_skew |
|---|
| 283 | zftu(ji ,jj,jk ) = zftu(ji ,jj,jk ) - ( zah * zdxt + (zah_slp - zaei_slp) * zdzt ) * zbu * ze1ur |
|---|
| 284 | ztfw(ji+ip,jj,jk+kp) = ztfw(ji+ip,jj,jk+kp) - ( zah_slp + zaei_slp) * zdxt * zbu * ze3wr |
|---|
| 285 | END DO |
|---|
| 286 | END DO |
|---|
| 287 | END DO |
|---|
| 288 | END DO |
|---|
| 289 | ! |
|---|
| 290 | DO jp = 0, 1 |
|---|
| 291 | DO kp = 0, 1 |
|---|
| 292 | DO jj = 1, jpjm1 |
|---|
| 293 | DO ji = 1, fs_jpim1 |
|---|
| 294 | ze2vr = r1_e2v(ji,jj) |
|---|
| 295 | zdyt = zdjt(ji,jj,jk) * ze2vr |
|---|
| 296 | ze3wr = 1._wp / e3w_n(ji,jj+jp,jk+kp) |
|---|
| 297 | zdzt = zdkt3d(ji,jj+jp,kp) * ze3wr |
|---|
| 298 | zslope_skew = triadj_g(ji,jj+jp,jk,1-jp,kp) |
|---|
| 299 | zslope_iso = triadj(ji,jj+jp,jk,1-jp,kp) |
|---|
| 300 | zbv = 0.25_wp * e1e2v(ji,jj) * e3v_n(ji,jj,jk) |
|---|
| 301 | ! ln_botmix_triad is .T. don't mask zah for bottom half cells !!gm ????? ahv is masked... |
|---|
| 302 | zah = pahv(ji,jj,jk) |
|---|
| 303 | zah_slp = zah * zslope_iso |
|---|
| 304 | IF( ln_ldfeiv ) zaei_slp = aeiv(ji,jj,jk) * zslope_skew |
|---|
| 305 | zftv(ji,jj ,jk ) = zftv(ji,jj ,jk ) - ( zah * zdyt + (zah_slp - zaei_slp) * zdzt ) * zbv * ze2vr |
|---|
| 306 | ztfw(ji,jj+jp,jk+kp) = ztfw(ji,jj+jp,jk+kp) - ( zah_slp + zaei_slp ) * zdyt * zbv * ze3wr |
|---|
| 307 | END DO |
|---|
| 308 | END DO |
|---|
| 309 | END DO |
|---|
| 310 | END DO |
|---|
| 311 | ! |
|---|
| 312 | ELSE |
|---|
| 313 | ! |
|---|
| 314 | DO ip = 0, 1 !== Horizontal & vertical fluxes |
|---|
| 315 | DO kp = 0, 1 |
|---|
| 316 | DO jj = 1, jpjm1 |
|---|
| 317 | DO ji = 1, fs_jpim1 |
|---|
| 318 | ze1ur = r1_e1u(ji,jj) |
|---|
| 319 | zdxt = zdit(ji,jj,jk) * ze1ur |
|---|
| 320 | ze3wr = 1._wp / e3w_n(ji+ip,jj,jk+kp) |
|---|
| 321 | zdzt = zdkt3d(ji+ip,jj,kp) * ze3wr |
|---|
| 322 | zslope_skew = triadi_g(ji+ip,jj,jk,1-ip,kp) |
|---|
| 323 | zslope_iso = triadi(ji+ip,jj,jk,1-ip,kp) |
|---|
| 324 | ! |
|---|
| 325 | zbu = 0.25_wp * e1e2u(ji,jj) * e3u_n(ji,jj,jk) |
|---|
| 326 | ! ln_botmix_triad is .F. mask zah for bottom half cells |
|---|
| 327 | zah = pahu(ji,jj,jk) * umask(ji,jj,jk+kp) ! pahu(ji+ip,jj,jk) ===>> ???? |
|---|
| 328 | zah_slp = zah * zslope_iso |
|---|
| 329 | IF( ln_ldfeiv ) zaei_slp = aeiu(ji,jj,jk) * zslope_skew ! aeit(ji+ip,jj,jk)*zslope_skew |
|---|
| 330 | zftu(ji ,jj,jk ) = zftu(ji ,jj,jk ) - ( zah * zdxt + (zah_slp - zaei_slp) * zdzt ) * zbu * ze1ur |
|---|
| 331 | ztfw(ji+ip,jj,jk+kp) = ztfw(ji+ip,jj,jk+kp) - (zah_slp + zaei_slp) * zdxt * zbu * ze3wr |
|---|
| 332 | END DO |
|---|
| 333 | END DO |
|---|
| 334 | END DO |
|---|
| 335 | END DO |
|---|
| 336 | ! |
|---|
| 337 | DO jp = 0, 1 |
|---|
| 338 | DO kp = 0, 1 |
|---|
| 339 | DO jj = 1, jpjm1 |
|---|
| 340 | DO ji = 1, fs_jpim1 |
|---|
| 341 | ze2vr = r1_e2v(ji,jj) |
|---|
| 342 | zdyt = zdjt(ji,jj,jk) * ze2vr |
|---|
| 343 | ze3wr = 1._wp / e3w_n(ji,jj+jp,jk+kp) |
|---|
| 344 | zdzt = zdkt3d(ji,jj+jp,kp) * ze3wr |
|---|
| 345 | zslope_skew = triadj_g(ji,jj+jp,jk,1-jp,kp) |
|---|
| 346 | zslope_iso = triadj(ji,jj+jp,jk,1-jp,kp) |
|---|
| 347 | zbv = 0.25_wp * e1e2v(ji,jj) * e3v_n(ji,jj,jk) |
|---|
| 348 | ! ln_botmix_triad is .F. mask zah for bottom half cells |
|---|
| 349 | zah = pahv(ji,jj,jk) * vmask(ji,jj,jk+kp) ! pahv(ji,jj+jp,jk) ???? |
|---|
| 350 | zah_slp = zah * zslope_iso |
|---|
| 351 | IF( ln_ldfeiv ) zaei_slp = aeiv(ji,jj,jk) * zslope_skew ! aeit(ji,jj+jp,jk)*zslope_skew |
|---|
| 352 | zftv(ji,jj,jk) = zftv(ji,jj,jk) - ( zah * zdyt + (zah_slp - zaei_slp) * zdzt ) * zbv * ze2vr |
|---|
| 353 | ztfw(ji,jj+jp,jk+kp) = ztfw(ji,jj+jp,jk+kp) - (zah_slp + zaei_slp) * zdyt * zbv * ze3wr |
|---|
| 354 | END DO |
|---|
| 355 | END DO |
|---|
| 356 | END DO |
|---|
| 357 | END DO |
|---|
| 358 | ENDIF |
|---|
| 359 | ! !== horizontal divergence and add to the general trend ==! |
|---|
| 360 | DO jj = 2 , jpjm1 |
|---|
| 361 | DO ji = fs_2, fs_jpim1 ! vector opt. |
|---|
| 362 | pta(ji,jj,jk,jn) = pta(ji,jj,jk,jn) + zsign * ( zftu(ji-1,jj,jk) - zftu(ji,jj,jk) & |
|---|
| 363 | & + zftv(ji,jj-1,jk) - zftv(ji,jj,jk) ) & |
|---|
| 364 | & / ( e1e2t(ji,jj) * e3t_n(ji,jj,jk) ) |
|---|
| 365 | END DO |
|---|
| 366 | END DO |
|---|
| 367 | ! |
|---|
| 368 | END DO |
|---|
| 369 | ! |
|---|
| 370 | ! !== add the vertical 33 flux ==! |
|---|
| 371 | IF( ln_traldf_lap ) THEN ! laplacian case: eddy coef = ah_wslp2 - akz |
|---|
| 372 | DO jk = 2, jpkm1 |
|---|
| 373 | DO jj = 1, jpjm1 |
|---|
| 374 | DO ji = fs_2, fs_jpim1 |
|---|
| 375 | ztfw(ji,jj,jk) = ztfw(ji,jj,jk) - e1e2t(ji,jj) / e3w_n(ji,jj,jk) * tmask(ji,jj,jk) & |
|---|
| 376 | & * ( ah_wslp2(ji,jj,jk) - akz(ji,jj,jk) ) & |
|---|
| 377 | & * ( ptb(ji,jj,jk-1,jn) - ptb(ji,jj,jk,jn) ) |
|---|
| 378 | END DO |
|---|
| 379 | END DO |
|---|
| 380 | END DO |
|---|
| 381 | ELSE ! bilaplacian |
|---|
| 382 | SELECT CASE( kpass ) |
|---|
| 383 | CASE( 1 ) ! 1st pass : eddy coef = ah_wslp2 |
|---|
| 384 | DO jk = 2, jpkm1 |
|---|
| 385 | DO jj = 1, jpjm1 |
|---|
| 386 | DO ji = fs_2, fs_jpim1 |
|---|
| 387 | ztfw(ji,jj,jk) = ztfw(ji,jj,jk) - e1e2t(ji,jj) / e3w_n(ji,jj,jk) * tmask(ji,jj,jk) & |
|---|
| 388 | & * ah_wslp2(ji,jj,jk) * ( ptb(ji,jj,jk-1,jn) - ptb(ji,jj,jk,jn) ) |
|---|
| 389 | END DO |
|---|
| 390 | END DO |
|---|
| 391 | END DO |
|---|
| 392 | CASE( 2 ) ! 2nd pass : eddy flux = ah_wslp2 and akz applied on ptb and ptbb gradients, resp. |
|---|
| 393 | DO jk = 2, jpkm1 |
|---|
| 394 | DO jj = 1, jpjm1 |
|---|
| 395 | DO ji = fs_2, fs_jpim1 |
|---|
| 396 | ztfw(ji,jj,jk) = ztfw(ji,jj,jk) - e1e2t(ji,jj) / e3w_n(ji,jj,jk) * tmask(ji,jj,jk) & |
|---|
| 397 | & * ( ah_wslp2(ji,jj,jk) * ( ptb (ji,jj,jk-1,jn) - ptb (ji,jj,jk,jn) ) & |
|---|
| 398 | & + akz (ji,jj,jk) * ( ptbb(ji,jj,jk-1,jn) - ptbb(ji,jj,jk,jn) ) ) |
|---|
| 399 | END DO |
|---|
| 400 | END DO |
|---|
| 401 | END DO |
|---|
| 402 | END SELECT |
|---|
| 403 | ENDIF |
|---|
| 404 | ! |
|---|
| 405 | DO jk = 1, jpkm1 !== Divergence of vertical fluxes added to pta ==! |
|---|
| 406 | DO jj = 2, jpjm1 |
|---|
| 407 | DO ji = fs_2, fs_jpim1 ! vector opt. |
|---|
| 408 | pta(ji,jj,jk,jn) = pta(ji,jj,jk,jn) + zsign * ( ztfw(ji,jj,jk+1) - ztfw(ji,jj,jk) ) & |
|---|
| 409 | & / ( e1e2t(ji,jj) * e3t_n(ji,jj,jk) ) |
|---|
| 410 | END DO |
|---|
| 411 | END DO |
|---|
| 412 | END DO |
|---|
| 413 | ! |
|---|
| 414 | IF( ( kpass == 1 .AND. ln_traldf_lap ) .OR. & !== first pass only ( laplacian) ==! |
|---|
| 415 | ( kpass == 2 .AND. ln_traldf_blp ) ) THEN !== 2nd pass (bilaplacian) ==! |
|---|
| 416 | ! |
|---|
| 417 | ! ! "Poleward" diffusive heat or salt transports (T-S case only) |
|---|
| 418 | IF( cdtype == 'TRA' .AND. ln_diaptr ) THEN |
|---|
| 419 | IF( jn == jp_tem) htr_ldf(:) = ptr_sj( zftv(:,:,:) ) ! 3.3 names |
|---|
| 420 | IF( jn == jp_sal) str_ldf(:) = ptr_sj( zftv(:,:,:) ) |
|---|
| 421 | ENDIF |
|---|
| 422 | ! |
|---|
| 423 | IF( iom_use("udiff_heattr") .OR. iom_use("vdiff_heattr") ) THEN |
|---|
| 424 | ! |
|---|
| 425 | IF( cdtype == 'TRA' .AND. jn == jp_tem ) THEN |
|---|
| 426 | z2d(:,:) = zftu(ji,jj,1) |
|---|
| 427 | DO jk = 2, jpkm1 |
|---|
| 428 | DO jj = 2, jpjm1 |
|---|
| 429 | DO ji = fs_2, fs_jpim1 ! vector opt. |
|---|
| 430 | z2d(ji,jj) = z2d(ji,jj) + zftu(ji,jj,jk) |
|---|
| 431 | END DO |
|---|
| 432 | END DO |
|---|
| 433 | END DO |
|---|
| 434 | z2d(:,:) = rau0_rcp * z2d(:,:) |
|---|
| 435 | CALL lbc_lnk( z2d, 'U', -1. ) |
|---|
| 436 | CALL iom_put( "udiff_heattr", z2d ) ! heat i-transport |
|---|
| 437 | ! |
|---|
| 438 | z2d(:,:) = zftv(ji,jj,1) |
|---|
| 439 | DO jk = 2, jpkm1 |
|---|
| 440 | DO jj = 2, jpjm1 |
|---|
| 441 | DO ji = fs_2, fs_jpim1 ! vector opt. |
|---|
| 442 | z2d(ji,jj) = z2d(ji,jj) + zftv(ji,jj,jk) |
|---|
| 443 | END DO |
|---|
| 444 | END DO |
|---|
| 445 | END DO |
|---|
| 446 | z2d(:,:) = rau0_rcp * z2d(:,:) |
|---|
| 447 | CALL lbc_lnk( z2d, 'V', -1. ) |
|---|
| 448 | CALL iom_put( "vdiff_heattr", z2d ) ! heat j-transport |
|---|
| 449 | ENDIF |
|---|
| 450 | ! |
|---|
| 451 | ENDIF |
|---|
| 452 | ! |
|---|
| 453 | ENDIF !== end pass selection ==! |
|---|
| 454 | ! |
|---|
| 455 | ! ! =============== |
|---|
| 456 | END DO ! end tracer loop |
|---|
| 457 | ! ! =============== |
|---|
| 458 | ! |
|---|
| 459 | CALL wrk_dealloc( jpi,jpj, z2d ) |
|---|
| 460 | CALL wrk_dealloc( jpi,jpj,jpk, zdit, zdjt, zftu, zftv, ztfw, zpsi_uw, zpsi_vw ) |
|---|
| 461 | ! |
|---|
| 462 | IF( nn_timing == 1 ) CALL timing_stop('tra_ldf_triad') |
|---|
| 463 | ! |
|---|
| 464 | END SUBROUTINE tra_ldf_triad |
|---|
| 465 | |
|---|
| 466 | !!============================================================================== |
|---|
| 467 | END MODULE traldf_triad |
|---|
