New URL for NEMO forge!   http://forge.nemo-ocean.eu

Since March 2022 along with NEMO 4.2 release, the code development moved to a self-hosted GitLab.
This present forge is now archived and remained online for history.
p4zflx.F90 in branches/2016/dev_INGV_UKMO_2016/NEMOGCM/NEMO/TOP_SRC/PISCES/P4Z – NEMO

source: branches/2016/dev_INGV_UKMO_2016/NEMOGCM/NEMO/TOP_SRC/PISCES/P4Z/p4zflx.F90 @ 7351

Last change on this file since 7351 was 7351, checked in by emanuelaclementi, 7 years ago

ticket #1805 step 3: /2016/dev_INGV_UKMO_2016 aligned to the trunk at revision 7161

  • Property svn:keywords set to Id
File size: 18.8 KB
Line 
1MODULE p4zflx
2   !!======================================================================
3   !!                         ***  MODULE p4zflx  ***
4   !! TOP :   PISCES CALCULATES GAS EXCHANGE AND CHEMISTRY AT SEA SURFACE
5   !!======================================================================
6   !! History :    -   !  1988-07  (E. MAIER-REIMER) Original code
7   !!              -   !  1998     (O. Aumont) additions
8   !!              -   !  1999     (C. Le Quere) modifications
9   !!             1.0  !  2004     (O. Aumont) modifications
10   !!             2.0  !  2007-12  (C. Ethe, G. Madec)  F90
11   !!                  !  2011-02  (J. Simeon, J. Orr) Include total atm P correction
12   !!----------------------------------------------------------------------
13#if defined key_pisces
14   !!----------------------------------------------------------------------
15   !!   'key_pisces'                                       PISCES bio-model
16   !!----------------------------------------------------------------------
17   !!   p4z_flx       :   CALCULATES GAS EXCHANGE AND CHEMISTRY AT SEA SURFACE
18   !!   p4z_flx_init  :   Read the namelist
19   !!   p4z_patm      :   Read sfc atm pressure [atm] for each grid cell
20   !!----------------------------------------------------------------------
21   USE oce_trc                      !  shared variables between ocean and passive tracers
22   USE trc                          !  passive tracers common variables
23   USE sms_pisces                   !  PISCES Source Minus Sink variables
24   USE p4zche                       !  Chemical model
25   USE prtctl_trc                   !  print control for debugging
26   USE iom                          !  I/O manager
27   USE fldread                      !  read input fields
28#if defined key_cpl_carbon_cycle
29   USE sbc_oce, ONLY :  atm_co2     !  atmospheric pCO2               
30#endif
31
32   IMPLICIT NONE
33   PRIVATE
34
35   PUBLIC   p4z_flx 
36   PUBLIC   p4z_flx_init 
37   PUBLIC   p4z_flx_alloc 
38
39   !                               !!** Namelist  nampisext  **
40   REAL(wp)          ::  atcco2     !: pre-industrial atmospheric [co2] (ppm)   
41   LOGICAL           ::  ln_co2int  !: flag to read in a file and interpolate atmospheric pco2 or not
42   CHARACTER(len=34) ::  clname     !: filename of pco2 values
43   INTEGER           ::  nn_offset  !: Offset model-data start year (default = 0)
44
45   !!  Variables related to reading atmospheric CO2 time history   
46   REAL(wp), ALLOCATABLE, SAVE, DIMENSION(:) :: atcco2h, years
47   INTEGER  :: nmaxrec, numco2
48
49   !                               !!* nampisatm namelist (Atmospheric PRessure) *
50   LOGICAL, PUBLIC ::   ln_presatm  !: ref. pressure: global mean Patm (F) or a constant (F)
51
52   REAL(wp) , ALLOCATABLE, SAVE, DIMENSION(:,:)  ::  patm      ! atmospheric pressure at kt                 [N/m2]
53   TYPE(FLD), ALLOCATABLE,       DIMENSION(:)    ::  sf_patm   ! structure of input fields (file informations, fields read)
54
55
56   REAL(wp), PUBLIC, ALLOCATABLE, SAVE, DIMENSION(:,:) :: oce_co2   !: ocean carbon flux
57   REAL(wp), PUBLIC, ALLOCATABLE, SAVE, DIMENSION(:,:) :: satmco2   !: atmospheric pco2
58
59   REAL(wp) ::  xconv  = 0.01_wp / 3600._wp !: coefficients for conversion
60
61   !!----------------------------------------------------------------------
62   !! NEMO/TOP 3.3 , NEMO Consortium (2010)
63   !! $Id$
64   !! Software governed by the CeCILL licence     (NEMOGCM/NEMO_CeCILL.txt)
65   !!----------------------------------------------------------------------
66CONTAINS
67
68   SUBROUTINE p4z_flx ( kt, knt )
69      !!---------------------------------------------------------------------
70      !!                     ***  ROUTINE p4z_flx  ***
71      !!
72      !! ** Purpose :   CALCULATES GAS EXCHANGE AND CHEMISTRY AT SEA SURFACE
73      !!
74      !! ** Method  :
75      !!              - Include total atm P correction via Esbensen & Kushnir (1981)
76      !!              - Pressure correction NOT done for key_cpl_carbon_cycle
77      !!              - Remove Wanninkhof chemical enhancement;
78      !!              - Add option for time-interpolation of atcco2.txt 
79      !!---------------------------------------------------------------------
80      !
81      INTEGER, INTENT(in) ::   kt, knt   !
82      !
83      INTEGER  ::   ji, jj, jm, iind, iindm1
84      REAL(wp) ::   ztc, ztc2, ztc3, ztc4, zws, zkgwan
85      REAL(wp) ::   zfld, zflu, zfld16, zflu16, zfact
86      REAL(wp) ::   zvapsw, zsal, zfco2, zxc2, xCO2approx, ztkel, zfugcoeff
87      REAL(wp) ::   zph, zah2, zbot, zdic, zalk, zsch_o2, zalka, zsch_co2
88      REAL(wp) ::   zyr_dec, zdco2dt
89      CHARACTER (len=25) :: charout
90      REAL(wp), POINTER, DIMENSION(:,:) :: zkgco2, zkgo2, zh2co3, zoflx, zw2d, zpco2atm 
91      !!---------------------------------------------------------------------
92      !
93      IF( nn_timing == 1 )  CALL timing_start('p4z_flx')
94      !
95      CALL wrk_alloc( jpi, jpj, zkgco2, zkgo2, zh2co3, zoflx, zpco2atm )
96      !
97
98      ! SURFACE CHEMISTRY (PCO2 AND [H+] IN
99      !     SURFACE LAYER); THE RESULT OF THIS CALCULATION
100      !     IS USED TO COMPUTE AIR-SEA FLUX OF CO2
101
102      IF( kt /= nit000 .AND. knt == 1 ) CALL p4z_patm( kt )    ! Get sea-level pressure (E&K [1981] climatology) for use in flux calcs
103
104      IF( ln_co2int ) THEN 
105         ! Linear temporal interpolation  of atmospheric pco2.  atcco2.txt has annual values.
106         ! Caveats: First column of .txt must be in years, decimal  years preferably.
107         ! For nn_offset, if your model year is iyy, nn_offset=(years(1)-iyy)
108         ! then the first atmospheric CO2 record read is at years(1)
109         zyr_dec = REAL( nyear + nn_offset, wp ) + REAL( nday_year, wp ) / REAL( nyear_len(1), wp )
110         jm = 1
111         DO WHILE( jm <= nmaxrec .AND. years(jm) < zyr_dec ) ;  jm = jm + 1 ;  END DO
112         iind = jm  ;   iindm1 = jm - 1
113         zdco2dt = ( atcco2h(iind) - atcco2h(iindm1) ) / ( years(iind) - years(iindm1) + rtrn )
114         atcco2  = zdco2dt * ( zyr_dec - years(iindm1) ) + atcco2h(iindm1)
115         satmco2(:,:) = atcco2 
116      ENDIF
117
118#if defined key_cpl_carbon_cycle
119      satmco2(:,:) = atm_co2(:,:)
120#endif
121
122      DO jm = 1, 10
123         DO jj = 1, jpj
124            DO ji = 1, jpi
125
126               ! DUMMY VARIABLES FOR DIC, H+, AND BORATE
127               zbot  = borat(ji,jj,1)
128               zfact = rhop(ji,jj,1) / 1000. + rtrn
129               zdic  = trb(ji,jj,1,jpdic) / zfact
130               zph   = MAX( hi(ji,jj,1), 1.e-10 ) / zfact
131               zalka = trb(ji,jj,1,jptal) / zfact
132
133               ! CALCULATE [ALK]([CO3--], [HCO3-])
134               zalk  = zalka - (  akw3(ji,jj,1) / zph - zph / aphscale(ji,jj,1)    &
135               &       + zbot / ( 1.+ zph / akb3(ji,jj,1) )  )
136
137               ! CALCULATE [H+] AND [H2CO3]
138               zah2   = SQRT(  (zdic-zalk)**2 + 4.* ( zalk * ak23(ji,jj,1)   &
139                  &                                        / ak13(ji,jj,1) ) * ( 2.* zdic - zalk )  )
140               zah2   = 0.5 * ak13(ji,jj,1) / zalk * ( ( zdic - zalk ) + zah2 )
141               zh2co3(ji,jj) = ( 2.* zdic - zalk ) / ( 2.+ ak13(ji,jj,1) / zah2 ) * zfact
142               hi(ji,jj,1)   = zah2 * zfact
143            END DO
144         END DO
145      END DO
146
147
148      ! --------------
149      ! COMPUTE FLUXES
150      ! --------------
151
152      ! FIRST COMPUTE GAS EXCHANGE COEFFICIENTS
153      ! -------------------------------------------
154
155      DO jj = 1, jpj
156         DO ji = 1, jpi
157            ztc  = MIN( 35., tsn(ji,jj,1,jp_tem) )
158            ztc2 = ztc * ztc
159            ztc3 = ztc * ztc2 
160            ztc4 = ztc2 * ztc2 
161            ! Compute the schmidt Number both O2 and CO2
162            zsch_co2 = 2116.8 - 136.25 * ztc + 4.7353 * ztc2 - 0.092307 * ztc3 + 0.0007555 * ztc4
163            zsch_o2  = 1920.4 - 135.6  * ztc + 5.2122 * ztc2 - 0.109390 * ztc3 + 0.0009377 * ztc4
164            !  wind speed
165            zws  = wndm(ji,jj) * wndm(ji,jj)
166            ! Compute the piston velocity for O2 and CO2
167            zkgwan = 0.251 * zws
168            zkgwan = zkgwan * xconv * ( 1.- fr_i(ji,jj) ) * tmask(ji,jj,1)
169# if defined key_degrad
170            zkgwan = zkgwan * facvol(ji,jj,1)
171#endif 
172            ! compute gas exchange for CO2 and O2
173            zkgco2(ji,jj) = zkgwan * SQRT( 660./ zsch_co2 )
174            zkgo2 (ji,jj) = zkgwan * SQRT( 660./ zsch_o2 )
175         END DO
176      END DO
177
178      DO jj = 1, jpj
179         DO ji = 1, jpi
180            ztkel     = tsn(ji,jj,1,jp_tem) + 273.15
181            zsal      = tsn(ji,jj,1,jp_sal) + ( 1.- tmask(ji,jj,1) ) * 35.
182            zvapsw    = EXP(24.4543 - 67.4509*(100.0/ztkel) - 4.8489*LOG(ztkel/100) - 0.000544*zsal)
183            zpco2atm(ji,jj) = satmco2(ji,jj) * ( patm(ji,jj) - zvapsw )
184            zxc2      = ( 1.0 - zpco2atm(ji,jj) * 1E-6 )**2
185            zfugcoeff = EXP( patm(ji,jj) * (chemc(ji,jj,2) + 2.0 * zxc2 * chemc(ji,jj,3) )   &
186            &           / ( 82.05736 * ztkel ))
187            zfco2 = zpco2atm(ji,jj) * zfugcoeff
188
189            ! Compute CO2 flux for the sea and air
190            zfld = zfco2 * chemc(ji,jj,1) * zkgco2(ji,jj)  ! (mol/L) * (m/s)
191            zflu = zh2co3(ji,jj) * zkgco2(ji,jj)                                   ! (mol/L) (m/s) ?
192            oce_co2(ji,jj) = ( zfld - zflu ) * rfact2 * e1e2t(ji,jj) * tmask(ji,jj,1) * 1000.
193            ! compute the trend
194            tra(ji,jj,1,jpdic) = tra(ji,jj,1,jpdic) + ( zfld - zflu ) * rfact2 / e3t_n(ji,jj,1) * tmask(ji,jj,1)
195
196            ! Compute O2 flux
197            zfld16 = patm(ji,jj) * chemo2(ji,jj,1) * zkgo2(ji,jj)          ! (mol/L) * (m/s)
198            zflu16 = trb(ji,jj,1,jpoxy) * zkgo2(ji,jj)
199            zoflx(ji,jj) = ( zfld16 - zflu16 ) * tmask(ji,jj,1)
200            tra(ji,jj,1,jpoxy) = tra(ji,jj,1,jpoxy) + zoflx(ji,jj) * rfact2 / e3t_n(ji,jj,1)
201         END DO
202      END DO
203
204      t_oce_co2_flx     = glob_sum( oce_co2(:,:) )                    !  Total Flux of Carbon
205      t_oce_co2_flx_cum = t_oce_co2_flx_cum + t_oce_co2_flx       !  Cumulative Total Flux of Carbon
206!      t_atm_co2_flx     = glob_sum( satmco2(:,:) * e1e2t(:,:) )       ! Total atmospheric pCO2
207      t_atm_co2_flx     =  atcco2      ! Total atmospheric pCO2
208 
209      IF(ln_ctl)   THEN  ! print mean trends (used for debugging)
210         WRITE(charout, FMT="('flx ')")
211         CALL prt_ctl_trc_info(charout)
212         CALL prt_ctl_trc(tab4d=tra, mask=tmask, clinfo=ctrcnm)
213      ENDIF
214
215      IF( lk_iomput .AND. knt == nrdttrc ) THEN
216         CALL wrk_alloc( jpi, jpj, zw2d ) 
217         IF( iom_use( "Cflx"  ) )  THEN
218            zw2d(:,:) = oce_co2(:,:) / e1e2t(:,:) * rfact2r
219            CALL iom_put( "Cflx"     , zw2d ) 
220         ENDIF
221         IF( iom_use( "Oflx"  ) )  THEN
222            zw2d(:,:) =  zoflx(:,:) * 1000 * tmask(:,:,1)
223            CALL iom_put( "Oflx" , zw2d )
224         ENDIF
225         IF( iom_use( "Kg"    ) )  THEN
226            zw2d(:,:) =  zkgco2(:,:) * tmask(:,:,1)
227            CALL iom_put( "Kg"   , zw2d )
228         ENDIF
229         IF( iom_use( "Dpco2" ) ) THEN
230           zw2d(:,:) = ( zpco2atm(:,:) - zh2co3(:,:) / ( chemc(:,:,1) + rtrn ) ) * tmask(:,:,1)
231           CALL iom_put( "Dpco2" ,  zw2d )
232         ENDIF
233         IF( iom_use( "Dpo2" ) )  THEN
234           zw2d(:,:) = ( atcox * patm(:,:) - atcox * trn(:,:,1,jpoxy) / ( chemo2(:,:,1) + rtrn ) ) * tmask(:,:,1)
235           CALL iom_put( "Dpo2"  , zw2d )
236         ENDIF
237         IF( iom_use( "tcflx" ) )  CALL iom_put( "tcflx"    , t_oce_co2_flx * rfact2r )   ! molC/s
238         CALL iom_put( "tcflxcum" , t_oce_co2_flx_cum )      ! molC
239         !
240         CALL wrk_dealloc( jpi, jpj, zw2d )
241      ELSE
242         IF( ln_diatrc ) THEN
243            trc2d(:,:,jp_pcs0_2d    ) = oce_co2(:,:) / e1e2t(:,:) * rfact2r 
244            trc2d(:,:,jp_pcs0_2d + 1) = zoflx(:,:) * 1000 * tmask(:,:,1) 
245            trc2d(:,:,jp_pcs0_2d + 2) = zkgco2(:,:) * tmask(:,:,1) 
246            trc2d(:,:,jp_pcs0_2d + 3) = ( zpco2atm(:,:) - zh2co3(:,:) / ( chemc(:,:,1) + rtrn ) ) * tmask(:,:,1) 
247         ENDIF
248      ENDIF
249      !
250      CALL wrk_dealloc( jpi, jpj, zkgco2, zkgo2, zh2co3, zoflx, zpco2atm )
251      !
252      IF( nn_timing == 1 )  CALL timing_stop('p4z_flx')
253      !
254   END SUBROUTINE p4z_flx
255
256
257   SUBROUTINE p4z_flx_init
258      !!----------------------------------------------------------------------
259      !!                  ***  ROUTINE p4z_flx_init  ***
260      !!
261      !! ** Purpose :   Initialization of atmospheric conditions
262      !!
263      !! ** Method  :   Read the nampisext namelist and check the parameters
264      !!      called at the first timestep (nittrc000)
265      !! ** input   :   Namelist nampisext
266      !!----------------------------------------------------------------------
267      NAMELIST/nampisext/ln_co2int, atcco2, clname, nn_offset
268      INTEGER :: jm
269      INTEGER :: ios                 ! Local integer output status for namelist read
270      !!----------------------------------------------------------------------
271      !
272
273      REWIND( numnatp_ref )              ! Namelist nampisext in reference namelist : Pisces atm. conditions
274      READ  ( numnatp_ref, nampisext, IOSTAT = ios, ERR = 901)
275901   IF( ios /= 0 ) CALL ctl_nam ( ios , 'nampisext in reference namelist', lwp )
276
277      REWIND( numnatp_cfg )              ! Namelist nampisext in configuration namelist : Pisces atm. conditions
278      READ  ( numnatp_cfg, nampisext, IOSTAT = ios, ERR = 902 )
279902   IF( ios /= 0 ) CALL ctl_nam ( ios , 'nampisext in configuration namelist', lwp )
280      IF(lwm) WRITE ( numonp, nampisext )
281      !
282      IF(lwp) THEN                         ! control print
283         WRITE(numout,*) ' '
284         WRITE(numout,*) ' Namelist parameters for air-sea exchange, nampisext'
285         WRITE(numout,*) ' ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~'
286         WRITE(numout,*) '    Choice for reading in the atm pCO2 file or constant value, ln_co2int =', ln_co2int
287         WRITE(numout,*) ' '
288      ENDIF
289      IF( .NOT.ln_co2int ) THEN
290         IF(lwp) THEN                         ! control print
291            WRITE(numout,*) '    Constant Atmospheric pCO2 value  atcco2    =', atcco2
292            WRITE(numout,*) ' '
293         ENDIF
294         satmco2(:,:)  = atcco2      ! Initialisation of atmospheric pco2
295      ELSE
296         IF(lwp)  THEN
297            WRITE(numout,*) '    Atmospheric pCO2 value  from file clname      =', TRIM( clname )
298            WRITE(numout,*) '    Offset model-data start year      nn_offset   =', nn_offset
299            WRITE(numout,*) ' '
300         ENDIF
301         CALL ctl_opn( numco2, TRIM( clname) , 'OLD', 'FORMATTED', 'SEQUENTIAL', -1 , numout, lwp )
302         jm = 0                      ! Count the number of record in co2 file
303         DO
304           READ(numco2,*,END=100) 
305           jm = jm + 1
306         END DO
307 100     nmaxrec = jm - 1 
308         ALLOCATE( years  (nmaxrec) )     ;      years  (:) = 0._wp
309         ALLOCATE( atcco2h(nmaxrec) )     ;      atcco2h(:) = 0._wp
310
311         REWIND(numco2)
312         DO jm = 1, nmaxrec          ! get  xCO2 data
313            READ(numco2, *)  years(jm), atcco2h(jm)
314            IF(lwp) WRITE(numout, '(f6.0,f7.2)')  years(jm), atcco2h(jm)
315         END DO
316         CLOSE(numco2)
317      ENDIF
318      !
319      oce_co2(:,:)  = 0._wp                ! Initialization of Flux of Carbon
320      t_oce_co2_flx = 0._wp
321      t_atm_co2_flx = 0._wp
322      !
323      CALL p4z_patm( nit000 )
324      !
325   END SUBROUTINE p4z_flx_init
326
327   SUBROUTINE p4z_patm( kt )
328
329      !!----------------------------------------------------------------------
330      !!                  ***  ROUTINE p4z_atm  ***
331      !!
332      !! ** Purpose :   Read and interpolate the external atmospheric sea-levl pressure
333      !! ** Method  :   Read the files and interpolate the appropriate variables
334      !!
335      !!----------------------------------------------------------------------
336      !! * arguments
337      INTEGER, INTENT( in  ) ::   kt   ! ocean time step
338      !
339      INTEGER            ::  ierr
340      INTEGER            ::  ios      ! Local integer output status for namelist read
341      CHARACTER(len=100) ::  cn_dir   ! Root directory for location of ssr files
342      TYPE(FLD_N)        ::  sn_patm  ! informations about the fields to be read
343      !!
344      NAMELIST/nampisatm/ ln_presatm, sn_patm, cn_dir
345
346      !                                         ! ----------------------- !
347      IF( kt == nit000 ) THEN                   ! First call kt=nittrc000 !
348
349         REWIND( numnatp_ref )              ! Namelist nampisatm in reference namelist : Pisces atm. sea level pressure file
350         READ  ( numnatp_ref, nampisatm, IOSTAT = ios, ERR = 901)
351901      IF( ios /= 0 ) CALL ctl_nam ( ios , 'nampisatm in reference namelist', lwp )
352
353         REWIND( numnatp_cfg )              ! Namelist nampisatm in configuration namelist : Pisces atm. sea level pressure file
354         READ  ( numnatp_cfg, nampisatm, IOSTAT = ios, ERR = 902 )
355902      IF( ios /= 0 ) CALL ctl_nam ( ios , 'nampisatm in configuration namelist', lwp )
356         IF(lwm) WRITE ( numonp, nampisatm )
357         !
358         !
359         IF(lwp) THEN                                 !* control print
360            WRITE(numout,*)
361            WRITE(numout,*) '   Namelist nampisatm : Atmospheric Pressure as external forcing'
362            WRITE(numout,*) '      constant atmopsheric pressure (F) or from a file (T)  ln_presatm = ', ln_presatm
363            WRITE(numout,*)
364         ENDIF
365         !
366         IF( ln_presatm ) THEN
367            ALLOCATE( sf_patm(1), STAT=ierr )           !* allocate and fill sf_patm (forcing structure) with sn_patm
368            IF( ierr > 0 )   CALL ctl_stop( 'STOP', 'p4z_flx: unable to allocate sf_patm structure' )
369            !
370            CALL fld_fill( sf_patm, (/ sn_patm /), cn_dir, 'p4z_flx', 'Atmospheric pressure ', 'nampisatm' )
371                                   ALLOCATE( sf_patm(1)%fnow(jpi,jpj,1)   )
372            IF( sn_patm%ln_tint )  ALLOCATE( sf_patm(1)%fdta(jpi,jpj,1,2) )
373         ENDIF
374         !                                         
375         IF( .NOT.ln_presatm )   patm(:,:) = 1.e0    ! Initialize patm if no reading from a file
376         !
377      ENDIF
378      !
379      IF( ln_presatm ) THEN
380         CALL fld_read( kt, 1, sf_patm )               !* input Patm provided at kt + 1/2
381         patm(:,:) = sf_patm(1)%fnow(:,:,1)                        ! atmospheric pressure
382      ENDIF
383      !
384   END SUBROUTINE p4z_patm
385
386   INTEGER FUNCTION p4z_flx_alloc()
387      !!----------------------------------------------------------------------
388      !!                     ***  ROUTINE p4z_flx_alloc  ***
389      !!----------------------------------------------------------------------
390      ALLOCATE( oce_co2(jpi,jpj), satmco2(jpi,jpj), patm(jpi,jpj), STAT=p4z_flx_alloc )
391      !
392      IF( p4z_flx_alloc /= 0 )   CALL ctl_warn('p4z_flx_alloc : failed to allocate arrays')
393      !
394   END FUNCTION p4z_flx_alloc
395
396#else
397   !!======================================================================
398   !!  Dummy module :                                   No PISCES bio-model
399   !!======================================================================
400CONTAINS
401   SUBROUTINE p4z_flx( kt )                   ! Empty routine
402      INTEGER, INTENT( in ) ::   kt
403      WRITE(*,*) 'p4z_flx: You should not have seen this print! error?', kt
404   END SUBROUTINE p4z_flx
405#endif 
406
407   !!======================================================================
408END MODULE p4zflx
Note: See TracBrowser for help on using the repository browser.