New URL for NEMO forge! http://forge.nemo-ocean.eu

Since March 2022 along with NEMO 4.2 release, the code development moved to a self-hosted GitLab.
This present forge is now archived and remained online for history.

sbcice_lim.F90 in branches/2016/dev_INGV_UKMO_2016/NEMOGCM/NEMO/OPA_SRC/SBC – NEMO

Context Navigation

source: branches/2016/dev_INGV_UKMO_2016/NEMOGCM/NEMO/OPA_SRC/SBC/sbcice_lim.F90 @ 7351

Last change on this file since 7351 was 7351, checked in by emanuelaclementi, 7 years ago
ticket #1805 step 3: /2016/dev_INGV_UKMO_2016 aligned to the trunk at revision 7161
Property svn:keywords set to `Id`
File size: 31.8 KB

Line
1	MODULE sbcice_lim
2	!!======================================================================
3	!! * MODULE sbcice_lim *
4	!! Surface module : update the ocean surface boundary condition over ice
5	!! & covered area using LIM sea-ice model
6	!! Sea-Ice model : LIM-3 Sea ice model time-stepping
7	!!=====================================================================
8	!! History : 2.0 ! 2006-12 (M. Vancoppenolle) Original code
9	!! 3.0 ! 2008-02 (C. Talandier) Surface module from icestp.F90
10	!! - ! 2008-04 (G. Madec) sltyle and lim_ctl routine
11	!! 3.3 ! 2010-11 (G. Madec) ice-ocean stress always computed at each ocean time-step
12	!! 3.4 ! 2011-01 (A Porter) dynamical allocation
13	!! - ! 2012-10 (C. Rousset) add lim_diahsb
14	!! 3.6 ! 2014-07 (M. Vancoppenolle, G. Madec, O. Marti) revise coupled interface
15	!!----------------------------------------------------------------------
16	#if defined key_lim3
17	!!----------------------------------------------------------------------
18	!! 'key_lim3' : LIM 3.0 sea-ice model
19	!!----------------------------------------------------------------------
20	!! sbc_ice_lim : sea-ice model time-stepping and update ocean sbc over ice-covered area
21	!!----------------------------------------------------------------------
22	USE oce ! ocean dynamics and tracers
23	USE dom_oce ! ocean space and time domain
24	USE ice ! LIM-3: ice variables
25	USE thd_ice ! LIM-3: thermodynamical variables
26	USE dom_ice ! LIM-3: ice domain
27	!
28	USE sbc_oce ! Surface boundary condition: ocean fields
29	USE sbc_ice ! Surface boundary condition: ice fields
30	USE sbcblk_core ! Surface boundary condition: CORE bulk
31	USE sbcblk_clio ! Surface boundary condition: CLIO bulk
32	USE sbccpl ! Surface boundary condition: coupled interface
33	USE albedo ! ocean & ice albedo
34	!
35	USE phycst ! Define parameters for the routines
36	USE eosbn2 ! equation of state
37	USE limdyn ! Ice dynamics
38	USE limtrp ! Ice transport
39	USE limhdf ! Ice horizontal diffusion
40	USE limthd ! Ice thermodynamics
41	USE limitd_me ! Mechanics on ice thickness distribution
42	USE limsbc ! sea surface boundary condition
43	USE limdiahsb ! Ice budget diagnostics
44	USE limwri ! Ice outputs
45	USE limrst ! Ice restarts
46	USE limupdate1 ! update of global variables
47	USE limupdate2 ! update of global variables
48	USE limvar ! Ice variables switch
49	USE limctl !
50	USE limmsh ! LIM mesh
51	USE limistate ! LIM initial state
52	USE limthd_sal ! LIM ice thermodynamics: salinity
53	!
54	USE c1d ! 1D vertical configuration
55	USE in_out_manager ! I/O manager
56	USE iom ! I/O manager library
57	USE prtctl ! Print control
58	USE lib_fortran !
59	USE lbclnk ! lateral boundary condition - MPP link
60	USE lib_mpp ! MPP library
61	USE wrk_nemo ! work arrays
62	USE timing ! Timing
63
64	#if defined key_bdy
65	USE bdyice_lim ! unstructured open boundary data (bdy_ice_lim routine)
66	#endif
67
68	IMPLICIT NONE
69	PRIVATE
70
71	PUBLIC sbc_ice_lim ! routine called by sbcmod.F90
72	PUBLIC sbc_lim_init ! routine called by sbcmod.F90
73
74	!! * Substitutions
75	# include "vectopt_loop_substitute.h90"
76	!!----------------------------------------------------------------------
77	!! NEMO/OPA 4.0 , UCL NEMO Consortium (2011)
78	!! $Id$
79	!! Software governed by the CeCILL licence (NEMOGCM/NEMO_CeCILL.txt)
80	!!----------------------------------------------------------------------
81	CONTAINS
82
83	SUBROUTINE sbc_ice_lim( kt, kblk )
84	!!---------------------------------------------------------------------
85	!! * ROUTINE sbc_ice_lim *
86	!!
87	!! ** Purpose : update the ocean surface boundary condition via the
88	!! Louvain la Neuve Sea Ice Model time stepping
89	!!
90	!! ** Method : ice model time stepping
91	!! - call the ice dynamics routine
92	!! - call the ice advection/diffusion routine
93	!! - call the ice thermodynamics routine
94	!! - call the routine that computes mass and
95	!! heat fluxes at the ice/ocean interface
96	!! - save the outputs
97	!! - save the outputs for restart when necessary
98	!!
99	!! ** Action : - time evolution of the LIM sea-ice model
100	!! - update all sbc variables below sea-ice:
101	!! utau, vtau, taum, wndm, qns , qsr, emp , sfx
102	!!---------------------------------------------------------------------
103	INTEGER, INTENT(in) :: kt ! ocean time step
104	INTEGER, INTENT(in) :: kblk ! type of bulk (=3 CLIO, =4 CORE, =5 COUPLED)
105	!!
106	INTEGER :: jl ! dummy loop index
107	REAL(wp), POINTER, DIMENSION(:,:,:) :: zalb_os, zalb_cs ! ice albedo under overcast/clear sky
108	REAL(wp), POINTER, DIMENSION(:,: ) :: zutau_ice, zvtau_ice
109	!!----------------------------------------------------------------------
110
111	IF( nn_timing == 1 ) CALL timing_start('sbc_ice_lim')
112
113	!-----------------------!
114	! --- Ice time step --- !
115	!-----------------------!
116	IF( MOD( kt-1, nn_fsbc ) == 0 ) THEN
117
118	! mean surface ocean current at ice velocity point (C-grid dynamics : U- & V-points as the ocean)
119	u_oce(:,:) = ssu_m(:,:) * umask(:,:,1)
120	v_oce(:,:) = ssv_m(:,:) * vmask(:,:,1)
121
122	! masked sea surface freezing temperature [Kelvin] (set to rt0 over land)
123	CALL eos_fzp( sss_m(:,:) , t_bo(:,:) )
124	t_bo(:,:) = ( t_bo(:,:) + rt0 ) * tmask(:,:,1) + rt0 * ( 1._wp - tmask(:,:,1) )
125
126	! Mask sea ice surface temperature (set to rt0 over land)
127	DO jl = 1, jpl
128	t_su(:,:,jl) = t_su(:,:,jl) * tmask(:,:,1) + rt0 * ( 1._wp - tmask(:,:,1) )
129	END DO
130	!
131	!------------------------------------------------!
132	! --- Dynamical coupling with the atmosphere --- !
133	!------------------------------------------------!
134	! It provides the following fields:
135	! utau_ice, vtau_ice : surface ice stress (U- & V-points) [N/m2]
136	!-----------------------------------------------------------------
137	SELECT CASE( kblk )
138	CASE( jp_clio ) ; CALL blk_ice_clio_tau ! CLIO bulk formulation
139	CASE( jp_core ) ; CALL blk_ice_core_tau ! CORE bulk formulation
140	CASE( jp_purecpl ) ; CALL sbc_cpl_ice_tau( utau_ice , vtau_ice ) ! Coupled formulation
141	END SELECT
142
143	IF( ln_mixcpl) THEN ! Case of a mixed Bulk/Coupled formulation
144	CALL wrk_alloc( jpi,jpj , zutau_ice, zvtau_ice)
145	CALL sbc_cpl_ice_tau( zutau_ice , zvtau_ice )
146	utau_ice(:,:) = utau_ice(:,:) * xcplmask(:,:,0) + zutau_ice(:,:) * ( 1. - xcplmask(:,:,0) )
147	vtau_ice(:,:) = vtau_ice(:,:) * xcplmask(:,:,0) + zvtau_ice(:,:) * ( 1. - xcplmask(:,:,0) )
148	CALL wrk_dealloc( jpi,jpj , zutau_ice, zvtau_ice)
149	ENDIF
150
151	!-------------------------------------------------------!
152	! --- ice dynamics and transport (except in 1D case) ---!
153	!-------------------------------------------------------!
154	numit = numit + nn_fsbc ! Ice model time step
155	!
156	CALL sbc_lim_bef ! Store previous ice values
157	CALL sbc_lim_diag0 ! set diag of mass, heat and salt fluxes to 0
158	CALL lim_rst_opn( kt ) ! Open Ice restart file
159	!
160	IF( .NOT. lk_c1d ) THEN
161	!
162	CALL lim_dyn( kt ) ! Ice dynamics ( rheology/dynamics )
163	!
164	CALL lim_trp( kt ) ! Ice transport ( Advection/diffusion )
165	!
166	IF( nn_monocat /= 2 ) CALL lim_itd_me ! Mechanical redistribution ! (ridging/rafting)
167	!
168	#if defined key_bdy
169	CALL bdy_ice_lim( kt ) ! bdy ice thermo
170	IF( ln_icectl ) CALL lim_prt( kt, iiceprt, jiceprt, 1, ' - ice thermo bdy - ' )
171	#endif
172	!
173	CALL lim_update1( kt ) ! Corrections
174	!
175	ENDIF
176
177	! previous lead fraction and ice volume for flux calculations
178	CALL sbc_lim_bef
179	CALL lim_var_glo2eqv ! ht_i and ht_s for ice albedo calculation
180	CALL lim_var_agg(1) ! at_i for coupling (via pfrld)
181	pfrld(:,:) = 1._wp - at_i(:,:)
182	phicif(:,:) = vt_i(:,:)
183
184	!------------------------------------------------------!
185	! --- Thermodynamical coupling with the atmosphere --- !
186	!------------------------------------------------------!
187	! It provides the following fields:
188	! qsr_ice , qns_ice : solar & non solar heat flux over ice (T-point) [W/m2]
189	! qla_ice : latent heat flux over ice (T-point) [W/m2]
190	! dqns_ice, dqla_ice : non solar & latent heat sensistivity (T-point) [W/m2]
191	! tprecip , sprecip : total & solid precipitation (T-point) [Kg/m2/s]
192	! fr1_i0 , fr2_i0 : 1sr & 2nd fraction of qsr penetration in ice [%]
193	!----------------------------------------------------------------------------------------
194	CALL wrk_alloc( jpi,jpj,jpl, zalb_os, zalb_cs )
195	CALL albedo_ice( t_su, ht_i, ht_s, zalb_cs, zalb_os ) ! cloud-sky and overcast-sky ice albedos
196
197	SELECT CASE( kblk )
198	CASE( jp_clio ) ! CLIO bulk formulation
199	! In CLIO the cloud fraction is read in the climatology and the all-sky albedo
200	! (alb_ice) is computed within the bulk routine
201	CALL blk_ice_clio_flx( t_su, zalb_cs, zalb_os, alb_ice )
202	IF( ln_mixcpl ) CALL sbc_cpl_ice_flx( p_frld=pfrld, palbi=alb_ice, psst=sst_m, pist=t_su )
203	IF( nn_limflx /= 2 ) CALL ice_lim_flx( t_su, alb_ice, qns_ice, qsr_ice, dqns_ice, evap_ice, devap_ice, nn_limflx )
204	CASE( jp_core ) ! CORE bulk formulation
205	! albedo depends on cloud fraction because of non-linear spectral effects
206	alb_ice(:,:,:) = ( 1. - cldf_ice ) * zalb_cs(:,:,:) + cldf_ice * zalb_os(:,:,:)
207	CALL blk_ice_core_flx( t_su, alb_ice )
208	IF( ln_mixcpl ) CALL sbc_cpl_ice_flx( p_frld=pfrld, palbi=alb_ice, psst=sst_m, pist=t_su )
209	IF( nn_limflx /= 2 ) CALL ice_lim_flx( t_su, alb_ice, qns_ice, qsr_ice, dqns_ice, evap_ice, devap_ice, nn_limflx )
210	CASE ( jp_purecpl )
211	! albedo depends on cloud fraction because of non-linear spectral effects
212	alb_ice(:,:,:) = ( 1. - cldf_ice ) * zalb_cs(:,:,:) + cldf_ice * zalb_os(:,:,:)
213	CALL sbc_cpl_ice_flx( p_frld=pfrld, palbi=alb_ice, psst=sst_m, pist=t_su )
214	IF( nn_limflx == 2 ) CALL ice_lim_flx( t_su, alb_ice, qns_ice, qsr_ice, dqns_ice, evap_ice, devap_ice, nn_limflx )
215	END SELECT
216	CALL wrk_dealloc( jpi,jpj,jpl, zalb_os, zalb_cs )
217
218	!----------------------------!
219	! --- ice thermodynamics --- !
220	!----------------------------!
221	CALL lim_thd( kt ) ! Ice thermodynamics
222	!
223	CALL lim_update2( kt ) ! Corrections
224	!
225	CALL lim_sbc_flx( kt ) ! Update surface ocean mass, heat and salt fluxes
226	!
227	IF(ln_limdiaout) CALL lim_diahsb ! Diagnostics and outputs
228	!
229	CALL lim_wri( 1 ) ! Ice outputs
230	!
231	IF( kt == nit000 .AND. ln_rstart ) &
232	& CALL iom_close( numrir ) ! close input ice restart file
233	!
234	IF( lrst_ice ) CALL lim_rst_write( kt ) ! Ice restart file
235	!
236	IF( ln_icectl ) CALL lim_ctl( kt ) ! alerts in case of model crash
237	!
238	ENDIF ! End sea-ice time step only
239
240	!-------------------------!
241	! --- Ocean time step --- !
242	!-------------------------!
243	! Update surface ocean stresses (only in ice-dynamic case) otherwise the atm.-ocean stresses are used everywhere
244	IF( ln_limdyn ) CALL lim_sbc_tau( kt, ub(:,:,1), vb(:,:,1) ) ! using before instantaneous surf. currents
245	!!gm remark, the ocean-ice stress is not saved in ice diag call above ..... find a solution!!!
246	!
247	IF( nn_timing == 1 ) CALL timing_stop('sbc_ice_lim')
248	!
249	END SUBROUTINE sbc_ice_lim
250
251
252	SUBROUTINE sbc_lim_init
253	!!----------------------------------------------------------------------
254	!! * ROUTINE sbc_lim_init *
255	!!
256	!! ** purpose : Allocate all the dynamic arrays of the LIM-3 modules
257	!!----------------------------------------------------------------------
258	INTEGER :: ji, jj, ierr
259	!!----------------------------------------------------------------------
260	IF(lwp) WRITE(numout,*)
261	IF(lwp) WRITE(numout,*) 'sbc_ice_lim : update ocean surface boudary condition'
262	IF(lwp) WRITE(numout,*) '~~~~~~~~~~~ via Louvain la Neuve Ice Model (LIM-3) time stepping'
263	!
264	! ! Open the reference and configuration namelist files and namelist output file
265	CALL ctl_opn( numnam_ice_ref, 'namelist_ice_ref', 'OLD', 'FORMATTED', 'SEQUENTIAL', -1, numout, lwp )
266	CALL ctl_opn( numnam_ice_cfg, 'namelist_ice_cfg', 'OLD', 'FORMATTED', 'SEQUENTIAL', -1, numout, lwp )
267	IF(lwm) CALL ctl_opn( numoni, 'output.namelist.ice', 'UNKNOWN', 'FORMATTED', 'SEQUENTIAL', -1, numout, lwp, 1 )
268	!
269	CALL ice_run ! set some ice run parameters
270	!
271	! ! Allocate the ice arrays
272	ierr = ice_alloc () ! ice variables
273	ierr = ierr + dom_ice_alloc () ! domain
274	ierr = ierr + sbc_ice_alloc () ! surface forcing
275	ierr = ierr + thd_ice_alloc () ! thermodynamics
276	ierr = ierr + lim_itd_me_alloc () ! ice thickness distribution - mechanics
277	!
278	IF( lk_mpp ) CALL mpp_sum( ierr )
279	IF( ierr /= 0 ) CALL ctl_stop('STOP', 'sbc_lim_init : unable to allocate ice arrays')
280	!
281	! ! adequation jpk versus ice/snow layers/categories
282	IF( jpl > jpk .OR. (nlay_i+1) > jpk .OR. nlay_s > jpk ) &
283	& CALL ctl_stop( 'STOP', &
284	& 'sbc_lim_init: the 3rd dimension of workspace arrays is too small.', &
285	& 'use more ocean levels or less ice/snow layers/categories.' )
286	!
287	CALL lim_itd_init ! ice thickness distribution initialization
288	!
289	CALL lim_hdf_init ! set ice horizontal diffusion computation parameters
290	!
291	CALL lim_thd_init ! set ice thermodynics parameters
292	!
293	CALL lim_thd_sal_init ! set ice salinity parameters
294	!
295	CALL lim_msh ! ice mesh initialization
296	!
297	CALL lim_itd_me_init ! ice thickness distribution initialization for mecanical deformation
298	! ! Initial sea-ice state
299	IF( .NOT. ln_rstart ) THEN ! start from rest: sea-ice deduced from sst
300	numit = 0
301	numit = nit000 - 1
302	CALL lim_istate
303	ELSE ! start from a restart file
304	CALL lim_rst_read
305	numit = nit000 - 1
306	ENDIF
307	CALL lim_var_agg(1)
308	CALL lim_var_glo2eqv
309	!
310	CALL lim_sbc_init ! ice surface boundary condition
311	!
312	fr_i(:,:) = at_i(:,:) ! initialisation of sea-ice fraction
313	tn_ice(:,:,:) = t_su(:,:,:) ! initialisation of surface temp for coupled simu
314	!
315	DO jj = 1, jpj
316	DO ji = 1, jpi
317	IF( gphit(ji,jj) > 0._wp ) THEN ; rn_amax_2d(ji,jj) = rn_amax_n ! NH
318	ELSE ; rn_amax_2d(ji,jj) = rn_amax_s ! SH
319	ENDIF
320	ENDDO
321	ENDDO
322	!
323	nstart = numit + nn_fsbc
324	nitrun = nitend - nit000 + 1
325	nlast = numit + nitrun
326	!
327	IF( nstock == 0 ) nstock = nlast + 1
328	!
329	END SUBROUTINE sbc_lim_init
330
331
332	SUBROUTINE ice_run
333	!!-------------------------------------------------------------------
334	!! * ROUTINE ice_run *
335	!!
336	!! ** Purpose : Definition some run parameter for ice model
337	!!
338	!! ** Method : Read the namicerun namelist and check the parameter
339	!! values called at the first timestep (nit000)
340	!!
341	!! ** input : Namelist namicerun
342	!!-------------------------------------------------------------------
343	INTEGER :: ios ! Local integer output status for namelist read
344	NAMELIST/namicerun/ jpl, nlay_i, nlay_s, cn_icerst_in, cn_icerst_indir, cn_icerst_out, cn_icerst_outdir, &
345	& ln_limdyn, rn_amax_n, rn_amax_s, ln_limdiahsb, ln_limdiaout, ln_icectl, iiceprt, jiceprt
346	!!-------------------------------------------------------------------
347	!
348	REWIND( numnam_ice_ref ) ! Namelist namicerun in reference namelist : Parameters for ice
349	READ ( numnam_ice_ref, namicerun, IOSTAT = ios, ERR = 901)
350	901 IF( ios /= 0 ) CALL ctl_nam ( ios , 'namicerun in reference namelist', lwp )
351	!
352	REWIND( numnam_ice_cfg ) ! Namelist namicerun in configuration namelist : Parameters for ice
353	READ ( numnam_ice_cfg, namicerun, IOSTAT = ios, ERR = 902 )
354	902 IF( ios /= 0 ) CALL ctl_nam ( ios , 'namicerun in configuration namelist', lwp )
355	IF(lwm) WRITE( numoni, namicerun )
356	!
357	IF(lwp) THEN ! control print
358	WRITE(numout,*)
359	WRITE(numout,*) 'ice_run : ice share parameters for dynamics/advection/thermo of sea-ice'
360	WRITE(numout,*) ' ~~~~~~'
361	WRITE(numout,*) ' number of ice categories = ', jpl
362	WRITE(numout,*) ' number of ice layers = ', nlay_i
363	WRITE(numout,*) ' number of snow layers = ', nlay_s
364	WRITE(numout,*) ' switch for ice dynamics (1) or not (0) ln_limdyn = ', ln_limdyn
365	WRITE(numout,*) ' maximum ice concentration for NH = ', rn_amax_n
366	WRITE(numout,*) ' maximum ice concentration for SH = ', rn_amax_s
367	WRITE(numout,*) ' Diagnose heat/salt budget or not ln_limdiahsb = ', ln_limdiahsb
368	WRITE(numout,*) ' Output heat/salt budget or not ln_limdiaout = ', ln_limdiaout
369	WRITE(numout,*) ' control prints in ocean.out for (i,j)=(iiceprt,jiceprt) = ', ln_icectl
370	WRITE(numout,*) ' i-index for control prints (ln_icectl=true) = ', iiceprt
371	WRITE(numout,*) ' j-index for control prints (ln_icectl=true) = ', jiceprt
372	ENDIF
373	!
374	! sea-ice timestep and inverse
375	rdt_ice = nn_fsbc * rdt
376	r1_rdtice = 1._wp / rdt_ice
377
378	! inverse of nlay_i and nlay_s
379	r1_nlay_i = 1._wp / REAL( nlay_i, wp )
380	r1_nlay_s = 1._wp / REAL( nlay_s, wp )
381	!
382	#if defined key_bdy
383	IF( lwp .AND. ln_limdiahsb ) CALL ctl_warn('online conservation check activated but it does not work with BDY')
384	#endif
385	!
386	END SUBROUTINE ice_run
387
388
389	SUBROUTINE lim_itd_init
390	!!------------------------------------------------------------------
391	!! * ROUTINE lim_itd_init *
392	!!
393	!! ** Purpose : Initializes the ice thickness distribution
394	!! ** Method : ...
395	!! ** input : Namelist namiceitd
396	!!-------------------------------------------------------------------
397	INTEGER :: ios ! Local integer output status for namelist read
398	NAMELIST/namiceitd/ nn_catbnd, rn_himean
399	!
400	INTEGER :: jl ! dummy loop index
401	REAL(wp) :: zc1, zc2, zc3, zx1 ! local scalars
402	REAL(wp) :: zhmax, znum, zden, zalpha !
403	!!------------------------------------------------------------------
404	!
405	REWIND( numnam_ice_ref ) ! Namelist namiceitd in reference namelist : Parameters for ice
406	READ ( numnam_ice_ref, namiceitd, IOSTAT = ios, ERR = 903)
407	903 IF( ios /= 0 ) CALL ctl_nam ( ios , 'namiceitd in reference namelist', lwp )
408	!
409	REWIND( numnam_ice_cfg ) ! Namelist namiceitd in configuration namelist : Parameters for ice
410	READ ( numnam_ice_cfg, namiceitd, IOSTAT = ios, ERR = 904 )
411	904 IF( ios /= 0 ) CALL ctl_nam ( ios , 'namiceitd in configuration namelist', lwp )
412	IF(lwm) WRITE( numoni, namiceitd )
413	!
414	IF(lwp) THEN ! control print
415	WRITE(numout,*)
416	WRITE(numout,*) 'ice_itd : ice cat distribution'
417	WRITE(numout,*) ' ~~~~~~'
418	WRITE(numout,*) ' shape of ice categories distribution nn_catbnd = ', nn_catbnd
419	WRITE(numout,*) ' mean ice thickness in the domain (used if nn_catbnd=2) rn_himean = ', rn_himean
420	ENDIF
421	!
422	!----------------------------------
423	!- Thickness categories boundaries
424	!----------------------------------
425	IF(lwp) WRITE(numout,*)
426	IF(lwp) WRITE(numout,*) 'lim_itd_init : Initialization of ice cat distribution '
427	IF(lwp) WRITE(numout,*) '~~~~~~~~~~~~'
428	!
429	hi_max(:) = 0._wp
430	!
431	SELECT CASE ( nn_catbnd ) ! type of ice categories distribution
432	!
433	CASE (1) !== tanh function (CICE) ==!
434	zc1 = 3._wp / REAL( jpl, wp )
435	zc2 = 10._wp * zc1
436	zc3 = 3._wp
437	DO jl = 1, jpl
438	zx1 = REAL( jl-1, wp ) / REAL( jpl, wp )
439	hi_max(jl) = hi_max(jl-1) + zc1 + zc2 * (1._wp + TANH( zc3 * (zx1 - 1._wp ) ) )
440	END DO
441	!
442	CASE (2) !== h^(-alpha) function ==!
443	zalpha = 0.05_wp
444	zhmax = 3._wp * rn_himean
445	DO jl = 1, jpl
446	znum = jpl * ( zhmax+1 )**zalpha
447	zden = REAL( jpl-jl , wp ) * ( zhmax + 1._wp )**zalpha + REAL( jl , wp )
448	hi_max(jl) = ( znum / zden )**(1./zalpha) - 1
449	END DO
450	!
451	END SELECT
452	!
453	DO jl = 1, jpl ! mean thickness by category
454	hi_mean(jl) = ( hi_max(jl) + hi_max(jl-1) ) * 0.5_wp
455	END DO
456	!
457	hi_max(jpl) = 99._wp ! set to a big value to ensure that all ice is thinner than hi_max(jpl)
458	!
459	IF(lwp) WRITE(numout,*) ' Thickness category boundaries '
460	IF(lwp) WRITE(numout,*) ' hi_max ', hi_max(0:jpl)
461	!
462	END SUBROUTINE lim_itd_init
463
464
465	SUBROUTINE ice_lim_flx( ptn_ice , palb_ice, pqns_ice , &
466	& pqsr_ice, pdqn_ice, pevap_ice, pdevap_ice, k_limflx )
467	!!---------------------------------------------------------------------
468	!! * ROUTINE ice_lim_flx *
469	!!
470	!! ** Purpose : update the ice surface boundary condition by averaging and / or
471	!! redistributing fluxes on ice categories
472	!!
473	!! ** Method : average then redistribute
474	!!
475	!! ** Action :
476	!!---------------------------------------------------------------------
477	INTEGER , INTENT(in ) :: k_limflx ! =-1 do nothing; =0 average ;
478	! ! =1 average and redistribute ; =2 redistribute
479	REAL(wp), DIMENSION(:,:,:), INTENT(in ) :: ptn_ice ! ice surface temperature
480	REAL(wp), DIMENSION(:,:,:), INTENT(in ) :: palb_ice ! ice albedo
481	REAL(wp), DIMENSION(:,:,:), INTENT(inout) :: pqns_ice ! non solar flux
482	REAL(wp), DIMENSION(:,:,:), INTENT(inout) :: pqsr_ice ! net solar flux
483	REAL(wp), DIMENSION(:,:,:), INTENT(inout) :: pdqn_ice ! non solar flux sensitivity
484	REAL(wp), DIMENSION(:,:,:), INTENT(inout) :: pevap_ice ! sublimation
485	REAL(wp), DIMENSION(:,:,:), INTENT(inout) :: pdevap_ice ! sublimation sensitivity
486	!
487	INTEGER :: jl ! dummy loop index
488	!
489	REAL(wp), POINTER, DIMENSION(:,:) :: zalb_m ! Mean albedo over all categories
490	REAL(wp), POINTER, DIMENSION(:,:) :: ztem_m ! Mean temperature over all categories
491	!
492	REAL(wp), POINTER, DIMENSION(:,:) :: z_qsr_m ! Mean solar heat flux over all categories
493	REAL(wp), POINTER, DIMENSION(:,:) :: z_qns_m ! Mean non solar heat flux over all categories
494	REAL(wp), POINTER, DIMENSION(:,:) :: z_evap_m ! Mean sublimation over all categories
495	REAL(wp), POINTER, DIMENSION(:,:) :: z_dqn_m ! Mean d(qns)/dT over all categories
496	REAL(wp), POINTER, DIMENSION(:,:) :: z_devap_m ! Mean d(evap)/dT over all categories
497	!!----------------------------------------------------------------------
498	!
499	IF( nn_timing == 1 ) CALL timing_start('ice_lim_flx')
500	!
501	SELECT CASE( k_limflx ) !== averaged on all ice categories ==!
502	CASE( 0 , 1 )
503	CALL wrk_alloc( jpi,jpj, z_qsr_m, z_qns_m, z_evap_m, z_dqn_m, z_devap_m)
504	!
505	z_qns_m (:,:) = fice_ice_ave ( pqns_ice (:,:,:) )
506	z_qsr_m (:,:) = fice_ice_ave ( pqsr_ice (:,:,:) )
507	z_dqn_m (:,:) = fice_ice_ave ( pdqn_ice (:,:,:) )
508	z_evap_m (:,:) = fice_ice_ave ( pevap_ice (:,:,:) )
509	z_devap_m(:,:) = fice_ice_ave ( pdevap_ice (:,:,:) )
510	DO jl = 1, jpl
511	pdqn_ice (:,:,jl) = z_dqn_m(:,:)
512	pdevap_ice(:,:,jl) = z_devap_m(:,:)
513	END DO
514	!
515	DO jl = 1, jpl
516	pqns_ice (:,:,jl) = z_qns_m(:,:)
517	pqsr_ice (:,:,jl) = z_qsr_m(:,:)
518	pevap_ice(:,:,jl) = z_evap_m(:,:)
519	END DO
520	!
521	CALL wrk_dealloc( jpi,jpj, z_qsr_m, z_qns_m, z_evap_m, z_dqn_m, z_devap_m)
522	END SELECT
523	!
524	SELECT CASE( k_limflx ) !== redistribution on all ice categories ==!
525	CASE( 1 , 2 )
526	CALL wrk_alloc( jpi,jpj, zalb_m, ztem_m )
527	!
528	zalb_m(:,:) = fice_ice_ave ( palb_ice (:,:,:) )
529	ztem_m(:,:) = fice_ice_ave ( ptn_ice (:,:,:) )
530	DO jl = 1, jpl
531	pqns_ice (:,:,jl) = pqns_ice (:,:,jl) + pdqn_ice (:,:,jl) * ( ptn_ice(:,:,jl) - ztem_m(:,:) )
532	pevap_ice(:,:,jl) = pevap_ice(:,:,jl) + pdevap_ice(:,:,jl) * ( ptn_ice(:,:,jl) - ztem_m(:,:) )
533	pqsr_ice (:,:,jl) = pqsr_ice (:,:,jl) * ( 1._wp - palb_ice(:,:,jl) ) / ( 1._wp - zalb_m(:,:) )
534	END DO
535	!
536	CALL wrk_dealloc( jpi,jpj, zalb_m, ztem_m )
537	END SELECT
538	!
539	IF( nn_timing == 1 ) CALL timing_stop('ice_lim_flx')
540	!
541	END SUBROUTINE ice_lim_flx
542
543
544	SUBROUTINE sbc_lim_bef
545	!!----------------------------------------------------------------------
546	!! * ROUTINE sbc_lim_bef *
547	!!
548	!! ** purpose : store ice variables at "before" time step
549	!!----------------------------------------------------------------------
550	a_i_b (:,:,:) = a_i (:,:,:) ! ice area
551	e_i_b (:,:,:,:) = e_i (:,:,:,:) ! ice thermal energy
552	v_i_b (:,:,:) = v_i (:,:,:) ! ice volume
553	v_s_b (:,:,:) = v_s (:,:,:) ! snow volume
554	e_s_b (:,:,:,:) = e_s (:,:,:,:) ! snow thermal energy
555	smv_i_b(:,:,:) = smv_i(:,:,:) ! salt content
556	oa_i_b (:,:,:) = oa_i (:,:,:) ! areal age content
557	u_ice_b(:,:) = u_ice(:,:)
558	v_ice_b(:,:) = v_ice(:,:)
559	!
560	END SUBROUTINE sbc_lim_bef
561
562
563	SUBROUTINE sbc_lim_diag0
564	!!----------------------------------------------------------------------
565	!! * ROUTINE sbc_lim_diag0 *
566	!!
567	!! ** purpose : set ice-ocean and ice-atm. fluxes to zeros at the beggining
568	!! of the time step
569	!!----------------------------------------------------------------------
570	sfx (:,:) = 0._wp ;
571	sfx_bri(:,:) = 0._wp ;
572	sfx_sni(:,:) = 0._wp ; sfx_opw(:,:) = 0._wp
573	sfx_bog(:,:) = 0._wp ; sfx_dyn(:,:) = 0._wp
574	sfx_bom(:,:) = 0._wp ; sfx_sum(:,:) = 0._wp
575	sfx_res(:,:) = 0._wp ; sfx_sub(:,:) = 0._wp
576	!
577	wfx_snw(:,:) = 0._wp ; wfx_ice(:,:) = 0._wp
578	wfx_sni(:,:) = 0._wp ; wfx_opw(:,:) = 0._wp
579	wfx_bog(:,:) = 0._wp ; wfx_dyn(:,:) = 0._wp
580	wfx_bom(:,:) = 0._wp ; wfx_sum(:,:) = 0._wp
581	wfx_res(:,:) = 0._wp ; wfx_sub(:,:) = 0._wp
582	wfx_spr(:,:) = 0._wp ;
583	!
584	hfx_thd(:,:) = 0._wp ;
585	hfx_snw(:,:) = 0._wp ; hfx_opw(:,:) = 0._wp
586	hfx_bog(:,:) = 0._wp ; hfx_dyn(:,:) = 0._wp
587	hfx_bom(:,:) = 0._wp ; hfx_sum(:,:) = 0._wp
588	hfx_res(:,:) = 0._wp ; hfx_sub(:,:) = 0._wp
589	hfx_spr(:,:) = 0._wp ; hfx_dif(:,:) = 0._wp
590	hfx_err(:,:) = 0._wp ; hfx_err_rem(:,:) = 0._wp
591	hfx_err_dif(:,:) = 0._wp
592	wfx_err_sub(:,:) = 0._wp
593	!
594	afx_tot(:,:) = 0._wp ;
595	afx_dyn(:,:) = 0._wp ; afx_thd(:,:) = 0._wp
596	!
597	diag_heat(:,:) = 0._wp ; diag_smvi(:,:) = 0._wp ;
598	diag_vice(:,:) = 0._wp ; diag_vsnw(:,:) = 0._wp ;
599	!
600	END SUBROUTINE sbc_lim_diag0
601
602
603	FUNCTION fice_cell_ave ( ptab )
604	!!--------------------------------------------------------------------------
605	!! * Compute average over categories, for grid cell (ice covered and free ocean)
606	!!--------------------------------------------------------------------------
607	REAL (wp), DIMENSION (jpi,jpj) :: fice_cell_ave
608	REAL (wp), DIMENSION (jpi,jpj,jpl), INTENT (in) :: ptab
609	INTEGER :: jl ! Dummy loop index
610
611	fice_cell_ave (:,:) = 0.0_wp
612	DO jl = 1, jpl
613	fice_cell_ave (:,:) = fice_cell_ave (:,:) + a_i (:,:,jl) * ptab (:,:,jl)
614	END DO
615
616	END FUNCTION fice_cell_ave
617
618
619	FUNCTION fice_ice_ave ( ptab )
620	!!--------------------------------------------------------------------------
621	!! * Compute average over categories, for ice covered part of grid cell
622	!!--------------------------------------------------------------------------
623	REAL (kind=wp), DIMENSION (jpi,jpj) :: fice_ice_ave
624	REAL (kind=wp), DIMENSION (jpi,jpj,jpl), INTENT(in) :: ptab
625
626	fice_ice_ave (:,:) = 0.0_wp
627	WHERE ( at_i (:,:) > 0.0_wp ) fice_ice_ave (:,:) = fice_cell_ave ( ptab (:,:,:)) / at_i (:,:)
628
629	END FUNCTION fice_ice_ave
630
631	#else
632	!!----------------------------------------------------------------------
633	!! Default option Dummy module NO LIM 3.0 sea-ice model
634	!!----------------------------------------------------------------------
635	CONTAINS
636	SUBROUTINE sbc_ice_lim ( kt, kblk ) ! Dummy routine
637	WRITE(,) 'sbc_ice_lim: You should not have seen this print! error?', kt, kblk
638	END SUBROUTINE sbc_ice_lim
639	SUBROUTINE sbc_lim_init ! Dummy routine
640	END SUBROUTINE sbc_lim_init
641	#endif
642
643	!!======================================================================
644	END MODULE sbcice_lim

Note: See TracBrowser for help on using the repository browser.

Download in other formats: