New URL for NEMO forge!   http://forge.nemo-ocean.eu

Since March 2022 along with NEMO 4.2 release, the code development moved to a self-hosted GitLab.
This present forge is now archived and remained online for history.
zdfgls.F90 in branches/2015/nemo_v3_6_STABLE/NEMOGCM/NEMO/OPA_SRC/ZDF – NEMO

source: branches/2015/nemo_v3_6_STABLE/NEMOGCM/NEMO/OPA_SRC/ZDF/zdfgls.F90 @ 5610

Last change on this file since 5610 was 5610, checked in by cetlod, 9 years ago

bugfix to reduce lines over 132, see ticket #1564
  • Property svn:keywords set to Id
File size: 58.5 KB
Line 
1MODULE zdfgls
2   !!======================================================================
3   !!                       ***  MODULE  zdfgls  ***
4   !! Ocean physics:  vertical mixing coefficient computed from the gls
5   !!                 turbulent closure parameterization
6   !!======================================================================
7   !! History :   3.0  !  2009-09  (G. Reffray)  Original code
8   !!             3.3  !  2010-10  (C. Bricaud)  Add in the reference
9   !!----------------------------------------------------------------------
10#if defined key_zdfgls   ||   defined key_esopa
11   !!----------------------------------------------------------------------
12   !!   'key_zdfgls'                 Generic Length Scale vertical physics
13   !!----------------------------------------------------------------------
14   !!   zdf_gls       : update momentum and tracer Kz from a gls scheme
15   !!   zdf_gls_init  : initialization, namelist read, and parameters control
16   !!   gls_rst       : read/write gls restart in ocean restart file
17   !!----------------------------------------------------------------------
18   USE oce            ! ocean dynamics and active tracers
19   USE dom_oce        ! ocean space and time domain
20   USE domvvl         ! ocean space and time domain : variable volume layer
21   USE zdf_oce        ! ocean vertical physics
22   USE zdfbfr         ! bottom friction (only for rn_bfrz0)
23   USE sbc_oce        ! surface boundary condition: ocean
24   USE phycst         ! physical constants
25   USE zdfmxl         ! mixed layer
26   USE lbclnk         ! ocean lateral boundary conditions (or mpp link)
27   USE lib_mpp        ! MPP manager
28   USE wrk_nemo       ! work arrays
29   USE prtctl         ! Print control
30   USE in_out_manager ! I/O manager
31   USE iom            ! I/O manager library
32   USE timing         ! Timing
33   USE lib_fortran    ! Fortran utilities (allows no signed zero when 'key_nosignedzero' defined) 
34
35   IMPLICIT NONE
36   PRIVATE
37
38   PUBLIC   zdf_gls        ! routine called in step module
39   PUBLIC   zdf_gls_init   ! routine called in opa module
40   PUBLIC   gls_rst        ! routine called in step module
41
42   LOGICAL , PUBLIC, PARAMETER ::   lk_zdfgls = .TRUE.   !: TKE vertical mixing flag
43   !
44   REAL(wp), PUBLIC, ALLOCATABLE, SAVE, DIMENSION(:,:,:) ::   en      !: now turbulent kinetic energy
45   REAL(wp), PUBLIC, ALLOCATABLE, SAVE, DIMENSION(:,:,:) ::   mxln    !: now mixing length
46   REAL(wp), PUBLIC, ALLOCATABLE, SAVE, DIMENSION(:,:,:) ::   zwall   !: wall function
47   REAL(wp), PUBLIC, ALLOCATABLE, SAVE, DIMENSION(:,:,:) ::   avt_k   ! not enhanced Kz
48   REAL(wp), PUBLIC, ALLOCATABLE, SAVE, DIMENSION(:,:,:) ::   avm_k   ! not enhanced Kz
49   REAL(wp), PUBLIC, ALLOCATABLE, SAVE, DIMENSION(:,:,:) ::   avmu_k  ! not enhanced Kz
50   REAL(wp), PUBLIC, ALLOCATABLE, SAVE, DIMENSION(:,:,:) ::   avmv_k  ! not enhanced Kz
51   REAL(wp), PUBLIC, ALLOCATABLE, SAVE, DIMENSION(:,:)   ::   ustars2 !: Squared surface velocity scale at T-points
52   REAL(wp), PUBLIC, ALLOCATABLE, SAVE, DIMENSION(:,:)   ::   ustarb2 !: Squared bottom  velocity scale at T-points
53
54   !                              !! ** Namelist  namzdf_gls  **
55   LOGICAL  ::   ln_length_lim     ! use limit on the dissipation rate under stable stratification (Galperin et al. 1988)
56   LOGICAL  ::   ln_sigpsi         ! Activate Burchard (2003) modification for k-eps closure & wave breaking mixing
57   INTEGER  ::   nn_bc_surf        ! surface boundary condition (=0/1)
58   INTEGER  ::   nn_bc_bot         ! bottom boundary condition (=0/1)
59   INTEGER  ::   nn_z0_met         ! Method for surface roughness computation
60   INTEGER  ::   nn_stab_func      ! stability functions G88, KC or Canuto (=0/1/2)
61   INTEGER  ::   nn_clos           ! closure 0/1/2/3 MY82/k-eps/k-w/gen
62   REAL(wp) ::   rn_clim_galp      ! Holt 2008 value for k-eps: 0.267
63   REAL(wp) ::   rn_epsmin         ! minimum value of dissipation (m2/s3)
64   REAL(wp) ::   rn_emin           ! minimum value of TKE (m2/s2)
65   REAL(wp) ::   rn_charn          ! Charnock constant for surface breaking waves mixing : 1400. (standard) or 2.e5 (Stacey value)
66   REAL(wp) ::   rn_crban          ! Craig and Banner constant for surface breaking waves mixing
67   REAL(wp) ::   rn_hsro           ! Minimum surface roughness
68   REAL(wp) ::   rn_frac_hs        ! Fraction of wave height as surface roughness (if nn_z0_met > 1)
69
70   REAL(wp) ::   rcm_sf        =  0.73_wp     ! Shear free turbulence parameters
71   REAL(wp) ::   ra_sf         = -2.0_wp      ! Must be negative -2 < ra_sf < -1
72   REAL(wp) ::   rl_sf         =  0.2_wp      ! 0 <rl_sf<vkarmn   
73   REAL(wp) ::   rghmin        = -0.28_wp
74   REAL(wp) ::   rgh0          =  0.0329_wp
75   REAL(wp) ::   rghcri        =  0.03_wp
76   REAL(wp) ::   ra1           =  0.92_wp
77   REAL(wp) ::   ra2           =  0.74_wp
78   REAL(wp) ::   rb1           = 16.60_wp
79   REAL(wp) ::   rb2           = 10.10_wp         
80   REAL(wp) ::   re2           =  1.33_wp         
81   REAL(wp) ::   rl1           =  0.107_wp
82   REAL(wp) ::   rl2           =  0.0032_wp
83   REAL(wp) ::   rl3           =  0.0864_wp
84   REAL(wp) ::   rl4           =  0.12_wp
85   REAL(wp) ::   rl5           = 11.9_wp
86   REAL(wp) ::   rl6           =  0.4_wp
87   REAL(wp) ::   rl7           =  0.0_wp
88   REAL(wp) ::   rl8           =  0.48_wp
89   REAL(wp) ::   rm1           =  0.127_wp
90   REAL(wp) ::   rm2           =  0.00336_wp
91   REAL(wp) ::   rm3           =  0.0906_wp
92   REAL(wp) ::   rm4           =  0.101_wp
93   REAL(wp) ::   rm5           = 11.2_wp
94   REAL(wp) ::   rm6           =  0.4_wp
95   REAL(wp) ::   rm7           =  0.0_wp
96   REAL(wp) ::   rm8           =  0.318_wp
97   REAL(wp) ::   rtrans        =  0.1_wp
98   REAL(wp) ::   rc02, rc02r, rc03, rc04                          ! coefficients deduced from above parameters
99   REAL(wp) ::   rsbc_tke1, rsbc_tke2, rfact_tke                  !     -           -           -        -
100   REAL(wp) ::   rsbc_psi1, rsbc_psi2, rfact_psi                  !     -           -           -        -
101   REAL(wp) ::   rsbc_zs1, rsbc_zs2                               !     -           -           -        -
102   REAL(wp) ::   rc0, rc2, rc3, rf6, rcff, rc_diff                !     -           -           -        -
103   REAL(wp) ::   rs0, rs1, rs2, rs4, rs5, rs6                     !     -           -           -        -
104   REAL(wp) ::   rd0, rd1, rd2, rd3, rd4, rd5                     !     -           -           -        -
105   REAL(wp) ::   rsc_tke, rsc_psi, rpsi1, rpsi2, rpsi3, rsc_psi0  !     -           -           -        -
106   REAL(wp) ::   rpsi3m, rpsi3p, rpp, rmm, rnn                    !     -           -           -        -
107
108   !! * Substitutions
109#  include "domzgr_substitute.h90"
110#  include "vectopt_loop_substitute.h90"
111   !!----------------------------------------------------------------------
112   !! NEMO/OPA 3.3 , NEMO Consortium (2010)
113   !! $Id$
114   !! Software governed by the CeCILL licence     (NEMOGCM/NEMO_CeCILL.txt)
115   !!----------------------------------------------------------------------
116CONTAINS
117
118   INTEGER FUNCTION zdf_gls_alloc()
119      !!----------------------------------------------------------------------
120      !!                ***  FUNCTION zdf_gls_alloc  ***
121      !!----------------------------------------------------------------------
122      ALLOCATE( en(jpi,jpj,jpk),  mxln(jpi,jpj,jpk), zwall(jpi,jpj,jpk) ,     &
123         &      avt_k (jpi,jpj,jpk) , avm_k (jpi,jpj,jpk),                    &
124         &      avmu_k(jpi,jpj,jpk) , avmv_k(jpi,jpj,jpk),                    &
125         &      ustars2(jpi,jpj), ustarb2(jpi,jpj)                      , STAT= zdf_gls_alloc )
126         !
127      IF( lk_mpp             )   CALL mpp_sum ( zdf_gls_alloc )
128      IF( zdf_gls_alloc /= 0 )   CALL ctl_warn('zdf_gls_alloc: failed to allocate arrays')
129   END FUNCTION zdf_gls_alloc
130
131
132   SUBROUTINE zdf_gls( kt )
133      !!----------------------------------------------------------------------
134      !!                   ***  ROUTINE zdf_gls  ***
135      !!
136      !! ** Purpose :   Compute the vertical eddy viscosity and diffusivity
137      !!              coefficients using the GLS turbulent closure scheme.
138      !!----------------------------------------------------------------------
139      INTEGER, INTENT(in) ::   kt ! ocean time step
140      INTEGER  ::   ji, jj, jk, ibot, ibotm1, dir  ! dummy loop arguments
141      REAL(wp) ::   zesh2, zsigpsi, zcoef, zex1, zex2   ! local scalars
142      REAL(wp) ::   ztx2, zty2, zup, zdown, zcof        !   -      -
143      REAL(wp) ::   zratio, zrn2, zflxb, sh             !   -      -
144      REAL(wp) ::   prod, buoy, diss, zdiss, sm         !   -      -
145      REAL(wp) ::   gh, gm, shr, dif, zsqen, zav        !   -      -
146      REAL(wp), POINTER, DIMENSION(:,:  ) ::   zdep
147      REAL(wp), POINTER, DIMENSION(:,:  ) ::   zkar
148      REAL(wp), POINTER, DIMENSION(:,:  ) ::   zflxs       ! Turbulence fluxed induced by internal waves
149      REAL(wp), POINTER, DIMENSION(:,:  ) ::   zhsro       ! Surface roughness (surface waves)
150      REAL(wp), POINTER, DIMENSION(:,:,:) ::   eb          ! tke at time before
151      REAL(wp), POINTER, DIMENSION(:,:,:) ::   mxlb        ! mixing length at time before
152      REAL(wp), POINTER, DIMENSION(:,:,:) ::   shear       ! vertical shear
153      REAL(wp), POINTER, DIMENSION(:,:,:) ::   eps         ! dissipation rate
154      REAL(wp), POINTER, DIMENSION(:,:,:) ::   zwall_psi   ! Wall function use in the wb case (ln_sigpsi)
155      REAL(wp), POINTER, DIMENSION(:,:,:) ::   psi         ! psi at time now
156      REAL(wp), POINTER, DIMENSION(:,:,:) ::   z_elem_a    ! element of the first  matrix diagonal
157      REAL(wp), POINTER, DIMENSION(:,:,:) ::   z_elem_b    ! element of the second matrix diagonal
158      REAL(wp), POINTER, DIMENSION(:,:,:) ::   z_elem_c    ! element of the third  matrix diagonal
159      !!--------------------------------------------------------------------
160      !
161      IF( nn_timing == 1 )  CALL timing_start('zdf_gls')
162      !
163      CALL wrk_alloc( jpi,jpj, zdep, zkar, zflxs, zhsro )
164      CALL wrk_alloc( jpi,jpj,jpk, eb, mxlb, shear, eps, zwall_psi, z_elem_a, z_elem_b, z_elem_c, psi  )
165     
166      ! Preliminary computing
167
168      ustars2 = 0._wp   ;   ustarb2 = 0._wp   ;   psi  = 0._wp   ;   zwall_psi = 0._wp
169
170      IF( kt /= nit000 ) THEN   ! restore before value to compute tke
171         avt (:,:,:) = avt_k (:,:,:)
172         avm (:,:,:) = avm_k (:,:,:)
173         avmu(:,:,:) = avmu_k(:,:,:)
174         avmv(:,:,:) = avmv_k(:,:,:) 
175      ENDIF
176
177      ! Compute surface and bottom friction at T-points
178!CDIR NOVERRCHK         
179      DO jj = 2, jpjm1         
180!CDIR NOVERRCHK         
181         DO ji = fs_2, fs_jpim1   ! vector opt.         
182            !
183            ! surface friction
184            ustars2(ji,jj) = r1_rau0 * taum(ji,jj) * tmask(ji,jj,1)
185            !   
186            ! bottom friction (explicit before friction)       
187            ! Note that we chose here not to bound the friction as in dynbfr)   
188            ztx2 = (  bfrua(ji,jj)  * ub(ji,jj,mbku(ji,jj)) + bfrua(ji-1,jj) * ub(ji-1,jj,mbku(ji-1,jj))  )   &         
189               & * ( 1._wp - 0.5_wp * umask(ji,jj,1) * umask(ji-1,jj,1)  )     
190            zty2 = (  bfrva(ji,jj)  * vb(ji,jj,mbkv(ji,jj)) + bfrva(ji,jj-1) * vb(ji,jj-1,mbkv(ji,jj-1))  )   &         
191               & * ( 1._wp - 0.5_wp * vmask(ji,jj,1) * vmask(ji,jj-1,1)  )     
192            ustarb2(ji,jj) = SQRT( ztx2 * ztx2 + zty2 * zty2 ) * tmask(ji,jj,1)         
193         END DO         
194      END DO   
195
196      ! Set surface roughness length
197      SELECT CASE ( nn_z0_met )
198      !
199      CASE ( 0 )             ! Constant roughness         
200         zhsro(:,:) = rn_hsro
201      CASE ( 1 )             ! Standard Charnock formula
202         zhsro(:,:) = MAX(rsbc_zs1 * ustars2(:,:), rn_hsro)
203      CASE ( 2 )             ! Roughness formulae according to Rascle et al., Ocean Modelling (2008)
204         zdep(:,:)  = 30.*TANH(2.*0.3/(28.*SQRT(MAX(ustars2(:,:),rsmall))))             ! Wave age (eq. 10)
205         zhsro(:,:) = MAX(rsbc_zs2 * ustars2(:,:) * zdep(:,:)**1.5, rn_hsro) ! zhsro = rn_frac_hs * Hsw (eq. 11)
206      !
207      END SELECT
208
209      ! Compute shear and dissipation rate
210      DO jk = 2, jpkm1
211         DO jj = 2, jpjm1
212            DO ji = fs_2, fs_jpim1   ! vector opt.
213               avmu(ji,jj,jk) = avmu(ji,jj,jk) * ( un(ji,jj,jk-1) - un(ji,jj,jk) )   &
214                  &                            * ( ub(ji,jj,jk-1) - ub(ji,jj,jk) )   &
215                  &                            / (  fse3uw_n(ji,jj,jk)               &
216                  &                            *    fse3uw_b(ji,jj,jk) )
217               avmv(ji,jj,jk) = avmv(ji,jj,jk) * ( vn(ji,jj,jk-1) - vn(ji,jj,jk) )   &
218                  &                            * ( vb(ji,jj,jk-1) - vb(ji,jj,jk) )   &
219                  &                            / (  fse3vw_n(ji,jj,jk)               &
220                  &                            *    fse3vw_b(ji,jj,jk) )
221               eps(ji,jj,jk)  = rc03 * en(ji,jj,jk) * SQRT(en(ji,jj,jk)) / mxln(ji,jj,jk)
222            END DO
223         END DO
224      END DO
225      !
226      ! Lateral boundary conditions (avmu,avmv) (sign unchanged)
227      CALL lbc_lnk( avmu, 'U', 1. )   ;   CALL lbc_lnk( avmv, 'V', 1. )
228
229      ! Save tke at before time step
230      eb  (:,:,:) = en  (:,:,:)
231      mxlb(:,:,:) = mxln(:,:,:)
232
233      IF( nn_clos == 0 ) THEN    ! Mellor-Yamada
234         DO jk = 2, jpkm1
235            DO jj = 2, jpjm1 
236               DO ji = fs_2, fs_jpim1   ! vector opt.
237                  zup   = mxln(ji,jj,jk) * fsdepw(ji,jj,mbkt(ji,jj)+1)
238                  zdown = vkarmn * fsdepw(ji,jj,jk) * ( -fsdepw(ji,jj,jk) + fsdepw(ji,jj,mbkt(ji,jj)+1) )
239                  zcoef = ( zup / MAX( zdown, rsmall ) )
240                  zwall (ji,jj,jk) = ( 1._wp + re2 * zcoef*zcoef ) * tmask(ji,jj,jk)
241               END DO
242            END DO
243         END DO
244      ENDIF
245
246      !!---------------------------------!!
247      !!   Equation to prognostic k      !!
248      !!---------------------------------!!
249      !
250      ! Now Turbulent kinetic energy (output in en)
251      ! -------------------------------
252      ! Resolution of a tridiagonal linear system by a "methode de chasse"
253      ! computation from level 2 to jpkm1  (e(1) computed after and e(jpk)=0 ).
254      ! The surface boundary condition are set after
255      ! The bottom boundary condition are also set after. In standard e(bottom)=0.
256      ! z_elem_b : diagonal z_elem_c : upper diagonal z_elem_a : lower diagonal
257      ! Warning : after this step, en : right hand side of the matrix
258
259      DO jk = 2, jpkm1
260         DO jj = 2, jpjm1
261            DO ji = fs_2, fs_jpim1   ! vector opt.
262               !
263               ! shear prod. at w-point weightened by mask
264               shear(ji,jj,jk) =  ( avmu(ji-1,jj,jk) + avmu(ji,jj,jk) ) / MAX( 1.e0 , umask(ji-1,jj,jk) + umask(ji,jj,jk) )   &
265                  &             + ( avmv(ji,jj-1,jk) + avmv(ji,jj,jk) ) / MAX( 1.e0 , vmask(ji,jj-1,jk) + vmask(ji,jj,jk) )
266               !
267               ! stratif. destruction
268               buoy = - avt(ji,jj,jk) * rn2(ji,jj,jk)
269               !
270               ! shear prod. - stratif. destruction
271               diss = eps(ji,jj,jk)
272               !
273               dir = 0.5_wp + SIGN( 0.5_wp, shear(ji,jj,jk) + buoy )   ! dir =1(=0) if shear(ji,jj,jk)+buoy >0(<0)
274               !
275               zesh2 = dir*(shear(ji,jj,jk)+buoy)+(1._wp-dir)*shear(ji,jj,jk)          ! production term
276               zdiss = dir*(diss/en(ji,jj,jk))   +(1._wp-dir)*(diss-buoy)/en(ji,jj,jk) ! dissipation term
277               !
278               ! Compute a wall function from 1. to rsc_psi*zwall/rsc_psi0
279               ! Note that as long that Dirichlet boundary conditions are NOT set at the first and last levels (GOTM style)
280               ! there is no need to set a boundary condition for zwall_psi at the top and bottom boundaries.
281               ! Otherwise, this should be rsc_psi/rsc_psi0
282               IF( ln_sigpsi ) THEN
283                  zsigpsi = MIN( 1._wp, zesh2 / eps(ji,jj,jk) )     ! 0. <= zsigpsi <= 1.
284                  zwall_psi(ji,jj,jk) = rsc_psi /   & 
285                     &     (  zsigpsi * rsc_psi + (1._wp-zsigpsi) * rsc_psi0 / MAX( zwall(ji,jj,jk), 1._wp )  )
286               ELSE
287                  zwall_psi(ji,jj,jk) = 1._wp
288               ENDIF
289               !
290               ! building the matrix
291               zcof = rfact_tke * tmask(ji,jj,jk)
292               !
293               ! lower diagonal
294               z_elem_a(ji,jj,jk) = zcof * ( avm  (ji,jj,jk  ) + avm  (ji,jj,jk-1) )   &
295                  &                      / ( fse3t(ji,jj,jk-1) * fse3w(ji,jj,jk  ) )
296               !
297               ! upper diagonal
298               z_elem_c(ji,jj,jk) = zcof * ( avm  (ji,jj,jk+1) + avm  (ji,jj,jk  ) )   &
299                  &                      / ( fse3t(ji,jj,jk  ) * fse3w(ji,jj,jk) )
300               !
301               ! diagonal
302               z_elem_b(ji,jj,jk) = 1._wp - z_elem_a(ji,jj,jk) - z_elem_c(ji,jj,jk)  &
303                  &                       + rdt * zdiss * tmask(ji,jj,jk) 
304               !
305               ! right hand side in en
306               en(ji,jj,jk) = en(ji,jj,jk) + rdt * zesh2 * tmask(ji,jj,jk)
307            END DO
308         END DO
309      END DO
310      !
311      z_elem_b(:,:,jpk) = 1._wp
312      !
313      ! Set surface condition on zwall_psi (1 at the bottom)
314      zwall_psi(:,:,1) = zwall_psi(:,:,2)
315      zwall_psi(:,:,jpk) = 1.
316      !
317      ! Surface boundary condition on tke
318      ! ---------------------------------
319      !
320      SELECT CASE ( nn_bc_surf )
321      !
322      CASE ( 0 )             ! Dirichlet case
323      ! First level
324      en(:,:,1) = rc02r * ustars2(:,:) * (1._wp + rsbc_tke1)**(2._wp/3._wp)
325      en(:,:,1) = MAX(en(:,:,1), rn_emin) 
326      z_elem_a(:,:,1) = en(:,:,1)
327      z_elem_c(:,:,1) = 0._wp
328      z_elem_b(:,:,1) = 1._wp
329      !
330      ! One level below
331      en(:,:,2) = rc02r * ustars2(:,:) * (1._wp + rsbc_tke1 * ((zhsro(:,:)+fsdepw(:,:,2)) &
332          &            / zhsro(:,:) )**(1.5_wp*ra_sf))**(2._wp/3._wp)
333      en(:,:,2) = MAX(en(:,:,2), rn_emin )
334      z_elem_a(:,:,2) = 0._wp 
335      z_elem_c(:,:,2) = 0._wp
336      z_elem_b(:,:,2) = 1._wp
337      !
338      !
339      CASE ( 1 )             ! Neumann boundary condition on d(e)/dz
340      !
341      ! Dirichlet conditions at k=1
342      en(:,:,1)       = rc02r * ustars2(:,:) * (1._wp + rsbc_tke1)**(2._wp/3._wp)
343      en(:,:,1)       = MAX(en(:,:,1), rn_emin)     
344      z_elem_a(:,:,1) = en(:,:,1)
345      z_elem_c(:,:,1) = 0._wp
346      z_elem_b(:,:,1) = 1._wp
347      !
348      ! at k=2, set de/dz=Fw
349      !cbr
350      z_elem_b(:,:,2) = z_elem_b(:,:,2) +  z_elem_a(:,:,2) ! Remove z_elem_a from z_elem_b
351      z_elem_a(:,:,2) = 0._wp
352      zkar(:,:)       = (rl_sf + (vkarmn-rl_sf)*(1.-exp(-rtrans*fsdept(:,:,1)/zhsro(:,:)) ))
353      zflxs(:,:)      = rsbc_tke2 * ustars2(:,:)**1.5_wp * zkar(:,:) &
354           &                      * ((zhsro(:,:)+fsdept(:,:,1))/zhsro(:,:) )**(1.5_wp*ra_sf)
355
356      en(:,:,2) = en(:,:,2) + zflxs(:,:)/fse3w(:,:,2)
357      !
358      !
359      END SELECT
360
361      ! Bottom boundary condition on tke
362      ! --------------------------------
363      !
364      SELECT CASE ( nn_bc_bot )
365      !
366      CASE ( 0 )             ! Dirichlet
367         !                      ! en(ibot) = u*^2 / Co2 and mxln(ibot) = rn_lmin
368         !                      ! Balance between the production and the dissipation terms
369!CDIR NOVERRCHK
370         DO jj = 2, jpjm1
371!CDIR NOVERRCHK
372            DO ji = fs_2, fs_jpim1   ! vector opt.
373               ibot   = mbkt(ji,jj) + 1      ! k   bottom level of w-point
374               ibotm1 = mbkt(ji,jj)          ! k-1 bottom level of w-point but >=1
375               !
376               ! Bottom level Dirichlet condition:
377               z_elem_a(ji,jj,ibot  ) = 0._wp
378               z_elem_c(ji,jj,ibot  ) = 0._wp
379               z_elem_b(ji,jj,ibot  ) = 1._wp
380               en(ji,jj,ibot  ) = MAX( rc02r * ustarb2(ji,jj), rn_emin )
381               !
382               ! Just above last level, Dirichlet condition again
383               z_elem_a(ji,jj,ibotm1) = 0._wp
384               z_elem_c(ji,jj,ibotm1) = 0._wp
385               z_elem_b(ji,jj,ibotm1) = 1._wp
386               en(ji,jj,ibotm1) = MAX( rc02r * ustarb2(ji,jj), rn_emin ) 
387            END DO
388         END DO
389         !
390      CASE ( 1 )             ! Neumman boundary condition
391         !                     
392!CDIR NOVERRCHK
393         DO jj = 2, jpjm1
394!CDIR NOVERRCHK
395            DO ji = fs_2, fs_jpim1   ! vector opt.
396               ibot   = mbkt(ji,jj) + 1      ! k   bottom level of w-point
397               ibotm1 = mbkt(ji,jj)          ! k-1 bottom level of w-point but >=1
398               !
399               ! Bottom level Dirichlet condition:
400               z_elem_a(ji,jj,ibot) = 0._wp
401               z_elem_c(ji,jj,ibot) = 0._wp
402               z_elem_b(ji,jj,ibot) = 1._wp
403               en(ji,jj,ibot) = MAX( rc02r * ustarb2(ji,jj), rn_emin )
404               !
405               ! Just above last level: Neumann condition
406               z_elem_b(ji,jj,ibotm1) = z_elem_b(ji,jj,ibotm1) + z_elem_c(ji,jj,ibotm1)   ! Remove z_elem_c from z_elem_b
407               z_elem_c(ji,jj,ibotm1) = 0._wp
408            END DO
409         END DO
410         !
411      END SELECT
412
413      ! Matrix inversion (en prescribed at surface and the bottom)
414      ! ----------------------------------------------------------
415      !
416      DO jk = 2, jpkm1                             ! First recurrence : Dk = Dk - Lk * Uk-1 / Dk-1
417         DO jj = 2, jpjm1
418            DO ji = fs_2, fs_jpim1    ! vector opt.
419               z_elem_b(ji,jj,jk) = z_elem_b(ji,jj,jk) - z_elem_a(ji,jj,jk) * z_elem_c(ji,jj,jk-1) / z_elem_b(ji,jj,jk-1)
420            END DO
421         END DO
422      END DO
423      DO jk = 2, jpk                               ! Second recurrence : Lk = RHSk - Lk / Dk-1 * Lk-1
424         DO jj = 2, jpjm1
425            DO ji = fs_2, fs_jpim1    ! vector opt.
426               z_elem_a(ji,jj,jk) = en(ji,jj,jk) - z_elem_a(ji,jj,jk) / z_elem_b(ji,jj,jk-1) * z_elem_a(ji,jj,jk-1)
427            END DO
428         END DO
429      END DO
430      DO jk = jpk-1, 2, -1                         ! thrid recurrence : Ek = ( Lk - Uk * Ek+1 ) / Dk
431         DO jj = 2, jpjm1
432            DO ji = fs_2, fs_jpim1    ! vector opt.
433               en(ji,jj,jk) = ( z_elem_a(ji,jj,jk) - z_elem_c(ji,jj,jk) * en(ji,jj,jk+1) ) / z_elem_b(ji,jj,jk)
434            END DO
435         END DO
436      END DO
437      !                                            ! set the minimum value of tke
438      en(:,:,:) = MAX( en(:,:,:), rn_emin )
439
440      !!----------------------------------------!!
441      !!   Solve prognostic equation for psi    !!
442      !!----------------------------------------!!
443
444      ! Set psi to previous time step value
445      !
446      SELECT CASE ( nn_clos )
447      !
448      CASE( 0 )               ! k-kl  (Mellor-Yamada)
449         DO jk = 2, jpkm1
450            DO jj = 2, jpjm1
451               DO ji = fs_2, fs_jpim1   ! vector opt.
452                  psi(ji,jj,jk)  = eb(ji,jj,jk) * mxlb(ji,jj,jk)
453               END DO
454            END DO
455         END DO
456         !
457      CASE( 1 )               ! k-eps
458         DO jk = 2, jpkm1
459            DO jj = 2, jpjm1
460               DO ji = fs_2, fs_jpim1   ! vector opt.
461                  psi(ji,jj,jk)  = eps(ji,jj,jk)
462               END DO
463            END DO
464         END DO
465         !
466      CASE( 2 )               ! k-w
467         DO jk = 2, jpkm1
468            DO jj = 2, jpjm1
469               DO ji = fs_2, fs_jpim1   ! vector opt.
470                  psi(ji,jj,jk)  = SQRT( eb(ji,jj,jk) ) / ( rc0 * mxlb(ji,jj,jk) )
471               END DO
472            END DO
473         END DO
474         !
475      CASE( 3 )               ! generic
476         DO jk = 2, jpkm1
477            DO jj = 2, jpjm1
478               DO ji = fs_2, fs_jpim1   ! vector opt.
479                  psi(ji,jj,jk)  = rc02 * eb(ji,jj,jk) * mxlb(ji,jj,jk)**rnn 
480               END DO
481            END DO
482         END DO
483         !
484      END SELECT
485      !
486      ! Now gls (output in psi)
487      ! -------------------------------
488      ! Resolution of a tridiagonal linear system by a "methode de chasse"
489      ! computation from level 2 to jpkm1  (e(1) already computed and e(jpk)=0 ).
490      ! z_elem_b : diagonal z_elem_c : upper diagonal z_elem_a : lower diagonal
491      ! Warning : after this step, en : right hand side of the matrix
492
493      DO jk = 2, jpkm1
494         DO jj = 2, jpjm1
495            DO ji = fs_2, fs_jpim1   ! vector opt.
496               !
497               ! psi / k
498               zratio = psi(ji,jj,jk) / eb(ji,jj,jk) 
499               !
500               ! psi3+ : stable : B=-KhN²<0 => N²>0 if rn2>0 dir = 1 (stable) otherwise dir = 0 (unstable)
501               dir = 0.5_wp + SIGN( 0.5_wp, rn2(ji,jj,jk) )
502               !
503               rpsi3 = dir * rpsi3m + ( 1._wp - dir ) * rpsi3p
504               !
505               ! shear prod. - stratif. destruction
506               prod = rpsi1 * zratio * shear(ji,jj,jk)
507               !
508               ! stratif. destruction
509               buoy = rpsi3 * zratio * (- avt(ji,jj,jk) * rn2(ji,jj,jk) )
510               !
511               ! shear prod. - stratif. destruction
512               diss = rpsi2 * zratio * zwall(ji,jj,jk) * eps(ji,jj,jk)
513               !
514               dir = 0.5_wp + SIGN( 0.5_wp, prod + buoy )   ! dir =1(=0) if shear(ji,jj,jk)+buoy >0(<0)
515               !
516               zesh2 = dir * ( prod + buoy )          + (1._wp - dir ) * prod                        ! production term
517               zdiss = dir * ( diss / psi(ji,jj,jk) ) + (1._wp - dir ) * (diss-buoy) / psi(ji,jj,jk) ! dissipation term
518               !                                                       
519               ! building the matrix
520               zcof = rfact_psi * zwall_psi(ji,jj,jk) * tmask(ji,jj,jk)
521               ! lower diagonal
522               z_elem_a(ji,jj,jk) = zcof * ( avm  (ji,jj,jk  ) + avm  (ji,jj,jk-1) )   &
523                  &                      / ( fse3t(ji,jj,jk-1) * fse3w(ji,jj,jk  ) )
524               ! upper diagonal
525               z_elem_c(ji,jj,jk) = zcof * ( avm  (ji,jj,jk+1) + avm  (ji,jj,jk  ) )   &
526                  &                      / ( fse3t(ji,jj,jk  ) * fse3w(ji,jj,jk) )
527               ! diagonal
528               z_elem_b(ji,jj,jk) = 1._wp - z_elem_a(ji,jj,jk) - z_elem_c(ji,jj,jk)  &
529                  &                       + rdt * zdiss * tmask(ji,jj,jk)
530               !
531               ! right hand side in psi
532               psi(ji,jj,jk) = psi(ji,jj,jk) + rdt * zesh2 * tmask(ji,jj,jk)
533            END DO
534         END DO
535      END DO
536      !
537      z_elem_b(:,:,jpk) = 1._wp
538
539      ! Surface boundary condition on psi
540      ! ---------------------------------
541      !
542      SELECT CASE ( nn_bc_surf )
543      !
544      CASE ( 0 )             ! Dirichlet boundary conditions
545      !
546      ! Surface value
547      zdep(:,:)       = zhsro(:,:) * rl_sf ! Cosmetic
548      psi (:,:,1)     = rc0**rpp * en(:,:,1)**rmm * zdep(:,:)**rnn * tmask(:,:,1)
549      z_elem_a(:,:,1) = psi(:,:,1)
550      z_elem_c(:,:,1) = 0._wp
551      z_elem_b(:,:,1) = 1._wp
552      !
553      ! One level below
554      zkar(:,:)       = (rl_sf + (vkarmn-rl_sf)*(1._wp-exp(-rtrans*fsdepw(:,:,2)/zhsro(:,:) )))
555      zdep(:,:)       = (zhsro(:,:) + fsdepw(:,:,2)) * zkar(:,:)
556      psi (:,:,2)     = rc0**rpp * en(:,:,2)**rmm * zdep(:,:)**rnn * tmask(:,:,1)
557      z_elem_a(:,:,2) = 0._wp
558      z_elem_c(:,:,2) = 0._wp
559      z_elem_b(:,:,2) = 1._wp
560      !
561      !
562      CASE ( 1 )             ! Neumann boundary condition on d(psi)/dz
563      !
564      ! Surface value: Dirichlet
565      zdep(:,:)       = zhsro(:,:) * rl_sf
566      psi (:,:,1)     = rc0**rpp * en(:,:,1)**rmm * zdep(:,:)**rnn * tmask(:,:,1)
567      z_elem_a(:,:,1) = psi(:,:,1)
568      z_elem_c(:,:,1) = 0._wp
569      z_elem_b(:,:,1) = 1._wp
570      !
571      ! Neumann condition at k=2
572      z_elem_b(:,:,2) = z_elem_b(:,:,2) +  z_elem_a(:,:,2) ! Remove z_elem_a from z_elem_b
573      z_elem_a(:,:,2) = 0._wp
574      !
575      ! Set psi vertical flux at the surface:
576      zkar(:,:) = rl_sf + (vkarmn-rl_sf)*(1._wp-exp(-rtrans*fsdept(:,:,1)/zhsro(:,:) )) ! Lengh scale slope
577      zdep(:,:) = ((zhsro(:,:) + fsdept(:,:,1)) / zhsro(:,:))**(rmm*ra_sf)
578      zflxs(:,:) = (rnn + rsbc_tke1 * (rnn + rmm*ra_sf) * zdep(:,:))*(1._wp + rsbc_tke1*zdep(:,:))**(2._wp*rmm/3._wp-1_wp)
579      zdep(:,:) =  rsbc_psi1 * (zwall_psi(:,:,1)*avm(:,:,1)+zwall_psi(:,:,2)*avm(:,:,2)) * &
580             & ustars2(:,:)**rmm * zkar(:,:)**rnn * (zhsro(:,:) + fsdept(:,:,1))**(rnn-1.)
581      zflxs(:,:) = zdep(:,:) * zflxs(:,:)
582      psi(:,:,2) = psi(:,:,2) + zflxs(:,:) / fse3w(:,:,2)
583
584      !   
585      !
586      END SELECT
587
588      ! Bottom boundary condition on psi
589      ! --------------------------------
590      !
591      SELECT CASE ( nn_bc_bot )
592      !
593      !
594      CASE ( 0 )             ! Dirichlet
595         !                      ! en(ibot) = u*^2 / Co2 and mxln(ibot) = vkarmn * rn_bfrz0
596         !                      ! Balance between the production and the dissipation terms
597!CDIR NOVERRCHK
598         DO jj = 2, jpjm1
599!CDIR NOVERRCHK
600            DO ji = fs_2, fs_jpim1   ! vector opt.
601               ibot   = mbkt(ji,jj) + 1      ! k   bottom level of w-point
602               ibotm1 = mbkt(ji,jj)          ! k-1 bottom level of w-point but >=1
603               zdep(ji,jj) = vkarmn * rn_bfrz0
604               psi (ji,jj,ibot) = rc0**rpp * en(ji,jj,ibot)**rmm * zdep(ji,jj)**rnn
605               z_elem_a(ji,jj,ibot) = 0._wp
606               z_elem_c(ji,jj,ibot) = 0._wp
607               z_elem_b(ji,jj,ibot) = 1._wp
608               !
609               ! Just above last level, Dirichlet condition again (GOTM like)
610               zdep(ji,jj) = vkarmn * ( rn_bfrz0 + fse3t(ji,jj,ibotm1) )
611               psi (ji,jj,ibotm1) = rc0**rpp * en(ji,jj,ibot  )**rmm * zdep(ji,jj)**rnn
612               z_elem_a(ji,jj,ibotm1) = 0._wp
613               z_elem_c(ji,jj,ibotm1) = 0._wp
614               z_elem_b(ji,jj,ibotm1) = 1._wp
615            END DO
616         END DO
617         !
618      CASE ( 1 )             ! Neumman boundary condition
619         !                     
620!CDIR NOVERRCHK
621         DO jj = 2, jpjm1
622!CDIR NOVERRCHK
623            DO ji = fs_2, fs_jpim1   ! vector opt.
624               ibot   = mbkt(ji,jj) + 1      ! k   bottom level of w-point
625               ibotm1 = mbkt(ji,jj)          ! k-1 bottom level of w-point but >=1
626               !
627               ! Bottom level Dirichlet condition:
628               zdep(ji,jj) = vkarmn * rn_bfrz0
629               psi (ji,jj,ibot) = rc0**rpp * en(ji,jj,ibot)**rmm * zdep(ji,jj)**rnn
630               !
631               z_elem_a(ji,jj,ibot) = 0._wp
632               z_elem_c(ji,jj,ibot) = 0._wp
633               z_elem_b(ji,jj,ibot) = 1._wp
634               !
635               ! Just above last level: Neumann condition with flux injection
636               z_elem_b(ji,jj,ibotm1) = z_elem_b(ji,jj,ibotm1) + z_elem_c(ji,jj,ibotm1) ! Remove z_elem_c from z_elem_b
637               z_elem_c(ji,jj,ibotm1) = 0.
638               !
639               ! Set psi vertical flux at the bottom:
640               zdep(ji,jj) = rn_bfrz0 + 0.5_wp*fse3t(ji,jj,ibotm1)
641               zflxb = rsbc_psi2 * ( avm(ji,jj,ibot) + avm(ji,jj,ibotm1) )   &
642                  &  * (0.5_wp*(en(ji,jj,ibot)+en(ji,jj,ibotm1)))**rmm * zdep(ji,jj)**(rnn-1._wp)
643               psi(ji,jj,ibotm1) = psi(ji,jj,ibotm1) + zflxb / fse3w(ji,jj,ibotm1)
644            END DO
645         END DO
646         !
647      END SELECT
648
649      ! Matrix inversion
650      ! ----------------
651      !
652      DO jk = 2, jpkm1                             ! First recurrence : Dk = Dk - Lk * Uk-1 / Dk-1
653         DO jj = 2, jpjm1
654            DO ji = fs_2, fs_jpim1    ! vector opt.
655               z_elem_b(ji,jj,jk) = z_elem_b(ji,jj,jk) - z_elem_a(ji,jj,jk) * z_elem_c(ji,jj,jk-1) / z_elem_b(ji,jj,jk-1)
656            END DO
657         END DO
658      END DO
659      DO jk = 2, jpk                               ! Second recurrence : Lk = RHSk - Lk / Dk-1 * Lk-1
660         DO jj = 2, jpjm1
661            DO ji = fs_2, fs_jpim1    ! vector opt.
662               z_elem_a(ji,jj,jk) = psi(ji,jj,jk) - z_elem_a(ji,jj,jk) / z_elem_b(ji,jj,jk-1) * z_elem_a(ji,jj,jk-1)
663            END DO
664         END DO
665      END DO
666      DO jk = jpk-1, 2, -1                         ! Third recurrence : Ek = ( Lk - Uk * Ek+1 ) / Dk
667         DO jj = 2, jpjm1
668            DO ji = fs_2, fs_jpim1    ! vector opt.
669               psi(ji,jj,jk) = ( z_elem_a(ji,jj,jk) - z_elem_c(ji,jj,jk) * psi(ji,jj,jk+1) ) / z_elem_b(ji,jj,jk)
670            END DO
671         END DO
672      END DO
673
674      ! Set dissipation
675      !----------------
676
677      SELECT CASE ( nn_clos )
678      !
679      CASE( 0 )               ! k-kl  (Mellor-Yamada)
680         DO jk = 1, jpkm1
681            DO jj = 2, jpjm1
682               DO ji = fs_2, fs_jpim1   ! vector opt.
683                  eps(ji,jj,jk) = rc03 * en(ji,jj,jk) * en(ji,jj,jk) * SQRT( en(ji,jj,jk) ) / MAX( psi(ji,jj,jk), rn_epsmin)
684               END DO
685            END DO
686         END DO
687         !
688      CASE( 1 )               ! k-eps
689         DO jk = 1, jpkm1
690            DO jj = 2, jpjm1
691               DO ji = fs_2, fs_jpim1   ! vector opt.
692                  eps(ji,jj,jk) = psi(ji,jj,jk)
693               END DO
694            END DO
695         END DO
696         !
697      CASE( 2 )               ! k-w
698         DO jk = 1, jpkm1
699            DO jj = 2, jpjm1
700               DO ji = fs_2, fs_jpim1   ! vector opt.
701                  eps(ji,jj,jk) = rc04 * en(ji,jj,jk) * psi(ji,jj,jk) 
702               END DO
703            END DO
704         END DO
705         !
706      CASE( 3 )               ! generic
707         zcoef = rc0**( 3._wp  + rpp/rnn )
708         zex1  =      ( 1.5_wp + rmm/rnn )
709         zex2  = -1._wp / rnn
710         DO jk = 1, jpkm1
711            DO jj = 2, jpjm1
712               DO ji = fs_2, fs_jpim1   ! vector opt.
713                  eps(ji,jj,jk) = zcoef * en(ji,jj,jk)**zex1 * psi(ji,jj,jk)**zex2
714               END DO
715            END DO
716         END DO
717         !
718      END SELECT
719
720      ! Limit dissipation rate under stable stratification
721      ! --------------------------------------------------
722      DO jk = 1, jpkm1 ! Note that this set boundary conditions on mxln at the same time
723         DO jj = 2, jpjm1
724            DO ji = fs_2, fs_jpim1    ! vector opt.
725               ! limitation
726               eps(ji,jj,jk)  = MAX( eps(ji,jj,jk), rn_epsmin )
727               mxln(ji,jj,jk)  = rc03 * en(ji,jj,jk) * SQRT( en(ji,jj,jk) ) / eps(ji,jj,jk)
728               ! Galperin criterium (NOTE : Not required if the proper value of C3 in stable cases is calculated)
729               zrn2 = MAX( rn2(ji,jj,jk), rsmall )
730               IF (ln_length_lim) mxln(ji,jj,jk) = MIN(  rn_clim_galp * SQRT( 2._wp * en(ji,jj,jk) / zrn2 ), mxln(ji,jj,jk) )
731            END DO
732         END DO
733      END DO 
734
735      !
736      ! Stability function and vertical viscosity and diffusivity
737      ! ---------------------------------------------------------
738      !
739      SELECT CASE ( nn_stab_func )
740      !
741      CASE ( 0 , 1 )             ! Galperin or Kantha-Clayson stability functions
742         DO jk = 2, jpkm1
743            DO jj = 2, jpjm1
744               DO ji = fs_2, fs_jpim1   ! vector opt.
745                  ! zcof =  l²/q²
746                  zcof = mxlb(ji,jj,jk) * mxlb(ji,jj,jk) / ( 2._wp*eb(ji,jj,jk) )
747                  ! Gh = -N²l²/q²
748                  gh = - rn2(ji,jj,jk) * zcof
749                  gh = MIN( gh, rgh0   )
750                  gh = MAX( gh, rghmin )
751                  ! Stability functions from Kantha and Clayson (if C2=C3=0 => Galperin)
752                  sh = ra2*( 1._wp-6._wp*ra1/rb1 ) / ( 1.-3.*ra2*gh*(6.*ra1+rb2*( 1._wp-rc3 ) ) )
753                  sm = ( rb1**(-1._wp/3._wp) + ( 18._wp*ra1*ra1 + 9._wp*ra1*ra2*(1._wp-rc2) )*sh*gh ) / (1._wp-9._wp*ra1*ra2*gh)
754                  !
755                  ! Store stability function in avmu and avmv
756                  avmu(ji,jj,jk) = rc_diff * sh * tmask(ji,jj,jk)
757                  avmv(ji,jj,jk) = rc_diff * sm * tmask(ji,jj,jk)
758               END DO
759            END DO
760         END DO
761         !
762      CASE ( 2, 3 )               ! Canuto stability functions
763         DO jk = 2, jpkm1
764            DO jj = 2, jpjm1
765               DO ji = fs_2, fs_jpim1   ! vector opt.
766                  ! zcof =  l²/q²
767                  zcof = mxlb(ji,jj,jk)*mxlb(ji,jj,jk) / ( 2._wp * eb(ji,jj,jk) )
768                  ! Gh = -N²l²/q²
769                  gh = - rn2(ji,jj,jk) * zcof
770                  gh = MIN( gh, rgh0   )
771                  gh = MAX( gh, rghmin )
772                  gh = gh * rf6
773                  ! Gm =  M²l²/q² Shear number
774                  shr = shear(ji,jj,jk) / MAX( avm(ji,jj,jk), rsmall )
775                  gm = MAX( shr * zcof , 1.e-10 )
776                  gm = gm * rf6
777                  gm = MIN ( (rd0 - rd1*gh + rd3*gh*gh) / (rd2-rd4*gh) , gm )
778                  ! Stability functions from Canuto
779                  rcff = rd0 - rd1*gh +rd2*gm + rd3*gh*gh - rd4*gh*gm + rd5*gm*gm
780                  sm = (rs0 - rs1*gh + rs2*gm) / rcff
781                  sh = (rs4 - rs5*gh + rs6*gm) / rcff
782                  !
783                  ! Store stability function in avmu and avmv
784                  avmu(ji,jj,jk) = rc_diff * sh * tmask(ji,jj,jk)
785                  avmv(ji,jj,jk) = rc_diff * sm * tmask(ji,jj,jk)
786               END DO
787            END DO
788         END DO
789         !
790      END SELECT
791
792      ! Boundary conditions on stability functions for momentum (Neumann):
793      ! Lines below are useless if GOTM style Dirichlet conditions are used
794
795      avmv(:,:,1) = avmv(:,:,2)
796
797      DO jj = 2, jpjm1
798         DO ji = fs_2, fs_jpim1   ! vector opt.
799            avmv(ji,jj,mbkt(ji,jj)+1) = avmv(ji,jj,mbkt(ji,jj))
800         END DO
801      END DO
802
803      ! Compute diffusivities/viscosities
804      ! The computation below could be restrained to jk=2 to jpkm1 if GOTM style Dirichlet conditions are used
805      DO jk = 1, jpk
806         DO jj = 2, jpjm1
807            DO ji = fs_2, fs_jpim1   ! vector opt.
808               zsqen         = SQRT( 2._wp * en(ji,jj,jk) ) * mxln(ji,jj,jk)
809               zav           = zsqen * avmu(ji,jj,jk)
810               avt(ji,jj,jk) = MAX( zav, avtb(jk) )*tmask(ji,jj,jk) ! apply mask for zdfmxl routine
811               zav           = zsqen * avmv(ji,jj,jk)
812               avm(ji,jj,jk) = MAX( zav, avmb(jk) ) ! Note that avm is not masked at the surface and the bottom
813            END DO
814         END DO
815      END DO
816      !
817      ! Lateral boundary conditions (sign unchanged)
818      avt(:,:,1)  = 0._wp
819      CALL lbc_lnk( avm, 'W', 1. )   ;   CALL lbc_lnk( avt, 'W', 1. )
820
821      DO jk = 2, jpkm1            !* vertical eddy viscosity at u- and v-points
822         DO jj = 2, jpjm1
823            DO ji = fs_2, fs_jpim1   ! vector opt.
824               avmu(ji,jj,jk) = 0.5 * ( avm(ji,jj,jk) + avm(ji+1,jj  ,jk) ) * umask(ji,jj,jk)
825               avmv(ji,jj,jk) = 0.5 * ( avm(ji,jj,jk) + avm(ji  ,jj+1,jk) ) * vmask(ji,jj,jk)
826            END DO
827         END DO
828      END DO
829      avmu(:,:,1) = 0._wp             ;   avmv(:,:,1) = 0._wp                 ! set surface to zero
830      CALL lbc_lnk( avmu, 'U', 1. )   ;   CALL lbc_lnk( avmv, 'V', 1. )       ! Lateral boundary conditions
831
832      IF(ln_ctl) THEN
833         CALL prt_ctl( tab3d_1=en  , clinfo1=' gls  - e: ', tab3d_2=avt, clinfo2=' t: ', ovlap=1, kdim=jpk)
834         CALL prt_ctl( tab3d_1=avmu, clinfo1=' gls  - u: ', mask1=umask,                   &
835            &          tab3d_2=avmv, clinfo2=       ' v: ', mask2=vmask, ovlap=1, kdim=jpk )
836      ENDIF
837      !
838      avt_k (:,:,:) = avt (:,:,:)
839      avm_k (:,:,:) = avm (:,:,:)
840      avmu_k(:,:,:) = avmu(:,:,:)
841      avmv_k(:,:,:) = avmv(:,:,:)
842      !
843      CALL wrk_dealloc( jpi,jpj, zdep, zkar, zflxs, zhsro )
844      CALL wrk_dealloc( jpi,jpj,jpk, eb, mxlb, shear, eps, zwall_psi, z_elem_a, z_elem_b, z_elem_c, psi )
845      !
846      IF( nn_timing == 1 )  CALL timing_stop('zdf_gls')
847      !
848      !
849   END SUBROUTINE zdf_gls
850
851
852   SUBROUTINE zdf_gls_init
853      !!----------------------------------------------------------------------
854      !!                  ***  ROUTINE zdf_gls_init  ***
855      !!                     
856      !! ** Purpose :   Initialization of the vertical eddy diffivity and
857      !!      viscosity when using a gls turbulent closure scheme
858      !!
859      !! ** Method  :   Read the namzdf_gls namelist and check the parameters
860      !!      called at the first timestep (nit000)
861      !!
862      !! ** input   :   Namlist namzdf_gls
863      !!
864      !! ** Action  :   Increase by 1 the nstop flag is setting problem encounter
865      !!
866      !!----------------------------------------------------------------------
867      USE dynzdf_exp
868      USE trazdf_exp
869      !
870      INTEGER ::   jk    ! dummy loop indices
871      INTEGER ::   ios   ! Local integer output status for namelist read
872      REAL(wp)::   zcr   ! local scalar
873      !!
874      NAMELIST/namzdf_gls/rn_emin, rn_epsmin, ln_length_lim, &
875         &            rn_clim_galp, ln_sigpsi, rn_hsro,      &
876         &            rn_crban, rn_charn, rn_frac_hs,        &
877         &            nn_bc_surf, nn_bc_bot, nn_z0_met,      &
878         &            nn_stab_func, nn_clos
879      !!----------------------------------------------------------
880      !
881      IF( nn_timing == 1 )  CALL timing_start('zdf_gls_init')
882      !
883      REWIND( numnam_ref )              ! Namelist namzdf_gls in reference namelist : Vertical eddy diffivity and viscosity using gls turbulent closure scheme
884      READ  ( numnam_ref, namzdf_gls, IOSTAT = ios, ERR = 901)
885901   IF( ios /= 0 ) CALL ctl_nam ( ios , 'namzdf_gls in reference namelist', lwp )
886
887      REWIND( numnam_cfg )              ! Namelist namzdf_gls in configuration namelist : Vertical eddy diffivity and viscosity using gls turbulent closure scheme
888      READ  ( numnam_cfg, namzdf_gls, IOSTAT = ios, ERR = 902 )
889902   IF( ios /= 0 ) CALL ctl_nam ( ios , 'namzdf_gls in configuration namelist', lwp )
890      IF(lwm) WRITE ( numond, namzdf_gls )
891
892      IF(lwp) THEN                     !* Control print
893         WRITE(numout,*)
894         WRITE(numout,*) 'zdf_gls_init : gls turbulent closure scheme'
895         WRITE(numout,*) '~~~~~~~~~~~~'
896         WRITE(numout,*) '   Namelist namzdf_gls : set gls mixing parameters'
897         WRITE(numout,*) '      minimum value of en                           rn_emin        = ', rn_emin
898         WRITE(numout,*) '      minimum value of eps                          rn_epsmin      = ', rn_epsmin
899         WRITE(numout,*) '      Limit dissipation rate under stable stratif.  ln_length_lim  = ', ln_length_lim
900         WRITE(numout,*) '      Galperin limit (Standard: 0.53, Holt: 0.26)   rn_clim_galp   = ', rn_clim_galp
901         WRITE(numout,*) '      TKE Surface boundary condition                nn_bc_surf     = ', nn_bc_surf
902         WRITE(numout,*) '      TKE Bottom boundary condition                 nn_bc_bot      = ', nn_bc_bot
903         WRITE(numout,*) '      Modify psi Schmidt number (wb case)           ln_sigpsi      = ', ln_sigpsi
904         WRITE(numout,*) '      Craig and Banner coefficient                  rn_crban       = ', rn_crban
905         WRITE(numout,*) '      Charnock coefficient                          rn_charn       = ', rn_charn
906         WRITE(numout,*) '      Surface roughness formula                     nn_z0_met      = ', nn_z0_met
907         WRITE(numout,*) '      Wave height frac. (used if nn_z0_met=2)       rn_frac_hs     = ', rn_frac_hs
908         WRITE(numout,*) '      Stability functions                           nn_stab_func   = ', nn_stab_func
909         WRITE(numout,*) '      Type of closure                               nn_clos        = ', nn_clos
910         WRITE(numout,*) '      Surface roughness (m)                         rn_hsro        = ', rn_hsro
911         WRITE(numout,*) '      Bottom roughness (m) (nambfr namelist)        rn_bfrz0       = ', rn_bfrz0
912      ENDIF
913
914      !                                !* allocate gls arrays
915      IF( zdf_gls_alloc() /= 0 )   CALL ctl_stop( 'STOP', 'zdf_gls_init : unable to allocate arrays' )
916
917      !                                !* Check of some namelist values
918      IF( nn_bc_surf < 0 .OR. nn_bc_surf > 1 ) CALL ctl_stop( 'bad flag: nn_bc_surf is 0 or 1' )
919      IF( nn_bc_surf < 0 .OR. nn_bc_surf > 1 ) CALL ctl_stop( 'bad flag: nn_bc_surf is 0 or 1' )
920      IF( nn_z0_met < 0 .OR. nn_z0_met > 2 ) CALL ctl_stop( 'bad flag: nn_z0_met is 0, 1 or 2' )
921      IF( nn_stab_func  < 0 .OR. nn_stab_func  > 3 ) CALL ctl_stop( 'bad flag: nn_stab_func is 0, 1, 2 and 3' )
922      IF( nn_clos       < 0 .OR. nn_clos       > 3 ) CALL ctl_stop( 'bad flag: nn_clos is 0, 1, 2 or 3' )
923
924      SELECT CASE ( nn_clos )          !* set the parameters for the chosen closure
925      !
926      CASE( 0 )                              ! k-kl  (Mellor-Yamada)
927         !
928         IF(lwp) WRITE(numout,*) 'The choosen closure is k-kl closed to the classical Mellor-Yamada'
929         rpp     = 0._wp
930         rmm     = 1._wp
931         rnn     = 1._wp
932         rsc_tke = 1.96_wp
933         rsc_psi = 1.96_wp
934         rpsi1   = 0.9_wp
935         rpsi3p  = 1._wp
936         rpsi2   = 0.5_wp
937         !
938         SELECT CASE ( nn_stab_func )
939         CASE( 0, 1 )   ;   rpsi3m = 2.53_wp       ! G88 or KC stability functions
940         CASE( 2 )      ;   rpsi3m = 2.62_wp       ! Canuto A stability functions
941         CASE( 3 )      ;   rpsi3m = 2.38          ! Canuto B stability functions (caution : constant not identified)
942         END SELECT
943         !
944      CASE( 1 )                              ! k-eps
945         !
946         IF(lwp) WRITE(numout,*) 'The choosen closure is k-eps'
947         rpp     =  3._wp
948         rmm     =  1.5_wp
949         rnn     = -1._wp
950         rsc_tke =  1._wp
951         rsc_psi =  1.2_wp  ! Schmidt number for psi
952         rpsi1   =  1.44_wp
953         rpsi3p  =  1._wp
954         rpsi2   =  1.92_wp
955         !
956         SELECT CASE ( nn_stab_func )
957         CASE( 0, 1 )   ;   rpsi3m = -0.52_wp      ! G88 or KC stability functions
958         CASE( 2 )      ;   rpsi3m = -0.629_wp     ! Canuto A stability functions
959         CASE( 3 )      ;   rpsi3m = -0.566        ! Canuto B stability functions
960         END SELECT
961         !
962      CASE( 2 )                              ! k-omega
963         !
964         IF(lwp) WRITE(numout,*) 'The choosen closure is k-omega'
965         rpp     = -1._wp
966         rmm     =  0.5_wp
967         rnn     = -1._wp
968         rsc_tke =  2._wp
969         rsc_psi =  2._wp
970         rpsi1   =  0.555_wp
971         rpsi3p  =  1._wp
972         rpsi2   =  0.833_wp
973         !
974         SELECT CASE ( nn_stab_func )
975         CASE( 0, 1 )   ;   rpsi3m = -0.58_wp       ! G88 or KC stability functions
976         CASE( 2 )      ;   rpsi3m = -0.64_wp       ! Canuto A stability functions
977         CASE( 3 )      ;   rpsi3m = -0.64_wp       ! Canuto B stability functions caution : constant not identified)
978         END SELECT
979         !
980      CASE( 3 )                              ! generic
981         !
982         IF(lwp) WRITE(numout,*) 'The choosen closure is generic'
983         rpp     = 2._wp
984         rmm     = 1._wp
985         rnn     = -0.67_wp
986         rsc_tke = 0.8_wp
987         rsc_psi = 1.07_wp
988         rpsi1   = 1._wp
989         rpsi3p  = 1._wp
990         rpsi2   = 1.22_wp
991         !
992         SELECT CASE ( nn_stab_func )
993         CASE( 0, 1 )   ;   rpsi3m = 0.1_wp         ! G88 or KC stability functions
994         CASE( 2 )      ;   rpsi3m = 0.05_wp        ! Canuto A stability functions
995         CASE( 3 )      ;   rpsi3m = 0.05_wp        ! Canuto B stability functions caution : constant not identified)
996         END SELECT
997         !
998      END SELECT
999
1000      !
1001      SELECT CASE ( nn_stab_func )     !* set the parameters of the stability functions
1002      !
1003      CASE ( 0 )                             ! Galperin stability functions
1004         !
1005         IF(lwp) WRITE(numout,*) 'Stability functions from Galperin'
1006         rc2     =  0._wp
1007         rc3     =  0._wp
1008         rc_diff =  1._wp
1009         rc0     =  0.5544_wp
1010         rcm_sf  =  0.9884_wp
1011         rghmin  = -0.28_wp
1012         rgh0    =  0.0233_wp
1013         rghcri  =  0.02_wp
1014         !
1015      CASE ( 1 )                             ! Kantha-Clayson stability functions
1016         !
1017         IF(lwp) WRITE(numout,*) 'Stability functions from Kantha-Clayson'
1018         rc2     =  0.7_wp
1019         rc3     =  0.2_wp
1020         rc_diff =  1._wp
1021         rc0     =  0.5544_wp
1022         rcm_sf  =  0.9884_wp
1023         rghmin  = -0.28_wp
1024         rgh0    =  0.0233_wp
1025         rghcri  =  0.02_wp
1026         !
1027      CASE ( 2 )                             ! Canuto A stability functions
1028         !
1029         IF(lwp) WRITE(numout,*) 'Stability functions from Canuto A'
1030         rs0 = 1.5_wp * rl1 * rl5*rl5
1031         rs1 = -rl4*(rl6+rl7) + 2._wp*rl4*rl5*(rl1-(1._wp/3._wp)*rl2-rl3) + 1.5_wp*rl1*rl5*rl8
1032         rs2 = -(3._wp/8._wp) * rl1*(rl6*rl6-rl7*rl7)
1033         rs4 = 2._wp * rl5
1034         rs5 = 2._wp * rl4
1035         rs6 = (2._wp/3._wp) * rl5 * ( 3._wp*rl3*rl3 - rl2*rl2 ) - 0.5_wp * rl5*rl1 * (3._wp*rl3-rl2)   &
1036            &                                                    + 0.75_wp * rl1 * ( rl6 - rl7 )
1037         rd0 = 3._wp * rl5*rl5
1038         rd1 = rl5 * ( 7._wp*rl4 + 3._wp*rl8 )
1039         rd2 = rl5*rl5 * ( 3._wp*rl3*rl3 - rl2*rl2 ) - 0.75_wp*(rl6*rl6 - rl7*rl7 )
1040         rd3 = rl4 * ( 4._wp*rl4 + 3._wp*rl8)
1041         rd4 = rl4 * ( rl2 * rl6 - 3._wp*rl3*rl7 - rl5*(rl2*rl2 - rl3*rl3 ) ) + rl5*rl8 * ( 3._wp*rl3*rl3 - rl2*rl2 )
1042         rd5 = 0.25_wp * ( rl2*rl2 - 3._wp *rl3*rl3 ) * ( rl6*rl6 - rl7*rl7 )
1043         rc0 = 0.5268_wp
1044         rf6 = 8._wp / (rc0**6._wp)
1045         rc_diff = SQRT(2._wp) / (rc0**3._wp)
1046         rcm_sf  =  0.7310_wp
1047         rghmin  = -0.28_wp
1048         rgh0    =  0.0329_wp
1049         rghcri  =  0.03_wp
1050         !
1051      CASE ( 3 )                             ! Canuto B stability functions
1052         !
1053         IF(lwp) WRITE(numout,*) 'Stability functions from Canuto B'
1054         rs0 = 1.5_wp * rm1 * rm5*rm5
1055         rs1 = -rm4 * (rm6+rm7) + 2._wp * rm4*rm5*(rm1-(1._wp/3._wp)*rm2-rm3) + 1.5_wp * rm1*rm5*rm8
1056         rs2 = -(3._wp/8._wp) * rm1 * (rm6*rm6-rm7*rm7 )
1057         rs4 = 2._wp * rm5
1058         rs5 = 2._wp * rm4
1059         rs6 = (2._wp/3._wp) * rm5 * (3._wp*rm3*rm3-rm2*rm2) - 0.5_wp * rm5*rm1*(3._wp*rm3-rm2) + 0.75_wp * rm1*(rm6-rm7)
1060         rd0 = 3._wp * rm5*rm5
1061         rd1 = rm5 * (7._wp*rm4 + 3._wp*rm8)
1062         rd2 = rm5*rm5 * (3._wp*rm3*rm3 - rm2*rm2) - 0.75_wp * (rm6*rm6 - rm7*rm7)
1063         rd3 = rm4 * ( 4._wp*rm4 + 3._wp*rm8 )
1064         rd4 = rm4 * ( rm2*rm6 -3._wp*rm3*rm7 - rm5*(rm2*rm2 - rm3*rm3) ) + rm5 * rm8 * ( 3._wp*rm3*rm3 - rm2*rm2 )
1065         rd5 = 0.25_wp * ( rm2*rm2 - 3._wp*rm3*rm3 ) * ( rm6*rm6 - rm7*rm7 )
1066         rc0 = 0.5268_wp            !!       rc0 = 0.5540_wp (Warner ...) to verify !
1067         rf6 = 8._wp / ( rc0**6._wp )
1068         rc_diff = SQRT(2._wp)/(rc0**3.)
1069         rcm_sf  =  0.7470_wp
1070         rghmin  = -0.28_wp
1071         rgh0    =  0.0444_wp
1072         rghcri  =  0.0414_wp
1073         !
1074      END SELECT
1075   
1076      !                                !* Set Schmidt number for psi diffusion in the wave breaking case
1077      !                                     ! See Eq. (13) of Carniel et al, OM, 30, 225-239, 2009
1078      !                                     !  or Eq. (17) of Burchard, JPO, 31, 3133-3145, 2001
1079      IF( ln_sigpsi ) THEN
1080         ra_sf = -1.5 ! Set kinetic energy slope, then deduce rsc_psi and rl_sf
1081         ! Verification: retrieve Burchard (2001) results by uncomenting the line below:
1082         ! Note that the results depend on the value of rn_cm_sf which is constant (=rc0) in his work
1083         ! ra_sf = -SQRT(2./3.*rc0**3./rn_cm_sf*rn_sc_tke)/vkarmn
1084         rsc_psi0 = rsc_tke/(24.*rpsi2)*(-1.+(4.*rnn + ra_sf*(1.+4.*rmm))**2./(ra_sf**2.))
1085      ELSE
1086         rsc_psi0 = rsc_psi
1087      ENDIF
1088 
1089      !                                !* Shear free turbulence parameters
1090      !
1091      ra_sf  = -4._wp*rnn*SQRT(rsc_tke) / ( (1._wp+4._wp*rmm)*SQRT(rsc_tke) &
1092               &                              - SQRT(rsc_tke + 24._wp*rsc_psi0*rpsi2 ) )
1093
1094      IF ( rn_crban==0._wp ) THEN
1095         rl_sf = vkarmn
1096      ELSE
1097         rl_sf = rc0 * SQRT(rc0/rcm_sf) * SQRT( ( (1._wp + 4._wp*rmm + 8._wp*rmm**2_wp)*rsc_tke          &
1098                 &                                       + 12._wp * rsc_psi0*rpsi2 - (1._wp + 4._wp*rmm) &
1099                 &                                                *SQRT(rsc_tke*(rsc_tke                 &
1100                 &                                                   + 24._wp*rsc_psi0*rpsi2)) )         &
1101                 &                                         /(12._wp*rnn**2.)                             &
1102                 &                                       )
1103      ENDIF
1104
1105      !
1106      IF(lwp) THEN                     !* Control print
1107         WRITE(numout,*)
1108         WRITE(numout,*) 'Limit values'
1109         WRITE(numout,*) '~~~~~~~~~~~~'
1110         WRITE(numout,*) 'Parameter  m = ',rmm
1111         WRITE(numout,*) 'Parameter  n = ',rnn
1112         WRITE(numout,*) 'Parameter  p = ',rpp
1113         WRITE(numout,*) 'rpsi1   = ',rpsi1
1114         WRITE(numout,*) 'rpsi2   = ',rpsi2
1115         WRITE(numout,*) 'rpsi3m  = ',rpsi3m
1116         WRITE(numout,*) 'rpsi3p  = ',rpsi3p
1117         WRITE(numout,*) 'rsc_tke = ',rsc_tke
1118         WRITE(numout,*) 'rsc_psi = ',rsc_psi
1119         WRITE(numout,*) 'rsc_psi0 = ',rsc_psi0
1120         WRITE(numout,*) 'rc0     = ',rc0
1121         WRITE(numout,*)
1122         WRITE(numout,*) 'Shear free turbulence parameters:'
1123         WRITE(numout,*) 'rcm_sf  = ',rcm_sf
1124         WRITE(numout,*) 'ra_sf   = ',ra_sf
1125         WRITE(numout,*) 'rl_sf   = ',rl_sf
1126         WRITE(numout,*)
1127      ENDIF
1128
1129      !                                !* Constants initialization
1130      rc02  = rc0  * rc0   ;   rc02r = 1. / rc02
1131      rc03  = rc02 * rc0
1132      rc04  = rc03 * rc0
1133      rsbc_tke1 = -3._wp/2._wp*rn_crban*ra_sf*rl_sf                      ! Dirichlet + Wave breaking
1134      rsbc_tke2 = rdt * rn_crban / rl_sf                                 ! Neumann + Wave breaking
1135      zcr = MAX(rsmall, rsbc_tke1**(1./(-ra_sf*3._wp/2._wp))-1._wp )
1136      rtrans = 0.2_wp / zcr                                              ! Ad. inverse transition length between log and wave layer
1137      rsbc_zs1  = rn_charn/grav                                          ! Charnock formula for surface roughness
1138      rsbc_zs2  = rn_frac_hs / 0.85_wp / grav * 665._wp                  ! Rascle formula for surface roughness
1139      rsbc_psi1 = -0.5_wp * rdt * rc0**(rpp-2._wp*rmm) / rsc_psi
1140      rsbc_psi2 = -0.5_wp * rdt * rc0**rpp * rnn * vkarmn**rnn / rsc_psi ! Neumann + NO Wave breaking
1141
1142      rfact_tke = -0.5_wp / rsc_tke * rdt                                ! Cst used for the Diffusion term of tke
1143      rfact_psi = -0.5_wp / rsc_psi * rdt                                ! Cst used for the Diffusion term of tke
1144
1145      !                                !* Wall proximity function
1146      zwall (:,:,:) = 1._wp * tmask(:,:,:)
1147
1148      !                                !* set vertical eddy coef. to the background value
1149      DO jk = 1, jpk
1150         avt (:,:,jk) = avtb(jk) * tmask(:,:,jk)
1151         avm (:,:,jk) = avmb(jk) * tmask(:,:,jk)
1152         avmu(:,:,jk) = avmb(jk) * umask(:,:,jk)
1153         avmv(:,:,jk) = avmb(jk) * vmask(:,:,jk)
1154      END DO
1155      !                             
1156      CALL gls_rst( nit000, 'READ' )   !* read or initialize all required files
1157      !
1158      IF( nn_timing == 1 )  CALL timing_stop('zdf_gls_init')
1159      !
1160   END SUBROUTINE zdf_gls_init
1161
1162
1163   SUBROUTINE gls_rst( kt, cdrw )
1164      !!---------------------------------------------------------------------
1165      !!                   ***  ROUTINE ts_rst  ***
1166      !!                     
1167      !! ** Purpose :   Read or write TKE file (en) in restart file
1168      !!
1169      !! ** Method  :   use of IOM library
1170      !!                if the restart does not contain TKE, en is either
1171      !!                set to rn_emin or recomputed (nn_igls/=0)
1172      !!----------------------------------------------------------------------
1173      INTEGER         , INTENT(in) ::   kt         ! ocean time-step
1174      CHARACTER(len=*), INTENT(in) ::   cdrw       ! "READ"/"WRITE" flag
1175      !
1176      INTEGER ::   jit, jk   ! dummy loop indices
1177      INTEGER ::   id1, id2, id3, id4, id5, id6
1178      INTEGER ::   ji, jj, ikbu, ikbv
1179      REAL(wp)::   cbx, cby
1180      !!----------------------------------------------------------------------
1181      !
1182      IF( TRIM(cdrw) == 'READ' ) THEN        ! Read/initialise
1183         !                                   ! ---------------
1184         IF( ln_rstart ) THEN                   !* Read the restart file
1185            id1 = iom_varid( numror, 'en'   , ldstop = .FALSE. )
1186            id2 = iom_varid( numror, 'avt'  , ldstop = .FALSE. )
1187            id3 = iom_varid( numror, 'avm'  , ldstop = .FALSE. )
1188            id4 = iom_varid( numror, 'avmu' , ldstop = .FALSE. )
1189            id5 = iom_varid( numror, 'avmv' , ldstop = .FALSE. )
1190            id6 = iom_varid( numror, 'mxln' , ldstop = .FALSE. )
1191            !
1192            IF( MIN( id1, id2, id3, id4, id5, id6 ) > 0 ) THEN        ! all required arrays exist
1193               CALL iom_get( numror, jpdom_autoglo, 'en'    , en     )
1194               CALL iom_get( numror, jpdom_autoglo, 'avt'   , avt    )
1195               CALL iom_get( numror, jpdom_autoglo, 'avm'   , avm    )
1196               CALL iom_get( numror, jpdom_autoglo, 'avmu'  , avmu   )
1197               CALL iom_get( numror, jpdom_autoglo, 'avmv'  , avmv   )
1198               CALL iom_get( numror, jpdom_autoglo, 'mxln'  , mxln   )
1199            ELSE                       
1200               IF(lwp) WRITE(numout,*) ' ===>>>> : previous run without gls scheme, en and mxln computed by iterative loop'
1201               en  (:,:,:) = rn_emin
1202               mxln(:,:,:) = 0.05       
1203               avt_k (:,:,:) = avt (:,:,:)
1204               avm_k (:,:,:) = avm (:,:,:)
1205               avmu_k(:,:,:) = avmu(:,:,:)
1206               avmv_k(:,:,:) = avmv(:,:,:)
1207               DO jit = nit000 + 1, nit000 + 10   ;   CALL zdf_gls( jit )   ;   END DO
1208            ENDIF
1209         ELSE                                   !* Start from rest
1210            IF(lwp) WRITE(numout,*) ' ===>>>> : Initialisation of en and mxln by background values'
1211            en  (:,:,:) = rn_emin
1212            mxln(:,:,:) = 0.05       
1213         ENDIF
1214         !
1215      ELSEIF( TRIM(cdrw) == 'WRITE' ) THEN   ! Create restart file
1216         !                                   ! -------------------
1217         IF(lwp) WRITE(numout,*) '---- gls-rst ----'
1218         CALL iom_rstput( kt, nitrst, numrow, 'en'   , en     ) 
1219         CALL iom_rstput( kt, nitrst, numrow, 'avt'  , avt_k  )
1220         CALL iom_rstput( kt, nitrst, numrow, 'avm'  , avm_k  )
1221         CALL iom_rstput( kt, nitrst, numrow, 'avmu' , avmu_k ) 
1222         CALL iom_rstput( kt, nitrst, numrow, 'avmv' , avmv_k )
1223         CALL iom_rstput( kt, nitrst, numrow, 'mxln' , mxln   )
1224         !
1225      ENDIF
1226      !
1227   END SUBROUTINE gls_rst
1228
1229#else
1230   !!----------------------------------------------------------------------
1231   !!   Dummy module :                                        NO TKE scheme
1232   !!----------------------------------------------------------------------
1233   LOGICAL, PUBLIC, PARAMETER ::   lk_zdfgls = .FALSE.   !: TKE flag
1234CONTAINS
1235   SUBROUTINE zdf_gls_init           ! Empty routine
1236      WRITE(*,*) 'zdf_gls_init: You should not have seen this print! error?'
1237   END SUBROUTINE zdf_gls_init
1238   SUBROUTINE zdf_gls( kt )          ! Empty routine
1239      WRITE(*,*) 'zdf_gls: You should not have seen this print! error?', kt
1240   END SUBROUTINE zdf_gls
1241   SUBROUTINE gls_rst( kt, cdrw )          ! Empty routine
1242      INTEGER         , INTENT(in) ::   kt         ! ocean time-step
1243      CHARACTER(len=*), INTENT(in) ::   cdrw       ! "READ"/"WRITE" flag
1244      WRITE(*,*) 'gls_rst: You should not have seen this print! error?', kt, cdrw
1245   END SUBROUTINE gls_rst
1246#endif
1247
1248   !!======================================================================
1249END MODULE zdfgls
1250
Note: See TracBrowser for help on using the repository browser.