New URL for NEMO forge!   http://forge.nemo-ocean.eu

Since March 2022 along with NEMO 4.2 release, the code development moved to a self-hosted GitLab.
This present forge is now archived and remained online for history.
domzgr.F90 in branches/2016/dev_r6409_SIMPLIF_2_usrdef/NEMOGCM/NEMO/OPA_SRC/DOM – NEMO

source: branches/2016/dev_r6409_SIMPLIF_2_usrdef/NEMOGCM/NEMO/OPA_SRC/DOM/domzgr.F90 @ 7188

Last change on this file since 7188 was 7188, checked in by gm, 7 years ago

#1692 - branch SIMPLIF_2_usrdef: e3.=dk[dep.] (discret derivative)
  • Property svn:keywords set to Id
File size: 18.3 KB
Line 
1MODULE domzgr
2   !!==============================================================================
3   !!                       ***  MODULE domzgr   ***
4   !! Ocean domain : definition of the vertical coordinate system
5   !!==============================================================================
6   !! History :  OPA  ! 1995-12  (G. Madec)  Original code : s vertical coordinate
7   !!                 ! 1997-07  (G. Madec)  lbc_lnk call
8   !!                 ! 1997-04  (J.-O. Beismann)
9   !!            8.5  ! 2002-09  (A. Bozec, G. Madec)  F90: Free form and module
10   !!             -   ! 2002-09  (A. de Miranda)  rigid-lid + islands
11   !!  NEMO      1.0  ! 2003-08  (G. Madec)  F90: Free form and module
12   !!             -   ! 2005-10  (A. Beckmann)  modifications for hybrid s-ccordinates & new stretching function
13   !!            2.0  ! 2006-04  (R. Benshila, G. Madec)  add zgr_zco
14   !!            3.0  ! 2008-06  (G. Madec)  insertion of domzgr_zps.h90 & conding style
15   !!            3.2  ! 2009-07  (R. Benshila) Suppression of rigid-lid option
16   !!            3.3  ! 2010-11  (G. Madec) add mbk. arrays associated to the deepest ocean level
17   !!            3.4  ! 2012-08  (J. Siddorn) added Siddorn and Furner stretching function
18   !!            3.4  ! 2012-12  (R. Bourdalle-Badie and G. Reffray)  modify C1D case 
19   !!            3.6  ! 2014-11  (P. Mathiot and C. Harris) add ice shelf capabilitye 
20   !!            3.?  ! 2015-11  (H. Liu) Modifications for Wetting/Drying
21   !!----------------------------------------------------------------------
22
23   !!----------------------------------------------------------------------
24   !!   dom_zgr       : read or set the ocean vertical coordinate system
25   !!   zgr_read      : read the vertical domain coordinate and mask in domain_cfg file
26   !!   zgr_top_bot   : ocean top and bottom level for t-, u, and v-points with 1 as minimum value
27   !!---------------------------------------------------------------------
28   USE oce            ! ocean variables
29   USE dom_oce        ! ocean domain
30   USE usrdef_zgr     ! user defined vertical coordinate system
31   USE depth_e3       ! depth <=> e3
32   !
33   USE in_out_manager ! I/O manager
34   USE iom            ! I/O library
35   USE lbclnk         ! ocean lateral boundary conditions (or mpp link)
36   USE lib_mpp        ! distributed memory computing library
37   USE wrk_nemo       ! Memory allocation
38   USE timing         ! Timing
39
40   IMPLICIT NONE
41   PRIVATE
42
43   PUBLIC   dom_zgr        ! called by dom_init.F90
44
45  !! * Substitutions
46#  include "vectopt_loop_substitute.h90"
47   !!----------------------------------------------------------------------
48   !! NEMO/OPA 3.3.1 , NEMO Consortium (2011)
49   !! $Id$
50   !! Software governed by the CeCILL licence     (NEMOGCM/NEMO_CeCILL.txt)
51   !!----------------------------------------------------------------------
52CONTAINS       
53
54   SUBROUTINE dom_zgr( k_top, k_bot )
55      !!----------------------------------------------------------------------
56      !!                ***  ROUTINE dom_zgr  ***
57      !!                   
58      !! ** Purpose :   set the depth of model levels and the resulting
59      !!              vertical scale factors.
60      !!
61      !! ** Method  : - reference 1D vertical coordinate (gdep._1d, e3._1d)
62      !!              - read/set ocean depth and ocean levels (bathy, mbathy)
63      !!              - vertical coordinate (gdep., e3.) depending on the
64      !!                coordinate chosen :
65      !!                   ln_zco=T   z-coordinate   
66      !!                   ln_zps=T   z-coordinate with partial steps
67      !!                   ln_zco=T   s-coordinate
68      !!
69      !! ** Action  :   define gdep., e3., mbathy and bathy
70      !!----------------------------------------------------------------------
71      INTEGER, DIMENSION(:,:), INTENT(out) ::   k_top, k_bot   ! ocean first and last level indices
72      !
73      INTEGER  ::   jk                  ! dummy loop index
74      INTEGER  ::   ioptio, ibat, ios   ! local integer
75      REAL(wp) ::   zrefdep             ! depth of the reference level (~10m)
76      !!----------------------------------------------------------------------
77      !
78      IF( nn_timing == 1 )   CALL timing_start('dom_zgr')
79      !
80      IF(lwp) THEN                     ! Control print
81         WRITE(numout,*)
82         WRITE(numout,*) 'dom_zgr : vertical coordinate'
83         WRITE(numout,*) '~~~~~~~'
84      ENDIF
85
86      IF( ln_linssh .AND. lwp) WRITE(numout,*) '   linear free surface: the vertical mesh does not change in time'
87
88
89      IF( ln_read_cfg ) THEN        !==  read in mesh_mask.nc file  ==!
90         IF(lwp) WRITE(numout,*)
91         IF(lwp) WRITE(numout,*) '          Read vertical mesh in "domain_cfg" file'
92         !
93         CALL zgr_read   ( ln_zco  , ln_zps  , ln_sco, ln_isfcav,   & 
94            &              gdept_1d, gdepw_1d, e3t_1d, e3w_1d   ,   &    ! 1D gridpoints depth
95            &              gdept_0 , gdepw_0                    ,   &    ! gridpoints depth
96            &              e3t_0   , e3u_0   , e3v_0 , e3f_0    ,   &    ! vertical scale factors
97            &              e3w_0   , e3uw_0  , e3vw_0           ,   &    ! vertical scale factors
98            &              k_top   , k_bot            )                  ! 1st & last ocean level
99         !
100      ELSE                          !==  User defined configuration  ==!
101         IF(lwp) WRITE(numout,*)
102         IF(lwp) WRITE(numout,*) '          User defined vertical mesh (usr_def_zgr)'
103         !
104         CALL usr_def_zgr( ln_zco  , ln_zps  , ln_sco, ln_isfcav,   & 
105            &              gdept_1d, gdepw_1d, e3t_1d, e3w_1d   ,   &    ! 1D gridpoints depth
106            &              gdept_0 , gdepw_0                    ,   &    ! gridpoints depth
107            &              e3t_0   , e3u_0   , e3v_0 , e3f_0    ,   &    ! vertical scale factors
108            &              e3w_0   , e3uw_0  , e3vw_0           ,   &    ! vertical scale factors
109            &              k_top   , k_bot            )                  ! 1st & last ocean level
110         !
111      ENDIF
112      !
113!!gm to be remove when removing the OLD definition of e3 scale factors so that gde3w disappears
114      ! Compute gde3w_0 (vertical sum of e3w)
115      gde3w_0(:,:,1) = 0.5_wp * e3w_0(:,:,1)
116      DO jk = 2, jpk
117         gde3w_0(:,:,jk) = gde3w_0(:,:,jk-1) + e3w_0(:,:,jk)
118      END DO
119      !
120      IF(lwp) THEN                     ! Control print
121         WRITE(numout,*)
122         WRITE(numout,*) '   Type of vertical coordinate (read in domain_cfg.nc or set through user defined routines) :'
123         WRITE(numout,*) '      z-coordinate - full steps      ln_zco    = ', ln_zco
124         WRITE(numout,*) '      z-coordinate - partial steps   ln_zps    = ', ln_zps
125         WRITE(numout,*) '      s- or hybrid z-s-coordinate    ln_sco    = ', ln_sco
126         WRITE(numout,*) '      ice shelf cavities             ln_isfcav = ', ln_isfcav
127      ENDIF
128
129      ioptio = 0                       ! Check Vertical coordinate options
130      IF( ln_zco      )   ioptio = ioptio + 1
131      IF( ln_zps      )   ioptio = ioptio + 1
132      IF( ln_sco      )   ioptio = ioptio + 1
133      IF( ioptio /= 1 )   CALL ctl_stop( ' none or several vertical coordinate options used' )
134
135
136      !                                ! top/bottom ocean level indices for t-, u- and v-points (f-point also for top)
137      CALL zgr_top_bot( k_top, k_bot )      ! with a minimum value set to 1
138     
139
140      !                                ! deepest/shallowest W level Above/Below ~10m
141!!gm BUG in s-coordinate this does not work!
142      zrefdep = 10._wp - 0.1_wp * MINVAL( e3w_1d )                   ! ref. depth with tolerance (10% of minimum layer thickness)
143      nlb10 = MINLOC( gdepw_1d, mask = gdepw_1d > zrefdep, dim = 1 ) ! shallowest W level Below ~10m
144      nla10 = nlb10 - 1                                              ! deepest    W level Above ~10m
145!!gm end bug
146      !
147      !
148      IF( nprint == 1 .AND. lwp )   THEN
149         WRITE(numout,*) ' MIN val k_top   ', MINVAL(   k_top(:,:) ), ' MAX ', MAXVAL( k_top(:,:) )
150         WRITE(numout,*) ' MIN val k_bot   ', MINVAL(   k_bot(:,:) ), ' MAX ', MAXVAL( k_bot(:,:) )
151         WRITE(numout,*) ' MIN val depth t ', MINVAL( gdept_0(:,:,:) ),   &
152            &                          ' w ', MINVAL( gdepw_0(:,:,:) ), '3w ', MINVAL( gde3w_0(:,:,:) )
153         WRITE(numout,*) ' MIN val e3    t ', MINVAL(   e3t_0(:,:,:) ), ' f ', MINVAL(   e3f_0(:,:,:) ),  &
154            &                          ' u ', MINVAL(   e3u_0(:,:,:) ), ' u ', MINVAL(   e3v_0(:,:,:) ),  &
155            &                          ' uw', MINVAL(  e3uw_0(:,:,:) ), ' vw', MINVAL(  e3vw_0(:,:,:)),   &
156            &                          ' w ', MINVAL(   e3w_0(:,:,:) )
157
158         WRITE(numout,*) ' MAX val depth t ', MAXVAL( gdept_0(:,:,:) ),   &
159            &                          ' w ', MAXVAL( gdepw_0(:,:,:) ), '3w ', MAXVAL( gde3w_0(:,:,:) )
160         WRITE(numout,*) ' MAX val e3    t ', MAXVAL(   e3t_0(:,:,:) ), ' f ', MAXVAL(   e3f_0(:,:,:) ),  &
161            &                          ' u ', MAXVAL(   e3u_0(:,:,:) ), ' u ', MAXVAL(   e3v_0(:,:,:) ),  &
162            &                          ' uw', MAXVAL(  e3uw_0(:,:,:) ), ' vw', MAXVAL(  e3vw_0(:,:,:) ),  &
163            &                          ' w ', MAXVAL(   e3w_0(:,:,:) )
164      ENDIF
165      !
166      IF( nn_timing == 1 )  CALL timing_stop('dom_zgr')
167      !
168   END SUBROUTINE dom_zgr
169
170
171   SUBROUTINE zgr_read( ld_zco  , ld_zps  , ld_sco  , ld_isfcav,   &   ! type of vertical coordinate
172      &                 pdept_1d, pdepw_1d, pe3t_1d , pe3w_1d  ,   &   ! 1D reference vertical coordinate
173      &                 pdept , pdepw ,                            &   ! 3D t & w-points depth
174      &                 pe3t  , pe3u  , pe3v   , pe3f ,            &   ! vertical scale factors
175      &                 pe3w  , pe3uw , pe3vw         ,            &   !     -      -      -
176      &                 k_top  , k_bot    )                            ! top & bottom ocean level
177      !!---------------------------------------------------------------------
178      !!              ***  ROUTINE zgr_read  ***
179      !!
180      !! ** Purpose :   Read the vertical information in a domain_cfg.nc file
181      !!
182      !!----------------------------------------------------------------------
183      LOGICAL                   , INTENT(out) ::   ld_zco, ld_zps, ld_sco      ! vertical coordinate flags
184      LOGICAL                   , INTENT(out) ::   ld_isfcav                   ! under iceshelf cavity flag
185      REAL(wp), DIMENSION(:)    , INTENT(out) ::   pdept_1d, pdepw_1d          ! 1D grid-point depth       [m]
186      REAL(wp), DIMENSION(:)    , INTENT(out) ::   pe3t_1d , pe3w_1d           ! 1D vertical scale factors [m]
187      REAL(wp), DIMENSION(:,:,:), INTENT(out) ::   pdept, pdepw                ! grid-point depth          [m]
188      REAL(wp), DIMENSION(:,:,:), INTENT(out) ::   pe3t , pe3u , pe3v , pe3f   ! vertical scale factors    [m]
189      REAL(wp), DIMENSION(:,:,:), INTENT(out) ::   pe3w , pe3uw, pe3vw         !    -       -      -
190      INTEGER , DIMENSION(:,:)  , INTENT(out) ::   k_top , k_bot               ! first & last ocean level
191      !
192      INTEGER  ::   jk     ! dummy loop index
193      INTEGER  ::   inum   ! local logical unit
194      REAL(WP) ::   z_zco, z_zps, z_sco, z_cav
195      REAL(wp), DIMENSION(jpi,jpj) ::   z2d   ! 2D workspace
196      !!----------------------------------------------------------------------
197      !
198      IF(lwp) THEN
199         WRITE(numout,*)
200         WRITE(numout,*) '   zgr_read : read the vertical coordinates in "domain_cfg.nc" file'
201         WRITE(numout,*) '   ~~~~~~~~      jpiglo = ', jpiglo, ' jpjglo = ', jpjglo, ' jpkglo = ', jpkglo
202      ENDIF
203      !
204      CALL iom_open( 'domain_cfg', inum )
205      !
206      !                                   ! type of vertical coordinate
207      CALL iom_get( inum, 'ln_zco'   , z_zco )
208      CALL iom_get( inum, 'ln_zps'   , z_zps )
209      CALL iom_get( inum, 'ln_sco'   , z_sco )
210      IF( z_zco == 0._wp ) THEN   ;   ld_zco = .false.   ;   ELSE   ;   ld_zco = .true.   ;   ENDIF
211      IF( z_zps == 0._wp ) THEN   ;   ld_zps = .false.   ;   ELSE   ;   ld_zps = .true.   ;   ENDIF
212      IF( z_sco == 0._wp ) THEN   ;   ld_sco = .false.   ;   ELSE   ;   ld_sco = .true.   ;   ENDIF
213      !
214      !                                   ! ocean cavities under iceshelves
215      CALL iom_get( inum, 'ln_isfcav', z_cav )
216      IF( z_cav == 0._wp ) THEN   ;   ld_isfcav = .false.   ;   ELSE   ;   ld_isfcav = .true.   ;   ENDIF
217      !
218      !                                   ! reference 1D-coordinate
219      CALL iom_get( inum, jpdom_unknown, 'e3t_1d'  , pe3t_1d  )
220      CALL iom_get( inum, jpdom_unknown, 'e3w_1d'  , pe3w_1d  )
221      !
222      IF(  iom_varid( inum, 'gdept_1d', ldstop = .FALSE. ) > 0  .AND.  &
223         & iom_varid( inum, 'gdepw_1d', ldstop = .FALSE. ) > 0    ) THEN
224         CALL ctl_warn( 'zgr_read : old definition of 1d depths and scale factors used ', & 
225            &                      'depths at t- and w-points read in domain_cfg file')
226         CALL iom_get( inum, jpdom_unknown, 'gdept_1d', pdept_1d )   
227         CALL iom_get( inum, jpdom_unknown, 'gdepw_1d', pdepw_1d )
228      ELSE
229         CALL e3_to_depth( pe3t_1d, pe3w_1d, pdept_1d, pdepw_1d )
230         IF(lwp) THEN                        ! control print
231            WRITE(numout,*)
232            WRITE(numout,*) '              Reference 1D z-coordinate depth and scale factors:'
233            WRITE(numout, "(9x,' level  gdept_1d  gdepw_1d  e3t_1d   e3w_1d  ')" )
234            WRITE(numout, "(10x, i4, 4f9.2)" ) ( jk, pdept_1d(jk), pdepw_1d(jk), pe3t_1d(jk), pe3w_1d(jk), jk = 1, jpk )
235         ENDIF
236      ENDIF
237      !
238      !                                   ! 3D vertical scale factors
239      CALL iom_get( inum, jpdom_data, 'e3t_0'  , pe3t  , lrowattr=ln_use_jattr )
240      CALL iom_get( inum, jpdom_data, 'e3u_0'  , pe3u  , lrowattr=ln_use_jattr )
241      CALL iom_get( inum, jpdom_data, 'e3v_0'  , pe3v  , lrowattr=ln_use_jattr )
242      CALL iom_get( inum, jpdom_data, 'e3f_0'  , pe3f  , lrowattr=ln_use_jattr )
243      CALL iom_get( inum, jpdom_data, 'e3w_0'  , pe3w  , lrowattr=ln_use_jattr )
244      CALL iom_get( inum, jpdom_data, 'e3uw_0' , pe3uw , lrowattr=ln_use_jattr )
245      CALL iom_get( inum, jpdom_data, 'e3vw_0' , pe3vw , lrowattr=ln_use_jattr )
246      !
247      !                                   ! 3D depths
248      IF(  iom_varid( inum, 'gdept_0', ldstop = .FALSE. ) > 0  .AND.  &
249         & iom_varid( inum, 'gdepw_0', ldstop = .FALSE. ) > 0    ) THEN
250         CALL ctl_warn( 'zgr_read : old definition of depths and scale factors used ', & 
251            &                      'depths at t- and w-points read in domain_cfg file')
252         CALL iom_get( inum, jpdom_data, 'gdept_0' , pdept , lrowattr=ln_use_jattr )
253         CALL iom_get( inum, jpdom_data, 'gdepw_0' , pdepw , lrowattr=ln_use_jattr )
254      ELSE
255         CALL e3_to_depth( pe3t, pe3w, pdept, pdepw )
256      ENDIF
257      !
258      !                                   ! ocean top and bottom level
259      CALL iom_get( inum, jpdom_data, 'bottom_level' , z2d  , lrowattr=ln_use_jattr )  ! nb of ocean T-points
260      k_bot(:,:) = INT( z2d(:,:) )
261      CALL iom_get( inum, jpdom_data, 'top_level'    , z2d  , lrowattr=ln_use_jattr )   ! nb of ocean T-points (ISF)
262      k_top(:,:) = INT( z2d(:,:) )
263      !
264      CALL iom_close( inum )
265      !
266   END SUBROUTINE zgr_read
267
268
269   SUBROUTINE zgr_top_bot( k_top, k_bot )
270      !!----------------------------------------------------------------------
271      !!                    ***  ROUTINE zgr_top_bot  ***
272      !!
273      !! ** Purpose :   defines the vertical index of ocean bottom (mbk. arrays)
274      !!
275      !! ** Method  :   computes from k_top and k_bot with a minimum value of 1 over land
276      !!
277      !! ** Action  :   mikt, miku, mikv :   vertical indices of the shallowest
278      !!                                     ocean level at t-, u- & v-points
279      !!                                     (min value = 1)
280      !! ** Action  :   mbkt, mbku, mbkv :   vertical indices of the deeptest
281      !!                                     ocean level at t-, u- & v-points
282      !!                                     (min value = 1 over land)
283      !!----------------------------------------------------------------------
284      INTEGER , DIMENSION(:,:), INTENT(in) ::   k_top, k_bot   ! top & bottom ocean level indices
285      !
286      INTEGER ::   ji, jj   ! dummy loop indices
287      REAL(wp), POINTER, DIMENSION(:,:) ::  zk
288      !!----------------------------------------------------------------------
289      !
290      IF( nn_timing == 1 )  CALL timing_start('zgr_bot_level')
291      !
292      CALL wrk_alloc( jpi,jpj,   zk )
293      !
294      IF(lwp) WRITE(numout,*)
295      IF(lwp) WRITE(numout,*) '    zgr_top_bot : ocean top and bottom k-index of T-, U-, V- and W-levels '
296      IF(lwp) WRITE(numout,*) '    ~~~~~~~~~~~'
297      !
298      mikt(:,:) = MAX( k_top(:,:) , 1 )    ! top    ocean k-index of T-level (=1 over land)
299      !
300      mbkt(:,:) = MAX( k_bot(:,:) , 1 )    ! bottom ocean k-index of T-level (=1 over land)
301 
302      !                                    ! N.B.  top     k-index of W-level = mikt
303      !                                    !       bottom  k-index of W-level = mbkt+1
304      DO jj = 1, jpjm1
305         DO ji = 1, jpim1
306            miku(ji,jj) = MAX(  mikt(ji+1,jj  ) , mikt(ji,jj)  )
307            mikv(ji,jj) = MAX(  mikt(ji  ,jj+1) , mikt(ji,jj)  )
308            mikf(ji,jj) = MAX(  mikt(ji  ,jj+1) , mikt(ji,jj), mikt(ji+1,jj  ), mikt(ji+1,jj+1)  )
309            !
310            mbku(ji,jj) = MIN(  mbkt(ji+1,jj  ) , mbkt(ji,jj)  )
311            mbkv(ji,jj) = MIN(  mbkt(ji  ,jj+1) , mbkt(ji,jj)  )
312         END DO
313      END DO
314      ! converte into REAL to use lbc_lnk ; impose a min value of 1 as a zero can be set in lbclnk
315      zk(:,:) = REAL( miku(:,:), wp )   ;   CALL lbc_lnk( zk, 'U', 1. )   ;   miku(:,:) = MAX( INT( zk(:,:) ), 1 )
316      zk(:,:) = REAL( mikv(:,:), wp )   ;   CALL lbc_lnk( zk, 'V', 1. )   ;   mikv(:,:) = MAX( INT( zk(:,:) ), 1 )
317      zk(:,:) = REAL( mikf(:,:), wp )   ;   CALL lbc_lnk( zk, 'F', 1. )   ;   mikf(:,:) = MAX( INT( zk(:,:) ), 1 )
318      !
319      zk(:,:) = REAL( mbku(:,:), wp )   ;   CALL lbc_lnk( zk, 'U', 1. )   ;   mbku(:,:) = MAX( INT( zk(:,:) ), 1 )
320      zk(:,:) = REAL( mbkv(:,:), wp )   ;   CALL lbc_lnk( zk, 'V', 1. )   ;   mbkv(:,:) = MAX( INT( zk(:,:) ), 1 )
321      !
322      CALL wrk_dealloc( jpi,jpj,   zk )
323      !
324      IF( nn_timing == 1 )  CALL timing_stop('zgr_top_level')
325      !
326   END SUBROUTINE zgr_top_bot
327
328   !!======================================================================
329END MODULE domzgr
Note: See TracBrowser for help on using the repository browser.