New URL for NEMO forge!   http://forge.nemo-ocean.eu

Since March 2022 along with NEMO 4.2 release, the code development moved to a self-hosted GitLab.
This present forge is now archived and remained online for history.
ldftra.F90 in branches/2016/dev_r6519_HPC_4/NEMOGCM/NEMO/OPA_SRC/LDF – NEMO

source: branches/2016/dev_r6519_HPC_4/NEMOGCM/NEMO/OPA_SRC/LDF/ldftra.F90 @ 7037

Last change on this file since 7037 was 7037, checked in by mocavero, 8 years ago

ORCA2_LIM_PISCES hybrid version update
  • Property svn:keywords set to Id
File size: 43.1 KB
Line 
1MODULE ldftra
2   !!======================================================================
3   !!                       ***  MODULE  ldftra  ***
4   !! Ocean physics:  lateral diffusivity coefficients
5   !!=====================================================================
6   !! History :       ! 1997-07  (G. Madec)  from inimix.F split in 2 routines
7   !!   NEMO     1.0  ! 2002-09  (G. Madec)  F90: Free form and module
8   !!            2.0  ! 2005-11  (G. Madec) 
9   !!            3.7  ! 2013-12  (F. Lemarie, G. Madec)  restructuration/simplification of aht/aeiv specification,
10   !!                 !                                  add velocity dependent coefficient and optional read in file
11   !!----------------------------------------------------------------------
12
13   !!----------------------------------------------------------------------
14   !!   ldf_tra_init : initialization, namelist read, and parameters control
15   !!   ldf_tra      : update lateral eddy diffusivity coefficients at each time step
16   !!   ldf_eiv_init : initialization of the eiv coeff. from namelist choices
17   !!   ldf_eiv      : time evolution of the eiv coefficients (function of the growth rate of baroclinic instability)
18   !!   ldf_eiv_trp  : add to the input ocean transport the contribution of the EIV parametrization
19   !!   ldf_eiv_dia  : diagnose the eddy induced velocity from the eiv streamfunction
20   !!----------------------------------------------------------------------
21   USE oce             ! ocean dynamics and tracers
22   USE dom_oce         ! ocean space and time domain
23   USE phycst          ! physical constants
24   USE ldfslp          ! lateral diffusion: slope of iso-neutral surfaces
25   USE ldfc1d_c2d      ! lateral diffusion: 1D & 2D cases
26   USE diaar5, ONLY:   lk_diaar5
27   !
28   USE trc_oce, ONLY: lk_offline ! offline flag
29   USE in_out_manager  ! I/O manager
30   USE iom             ! I/O module for ehanced bottom friction file
31   USE lib_mpp         ! distribued memory computing library
32   USE lbclnk          ! ocean lateral boundary conditions (or mpp link)
33   USE wrk_nemo        ! work arrays
34   USE timing          ! timing
35
36   IMPLICIT NONE
37   PRIVATE
38
39   PUBLIC   ldf_tra_init   ! called by nemogcm.F90
40   PUBLIC   ldf_tra        ! called by step.F90
41   PUBLIC   ldf_eiv_init   ! called by nemogcm.F90
42   PUBLIC   ldf_eiv        ! called by step.F90
43   PUBLIC   ldf_eiv_trp    ! called by traadv.F90
44   PUBLIC   ldf_eiv_dia    ! called by traldf_iso and traldf_iso_triad.F90
45   
46   !                                   !!* Namelist namtra_ldf : lateral mixing on tracers *
47   !                                    != Operator type =!
48   LOGICAL , PUBLIC ::   ln_traldf_lap       !: laplacian operator
49   LOGICAL , PUBLIC ::   ln_traldf_blp       !: bilaplacian operator
50   !                                    != Direction of action =!
51   LOGICAL , PUBLIC ::   ln_traldf_lev       !: iso-level direction
52   LOGICAL , PUBLIC ::   ln_traldf_hor       !: horizontal (geopotential) direction
53!  LOGICAL , PUBLIC ::   ln_traldf_iso       !: iso-neutral direction                    (see ldfslp)
54!  LOGICAL , PUBLIC ::   ln_traldf_triad     !: griffies triad scheme                    (see ldfslp)
55   LOGICAL , PUBLIC ::   ln_traldf_msc       !: Method of Stabilizing Correction
56!  LOGICAL , PUBLIC ::   ln_triad_iso        !: pure horizontal mixing in ML             (see ldfslp)
57!  LOGICAL , PUBLIC ::   ln_botmix_triad     !: mixing on bottom                         (see ldfslp)
58!  REAL(wp), PUBLIC ::   rn_sw_triad         !: =1/0 switching triad / all 4 triads used (see ldfslp)
59!  REAL(wp), PUBLIC ::   rn_slpmax           !: slope limit                              (see ldfslp)
60   !                                    !=  Coefficients =!
61   INTEGER , PUBLIC ::   nn_aht_ijk_t        !: choice of time & space variations of the lateral eddy diffusivity coef.
62   REAL(wp), PUBLIC ::   rn_aht_0            !:   laplacian lateral eddy diffusivity [m2/s]
63   REAL(wp), PUBLIC ::   rn_bht_0            !: bilaplacian lateral eddy diffusivity [m4/s]
64
65   !                                   !!* Namelist namtra_ldfeiv : eddy induced velocity param. *
66   !                                    != Use/diagnose eiv =!
67   LOGICAL , PUBLIC ::   ln_ldfeiv           !: eddy induced velocity flag
68   LOGICAL , PUBLIC ::   ln_ldfeiv_dia       !: diagnose & output eiv streamfunction and velocity (IOM)
69   !                                    != Coefficients =!
70   INTEGER , PUBLIC ::   nn_aei_ijk_t        !: choice of time/space variation of the eiv coeff.
71   REAL(wp), PUBLIC ::   rn_aeiv_0           !: eddy induced velocity coefficient [m2/s]
72   
73   LOGICAL , PUBLIC ::   l_ldftra_time = .FALSE.   !: flag for time variation of the lateral eddy diffusivity coef.
74   LOGICAL , PUBLIC ::   l_ldfeiv_time = .FALSE.   ! flag for time variation of the eiv coef.
75
76   REAL(wp), PUBLIC, ALLOCATABLE, SAVE, DIMENSION(:,:,:) ::   ahtu, ahtv   !: eddy diffusivity coef. at U- and V-points   [m2/s]
77   REAL(wp), PUBLIC, ALLOCATABLE, SAVE, DIMENSION(:,:,:) ::   aeiu, aeiv   !: eddy induced velocity coeff.                [m2/s]
78
79   REAL(wp) ::   r1_4  = 0.25_wp          ! =1/4
80   REAL(wp) ::   r1_12 = 1._wp / 12._wp   ! =1/12
81
82   !! * Substitutions
83#  include "vectopt_loop_substitute.h90"
84   !!----------------------------------------------------------------------
85   !! NEMO/OPA 3.7 , NEMO Consortium (2015)
86   !! $Id$
87   !! Software governed by the CeCILL licence     (NEMOGCM/NEMO_CeCILL.txt)
88   !!----------------------------------------------------------------------
89CONTAINS
90
91   SUBROUTINE ldf_tra_init
92      !!----------------------------------------------------------------------
93      !!                  ***  ROUTINE ldf_tra_init  ***
94      !!
95      !! ** Purpose :   initializations of the tracer lateral mixing coeff.
96      !!
97      !! ** Method  : * the eddy diffusivity coef. specification depends on:
98      !!
99      !!    ln_traldf_lap = T     laplacian operator
100      !!    ln_traldf_blp = T   bilaplacian operator
101      !!
102      !!    nn_aht_ijk_t  =  0 => = constant
103      !!                  !
104      !!                  = 10 => = F(z) : constant with a reduction of 1/4 with depth
105      !!                  !
106      !!                  =-20 => = F(i,j)   = shape read in 'eddy_diffusivity.nc' file
107      !!                  = 20    = F(i,j)   = F(e1,e2) or F(e1^3,e2^3) (lap or bilap case)
108      !!                  = 21    = F(i,j,t) = F(growth rate of baroclinic instability)
109      !!                  !
110      !!                  =-30 => = F(i,j,k)   = shape read in 'eddy_diffusivity.nc' file
111      !!                  = 30    = F(i,j,k)   = 2D (case 20) + decrease with depth (case 10)
112      !!                  = 31    = F(i,j,k,t) = F(local velocity) (  |u|e  /12   laplacian operator
113      !!                                                          or |u|e^3/12 bilaplacian operator )
114      !!              * initialisation of the eddy induced velocity coefficient by a call to ldf_eiv_init
115      !!           
116      !! ** action  : ahtu, ahtv initialized once for all or l_ldftra_time set to true
117      !!              aeiu, aeiv initialized once for all or l_ldfeiv_time set to true
118      !!----------------------------------------------------------------------
119      INTEGER  ::   jk                ! dummy loop indices
120      INTEGER  ::   ierr, inum, ios   ! local integer
121      REAL(wp) ::   zah0              ! local scalar
122      !
123      NAMELIST/namtra_ldf/ ln_traldf_lap, ln_traldf_blp  ,                   &   ! type of operator
124         &                 ln_traldf_lev, ln_traldf_hor  , ln_traldf_triad,  &   ! acting direction of the operator
125         &                 ln_traldf_iso, ln_traldf_msc  ,  rn_slpmax     ,  &   ! option for iso-neutral operator
126         &                 ln_triad_iso , ln_botmix_triad, rn_sw_triad    ,  &   ! option for triad operator
127         &                 rn_aht_0     , rn_bht_0       , nn_aht_ijk_t          ! lateral eddy coefficient
128      !!----------------------------------------------------------------------
129      !
130      !  Choice of lateral tracer physics
131      ! =================================
132      !
133      REWIND( numnam_ref )              ! Namelist namtra_ldf in reference namelist : Lateral physics on tracers
134      READ  ( numnam_ref, namtra_ldf, IOSTAT = ios, ERR = 901)
135901   IF( ios /= 0 ) CALL ctl_nam ( ios , 'namtra_ldf in reference namelist', lwp )
136      !
137      REWIND( numnam_cfg )              ! Namelist namtra_ldf in configuration namelist : Lateral physics on tracers
138      READ  ( numnam_cfg, namtra_ldf, IOSTAT = ios, ERR = 902 )
139902   IF( ios /= 0 ) CALL ctl_nam ( ios , 'namtra_ldf in configuration namelist', lwp )
140      IF(lwm) WRITE ( numond, namtra_ldf )
141      !
142      IF(lwp) THEN                      ! control print
143         WRITE(numout,*)
144         WRITE(numout,*) 'ldf_tra_init : lateral tracer physics'
145         WRITE(numout,*) '~~~~~~~~~~~~ '
146         WRITE(numout,*) '   Namelist namtra_ldf : lateral mixing parameters (type, direction, coefficients)'
147         !
148         WRITE(numout,*) '      type :'
149         WRITE(numout,*) '         laplacian operator                      ln_traldf_lap   = ', ln_traldf_lap
150         WRITE(numout,*) '         bilaplacian operator                    ln_traldf_blp   = ', ln_traldf_blp
151         !
152         WRITE(numout,*) '      direction of action :'
153         WRITE(numout,*) '         iso-level                               ln_traldf_lev   = ', ln_traldf_lev
154         WRITE(numout,*) '         horizontal (geopotential)               ln_traldf_hor   = ', ln_traldf_hor
155         WRITE(numout,*) '         iso-neutral Madec operator              ln_traldf_iso   = ', ln_traldf_iso
156         WRITE(numout,*) '         iso-neutral triad operator              ln_traldf_triad = ', ln_traldf_triad
157         WRITE(numout,*) '            iso-neutral (Method of Stab. Corr.)  ln_traldf_msc   = ', ln_traldf_msc
158         WRITE(numout,*) '            maximum isoppycnal slope             rn_slpmax       = ', rn_slpmax
159         WRITE(numout,*) '            pure lateral mixing in ML            ln_triad_iso    = ', ln_triad_iso
160         WRITE(numout,*) '            switching triad or not               rn_sw_triad     = ', rn_sw_triad
161         WRITE(numout,*) '            lateral mixing on bottom             ln_botmix_triad = ', ln_botmix_triad
162         !
163         WRITE(numout,*) '      coefficients :'
164         WRITE(numout,*) '         lateral eddy diffusivity   (lap case)   rn_aht_0        = ', rn_aht_0
165         WRITE(numout,*) '         lateral eddy diffusivity (bilap case)   rn_bht_0        = ', rn_bht_0
166         WRITE(numout,*) '         type of time-space variation            nn_aht_ijk_t    = ', nn_aht_ijk_t
167      ENDIF
168      !
169      !                                ! Parameter control
170      !
171      IF( .NOT.ln_traldf_lap .AND. .NOT.ln_traldf_blp ) THEN
172         IF(lwp) WRITE(numout,*) '   No diffusive operator selected. ahtu and ahtv are not allocated'
173         l_ldftra_time = .FALSE.
174         RETURN
175      ENDIF
176      !
177      IF( ln_traldf_blp .AND. ( ln_traldf_iso .OR. ln_traldf_triad) ) THEN     ! iso-neutral bilaplacian need MSC
178         IF( .NOT.ln_traldf_msc )   CALL ctl_stop( 'tra_ldf_init: iso-neutral bilaplacian requires ln_traldf_msc=.true.' )
179      ENDIF
180      !
181      !  Space/time variation of eddy coefficients
182      ! ===========================================
183      !                                               ! allocate the aht arrays
184      ALLOCATE( ahtu(jpi,jpj,jpk) , ahtv(jpi,jpj,jpk) , STAT=ierr )
185      IF( ierr /= 0 )   CALL ctl_stop( 'STOP', 'ldf_tra_init: failed to allocate arrays')
186      !
187!$OMP PARALLEL WORKSHARE
188      ahtu(:,:,jpk) = 0._wp                           ! last level always 0 
189      ahtv(:,:,jpk) = 0._wp
190!$OMP END PARALLEL WORKSHARE
191      !
192      !                                               ! value of eddy mixing coef.
193      IF    ( ln_traldf_lap ) THEN   ;   zah0 =      rn_aht_0        !   laplacian operator
194      ELSEIF( ln_traldf_blp ) THEN   ;   zah0 = ABS( rn_bht_0 )      ! bilaplacian operator
195      ENDIF
196      !
197      l_ldftra_time = .FALSE.                         ! no time variation except in case defined below
198      !
199      IF( ln_traldf_lap .OR. ln_traldf_blp ) THEN     ! only if a lateral diffusion operator is used
200         !
201         SELECT CASE(  nn_aht_ijk_t  )                   ! Specification of space time variations of ehtu, ahtv
202         !
203         CASE(   0  )      !==  constant  ==!
204            IF(lwp) WRITE(numout,*) '          tracer mixing coef. = constant = ', rn_aht_0
205!$OMP PARALLEL WORKSHARE
206            ahtu(:,:,:) = zah0 * umask(:,:,:)
207            ahtv(:,:,:) = zah0 * vmask(:,:,:)
208!$OMP END PARALLEL WORKSHARE
209            !
210         CASE(  10  )      !==  fixed profile  ==!
211            IF(lwp) WRITE(numout,*) '          tracer mixing coef. = F( depth )'
212!$OMP PARALLEL WORKSHARE
213            ahtu(:,:,1) = zah0 * umask(:,:,1)                      ! constant surface value
214            ahtv(:,:,1) = zah0 * vmask(:,:,1)
215!$OMP END PARALLEL WORKSHARE
216            CALL ldf_c1d( 'TRA', r1_4, ahtu(:,:,1), ahtv(:,:,1), ahtu, ahtv )
217            !
218         CASE ( -20 )      !== fixed horizontal shape read in file  ==!
219            IF(lwp) WRITE(numout,*) '          tracer mixing coef. = F(i,j) read in eddy_diffusivity.nc file'
220            CALL iom_open( 'eddy_diffusivity_2D.nc', inum )
221            CALL iom_get ( inum, jpdom_data, 'ahtu_2D', ahtu(:,:,1) )
222            CALL iom_get ( inum, jpdom_data, 'ahtv_2D', ahtv(:,:,1) )
223            CALL iom_close( inum )
224!$OMP PARALLEL DO schedule(static) private(jk)
225            DO jk = 2, jpkm1
226               ahtu(:,:,jk) = ahtu(:,:,1) * umask(:,:,jk)
227               ahtv(:,:,jk) = ahtv(:,:,1) * vmask(:,:,jk)
228            END DO
229            !
230         CASE(  20  )      !== fixed horizontal shape  ==!
231            IF(lwp) WRITE(numout,*) '          tracer mixing coef. = F( e1, e2 ) or F( e1^3, e2^3 ) (lap or blp case)'
232            IF( ln_traldf_lap )   CALL ldf_c2d( 'TRA', 'LAP', zah0, ahtu, ahtv )    ! surface value proportional to scale factor
233            IF( ln_traldf_blp )   CALL ldf_c2d( 'TRA', 'BLP', zah0, ahtu, ahtv )    ! surface value proportional to scale factor
234            !
235         CASE(  21  )      !==  time varying 2D field  ==!
236            IF(lwp) WRITE(numout,*) '          tracer mixing coef. = F( latitude, longitude, time )'
237            IF(lwp) WRITE(numout,*) '                              = F( growth rate of baroclinic instability )'
238            IF(lwp) WRITE(numout,*) '                              min value = 0.1 * rn_aht_0'
239            IF(lwp) WRITE(numout,*) '                              max value = rn_aht_0 (rn_aeiv_0 if nn_aei_ijk_t=21)'
240            IF(lwp) WRITE(numout,*) '                              increased to rn_aht_0 within 20N-20S'
241            !
242            l_ldftra_time = .TRUE.     ! will be calculated by call to ldf_tra routine in step.F90
243            !
244            IF( ln_traldf_blp ) THEN
245               CALL ctl_stop( 'ldf_tra_init: aht=F(growth rate of baroc. insta.) incompatible with bilaplacian operator' )
246            ENDIF
247            !
248         CASE( -30  )      !== fixed 3D shape read in file  ==!
249            IF(lwp) WRITE(numout,*) '          tracer mixing coef. = F(i,j,k) read in eddy_diffusivity.nc file'
250            CALL iom_open( 'eddy_diffusivity_3D.nc', inum )
251            CALL iom_get ( inum, jpdom_data, 'ahtu_3D', ahtu )
252            CALL iom_get ( inum, jpdom_data, 'ahtv_3D', ahtv )
253            CALL iom_close( inum )
254!$OMP PARALLEL DO schedule(static) private(jk)
255            DO jk = 1, jpkm1
256               ahtu(:,:,jk) = ahtu(:,:,jk) * umask(:,:,jk)
257               ahtv(:,:,jk) = ahtv(:,:,jk) * vmask(:,:,jk)
258            END DO
259            !
260         CASE(  30  )      !==  fixed 3D shape  ==!
261            IF(lwp) WRITE(numout,*) '          tracer mixing coef. = F( latitude, longitude, depth )'
262            IF( ln_traldf_lap )   CALL ldf_c2d( 'TRA', 'LAP', zah0, ahtu, ahtv )    ! surface value proportional to scale factor
263            IF( ln_traldf_blp )   CALL ldf_c2d( 'TRA', 'BLP', zah0, ahtu, ahtv )    ! surface value proportional to scale factor
264            !                                                    ! reduction with depth
265            CALL ldf_c1d( 'TRA', r1_4, ahtu(:,:,1), ahtv(:,:,1), ahtu, ahtv )
266            !
267         CASE(  31  )      !==  time varying 3D field  ==!
268            IF(lwp) WRITE(numout,*) '          tracer mixing coef. = F( latitude, longitude, depth , time )'
269            IF(lwp) WRITE(numout,*) '                                proportional to the velocity : |u|e/12 or |u|e^3/12'
270            !
271            l_ldftra_time = .TRUE.     ! will be calculated by call to ldf_tra routine in step.F90
272            !
273         CASE DEFAULT
274            CALL ctl_stop('ldf_tra_init: wrong choice for nn_aht_ijk_t, the type of space-time variation of aht')
275         END SELECT
276         !
277         IF( ln_traldf_blp .AND. .NOT. l_ldftra_time ) THEN
278            ahtu(:,:,:) = SQRT( ahtu(:,:,:) )
279            ahtv(:,:,:) = SQRT( ahtv(:,:,:) )
280         ENDIF
281         !
282      ENDIF
283      !
284   END SUBROUTINE ldf_tra_init
285
286
287   SUBROUTINE ldf_tra( kt )
288      !!----------------------------------------------------------------------
289      !!                  ***  ROUTINE ldf_tra  ***
290      !!
291      !! ** Purpose :   update at kt the tracer lateral mixing coeff. (aht and aeiv)
292      !!
293      !! ** Method  :   time varying eddy diffusivity coefficients:
294      !!
295      !!    nn_aei_ijk_t = 21    aeiu, aeiv = F(i,j,  t) = F(growth rate of baroclinic instability)
296      !!                                                   with a reduction to 0 in vicinity of the Equator
297      !!    nn_aht_ijk_t = 21    ahtu, ahtv = F(i,j,  t) = F(growth rate of baroclinic instability)
298      !!
299      !!                 = 31    ahtu, ahtv = F(i,j,k,t) = F(local velocity) (  |u|e  /12   laplacian operator
300      !!                                                                     or |u|e^3/12 bilaplacian operator )
301      !!
302      !! ** action  :   ahtu, ahtv   update at each time step   
303      !!                aeiu, aeiv      -       -     -    -   (if ln_ldfeiv=T)
304      !!----------------------------------------------------------------------
305      INTEGER, INTENT(in) ::   kt   ! time step
306      !
307      INTEGER  ::   ji, jj, jk   ! dummy loop indices
308      REAL(wp) ::   zaht, zaht_min, z1_f20       ! local scalar
309      !!----------------------------------------------------------------------
310      !
311      IF( nn_aei_ijk_t == 21 ) THEN       ! eddy induced velocity coefficients
312         !                                ! =F(growth rate of baroclinic instability)
313         !                                ! max value rn_aeiv_0 ; decreased to 0 within 20N-20S
314         CALL ldf_eiv( kt, rn_aeiv_0, aeiu, aeiv )
315         IF(lwp .AND. kt<=nit000+20 )   WRITE(numout,*) ' kt , ldf_eiv appel', kt
316      ENDIF
317      !
318      SELECT CASE(  nn_aht_ijk_t  )       ! Eddy diffusivity coefficients
319      !
320      CASE(  21  )       !==  time varying 2D field  ==!   = F( growth rate of baroclinic instability )
321         !                                             !   min value rn_aht_0 / 10
322         !                                             !   max value rn_aht_0 (rn_aeiv_0 if nn_aei_ijk_t=21)
323         !                                             !   increase to rn_aht_0 within 20N-20S
324         IF( nn_aei_ijk_t /= 21 ) THEN
325            CALL ldf_eiv( kt, rn_aht_0, ahtu, ahtv )
326            IF(lwp .AND. kt<=nit000+20 )   WRITE(numout,*) ' kt , ldf_eiv appel  2', kt
327         ELSE
328            ahtu(:,:,1) = aeiu(:,:,1)
329            ahtv(:,:,1) = aeiv(:,:,1)
330            IF(lwp .AND. kt<=nit000+20 )   WRITE(numout,*) ' kt , ahtu=aeiu', kt
331         ENDIF
332         !
333         z1_f20   = 1._wp / (  2._wp * omega * SIN( rad * 20._wp )  )      ! 1 / ff(20 degrees)   
334         zaht_min = 0.2_wp * rn_aht_0                                      ! minimum value for aht
335!$OMP PARALLEL
336!$OMP DO schedule(static) private(jj,ji,zaht)
337         DO jj = 1, jpj
338            DO ji = 1, jpi
339               zaht = ( 1._wp -  MIN( 1._wp , ABS( ff(ji,jj) * z1_f20 ) ) ) * ( rn_aht_0 - zaht_min )
340               ahtu(ji,jj,1) = (  MAX( zaht_min, ahtu(ji,jj,1) ) + zaht  ) * umask(ji,jj,1)     ! min value zaht_min
341               ahtv(ji,jj,1) = (  MAX( zaht_min, ahtv(ji,jj,1) ) + zaht  ) * vmask(ji,jj,1)     ! increase within 20S-20N
342            END DO
343         END DO
344!$OMP DO schedule(static) private(jk)
345         DO jk = 2, jpkm1                             ! deeper value = surface value
346            ahtu(:,:,jk) = ahtu(:,:,1) * umask(:,:,jk)
347            ahtv(:,:,jk) = ahtv(:,:,1) * vmask(:,:,jk)
348         END DO
349!$OMP END DO NOWAIT
350!$OMP END PARALLEL
351         !
352      CASE(  31  )       !==  time varying 3D field  ==!   = F( local velocity )
353         IF( ln_traldf_lap     ) THEN          !   laplacian operator |u| e /12
354!$OMP PARALLEL DO schedule(static) private(jk)
355            DO jk = 1, jpkm1
356               ahtu(:,:,jk) = ABS( ub(:,:,jk) ) * e1u(:,:) * r1_12
357               ahtv(:,:,jk) = ABS( vb(:,:,jk) ) * e2v(:,:) * r1_12
358            END DO
359         ELSEIF( ln_traldf_blp ) THEN      ! bilaplacian operator      sqrt( |u| e^3 /12 ) = sqrt( |u| e /12 ) * e
360!$OMP PARALLEL DO schedule(static) private(jk)
361            DO jk = 1, jpkm1
362               ahtu(:,:,jk) = SQRT(  ABS( ub(:,:,jk) ) * e1u(:,:) * r1_12  ) * e1u(:,:)
363               ahtv(:,:,jk) = SQRT(  ABS( vb(:,:,jk) ) * e2v(:,:) * r1_12  ) * e2v(:,:)
364            END DO
365         ENDIF
366         !
367      END SELECT
368      !
369      IF( .NOT.lk_offline ) THEN
370         CALL iom_put( "ahtu_2d", ahtu(:,:,1) )   ! surface u-eddy diffusivity coeff.
371         CALL iom_put( "ahtv_2d", ahtv(:,:,1) )   ! surface v-eddy diffusivity coeff.
372         CALL iom_put( "ahtu_3d", ahtu(:,:,:) )   ! 3D      u-eddy diffusivity coeff.
373         CALL iom_put( "ahtv_3d", ahtv(:,:,:) )   ! 3D      v-eddy diffusivity coeff.
374         !
375!!gm  : THE IF below is to be checked (comes from Seb)
376         IF( ln_ldfeiv ) THEN
377           CALL iom_put( "aeiu_2d", aeiu(:,:,1) )   ! surface u-EIV coeff.
378           CALL iom_put( "aeiv_2d", aeiv(:,:,1) )   ! surface v-EIV coeff.
379           CALL iom_put( "aeiu_3d", aeiu(:,:,:) )   ! 3D      u-EIV coeff.
380           CALL iom_put( "aeiv_3d", aeiv(:,:,:) )   ! 3D      v-EIV coeff.
381         ENDIF     
382      ENDIF
383      !
384   END SUBROUTINE ldf_tra
385
386
387   SUBROUTINE ldf_eiv_init
388      !!----------------------------------------------------------------------
389      !!                  ***  ROUTINE ldf_eiv_init  ***
390      !!
391      !! ** Purpose :   initialization of the eiv coeff. from namelist choices.
392      !!
393      !! ** Method :
394      !!
395      !! ** Action :   aeiu , aeiv   : EIV coeff. at u- & v-points
396      !!               l_ldfeiv_time : =T if EIV coefficients vary with time
397      !!----------------------------------------------------------------------
398      INTEGER  ::   jk                ! dummy loop indices
399      INTEGER  ::   ierr, inum, ios   ! local integer
400      !
401      NAMELIST/namtra_ldfeiv/ ln_ldfeiv   , ln_ldfeiv_dia,   &    ! eddy induced velocity (eiv)
402         &                    nn_aei_ijk_t, rn_aeiv_0             ! eiv  coefficient
403      !!----------------------------------------------------------------------
404      !
405      REWIND( numnam_ref )              ! Namelist namtra_ldfeiv in reference namelist : eddy induced velocity param.
406      READ  ( numnam_ref, namtra_ldfeiv, IOSTAT = ios, ERR = 901)
407901   IF( ios /= 0 ) CALL ctl_nam ( ios , 'namtra_ldfeiv in reference namelist', lwp )
408      !
409      REWIND( numnam_cfg )              ! Namelist namtra_ldfeiv in configuration namelist : eddy induced velocity param.
410      READ  ( numnam_cfg, namtra_ldfeiv, IOSTAT = ios, ERR = 902 )
411902   IF( ios /= 0 ) CALL ctl_nam ( ios , 'namtra_ldfeiv in configuration namelist', lwp )
412      IF(lwm)  WRITE ( numond, namtra_ldfeiv )
413
414      IF(lwp) THEN                      ! control print
415         WRITE(numout,*)
416         WRITE(numout,*) 'ldf_eiv_init : eddy induced velocity parametrization'
417         WRITE(numout,*) '~~~~~~~~~~~~ '
418         WRITE(numout,*) '   Namelist namtra_ldfeiv : '
419         WRITE(numout,*) '      Eddy Induced Velocity (eiv) param.      ln_ldfeiv     = ', ln_ldfeiv
420         WRITE(numout,*) '      eiv streamfunction & velocity diag.     ln_ldfeiv_dia = ', ln_ldfeiv_dia
421         WRITE(numout,*) '      eddy induced velocity coef.             rn_aeiv_0     = ', rn_aeiv_0
422         WRITE(numout,*) '      type of time-space variation            nn_aei_ijk_t  = ', nn_aei_ijk_t
423         WRITE(numout,*)
424      ENDIF
425      !
426      IF( ln_ldfeiv .AND. ln_traldf_blp )   CALL ctl_stop( 'ldf_eiv_init: eddy induced velocity ONLY with laplacian diffusivity' )
427
428      !                                 ! Parameter control
429      l_ldfeiv_time = .FALSE.   
430      !
431      IF( ln_ldfeiv ) THEN                         ! allocate the aei arrays
432         ALLOCATE( aeiu(jpi,jpj,jpk), aeiv(jpi,jpj,jpk), STAT=ierr )
433         IF( ierr /= 0 )   CALL ctl_stop('STOP', 'ldf_eiv: failed to allocate arrays')
434         !
435         SELECT CASE( nn_aei_ijk_t )               ! Specification of space time variations of eaiu, aeiv
436         !
437         CASE(   0  )      !==  constant  ==!
438            IF(lwp) WRITE(numout,*) '          eddy induced velocity coef. = constant = ', rn_aeiv_0
439!$OMP PARALLEL WORKSHARE
440            aeiu(:,:,:) = rn_aeiv_0
441            aeiv(:,:,:) = rn_aeiv_0
442!$OMP END PARALLEL WORKSHARE
443            !
444         CASE(  10  )      !==  fixed profile  ==!
445            IF(lwp) WRITE(numout,*) '          eddy induced velocity coef. = F( depth )'
446!$OMP PARALLEL WORKSHARE
447            aeiu(:,:,1) = rn_aeiv_0                                ! constant surface value
448            aeiv(:,:,1) = rn_aeiv_0
449!$OMP END PARALLEL WORKSHARE
450            CALL ldf_c1d( 'TRA', r1_4, aeiu(:,:,1), aeiv(:,:,1), aeiu, aeiv )
451            !
452         CASE ( -20 )      !== fixed horizontal shape read in file  ==!
453            IF(lwp) WRITE(numout,*) '          tracer mixing coef. = F(i,j) read in eddy_diffusivity_2D.nc file'
454            CALL iom_open ( 'eddy_induced_velocity_2D.nc', inum )
455            CALL iom_get  ( inum, jpdom_data, 'aeiu', aeiu(:,:,1) )
456            CALL iom_get  ( inum, jpdom_data, 'aeiv', aeiv(:,:,1) )
457            CALL iom_close( inum )
458!$OMP PARALLEL DO schedule(static) private(jk)
459            DO jk = 2, jpk
460               aeiu(:,:,jk) = aeiu(:,:,1)
461               aeiv(:,:,jk) = aeiv(:,:,1)
462            END DO
463            !
464         CASE(  20  )      !== fixed horizontal shape  ==!
465            IF(lwp) WRITE(numout,*) '          tracer mixing coef. = F( e1, e2 ) or F( e1^3, e2^3 ) (lap or bilap case)'
466            CALL ldf_c2d( 'TRA', 'LAP', rn_aeiv_0, aeiu, aeiv )    ! surface value proportional to scale factor
467            !
468         CASE(  21  )       !==  time varying 2D field  ==!
469            IF(lwp) WRITE(numout,*) '          tracer mixing coef. = F( latitude, longitude, time )'
470            IF(lwp) WRITE(numout,*) '                              = F( growth rate of baroclinic instability )'
471            !
472            l_ldfeiv_time = .TRUE.     ! will be calculated by call to ldf_tra routine in step.F90
473            !
474         CASE( -30  )      !== fixed 3D shape read in file  ==!
475            IF(lwp) WRITE(numout,*) '          tracer mixing coef. = F(i,j,k) read in eddy_diffusivity_3D.nc file'
476            CALL iom_open ( 'eddy_induced_velocity_3D.nc', inum )
477            CALL iom_get  ( inum, jpdom_data, 'aeiu', aeiu )
478            CALL iom_get  ( inum, jpdom_data, 'aeiv', aeiv )
479            CALL iom_close( inum )
480            !
481         CASE(  30  )       !==  fixed 3D shape  ==!
482            IF(lwp) WRITE(numout,*) '          tracer mixing coef. = F( latitude, longitude, depth )'
483            CALL ldf_c2d( 'TRA', 'LAP', rn_aeiv_0, aeiu, aeiv )    ! surface value proportional to scale factor
484            !                                                 ! reduction with depth
485            CALL ldf_c1d( 'TRA', r1_4, aeiu(:,:,1), aeiv(:,:,1), aeiu, aeiv )
486            !
487         CASE DEFAULT
488            CALL ctl_stop('ldf_tra_init: wrong choice for nn_aei_ijk_t, the type of space-time variation of aei')
489         END SELECT
490         !
491      ELSE
492          IF(lwp) WRITE(numout,*) '   eddy induced velocity param is NOT used neither diagnosed'
493          ln_ldfeiv_dia = .FALSE.
494      ENDIF
495      !                   
496   END SUBROUTINE ldf_eiv_init
497
498
499   SUBROUTINE ldf_eiv( kt, paei0, paeiu, paeiv )
500      !!----------------------------------------------------------------------
501      !!                  ***  ROUTINE ldf_eiv  ***
502      !!
503      !! ** Purpose :   Compute the eddy induced velocity coefficient from the
504      !!              growth rate of baroclinic instability.
505      !!
506      !! ** Method  :   coefficient function of the growth rate of baroclinic instability
507      !!
508      !! Reference : Treguier et al. JPO 1997   ; Held and Larichev JAS 1996
509      !!----------------------------------------------------------------------
510      INTEGER                         , INTENT(in   ) ::   kt             ! ocean time-step index
511      REAL(wp)                        , INTENT(inout) ::   paei0          ! max value            [m2/s]
512      REAL(wp), DIMENSION(jpi,jpj,jpk), INTENT(inout) ::   paeiu, paeiv   ! eiv coefficient      [m2/s]
513      !
514      INTEGER  ::   ji, jj, jk    ! dummy loop indices
515      REAL(wp) ::   zfw, ze3w, zn2, z1_f20, zaht, zaht_min, zzaei   ! local scalars
516      REAL(wp), DIMENSION(:,:), POINTER ::   zn, zah, zhw, zross, zaeiw   ! 2D workspace
517      !!----------------------------------------------------------------------
518      !
519      IF( nn_timing == 1 )   CALL timing_start('ldf_eiv')
520      !
521      CALL wrk_alloc( jpi,jpj,   zn, zah, zhw, zross, zaeiw )
522      !     
523!$OMP PARALLEL WORKSHARE
524      zn   (:,:) = 0._wp      ! Local initialization
525      zhw  (:,:) = 5._wp
526      zah  (:,:) = 0._wp
527      zross(:,:) = 0._wp
528!$OMP END PARALLEL WORKSHARE
529      !                       ! Compute lateral diffusive coefficient at T-point
530      IF( ln_traldf_triad ) THEN
531         DO jk = 1, jpk
532!$OMP PARALLEL DO schedule(static) private(jj,ji,zn2,ze3w)
533            DO jj = 2, jpjm1
534               DO ji = 2, jpim1
535                  ! Take the max of N^2 and zero then take the vertical sum
536                  ! of the square root of the resulting N^2 ( required to compute
537                  ! internal Rossby radius Ro = .5 * sum_jpk(N) / f
538                  zn2 = MAX( rn2b(ji,jj,jk), 0._wp )
539                  zn(ji,jj) = zn(ji,jj) + SQRT( zn2 ) * e3w_n(ji,jj,jk)
540                  ! Compute elements required for the inverse time scale of baroclinic
541                  ! eddies using the isopycnal slopes calculated in ldfslp.F :
542                  ! T^-1 = sqrt(m_jpk(N^2*(r1^2+r2^2)*e3w))
543                  ze3w = e3w_n(ji,jj,jk) * tmask(ji,jj,jk)
544                  zah(ji,jj) = zah(ji,jj) + zn2 * wslp2(ji,jj,jk) * ze3w
545                  zhw(ji,jj) = zhw(ji,jj) + ze3w
546               END DO
547            END DO
548         END DO
549      ELSE
550         DO jk = 1, jpk
551!$OMP PARALLEL DO schedule(static) private(jj,ji,zn2,ze3w)
552            DO jj = 2, jpjm1
553               DO ji = 2, jpim1
554                  ! Take the max of N^2 and zero then take the vertical sum
555                  ! of the square root of the resulting N^2 ( required to compute
556                  ! internal Rossby radius Ro = .5 * sum_jpk(N) / f
557                  zn2 = MAX( rn2b(ji,jj,jk), 0._wp )
558                  zn(ji,jj) = zn(ji,jj) + SQRT( zn2 ) * e3w_n(ji,jj,jk)
559                  ! Compute elements required for the inverse time scale of baroclinic
560                  ! eddies using the isopycnal slopes calculated in ldfslp.F :
561                  ! T^-1 = sqrt(m_jpk(N^2*(r1^2+r2^2)*e3w))
562                  ze3w = e3w_n(ji,jj,jk) * tmask(ji,jj,jk)
563                  zah(ji,jj) = zah(ji,jj) + zn2 * ( wslpi(ji,jj,jk) * wslpi(ji,jj,jk)   &
564                     &                            + wslpj(ji,jj,jk) * wslpj(ji,jj,jk) ) * ze3w
565                  zhw(ji,jj) = zhw(ji,jj) + ze3w
566               END DO
567            END DO
568         END DO
569      END IF
570
571!$OMP PARALLEL
572!$OMP DO schedule(static) private(jj,ji,zfw)
573      DO jj = 2, jpjm1
574         DO ji = fs_2, fs_jpim1   ! vector opt.
575            zfw = MAX( ABS( 2. * omega * SIN( rad * gphit(ji,jj) ) ) , 1.e-10 )
576            ! Rossby radius at w-point taken < 40km and  > 2km
577            zross(ji,jj) = MAX( MIN( .4 * zn(ji,jj) / zfw, 40.e3 ), 2.e3 )
578            ! Compute aeiw by multiplying Ro^2 and T^-1
579            zaeiw(ji,jj) = zross(ji,jj) * zross(ji,jj) * SQRT( zah(ji,jj) / zhw(ji,jj) ) * tmask(ji,jj,1)
580         END DO
581      END DO
582
583!!gm      IF( cp_cfg == "orca" .AND. jp_cfg == 2 ) THEN   ! ORCA R2
584!!gm         DO jj = 2, jpjm1
585!!gm            DO ji = fs_2, fs_jpim1   ! vector opt.
586!!gm               ! Take the minimum between aeiw and 1000 m2/s over shelves (depth shallower than 650 m)
587!!gm               IF( mbkt(ji,jj) <= 20 )   zaeiw(ji,jj) = MIN( zaeiw(ji,jj), 1000. )
588!!gm            END DO
589!!gm         END DO
590!!gm      ENDIF
591
592      !                                         !==  Bound on eiv coeff.  ==!
593      z1_f20 = 1._wp / (  2._wp * omega * sin( rad * 20._wp )  )
594!$OMP DO schedule(static) private(jj,ji,zzaei)
595      DO jj = 2, jpjm1
596         DO ji = fs_2, fs_jpim1   ! vector opt.
597            zzaei = MIN( 1._wp, ABS( ff(ji,jj) * z1_f20 ) ) * zaeiw(ji,jj)       ! tropical decrease
598            zaeiw(ji,jj) = MIN( zzaei , paei0 )                                  ! Max value = paei0
599         END DO
600      END DO
601!$OMP END DO NOWAIT
602!$OMP END PARALLEL
603      CALL lbc_lnk( zaeiw(:,:), 'W', 1. )       ! lateral boundary condition
604      !               
605!$OMP PARALLEL DO schedule(static) private(jj,ji,zfw)
606      DO jj = 2, jpjm1                          !== aei at u- and v-points  ==!
607         DO ji = fs_2, fs_jpim1   ! vector opt.
608            paeiu(ji,jj,1) = 0.5_wp * ( zaeiw(ji,jj) + zaeiw(ji+1,jj  ) ) * umask(ji,jj,1)
609            paeiv(ji,jj,1) = 0.5_wp * ( zaeiw(ji,jj) + zaeiw(ji  ,jj+1) ) * vmask(ji,jj,1)
610         END DO
611      END DO
612      CALL lbc_lnk( paeiu(:,:,1), 'U', 1. )   ;   CALL lbc_lnk( paeiv(:,:,1), 'V', 1. )      ! lateral boundary condition
613
614!$OMP PARALLEL DO schedule(static) private(jk)
615      DO jk = 2, jpkm1                          !==  deeper values equal the surface one  ==!
616         paeiu(:,:,jk) = paeiu(:,:,1) * umask(:,:,jk)
617         paeiv(:,:,jk) = paeiv(:,:,1) * vmask(:,:,jk)
618      END DO
619      ! 
620      CALL wrk_dealloc( jpi,jpj,   zn, zah, zhw, zross, zaeiw )
621      !
622      IF( nn_timing == 1 )   CALL timing_stop('ldf_eiv')
623      !
624   END SUBROUTINE ldf_eiv
625
626
627   SUBROUTINE ldf_eiv_trp( kt, kit000, pun, pvn, pwn, cdtype )
628      !!----------------------------------------------------------------------
629      !!                  ***  ROUTINE ldf_eiv_trp  ***
630      !!
631      !! ** Purpose :   add to the input ocean transport the contribution of
632      !!              the eddy induced velocity parametrization.
633      !!
634      !! ** Method  :   The eddy induced transport is computed from a flux stream-
635      !!              function which depends on the slope of iso-neutral surfaces
636      !!              (see ldf_slp). For example, in the i-k plan :
637      !!                   psi_uw = mk(aeiu) e2u mi(wslpi)   [in m3/s]
638      !!                   Utr_eiv = - dk[psi_uw]
639      !!                   Vtr_eiv = + di[psi_uw]
640      !!                ln_ldfeiv_dia = T : output the associated streamfunction,
641      !!                                    velocity and heat transport (call ldf_eiv_dia)
642      !!
643      !! ** Action  : pun, pvn increased by the eiv transport
644      !!----------------------------------------------------------------------
645      INTEGER                         , INTENT(in   ) ::   kt       ! ocean time-step index
646      INTEGER                         , INTENT(in   ) ::   kit000   ! first time step index
647      CHARACTER(len=3)                , INTENT(in   ) ::   cdtype   ! =TRA or TRC (tracer indicator)
648      REAL(wp), DIMENSION(jpi,jpj,jpk), INTENT(inout) ::   pun      ! in : 3 ocean transport components   [m3/s]
649      REAL(wp), DIMENSION(jpi,jpj,jpk), INTENT(inout) ::   pvn      ! out: 3 ocean transport components   [m3/s]
650      REAL(wp), DIMENSION(jpi,jpj,jpk), INTENT(inout) ::   pwn      ! increased by the eiv                [m3/s]
651      !!
652      INTEGER  ::   ji, jj, jk                 ! dummy loop indices
653      REAL(wp) ::   zuwk, zuwk1, zuwi, zuwi1   ! local scalars
654      REAL(wp) ::   zvwk, zvwk1, zvwj, zvwj1   !   -      -
655      REAL(wp), POINTER, DIMENSION(:,:,:) ::   zpsi_uw, zpsi_vw
656      !!----------------------------------------------------------------------
657      !
658      IF( nn_timing == 1 )   CALL timing_start( 'ldf_eiv_trp')
659      !
660      CALL wrk_alloc( jpi,jpj,jpk,   zpsi_uw, zpsi_vw )
661
662      IF( kt == kit000 )  THEN
663         IF(lwp) WRITE(numout,*)
664         IF(lwp) WRITE(numout,*) 'ldf_eiv_trp : eddy induced advection on ', cdtype,' :'
665         IF(lwp) WRITE(numout,*) '~~~~~~~~~~~   add to velocity fields the eiv component'
666      ENDIF
667
668     
669!$OMP PARALLEL
670!$OMP WORKSHARE     
671      zpsi_uw(:,:, 1 ) = 0._wp   ;   zpsi_vw(:,:, 1 ) = 0._wp
672      zpsi_uw(:,:,jpk) = 0._wp   ;   zpsi_vw(:,:,jpk) = 0._wp
673!$OMP END WORKSHARE NOWAIT
674      !
675!$OMP DO schedule(static) private(jk,jj,ji)
676      DO jk = 2, jpkm1
677         DO jj = 1, jpjm1
678            DO ji = 1, fs_jpim1   ! vector opt.
679               zpsi_uw(ji,jj,jk) = - 0.25_wp * e2u(ji,jj) * ( wslpi(ji,jj,jk  ) + wslpi(ji+1,jj,jk) )   &
680                  &                                       * ( aeiu (ji,jj,jk-1) + aeiu (ji  ,jj,jk) ) * umask(ji,jj,jk)
681               zpsi_vw(ji,jj,jk) = - 0.25_wp * e1v(ji,jj) * ( wslpj(ji,jj,jk  ) + wslpj(ji,jj+1,jk) )   &
682                  &                                       * ( aeiv (ji,jj,jk-1) + aeiv (ji,jj  ,jk) ) * vmask(ji,jj,jk)
683            END DO
684         END DO
685      END DO
686      !
687!$OMP DO schedule(static) private(jk,jj,ji)
688      DO jk = 1, jpkm1
689         DO jj = 1, jpjm1
690            DO ji = 1, fs_jpim1   ! vector opt.               
691               pun(ji,jj,jk) = pun(ji,jj,jk) - ( zpsi_uw(ji,jj,jk) - zpsi_uw(ji,jj,jk+1) )
692               pvn(ji,jj,jk) = pvn(ji,jj,jk) - ( zpsi_vw(ji,jj,jk) - zpsi_vw(ji,jj,jk+1) )
693            END DO
694         END DO
695      END DO
696!$OMP END DO NOWAIT
697!$OMP DO schedule(static) private(jk,jj,ji)
698      DO jk = 1, jpkm1
699         DO jj = 2, jpjm1
700            DO ji = fs_2, fs_jpim1   ! vector opt.
701               pwn(ji,jj,jk) = pwn(ji,jj,jk) + (  zpsi_uw(ji,jj,jk) - zpsi_uw(ji-1,jj  ,jk)   &
702                  &                             + zpsi_vw(ji,jj,jk) - zpsi_vw(ji  ,jj-1,jk) )
703            END DO
704         END DO
705      END DO
706!$OMP END DO NOWAIT
707!$OMP END PARALLEL
708      !
709      !                              ! diagnose the eddy induced velocity and associated heat transport
710      IF( ln_ldfeiv_dia .AND. cdtype == 'TRA' )   CALL ldf_eiv_dia( zpsi_uw, zpsi_vw )
711      !
712      CALL wrk_dealloc( jpi,jpj,jpk,   zpsi_uw, zpsi_vw )
713      !
714      IF( nn_timing == 1 )   CALL timing_stop( 'ldf_eiv_trp')
715      !
716    END SUBROUTINE ldf_eiv_trp
717
718
719   SUBROUTINE ldf_eiv_dia( psi_uw, psi_vw )
720      !!----------------------------------------------------------------------
721      !!                  ***  ROUTINE ldf_eiv_dia  ***
722      !!
723      !! ** Purpose :   diagnose the eddy induced velocity and its associated
724      !!              vertically integrated heat transport.
725      !!
726      !! ** Method :
727      !!
728      !!----------------------------------------------------------------------
729      REAL(wp), DIMENSION(jpi,jpj,jpk), INTENT(inout) ::   psi_uw, psi_vw   ! streamfunction   [m3/s]
730      !
731      INTEGER  ::   ji, jj, jk    ! dummy loop indices
732      REAL(wp) ::   zztmp   ! local scalar
733      REAL(wp), DIMENSION(:,:)  , POINTER ::   zw2d   ! 2D workspace
734      REAL(wp), DIMENSION(:,:,:), POINTER ::   zw3d   ! 3D workspace
735      !!----------------------------------------------------------------------
736      !
737      IF( nn_timing == 1 )  CALL timing_start( 'ldf_eiv_dia')
738      !
739      !                                                  !==  eiv stream function: output  ==!
740      CALL lbc_lnk( psi_uw, 'U', -1. )                         ! lateral boundary condition
741      CALL lbc_lnk( psi_vw, 'V', -1. )
742      !
743!!gm      CALL iom_put( "psi_eiv_uw", psi_uw )                 ! output
744!!gm      CALL iom_put( "psi_eiv_vw", psi_vw )
745      !
746      !                                                  !==  eiv velocities: calculate and output  ==!
747      CALL wrk_alloc( jpi,jpj,jpk,   zw3d )
748      !
749!$OMP PARALLEL
750!$OMP WORKSHARE
751      zw3d(:,:,jpk) = 0._wp                                    ! bottom value always 0
752!$OMP END WORKSHARE NOWAIT
753      !
754!$OMP DO schedule(static) private(jk)
755      DO jk = 1, jpkm1                                         ! e2u e3u u_eiv = -dk[psi_uw]
756         zw3d(:,:,jk) = ( psi_uw(:,:,jk+1) - psi_uw(:,:,jk) ) / ( e2u(:,:) * e3u_n(:,:,jk) )
757      END DO
758!$OMP END DO NOWAIT
759!$OMP END PARALLEL
760      CALL iom_put( "uoce_eiv", zw3d )
761      !
762!$OMP PARALLEL DO schedule(static) private(jk)
763      DO jk = 1, jpkm1                                         ! e1v e3v v_eiv = -dk[psi_vw]
764         zw3d(:,:,jk) = ( psi_vw(:,:,jk+1) - psi_vw(:,:,jk) ) / ( e1v(:,:) * e3v_n(:,:,jk) )
765      END DO
766      CALL iom_put( "voce_eiv", zw3d )
767      !
768!$OMP PARALLEL DO schedule(static) private(jk,jj,ji)
769      DO jk = 1, jpkm1                                         ! e1 e2 w_eiv = dk[psix] + dk[psix]
770         DO jj = 2, jpjm1
771            DO ji = fs_2, fs_jpim1  ! vector opt.
772               zw3d(ji,jj,jk) = (  psi_vw(ji,jj,jk) - psi_vw(ji  ,jj-1,jk)    &
773                  &              + psi_uw(ji,jj,jk) - psi_uw(ji-1,jj  ,jk)  ) / e1e2t(ji,jj)
774            END DO
775         END DO
776      END DO
777      CALL lbc_lnk( zw3d, 'T', 1. )      ! lateral boundary condition
778      CALL iom_put( "woce_eiv", zw3d )
779      !
780      CALL wrk_dealloc( jpi,jpj,jpk,   zw3d )
781      !     
782      !
783      IF( lk_diaar5 ) THEN                               !==  eiv heat transport: calculate and output  ==!
784         CALL wrk_alloc( jpi,jpj,   zw2d )
785         !
786         zztmp = 0.5_wp * rau0 * rcp 
787!$OMP PARALLEL
788!$OMP WORKSHARE
789         zw2d(:,:) = 0._wp
790!$OMP END WORKSHARE
791         DO jk = 1, jpkm1
792!$OMP DO schedule(static) private(jj,ji)
793            DO jj = 2, jpjm1
794               DO ji = fs_2, fs_jpim1   ! vector opt.
795                  zw2d(ji,jj) = zw2d(ji,jj) + zztmp * ( psi_uw(ji,jj,jk+1)      - psi_uw(ji,jj,jk)          )   &
796                     &                              * ( tsn   (ji,jj,jk,jp_tem) + tsn   (ji+1,jj,jk,jp_tem) ) 
797               END DO
798            END DO
799!$OMP END DO NOWAIT
800         END DO
801!$OMP END PARALLEL
802         CALL lbc_lnk( zw2d, 'U', -1. )
803         CALL iom_put( "ueiv_heattr", zw2d )                  ! heat transport in i-direction
804!$OMP PARALLEL
805!$OMP WORKSHARE
806         zw2d(:,:) = 0._wp 
807!$OMP END WORKSHARE
808         DO jk = 1, jpkm1
809!$OMP DO schedule(static) private(jj,ji)
810            DO jj = 2, jpjm1
811               DO ji = fs_2, fs_jpim1   ! vector opt.
812                  zw2d(ji,jj) = zw2d(ji,jj) + zztmp * ( psi_vw(ji,jj,jk+1)      - psi_vw(ji,jj,jk)          )   &
813                     &                              * ( tsn   (ji,jj,jk,jp_tem) + tsn   (ji,jj+1,jk,jp_tem) ) 
814               END DO
815            END DO
816!$OMP END DO NOWAIT
817         END DO
818!$OMP END PARALLEL
819         CALL lbc_lnk( zw2d, 'V', -1. )
820         CALL iom_put( "veiv_heattr", zw2d )                  !  heat transport in i-direction
821         !
822         CALL wrk_dealloc( jpi,jpj,   zw2d )
823      ENDIF
824      !
825      IF( nn_timing == 1 )  CALL timing_stop( 'ldf_eiv_dia')     
826      !
827   END SUBROUTINE ldf_eiv_dia
828
829   !!======================================================================
830END MODULE ldftra
Note: See TracBrowser for help on using the repository browser.