New URL for NEMO forge!   http://forge.nemo-ocean.eu

Since March 2022 along with NEMO 4.2 release, the code development moved to a self-hosted GitLab.
This present forge is now archived and remained online for history.
step.F90 in branches/2015/dev_r5847_MERCATOR9_solveur_simplification/NEMOGCM/NEMO/OPA_SRC – NEMO

source: branches/2015/dev_r5847_MERCATOR9_solveur_simplification/NEMOGCM/NEMO/OPA_SRC/step.F90 @ 5917

Last change on this file since 5917 was 5917, checked in by jchanut, 8 years ago

Free surface simplification #1620. Step 4 (Final): add Gurvan's suggestions

  • Property svn:keywords set to Id
File size: 19.6 KB
Line 
1MODULE step
2   !!======================================================================
3   !!                       ***  MODULE step  ***
4   !! Time-stepping    : manager of the ocean, tracer and ice time stepping
5   !!======================================================================
6   !! History :  OPA  !  1991-03  (G. Madec)  Original code
7   !!             -   !  1991-11  (G. Madec)
8   !!             -   !  1992-06  (M. Imbard)  add a first output record
9   !!             -   !  1996-04  (G. Madec)  introduction of dynspg
10   !!             -   !  1996-04  (M.A. Foujols)  introduction of passive tracer
11   !!            8.0  !  1997-06  (G. Madec)  new architecture of call
12   !!            8.2  !  1997-06  (G. Madec, M. Imbard, G. Roullet)  free surface
13   !!             -   !  1999-02  (G. Madec, N. Grima)  hpg implicit
14   !!             -   !  2000-07  (J-M Molines, M. Imbard)  Open Bondary Conditions
15   !!   NEMO     1.0  !  2002-06  (G. Madec)  free form, suppress macro-tasking
16   !!             -   !  2004-08  (C. Talandier) New trends organization
17   !!             -   !  2005-01  (C. Ethe) Add the KPP closure scheme
18   !!             -   !  2005-11  (G. Madec)  Reorganisation of tra and dyn calls
19   !!             -   !  2006-01  (L. Debreu, C. Mazauric)  Agrif implementation
20   !!             -   !  2006-07  (S. Masson)  restart using iom
21   !!            3.2  !  2009-02  (G. Madec, R. Benshila)  reintroduicing z*-coordinate
22   !!             -   !  2009-06  (S. Masson, G. Madec)  TKE restart compatible with key_cpl
23   !!            3.3  !  2010-05  (K. Mogensen, A. Weaver, M. Martin, D. Lea) Assimilation interface
24   !!             -   !  2010-10  (C. Ethe, G. Madec) reorganisation of initialisation phase + merge TRC-TRA
25   !!            3.4  !  2011-04  (G. Madec, C. Ethe) Merge of dtatem and dtasal
26   !!            3.6  !  2012-07  (J. Simeon, G. Madec. C. Ethe)  Online coarsening of outputs
27   !!            3.6  !  2014-04  (F. Roquet, G. Madec) New equations of state
28   !!            3.7  !  2014-10  (G. Madec)  LDF simplication
29   !!             -   !  2014-12  (G. Madec) remove KPP scheme
30   !!             -   !  2015-11  (J. Chanut) free surface simplification
31   !!----------------------------------------------------------------------
32
33   !!----------------------------------------------------------------------
34   !!   stp             : OPA system time-stepping
35   !!----------------------------------------------------------------------
36   USE step_oce         ! time stepping definition modules
37   USE iom
38
39   IMPLICIT NONE
40   PRIVATE
41
42   PUBLIC   stp   ! called by nemogcm.F90
43
44   !! * Substitutions
45#  include "domzgr_substitute.h90"
46!!gm   #  include "zdfddm_substitute.h90"
47   !!----------------------------------------------------------------------
48   !! NEMO/OPA 3.7 , NEMO Consortium (2015)
49   !! $Id$
50   !! Software governed by the CeCILL licence     (NEMOGCM/NEMO_CeCILL.txt)
51   !!----------------------------------------------------------------------
52CONTAINS
53
54#if defined key_agrif
55   RECURSIVE SUBROUTINE stp( )
56      INTEGER             ::   kstp   ! ocean time-step index
57#else
58   SUBROUTINE stp( kstp )
59      INTEGER, INTENT(in) ::   kstp   ! ocean time-step index
60#endif
61      !!----------------------------------------------------------------------
62      !!                     ***  ROUTINE stp  ***
63      !!
64      !! ** Purpose : - Time stepping of OPA (momentum and active tracer eqs.)
65      !!              - Time stepping of LIM (dynamic and thermodynamic eqs.)
66      !!              - Tme stepping  of TRC (passive tracer eqs.)
67      !!
68      !! ** Method  : -1- Update forcings and data
69      !!              -2- Update ocean physics
70      !!              -3- Compute the t and s trends
71      !!              -4- Update t and s
72      !!              -5- Compute the momentum trends
73      !!              -6- Update the horizontal velocity
74      !!              -7- Compute the diagnostics variables (rd,N2, hdiv,w)
75      !!              -8- Outputs and diagnostics
76      !!----------------------------------------------------------------------
77      INTEGER ::   jk       ! dummy loop indice
78      INTEGER ::   indic    ! error indicator if < 0
79      INTEGER ::   kcall    ! optional integer argument (dom_vvl_sf_nxt)
80      !! ---------------------------------------------------------------------
81#if defined key_agrif
82      kstp = nit000 + Agrif_Nb_Step()
83      IF( lk_agrif_debug ) THEN
84         IF( Agrif_Root() .and. lwp)   WRITE(*,*) '---'
85         IF(lwp)   WRITE(*,*) 'Grid Number', Agrif_Fixed(),' time step ', kstp, 'int tstep', Agrif_NbStepint()
86      ENDIF
87      IF( kstp == nit000 + 1 )   lk_agrif_fstep = .FALSE.
88# if defined key_iomput
89      IF( Agrif_Nbstepint() == 0 )   CALL iom_swap( cxios_context )
90# endif
91#endif
92      !>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>
93      ! update I/O and calendar
94      !<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<
95                             indic = 0                ! reset to no error condition
96                             
97      IF( kstp == nit000 ) THEN                       ! initialize IOM context (must be done after nemo_init for AGRIF+XIOS+OASIS)
98                             CALL iom_init(      cxios_context          )  ! for model grid (including passible AGRIF zoom)
99         IF( ln_crs      )   CALL iom_init( TRIM(cxios_context)//"_crs" )  ! for coarse grid
100      ENDIF
101      IF( kstp /= nit000 )   CALL day( kstp )         ! Calendar (day was already called at nit000 in day_init)
102                             CALL iom_setkt( kstp - nit000 + 1,      cxios_context          )   ! tell IOM we are at time step kstp
103      IF( ln_crs         )   CALL iom_setkt( kstp - nit000 + 1, TRIM(cxios_context)//"_crs" )   ! tell IOM we are at time step kstp
104
105      !>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>
106      ! Update external forcing (tides, open boundaries, and surface boundary condition (including sea-ice)
107      !<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<
108      IF( lk_tide    )   CALL sbc_tide( kstp )                   ! update tide potential
109      IF( ln_apr_dyn )   CALL sbc_apr ( kstp )                   ! atmospheric pressure (NB: call before bdy_dta which needs ssh_ib)
110      IF( lk_bdy     )   CALL bdy_dta ( kstp, time_offset=+1 )   ! update dynamic & tracer data at open boundaries
111                         CALL sbc     ( kstp )                   ! Sea Boundary Condition (including sea-ice)
112
113      !>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>
114      ! Update stochastic parameters and random T/S fluctuations
115      !>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>
116                         CALL sto_par( kstp )          ! Stochastic parameters
117
118      !>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>
119      ! Ocean physics update                (ua, va, tsa used as workspace)
120      !<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<
121      !  THERMODYNAMICS
122                         CALL eos_rab( tsb, rab_b )       ! before local thermal/haline expension ratio at T-points
123                         CALL eos_rab( tsn, rab_n )       ! now    local thermal/haline expension ratio at T-points
124                         CALL bn2    ( tsb, rab_b, rn2b ) ! before Brunt-Vaisala frequency
125                         CALL bn2    ( tsn, rab_n, rn2  ) ! now    Brunt-Vaisala frequency
126
127      !
128      !  VERTICAL PHYSICS
129                         CALL zdf_bfr( kstp )         ! bottom friction (if quadratic)
130      !                                               ! Vertical eddy viscosity and diffusivity coefficients
131      IF( lk_zdfric  )   CALL zdf_ric( kstp )            ! Richardson number dependent Kz
132      IF( lk_zdftke  )   CALL zdf_tke( kstp )            ! TKE closure scheme for Kz
133      IF( lk_zdfgls  )   CALL zdf_gls( kstp )            ! GLS closure scheme for Kz
134      IF( lk_zdfcst  ) THEN                              ! Constant Kz (reset avt, avm[uv] to the background value)
135         avt (:,:,:) = rn_avt0 * wmask (:,:,:)
136         avmu(:,:,:) = rn_avm0 * wumask(:,:,:)
137         avmv(:,:,:) = rn_avm0 * wvmask(:,:,:)
138      ENDIF
139
140      IF( ln_rnf_mouth ) THEN                         ! increase diffusivity at rivers mouths
141         DO jk = 2, nkrnf   ;   avt(:,:,jk) = avt(:,:,jk) + 2._wp * rn_avt_rnf * rnfmsk(:,:) * tmask(:,:,jk)   ;   END DO
142      ENDIF
143      IF( ln_zdfevd  )   CALL zdf_evd( kstp )         ! enhanced vertical eddy diffusivity
144
145      IF( lk_zdftmx  )   CALL zdf_tmx( kstp )         ! tidal vertical mixing
146
147      IF( lk_zdfddm  )   CALL zdf_ddm( kstp )         ! double diffusive mixing
148
149                         CALL zdf_mxl( kstp )         ! mixed layer depth
150
151                                                      ! write TKE or GLS information in the restart file
152      IF( lrst_oce .AND. lk_zdftke )   CALL tke_rst( kstp, 'WRITE' )
153      IF( lrst_oce .AND. lk_zdfgls )   CALL gls_rst( kstp, 'WRITE' )
154      !
155      !  LATERAL  PHYSICS
156      !
157      IF( l_ldfslp ) THEN                             ! slope of lateral mixing
158!!gm : why this here ????
159         IF(ln_sto_eos ) CALL sto_pts( tsn )          ! Random T/S fluctuations
160!!gm
161                         CALL eos( tsb, rhd, gdept_0(:,:,:) )               ! before in situ density
162
163         IF( ln_zps .AND. .NOT. ln_isfcav)                               &
164            &            CALL zps_hde    ( kstp, jpts, tsb, gtsu, gtsv,  &  ! Partial steps: before horizontal gradient
165            &                                          rhd, gru , grv    )  ! of t, s, rd at the last ocean level
166
167         IF( ln_zps .AND.       ln_isfcav)                               &
168            &            CALL zps_hde_isf( kstp, jpts, tsb, gtsu, gtsv, gtui, gtvi,   &    ! Partial steps for top cell (ISF)
169            &                                          rhd, gru , grv , aru , arv , gzu , gzv , ge3ru , ge3rv ,   &
170            &                                   grui, grvi, arui, arvi, gzui, gzvi, ge3rui, ge3rvi    ) ! of t, s, rd at the first ocean level
171
172         IF( ln_traldf_triad ) THEN
173                         CALL ldf_slp_triad( kstp )                       ! before slope for triad operator
174         ELSE     
175                         CALL ldf_slp     ( kstp, rhd, rn2b )             ! before slope for standard operator
176         ENDIF
177      ENDIF
178      !                                               ! eddy diffusivity coeff. and/or eiv coeff.
179      IF( l_ldftra_time .OR. l_ldfeiv_time )   CALL ldf_tra( kstp ) 
180
181      !>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>
182      !  Ocean dynamics : hdiv, ssh, e3, u, v, w
183      !<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<
184
185                         CALL ssh_nxt       ( kstp )  ! after ssh (includes call to div_hor)
186      IF( lk_vvl     )   CALL dom_vvl_sf_nxt( kstp )  ! after vertical scale factors
187                         CALL wzv           ( kstp )  ! now cross-level velocity
188
189!!gm : why also here ????
190      IF(ln_sto_eos  )   CALL sto_pts( tsn )                             ! Random T/S fluctuations
191!!gm
192                         CALL eos    ( tsn, rhd, rhop, fsdept_n(:,:,:) ) ! now in situ density for hpg computation
193                           
194                         ua(:,:,:) = 0._wp            ! set dynamics trends to zero
195                         va(:,:,:) = 0._wp
196
197      IF(  lk_asminc .AND. ln_asmiau .AND. ln_dyninc )   &
198                         CALL dyn_asm_inc   ( kstp )  ! apply dynamics assimilation increment
199      IF( lk_bdy     )   CALL bdy_dyn3d_dmp ( kstp )  ! bdy damping trends
200#if defined key_agrif
201      IF(.NOT. Agrif_Root())  & 
202               &         CALL Agrif_Sponge_dyn        ! momentum sponge
203#endif
204                         CALL dyn_adv       ( kstp )  ! advection (vector or flux form)
205                         CALL dyn_vor       ( kstp )  ! vorticity term including Coriolis
206                         CALL dyn_ldf       ( kstp )  ! lateral mixing
207                         CALL dyn_hpg       ( kstp )  ! horizontal gradient of Hydrostatic pressure
208                         CALL dyn_spg       ( kstp )  ! surface pressure gradient
209
210                                                      ! With split-explicit free surface, since now transports have been updated and ssha as well
211      IF( ln_dynspg_ts ) THEN                         ! vertical scale factors and vertical velocity need to be updated
212                            CALL div_hor    ( kstp )              ! Horizontal divergence  (2nd call in time-split case)
213         IF( lk_vvl )       CALL dom_vvl_sf_nxt( kstp, kcall=2 )  ! after vertical scale factors (update depth average component)
214                            CALL wzv        ( kstp )              ! now cross-level velocity
215      ENDIF
216
217                         CALL dyn_bfr       ( kstp )  ! bottom friction
218                         CALL dyn_zdf       ( kstp )  ! vertical diffusion
219
220      !>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>
221      ! diagnostics and outputs             
222      !<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<
223      IF( lk_floats  )   CALL flo_stp       ( kstp )  ! drifting Floats
224      IF( lk_diahth  )   CALL dia_hth       ( kstp )  ! Thermocline depth (20 degres isotherm depth)
225      IF(.NOT.ln_cpl )   CALL dia_fwb       ( kstp )  ! Fresh water budget diagnostics
226      IF( lk_diadct  )   CALL dia_dct       ( kstp )  ! Transports
227      IF( lk_diaar5  )   CALL dia_ar5       ( kstp )  ! ar5 diag
228      IF( lk_diaharm )   CALL dia_harm      ( kstp )  ! Tidal harmonic analysis
229                         CALL dia_wri       ( kstp )  ! ocean model: outputs
230      !
231      IF( ln_crs     )   CALL crs_fld       ( kstp )  ! ocean model: online field coarsening & output
232
233#if defined key_top
234      !>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>
235      ! Passive Tracer Model
236      !<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<
237                         CALL trc_stp       ( kstp )  ! time-stepping
238#endif
239
240      !>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>
241      ! Active tracers                             
242      !<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<
243                         tsa(:,:,:,:) = 0._wp         ! set tracer trends to zero
244
245      IF(  lk_asminc .AND. ln_asmiau .AND. &
246         & ln_trainc )   CALL tra_asm_inc   ( kstp )  ! apply tracer assimilation increment
247                         CALL tra_sbc       ( kstp )  ! surface boundary condition
248      IF( ln_traqsr  )   CALL tra_qsr       ( kstp )  ! penetrative solar radiation qsr
249      IF( ln_trabbc  )   CALL tra_bbc       ( kstp )  ! bottom heat flux
250      IF( lk_trabbl  )   CALL tra_bbl       ( kstp )  ! advective (and/or diffusive) bottom boundary layer scheme
251      IF( ln_tradmp  )   CALL tra_dmp       ( kstp )  ! internal damping trends
252      IF( lk_bdy     )   CALL bdy_tra_dmp   ( kstp )  ! bdy damping trends
253#if defined key_agrif
254      IF(.NOT. Agrif_Root())  & 
255               &         CALL Agrif_Sponge_tra        ! tracers sponge
256#endif
257                         CALL tra_adv       ( kstp )  ! horizontal & vertical advection
258                         CALL tra_ldf       ( kstp )  ! lateral mixing
259
260!!gm : why CALL to dia_ptr has been moved here??? (use trends info?)
261      IF( ln_diaptr  )   CALL dia_ptr                 ! Poleward adv/ldf TRansports diagnostics
262!!gm
263                         CALL tra_zdf       ( kstp )  ! vertical mixing and after tracer fields
264      IF( ln_zdfnpc  )   CALL tra_npc       ( kstp )  ! update after fields by non-penetrative convection
265
266      !>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>
267      ! Set boundary conditions and Swap
268      !<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<
269!!jc1: For agrif, it would be much better to finalize tracers/momentum here (e.g. bdy conditions) and move the swap
270!!    (and time filtering) after Agrif update. Then restart would be done after and would contain updated fields.
271!!    If so:
272!!    (i) no need to call agrif update at initialization time
273!!    (ii) no need to update "before" fields
274!!
275!!    Apart from creating new tra_swp/dyn_swp routines, this however:
276!!    (i) makes boundary conditions at initialization time computed from updated fields which is not the case between
277!!    two restarts => restartability issue. One can circumvent this, maybe, by assuming "interface separation",
278!!    e.g. a shift of the feedback interface inside child domain.
279!!    (ii) requires that all restart outputs of updated variables by agrif (e.g. passive tracers/tke/barotropic arrays) are done at the same
280!!    place.
281!!
282!!jc2: dynnxt must be the latest call. fse3t_b are indeed updated in that routine
283                         CALL tra_nxt       ( kstp )  ! finalize (bcs) tracer fields at next time step and swap
284                         CALL dyn_nxt       ( kstp )  ! finalize (bcs) velocities at next time step and swap
285                         CALL ssh_swp       ( kstp )  ! swap of sea surface height
286      IF( lk_vvl     )   CALL dom_vvl_sf_swp( kstp )  ! swap of vertical scale factors
287      !
288
289!!gm : This does not only concern the dynamics ==>>> add a new title
290!!gm2: why ouput restart before AGRIF update?
291!!
292!!jc: That would be better, but see comment above
293!!
294      IF( lrst_oce   )   CALL rst_write     ( kstp )  ! write output ocean restart file
295
296#if defined key_agrif
297      !>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>
298      ! AGRIF
299      !<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<     
300                         CALL Agrif_Integrate_ChildGrids( stp ) 
301
302      IF ( Agrif_NbStepint().EQ.0 ) THEN              ! AGRIF Update
303!!jc in fact update i useless at last time step, but do it for global diagnostics
304                         CALL Agrif_Update_Tra()      ! Update active tracers
305                         CALL Agrif_Update_Dyn()      ! Update momentum
306      ENDIF
307#endif
308      IF( ln_diahsb  )   CALL dia_hsb       ( kstp )  ! - ML - global conservation diagnostics
309      IF( lk_diaobs  )   CALL dia_obs       ( kstp )  ! obs-minus-model (assimilation) diagnostics (call after dynamics update)
310
311      !>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>
312      ! Control
313      !<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<
314                         CALL stp_ctl       ( kstp, indic )
315      IF( indic < 0  )   THEN
316                         CALL ctl_stop( 'step: indic < 0' )
317                         CALL dia_wri_state( 'output.abort', kstp )
318      ENDIF
319      IF( kstp == nit000 )   THEN
320                 CALL iom_close( numror )     ! close input  ocean restart file
321         IF(lwm) CALL FLUSH    ( numond )     ! flush output namelist oce
322         IF(lwm.AND.numoni /= -1 )   &
323            &    CALL FLUSH    ( numoni )     ! flush output namelist ice (if exist)
324      ENDIF
325
326      !>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>
327      ! Coupled mode
328      !<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<
329!!gm why lk_oasis and not lk_cpl ????
330      IF( lk_oasis   )   CALL sbc_cpl_snd( kstp )     ! coupled mode : field exchanges
331      !
332#if defined key_iomput
333      IF( kstp == nitend .OR. indic < 0 ) THEN
334                      CALL iom_context_finalize(      cxios_context          ) ! needed for XIOS+AGRIF
335         IF( ln_crs ) CALL iom_context_finalize( trim(cxios_context)//"_crs" ) !
336      ENDIF
337#endif
338      !
339      IF( nn_timing == 1 .AND.  kstp == nit000  )   CALL timing_reset
340      !
341   END SUBROUTINE stp
342
343   !!======================================================================
344END MODULE step
Note: See TracBrowser for help on using the repository browser.