New URL for NEMO forge!   http://forge.nemo-ocean.eu

Since March 2022 along with NEMO 4.2 release, the code development moved to a self-hosted GitLab.
This present forge is now archived and remained online for history.
step.F90 in branches/2015/dev_r5836_NOC3_vvl_by_default/NEMOGCM/NEMO/OPA_SRC – NEMO

source: branches/2015/dev_r5836_NOC3_vvl_by_default/NEMOGCM/NEMO/OPA_SRC/step.F90 @ 5883

Last change on this file since 5883 was 5883, checked in by gm, 8 years ago

#1613: vvl by default: TRA/TRC remove optimization associated with linear free surface

  • Property svn:keywords set to Id
File size: 23.7 KB
Line 
1MODULE step
2   !!======================================================================
3   !!                       ***  MODULE step  ***
4   !! Time-stepping    : manager of the ocean, tracer and ice time stepping
5   !!======================================================================
6   !! History :  OPA  !  1991-03  (G. Madec)  Original code
7   !!             -   !  1991-11  (G. Madec)
8   !!             -   !  1992-06  (M. Imbard)  add a first output record
9   !!             -   !  1996-04  (G. Madec)  introduction of dynspg
10   !!             -   !  1996-04  (M.A. Foujols)  introduction of passive tracer
11   !!            8.0  !  1997-06  (G. Madec)  new architecture of call
12   !!            8.2  !  1997-06  (G. Madec, M. Imbard, G. Roullet)  free surface
13   !!             -   !  1999-02  (G. Madec, N. Grima)  hpg implicit
14   !!             -   !  2000-07  (J-M Molines, M. Imbard)  Open Bondary Conditions
15   !!   NEMO     1.0  !  2002-06  (G. Madec)  free form, suppress macro-tasking
16   !!             -   !  2004-08  (C. Talandier) New trends organization
17   !!             -   !  2005-01  (C. Ethe) Add the KPP closure scheme
18   !!             -   !  2005-11  (G. Madec)  Reorganisation of tra and dyn calls
19   !!             -   !  2006-01  (L. Debreu, C. Mazauric)  Agrif implementation
20   !!             -   !  2006-07  (S. Masson)  restart using iom
21   !!            3.2  !  2009-02  (G. Madec, R. Benshila)  reintroduicing z*-coordinate
22   !!             -   !  2009-06  (S. Masson, G. Madec)  TKE restart compatible with key_cpl
23   !!            3.3  !  2010-05  (K. Mogensen, A. Weaver, M. Martin, D. Lea) Assimilation interface
24   !!             -   !  2010-10  (C. Ethe, G. Madec) reorganisation of initialisation phase + merge TRC-TRA
25   !!            3.4  !  2011-04  (G. Madec, C. Ethe) Merge of dtatem and dtasal
26   !!            3.6  !  2012-07  (J. Simeon, G. Madec. C. Ethe)  Online coarsening of outputs
27   !!            3.6  !  2014-04  (F. Roquet, G. Madec) New equations of state
28   !!            3.7  !  2014-10  (G. Madec)  LDF simplication
29   !!             -   !  2014-12  (G. Madec) remove KPP scheme
30   !!----------------------------------------------------------------------
31
32   !!----------------------------------------------------------------------
33   !!   stp             : OPA system time-stepping
34   !!----------------------------------------------------------------------
35   USE step_oce         ! time stepping definition modules
36   USE iom
37
38   IMPLICIT NONE
39   PRIVATE
40
41   PUBLIC   stp   ! called by nemogcm.F90
42
43   !!----------------------------------------------------------------------
44   !! NEMO/OPA 3.7 , NEMO Consortium (2015)
45   !! $Id$
46   !! Software governed by the CeCILL licence     (NEMOGCM/NEMO_CeCILL.txt)
47   !!----------------------------------------------------------------------
48CONTAINS
49
50#if defined key_agrif
51   RECURSIVE SUBROUTINE stp( )
52      INTEGER             ::   kstp   ! ocean time-step index
53#else
54   SUBROUTINE stp( kstp )
55      INTEGER, INTENT(in) ::   kstp   ! ocean time-step index
56#endif
57      !!----------------------------------------------------------------------
58      !!                     ***  ROUTINE stp  ***
59      !!
60      !! ** Purpose : - Time stepping of OPA (momentum and active tracer eqs.)
61      !!              - Time stepping of LIM (dynamic and thermodynamic eqs.)
62      !!              - Tme stepping  of TRC (passive tracer eqs.)
63      !!
64      !! ** Method  : -1- Update forcings and data
65      !!              -2- Update ocean physics
66      !!              -3- Compute the t and s trends
67      !!              -4- Update t and s
68      !!              -5- Compute the momentum trends
69      !!              -6- Update the horizontal velocity
70      !!              -7- Compute the diagnostics variables (rd,N2, hdiv,w)
71      !!              -8- Outputs and diagnostics
72      !!----------------------------------------------------------------------
73      INTEGER ::   jk       ! dummy loop indice
74      INTEGER ::   indic    ! error indicator if < 0
75      INTEGER ::   kcall    ! optional integer argument (dom_vvl_sf_nxt)
76      !! ---------------------------------------------------------------------
77#if defined key_agrif
78      kstp = nit000 + Agrif_Nb_Step()
79      IF( lk_agrif_debug ) THEN
80         IF( Agrif_Root() .and. lwp)   WRITE(*,*) '---'
81         IF(lwp)   WRITE(*,*) 'Grid Number', Agrif_Fixed(),' time step ', kstp, 'int tstep', Agrif_NbStepint()
82      ENDIF
83      IF( kstp == nit000 + 1 )   lk_agrif_fstep = .FALSE.
84# if defined key_iomput
85      IF( Agrif_Nbstepint() == 0 )   CALL iom_swap( cxios_context )
86# endif
87#endif
88      !>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>
89      ! update I/O and calendar
90      !<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<
91                             indic = 0                ! reset to no error condition
92                             
93      IF( kstp == nit000 ) THEN                       ! initialize IOM context (must be done after nemo_init for AGRIF+XIOS+OASIS)
94                             CALL iom_init(      cxios_context          )  ! for model grid (including passible AGRIF zoom)
95         IF( ln_crs      )   CALL iom_init( TRIM(cxios_context)//"_crs" )  ! for coarse grid
96      ENDIF
97      IF( kstp /= nit000 )   CALL day( kstp )         ! Calendar (day was already called at nit000 in day_init)
98                             CALL iom_setkt( kstp - nit000 + 1,      cxios_context          )   ! tell IOM we are at time step kstp
99      IF( ln_crs         )   CALL iom_setkt( kstp - nit000 + 1, TRIM(cxios_context)//"_crs" )   ! tell IOM we are at time step kstp
100
101      !>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>
102      ! Update external forcing (tides, open boundaries, and surface boundary condition (including sea-ice)
103      !<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<
104      IF( lk_tide    )   CALL sbc_tide( kstp )                   ! update tide potential
105      IF( ln_apr_dyn )   CALL sbc_apr ( kstp )                   ! atmospheric pressure (NB: call before bdy_dta which needs ssh_ib)
106      IF( lk_bdy     )   CALL bdy_dta ( kstp, time_offset=+1 )   ! update dynamic & tracer data at open boundaries
107                         CALL sbc     ( kstp )                   ! Sea Boundary Condition (including sea-ice)
108
109      !>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>
110      ! Update stochastic parameters and random T/S fluctuations
111      !>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>
112                         CALL sto_par( kstp )          ! Stochastic parameters
113
114      !>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>
115      ! Ocean physics update                (ua, va, tsa used as workspace)
116      !<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<
117      !  THERMODYNAMICS
118                         CALL eos_rab( tsb, rab_b )       ! before local thermal/haline expension ratio at T-points
119                         CALL eos_rab( tsn, rab_n )       ! now    local thermal/haline expension ratio at T-points
120                         CALL bn2    ( tsb, rab_b, rn2b ) ! before Brunt-Vaisala frequency
121                         CALL bn2    ( tsn, rab_n, rn2  ) ! now    Brunt-Vaisala frequency
122
123      !
124      !  VERTICAL PHYSICS
125                         CALL zdf_bfr( kstp )         ! bottom friction (if quadratic)
126      !                                               ! Vertical eddy viscosity and diffusivity coefficients
127      IF( lk_zdfric  )   CALL zdf_ric( kstp )            ! Richardson number dependent Kz
128      IF( lk_zdftke  )   CALL zdf_tke( kstp )            ! TKE closure scheme for Kz
129      IF( lk_zdfgls  )   CALL zdf_gls( kstp )            ! GLS closure scheme for Kz
130      IF( lk_zdfcst  ) THEN                              ! Constant Kz (reset avt, avm[uv] to the background value)
131         avt (:,:,:) = rn_avt0 * wmask (:,:,:)
132         avmu(:,:,:) = rn_avm0 * wumask(:,:,:)
133         avmv(:,:,:) = rn_avm0 * wvmask(:,:,:)
134      ENDIF
135
136      IF( ln_rnf_mouth ) THEN                         ! increase diffusivity at rivers mouths
137         DO jk = 2, nkrnf   ;   avt(:,:,jk) = avt(:,:,jk) + 2._wp * rn_avt_rnf * rnfmsk(:,:) * tmask(:,:,jk)   ;   END DO
138      ENDIF
139      IF( ln_zdfevd  )   CALL zdf_evd( kstp )         ! enhanced vertical eddy diffusivity
140
141      IF( lk_zdftmx  )   CALL zdf_tmx( kstp )         ! tidal vertical mixing
142
143      IF( lk_zdfddm  )   CALL zdf_ddm( kstp )         ! double diffusive mixing
144
145                         CALL zdf_mxl( kstp )         ! mixed layer depth
146
147                                                      ! write TKE or GLS information in the restart file
148      IF( lrst_oce .AND. lk_zdftke )   CALL tke_rst( kstp, 'WRITE' )
149      IF( lrst_oce .AND. lk_zdfgls )   CALL gls_rst( kstp, 'WRITE' )
150      !
151      !  LATERAL  PHYSICS
152      !
153      IF( l_ldfslp ) THEN                             ! slope of lateral mixing
154!!gm : why this here ????
155         IF(ln_sto_eos ) CALL sto_pts( tsn )          ! Random T/S fluctuations
156!!gm
157                         CALL eos( tsb, rhd, gdept_0(:,:,:) )               ! before in situ density
158
159         IF( ln_zps .AND. .NOT. ln_isfcav)                               &
160            &            CALL zps_hde    ( kstp, jpts, tsb, gtsu, gtsv,  &  ! Partial steps: before horizontal gradient
161            &                                          rhd, gru , grv    )  ! of t, s, rd at the last ocean level
162
163         IF( ln_zps .AND.       ln_isfcav)                               &
164            &            CALL zps_hde_isf( kstp, jpts, tsb, gtsu, gtsv, gtui, gtvi,   &    ! Partial steps for top cell (ISF)
165            &                                          rhd, gru , grv , aru , arv , gzu , gzv , ge3ru , ge3rv ,   &
166            &                                   grui, grvi, arui, arvi, gzui, gzvi, ge3rui, ge3rvi    ) ! of t, s, rd at the first ocean level
167
168         IF( ln_traldf_triad ) THEN
169                         CALL ldf_slp_triad( kstp )                       ! before slope for triad operator
170         ELSE     
171                         CALL ldf_slp     ( kstp, rhd, rn2b )             ! before slope for standard operator
172         ENDIF
173      ENDIF
174      !                                               ! eddy diffusivity coeff. and/or eiv coeff.
175      IF( l_ldftra_time .OR. l_ldfeiv_time )   CALL ldf_tra( kstp ) 
176
177      !>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>
178      !  Ocean dynamics : hdiv, ssh, e3, wn
179      !<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<
180                             CALL ssh_nxt       ( kstp )  ! after ssh (includes call to div_hor)
181                             CALL dom_vvl_sf_nxt( kstp )  ! after vertical scale factors
182                             CALL wzv           ( kstp )  ! now cross-level velocity
183
184      IF( lk_dynspg_ts ) THEN 
185          ! In case the time splitting case, update almost all momentum trends here:
186          ! Note that the computation of vertical velocity above, hence "after" sea level
187          ! is necessary to compute momentum advection for the rhs of barotropic loop:
188!!gm : why also here ????
189            IF(ln_sto_eos ) CALL sto_pts( tsn )                             ! Random T/S fluctuations
190!!gm
191                            CALL eos    ( tsn, rhd, rhop, gdept_n(:,:,:) )  ! now in situ density for hpg computation
192                           
193            IF( ln_zps .AND. .NOT. ln_isfcav)   &                           ! Partial steps: bottom before horizontal gradient
194               &            CALL zps_hde    ( kstp, jpts, tsn, gtsu, gtsv,  &  ! of t, s, rd at the last ocean level
195               &                                          rhd, gru , grv    )
196            IF( ln_zps .AND.       ln_isfcav)   &                           ! Partial steps: top & bottom before horizontal gradient
197               &            CALL zps_hde_isf( kstp, jpts, tsn, gtsu, gtsv, gtui, gtvi,   & 
198               &                                          rhd, gru , grv , aru , arv , gzu , gzv , ge3ru , ge3rv ,   &
199               &                                               grui, grvi, arui, arvi, gzui, gzvi, ge3rui, ge3rvi    )
200
201                                  ua(:,:,:) = 0._wp            ! set dynamics trends to zero
202                                  va(:,:,:) = 0._wp
203          IF(  lk_asminc .AND. ln_asmiau .AND. &
204             & ln_dyninc       )  CALL dyn_asm_inc  ( kstp )   ! apply dynamics assimilation increment
205          IF( lk_bdy           )  CALL bdy_dyn3d_dmp( kstp )   ! bdy damping trends
206                                  CALL dyn_adv      ( kstp )   ! advection (vector or flux form)
207                                  CALL dyn_vor      ( kstp )   ! vorticity term including Coriolis
208                                  CALL dyn_ldf      ( kstp )   ! lateral mixing
209#if defined key_agrif
210          IF(.NOT. Agrif_Root())  CALL Agrif_Sponge_dyn        ! momentum sponge
211#endif
212                                  CALL dyn_hpg( kstp )         ! horizontal gradient of Hydrostatic pressure
213                                  CALL dyn_spg( kstp, indic )  ! surface pressure gradient
214
215                                  ua_sv(:,:,:) = ua(:,:,:)     ! Save trends (barotropic trend has been fully updated at this stage)
216                                  va_sv(:,:,:) = va(:,:,:)
217
218                                  CALL div_hor( kstp )         ! Horizontal divergence  (2nd call in time-split case)
219                                  CALL dom_vvl_sf_nxt( kstp, kcall=2 )  ! after vertical scale factors (update depth average component)
220                                  CALL wzv           ( kstp )  ! now cross-level velocity
221      ENDIF
222
223      !>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>
224      ! diagnostics and outputs             (ua, va, tsa used as workspace)
225      !<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<
226      IF( lk_floats  )   CALL flo_stp( kstp )         ! drifting Floats
227      IF( lk_diahth  )   CALL dia_hth( kstp )         ! Thermocline depth (20 degres isotherm depth)
228      IF(.NOT.ln_cpl )   CALL dia_fwb( kstp )         ! Fresh water budget diagnostics
229      IF( lk_diadct  )   CALL dia_dct( kstp )         ! Transports
230      IF( lk_diaar5  )   CALL dia_ar5( kstp )         ! ar5 diag
231      IF( lk_diaharm )   CALL dia_harm( kstp )        ! Tidal harmonic analysis
232                         CALL dia_wri( kstp )         ! ocean model: outputs
233      !
234      IF( ln_crs     )   CALL crs_fld( kstp )         ! ocean model: online field coarsening & output
235
236#if defined key_top
237      !>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>
238      ! Passive Tracer Model
239      !<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<
240                         CALL trc_stp( kstp )         ! time-stepping
241#endif
242
243      !>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>
244      ! Active tracers                              (ua, va used as workspace)
245      !<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<
246                             tsa(:,:,:,:) = 0._wp           ! set tracer trends to zero
247
248      IF(  lk_asminc .AND. ln_asmiau .AND. &
249         & ln_trainc     )   CALL tra_asm_inc( kstp )       ! apply tracer assimilation increment
250                             CALL tra_sbc    ( kstp )       ! surface boundary condition
251      IF( ln_traqsr      )   CALL tra_qsr    ( kstp )       ! penetrative solar radiation qsr
252      IF( ln_trabbc      )   CALL tra_bbc    ( kstp )       ! bottom heat flux
253      IF( lk_trabbl      )   CALL tra_bbl    ( kstp )       ! advective (and/or diffusive) bottom boundary layer scheme
254      IF( ln_tradmp      )   CALL tra_dmp    ( kstp )       ! internal damping trends
255      IF( lk_bdy         )   CALL bdy_tra_dmp( kstp )       ! bdy damping trends
256                             CALL tra_adv    ( kstp )       ! horizontal & vertical advection
257                             CALL tra_ldf    ( kstp )       ! lateral mixing
258
259!!gm : why CALL to dia_ptr has been moved here??? (use trends info?)
260      IF( ln_diaptr      )   CALL dia_ptr                   ! Poleward adv/ldf TRansports diagnostics
261!!gm
262
263#if defined key_agrif
264      IF(.NOT. Agrif_Root()) CALL Agrif_Sponge_tra          ! tracers sponge
265#endif
266                             CALL tra_zdf    ( kstp )       ! vertical mixing and after tracer fields
267
268      IF( ln_dynhpg_imp  ) THEN                             ! semi-implicit hpg (time stepping then eos)
269         IF( ln_zdfnpc   )   CALL tra_npc( kstp )                ! update after fields by non-penetrative convection
270                             CALL tra_nxt( kstp )                ! tracer fields at next time step
271!!gm : why again a call to sto_pts ???
272            IF( ln_sto_eos ) CALL sto_pts( tsn )                 ! Random T/S fluctuations
273!!gm
274                             CALL eos    ( tsa, rhd, rhop, gdept_n(:,:,:) )   ! Time-filtered in situ density for hpg computation
275            IF( ln_zps .AND. .NOT. ln_isfcav)                                &
276               &             CALL zps_hde    ( kstp, jpts, tsa, gtsu, gtsv,  &  ! Partial steps: before horizontal gradient
277               &                                           rhd, gru , grv    )  ! of t, s, rd at the last ocean level
278            IF( ln_zps .AND.       ln_isfcav)                                &
279               &             CALL zps_hde_isf( kstp, jpts, tsa, gtsu, gtsv, gtui, gtvi,  &    ! Partial steps for top/bottom cells
280               &                                           rhd, gru , grv , aru , arv , gzu , gzv , ge3ru , ge3rv ,   &
281               &                                                grui, grvi, arui, arvi, gzui, gzvi, ge3rui, ge3rvi    )
282      ELSE                                                  ! centered hpg  (eos then time stepping)
283         IF ( .NOT. lk_dynspg_ts ) THEN                     ! eos already called in time-split case
284!!gm : why again a call to sto_pts ???
285            IF( ln_sto_eos ) CALL sto_pts( tsn )    ! Random T/S fluctuations
286!!gm
287                             CALL eos    ( tsn, rhd, rhop, gdept_n(:,:,:) )  ! now in situ density for hpg computation
288         IF( ln_zps .AND. .NOT. ln_isfcav)                                   &
289               &             CALL zps_hde    ( kstp, jpts, tsn, gtsu, gtsv,  &    ! Partial steps: bottom before horizontal gradient
290               &                                           rhd, gru , grv    )    ! of t, s, rd at the last ocean level
291         IF( ln_zps .AND.       ln_isfcav)                                   & 
292               &             CALL zps_hde_isf( kstp, jpts, tsn, gtsu, gtsv, gtui, gtvi,   &    ! Partial steps for top/bottom cells
293               &                                           rhd, gru , grv , aru , arv , gzu , gzv , ge3ru , ge3rv ,   &
294               &                                    grui, grvi, arui, arvi, gzui, gzvi, ge3rui, ge3rvi    ) ! of t, s, rd at the last ocean level
295         ENDIF
296         IF( ln_zdfnpc   )   CALL tra_npc( kstp )                ! update after fields by non-penetrative convection
297                             CALL tra_nxt( kstp )                ! tracer fields at next time step
298      ENDIF
299
300      !>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>
301      ! Dynamics                                    (tsa used as workspace)
302      !<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<
303      IF( lk_dynspg_ts   )  THEN
304                                                             ! revert to previously computed momentum tendencies
305                                                             ! (not using ua, va as temporary arrays during tracers' update could avoid that)
306                               ua(:,:,:) = ua_sv(:,:,:)
307                               va(:,:,:) = va_sv(:,:,:)
308
309                               CALL dyn_bfr( kstp )         ! bottom friction
310                               CALL dyn_zdf( kstp )         ! vertical diffusion
311      ELSE
312                               ua(:,:,:) = 0._wp            ! set dynamics trends to zero
313                               va(:,:,:) = 0._wp
314
315        IF(  lk_asminc .AND. ln_asmiau .AND. &
316           & ln_dyninc      )  CALL dyn_asm_inc( kstp )     ! apply dynamics assimilation increment
317        IF( ln_bkgwri )        CALL asm_bkg_wri( kstp )     ! output background fields
318        IF( lk_bdy          )  CALL bdy_dyn3d_dmp(kstp )    ! bdy damping trends
319                               CALL dyn_adv( kstp )         ! advection (vector or flux form)
320                               CALL dyn_vor( kstp )         ! vorticity term including Coriolis
321                               CALL dyn_ldf( kstp )         ! lateral mixing
322#if defined key_agrif
323        IF(.NOT. Agrif_Root()) CALL Agrif_Sponge_dyn        ! momemtum sponge
324#endif
325                               CALL dyn_hpg( kstp )         ! horizontal gradient of Hydrostatic pressure
326                               CALL dyn_bfr( kstp )         ! bottom friction
327                               CALL dyn_zdf( kstp )         ! vertical diffusion
328                               CALL dyn_spg( kstp, indic )  ! surface pressure gradient
329      ENDIF
330                               CALL dyn_nxt( kstp )         ! lateral velocity at next time step
331
332                               CALL ssh_swp( kstp )         ! swap of sea surface height
333                               CALL dom_vvl_sf_swp( kstp )  ! swap of vertical scale factors
334      !
335
336!!gm : This does not only concern the dynamics ==>>> add a new title
337!!gm2: why ouput restart before AGRIF update?
338      IF( lrst_oce         )   CALL rst_write( kstp )       ! write output ocean restart file
339
340#if defined key_agrif
341      !>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>
342      ! AGRIF
343      !<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<     
344                               CALL Agrif_Integrate_ChildGrids( stp ) 
345
346      IF ( Agrif_NbStepint().EQ.0 ) THEN
347                               CALL Agrif_Update_Tra()      ! Update active tracers
348                               CALL Agrif_Update_Dyn()      ! Update momentum
349      ENDIF
350#endif
351      IF( ln_diahsb        )   CALL dia_hsb( kstp )         ! - ML - global conservation diagnostics
352      IF( lk_diaobs  )         CALL dia_obs( kstp )         ! obs-minus-model (assimilation) diagnostics (call after dynamics update)
353
354      !>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>
355      ! Control
356      !<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<
357                               CALL stp_ctl( kstp, indic )
358      IF( indic < 0        )   THEN
359                               CALL ctl_stop( 'step: indic < 0' )
360                               CALL dia_wri_state( 'output.abort', kstp )
361      ENDIF
362      IF( kstp == nit000   )   THEN
363                 CALL iom_close( numror )     ! close input  ocean restart file
364         IF(lwm) CALL FLUSH    ( numond )     ! flush output namelist oce
365         IF(lwm.AND.numoni /= -1 )   &
366            &    CALL FLUSH    ( numoni )     ! flush output namelist ice (if exist)
367      ENDIF
368
369      !>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>
370      ! Coupled mode
371      !<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<
372!!gm why lk_oasis and not lk_cpl ????
373      IF( lk_oasis         )   CALL sbc_cpl_snd( kstp )     ! coupled mode : field exchanges
374      !
375#if defined key_iomput
376      IF( kstp == nitend .OR. indic < 0 ) THEN
377                      CALL iom_context_finalize(      cxios_context          ) ! needed for XIOS+AGRIF
378         IF( ln_crs ) CALL iom_context_finalize( trim(cxios_context)//"_crs" ) !
379      ENDIF
380#endif
381      !
382      IF( nn_timing == 1 .AND.  kstp == nit000  )   CALL timing_reset
383      !
384   END SUBROUTINE stp
385
386   !!======================================================================
387END MODULE step
Note: See TracBrowser for help on using the repository browser.