New URL for NEMO forge!   http://forge.nemo-ocean.eu

Since March 2022 along with NEMO 4.2 release, the code development moved to a self-hosted GitLab.
This present forge is now archived and remained online for history.
sbcwave.F90 in branches/2015/dev_r5936_INGV1_WAVE/NEMOGCM/NEMO/OPA_SRC/SBC – NEMO

source: branches/2015/dev_r5936_INGV1_WAVE/NEMOGCM/NEMO/OPA_SRC/SBC/sbcwave.F90 @ 7340

Last change on this file since 7340 was 7340, checked in by emanuelaclementi, 7 years ago

#1643 Correction after review in development branch 2015/dev_r5936_INGV1_WAVE

  • Property svn:keywords set to Id
File size: 12.8 KB
Line 
1MODULE sbcwave
2   !!======================================================================
3   !!                       ***  MODULE  sbcwave  ***
4   !! Wave module
5   !!======================================================================
6   !! History :  3.3  !   2011-09  (M. Adani)  Original code: Drag Coefficient
7   !!         :  3.4  !   2012-10  (M. Adani)  Stokes Drift
8   !!            3.6  !   2014-09  (E. Clementi,P. Oddo) New Stokes Drift Computation
9   !!----------------------------------------------------------------------
10
11   !!----------------------------------------------------------------------
12   !!   sbc_wave      : wave data from wave model in netcdf files
13   !!----------------------------------------------------------------------
14   USE oce            !
15   USE sbc_oce        ! Surface boundary condition: ocean fields
16   USE bdy_oce        !
17   USE domvvl         !
18   USE iom            ! I/O manager library
19   USE in_out_manager ! I/O manager
20   USE lib_mpp        ! distribued memory computing library
21   USE fldread        ! read input fields
22   USE wrk_nemo       !
23   USE phycst         ! physical constants
24
25   IMPLICIT NONE
26   PRIVATE
27
28   PUBLIC   sbc_wave    ! routine called in sbcmod
29   
30   INTEGER, PARAMETER ::   jpfld  = 4           ! number of files to read for stokes drift
31   INTEGER, PARAMETER ::   jp_usd = 1           ! index of stokes drift  (i-component) (m/s)    at T-point
32   INTEGER, PARAMETER ::   jp_vsd = 2           ! index of stokes drift  (j-component) (m/s)    at T-point
33   INTEGER, PARAMETER ::   jp_swh = 3           ! index of significant wave hight      (m)      at T-point
34   INTEGER, PARAMETER ::   jp_wmp = 4           ! index of mean wave period            (s)      at T-point
35
36   TYPE(FLD), ALLOCATABLE, DIMENSION(:)  :: sf_cd    ! structure of input fields (file informations, fields read) Drag Coefficient
37   TYPE(FLD), ALLOCATABLE, DIMENSION(:)  :: sf_sd    ! structure of input fields (file informations, fields read) Stokes Drift
38   TYPE(FLD), ALLOCATABLE, DIMENSION(:)  :: sf_wn    ! structure of input fields (file informations, fields read) wave number for Qiao
39   TYPE(FLD), ALLOCATABLE, DIMENSION(:)  :: sf_tauoc ! structure of input fields (file informations, fields read) normalized wave stress into the ocean
40   REAL(wp), PUBLIC, ALLOCATABLE, DIMENSION(:,:)       :: cdn_wave 
41   REAL(wp), PUBLIC, ALLOCATABLE, DIMENSION(:,:)       :: swh,wmp, wnum
42   REAL(wp), PUBLIC, ALLOCATABLE, DIMENSION(:,:)       :: tauoc_wave
43   REAL(wp), PUBLIC, ALLOCATABLE, DIMENSION(:,:)       :: tsd2d
44   REAL(wp), PUBLIC, ALLOCATABLE, DIMENSION(:,:,:)     :: usd3d, vsd3d, wsd3d 
45   REAL(wp), PUBLIC, ALLOCATABLE, DIMENSION(:,:,:)     :: usd3dt , vsd3dt 
46
47   !! * Substitutions
48#  include "domzgr_substitute.h90"
49#  include "vectopt_loop_substitute.h90"
50   !!----------------------------------------------------------------------
51   !! NEMO/OPA 3.7 , NEMO Consortium (2014)
52   !! $Id$
53   !! Software governed by the CeCILL licence     (NEMOGCM/NEMO_CeCILL.txt)
54   !!----------------------------------------------------------------------
55CONTAINS
56
57   SUBROUTINE sbc_wave( kt )
58      !!---------------------------------------------------------------------
59      !!                     ***  ROUTINE sbc_wave  ***
60      !!
61      !! ** Purpose :   read wave parameters from wave model  in netcdf files.
62      !!
63      !! ** Method  : - Read namelist namsbc_wave
64      !!              - Read Cd_n10 fields in netcdf files
65      !!              - Read stokes drift 2d in netcdf files
66      !!              - Read wave number in netcdf files
67      !!              - Compute 3d stokes drift using Breivik et al.,2014
68      !!                formulation
69      !! ** action 
70      !!---------------------------------------------------------------------
71      USE zdf_oce,  ONLY : ln_zdfqiao
72
73      INTEGER, INTENT( in  ) :: kt       ! ocean time step
74      !
75      INTEGER            ::  ierror           ! return error code
76      INTEGER            ::  ifpr, jj,ji,jk   ! dummy loop indice
77      INTEGER            ::  ios              ! Local integer output status for namelist read
78      CHARACTER(len=100) ::  cn_dir           ! Root directory for location of drag coefficient files
79      REAL(wp)           ::  ztransp, zfac, zsp0, zk, zus, zvs
80      REAL(wp), DIMENSION(jpi,jpj) :: zusd2dt, zvsd2dt
81      REAL(wp), DIMENSION(jpi,jpj,jpk) :: ze3hdiv   ! 3D workspace
82      TYPE(FLD_N) ::  sn_cdg, sn_usd, sn_vsd            ! informations about the fields to be read
83      TYPE(FLD_N) ::  sn_swh, sn_wmp, sn_wnum, sn_tauoc !     "          "    "     "    "  "   "
84      TYPE(FLD_N), DIMENSION(jpfld) ::   slf_i          ! array of namelist informations on the fields to read
85      NAMELIST/namsbc_wave/  sn_cdg, cn_dir, sn_usd, sn_vsd, sn_swh, sn_wmp, sn_wnum, sn_tauoc
86      !!---------------------------------------------------------------------
87      !
88      !                                         ! -------------------- !
89      IF( kt == nit000 ) THEN                   ! First call kt=nit000 !
90         !                                      ! -------------------- !
91         REWIND( numnam_ref )              ! Namelist namsbc_wave in reference namelist : File for drag coeff. from wave model
92         READ  ( numnam_ref, namsbc_wave, IOSTAT = ios, ERR = 901)
93901      IF( ios /= 0 ) CALL ctl_nam ( ios , 'namsbc_wave in reference namelist', lwp )
94
95         REWIND( numnam_cfg )              ! Namelist namsbc_wave in configuration namelist : File for drag coeff. from wave model
96         READ  ( numnam_cfg, namsbc_wave, IOSTAT = ios, ERR = 902 )
97902      IF( ios /= 0 ) CALL ctl_nam ( ios , 'namsbc_wave in configuration namelist', lwp )
98         IF(lwm) WRITE ( numond, namsbc_wave )
99         !
100         IF( ln_cdgw ) THEN
101            ALLOCATE( sf_cd(1), STAT=ierror )           ! allocate and fill sf_wave with sn_cdg
102            IF( ierror > 0 )   CALL ctl_stop( 'STOP', 'sbc_wave: unable to allocate sf_wave structure' )
103            !
104            ALLOCATE( sf_cd(1)%fnow(jpi,jpj,1) )
105            IF( sn_cdg%ln_tint ) ALLOCATE( sf_cd(1)%fdta(jpi,jpj,1,2) )
106            CALL fld_fill( sf_cd, (/ sn_cdg /), cn_dir, 'sbc_wave', 'Wave module ', 'namsbc_wave' )
107            ALLOCATE( cdn_wave(jpi,jpj) )
108         ENDIF
109
110         IF( ln_tauoc ) THEN
111            ALLOCATE( sf_tauoc(1), STAT=ierror )           ! allocate and fill sf_wave with sn_tauoc
112            IF( ierror > 0 )   CALL ctl_stop( 'STOP', 'sbc_wave: unable to allocate sf_wave structure' )
113            !
114            ALLOCATE( sf_tauoc(1)%fnow(jpi,jpj,1) )
115            IF( sn_tauoc%ln_tint ) ALLOCATE( sf_tauoc(1)%fdta(jpi,jpj,1,2) )
116            CALL fld_fill( sf_tauoc, (/ sn_tauoc /), cn_dir, 'sbc_wave', 'Wave module', 'namsbc_wave' )
117            ALLOCATE( tauoc_wave(jpi,jpj) )
118            tauoc_wave(:,:) = 0.0
119         ENDIF
120
121         IF( ln_sdw ) THEN
122            slf_i(jp_usd) = sn_usd ; slf_i(jp_vsd) = sn_vsd;
123            slf_i(jp_swh) = sn_swh ; slf_i(jp_wmp) = sn_wmp;
124            ALLOCATE( sf_sd(jpfld), STAT=ierror )           ! allocate and fill sf_sd with stokes drift
125            IF( ierror > 0 )   CALL ctl_stop( 'STOP', 'sbc_wave: unable to allocate sf_wave structure' )
126            !
127            DO ifpr = 1, jpfld
128               ALLOCATE( sf_sd(ifpr)%fnow(jpi,jpj,1) )
129               IF( slf_i(ifpr)%ln_tint )   ALLOCATE( sf_sd(ifpr)%fdta(jpi,jpj,1,2) )
130            END DO
131
132            CALL fld_fill( sf_sd, slf_i, cn_dir, 'sbc_wave', 'Wave module ', 'namsbc_wave' )
133            ALLOCATE( usd3dt(jpi,jpj,jpk), vsd3dt(jpi,jpj,jpk), wsd3d(jpi,jpj,jpk) )
134            ALLOCATE( usd3d (jpi,jpj,jpk), vsd3d (jpi,jpj,jpk) )
135            ALLOCATE( swh(jpi,jpj), wmp(jpi,jpj) )
136            usd3d(:,:,:) = 0._wp       
137            vsd3d(:,:,:) = 0._wp     
138            wsd3d(:,:,:) = 0._wp   
139            IF( ln_zdfqiao ) THEN     !==  Vertical mixing enhancement using Qiao,2010  ==!
140               ALLOCATE( sf_wn(1), STAT=ierror )           !* allocate and fill sf_wave with sn_wnum
141               IF( ierror > 0 )   CALL ctl_stop( 'STOP', 'sbc_wave: unable to allocate sf_wave structure' )
142               ALLOCATE( sf_wn(1)%fnow(jpi,jpj,1) )
143               IF( sn_wnum%ln_tint )  ALLOCATE( sf_wn(1)%fdta(jpi,jpj,1,2) )
144               CALL fld_fill( sf_wn, (/ sn_wnum /), cn_dir, 'sbc_wave', 'Wave module', 'namsbc_wave' )
145               ALLOCATE( wnum(jpi,jpj),tsd2d(jpi,jpj) )
146            ENDIF
147         ENDIF
148      ENDIF
149      !
150      IF( ln_cdgw ) THEN              !==  Neutral drag coefficient  ==!
151         CALL fld_read( kt, nn_fsbc, sf_cd )        ! read from external forcing
152         cdn_wave(:,:) = sf_cd(1)%fnow(:,:,1)
153      ENDIF
154
155      IF( ln_tauoc ) THEN             !==  Wave induced stress  ==!
156         CALL fld_read( kt, nn_fsbc, sf_tauoc )     ! read wave norm stress from external forcing
157         tauoc_wave(:,:) = sf_tauoc(1)%fnow(:,:,1)
158      ENDIF
159
160      IF( ln_sdw )  THEN              !==  Computation of the 3d Stokes Drift  ==!
161         CALL fld_read( kt, nn_fsbc, sf_sd )        ! read wave parameters from external forcing
162         swh(:,:)     = sf_sd(jp_swh)%fnow(:,:,1)   ! significant wave height
163         wmp(:,:)     = sf_sd(jp_wmp)%fnow(:,:,1)   ! wave mean period
164         zusd2dt(:,:) = sf_sd(jp_usd)%fnow(:,:,1)   ! 2D zonal Stokes Drift at T point
165         zvsd2dt(:,:) = sf_sd(jp_vsd)%fnow(:,:,1)   ! 2D meridional Stokes Drift at T point
166         !
167         !==  Computation of the 3d Stokes Drift according to Breivik et al.,2014
168         !(DOI: 10.1175/JPO-D-14-0020.1)==!
169         !
170         DO jk = 1, jpk
171            DO jj = 1, jpj
172               DO ji = 1, jpi
173                  ! On T grid
174                  ! Stokes transport speed estimated from Hs and Tmean
175                  ztransp = 2.0_wp*rpi*swh(ji,jj)**2.0_wp/(16.0_wp*MAX(wmp(ji,jj),0.0000001_wp))
176                  ! Stokes surface speed
177                  zsp0 = SQRT( zusd2dt(ji,jj)**2 + zvsd2dt(ji,jj)**2 )
178                  ! Wavenumber scale
179                  zk = ABS(zsp0)/MAX(ABS(5.97_wp*ztransp),0.0000001_wp)
180                  ! Depth attenuation
181                  zfac = EXP(-2.0_wp*zk*fsdept(ji,jj,jk))/(1.0_wp+8.0_wp*zk*fsdept(ji,jj,jk))
182                  !
183                  usd3dt(ji,jj,jk) = zfac * zusd2dt(ji,jj) * tmask(ji,jj,jk)
184                  vsd3dt(ji,jj,jk) = zfac * zvsd2dt(ji,jj) * tmask(ji,jj,jk)
185               END DO
186            END DO
187         END DO
188         ! Into the U and V Grid
189         DO jk = 1, jpkm1
190            DO jj = 1, jpjm1
191               DO ji = 1, jpim1
192                  usd3d(ji,jj,jk) = 0.5 *  umask(ji,jj,jk) *   &
193                                  &  ( usd3dt(ji,jj,jk) + usd3dt(ji+1,jj,jk) )
194                  vsd3d(ji,jj,jk) = 0.5 *  vmask(ji,jj,jk) *   &
195                                  &  ( vsd3dt(ji,jj,jk) + vsd3dt(ji,jj+1,jk) )
196               END DO
197            END DO
198         END DO
199         !
200         CALL lbc_lnk( usd3d(:,:,:), 'U', -1. )
201         CALL lbc_lnk( vsd3d(:,:,:), 'V', -1. )
202         !
203         DO jk = 1, jpkm1               ! Horizontal divergence
204            DO jj = 2, jpj
205               DO ji = fs_2, jpi   
206                  ze3hdiv(ji,jj,jk) = (  e2u(ji  ,jj) * usd3d(ji  ,jj,jk)     &
207                     &                 - e2u(ji-1,jj) * usd3d(ji-1,jj,jk)     &
208                     &                 + e1v(ji,jj  ) * vsd3d(ji,jj  ,jk)     &
209                     &                 - e1v(ji,jj-1) * vsd3d(ji,jj-1,jk)   ) * r1_e1e2t(ji,jj)
210               END DO 
211            END DO 
212         END DO
213         !
214         IF( .NOT. AGRIF_Root() ) THEN
215            IF( nbondi ==  1 .OR. nbondi == 2 )   ze3hdiv(nlci-1,   :  ,:) = 0._wp      ! east
216            IF( nbondi == -1 .OR. nbondi == 2 )   ze3hdiv(  2   ,   :  ,:) = 0._wp      ! west
217            IF( nbondj ==  1 .OR. nbondj == 2 )   ze3hdiv(  :   ,nlcj-1,:) = 0._wp      ! north
218            IF( nbondj == -1 .OR. nbondj == 2 )   ze3hdiv(  :   ,  2   ,:) = 0._wp      ! south
219         ENDIF
220         !
221         CALL lbc_lnk( ze3hdiv, 'T', 1. ) 
222         !
223         DO jk = jpkm1, 1, -1                   ! integrate from the bottom the e3t * hor. divergence
224            wsd3d(:,:,jk) = wsd3d(:,:,jk+1) - fse3t_n(:,:,jk) * ze3hdiv(:,:,jk)
225         END DO
226#if defined key_bdy
227         IF( lk_bdy ) THEN
228            DO jk = 1, jpkm1
229               wsd3d(:,:,jk) = wsd3d(:,:,jk) * bdytmask(:,:)
230            END DO
231         ENDIF
232#endif
233
234         IF ( ln_zdfqiao ) THEN
235            CALL fld_read( kt, nn_fsbc, sf_wn )      ! read wave parameters from external forcing
236            wnum(:,:) = sf_wn(1)%fnow(:,:,1)
237           
238            ! Calculate the module of the stokes drift on T grid
239            !-------------------------------------------------
240            DO jj = 1, jpj
241               DO ji = 1, jpi
242                  tsd2d(ji,jj) = SQRT( zusd2dt(ji,jj)**2 + zvsd2dt(ji,jj)**2 ) 
243               END DO
244            END DO
245         ENDIF
246         !
247      ENDIF
248      !
249   END SUBROUTINE sbc_wave
250     
251   !!======================================================================
252END MODULE sbcwave
Note: See TracBrowser for help on using the repository browser.