New URL for NEMO forge!   http://forge.nemo-ocean.eu

Since March 2022 along with NEMO 4.2 release, the code development moved to a self-hosted GitLab.
This present forge is now archived and remained online for history.
trcnxt.F90 in branches/2015/dev_r5836_NOC3_vvl_by_default/NEMOGCM/NEMO/TOP_SRC/TRP – NEMO

source: branches/2015/dev_r5836_NOC3_vvl_by_default/NEMOGCM/NEMO/TOP_SRC/TRP/trcnxt.F90 @ 5916

Last change on this file since 5916 was 5916, checked in by acc, 8 years ago

Branch dev_r5836_NOC3_vvl_by_default. Changes to ensure successful SETTE testing. Affects tranxt.F90, trcnxt.F90 and traqsr.F90 only. Reduces dangerous dependencies on fields set in haloes but introduces additional lbc_lnks instead.

  • Property svn:keywords set to Id
File size: 7.8 KB
RevLine 
[941]1MODULE trcnxt
2   !!======================================================================
3   !!                       ***  MODULE  trcnxt  ***
4   !! Ocean passive tracers:  time stepping on passives tracers
5   !!======================================================================
[2528]6   !! History :  7.0  !  1991-11  (G. Madec)  Original code
7   !!                 !  1993-03  (M. Guyon)  symetrical conditions
8   !!                 !  1995-02  (M. Levy)   passive tracers
9   !!                 !  1996-02  (G. Madec & M. Imbard)  opa release 8.0
10   !!            8.0  !  1996-04  (A. Weaver)  Euler forward step
11   !!            8.2  !  1999-02  (G. Madec, N. Grima)  semi-implicit pressure grad.
12   !!  NEMO      1.0  !  2002-08  (G. Madec)  F90: Free form and module
13   !!                 !  2002-08  (G. Madec)  F90: Free form and module
14   !!                 !  2002-11  (C. Talandier, A-M Treguier) Open boundaries
15   !!                 !  2004-03  (C. Ethe) passive tracers
16   !!                 !  2007-02  (C. Deltel) Diagnose ML trends for passive tracers
17   !!            2.0  !  2006-02  (L. Debreu, C. Mazauric) Agrif implementation
18   !!            3.0  !  2008-06  (G. Madec)  time stepping always done in trazdf
19   !!            3.1  !  2009-02  (G. Madec, R. Benshila)  re-introduce the vvl option
20   !!            3.3  !  2010-06  (C. Ethe, G. Madec) Merge TRA-TRC
[1175]21   !!----------------------------------------------------------------------
[941]22#if defined key_top
23   !!----------------------------------------------------------------------
24   !!   'key_top'                                                TOP models
25   !!----------------------------------------------------------------------
26   !!   trc_nxt     : time stepping on passive tracers
27   !!----------------------------------------------------------------------
28   USE oce_trc         ! ocean dynamics and tracers variables
[2528]29   USE trc             ! ocean passive tracers variables
[941]30   USE lbclnk          ! ocean lateral boundary conditions (or mpp link)
31   USE prtctl_trc      ! Print control for debbuging
[4990]32   USE trd_oce
[2528]33   USE trdtra
34   USE tranxt
35# if defined key_agrif
[941]36   USE agrif_top_interp
[2528]37# endif
[941]38
39   IMPLICIT NONE
40   PRIVATE
41
[2715]42   PUBLIC   trc_nxt          ! routine called by step.F90
43   PUBLIC   trc_nxt_alloc    ! routine called by nemogcm.F90
[2528]44
[2715]45   REAL(wp), ALLOCATABLE, SAVE, DIMENSION(:) ::   r2dt
46
[941]47   !!----------------------------------------------------------------------
[2528]48   !! NEMO/TOP 3.3 , NEMO Consortium (2010)
[1152]49   !! $Id$
[2715]50   !! Software governed by the CeCILL licence     (NEMOGCM/NEMO_CeCILL.txt)
[941]51   !!----------------------------------------------------------------------
52CONTAINS
53
[2715]54   INTEGER FUNCTION trc_nxt_alloc()
55      !!----------------------------------------------------------------------
56      !!                   ***  ROUTINE trc_nxt_alloc  ***
57      !!----------------------------------------------------------------------
58      ALLOCATE( r2dt(jpk), STAT=trc_nxt_alloc )
59      !
60      IF( trc_nxt_alloc /= 0 )   CALL ctl_warn('trc_nxt_alloc : failed to allocate array')
61      !
62   END FUNCTION trc_nxt_alloc
63
64
[941]65   SUBROUTINE trc_nxt( kt )
66      !!----------------------------------------------------------------------
67      !!                   ***  ROUTINE trcnxt  ***
68      !!
69      !! ** Purpose :   Compute the passive tracers fields at the
70      !!      next time-step from their temporal trends and swap the fields.
71      !!
72      !! ** Method  :   Apply lateral boundary conditions on (ua,va) through
73      !!      call to lbc_lnk routine
74      !!   default:
75      !!      arrays swap
76      !!         (trn) = (tra) ; (tra) = (0,0)
77      !!         (trb) = (trn)
78      !!
79      !!   For Arakawa or TVD Scheme :
80      !!      A Asselin time filter applied on now tracers (trn) to avoid
81      !!      the divergence of two consecutive time-steps and tr arrays
82      !!      to prepare the next time_step:
83      !!         (trb) = (trn) + atfp [ (trb) + (tra) - 2 (trn) ]
84      !!         (trn) = (tra) ; (tra) = (0,0)
85      !!
86      !!
87      !! ** Action  : - update trb, trn
88      !!----------------------------------------------------------------------
[1271]89      INTEGER, INTENT( in ) ::   kt     ! ocean time-step index
[2715]90      !
[2528]91      INTEGER  ::   jk, jn   ! dummy loop indices
[941]92      REAL(wp) ::   zfact            ! temporary scalar
93      CHARACTER (len=22) :: charout
[3294]94      REAL(wp), POINTER, DIMENSION(:,:,:,:) ::  ztrdt 
[941]95      !!----------------------------------------------------------------------
[3294]96      !
97      IF( nn_timing == 1 )  CALL timing_start('trc_nxt')
98      !
99      IF( kt == nittrc000 .AND. lwp ) THEN
[941]100         WRITE(numout,*)
101         WRITE(numout,*) 'trc_nxt : time stepping on passive tracers'
102      ENDIF
[5883]103      !
[5656]104#if defined key_agrif
105      CALL Agrif_trc                   ! AGRIF zoom boundaries
106#endif
[5883]107      DO jn = 1, jptra                 ! Update after tracer on domain lateral boundaries
[941]108         CALL lbc_lnk( tra(:,:,:,jn), 'T', 1. )   
[2528]109      END DO
110#if defined key_bdy
[5883]111!!      CALL bdy_trc( kt )             ! BDY open boundaries
[2528]112#endif
[941]113
[5883]114      !                                ! set time step size (Euler/Leapfrog)
[3294]115      IF( neuler == 0 .AND. kt ==  nittrc000 ) THEN  ;  r2dt(:) =     rdttrc(:)   ! at nittrc000             (Euler)
[5385]116      ELSEIF( kt <= nittrc000 + nn_dttrc )     THEN  ;  r2dt(:) = 2.* rdttrc(:)   ! at nit000 or nit000+1 (Leapfrog)
[2528]117      ENDIF
[941]118
[5883]119      IF( l_trdtrc )  THEN             ! trends: store now fields before the Asselin filter application
120         CALL wrk_alloc( jpi, jpj, jpk, jptra, ztrdt )
[2528]121         ztrdt(:,:,:,:)  = trn(:,:,:,:)
122      ENDIF
[5883]123      !                                ! Leap-Frog + Asselin filter time stepping
124      IF( neuler == 0 .AND. kt == nittrc000 ) THEN    ! Euler time-stepping at first time-step (only swap)
[2528]125         DO jn = 1, jptra
126            DO jk = 1, jpkm1
127               trn(:,:,jk,jn) = tra(:,:,jk,jn)
128            END DO
129         END DO
[5883]130      ELSE                                            ! Asselin filter + swap
[5866]131         IF( ln_linssh ) THEN   ;   CALL tra_nxt_fix( kt, nittrc000,         'TRC', trb, trn, tra, jptra )  !     linear ssh
132         ELSE                   ;   CALL tra_nxt_vvl( kt, nittrc000, rdttrc, 'TRC', trb, trn, tra,      &
133           &                                                                   sbc_trc, sbc_trc_b, jptra )  ! non-linear ssh
[2528]134         ENDIF
[5916]135         !
136         DO jn = 1, jptra
137            CALL lbc_lnk( trb(:,:,:,jn), 'T', 1._wp ) 
138            CALL lbc_lnk( trn(:,:,:,jn), 'T', 1._wp )
139            CALL lbc_lnk( tra(:,:,:,jn), 'T', 1._wp )
140         END DO
[2528]141      ENDIF
[5883]142      !
143      IF( l_trdtrc ) THEN              ! trends: send Asselin filter trends to trdtra manager for further diagnostics
[2528]144         DO jn = 1, jptra
145            DO jk = 1, jpkm1
[5883]146               zfact = 1._wp / r2dt(jk) 
[2528]147               ztrdt(:,:,jk,jn) = ( trb(:,:,jk,jn) - ztrdt(:,:,jk,jn) ) * zfact 
[4990]148               CALL trd_tra( kt, 'TRC', jn, jptra_atf, ztrdt )
[1175]149            END DO
[2528]150         END DO
[3294]151         CALL wrk_dealloc( jpi, jpj, jpk, jptra, ztrdt ) 
[2528]152      END IF
153      !
[941]154      IF(ln_ctl)   THEN  ! print mean trends (used for debugging)
155         WRITE(charout, FMT="('nxt')")
156         CALL prt_ctl_trc_info(charout)
157         CALL prt_ctl_trc(tab4d=trn, mask=tmask, clinfo=ctrcnm)
158      ENDIF
[2528]159      !
[3294]160      IF( nn_timing == 1 )  CALL timing_stop('trc_nxt')
161      !
[941]162   END SUBROUTINE trc_nxt
163
164#else
165   !!----------------------------------------------------------------------
166   !!   Default option                                         Empty module
167   !!----------------------------------------------------------------------
168CONTAINS
169   SUBROUTINE trc_nxt( kt ) 
170      INTEGER, INTENT(in) :: kt
171      WRITE(*,*) 'trc_nxt: You should not have seen this print! error?', kt
172   END SUBROUTINE trc_nxt
173#endif
174   !!======================================================================
175END MODULE trcnxt
Note: See TracBrowser for help on using the repository browser.