New URL for NEMO forge!   http://forge.nemo-ocean.eu

Since March 2022 along with NEMO 4.2 release, the code development moved to a self-hosted GitLab.
This present forge is now archived and remained online for history.
tranxt.F90 in branches/2015/dev_r5836_NOC3_vvl_by_default/NEMOGCM/NEMO/OPA_SRC/TRA – NEMO

source: branches/2015/dev_r5836_NOC3_vvl_by_default/NEMOGCM/NEMO/OPA_SRC/TRA/tranxt.F90 @ 6004

Last change on this file since 6004 was 6004, checked in by gm, 8 years ago

#1613: vvl by default, step III: Merge with the trunk (free surface simplification) (see wiki)
  • Property svn:keywords set to Id
File size: 16.5 KB
Line 
1MODULE tranxt
2   !!======================================================================
3   !!                       ***  MODULE  tranxt  ***
4   !! Ocean active tracers:  time stepping on temperature and salinity
5   !!======================================================================
6   !! History :  OPA  !  1991-11  (G. Madec)  Original code
7   !!            7.0  !  1993-03  (M. Guyon)  symetrical conditions
8   !!            8.0  !  1996-02  (G. Madec & M. Imbard)  opa release 8.0
9   !!             -   !  1996-04  (A. Weaver)  Euler forward step
10   !!            8.2  !  1999-02  (G. Madec, N. Grima)  semi-implicit pressure grad.
11   !!  NEMO      1.0  !  2002-08  (G. Madec)  F90: Free form and module
12   !!             -   !  2002-11  (C. Talandier, A-M Treguier) Open boundaries
13   !!             -   !  2005-04  (C. Deltel) Add Asselin trend in the ML budget
14   !!            2.0  !  2006-02  (L. Debreu, C. Mazauric) Agrif implementation
15   !!            3.0  !  2008-06  (G. Madec)  time stepping always done in trazdf
16   !!            3.1  !  2009-02  (G. Madec, R. Benshila)  re-introduce the vvl option
17   !!            3.3  !  2010-04  (M. Leclair, G. Madec)  semi-implicit hpg with asselin filter + modified LF-RA
18   !!             -   !  2010-05  (C. Ethe, G. Madec)  merge TRC-TRA
19   !!----------------------------------------------------------------------
20
21   !!----------------------------------------------------------------------
22   !!   tra_nxt       : time stepping on tracers
23   !!   tra_nxt_fix   : time stepping on tracers : fixed    volume case
24   !!   tra_nxt_vvl   : time stepping on tracers : variable volume case
25   !!----------------------------------------------------------------------
26   USE oce             ! ocean dynamics and tracers variables
27   USE dom_oce         ! ocean space and time domain variables
28   USE sbc_oce         ! surface boundary condition: ocean
29   USE sbcrnf          ! river runoffs
30   USE sbcisf          ! ice shelf melting/freezing
31   USE zdf_oce         ! ocean vertical mixing
32   USE domvvl          ! variable volume
33   USE trd_oce         ! trends: ocean variables
34   USE trdtra          ! trends manager: tracers
35   USE traqsr          ! penetrative solar radiation (needed for nksr)
36   USE phycst          ! physical constant
37   USE ldftra          ! lateral physics on tracers
38   USE ldfslp
39   USE bdy_oce         ! BDY open boundary condition variables
40   USE bdytra          ! open boundary condition (bdy_tra routine)
41   !
42   USE in_out_manager  ! I/O manager
43   USE lbclnk          ! ocean lateral boundary conditions (or mpp link)
44   USE prtctl          ! Print control
45   USE wrk_nemo        ! Memory allocation
46   USE timing          ! Timing
47#if defined key_agrif
48   USE agrif_opa_interp
49#endif
50
51   IMPLICIT NONE
52   PRIVATE
53
54   PUBLIC   tra_nxt       ! routine called by step.F90
55   PUBLIC   tra_nxt_fix   ! to be used in trcnxt
56   PUBLIC   tra_nxt_vvl   ! to be used in trcnxt
57
58   !! * Substitutions
59#  include "vectopt_loop_substitute.h90"
60   !!----------------------------------------------------------------------
61   !! NEMO/OPA 3.3 , NEMO-Consortium (2010)
62   !! $Id$
63   !! Software governed by the CeCILL licence     (NEMOGCM/NEMO_CeCILL.txt)
64   !!----------------------------------------------------------------------
65CONTAINS
66
67   SUBROUTINE tra_nxt( kt )
68      !!----------------------------------------------------------------------
69      !!                   ***  ROUTINE tranxt  ***
70      !!
71      !! ** Purpose :   Apply the boundary condition on the after temperature 
72      !!             and salinity fields, achieved the time stepping by adding
73      !!             the Asselin filter on now fields and swapping the fields.
74      !!
75      !! ** Method  :   At this stage of the computation, ta and sa are the
76      !!             after temperature and salinity as the time stepping has
77      !!             been performed in trazdf_imp or trazdf_exp module.
78      !!
79      !!              - Apply lateral boundary conditions on (ta,sa)
80      !!             at the local domain   boundaries through lbc_lnk call,
81      !!             at the one-way open boundaries (lk_bdy=T),
82      !!             at the AGRIF zoom   boundaries (lk_agrif=T)
83      !!
84      !!              - Update lateral boundary conditions on AGRIF children
85      !!             domains (lk_agrif=T)
86      !!
87      !! ** Action  : - tsb & tsn ready for the next time step
88      !!----------------------------------------------------------------------
89      INTEGER, INTENT(in) ::   kt    ! ocean time-step index
90      !!
91      INTEGER  ::   ji, jj, jk, jn   ! dummy loop indices
92      REAL(wp) ::   zfact            ! local scalars
93      REAL(wp), POINTER, DIMENSION(:,:,:) ::  ztrdt, ztrds
94      !!----------------------------------------------------------------------
95      !
96      IF( nn_timing == 1 )  CALL timing_start( 'tra_nxt')
97      !
98      IF( kt == nit000 ) THEN
99         IF(lwp) WRITE(numout,*)
100         IF(lwp) WRITE(numout,*) 'tra_nxt : achieve the time stepping by Asselin filter and array swap'
101         IF(lwp) WRITE(numout,*) '~~~~~~~'
102      ENDIF
103
104      ! Update after tracer on domain lateral boundaries
105      !
106#if defined key_agrif
107      CALL Agrif_tra                     ! AGRIF zoom boundaries
108#endif
109      !
110      CALL lbc_lnk( tsa(:,:,:,jp_tem), 'T', 1._wp )      ! local domain boundaries  (T-point, unchanged sign)
111      CALL lbc_lnk( tsa(:,:,:,jp_sal), 'T', 1._wp )
112      !
113#if defined key_bdy 
114      IF( lk_bdy )   CALL bdy_tra( kt )  ! BDY open boundaries
115#endif
116 
117      ! set time step size (Euler/Leapfrog)
118      IF( neuler == 0 .AND. kt == nit000 ) THEN   ;   r2dtra(:) =     rdttra(:)      ! at nit000             (Euler)
119      ELSEIF( kt <= nit000 + 1 )           THEN   ;   r2dtra(:) = 2._wp* rdttra(:)      ! at nit000 or nit000+1 (Leapfrog)
120      ENDIF
121
122      ! trends computation initialisation
123      IF( l_trdtra )   THEN                    ! store now fields before applying the Asselin filter
124         CALL wrk_alloc( jpi, jpj, jpk, ztrdt, ztrds )
125         ztrdt(:,:,:) = tsn(:,:,:,jp_tem) 
126         ztrds(:,:,:) = tsn(:,:,:,jp_sal)
127         IF( ln_traldf_iso ) THEN              ! diagnose the "pure" Kz diffusive trend
128            CALL trd_tra( kt, 'TRA', jp_tem, jptra_zdfp, ztrdt )
129            CALL trd_tra( kt, 'TRA', jp_sal, jptra_zdfp, ztrds )
130         ENDIF
131      ENDIF
132
133      IF( neuler == 0 .AND. kt == nit000 ) THEN       ! Euler time-stepping at first time-step (only swap)
134         DO jn = 1, jpts
135            DO jk = 1, jpkm1
136               tsn(:,:,jk,jn) = tsa(:,:,jk,jn)   
137            END DO
138         END DO
139         !
140      ELSE                                            ! Leap-Frog + Asselin filter time stepping
141         !
142         IF( ln_linssh ) THEN   ;   CALL tra_nxt_fix( kt, nit000,         'TRA', tsb, tsn, tsa, jpts )  ! linear free surface
143         ELSE                   ;   CALL tra_nxt_vvl( kt, nit000, rdttra, 'TRA', tsb, tsn, tsa,   &
144           &                                                                sbc_tsc, sbc_tsc_b, jpts )  ! non-linear free surface
145         ENDIF
146         !
147         DO jn = 1, jpts
148            CALL lbc_lnk( tsb(:,:,:,jn), 'T', 1._wp ) 
149            CALL lbc_lnk( tsn(:,:,:,jn), 'T', 1._wp )
150         END DO
151      ENDIF     
152      !
153      IF( l_trdtra ) THEN      ! trend of the Asselin filter (tb filtered - tb)/dt     
154         DO jk = 1, jpkm1
155            zfact = 1._wp / r2dtra(jk)             
156            ztrdt(:,:,jk) = ( tsb(:,:,jk,jp_tem) - ztrdt(:,:,jk) ) * zfact
157            ztrds(:,:,jk) = ( tsb(:,:,jk,jp_sal) - ztrds(:,:,jk) ) * zfact
158         END DO
159         CALL trd_tra( kt, 'TRA', jp_tem, jptra_atf, ztrdt )
160         CALL trd_tra( kt, 'TRA', jp_sal, jptra_atf, ztrds )
161         CALL wrk_dealloc( jpi, jpj, jpk, ztrdt, ztrds )
162      END IF
163      !
164      !                        ! control print
165      IF(ln_ctl)   CALL prt_ctl( tab3d_1=tsn(:,:,:,jp_tem), clinfo1=' nxt  - Tn: ', mask1=tmask,   &
166         &                       tab3d_2=tsn(:,:,:,jp_sal), clinfo2=       ' Sn: ', mask2=tmask )
167      !
168      IF( nn_timing == 1 )   CALL timing_stop('tra_nxt')
169      !
170   END SUBROUTINE tra_nxt
171
172
173   SUBROUTINE tra_nxt_fix( kt, kit000, cdtype, ptb, ptn, pta, kjpt )
174      !!----------------------------------------------------------------------
175      !!                   ***  ROUTINE tra_nxt_fix  ***
176      !!
177      !! ** Purpose :   fixed volume: apply the Asselin time filter and
178      !!                swap the tracer fields.
179      !!
180      !! ** Method  : - Apply a Asselin time filter on now fields.
181      !!              - swap tracer fields to prepare the next time_step.
182      !!
183      !! ** Action  : - tsb & tsn ready for the next time step
184      !!----------------------------------------------------------------------
185      INTEGER                              , INTENT(in   ) ::  kt        ! ocean time-step index
186      INTEGER                              , INTENT(in   ) ::  kit000    ! first time step index
187      CHARACTER(len=3)                     , INTENT(in   ) ::  cdtype    ! =TRA or TRC (tracer indicator)
188      INTEGER                              , INTENT(in   ) ::  kjpt      ! number of tracers
189      REAL(wp), DIMENSION(jpi,jpj,jpk,kjpt), INTENT(inout) ::  ptb       ! before tracer fields
190      REAL(wp), DIMENSION(jpi,jpj,jpk,kjpt), INTENT(inout) ::  ptn       ! now tracer fields
191      REAL(wp), DIMENSION(jpi,jpj,jpk,kjpt), INTENT(inout) ::  pta       ! tracer trend
192      !
193      INTEGER  ::   ji, jj, jk, jn   ! dummy loop indices
194      REAL(wp) ::   ztn, ztd         ! local scalars
195      !!----------------------------------------------------------------------
196      !
197      IF( kt == kit000 )  THEN
198         IF(lwp) WRITE(numout,*)
199         IF(lwp) WRITE(numout,*) 'tra_nxt_fix : time stepping', cdtype
200         IF(lwp) WRITE(numout,*) '~~~~~~~~~~~'
201      ENDIF
202      !
203      DO jn = 1, kjpt
204         !
205         DO jk = 1, jpkm1
206            DO jj = 2, jpjm1
207               DO ji = fs_2, fs_jpim1
208                  ztn = ptn(ji,jj,jk,jn)                                   
209                  ztd = pta(ji,jj,jk,jn) - 2._wp * ztn + ptb(ji,jj,jk,jn)  ! time laplacian on tracers
210                  !
211                  ptb(ji,jj,jk,jn) = ztn + atfp * ztd                      ! ptb <-- filtered ptn
212                  ptn(ji,jj,jk,jn) = pta(ji,jj,jk,jn)                      ! ptn <-- pta
213               END DO
214           END DO
215         END DO
216         !
217      END DO
218      !
219   END SUBROUTINE tra_nxt_fix
220
221
222   SUBROUTINE tra_nxt_vvl( kt, kit000, p2dt, cdtype, ptb, ptn, pta, psbc_tc, psbc_tc_b, kjpt )
223      !!----------------------------------------------------------------------
224      !!                   ***  ROUTINE tra_nxt_vvl  ***
225      !!
226      !! ** Purpose :   Time varying volume: apply the Asselin time filter 
227      !!                and swap the tracer fields.
228      !!
229      !! ** Method  : - Apply a thickness weighted Asselin time filter on now fields.
230      !!              - swap tracer fields to prepare the next time_step.
231      !!             tb  = ( e3t_n*tn + atfp*[ e3t_b*tb - 2 e3t_n*tn + e3t_a*ta ] )
232      !!                  /( e3t_n    + atfp*[ e3t_b    - 2 e3t_n    + e3t_a    ] )
233      !!             tn  = ta
234      !!
235      !! ** Action  : - tsb & tsn ready for the next time step
236      !!----------------------------------------------------------------------
237      INTEGER                              , INTENT(in   ) ::  kt        ! ocean time-step index
238      INTEGER                              , INTENT(in   ) ::  kit000    ! first time step index
239      REAL(wp), DIMENSION(jpk)             , INTENT(in   ) ::  p2dt      ! time-step
240      CHARACTER(len=3)                     , INTENT(in   ) ::  cdtype    ! =TRA or TRC (tracer indicator)
241      INTEGER                              , INTENT(in   ) ::  kjpt      ! number of tracers
242      REAL(wp), DIMENSION(jpi,jpj,jpk,kjpt), INTENT(inout) ::  ptb       ! before tracer fields
243      REAL(wp), DIMENSION(jpi,jpj,jpk,kjpt), INTENT(inout) ::  ptn       ! now tracer fields
244      REAL(wp), DIMENSION(jpi,jpj,jpk,kjpt), INTENT(inout) ::  pta       ! tracer trend
245      REAL(wp), DIMENSION(jpi,jpj    ,kjpt), INTENT(in   ) ::  psbc_tc   ! surface tracer content
246      REAL(wp), DIMENSION(jpi,jpj    ,kjpt), INTENT(in   ) ::  psbc_tc_b ! before surface tracer content
247      !
248      LOGICAL  ::   ll_traqsr, ll_rnf, ll_isf   ! local logical
249      INTEGER  ::   ji, jj, jk, jn              ! dummy loop indices
250      REAL(wp) ::   zfact1, ztc_a , ztc_n , ztc_b , ztc_f , ztc_d    ! local scalar
251      REAL(wp) ::   zfact2, ze3t_b, ze3t_n, ze3t_a, ze3t_f, ze3t_d   !   -      -
252      !!----------------------------------------------------------------------
253      !
254      IF( kt == kit000 )  THEN
255         IF(lwp) WRITE(numout,*)
256         IF(lwp) WRITE(numout,*) 'tra_nxt_vvl : time stepping', cdtype
257         IF(lwp) WRITE(numout,*) '~~~~~~~~~~~'
258      ENDIF
259      !
260      IF( cdtype == 'TRA' )  THEN   ! active  tracers case
261         ll_traqsr  = ln_traqsr        ! solar penetration
262         ll_rnf     = ln_rnf           ! river runoffs
263         IF( nn_isf >= 1 ) THEN
264            ll_isf = .TRUE.            ! ice shelf melting/freezing
265         ELSE
266            ll_isf = .FALSE.
267         END IF
268      ELSE                          ! passive tracers case
269         ll_traqsr  = .FALSE.          ! NO solar penetration
270         ll_rnf     = .FALSE.          ! NO river runoffs ????          !!gm BUG ? 
271         ll_isf     = .FALSE.          ! NO ice shelf melting/freezing  !!gm BUG ??
272      ENDIF
273      !
274      DO jn = 1, kjpt     
275         DO jk = 1, jpkm1
276            zfact1 = atfp * p2dt(jk)
277            zfact2 = zfact1 * r1_rau0
278            DO jj = 2, jpjm1
279               DO ji = fs_2, fs_jpim1
280                  ze3t_b = e3t_b(ji,jj,jk)
281                  ze3t_n = e3t_n(ji,jj,jk)
282                  ze3t_a = e3t_a(ji,jj,jk)
283                  !                                         ! tracer content at Before, now and after
284                  ztc_b  = ptb(ji,jj,jk,jn) * ze3t_b
285                  ztc_n  = ptn(ji,jj,jk,jn) * ze3t_n
286                  ztc_a  = pta(ji,jj,jk,jn) * ze3t_a
287                  !
288                  ze3t_d = ze3t_a - 2. * ze3t_n + ze3t_b
289                  ztc_d  = ztc_a  - 2. * ztc_n  + ztc_b
290                  !
291                  ze3t_f = ze3t_n + atfp * ze3t_d
292                  ztc_f  = ztc_n  + atfp * ztc_d
293                  !
294                  IF( jk == mikt(ji,jj) ) THEN           ! first level
295                     ze3t_f = ze3t_f - zfact2 * ( (emp_b(ji,jj)    - emp(ji,jj)   )  &
296                            &                   - (rnf_b(ji,jj)    - rnf(ji,jj)   )  &
297                            &                   + (fwfisf_b(ji,jj) - fwfisf(ji,jj))  )
298                     ztc_f  = ztc_f  - zfact1 * ( psbc_tc(ji,jj,jn) - psbc_tc_b(ji,jj,jn) )
299                  ENDIF
300                  !
301                  ! solar penetration (temperature only)
302                  IF( ll_traqsr .AND. jn == jp_tem .AND. jk <= nksr )                            & 
303                     &     ztc_f  = ztc_f  - zfact1 * ( qsr_hc(ji,jj,jk) - qsr_hc_b(ji,jj,jk) ) 
304                     !
305                  ! river runoff
306                  IF( ll_rnf .AND. jk <= nk_rnf(ji,jj) )                                          &
307                     &     ztc_f  = ztc_f  - zfact1 * ( rnf_tsc(ji,jj,jn) - rnf_tsc_b(ji,jj,jn) ) & 
308                     &                              * e3t_n(ji,jj,jk) / h_rnf(ji,jj)
309                     !
310                  ! ice shelf
311                  IF( ll_isf ) THEN
312                     ! level fully include in the Losch_2008 ice shelf boundary layer
313                     IF ( jk >= misfkt(ji,jj) .AND. jk < misfkb(ji,jj) )                          &
314                        ztc_f  = ztc_f  - zfact1 * ( risf_tsc(ji,jj,jn) - risf_tsc_b(ji,jj,jn) )  &
315                               &                 * e3t_n(ji,jj,jk) * r1_hisf_tbl (ji,jj)
316                     ! level partially include in Losch_2008 ice shelf boundary layer
317                     IF ( jk == misfkb(ji,jj) )                                                   &
318                        ztc_f  = ztc_f  - zfact1 * ( risf_tsc(ji,jj,jn) - risf_tsc_b(ji,jj,jn) )  &
319                               &                 * e3t_n(ji,jj,jk) * r1_hisf_tbl (ji,jj) * ralpha(ji,jj)
320                  END IF
321                  !
322                  ze3t_f = 1.e0 / ze3t_f
323                  ptb(ji,jj,jk,jn) = ztc_f * ze3t_f       ! ptb <-- ptn filtered
324                  ptn(ji,jj,jk,jn) = pta(ji,jj,jk,jn)     ! ptn <-- pta
325                  !
326               END DO
327            END DO
328         END DO
329         !
330      END DO
331      !
332   END SUBROUTINE tra_nxt_vvl
333
334   !!======================================================================
335END MODULE tranxt
Note: See TracBrowser for help on using the repository browser.