New URL for NEMO forge!   http://forge.nemo-ocean.eu

Since March 2022 along with NEMO 4.2 release, the code development moved to a self-hosted GitLab.
This present forge is now archived and remained online for history.
dynzad.F90 in branches/2016/dev_r6519_HPC_4/NEMOGCM/NEMO/OPA_SRC/DYN – NEMO

source: branches/2016/dev_r6519_HPC_4/NEMOGCM/NEMO/OPA_SRC/DYN/dynzad.F90 @ 7037

Last change on this file since 7037 was 7037, checked in by mocavero, 8 years ago

ORCA2_LIM_PISCES hybrid version update
  • Property svn:keywords set to Id
File size: 13.4 KB
Line 
1MODULE dynzad
2   !!======================================================================
3   !!                       ***  MODULE  dynzad  ***
4   !! Ocean dynamics : vertical advection trend
5   !!======================================================================
6   !! History :  OPA  ! 1991-01  (G. Madec) Original code
7   !!            7.0  ! 1991-11  (G. Madec)
8   !!            7.5  ! 1996-01  (G. Madec) statement function for e3
9   !!   NEMO     0.5  ! 2002-07  (G. Madec) Free form, F90
10   !!----------------------------------------------------------------------
11   
12   !!----------------------------------------------------------------------
13   !!   dyn_zad       : vertical advection momentum trend
14   !!----------------------------------------------------------------------
15   USE oce            ! ocean dynamics and tracers
16   USE dom_oce        ! ocean space and time domain
17   USE sbc_oce        ! surface boundary condition: ocean
18   USE trd_oce        ! trends: ocean variables
19   USE trddyn         ! trend manager: dynamics
20   !
21   USE in_out_manager ! I/O manager
22   USE lib_mpp        ! MPP library
23   USE prtctl         ! Print control
24   USE wrk_nemo       ! Memory Allocation
25   USE timing         ! Timing
26
27   IMPLICIT NONE
28   PRIVATE
29   
30   PUBLIC   dyn_zad       ! routine called by dynadv.F90
31   PUBLIC   dyn_zad_zts   ! routine called by dynadv.F90
32
33   !! * Substitutions
34#  include "vectopt_loop_substitute.h90"
35   !!----------------------------------------------------------------------
36   !! NEMO/OPA 3.3 , NEMO Consortium (2010)
37   !! $Id$
38   !! Software governed by the CeCILL licence     (NEMOGCM/NEMO_CeCILL.txt)
39   !!----------------------------------------------------------------------
40CONTAINS
41
42   SUBROUTINE dyn_zad ( kt )
43      !!----------------------------------------------------------------------
44      !!                  ***  ROUTINE dynzad  ***
45      !!
46      !! ** Purpose :   Compute the now vertical momentum advection trend and
47      !!      add it to the general trend of momentum equation.
48      !!
49      !! ** Method  :   The now vertical advection of momentum is given by:
50      !!         w dz(u) = ua + 1/(e1e2u*e3u) mk+1[ mi(e1e2t*wn) dk(un) ]
51      !!         w dz(v) = va + 1/(e1e2v*e3v) mk+1[ mj(e1e2t*wn) dk(vn) ]
52      !!      Add this trend to the general trend (ua,va):
53      !!         (ua,va) = (ua,va) + w dz(u,v)
54      !!
55      !! ** Action  : - Update (ua,va) with the vert. momentum adv. trends
56      !!              - Send the trends to trddyn for diagnostics (l_trddyn=T)
57      !!----------------------------------------------------------------------
58      INTEGER, INTENT(in) ::   kt   ! ocean time-step inedx
59      !
60      INTEGER  ::   ji, jj, jk      ! dummy loop indices
61      REAL(wp) ::   zua, zva        ! temporary scalars
62      REAL(wp), POINTER, DIMENSION(:,:,:) ::  zwuw , zwvw
63      REAL(wp), POINTER, DIMENSION(:,:  ) ::  zww
64      REAL(wp), POINTER, DIMENSION(:,:,:) ::  ztrdu, ztrdv
65      !!----------------------------------------------------------------------
66      !
67      IF( nn_timing == 1 )  CALL timing_start('dyn_zad')
68      !
69      CALL wrk_alloc( jpi,jpj, zww ) 
70      CALL wrk_alloc( jpi,jpj,jpk, zwuw , zwvw ) 
71      !
72      IF( kt == nit000 ) THEN
73         IF(lwp)WRITE(numout,*)
74         IF(lwp)WRITE(numout,*) 'dyn_zad : arakawa advection scheme'
75      ENDIF
76
77      IF( l_trddyn )   THEN         ! Save ua and va trends
78         CALL wrk_alloc( jpi, jpj, jpk, ztrdu, ztrdv ) 
79!$OMP PARALLEL WORKSHARE
80         ztrdu(:,:,:) = ua(:,:,:) 
81         ztrdv(:,:,:) = va(:,:,:) 
82!$OMP END PARALLEL WORKSHARE
83      ENDIF
84     
85!$OMP PARALLEL
86      DO jk = 2, jpkm1              ! Vertical momentum advection at level w and u- and v- vertical
87!$OMP DO schedule(static) private(jj, ji)
88         DO jj = 2, jpj                   ! vertical fluxes
89            DO ji = fs_2, jpi             ! vector opt.
90               zww(ji,jj) = 0.25_wp * e1e2t(ji,jj) * wn(ji,jj,jk)
91            END DO
92         END DO
93!$OMP DO schedule(static) private(jj, ji)
94         DO jj = 2, jpjm1                 ! vertical momentum advection at w-point
95            DO ji = fs_2, fs_jpim1        ! vector opt.
96               zwuw(ji,jj,jk) = ( zww(ji+1,jj  ) + zww(ji,jj) ) * ( un(ji,jj,jk-1) - un(ji,jj,jk) )
97               zwvw(ji,jj,jk) = ( zww(ji  ,jj+1) + zww(ji,jj) ) * ( vn(ji,jj,jk-1) - vn(ji,jj,jk) )
98            END DO 
99         END DO   
100      END DO
101!$OMP END PARALLEL
102      !
103      ! Surface and bottom advective fluxes set to zero
104      IF ( ln_isfcav ) THEN
105!$OMP PARALLEL DO schedule(static) private(jj, ji)
106         DO jj = 2, jpjm1
107            DO ji = fs_2, fs_jpim1           ! vector opt.
108               zwuw(ji,jj, 1:miku(ji,jj) ) = 0._wp
109               zwvw(ji,jj, 1:mikv(ji,jj) ) = 0._wp
110               zwuw(ji,jj,jpk) = 0._wp
111               zwvw(ji,jj,jpk) = 0._wp
112            END DO
113         END DO
114      ELSE
115!$OMP PARALLEL DO schedule(static) private(jj, ji)
116         DO jj = 2, jpjm1       
117            DO ji = fs_2, fs_jpim1           ! vector opt.
118               zwuw(ji,jj, 1 ) = 0._wp
119               zwvw(ji,jj, 1 ) = 0._wp
120               zwuw(ji,jj,jpk) = 0._wp
121               zwvw(ji,jj,jpk) = 0._wp
122            END DO 
123         END DO
124      END IF
125
126!$OMP PARALLEL DO schedule(static) private(jk, jj, ji, zua, zva)
127      DO jk = 1, jpkm1              ! Vertical momentum advection at u- and v-points
128         DO jj = 2, jpjm1
129            DO ji = fs_2, fs_jpim1       ! vector opt.
130               !                         ! vertical momentum advective trends
131               zua = - ( zwuw(ji,jj,jk) + zwuw(ji,jj,jk+1) ) * r1_e1e2u(ji,jj) / e3u_n(ji,jj,jk)
132               zva = - ( zwvw(ji,jj,jk) + zwvw(ji,jj,jk+1) ) * r1_e1e2v(ji,jj) / e3v_n(ji,jj,jk)
133               !                         ! add the trends to the general momentum trends
134               ua(ji,jj,jk) = ua(ji,jj,jk) + zua
135               va(ji,jj,jk) = va(ji,jj,jk) + zva
136            END DO 
137         END DO 
138      END DO
139
140      IF( l_trddyn ) THEN           ! save the vertical advection trends for diagnostic
141!$OMP PARALLEL WORKSHARE
142         ztrdu(:,:,:) = ua(:,:,:) - ztrdu(:,:,:)
143         ztrdv(:,:,:) = va(:,:,:) - ztrdv(:,:,:)
144!$OMP END PARALLEL WORKSHARE
145         CALL trd_dyn( ztrdu, ztrdv, jpdyn_zad, kt )
146         CALL wrk_dealloc( jpi, jpj, jpk, ztrdu, ztrdv ) 
147      ENDIF
148      !                             ! Control print
149      IF(ln_ctl)   CALL prt_ctl( tab3d_1=ua, clinfo1=' zad  - Ua: ', mask1=umask,   &
150         &                       tab3d_2=va, clinfo2=       ' Va: ', mask2=vmask, clinfo3='dyn' )
151      !
152      CALL wrk_dealloc( jpi,jpj, zww ) 
153      CALL wrk_dealloc( jpi,jpj,jpk, zwuw , zwvw ) 
154      !
155      IF( nn_timing == 1 )  CALL timing_stop('dyn_zad')
156      !
157   END SUBROUTINE dyn_zad
158
159
160   SUBROUTINE dyn_zad_zts ( kt )
161      !!----------------------------------------------------------------------
162      !!                  ***  ROUTINE dynzad_zts  ***
163      !!
164      !! ** Purpose :   Compute the now vertical momentum advection trend and
165      !!      add it to the general trend of momentum equation. This version
166      !!      uses sub-timesteps for improved numerical stability with small
167      !!      vertical grid sizes. This is especially relevant when using
168      !!      embedded ice with thin surface boxes.
169      !!
170      !! ** Method  :   The now vertical advection of momentum is given by:
171      !!         w dz(u) = ua + 1/(e1u*e2u*e3u) mk+1[ mi(e1t*e2t*wn) dk(un) ]
172      !!         w dz(v) = va + 1/(e1v*e2v*e3v) mk+1[ mj(e1t*e2t*wn) dk(vn) ]
173      !!      Add this trend to the general trend (ua,va):
174      !!         (ua,va) = (ua,va) + w dz(u,v)
175      !!
176      !! ** Action  : - Update (ua,va) with the vert. momentum adv. trends
177      !!              - Save the trends in (ztrdu,ztrdv) ('key_trddyn')
178      !!----------------------------------------------------------------------
179      INTEGER, INTENT(in) ::   kt   ! ocean time-step inedx
180      !
181      INTEGER  ::   ji, jj, jk, jl  ! dummy loop indices
182      INTEGER  ::   jnzts = 5       ! number of sub-timesteps for vertical advection
183      INTEGER  ::   jtb, jtn, jta   ! sub timestep pointers for leap-frog/euler forward steps
184      REAL(wp) ::   zua, zva        ! temporary scalars
185      REAL(wp) ::   zr_rdt          ! temporary scalar
186      REAL(wp) ::   z2dtzts         ! length of Euler forward sub-timestep for vertical advection
187      REAL(wp) ::   zts             ! length of sub-timestep for vertical advection
188      REAL(wp), POINTER, DIMENSION(:,:,:)   ::  zwuw , zwvw, zww
189      REAL(wp), POINTER, DIMENSION(:,:,:)   ::  ztrdu, ztrdv
190      REAL(wp), POINTER, DIMENSION(:,:,:,:) ::  zus , zvs
191      !!----------------------------------------------------------------------
192      !
193      IF( nn_timing == 1 )  CALL timing_start('dyn_zad_zts')
194      !
195      CALL wrk_alloc( jpi,jpj,jpk,     zwuw, zwvw, zww ) 
196      CALL wrk_alloc( jpi,jpj,jpk,3,   zus , zvs ) 
197      !
198      IF( kt == nit000 ) THEN
199         IF(lwp)WRITE(numout,*)
200         IF(lwp)WRITE(numout,*) 'dyn_zad_zts : arakawa advection scheme with sub-timesteps'
201      ENDIF
202
203      IF( l_trddyn )   THEN         ! Save ua and va trends
204         CALL wrk_alloc( jpi, jpj, jpk, ztrdu, ztrdv ) 
205         ztrdu(:,:,:) = ua(:,:,:) 
206         ztrdv(:,:,:) = va(:,:,:) 
207      ENDIF
208     
209      IF( neuler == 0 .AND. kt == nit000 ) THEN
210          z2dtzts =         rdt / REAL( jnzts, wp )   ! = rdt (restart with Euler time stepping)
211      ELSE
212          z2dtzts = 2._wp * rdt / REAL( jnzts, wp )   ! = 2 rdt (leapfrog)
213      ENDIF
214     
215      DO jk = 2, jpkm1                    ! Calculate and store vertical fluxes
216         DO jj = 2, jpj                   
217            DO ji = fs_2, jpi             ! vector opt.
218               zww(ji,jj,jk) = 0.25_wp * e1e2t(ji,jj) * wn(ji,jj,jk)
219            END DO
220         END DO
221      END DO
222
223      DO jj = 2, jpjm1                    ! Surface and bottom advective fluxes set to zero
224         DO ji = fs_2, fs_jpim1           ! vector opt.
225 !!gm missing ISF boundary condition
226            zwuw(ji,jj, 1 ) = 0._wp
227            zwvw(ji,jj, 1 ) = 0._wp
228            zwuw(ji,jj,jpk) = 0._wp
229            zwvw(ji,jj,jpk) = 0._wp
230         END DO 
231      END DO
232
233! Start with before values and use sub timestepping to reach after values
234
235      zus(:,:,:,1) = ub(:,:,:)
236      zvs(:,:,:,1) = vb(:,:,:)
237
238      DO jl = 1, jnzts                   ! Start of sub timestepping loop
239
240         IF( jl == 1 ) THEN              ! Euler forward to kick things off
241           jtb = 1   ;   jtn = 1   ;   jta = 2
242           zts = z2dtzts
243         ELSEIF( jl == 2 ) THEN          ! First leapfrog step
244           jtb = 1   ;   jtn = 2   ;   jta = 3
245           zts = 2._wp * z2dtzts
246         ELSE                            ! Shuffle pointers for subsequent leapfrog steps
247           jtb = MOD(jtb,3) + 1
248           jtn = MOD(jtn,3) + 1
249           jta = MOD(jta,3) + 1
250         ENDIF
251
252         DO jk = 2, jpkm1           ! Vertical momentum advection at level w and u- and v- vertical
253            DO jj = 2, jpjm1                 ! vertical momentum advection at w-point
254               DO ji = fs_2, fs_jpim1        ! vector opt.
255                  zwuw(ji,jj,jk) = ( zww(ji+1,jj  ,jk) + zww(ji,jj,jk) ) * ( zus(ji,jj,jk-1,jtn)-zus(ji,jj,jk,jtn) ) !* wumask(ji,jj,jk)
256                  zwvw(ji,jj,jk) = ( zww(ji  ,jj+1,jk) + zww(ji,jj,jk) ) * ( zvs(ji,jj,jk-1,jtn)-zvs(ji,jj,jk,jtn) ) !* wvmask(ji,jj,jk)
257               END DO 
258            END DO   
259         END DO
260         DO jk = 1, jpkm1           ! Vertical momentum advection at u- and v-points
261            DO jj = 2, jpjm1
262               DO ji = fs_2, fs_jpim1       ! vector opt.
263                  !                         ! vertical momentum advective trends
264                  zua = - ( zwuw(ji,jj,jk) + zwuw(ji,jj,jk+1) ) * r1_e1e2u(ji,jj) / e3u_n(ji,jj,jk)
265                  zva = - ( zwvw(ji,jj,jk) + zwvw(ji,jj,jk+1) ) * r1_e1e2v(ji,jj) / e3v_n(ji,jj,jk)
266                  zus(ji,jj,jk,jta) = zus(ji,jj,jk,jtb) + zua * zts
267                  zvs(ji,jj,jk,jta) = zvs(ji,jj,jk,jtb) + zva * zts
268               END DO 
269            END DO 
270         END DO
271
272      END DO      ! End of sub timestepping loop
273
274      zr_rdt = 1._wp / ( REAL( jnzts, wp ) * z2dtzts )
275      DO jk = 1, jpkm1              ! Recover trends over the outer timestep
276         DO jj = 2, jpjm1
277            DO ji = fs_2, fs_jpim1       ! vector opt.
278               !                         ! vertical momentum advective trends
279               !                         ! add the trends to the general momentum trends
280               ua(ji,jj,jk) = ua(ji,jj,jk) + ( zus(ji,jj,jk,jta) - ub(ji,jj,jk)) * zr_rdt
281               va(ji,jj,jk) = va(ji,jj,jk) + ( zvs(ji,jj,jk,jta) - vb(ji,jj,jk)) * zr_rdt
282            END DO 
283         END DO 
284      END DO
285
286      IF( l_trddyn ) THEN           ! save the vertical advection trends for diagnostic
287         ztrdu(:,:,:) = ua(:,:,:) - ztrdu(:,:,:)
288         ztrdv(:,:,:) = va(:,:,:) - ztrdv(:,:,:)
289         CALL trd_dyn( ztrdu, ztrdv, jpdyn_zad, kt )
290         CALL wrk_dealloc( jpi, jpj, jpk, ztrdu, ztrdv ) 
291      ENDIF
292      !                             ! Control print
293      IF(ln_ctl)   CALL prt_ctl( tab3d_1=ua, clinfo1=' zad  - Ua: ', mask1=umask,   &
294         &                       tab3d_2=va, clinfo2=       ' Va: ', mask2=vmask, clinfo3='dyn' )
295      !
296      CALL wrk_dealloc( jpi,jpj,jpk,     zwuw, zwvw, zww ) 
297      CALL wrk_dealloc( jpi,jpj,jpk,3,   zus , zvs ) 
298      !
299      IF( nn_timing == 1 )  CALL timing_stop('dyn_zad_zts')
300      !
301   END SUBROUTINE dyn_zad_zts
302
303   !!======================================================================
304END MODULE dynzad
Note: See TracBrowser for help on using the repository browser.