| 1 | MODULE sbcmod |
|---|
| 2 | !!====================================================================== |
|---|
| 3 | !! *** MODULE sbcmod *** |
|---|
| 4 | !! Surface module : provide to the ocean its surface boundary condition |
|---|
| 5 | !!====================================================================== |
|---|
| 6 | !! History : 3.0 ! 2006-07 (G. Madec) Original code |
|---|
| 7 | !! 3.1 ! 2008-08 (S. Masson, A. Caubel, E. Maisonnave, G. Madec) coupled interface |
|---|
| 8 | !! 3.3 ! 2010-04 (M. Leclair, G. Madec) Forcing averaged over 2 time steps |
|---|
| 9 | !! 3.3 ! 2010-10 (S. Masson) add diurnal cycle |
|---|
| 10 | !! 3.3 ! 2010-09 (D. Storkey) add ice boundary conditions (BDY) |
|---|
| 11 | !! - ! 2010-11 (G. Madec) ice-ocean stress always computed at each ocean time-step |
|---|
| 12 | !! - ! 2010-10 (J. Chanut, C. Bricaud, G. Madec) add the surface pressure forcing |
|---|
| 13 | !! 3.4 ! 2011-11 (C. Harris) CICE added as an option |
|---|
| 14 | !! 3.5 ! 2012-11 (A. Coward, G. Madec) Rethink of heat, mass and salt surface fluxes |
|---|
| 15 | !! 3.6 ! 2014-11 (P. Mathiot, C. Harris) add ice shelves melting |
|---|
| 16 | !!---------------------------------------------------------------------- |
|---|
| 17 | |
|---|
| 18 | !!---------------------------------------------------------------------- |
|---|
| 19 | !! sbc_init : read namsbc namelist |
|---|
| 20 | !! sbc : surface ocean momentum, heat and freshwater boundary conditions |
|---|
| 21 | !! sbc_final : Finalize CICE ice model (if used) |
|---|
| 22 | !!---------------------------------------------------------------------- |
|---|
| 23 | USE oce ! ocean dynamics and tracers |
|---|
| 24 | USE dom_oce ! ocean space and time domain |
|---|
| 25 | USE phycst ! physical constants |
|---|
| 26 | USE sbc_oce ! Surface boundary condition: ocean fields |
|---|
| 27 | USE trc_oce ! shared ocean-passive tracers variables |
|---|
| 28 | USE sbc_ice ! Surface boundary condition: ice fields |
|---|
| 29 | USE sbcdcy ! surface boundary condition: diurnal cycle |
|---|
| 30 | USE sbcssm ! surface boundary condition: sea-surface mean variables |
|---|
| 31 | USE sbcflx ! surface boundary condition: flux formulation |
|---|
| 32 | USE sbcblk_clio ! surface boundary condition: bulk formulation : CLIO |
|---|
| 33 | USE sbcblk_core ! surface boundary condition: bulk formulation : CORE |
|---|
| 34 | USE sbcblk_mfs ! surface boundary condition: bulk formulation : MFS |
|---|
| 35 | USE sbcice_if ! surface boundary condition: ice-if sea-ice model |
|---|
| 36 | USE sbcice_lim ! surface boundary condition: LIM 3.0 sea-ice model |
|---|
| 37 | USE sbcice_lim_2 ! surface boundary condition: LIM 2.0 sea-ice model |
|---|
| 38 | USE sbcice_cice ! surface boundary condition: CICE sea-ice model |
|---|
| 39 | USE sbccpl ! surface boundary condition: coupled florulation |
|---|
| 40 | USE cpl_oasis3 ! OASIS routines for coupling |
|---|
| 41 | USE sbcssr ! surface boundary condition: sea surface restoring |
|---|
| 42 | USE sbcrnf ! surface boundary condition: runoffs |
|---|
| 43 | USE sbcisf ! surface boundary condition: ice shelf |
|---|
| 44 | USE sbcfwb ! surface boundary condition: freshwater budget |
|---|
| 45 | USE icbstp ! Icebergs |
|---|
| 46 | USE traqsr ! active tracers: light penetration |
|---|
| 47 | USE sbcwave ! Wave module |
|---|
| 48 | USE bdy_par ! Require lk_bdy |
|---|
| 49 | USE usrdef_sbc ! user defined: surface boundary condition |
|---|
| 50 | USE usrdef_closea ! user defined: closed sea |
|---|
| 51 | ! |
|---|
| 52 | USE prtctl ! Print control (prt_ctl routine) |
|---|
| 53 | USE iom ! IOM library |
|---|
| 54 | USE in_out_manager ! I/O manager |
|---|
| 55 | USE lib_mpp ! MPP library |
|---|
| 56 | USE timing ! Timing |
|---|
| 57 | |
|---|
| 58 | USE diurnal_bulk, ONLY: ln_diurnal_only ! diurnal SST diagnostic |
|---|
| 59 | |
|---|
| 60 | IMPLICIT NONE |
|---|
| 61 | PRIVATE |
|---|
| 62 | |
|---|
| 63 | PUBLIC sbc ! routine called by step.F90 |
|---|
| 64 | PUBLIC sbc_init ! routine called by opa.F90 |
|---|
| 65 | |
|---|
| 66 | INTEGER :: nsbc ! type of surface boundary condition (deduced from namsbc informations) |
|---|
| 67 | |
|---|
| 68 | !!---------------------------------------------------------------------- |
|---|
| 69 | !! NEMO/OPA 4.0 , NEMO-consortium (2016) |
|---|
| 70 | !! $Id$ |
|---|
| 71 | !! Software governed by the CeCILL licence (NEMOGCM/NEMO_CeCILL.txt) |
|---|
| 72 | !!---------------------------------------------------------------------- |
|---|
| 73 | CONTAINS |
|---|
| 74 | |
|---|
| 75 | SUBROUTINE sbc_init |
|---|
| 76 | !!--------------------------------------------------------------------- |
|---|
| 77 | !! *** ROUTINE sbc_init *** |
|---|
| 78 | !! |
|---|
| 79 | !! ** Purpose : Initialisation of the ocean surface boundary computation |
|---|
| 80 | !! |
|---|
| 81 | !! ** Method : Read the namsbc namelist and set derived parameters |
|---|
| 82 | !! Call init routines for all other SBC modules that have one |
|---|
| 83 | !! |
|---|
| 84 | !! ** Action : - read namsbc parameters |
|---|
| 85 | !! - nsbc: type of sbc |
|---|
| 86 | !!---------------------------------------------------------------------- |
|---|
| 87 | INTEGER :: icpt ! local integer |
|---|
| 88 | !! |
|---|
| 89 | NAMELIST/namsbc/ nn_fsbc , ln_usr , ln_flx, ln_blk_clio, ln_blk_core, ln_blk_mfs, & |
|---|
| 90 | & ln_cpl , ln_mixcpl, nn_components , nn_limflx , & |
|---|
| 91 | & ln_traqsr, ln_dm2dc , & |
|---|
| 92 | & nn_ice , nn_ice_embd, & |
|---|
| 93 | & ln_rnf , ln_ssr , ln_isf , nn_fwb , ln_apr_dyn, & |
|---|
| 94 | & ln_wave , & |
|---|
| 95 | & nn_lsm |
|---|
| 96 | INTEGER :: ios |
|---|
| 97 | INTEGER :: ierr, ierr0, ierr1, ierr2, ierr3, jpm |
|---|
| 98 | LOGICAL :: ll_purecpl |
|---|
| 99 | !!---------------------------------------------------------------------- |
|---|
| 100 | ! |
|---|
| 101 | IF(lwp) THEN |
|---|
| 102 | WRITE(numout,*) |
|---|
| 103 | WRITE(numout,*) 'sbc_init : surface boundary condition setting' |
|---|
| 104 | WRITE(numout,*) '~~~~~~~~ ' |
|---|
| 105 | ENDIF |
|---|
| 106 | ! |
|---|
| 107 | REWIND( numnam_ref ) ! Namelist namsbc in reference namelist : Surface boundary |
|---|
| 108 | READ ( numnam_ref, namsbc, IOSTAT = ios, ERR = 901) |
|---|
| 109 | 901 IF( ios /= 0 ) CALL ctl_nam ( ios , 'namsbc in reference namelist', lwp ) |
|---|
| 110 | ! |
|---|
| 111 | REWIND( numnam_cfg ) ! Namelist namsbc in configuration namelist : Parameters of the run |
|---|
| 112 | READ ( numnam_cfg, namsbc, IOSTAT = ios, ERR = 902 ) |
|---|
| 113 | 902 IF( ios /= 0 ) CALL ctl_nam ( ios , 'namsbc in configuration namelist', lwp ) |
|---|
| 114 | IF(lwm) WRITE( numond, namsbc ) |
|---|
| 115 | ! |
|---|
| 116 | ! ! overwrite namelist parameter using CPP key information |
|---|
| 117 | IF( Agrif_Root() ) THEN ! AGRIF zoom |
|---|
| 118 | IF( lk_lim2 ) nn_ice = 2 |
|---|
| 119 | IF( lk_lim3 ) nn_ice = 3 |
|---|
| 120 | IF( lk_cice ) nn_ice = 4 |
|---|
| 121 | ENDIF |
|---|
| 122 | ! |
|---|
| 123 | IF(lwp) THEN ! Control print |
|---|
| 124 | WRITE(numout,*) ' Namelist namsbc (partly overwritten with CPP key setting)' |
|---|
| 125 | WRITE(numout,*) ' Frequency update of sbc (and ice) nn_fsbc = ', nn_fsbc |
|---|
| 126 | WRITE(numout,*) ' Type of air-sea fluxes : ' |
|---|
| 127 | WRITE(numout,*) ' user defined formulation ln_usr = ', ln_usr |
|---|
| 128 | WRITE(numout,*) ' flux formulation ln_flx = ', ln_flx |
|---|
| 129 | WRITE(numout,*) ' CLIO bulk formulation ln_blk_clio = ', ln_blk_clio |
|---|
| 130 | WRITE(numout,*) ' CORE bulk formulation ln_blk_core = ', ln_blk_core |
|---|
| 131 | WRITE(numout,*) ' MFS bulk formulation ln_blk_mfs = ', ln_blk_mfs |
|---|
| 132 | WRITE(numout,*) ' Type of coupling (Ocean/Ice/Atmosphere) : ' |
|---|
| 133 | WRITE(numout,*) ' ocean-atmosphere coupled formulation ln_cpl = ', ln_cpl |
|---|
| 134 | WRITE(numout,*) ' forced-coupled mixed formulation ln_mixcpl = ', ln_mixcpl |
|---|
| 135 | WRITE(numout,*) ' OASIS coupling (with atm or sas) lk_oasis = ', lk_oasis |
|---|
| 136 | WRITE(numout,*) ' components of your executable nn_components = ', nn_components |
|---|
| 137 | WRITE(numout,*) ' Multicategory heat flux formulation (LIM3) nn_limflx = ', nn_limflx |
|---|
| 138 | WRITE(numout,*) ' Sea-ice : ' |
|---|
| 139 | WRITE(numout,*) ' ice management in the sbc (=0/1/2/3) nn_ice = ', nn_ice |
|---|
| 140 | WRITE(numout,*) ' ice-ocean embedded/levitating (=0/1/2) nn_ice_embd = ', nn_ice_embd |
|---|
| 141 | WRITE(numout,*) ' Misc. options of sbc : ' |
|---|
| 142 | WRITE(numout,*) ' Light penetration in temperature Eq. ln_traqsr = ', ln_traqsr |
|---|
| 143 | WRITE(numout,*) ' daily mean to diurnal cycle qsr ln_dm2dc = ', ln_dm2dc |
|---|
| 144 | WRITE(numout,*) ' Sea Surface Restoring on SST and/or SSS ln_ssr = ', ln_ssr |
|---|
| 145 | WRITE(numout,*) ' FreshWater Budget control (=0/1/2) nn_fwb = ', nn_fwb |
|---|
| 146 | WRITE(numout,*) ' Patm gradient added in ocean & ice Eqs. ln_apr_dyn = ', ln_apr_dyn |
|---|
| 147 | WRITE(numout,*) ' runoff / runoff mouths ln_rnf = ', ln_rnf |
|---|
| 148 | WRITE(numout,*) ' iceshelf formulation ln_isf = ', ln_isf |
|---|
| 149 | WRITE(numout,*) ' closed sea (=0/1) (set in namdom) nn_closea = ', nn_closea |
|---|
| 150 | WRITE(numout,*) ' nb of iterations if land-sea-mask applied nn_lsm = ', nn_lsm |
|---|
| 151 | WRITE(numout,*) ' surface wave ln_wave = ', ln_wave |
|---|
| 152 | ENDIF |
|---|
| 153 | ! |
|---|
| 154 | IF( .NOT.ln_usr ) THEN ! the model calendar needs some specificities (except in user defined case) |
|---|
| 155 | IF( MOD( rday , rdt ) /= 0. ) CALL ctl_stop( 'the time step must devide the number of second of in a day' ) |
|---|
| 156 | IF( MOD( rday , 2. ) /= 0. ) CALL ctl_stop( 'the number of second of in a day must be an even number' ) |
|---|
| 157 | IF( MOD( rdt , 2. ) /= 0. ) CALL ctl_stop( 'the time step (in second) must be an even number' ) |
|---|
| 158 | ENDIF |
|---|
| 159 | ! |
|---|
| 160 | IF(lwp) THEN |
|---|
| 161 | WRITE(numout,*) |
|---|
| 162 | SELECT CASE ( nn_limflx ) ! LIM3 Multi-category heat flux formulation |
|---|
| 163 | CASE ( -1 ) ; WRITE(numout,*) ' LIM3: use per-category fluxes (nn_limflx = -1) ' |
|---|
| 164 | CASE ( 0 ) ; WRITE(numout,*) ' LIM3: use average per-category fluxes (nn_limflx = 0) ' |
|---|
| 165 | CASE ( 1 ) ; WRITE(numout,*) ' LIM3: use average then redistribute per-category fluxes (nn_limflx = 1) ' |
|---|
| 166 | CASE ( 2 ) ; WRITE(numout,*) ' LIM3: Redistribute a single flux over categories (nn_limflx = 2) ' |
|---|
| 167 | END SELECT |
|---|
| 168 | ENDIF |
|---|
| 169 | ! |
|---|
| 170 | IF( nn_components /= jp_iam_nemo .AND. .NOT. lk_oasis ) & |
|---|
| 171 | & CALL ctl_stop( 'sbc_init : OPA-SAS coupled via OASIS, but key_oasis3 disabled' ) |
|---|
| 172 | IF( nn_components == jp_iam_opa .AND. ln_cpl ) & |
|---|
| 173 | & CALL ctl_stop( 'sbc_init : OPA-SAS coupled via OASIS, but ln_cpl = T in OPA' ) |
|---|
| 174 | IF( nn_components == jp_iam_opa .AND. ln_mixcpl ) & |
|---|
| 175 | & CALL ctl_stop( 'sbc_init : OPA-SAS coupled via OASIS, but ln_mixcpl = T in OPA' ) |
|---|
| 176 | IF( ln_cpl .AND. .NOT. lk_oasis ) & |
|---|
| 177 | & CALL ctl_stop( 'sbc_init : OASIS-coupled atmosphere model, but key_oasis3 disabled' ) |
|---|
| 178 | IF( ln_mixcpl .AND. .NOT. lk_oasis ) & |
|---|
| 179 | & CALL ctl_stop( 'the forced-coupled mixed mode (ln_mixcpl) requires the cpp key key_oasis3' ) |
|---|
| 180 | IF( ln_mixcpl .AND. .NOT. ln_cpl ) & |
|---|
| 181 | & CALL ctl_stop( 'the forced-coupled mixed mode (ln_mixcpl) requires ln_cpl = T' ) |
|---|
| 182 | IF( ln_mixcpl .AND. nn_components /= jp_iam_nemo ) & |
|---|
| 183 | & CALL ctl_stop( 'the forced-coupled mixed mode (ln_mixcpl) is not yet working with sas-opa coupling via oasis' ) |
|---|
| 184 | |
|---|
| 185 | ! ! allocate sbc arrays |
|---|
| 186 | IF( sbc_oce_alloc() /= 0 ) CALL ctl_stop( 'sbc_init : unable to allocate sbc_oce arrays' ) |
|---|
| 187 | |
|---|
| 188 | ! ! Checks: |
|---|
| 189 | IF( .NOT. ln_isf ) THEN ! variable initialisation if no ice shelf |
|---|
| 190 | IF( sbc_isf_alloc() /= 0 ) CALL ctl_stop( 'STOP', 'sbc_init : unable to allocate sbc_isf arrays' ) |
|---|
| 191 | fwfisf (:,:) = 0.0_wp ; fwfisf_b (:,:) = 0.0_wp |
|---|
| 192 | risf_tsc(:,:,:) = 0.0_wp ; risf_tsc_b(:,:,:) = 0.0_wp |
|---|
| 193 | END IF |
|---|
| 194 | IF( nn_ice == 0 .AND. nn_components /= jp_iam_opa ) fr_i(:,:) = 0._wp ! no ice in the domain, ice fraction is always zero |
|---|
| 195 | |
|---|
| 196 | sfx(:,:) = 0._wp ! the salt flux due to freezing/melting will be computed (i.e. will be non-zero) |
|---|
| 197 | ! only if sea-ice is present |
|---|
| 198 | |
|---|
| 199 | fmmflx(:,:) = 0._wp ! freezing-melting array initialisation |
|---|
| 200 | |
|---|
| 201 | taum(:,:) = 0._wp ! Initialise taum for use in gls in case of reduced restart |
|---|
| 202 | |
|---|
| 203 | ! ! restartability |
|---|
| 204 | IF( ( nn_ice == 2 .OR. nn_ice ==3 ) .AND. .NOT.( ln_blk_clio .OR. ln_blk_core .OR. ln_cpl ) ) & |
|---|
| 205 | & CALL ctl_stop( 'LIM sea-ice model requires a bulk formulation or coupled configuration' ) |
|---|
| 206 | IF( nn_ice == 4 .AND. .NOT.( ln_blk_core .OR. ln_cpl ) ) & |
|---|
| 207 | & CALL ctl_stop( 'CICE sea-ice model requires ln_blk_core or ln_cpl' ) |
|---|
| 208 | IF( nn_ice == 4 .AND. lk_agrif ) & |
|---|
| 209 | & CALL ctl_stop( 'CICE sea-ice model not currently available with AGRIF' ) |
|---|
| 210 | IF( ( nn_ice == 3 .OR. nn_ice == 4 ) .AND. nn_ice_embd == 0 ) & |
|---|
| 211 | & CALL ctl_stop( 'LIM3 and CICE sea-ice models require nn_ice_embd = 1 or 2' ) |
|---|
| 212 | IF( ( nn_ice /= 3 ) .AND. ( nn_limflx >= 0 ) ) & |
|---|
| 213 | & WRITE(numout,*) 'The nn_limflx>=0 option has no effect if sea ice model is not LIM3' |
|---|
| 214 | IF( ( nn_ice == 3 ) .AND. ( ln_cpl ) .AND. ( ( nn_limflx == -1 ) .OR. ( nn_limflx == 1 ) ) ) & |
|---|
| 215 | & CALL ctl_stop( 'The chosen nn_limflx for LIM3 in coupled mode must be 0 or 2' ) |
|---|
| 216 | IF( ( nn_ice == 3 ) .AND. ( .NOT. ln_cpl ) .AND. ( nn_limflx == 2 ) ) & |
|---|
| 217 | & CALL ctl_stop( 'The chosen nn_limflx for LIM3 in forced mode cannot be 2' ) |
|---|
| 218 | |
|---|
| 219 | IF( ln_dm2dc ) nday_qsr = -1 ! initialisation flag |
|---|
| 220 | |
|---|
| 221 | IF( ln_dm2dc .AND. .NOT.( ln_flx .OR. ln_blk_core ) .AND. nn_components /= jp_iam_opa ) & |
|---|
| 222 | & CALL ctl_stop( 'diurnal cycle into qsr field from daily values requires a flux or core-bulk formulation' ) |
|---|
| 223 | |
|---|
| 224 | ! ! Choice of the Surface Boudary Condition (set nsbc) |
|---|
| 225 | ll_purecpl = ln_cpl .AND. .NOT. ln_mixcpl |
|---|
| 226 | ! |
|---|
| 227 | icpt = 0 |
|---|
| 228 | IF( ln_usr ) THEN ; nsbc = jp_usr ; icpt = icpt + 1 ; ENDIF ! user defined formulation |
|---|
| 229 | IF( ln_flx ) THEN ; nsbc = jp_flx ; icpt = icpt + 1 ; ENDIF ! flux formulation |
|---|
| 230 | IF( ln_blk_clio ) THEN ; nsbc = jp_clio ; icpt = icpt + 1 ; ENDIF ! CLIO bulk formulation |
|---|
| 231 | IF( ln_blk_core ) THEN ; nsbc = jp_core ; icpt = icpt + 1 ; ENDIF ! CORE bulk formulation |
|---|
| 232 | IF( ln_blk_mfs ) THEN ; nsbc = jp_mfs ; icpt = icpt + 1 ; ENDIF ! MFS bulk formulation |
|---|
| 233 | IF( ll_purecpl ) THEN ; nsbc = jp_purecpl ; icpt = icpt + 1 ; ENDIF ! Pure Coupled formulation |
|---|
| 234 | IF( nn_components == jp_iam_opa ) & |
|---|
| 235 | & THEN ; nsbc = jp_none ; icpt = icpt + 1 ; ENDIF ! opa coupling via SAS module |
|---|
| 236 | ! |
|---|
| 237 | IF( icpt /= 1 ) CALL ctl_stop( 'sbc_init: choose ONE and only ONE sbc option' ) |
|---|
| 238 | ! |
|---|
| 239 | IF(lwp) THEN |
|---|
| 240 | WRITE(numout,*) |
|---|
| 241 | SELECT CASE( nsbc ) |
|---|
| 242 | CASE( jp_usr ) ; WRITE(numout,*) ' user defined formulation' |
|---|
| 243 | CASE( jp_flx ) ; WRITE(numout,*) ' flux formulation' |
|---|
| 244 | CASE( jp_clio ) ; WRITE(numout,*) ' CLIO bulk formulation' |
|---|
| 245 | CASE( jp_core ) ; WRITE(numout,*) ' CORE bulk formulation' |
|---|
| 246 | CASE( jp_purecpl ) ; WRITE(numout,*) ' pure coupled formulation' |
|---|
| 247 | CASE( jp_mfs ) ; WRITE(numout,*) ' MFS Bulk formulation' |
|---|
| 248 | CASE( jp_none ) ; WRITE(numout,*) ' OPA coupled to SAS via oasis' |
|---|
| 249 | IF( ln_mixcpl ) WRITE(numout,*) ' + forced-coupled mixed formulation' |
|---|
| 250 | END SELECT |
|---|
| 251 | IF( nn_components/= jp_iam_nemo ) & |
|---|
| 252 | & WRITE(numout,*) ' + OASIS coupled SAS' |
|---|
| 253 | ENDIF |
|---|
| 254 | ! |
|---|
| 255 | IF( lk_oasis ) CALL sbc_cpl_init (nn_ice) ! OASIS initialisation. must be done before: (1) first time step |
|---|
| 256 | ! ! (2) the use of nn_fsbc |
|---|
| 257 | ! nn_fsbc initialization if OPA-SAS coupling via OASIS |
|---|
| 258 | ! sas model time step has to be declared in OASIS (mandatory) -> nn_fsbc has to be modified accordingly |
|---|
| 259 | IF( nn_components /= jp_iam_nemo ) THEN |
|---|
| 260 | IF( nn_components == jp_iam_opa ) nn_fsbc = cpl_freq('O_SFLX') / NINT(rdt) |
|---|
| 261 | IF( nn_components == jp_iam_sas ) nn_fsbc = cpl_freq('I_SFLX') / NINT(rdt) |
|---|
| 262 | ! |
|---|
| 263 | IF(lwp)THEN |
|---|
| 264 | WRITE(numout,*) |
|---|
| 265 | WRITE(numout,*)" OPA-SAS coupled via OASIS : nn_fsbc re-defined from OASIS namcouple ", nn_fsbc |
|---|
| 266 | WRITE(numout,*) |
|---|
| 267 | ENDIF |
|---|
| 268 | ENDIF |
|---|
| 269 | ! |
|---|
| 270 | IF( MOD( nitend - nit000 + 1, nn_fsbc) /= 0 .OR. & |
|---|
| 271 | MOD( nstock , nn_fsbc) /= 0 ) THEN |
|---|
| 272 | WRITE(ctmp1,*) 'experiment length (', nitend - nit000 + 1, ') or nstock (', nstock, & |
|---|
| 273 | & ' is NOT a multiple of nn_fsbc (', nn_fsbc, ')' |
|---|
| 274 | CALL ctl_stop( ctmp1, 'Impossible to properly do model restart' ) |
|---|
| 275 | ENDIF |
|---|
| 276 | ! |
|---|
| 277 | IF( MOD( rday, REAL(nn_fsbc, wp) * rdt ) /= 0 ) & |
|---|
| 278 | & CALL ctl_warn( 'nn_fsbc is NOT a multiple of the number of time steps in a day' ) |
|---|
| 279 | ! |
|---|
| 280 | IF( ln_dm2dc .AND. ( ( NINT(rday) / ( nn_fsbc * NINT(rdt) ) ) < 8 ) ) & |
|---|
| 281 | & CALL ctl_warn( 'diurnal cycle for qsr: the sampling of the diurnal cycle is too small...' ) |
|---|
| 282 | ! |
|---|
| 283 | CALL sbc_ssm_init ! Sea-surface mean fields initialisation |
|---|
| 284 | ! |
|---|
| 285 | IF( ln_ssr ) CALL sbc_ssr_init ! Sea-Surface Restoring initialisation |
|---|
| 286 | ! |
|---|
| 287 | CALL sbc_rnf_init ! Runof initialisation |
|---|
| 288 | ! |
|---|
| 289 | IF( nn_ice == 3 ) CALL sbc_lim_init ! LIM3 initialisation |
|---|
| 290 | ! |
|---|
| 291 | IF( nn_ice == 4 ) CALL cice_sbc_init( nsbc ) ! CICE initialisation |
|---|
| 292 | ! |
|---|
| 293 | END SUBROUTINE sbc_init |
|---|
| 294 | |
|---|
| 295 | |
|---|
| 296 | SUBROUTINE sbc( kt ) |
|---|
| 297 | !!--------------------------------------------------------------------- |
|---|
| 298 | !! *** ROUTINE sbc *** |
|---|
| 299 | !! |
|---|
| 300 | !! ** Purpose : provide at each time-step the ocean surface boundary |
|---|
| 301 | !! condition (momentum, heat and freshwater fluxes) |
|---|
| 302 | !! |
|---|
| 303 | !! ** Method : blah blah to be written ????????? |
|---|
| 304 | !! CAUTION : never mask the surface stress field (tke sbc) |
|---|
| 305 | !! |
|---|
| 306 | !! ** Action : - set the ocean surface boundary condition at before and now |
|---|
| 307 | !! time step, i.e. |
|---|
| 308 | !! utau_b, vtau_b, qns_b, qsr_b, emp_n, sfx_b, qrp_b, erp_b |
|---|
| 309 | !! utau , vtau , qns , qsr , emp , sfx , qrp , erp |
|---|
| 310 | !! - updte the ice fraction : fr_i |
|---|
| 311 | !!---------------------------------------------------------------------- |
|---|
| 312 | INTEGER, INTENT(in) :: kt ! ocean time step |
|---|
| 313 | !!--------------------------------------------------------------------- |
|---|
| 314 | ! |
|---|
| 315 | IF( nn_timing == 1 ) CALL timing_start('sbc') |
|---|
| 316 | ! |
|---|
| 317 | ! ! ---------------------------------------- ! |
|---|
| 318 | IF( kt /= nit000 ) THEN ! Swap of forcing fields ! |
|---|
| 319 | ! ! ---------------------------------------- ! |
|---|
| 320 | utau_b(:,:) = utau(:,:) ! Swap the ocean forcing fields |
|---|
| 321 | vtau_b(:,:) = vtau(:,:) ! (except at nit000 where before fields |
|---|
| 322 | qns_b (:,:) = qns (:,:) ! are set at the end of the routine) |
|---|
| 323 | emp_b (:,:) = emp (:,:) |
|---|
| 324 | sfx_b (:,:) = sfx (:,:) |
|---|
| 325 | ENDIF |
|---|
| 326 | ! ! ---------------------------------------- ! |
|---|
| 327 | ! ! forcing field computation ! |
|---|
| 328 | ! ! ---------------------------------------- ! |
|---|
| 329 | ! |
|---|
| 330 | IF( nn_components /= jp_iam_sas ) CALL sbc_ssm ( kt ) ! ocean sea surface variables (sst_m, sss_m, ssu_m, ssv_m) |
|---|
| 331 | ! ! averaged over nf_sbc time-step |
|---|
| 332 | IF( ln_wave ) CALL sbc_wave( kt ) ! surface waves |
|---|
| 333 | |
|---|
| 334 | |
|---|
| 335 | !== sbc formulation ==! |
|---|
| 336 | |
|---|
| 337 | SELECT CASE( nsbc ) ! Compute ocean surface boundary condition |
|---|
| 338 | ! ! (i.e. utau,vtau, qns, qsr, emp, sfx) |
|---|
| 339 | CASE( jp_usr ) ; CALL usr_def_sbc ( kt ) ! user defined formulation |
|---|
| 340 | CASE( jp_flx ) ; CALL sbc_flx ( kt ) ! flux formulation |
|---|
| 341 | CASE( jp_clio ) ; CALL sbc_blk_clio( kt ) ! bulk formulation : CLIO for the ocean |
|---|
| 342 | CASE( jp_core ) |
|---|
| 343 | IF( nn_components == jp_iam_sas ) & |
|---|
| 344 | & CALL sbc_cpl_rcv ( kt, nn_fsbc, nn_ice ) ! OPA-SAS coupling: SAS receiving fields from OPA |
|---|
| 345 | CALL sbc_blk_core( kt ) ! bulk formulation : CORE for the ocean |
|---|
| 346 | ! from oce: sea surface variables (sst_m, sss_m, ssu_m, ssv_m) |
|---|
| 347 | CASE( jp_purecpl ) ; CALL sbc_cpl_rcv ( kt, nn_fsbc, nn_ice ) ! pure coupled formulation |
|---|
| 348 | ! |
|---|
| 349 | CASE( jp_mfs ) ; CALL sbc_blk_mfs ( kt ) ! bulk formulation : MFS for the ocean |
|---|
| 350 | CASE( jp_none ) |
|---|
| 351 | IF( nn_components == jp_iam_opa ) & |
|---|
| 352 | & CALL sbc_cpl_rcv ( kt, nn_fsbc, nn_ice ) ! OPA-SAS coupling: OPA receiving fields from SAS |
|---|
| 353 | END SELECT |
|---|
| 354 | |
|---|
| 355 | IF( ln_mixcpl ) CALL sbc_cpl_rcv ( kt, nn_fsbc, nn_ice ) ! forced-coupled mixed formulation after forcing |
|---|
| 356 | |
|---|
| 357 | ! |
|---|
| 358 | ! !== Misc. Options ==! |
|---|
| 359 | ! |
|---|
| 360 | SELECT CASE( nn_ice ) ! Update heat and freshwater fluxes over sea-ice areas |
|---|
| 361 | CASE( 1 ) ; CALL sbc_ice_if ( kt ) ! Ice-cover climatology ("Ice-if" model) |
|---|
| 362 | CASE( 2 ) ; CALL sbc_ice_lim_2( kt, nsbc ) ! LIM-2 ice model |
|---|
| 363 | CASE( 3 ) ; CALL sbc_ice_lim ( kt, nsbc ) ! LIM-3 ice model |
|---|
| 364 | CASE( 4 ) ; CALL sbc_ice_cice ( kt, nsbc ) ! CICE ice model |
|---|
| 365 | END SELECT |
|---|
| 366 | |
|---|
| 367 | IF( ln_icebergs ) CALL icb_stp( kt ) ! compute icebergs |
|---|
| 368 | |
|---|
| 369 | IF( ln_isf ) CALL sbc_isf( kt ) ! compute iceshelves |
|---|
| 370 | |
|---|
| 371 | IF( ln_rnf ) CALL sbc_rnf( kt ) ! add runoffs to fresh water fluxes |
|---|
| 372 | |
|---|
| 373 | IF( ln_ssr ) CALL sbc_ssr( kt ) ! add SST/SSS damping term |
|---|
| 374 | |
|---|
| 375 | IF( nn_fwb /= 0 ) CALL sbc_fwb( kt, nn_fwb, nn_fsbc ) ! control the freshwater budget |
|---|
| 376 | |
|---|
| 377 | ! treatment of closed sea in the model domain |
|---|
| 378 | ! (update freshwater fluxes) |
|---|
| 379 | ! Should not be ran if ln_diurnal_only |
|---|
| 380 | IF( .NOT.(ln_diurnal_only) .AND. (nn_closea == 1) ) CALL sbc_clo( kt ) |
|---|
| 381 | |
|---|
| 382 | !RBbug do not understand why see ticket 667 |
|---|
| 383 | !clem: it looks like it is necessary for the north fold (in certain circumstances). Don't know why. |
|---|
| 384 | CALL lbc_lnk( emp, 'T', 1. ) |
|---|
| 385 | ! |
|---|
| 386 | IF( kt == nit000 ) THEN ! set the forcing field at nit000 - 1 ! |
|---|
| 387 | ! ! ---------------------------------------- ! |
|---|
| 388 | IF( ln_rstart .AND. & !* Restart: read in restart file |
|---|
| 389 | & iom_varid( numror, 'utau_b', ldstop = .FALSE. ) > 0 ) THEN |
|---|
| 390 | IF(lwp) WRITE(numout,*) ' nit000-1 surface forcing fields red in the restart file' |
|---|
| 391 | CALL iom_get( numror, jpdom_autoglo, 'utau_b', utau_b ) ! before i-stress (U-point) |
|---|
| 392 | CALL iom_get( numror, jpdom_autoglo, 'vtau_b', vtau_b ) ! before j-stress (V-point) |
|---|
| 393 | CALL iom_get( numror, jpdom_autoglo, 'qns_b' , qns_b ) ! before non solar heat flux (T-point) |
|---|
| 394 | ! The 3D heat content due to qsr forcing is treated in traqsr |
|---|
| 395 | ! CALL iom_get( numror, jpdom_autoglo, 'qsr_b' , qsr_b ) ! before solar heat flux (T-point) |
|---|
| 396 | CALL iom_get( numror, jpdom_autoglo, 'emp_b', emp_b ) ! before freshwater flux (T-point) |
|---|
| 397 | ! To ensure restart capability with 3.3x/3.4 restart files !! to be removed in v3.6 |
|---|
| 398 | IF( iom_varid( numror, 'sfx_b', ldstop = .FALSE. ) > 0 ) THEN |
|---|
| 399 | CALL iom_get( numror, jpdom_autoglo, 'sfx_b', sfx_b ) ! before salt flux (T-point) |
|---|
| 400 | ELSE |
|---|
| 401 | sfx_b (:,:) = sfx(:,:) |
|---|
| 402 | ENDIF |
|---|
| 403 | ELSE !* no restart: set from nit000 values |
|---|
| 404 | IF(lwp) WRITE(numout,*) ' nit000-1 surface forcing fields set to nit000' |
|---|
| 405 | utau_b(:,:) = utau(:,:) |
|---|
| 406 | vtau_b(:,:) = vtau(:,:) |
|---|
| 407 | qns_b (:,:) = qns (:,:) |
|---|
| 408 | emp_b (:,:) = emp(:,:) |
|---|
| 409 | sfx_b (:,:) = sfx(:,:) |
|---|
| 410 | ENDIF |
|---|
| 411 | ENDIF |
|---|
| 412 | ! ! ---------------------------------------- ! |
|---|
| 413 | IF( lrst_oce ) THEN ! Write in the ocean restart file ! |
|---|
| 414 | ! ! ---------------------------------------- ! |
|---|
| 415 | IF(lwp) WRITE(numout,*) |
|---|
| 416 | IF(lwp) WRITE(numout,*) 'sbc : ocean surface forcing fields written in ocean restart file ', & |
|---|
| 417 | & 'at it= ', kt,' date= ', ndastp |
|---|
| 418 | IF(lwp) WRITE(numout,*) '~~~~' |
|---|
| 419 | CALL iom_rstput( kt, nitrst, numrow, 'utau_b' , utau ) |
|---|
| 420 | CALL iom_rstput( kt, nitrst, numrow, 'vtau_b' , vtau ) |
|---|
| 421 | CALL iom_rstput( kt, nitrst, numrow, 'qns_b' , qns ) |
|---|
| 422 | ! The 3D heat content due to qsr forcing is treated in traqsr |
|---|
| 423 | ! CALL iom_rstput( kt, nitrst, numrow, 'qsr_b' , qsr ) |
|---|
| 424 | CALL iom_rstput( kt, nitrst, numrow, 'emp_b' , emp ) |
|---|
| 425 | CALL iom_rstput( kt, nitrst, numrow, 'sfx_b' , sfx ) |
|---|
| 426 | ENDIF |
|---|
| 427 | ! ! ---------------------------------------- ! |
|---|
| 428 | ! ! Outputs and control print ! |
|---|
| 429 | ! ! ---------------------------------------- ! |
|---|
| 430 | IF( MOD( kt-1, nn_fsbc ) == 0 ) THEN |
|---|
| 431 | CALL iom_put( "empmr" , emp - rnf ) ! upward water flux |
|---|
| 432 | CALL iom_put( "empbmr" , emp_b - rnf ) ! before upward water flux ( needed to recalculate the time evolution of ssh in offline ) |
|---|
| 433 | CALL iom_put( "saltflx", sfx ) ! downward salt flux |
|---|
| 434 | ! (includes virtual salt flux beneath ice |
|---|
| 435 | ! in linear free surface case) |
|---|
| 436 | CALL iom_put( "fmmflx", fmmflx ) ! Freezing-melting water flux |
|---|
| 437 | CALL iom_put( "qt" , qns + qsr ) ! total heat flux |
|---|
| 438 | CALL iom_put( "qns" , qns ) ! solar heat flux |
|---|
| 439 | CALL iom_put( "qsr" , qsr ) ! solar heat flux |
|---|
| 440 | IF( nn_ice > 0 .OR. nn_components == jp_iam_opa ) CALL iom_put( "ice_cover", fr_i ) ! ice fraction |
|---|
| 441 | CALL iom_put( "taum" , taum ) ! wind stress module |
|---|
| 442 | CALL iom_put( "wspd" , wndm ) ! wind speed module over free ocean or leads in presence of sea-ice |
|---|
| 443 | ENDIF |
|---|
| 444 | ! |
|---|
| 445 | CALL iom_put( "utau", utau ) ! i-wind stress (stress can be updated at |
|---|
| 446 | CALL iom_put( "vtau", vtau ) ! j-wind stress each time step in sea-ice) |
|---|
| 447 | ! |
|---|
| 448 | IF(ln_ctl) THEN ! print mean trends (used for debugging) |
|---|
| 449 | CALL prt_ctl(tab2d_1=fr_i , clinfo1=' fr_i - : ', mask1=tmask, ovlap=1 ) |
|---|
| 450 | CALL prt_ctl(tab2d_1=(emp-rnf + fwfisf), clinfo1=' emp-rnf - : ', mask1=tmask, ovlap=1 ) |
|---|
| 451 | CALL prt_ctl(tab2d_1=(sfx-rnf + fwfisf), clinfo1=' sfx-rnf - : ', mask1=tmask, ovlap=1 ) |
|---|
| 452 | CALL prt_ctl(tab2d_1=qns , clinfo1=' qns - : ', mask1=tmask, ovlap=1 ) |
|---|
| 453 | CALL prt_ctl(tab2d_1=qsr , clinfo1=' qsr - : ', mask1=tmask, ovlap=1 ) |
|---|
| 454 | CALL prt_ctl(tab3d_1=tmask , clinfo1=' tmask - : ', mask1=tmask, ovlap=1, kdim=jpk ) |
|---|
| 455 | CALL prt_ctl(tab3d_1=tsn(:,:,:,jp_tem), clinfo1=' sst - : ', mask1=tmask, ovlap=1, kdim=1 ) |
|---|
| 456 | CALL prt_ctl(tab3d_1=tsn(:,:,:,jp_sal), clinfo1=' sss - : ', mask1=tmask, ovlap=1, kdim=1 ) |
|---|
| 457 | CALL prt_ctl(tab2d_1=utau , clinfo1=' utau - : ', mask1=umask, & |
|---|
| 458 | & tab2d_2=vtau , clinfo2=' vtau - : ', mask2=vmask, ovlap=1 ) |
|---|
| 459 | ENDIF |
|---|
| 460 | |
|---|
| 461 | IF( kt == nitend ) CALL sbc_final ! Close down surface module if necessary |
|---|
| 462 | ! |
|---|
| 463 | IF( nn_timing == 1 ) CALL timing_stop('sbc') |
|---|
| 464 | ! |
|---|
| 465 | END SUBROUTINE sbc |
|---|
| 466 | |
|---|
| 467 | |
|---|
| 468 | SUBROUTINE sbc_final |
|---|
| 469 | !!--------------------------------------------------------------------- |
|---|
| 470 | !! *** ROUTINE sbc_final *** |
|---|
| 471 | !! |
|---|
| 472 | !! ** Purpose : Finalize CICE (if used) |
|---|
| 473 | !!--------------------------------------------------------------------- |
|---|
| 474 | ! |
|---|
| 475 | IF( nn_ice == 4 ) CALL cice_sbc_final |
|---|
| 476 | ! |
|---|
| 477 | END SUBROUTINE sbc_final |
|---|
| 478 | |
|---|
| 479 | !!====================================================================== |
|---|
| 480 | END MODULE sbcmod |
|---|
