New URL for NEMO forge!   http://forge.nemo-ocean.eu

Since March 2022 along with NEMO 4.2 release, the code development moved to a self-hosted GitLab.
This present forge is now archived and remained online for history.
dynzad.F90 in branches/2016/dev_r6519_HPC_4/NEMOGCM/NEMO/OPA_SRC/DYN – NEMO

source: branches/2016/dev_r6519_HPC_4/NEMOGCM/NEMO/OPA_SRC/DYN/dynzad.F90 @ 6748

Last change on this file since 6748 was 6748, checked in by mocavero, 8 years ago

GYRE hybrid parallelization
  • Property svn:keywords set to Id
File size: 13.4 KB
Line 
1MODULE dynzad
2   !!======================================================================
3   !!                       ***  MODULE  dynzad  ***
4   !! Ocean dynamics : vertical advection trend
5   !!======================================================================
6   !! History :  OPA  ! 1991-01  (G. Madec) Original code
7   !!            7.0  ! 1991-11  (G. Madec)
8   !!            7.5  ! 1996-01  (G. Madec) statement function for e3
9   !!   NEMO     0.5  ! 2002-07  (G. Madec) Free form, F90
10   !!----------------------------------------------------------------------
11   
12   !!----------------------------------------------------------------------
13   !!   dyn_zad       : vertical advection momentum trend
14   !!----------------------------------------------------------------------
15   USE oce            ! ocean dynamics and tracers
16   USE dom_oce        ! ocean space and time domain
17   USE sbc_oce        ! surface boundary condition: ocean
18   USE trd_oce        ! trends: ocean variables
19   USE trddyn         ! trend manager: dynamics
20   !
21   USE in_out_manager ! I/O manager
22   USE lib_mpp        ! MPP library
23   USE prtctl         ! Print control
24   USE wrk_nemo       ! Memory Allocation
25   USE timing         ! Timing
26
27   IMPLICIT NONE
28   PRIVATE
29   
30   PUBLIC   dyn_zad       ! routine called by dynadv.F90
31   PUBLIC   dyn_zad_zts   ! routine called by dynadv.F90
32
33   !! * Substitutions
34#  include "vectopt_loop_substitute.h90"
35   !!----------------------------------------------------------------------
36   !! NEMO/OPA 3.3 , NEMO Consortium (2010)
37   !! $Id$
38   !! Software governed by the CeCILL licence     (NEMOGCM/NEMO_CeCILL.txt)
39   !!----------------------------------------------------------------------
40CONTAINS
41
42   SUBROUTINE dyn_zad ( kt )
43      !!----------------------------------------------------------------------
44      !!                  ***  ROUTINE dynzad  ***
45      !!
46      !! ** Purpose :   Compute the now vertical momentum advection trend and
47      !!      add it to the general trend of momentum equation.
48      !!
49      !! ** Method  :   The now vertical advection of momentum is given by:
50      !!         w dz(u) = ua + 1/(e1e2u*e3u) mk+1[ mi(e1e2t*wn) dk(un) ]
51      !!         w dz(v) = va + 1/(e1e2v*e3v) mk+1[ mj(e1e2t*wn) dk(vn) ]
52      !!      Add this trend to the general trend (ua,va):
53      !!         (ua,va) = (ua,va) + w dz(u,v)
54      !!
55      !! ** Action  : - Update (ua,va) with the vert. momentum adv. trends
56      !!              - Send the trends to trddyn for diagnostics (l_trddyn=T)
57      !!----------------------------------------------------------------------
58      INTEGER, INTENT(in) ::   kt   ! ocean time-step inedx
59      !
60      INTEGER  ::   ji, jj, jk      ! dummy loop indices
61      REAL(wp) ::   zua, zva        ! temporary scalars
62      REAL(wp), POINTER, DIMENSION(:,:,:) ::  zwuw , zwvw
63      REAL(wp), POINTER, DIMENSION(:,:  ) ::  zww
64      REAL(wp), POINTER, DIMENSION(:,:,:) ::  ztrdu, ztrdv
65      !!----------------------------------------------------------------------
66      !
67      IF( nn_timing == 1 )  CALL timing_start('dyn_zad')
68      !
69      CALL wrk_alloc( jpi,jpj, zww ) 
70      CALL wrk_alloc( jpi,jpj,jpk, zwuw , zwvw ) 
71      !
72      IF( kt == nit000 ) THEN
73         IF(lwp)WRITE(numout,*)
74         IF(lwp)WRITE(numout,*) 'dyn_zad : arakawa advection scheme'
75      ENDIF
76
77      IF( l_trddyn )   THEN         ! Save ua and va trends
78         CALL wrk_alloc( jpi, jpj, jpk, ztrdu, ztrdv ) 
79!$OMP PARALLEL WORKSHARE
80         ztrdu(:,:,:) = ua(:,:,:) 
81         ztrdv(:,:,:) = va(:,:,:) 
82!$OMP END PARALLEL WORKSHARE
83      ENDIF
84     
85      DO jk = 2, jpkm1              ! Vertical momentum advection at level w and u- and v- vertical
86!$OMP PARALLEL DO schedule(static) private(jj, ji)
87         DO jj = 2, jpj                   ! vertical fluxes
88            DO ji = fs_2, jpi             ! vector opt.
89               zww(ji,jj) = 0.25_wp * e1e2t(ji,jj) * wn(ji,jj,jk)
90            END DO
91         END DO
92!$OMP PARALLEL DO schedule(static) private(jj, ji)
93         DO jj = 2, jpjm1                 ! vertical momentum advection at w-point
94            DO ji = fs_2, fs_jpim1        ! vector opt.
95               zwuw(ji,jj,jk) = ( zww(ji+1,jj  ) + zww(ji,jj) ) * ( un(ji,jj,jk-1) - un(ji,jj,jk) )
96               zwvw(ji,jj,jk) = ( zww(ji  ,jj+1) + zww(ji,jj) ) * ( vn(ji,jj,jk-1) - vn(ji,jj,jk) )
97            END DO 
98         END DO   
99      END DO
100      !
101      ! Surface and bottom advective fluxes set to zero
102      IF ( ln_isfcav ) THEN
103!$OMP PARALLEL DO schedule(static) private(jj, ji)
104         DO jj = 2, jpjm1
105            DO ji = fs_2, fs_jpim1           ! vector opt.
106               zwuw(ji,jj, 1:miku(ji,jj) ) = 0._wp
107               zwvw(ji,jj, 1:mikv(ji,jj) ) = 0._wp
108               zwuw(ji,jj,jpk) = 0._wp
109               zwvw(ji,jj,jpk) = 0._wp
110            END DO
111         END DO
112      ELSE
113!$OMP PARALLEL DO schedule(static) private(jj, ji)
114         DO jj = 2, jpjm1       
115            DO ji = fs_2, fs_jpim1           ! vector opt.
116               zwuw(ji,jj, 1 ) = 0._wp
117               zwvw(ji,jj, 1 ) = 0._wp
118               zwuw(ji,jj,jpk) = 0._wp
119               zwvw(ji,jj,jpk) = 0._wp
120            END DO 
121         END DO
122      END IF
123
124!$OMP PARALLEL DO schedule(static) private(jk, jj, ji, zua, zva)
125      DO jk = 1, jpkm1              ! Vertical momentum advection at u- and v-points
126         DO jj = 2, jpjm1
127            DO ji = fs_2, fs_jpim1       ! vector opt.
128               !                         ! vertical momentum advective trends
129               zua = - ( zwuw(ji,jj,jk) + zwuw(ji,jj,jk+1) ) * r1_e1e2u(ji,jj) / e3u_n(ji,jj,jk)
130               zva = - ( zwvw(ji,jj,jk) + zwvw(ji,jj,jk+1) ) * r1_e1e2v(ji,jj) / e3v_n(ji,jj,jk)
131               !                         ! add the trends to the general momentum trends
132               ua(ji,jj,jk) = ua(ji,jj,jk) + zua
133               va(ji,jj,jk) = va(ji,jj,jk) + zva
134            END DO 
135         END DO 
136      END DO
137
138      IF( l_trddyn ) THEN           ! save the vertical advection trends for diagnostic
139!$OMP PARALLEL WORKSHARE
140         ztrdu(:,:,:) = ua(:,:,:) - ztrdu(:,:,:)
141         ztrdv(:,:,:) = va(:,:,:) - ztrdv(:,:,:)
142!$OMP END PARALLEL WORKSHARE
143         CALL trd_dyn( ztrdu, ztrdv, jpdyn_zad, kt )
144         CALL wrk_dealloc( jpi, jpj, jpk, ztrdu, ztrdv ) 
145      ENDIF
146      !                             ! Control print
147      IF(ln_ctl)   CALL prt_ctl( tab3d_1=ua, clinfo1=' zad  - Ua: ', mask1=umask,   &
148         &                       tab3d_2=va, clinfo2=       ' Va: ', mask2=vmask, clinfo3='dyn' )
149      !
150      CALL wrk_dealloc( jpi,jpj, zww ) 
151      CALL wrk_dealloc( jpi,jpj,jpk, zwuw , zwvw ) 
152      !
153      IF( nn_timing == 1 )  CALL timing_stop('dyn_zad')
154      !
155   END SUBROUTINE dyn_zad
156
157
158   SUBROUTINE dyn_zad_zts ( kt )
159      !!----------------------------------------------------------------------
160      !!                  ***  ROUTINE dynzad_zts  ***
161      !!
162      !! ** Purpose :   Compute the now vertical momentum advection trend and
163      !!      add it to the general trend of momentum equation. This version
164      !!      uses sub-timesteps for improved numerical stability with small
165      !!      vertical grid sizes. This is especially relevant when using
166      !!      embedded ice with thin surface boxes.
167      !!
168      !! ** Method  :   The now vertical advection of momentum is given by:
169      !!         w dz(u) = ua + 1/(e1u*e2u*e3u) mk+1[ mi(e1t*e2t*wn) dk(un) ]
170      !!         w dz(v) = va + 1/(e1v*e2v*e3v) mk+1[ mj(e1t*e2t*wn) dk(vn) ]
171      !!      Add this trend to the general trend (ua,va):
172      !!         (ua,va) = (ua,va) + w dz(u,v)
173      !!
174      !! ** Action  : - Update (ua,va) with the vert. momentum adv. trends
175      !!              - Save the trends in (ztrdu,ztrdv) ('key_trddyn')
176      !!----------------------------------------------------------------------
177      INTEGER, INTENT(in) ::   kt   ! ocean time-step inedx
178      !
179      INTEGER  ::   ji, jj, jk, jl  ! dummy loop indices
180      INTEGER  ::   jnzts = 5       ! number of sub-timesteps for vertical advection
181      INTEGER  ::   jtb, jtn, jta   ! sub timestep pointers for leap-frog/euler forward steps
182      REAL(wp) ::   zua, zva        ! temporary scalars
183      REAL(wp) ::   zr_rdt          ! temporary scalar
184      REAL(wp) ::   z2dtzts         ! length of Euler forward sub-timestep for vertical advection
185      REAL(wp) ::   zts             ! length of sub-timestep for vertical advection
186      REAL(wp), POINTER, DIMENSION(:,:,:)   ::  zwuw , zwvw, zww
187      REAL(wp), POINTER, DIMENSION(:,:,:)   ::  ztrdu, ztrdv
188      REAL(wp), POINTER, DIMENSION(:,:,:,:) ::  zus , zvs
189      !!----------------------------------------------------------------------
190      !
191      IF( nn_timing == 1 )  CALL timing_start('dyn_zad_zts')
192      !
193      CALL wrk_alloc( jpi,jpj,jpk,     zwuw, zwvw, zww ) 
194      CALL wrk_alloc( jpi,jpj,jpk,3,   zus , zvs ) 
195      !
196      IF( kt == nit000 ) THEN
197         IF(lwp)WRITE(numout,*)
198         IF(lwp)WRITE(numout,*) 'dyn_zad_zts : arakawa advection scheme with sub-timesteps'
199      ENDIF
200
201      IF( l_trddyn )   THEN         ! Save ua and va trends
202         CALL wrk_alloc( jpi, jpj, jpk, ztrdu, ztrdv ) 
203         ztrdu(:,:,:) = ua(:,:,:) 
204         ztrdv(:,:,:) = va(:,:,:) 
205      ENDIF
206     
207      IF( neuler == 0 .AND. kt == nit000 ) THEN
208          z2dtzts =         rdt / REAL( jnzts, wp )   ! = rdt (restart with Euler time stepping)
209      ELSE
210          z2dtzts = 2._wp * rdt / REAL( jnzts, wp )   ! = 2 rdt (leapfrog)
211      ENDIF
212     
213      DO jk = 2, jpkm1                    ! Calculate and store vertical fluxes
214         DO jj = 2, jpj                   
215            DO ji = fs_2, jpi             ! vector opt.
216               zww(ji,jj,jk) = 0.25_wp * e1e2t(ji,jj) * wn(ji,jj,jk)
217            END DO
218         END DO
219      END DO
220
221      DO jj = 2, jpjm1                    ! Surface and bottom advective fluxes set to zero
222         DO ji = fs_2, fs_jpim1           ! vector opt.
223 !!gm missing ISF boundary condition
224            zwuw(ji,jj, 1 ) = 0._wp
225            zwvw(ji,jj, 1 ) = 0._wp
226            zwuw(ji,jj,jpk) = 0._wp
227            zwvw(ji,jj,jpk) = 0._wp
228         END DO 
229      END DO
230
231! Start with before values and use sub timestepping to reach after values
232
233      zus(:,:,:,1) = ub(:,:,:)
234      zvs(:,:,:,1) = vb(:,:,:)
235
236      DO jl = 1, jnzts                   ! Start of sub timestepping loop
237
238         IF( jl == 1 ) THEN              ! Euler forward to kick things off
239           jtb = 1   ;   jtn = 1   ;   jta = 2
240           zts = z2dtzts
241         ELSEIF( jl == 2 ) THEN          ! First leapfrog step
242           jtb = 1   ;   jtn = 2   ;   jta = 3
243           zts = 2._wp * z2dtzts
244         ELSE                            ! Shuffle pointers for subsequent leapfrog steps
245           jtb = MOD(jtb,3) + 1
246           jtn = MOD(jtn,3) + 1
247           jta = MOD(jta,3) + 1
248         ENDIF
249
250         DO jk = 2, jpkm1           ! Vertical momentum advection at level w and u- and v- vertical
251            DO jj = 2, jpjm1                 ! vertical momentum advection at w-point
252               DO ji = fs_2, fs_jpim1        ! vector opt.
253                  zwuw(ji,jj,jk) = ( zww(ji+1,jj  ,jk) + zww(ji,jj,jk) ) * ( zus(ji,jj,jk-1,jtn)-zus(ji,jj,jk,jtn) ) !* wumask(ji,jj,jk)
254                  zwvw(ji,jj,jk) = ( zww(ji  ,jj+1,jk) + zww(ji,jj,jk) ) * ( zvs(ji,jj,jk-1,jtn)-zvs(ji,jj,jk,jtn) ) !* wvmask(ji,jj,jk)
255               END DO 
256            END DO   
257         END DO
258         DO jk = 1, jpkm1           ! Vertical momentum advection at u- and v-points
259            DO jj = 2, jpjm1
260               DO ji = fs_2, fs_jpim1       ! vector opt.
261                  !                         ! vertical momentum advective trends
262                  zua = - ( zwuw(ji,jj,jk) + zwuw(ji,jj,jk+1) ) * r1_e1e2u(ji,jj) / e3u_n(ji,jj,jk)
263                  zva = - ( zwvw(ji,jj,jk) + zwvw(ji,jj,jk+1) ) * r1_e1e2v(ji,jj) / e3v_n(ji,jj,jk)
264                  zus(ji,jj,jk,jta) = zus(ji,jj,jk,jtb) + zua * zts
265                  zvs(ji,jj,jk,jta) = zvs(ji,jj,jk,jtb) + zva * zts
266               END DO 
267            END DO 
268         END DO
269
270      END DO      ! End of sub timestepping loop
271
272      zr_rdt = 1._wp / ( REAL( jnzts, wp ) * z2dtzts )
273      DO jk = 1, jpkm1              ! Recover trends over the outer timestep
274         DO jj = 2, jpjm1
275            DO ji = fs_2, fs_jpim1       ! vector opt.
276               !                         ! vertical momentum advective trends
277               !                         ! add the trends to the general momentum trends
278               ua(ji,jj,jk) = ua(ji,jj,jk) + ( zus(ji,jj,jk,jta) - ub(ji,jj,jk)) * zr_rdt
279               va(ji,jj,jk) = va(ji,jj,jk) + ( zvs(ji,jj,jk,jta) - vb(ji,jj,jk)) * zr_rdt
280            END DO 
281         END DO 
282      END DO
283
284      IF( l_trddyn ) THEN           ! save the vertical advection trends for diagnostic
285         ztrdu(:,:,:) = ua(:,:,:) - ztrdu(:,:,:)
286         ztrdv(:,:,:) = va(:,:,:) - ztrdv(:,:,:)
287         CALL trd_dyn( ztrdu, ztrdv, jpdyn_zad, kt )
288         CALL wrk_dealloc( jpi, jpj, jpk, ztrdu, ztrdv ) 
289      ENDIF
290      !                             ! Control print
291      IF(ln_ctl)   CALL prt_ctl( tab3d_1=ua, clinfo1=' zad  - Ua: ', mask1=umask,   &
292         &                       tab3d_2=va, clinfo2=       ' Va: ', mask2=vmask, clinfo3='dyn' )
293      !
294      CALL wrk_dealloc( jpi,jpj,jpk,     zwuw, zwvw, zww ) 
295      CALL wrk_dealloc( jpi,jpj,jpk,3,   zus , zvs ) 
296      !
297      IF( nn_timing == 1 )  CALL timing_stop('dyn_zad_zts')
298      !
299   END SUBROUTINE dyn_zad_zts
300
301   !!======================================================================
302END MODULE dynzad
Note: See TracBrowser for help on using the repository browser.