source: branches/2016/dev_r6409_SIMPLIF_2_usrdef/NEMOGCM/NEMO/OPA_SRC/DOM/domzgr.F90 @ 6977

Last change on this file since 6977 was 6977, checked in by flavoni, 4 years ago

fix bug in variable name

  • Property svn:keywords set to Id
File size: 16.8 KB
Line 
1MODULE domzgr
2   !!==============================================================================
3   !!                       ***  MODULE domzgr   ***
4   !! Ocean domain : definition of the vertical coordinate system
5   !!==============================================================================
6   !! History :  OPA  ! 1995-12  (G. Madec)  Original code : s vertical coordinate
7   !!                 ! 1997-07  (G. Madec)  lbc_lnk call
8   !!                 ! 1997-04  (J.-O. Beismann)
9   !!            8.5  ! 2002-09  (A. Bozec, G. Madec)  F90: Free form and module
10   !!             -   ! 2002-09  (A. de Miranda)  rigid-lid + islands
11   !!  NEMO      1.0  ! 2003-08  (G. Madec)  F90: Free form and module
12   !!             -   ! 2005-10  (A. Beckmann)  modifications for hybrid s-ccordinates & new stretching function
13   !!            2.0  ! 2006-04  (R. Benshila, G. Madec)  add zgr_zco
14   !!            3.0  ! 2008-06  (G. Madec)  insertion of domzgr_zps.h90 & conding style
15   !!            3.2  ! 2009-07  (R. Benshila) Suppression of rigid-lid option
16   !!            3.3  ! 2010-11  (G. Madec) add mbk. arrays associated to the deepest ocean level
17   !!            3.4  ! 2012-08  (J. Siddorn) added Siddorn and Furner stretching function
18   !!            3.4  ! 2012-12  (R. Bourdalle-Badie and G. Reffray)  modify C1D case 
19   !!            3.6  ! 2014-11  (P. Mathiot and C. Harris) add ice shelf capabilitye 
20   !!            3.?  ! 2015-11  (H. Liu) Modifications for Wetting/Drying
21   !!----------------------------------------------------------------------
22
23   !!----------------------------------------------------------------------
24   !!   dom_zgr       : read or set the ocean vertical coordinate system
25   !!   zgr_read      : read the vertical domain coordinate and mask in domain_cfg file
26   !!   zgr_top_bot   : ocean top and bottom level for t-, u, and v-points with 1 as minimum value
27   !!---------------------------------------------------------------------
28   USE oce            ! ocean variables
29   USE dom_oce        ! ocean domain
30   USE usrdef_zgr     ! user defined vertical coordinate system
31   !
32   USE in_out_manager ! I/O manager
33   USE iom            ! I/O library
34   USE lbclnk         ! ocean lateral boundary conditions (or mpp link)
35   USE lib_mpp        ! distributed memory computing library
36   USE wrk_nemo       ! Memory allocation
37   USE timing         ! Timing
38
39   IMPLICIT NONE
40   PRIVATE
41
42   PUBLIC   dom_zgr        ! called by dom_init.F90
43
44  !! * Substitutions
45#  include "vectopt_loop_substitute.h90"
46   !!----------------------------------------------------------------------
47   !! NEMO/OPA 3.3.1 , NEMO Consortium (2011)
48   !! $Id$
49   !! Software governed by the CeCILL licence     (NEMOGCM/NEMO_CeCILL.txt)
50   !!----------------------------------------------------------------------
51CONTAINS       
52
53   SUBROUTINE dom_zgr( k_top, k_bot )
54      !!----------------------------------------------------------------------
55      !!                ***  ROUTINE dom_zgr  ***
56      !!                   
57      !! ** Purpose :   set the depth of model levels and the resulting
58      !!              vertical scale factors.
59      !!
60      !! ** Method  : - reference 1D vertical coordinate (gdep._1d, e3._1d)
61      !!              - read/set ocean depth and ocean levels (bathy, mbathy)
62      !!              - vertical coordinate (gdep., e3.) depending on the
63      !!                coordinate chosen :
64      !!                   ln_zco=T   z-coordinate   
65      !!                   ln_zps=T   z-coordinate with partial steps
66      !!                   ln_zco=T   s-coordinate
67      !!
68      !! ** Action  :   define gdep., e3., mbathy and bathy
69      !!----------------------------------------------------------------------
70      INTEGER, DIMENSION(:,:), INTENT(out) ::   k_top, k_bot   ! ocean first and last level indices
71      !
72      INTEGER  ::   jk                  ! dummy loop index
73      INTEGER  ::   ioptio, ibat, ios   ! local integer
74      REAL(wp) ::   zrefdep             ! depth of the reference level (~10m)
75      !!----------------------------------------------------------------------
76      !
77      IF( nn_timing == 1 )   CALL timing_start('dom_zgr')
78      !
79      IF(lwp) THEN                     ! Control print
80         WRITE(numout,*)
81         WRITE(numout,*) 'dom_zgr : vertical coordinate'
82         WRITE(numout,*) '~~~~~~~'
83      ENDIF
84
85      IF( ln_linssh .AND. lwp) WRITE(numout,*) '   linear free surface: the vertical mesh does not change in time'
86
87
88      IF( ln_read_cfg ) THEN        !==  read in mesh_mask.nc file  ==!
89         IF(lwp) WRITE(numout,*)
90         IF(lwp) WRITE(numout,*) '          Read vertical mesh in "domain_cfg" file'
91         !
92         CALL zgr_read   ( ln_zco  , ln_zps  , ln_sco, ln_isfcav,   & 
93            &              gdept_1d, gdepw_1d, e3t_1d, e3w_1d   ,   &    ! 1D gridpoints depth
94            &              gdept_0 , gdepw_0                    ,   &    ! gridpoints depth
95            &              e3t_0   , e3u_0   , e3v_0 , e3f_0    ,   &    ! vertical scale factors
96            &              e3w_0   , e3uw_0  , e3vw_0           ,   &    ! vertical scale factors
97            &              k_top   , k_bot            )                  ! 1st & last ocean level
98         !
99      ELSE                          !==  User defined configuration  ==!
100         IF(lwp) WRITE(numout,*)
101         IF(lwp) WRITE(numout,*) '          User defined vertical mesh (usr_def_zgr)'
102         !
103         CALL usr_def_zgr( ln_zco  , ln_zps  , ln_sco, ln_isfcav,   & 
104            &              gdept_1d, gdepw_1d, e3t_1d, e3w_1d   ,   &    ! 1D gridpoints depth
105            &              gdept_0 , gdepw_0                    ,   &    ! gridpoints depth
106            &              e3t_0   , e3u_0   , e3v_0 , e3f_0    ,   &    ! vertical scale factors
107            &              e3w_0   , e3uw_0  , e3vw_0           ,   &    ! vertical scale factors
108            &              k_top   , k_bot            )                  ! 1st & last ocean level
109         !
110      ENDIF
111      !
112!!gm to be remove when changing the definition of e3 scale factors so that gde3w disappears
113      ! Compute gde3w_0 (vertical sum of e3w)
114      gde3w_0(:,:,1) = 0.5_wp * e3w_0(:,:,1)
115      DO jk = 2, jpk
116         gde3w_0(:,:,jk) = gde3w_0(:,:,jk-1) + e3w_0(:,:,jk)
117      END DO
118      !
119      IF(lwp) THEN                     ! Control print
120         WRITE(numout,*)
121         WRITE(numout,*) '   Type of vertical coordinate (read in domain_cfg.nc or set through user defined routines) :'
122         WRITE(numout,*) '      z-coordinate - full steps      ln_zco    = ', ln_zco
123         WRITE(numout,*) '      z-coordinate - partial steps   ln_zps    = ', ln_zps
124         WRITE(numout,*) '      s- or hybrid z-s-coordinate    ln_sco    = ', ln_sco
125         WRITE(numout,*) '      ice shelf cavities             ln_isfcav = ', ln_isfcav
126      ENDIF
127
128      ioptio = 0                       ! Check Vertical coordinate options
129      IF( ln_zco      )   ioptio = ioptio + 1
130      IF( ln_zps      )   ioptio = ioptio + 1
131      IF( ln_sco      )   ioptio = ioptio + 1
132      IF( ioptio /= 1 )   CALL ctl_stop( ' none or several vertical coordinate options used' )
133
134
135      !                                ! top/bottom ocean level indices for t-, u- and v-points (f-point also for top)
136      CALL zgr_top_bot( k_top, k_bot )      ! with a minimum value set to 1
137     
138
139      !                                ! deepest/shallowest W level Above/Below ~10m
140!!gm BUG in s-coordinate this does not work!
141      zrefdep = 10._wp - 0.1_wp * MINVAL( e3w_1d )                   ! ref. depth with tolerance (10% of minimum layer thickness)
142      nlb10 = MINLOC( gdepw_1d, mask = gdepw_1d > zrefdep, dim = 1 ) ! shallowest W level Below ~10m
143      nla10 = nlb10 - 1                                              ! deepest    W level Above ~10m
144!!gm end bug
145      !
146      !
147      IF( nprint == 1 .AND. lwp )   THEN
148         WRITE(numout,*) ' MIN val k_top   ', MINVAL(   k_top(:,:) ), ' MAX ', MAXVAL( k_top(:,:) )
149         WRITE(numout,*) ' MIN val k_bot   ', MINVAL(   k_bot(:,:) ), ' MAX ', MAXVAL( k_bot(:,:) )
150         WRITE(numout,*) ' MIN val depth t ', MINVAL( gdept_0(:,:,:) ),   &
151            &                          ' w ', MINVAL( gdepw_0(:,:,:) ), '3w ', MINVAL( gde3w_0(:,:,:) )
152         WRITE(numout,*) ' MIN val e3    t ', MINVAL(   e3t_0(:,:,:) ), ' f ', MINVAL(   e3f_0(:,:,:) ),  &
153            &                          ' u ', MINVAL(   e3u_0(:,:,:) ), ' u ', MINVAL(   e3v_0(:,:,:) ),  &
154            &                          ' uw', MINVAL(  e3uw_0(:,:,:) ), ' vw', MINVAL(  e3vw_0(:,:,:)),   &
155            &                          ' w ', MINVAL(   e3w_0(:,:,:) )
156
157         WRITE(numout,*) ' MAX val depth t ', MAXVAL( gdept_0(:,:,:) ),   &
158            &                          ' w ', MAXVAL( gdepw_0(:,:,:) ), '3w ', MAXVAL( gde3w_0(:,:,:) )
159         WRITE(numout,*) ' MAX val e3    t ', MAXVAL(   e3t_0(:,:,:) ), ' f ', MAXVAL(   e3f_0(:,:,:) ),  &
160            &                          ' u ', MAXVAL(   e3u_0(:,:,:) ), ' u ', MAXVAL(   e3v_0(:,:,:) ),  &
161            &                          ' uw', MAXVAL(  e3uw_0(:,:,:) ), ' vw', MAXVAL(  e3vw_0(:,:,:) ),  &
162            &                          ' w ', MAXVAL(   e3w_0(:,:,:) )
163      ENDIF
164      !
165      IF( nn_timing == 1 )  CALL timing_stop('dom_zgr')
166      !
167   END SUBROUTINE dom_zgr
168
169
170   SUBROUTINE zgr_read( ld_zco  , ld_zps  , ld_sco  , ld_isfcav,   &   ! type of vertical coordinate
171      &                 pdept_1d, pdepw_1d, pe3t_1d , pe3w_1d  ,   &   ! 1D reference vertical coordinate
172      &                 pdept , pdepw ,                            &   ! 3D t & w-points depth
173      &                 pe3t  , pe3u  , pe3v   , pe3f ,            &   ! vertical scale factors
174      &                 pe3w  , pe3uw , pe3vw         ,            &   !     -      -      -
175      &                 k_top  , k_bot    )                            ! top & bottom ocean level
176      !!---------------------------------------------------------------------
177      !!              ***  ROUTINE zgr_read  ***
178      !!
179      !! ** Purpose :   Read the vertical information in a domain_cfg.nc file
180      !!
181      !!----------------------------------------------------------------------
182      LOGICAL                   , INTENT(out) ::   ld_zco, ld_zps, ld_sco      ! vertical coordinate flags
183      LOGICAL                   , INTENT(out) ::   ld_isfcav                   ! under iceshelf cavity flag
184      REAL(wp), DIMENSION(:)    , INTENT(out) ::   pdept_1d, pdepw_1d          ! 1D grid-point depth       [m]
185      REAL(wp), DIMENSION(:)    , INTENT(out) ::   pe3t_1d , pe3w_1d           ! 1D vertical scale factors [m]
186      REAL(wp), DIMENSION(:,:,:), INTENT(out) ::   pdept, pdepw                ! grid-point depth          [m]
187      REAL(wp), DIMENSION(:,:,:), INTENT(out) ::   pe3t , pe3u , pe3v , pe3f   ! vertical scale factors    [m]
188      REAL(wp), DIMENSION(:,:,:), INTENT(out) ::   pe3w , pe3uw, pe3vw         !    -       -      -
189      INTEGER , DIMENSION(:,:)  , INTENT(out) ::   k_top , k_bot               ! first & last ocean level
190      !
191      INTEGER  ::   inum   ! local logical unit
192      REAL(WP) ::   z_zco, z_zps, z_sco, z_cav
193      REAL(wp), DIMENSION(jpi,jpj) ::   z2d   ! 2D workspace
194      !!----------------------------------------------------------------------
195      !
196      IF(lwp) THEN
197         WRITE(numout,*)
198         WRITE(numout,*) '   zgr_read : read the vertical coordinates in "domain_cfg.nc" file'
199         WRITE(numout,*) '   ~~~~~~~~      jpiglo = ', jpiglo, ' jpjglo = ', jpjglo, ' jpkglo = ', jpkglo
200      ENDIF
201      !
202      CALL iom_open( 'domain_cfg', inum )
203      !
204      !                                   ! type of vertical coordinate
205      CALL iom_get( inum, 'ln_zco'   , z_zco )
206      CALL iom_get( inum, 'ln_zps'   , z_zps )
207      CALL iom_get( inum, 'ln_sco'   , z_sco )
208      IF( z_zco == 0._wp ) THEN   ;   ld_zco = .false.   ;   ELSE   ;   ld_zco = .true.   ;   ENDIF
209      IF( z_zps == 0._wp ) THEN   ;   ld_zps = .false.   ;   ELSE   ;   ld_zps = .true.   ;   ENDIF
210      IF( z_sco == 0._wp ) THEN   ;   ld_sco = .false.   ;   ELSE   ;   ld_sco = .true.   ;   ENDIF
211      !
212      !                                   ! ocean cavities under iceshelves
213      CALL iom_get( inum, 'ln_isfcav', z_cav )
214      IF( z_cav == 0._wp ) THEN   ;   ld_isfcav = .false.   ;   ELSE   ;   ld_isfcav = .true.   ;   ENDIF
215      !
216      !                                   ! reference 1D-coordinate
217      CALL iom_get( inum, jpdom_unknown, 'gdept_1d', pdept_1d )   
218      CALL iom_get( inum, jpdom_unknown, 'gdepw_1d', pdepw_1d )
219      CALL iom_get( inum, jpdom_unknown, 'e3t_1d'  , pe3t_1d  )
220      CALL iom_get( inum, jpdom_unknown, 'e3w_1d'  , pe3w_1d  )
221      !
222      !                                   ! depth
223      CALL iom_get( inum, jpdom_data, 'gdept_0', pdept  )
224      CALL iom_get( inum, jpdom_data, 'gdepw_0', pdepw  )
225!      CALL iom_get( inum, jpdom_data, 'gde3w_0', pde3w )
226      !
227      !                                   ! vertical scale factors
228      CALL iom_get( inum, jpdom_data, 'e3t_0'  , pe3t  )
229      CALL iom_get( inum, jpdom_data, 'e3u_0'  , pe3u  )
230      CALL iom_get( inum, jpdom_data, 'e3v_0'  , pe3v  )
231      CALL iom_get( inum, jpdom_data, 'e3f_0'  , pe3f  )
232      CALL iom_get( inum, jpdom_data, 'e3w_0'  , pe3w  )
233      CALL iom_get( inum, jpdom_data, 'e3uw_0' , pe3uw )
234      CALL iom_get( inum, jpdom_data, 'e3vw_0' , pe3vw )
235
236      !                                   ! ocean top and bottom level
237      CALL iom_get( inum, jpdom_data, 'bottom_level' , z2d    )  ! nb of ocean T-points
238      k_bot(:,:) = INT( z2d(:,:) )
239      CALL iom_get( inum, jpdom_data, 'top_level'    , z2d     )   ! nb of ocean T-points (ISF)
240      k_top(:,:) = INT( z2d(:,:) )
241      !
242      CALL iom_close( inum )
243      !
244   END SUBROUTINE zgr_read
245
246
247   SUBROUTINE zgr_top_bot( k_top, k_bot )
248      !!----------------------------------------------------------------------
249      !!                    ***  ROUTINE zgr_top_bot  ***
250      !!
251      !! ** Purpose :   defines the vertical index of ocean bottom (mbk. arrays)
252      !!
253      !! ** Method  :   computes from k_top and k_bot with a minimum value of 1 over land
254      !!
255      !! ** Action  :   mikt, miku, mikv :   vertical indices of the shallowest
256      !!                                     ocean level at t-, u- & v-points
257      !!                                     (min value = 1)
258      !! ** Action  :   mbkt, mbku, mbkv :   vertical indices of the deeptest
259      !!                                     ocean level at t-, u- & v-points
260      !!                                     (min value = 1 over land)
261      !!----------------------------------------------------------------------
262      INTEGER , DIMENSION(:,:), INTENT(in) ::   k_top, k_bot   ! top & bottom ocean level indices
263      !
264      INTEGER ::   ji, jj   ! dummy loop indices
265      REAL(wp), POINTER, DIMENSION(:,:) ::  zk
266      !!----------------------------------------------------------------------
267      !
268      IF( nn_timing == 1 )  CALL timing_start('zgr_bot_level')
269      !
270      CALL wrk_alloc( jpi,jpj,   zk )
271      !
272      IF(lwp) WRITE(numout,*)
273      IF(lwp) WRITE(numout,*) '    zgr_top_bot : ocean top and bottom k-index of T-, U-, V- and W-levels '
274      IF(lwp) WRITE(numout,*) '    ~~~~~~~~~~~'
275      !
276      mikt(:,:) = MAX( k_top(:,:) , 1 )    ! top    ocean k-index of T-level (=1 over land)
277      !
278      mbkt(:,:) = MAX( k_bot(:,:) , 1 )    ! bottom ocean k-index of T-level (=1 over land)
279 
280      !                                    ! N.B.  top     k-index of W-level = mikt
281      !                                    !       bottom  k-index of W-level = mbkt+1
282      DO jj = 1, jpjm1
283         DO ji = 1, jpim1
284            miku(ji,jj) = MAX(  mikt(ji+1,jj  ) , mikt(ji,jj)  )
285            mikv(ji,jj) = MAX(  mikt(ji  ,jj+1) , mikt(ji,jj)  )
286            mikf(ji,jj) = MAX(  mikt(ji  ,jj+1) , mikt(ji,jj), mikt(ji+1,jj  ), mikt(ji+1,jj+1)  )
287            !
288            mbku(ji,jj) = MIN(  mbkt(ji+1,jj  ) , mbkt(ji,jj)  )
289            mbkv(ji,jj) = MIN(  mbkt(ji  ,jj+1) , mbkt(ji,jj)  )
290         END DO
291      END DO
292      ! converte into REAL to use lbc_lnk ; impose a min value of 1 as a zero can be set in lbclnk
293      zk(:,:) = REAL( miku(:,:), wp )   ;   CALL lbc_lnk( zk, 'U', 1. )   ;   miku(:,:) = MAX( INT( zk(:,:) ), 1 )
294      zk(:,:) = REAL( mikv(:,:), wp )   ;   CALL lbc_lnk( zk, 'V', 1. )   ;   mikv(:,:) = MAX( INT( zk(:,:) ), 1 )
295      zk(:,:) = REAL( mikf(:,:), wp )   ;   CALL lbc_lnk( zk, 'F', 1. )   ;   mikf(:,:) = MAX( INT( zk(:,:) ), 1 )
296      !
297      zk(:,:) = REAL( mbku(:,:), wp )   ;   CALL lbc_lnk( zk, 'U', 1. )   ;   mbku(:,:) = MAX( INT( zk(:,:) ), 1 )
298      zk(:,:) = REAL( mbkv(:,:), wp )   ;   CALL lbc_lnk( zk, 'V', 1. )   ;   mbkv(:,:) = MAX( INT( zk(:,:) ), 1 )
299      !
300      CALL wrk_dealloc( jpi,jpj,   zk )
301      !
302      IF( nn_timing == 1 )  CALL timing_stop('zgr_top_level')
303      !
304   END SUBROUTINE zgr_top_bot
305
306   !!======================================================================
307END MODULE domzgr
Note: See TracBrowser for help on using the repository browser.