source: branches/2015/nemo_v3_6_STABLE/NEMOGCM/NEMO/TOP_SRC/PISCES/P4Z/p4zmeso.F90 @ 8532

Last change on this file since 8532 was 8532, checked in by cetlod, 3 years ago

v3.6 stable: bugfixes to solve problem particle in PISCES, see ticket #1940

File size: 19.0 KB
Line 
1MODULE p4zmeso
2   !!======================================================================
3   !!                         ***  MODULE p4zmeso  ***
4   !! TOP :   PISCES Compute the sources/sinks for mesozooplankton
5   !!======================================================================
6   !! History :   1.0  !  2002     (O. Aumont) Original code
7   !!             2.0  !  2007-12  (C. Ethe, G. Madec)  F90
8   !!             3.4  !  2011-06  (O. Aumont, C. Ethe) Quota model for iron
9   !!----------------------------------------------------------------------
10#if defined key_pisces
11   !!----------------------------------------------------------------------
12   !!   'key_pisces'                                       PISCES bio-model
13   !!----------------------------------------------------------------------
14   !!   p4z_meso       :   Compute the sources/sinks for mesozooplankton
15   !!   p4z_meso_init  :   Initialization of the parameters for mesozooplankton
16   !!----------------------------------------------------------------------
17   USE oce_trc         !  shared variables between ocean and passive tracers
18   USE trc             !  passive tracers common variables
19   USE sms_pisces      !  PISCES Source Minus Sink variables
20   USE p4zsink         !  vertical flux of particulate matter due to sinking
21   USE p4zint          !  interpolation and computation of various fields
22   USE p4zprod         !  production
23   USE prtctl_trc      !  print control for debugging
24   USE iom             !  I/O manager
25
26   IMPLICIT NONE
27   PRIVATE
28
29   PUBLIC   p4z_meso              ! called in p4zbio.F90
30   PUBLIC   p4z_meso_init         ! called in trcsms_pisces.F90
31
32   !! * Shared module variables
33   REAL(wp), PUBLIC ::  part2        !: part of calcite not dissolved in mesozoo guts
34   REAL(wp), PUBLIC ::  xprefc       !: mesozoo preference for POC
35   REAL(wp), PUBLIC ::  xprefp       !: mesozoo preference for nanophyto
36   REAL(wp), PUBLIC ::  xprefz       !: mesozoo preference for diatoms
37   REAL(wp), PUBLIC ::  xprefpoc     !: mesozoo preference for POC
38   REAL(wp), PUBLIC ::  xthresh2zoo  !: zoo feeding threshold for mesozooplankton
39   REAL(wp), PUBLIC ::  xthresh2dia  !: diatoms feeding threshold for mesozooplankton
40   REAL(wp), PUBLIC ::  xthresh2phy  !: nanophyto feeding threshold for mesozooplankton
41   REAL(wp), PUBLIC ::  xthresh2poc  !: poc feeding threshold for mesozooplankton
42   REAL(wp), PUBLIC ::  xthresh2     !: feeding threshold for mesozooplankton
43   REAL(wp), PUBLIC ::  resrat2      !: exsudation rate of mesozooplankton
44   REAL(wp), PUBLIC ::  mzrat2       !: microzooplankton mortality rate
45   REAL(wp), PUBLIC ::  grazrat2     !: maximal mesozoo grazing rate
46   REAL(wp), PUBLIC ::  xkgraz2      !: non assimilated fraction of P by mesozoo
47   REAL(wp), PUBLIC ::  unass2       !: Efficicency of mesozoo growth
48   REAL(wp), PUBLIC ::  sigma2       !: Fraction of mesozoo excretion as DOM
49   REAL(wp), PUBLIC ::  epsher2      !: half sturation constant for grazing 2
50   REAL(wp), PUBLIC ::  grazflux     !: mesozoo flux feeding rate
51
52   !!* Substitution
53#  include "top_substitute.h90"
54   !!----------------------------------------------------------------------
55   !! NEMO/TOP 3.3 , NEMO Consortium (2010)
56   !! $Id: p4zmeso.F90 3160 2011-11-20 14:27:18Z cetlod $
57   !! Software governed by the CeCILL licence (NEMOGCM/NEMO_CeCILL.txt)
58   !!----------------------------------------------------------------------
59
60CONTAINS
61
62   SUBROUTINE p4z_meso( kt, knt )
63      !!---------------------------------------------------------------------
64      !!                     ***  ROUTINE p4z_meso  ***
65      !!
66      !! ** Purpose :   Compute the sources/sinks for mesozooplankton
67      !!
68      !! ** Method  : - ???
69      !!---------------------------------------------------------------------
70      INTEGER, INTENT(in) ::   kt, knt ! ocean time step
71      INTEGER  :: ji, jj, jk
72      REAL(wp) :: zcompadi, zcompaph, zcompapoc, zcompaz, zcompam
73      REAL(wp) :: zgraze2 , zdenom, zdenom2
74      REAL(wp) :: zfact   , zstep, zfood, zfoodlim, zproport
75      REAL(wp) :: zmortzgoc, zfrac, zfracfe, zratio, zratio2
76      REAL(wp) :: zepshert, zepsherv, zgrarsig, zgraztot, zgraztotn, zgraztotf
77      REAL(wp) :: zgrarem2, zgrafer2, zgrapoc2, zprcaca, zmortz2, zgrasrat, zgrasratn
78#if defined key_kriest
79      REAL znumpoc
80#endif
81      REAL(wp) :: zrespz2, ztortz2, zgrazd, zgrazz, zgrazpof
82      REAL(wp) :: zgrazn, zgrazpoc, zgraznf, zgrazf
83      REAL(wp) :: zgrazfffp, zgrazfffg, zgrazffep, zgrazffeg
84      CHARACTER (len=25) :: charout
85      REAL(wp), POINTER, DIMENSION(:,:,:) :: zgrazing, zw3d
86
87      !!---------------------------------------------------------------------
88      !
89      IF( nn_timing == 1 )  CALL timing_start('p4z_meso')
90      !
91      IF( lk_iomput ) THEN
92         CALL wrk_alloc( jpi, jpj, jpk, zgrazing )
93         zgrazing(:,:,:) = 0._wp
94      ENDIF
95
96      DO jk = 1, jpkm1
97         DO jj = 1, jpj
98            DO ji = 1, jpi
99               zcompam   = MAX( ( trb(ji,jj,jk,jpmes) - 1.e-9 ), 0.e0 )
100# if defined key_degrad
101               zstep     = xstep * facvol(ji,jj,jk)
102# else
103               zstep     = xstep
104# endif
105               zfact     = zstep * tgfunc2(ji,jj,jk) * zcompam
106
107               !  Respiration rates of both zooplankton
108               !  -------------------------------------
109               zrespz2   = resrat2 * zfact * trb(ji,jj,jk,jpmes) / ( xkmort + trb(ji,jj,jk,jpmes) )  &
110                  &      + resrat2 * zfact * 3. * nitrfac(ji,jj,jk)
111
112               !  Zooplankton mortality. A square function has been selected with
113               !  no real reason except that it seems to be more stable and may mimic predation
114               !  ---------------------------------------------------------------
115               ztortz2   = mzrat2 * 1.e6 * zfact * trb(ji,jj,jk,jpmes) * (1. - nitrfac(ji,jj,jk) )
116               !
117               zcompadi  = MAX( ( trb(ji,jj,jk,jpdia) - xthresh2dia ), 0.e0 )
118               zcompaz   = MAX( ( trb(ji,jj,jk,jpzoo) - xthresh2zoo ), 0.e0 )
119               ! Size effect of nanophytoplankton on grazing : the smaller it is, the less prone
120               ! it is to predation by mesozooplankton
121               ! -------------------------------------------------------------------------------
122               zcompaph  = MAX( ( trb(ji,jj,jk,jpphy) - xthresh2phy ), 0.e0 ) &
123                  &      * MIN(1., MAX( 0., ( quotan(ji,jj,jk) - 0.2) / 0.3 ) )
124               zcompapoc = MAX( ( trb(ji,jj,jk,jppoc) - xthresh2poc ), 0.e0 )
125
126               zfood     = xprefc * zcompadi + xprefz * zcompaz + xprefp * zcompaph + xprefpoc * zcompapoc 
127               zfoodlim  = MAX( 0., zfood - MIN( 0.5 * zfood, xthresh2 ) )
128               zdenom    = zfoodlim / ( xkgraz2 + zfoodlim )
129               zdenom2   = zdenom / ( zfood + rtrn )
130               zgraze2   = grazrat2 * zstep * tgfunc2(ji,jj,jk) * trb(ji,jj,jk,jpmes) * (1. - nitrfac(ji,jj,jk) ) 
131 
132
133               zgrazd    = zgraze2  * xprefc   * zcompadi  * zdenom2 
134               zgrazz    = zgraze2  * xprefz   * zcompaz   * zdenom2 
135               zgrazn    = zgraze2  * xprefp   * zcompaph  * zdenom2 
136               zgrazpoc  = zgraze2  * xprefpoc * zcompapoc * zdenom2 
137
138               zgraznf   = zgrazn   * trb(ji,jj,jk,jpnfe) / ( trb(ji,jj,jk,jpphy) + rtrn)
139               zgrazf    = zgrazd   * trb(ji,jj,jk,jpdfe) / ( trb(ji,jj,jk,jpdia) + rtrn)
140               zgrazpof  = zgrazpoc * trb(ji,jj,jk,jpsfe) / ( trb(ji,jj,jk,jppoc) + rtrn)
141
142               !  Mesozooplankton flux feeding on GOC
143               !  ----------------------------------
144               !  ----------------------------------
145# if ! defined key_kriest
146               zgrazffeg = grazflux  * zstep * wsbio4(ji,jj,jk)      &
147               &           * tgfunc2(ji,jj,jk) * trb(ji,jj,jk,jpgoc) * trb(ji,jj,jk,jpmes) &
148               &           * (1. - nitrfac(ji,jj,jk))
149               zgrazfffg = zgrazffeg * trb(ji,jj,jk,jpbfe) / (trb(ji,jj,jk,jpgoc) + rtrn)
150# endif
151               zgrazffep = grazflux  * zstep *  wsbio3(ji,jj,jk)     &
152               &           * tgfunc2(ji,jj,jk) * trb(ji,jj,jk,jppoc) * trb(ji,jj,jk,jpmes) &
153               &           * (1. - nitrfac(ji,jj,jk))
154               zgrazfffp = zgrazffep * trb(ji,jj,jk,jpsfe) / (trb(ji,jj,jk,jppoc) + rtrn)
155              !
156# if ! defined key_kriest
157              zgraztot  = zgrazd + zgrazz + zgrazn + zgrazpoc + zgrazffep + zgrazffeg
158              ! Compute the proportion of filter feeders
159              zproport  = (zgrazffep + zgrazffeg)/(rtrn + zgraztot)
160              ! Compute fractionation of aggregates. It is assumed that
161              ! diatoms based aggregates are more prone to fractionation
162              ! since they are more porous (marine snow instead of fecal pellets)
163              zratio    = trb(ji,jj,jk,jpgsi) / ( trb(ji,jj,jk,jpgoc) + rtrn )
164              zratio2   = zratio * zratio
165              zfrac     = zproport * grazflux  * zstep * wsbio4(ji,jj,jk)      &
166               &          * trb(ji,jj,jk,jpgoc) * trb(ji,jj,jk,jpmes)          &
167               &          * ( 0.2 + 3.8 * zratio2 / ( 1.**2 + zratio2 ) )
168              zfracfe   = zfrac * trb(ji,jj,jk,jpbfe) / (trb(ji,jj,jk,jpgoc) + rtrn)
169
170              zgrazffep = zproport * zgrazffep
171              zgrazffeg = zproport * zgrazffeg
172              zgrazfffp = zproport * zgrazfffp
173              zgrazfffg = zproport * zgrazfffg
174              zgraztot  = zgrazd + zgrazz + zgrazn + zgrazpoc + zgrazffep + zgrazffeg
175              zgraztotn = zgrazd * quotad(ji,jj,jk) + zgrazz + zgrazn * quotan(ji,jj,jk)   &
176              &   + zgrazpoc + zgrazffep + zgrazffeg
177              zgraztotf = zgrazf + zgraznf + zgrazz * ferat3 + zgrazpof + zgrazfffp + zgrazfffg
178# else
179              zgraztot  = zgrazd + zgrazz + zgrazn + zgrazpoc + zgrazffep
180              ! Compute the proportion of filter feeders
181              zproport  = zgrazffep / ( zgraztot + rtrn )
182              zgrazffep = zproport * zgrazffep
183              zgrazfffp = zproport * zgrazfffp
184              zgraztot  = zgrazd + zgrazz + zgrazn + zgrazpoc + zgrazffep
185              zgraztotn = zgrazd * quotad(ji,jj,jk) + zgrazz + zgrazn * quotan(ji,jj,jk) + zgrazpoc + zgrazffep
186              zgraztotf = zgrazf + zgraznf + zgrazz * ferat3 + zgrazpof + zgrazfffp
187# endif
188
189              ! Total grazing ( grazing by microzoo is already computed in p4zmicro )
190              IF( lk_iomput )  zgrazing(ji,jj,jk) = zgraztot
191
192              !    Mesozooplankton efficiency
193              !    --------------------------
194               zgrasrat  =  ( zgraztotf +rtrn )/ ( zgraztot + rtrn )
195               zgrasratn =  ( zgraztotn +rtrn )/ ( zgraztot + rtrn )
196               zepshert  = MIN( 1., zgrasratn, zgrasrat / ferat3)
197               zepsherv  = zepshert * MIN( epsher2, (1. - unass2) * zgrasrat / ferat3, (1. - unass2) * zgrasratn )
198               zgrarem2  = zgraztot * ( 1. - zepsherv - unass2 ) &
199                &       + ( 1. - epsher2 - unass2 ) / ( 1. - epsher2 ) * ztortz2
200               zgrafer2  = zgraztot * MAX( 0. , ( 1. - unass2 ) * zgrasrat - ferat3 * zepsherv )    &
201                &       + ferat3 * ( ( 1. - epsher2 - unass2 ) /( 1. - epsher2 ) * ztortz2 )
202               zgrapoc2  = zgraztot * unass2
203
204               !   Update the arrays TRA which contain the biological sources and sinks
205               zgrarsig  = zgrarem2 * sigma2
206               tra(ji,jj,jk,jppo4) = tra(ji,jj,jk,jppo4) + zgrarsig
207               tra(ji,jj,jk,jpnh4) = tra(ji,jj,jk,jpnh4) + zgrarsig
208               tra(ji,jj,jk,jpdoc) = tra(ji,jj,jk,jpdoc) + zgrarem2 - zgrarsig
209               tra(ji,jj,jk,jpoxy) = tra(ji,jj,jk,jpoxy) - o2ut * zgrarsig
210               tra(ji,jj,jk,jpfer) = tra(ji,jj,jk,jpfer) + zgrafer2
211               tra(ji,jj,jk,jpdic) = tra(ji,jj,jk,jpdic) + zgrarsig
212               tra(ji,jj,jk,jptal) = tra(ji,jj,jk,jptal) + rno3 * zgrarsig             
213
214               zmortz2 = ztortz2 + zrespz2
215               zmortzgoc = unass2 / ( 1. - epsher2 ) * ztortz2 + zrespz2
216               tra(ji,jj,jk,jpmes) = tra(ji,jj,jk,jpmes) - zmortz2 + zepsherv * zgraztot 
217               tra(ji,jj,jk,jpdia) = tra(ji,jj,jk,jpdia) - zgrazd
218               tra(ji,jj,jk,jpzoo) = tra(ji,jj,jk,jpzoo) - zgrazz
219               tra(ji,jj,jk,jpphy) = tra(ji,jj,jk,jpphy) - zgrazn
220               tra(ji,jj,jk,jpnch) = tra(ji,jj,jk,jpnch) - zgrazn * trb(ji,jj,jk,jpnch) / ( trb(ji,jj,jk,jpphy) + rtrn )
221               tra(ji,jj,jk,jpdch) = tra(ji,jj,jk,jpdch) - zgrazd * trb(ji,jj,jk,jpdch) / ( trb(ji,jj,jk,jpdia) + rtrn )
222               tra(ji,jj,jk,jpdsi) = tra(ji,jj,jk,jpdsi) - zgrazd * trb(ji,jj,jk,jpdsi) / ( trb(ji,jj,jk,jpdia) + rtrn )
223               tra(ji,jj,jk,jpgsi) = tra(ji,jj,jk,jpgsi) + zgrazd * trb(ji,jj,jk,jpdsi) / ( trb(ji,jj,jk,jpdia) + rtrn )
224               tra(ji,jj,jk,jpnfe) = tra(ji,jj,jk,jpnfe) - zgraznf
225               tra(ji,jj,jk,jpdfe) = tra(ji,jj,jk,jpdfe) - zgrazf
226
227               ! calcite production
228               zprcaca = xfracal(ji,jj,jk) * zgrazn
229               prodcal(ji,jj,jk) = prodcal(ji,jj,jk) + zprcaca  ! prodcal=prodcal(nanophy)+prodcal(microzoo)+prodcal(mesozoo)
230               !
231               zprcaca = part2 * zprcaca
232               tra(ji,jj,jk,jpdic) = tra(ji,jj,jk,jpdic) - zprcaca
233               tra(ji,jj,jk,jptal) = tra(ji,jj,jk,jptal) - 2. * zprcaca
234               tra(ji,jj,jk,jpcal) = tra(ji,jj,jk,jpcal) + zprcaca
235#if defined key_kriest
236              znumpoc = trb(ji,jj,jk,jpnum) / ( trb(ji,jj,jk,jppoc) + rtrn )
237              tra(ji,jj,jk,jppoc) = tra(ji,jj,jk,jppoc) + zmortzgoc - zgrazpoc - zgrazffep + zgrapoc2
238              tra(ji,jj,jk,jpnum) = tra(ji,jj,jk,jpnum) - zgrazpoc * znumpoc + zgrapoc2 * xkr_dmeso      &
239                 &   + zmortzgoc * xkr_dmeso - zgrazffep * znumpoc * wsbio4(ji,jj,jk) / ( wsbio3(ji,jj,jk) + rtrn )
240              tra(ji,jj,jk,jpsfe) = tra(ji,jj,jk,jpsfe) + ferat3 * zmortzgoc - zgrazfffp - zgrazpof    &
241                 &                 + zgraztotf * unass2
242#else
243              tra(ji,jj,jk,jppoc) = tra(ji,jj,jk,jppoc) - zgrazpoc - zgrazffep + zfrac
244              tra(ji,jj,jk,jpgoc) = tra(ji,jj,jk,jpgoc) + zmortzgoc - zgrazffeg + zgrapoc2 - zfrac
245              tra(ji,jj,jk,jpsfe) = tra(ji,jj,jk,jpsfe) - zgrazpof - zgrazfffp + zfracfe
246              tra(ji,jj,jk,jpbfe) = tra(ji,jj,jk,jpbfe) + ferat3 * zmortzgoc - zgrazfffg     &
247                 &                + zgraztotf * unass2 - zfracfe
248#endif
249            END DO
250         END DO
251      END DO
252      !
253      IF( lk_iomput .AND. knt == nrdttrc ) THEN
254         CALL wrk_alloc( jpi, jpj, jpk, zw3d )
255         IF( iom_use( "GRAZ2" ) ) THEN
256            zw3d(:,:,:) = zgrazing(:,:,:) * 1.e+3 * rfact2r * tmask(:,:,:)  !   Total grazing of phyto by zooplankton
257            CALL iom_put( "GRAZ2", zw3d )
258         ENDIF
259         IF( iom_use( "PCAL" ) ) THEN
260            zw3d(:,:,:) = prodcal(:,:,:) * 1.e+3 * rfact2r * tmask(:,:,:)   !  Calcite production
261            CALL iom_put( "PCAL", zw3d ) 
262         ENDIF
263         CALL wrk_dealloc( jpi, jpj, jpk, zw3d )
264      ENDIF
265      !
266      IF(ln_ctl)   THEN  ! print mean trends (used for debugging)
267        WRITE(charout, FMT="('meso')")
268        CALL prt_ctl_trc_info(charout)
269        CALL prt_ctl_trc(tab4d=tra, mask=tmask, clinfo=ctrcnm)
270      ENDIF
271      !
272      IF( lk_iomput )  CALL wrk_dealloc( jpi, jpj, jpk, zgrazing )
273      !
274      IF( nn_timing == 1 )  CALL timing_stop('p4z_meso')
275      !
276   END SUBROUTINE p4z_meso
277
278   SUBROUTINE p4z_meso_init
279
280      !!----------------------------------------------------------------------
281      !!                  ***  ROUTINE p4z_meso_init  ***
282      !!
283      !! ** Purpose :   Initialization of mesozooplankton parameters
284      !!
285      !! ** Method  :   Read the nampismes namelist and check the parameters
286      !!      called at the first timestep (nittrc000)
287      !!
288      !! ** input   :   Namelist nampismes
289      !!
290      !!----------------------------------------------------------------------
291
292      NAMELIST/nampismes/ part2, grazrat2, resrat2, mzrat2, xprefc, xprefp, xprefz,   &
293         &                xprefpoc, xthresh2dia, xthresh2phy, xthresh2zoo, xthresh2poc, &
294         &                xthresh2, xkgraz2, epsher2, sigma2, unass2, grazflux
295      INTEGER :: ios                 ! Local integer output status for namelist read
296
297      REWIND( numnatp_ref )              ! Namelist nampismes in reference namelist : Pisces mesozooplankton
298      READ  ( numnatp_ref, nampismes, IOSTAT = ios, ERR = 901)
299901   IF( ios /= 0 ) CALL ctl_nam ( ios , 'nampismes in reference namelist', lwp )
300
301      REWIND( numnatp_cfg )              ! Namelist nampismes in configuration namelist : Pisces mesozooplankton
302      READ  ( numnatp_cfg, nampismes, IOSTAT = ios, ERR = 902 )
303902   IF( ios /= 0 ) CALL ctl_nam ( ios , 'nampismes in configuration namelist', lwp )
304      IF(lwm) WRITE ( numonp, nampismes )
305
306
307      IF(lwp) THEN                         ! control print
308         WRITE(numout,*) ' ' 
309         WRITE(numout,*) ' Namelist parameters for mesozooplankton, nampismes'
310         WRITE(numout,*) ' ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~'
311         WRITE(numout,*) '    part of calcite not dissolved in mesozoo guts  part2        =', part2
312         WRITE(numout,*) '    mesozoo preference for phyto                   xprefc       =', xprefc
313         WRITE(numout,*) '    mesozoo preference for POC                     xprefp       =', xprefp
314         WRITE(numout,*) '    mesozoo preference for zoo                     xprefz       =', xprefz
315         WRITE(numout,*) '    mesozoo preference for poc                     xprefpoc     =', xprefpoc
316         WRITE(numout,*) '    microzoo feeding threshold  for mesozoo        xthresh2zoo  =', xthresh2zoo
317         WRITE(numout,*) '    diatoms feeding threshold  for mesozoo         xthresh2dia  =', xthresh2dia
318         WRITE(numout,*) '    nanophyto feeding threshold for mesozoo        xthresh2phy  =', xthresh2phy
319         WRITE(numout,*) '    poc feeding threshold for mesozoo              xthresh2poc  =', xthresh2poc
320         WRITE(numout,*) '    feeding threshold for mesozooplankton          xthresh2     =', xthresh2
321         WRITE(numout,*) '    exsudation rate of mesozooplankton             resrat2      =', resrat2
322         WRITE(numout,*) '    mesozooplankton mortality rate                 mzrat2       =', mzrat2
323         WRITE(numout,*) '    maximal mesozoo grazing rate                   grazrat2     =', grazrat2
324         WRITE(numout,*) '    mesozoo flux feeding rate                      grazflux     =', grazflux
325         WRITE(numout,*) '    non assimilated fraction of P by mesozoo       unass2       =', unass2
326         WRITE(numout,*) '    Efficicency of Mesozoo growth                  epsher2      =', epsher2
327         WRITE(numout,*) '    Fraction of mesozoo excretion as DOM           sigma2       =', sigma2
328         WRITE(numout,*) '    half sturation constant for grazing 2          xkgraz2      =', xkgraz2
329      ENDIF
330
331
332   END SUBROUTINE p4z_meso_init
333
334
335#else
336   !!======================================================================
337   !!  Dummy module :                                   No PISCES bio-model
338   !!======================================================================
339CONTAINS
340   SUBROUTINE p4z_meso                    ! Empty routine
341   END SUBROUTINE p4z_meso
342#endif 
343
344   !!======================================================================
345END MODULE p4zmeso
Note: See TracBrowser for help on using the repository browser.