New URL for NEMO forge!   http://forge.nemo-ocean.eu

Since March 2022 along with NEMO 4.2 release, the code development moved to a self-hosted GitLab.
This present forge is now archived and remained online for history.
sbcana.F90 in branches/2016/dev_r6519_HPC_4/NEMOGCM/NEMO/OPA_SRC/SBC – NEMO

source: branches/2016/dev_r6519_HPC_4/NEMOGCM/NEMO/OPA_SRC/SBC/sbcana.F90 @ 7037

Last change on this file since 7037 was 7037, checked in by mocavero, 7 years ago

ORCA2_LIM_PISCES hybrid version update

  • Property svn:keywords set to Id
File size: 16.8 KB
Line 
1MODULE sbcana
2   !!======================================================================
3   !!                       ***  MODULE  sbcana  ***
4   !! Ocean forcing:  analytical momentum, heat and freshwater forcings
5   !!=====================================================================
6   !! History :  3.0   ! 2006-06  (G. Madec)  Original code
7   !!            3.2   ! 2009-07  (G. Madec)  Style only
8   !!----------------------------------------------------------------------
9
10   !!----------------------------------------------------------------------
11   !!   sbc_ana  : set an analytical ocean forcing
12   !!   sbc_gyre : set the GYRE configuration analytical forcing
13   !!----------------------------------------------------------------------
14   USE oce             ! ocean dynamics and tracers
15   USE dom_oce         ! ocean space and time domain
16   USE sbc_oce         ! Surface boundary condition: ocean fields
17   USE phycst          ! physical constants
18   USE in_out_manager  ! I/O manager
19   USE lib_mpp         ! distribued memory computing library
20   USE lbclnk          ! ocean lateral boundary conditions (or mpp link)
21   USE lib_fortran
22
23   IMPLICIT NONE
24   PRIVATE
25
26   PUBLIC   sbc_ana    ! routine called in sbcmod module
27   PUBLIC   sbc_gyre   ! routine called in sbcmod module
28
29   !                       !!* Namelist namsbc_ana *
30   INTEGER  ::   nn_tau000  ! nb of time-step during which the surface stress
31   !                        ! increase from 0 to its nominal value
32   REAL(wp) ::   rn_utau0   ! constant wind stress value in i-direction
33   REAL(wp) ::   rn_vtau0   ! constant wind stress value in j-direction
34   REAL(wp) ::   rn_qns0    ! non solar heat flux
35   REAL(wp) ::   rn_qsr0    !     solar heat flux
36   REAL(wp) ::   rn_emp0    ! net freshwater flux
37   
38   !! * Substitutions
39#  include "vectopt_loop_substitute.h90"
40   !!----------------------------------------------------------------------
41   !! NEMO/OPA 3.3 , NEMO Consortium (2010)
42   !! $Id$
43   !! Software governed by the CeCILL licence     (NEMOGCM/NEMO_CeCILL.txt)
44   !!----------------------------------------------------------------------
45CONTAINS
46
47   SUBROUTINE sbc_ana( kt )
48      !!---------------------------------------------------------------------
49      !!                    ***  ROUTINE sbc_ana ***
50      !!             
51      !! ** Purpose :   provide at each time-step the ocean surface boundary
52      !!              condition, i.e. the momentum, heat and freshwater fluxes.
53      !!
54      !! ** Method  :   Constant and uniform surface forcing specified from
55      !!              namsbc_ana namelist parameters. All the fluxes are time
56      !!              independant except the stresses which increase from zero
57      !!              during the first nn_tau000 time-step
58      !!
59      !! ** Action  : - set the ocean surface boundary condition, i.e. 
60      !!                   utau, vtau, taum, wndm, qns, qsr, emp, sfx
61      !!----------------------------------------------------------------------
62      INTEGER, INTENT(in) ::   kt   ! ocean time step
63      !
64      INTEGER  ::   ios                   ! local integer
65      REAL(wp) ::   zrhoa  = 1.22_wp      ! air density kg/m3
66      REAL(wp) ::   zcdrag = 1.5e-3_wp    ! drag coefficient
67      REAL(wp) ::   zfact, ztx            ! local scalars
68      REAL(wp) ::   zcoef, zty, zmod      !   -      -
69      !!
70      NAMELIST/namsbc_ana/ nn_tau000, rn_utau0, rn_vtau0, rn_qns0, rn_qsr0, rn_emp0
71      !!---------------------------------------------------------------------
72      !
73      IF( kt == nit000 ) THEN
74         !
75         REWIND( numnam_ref )              ! Namelist namsbc_ana in reference namelist : Analytical surface fluxes
76         READ  ( numnam_ref, namsbc_ana, IOSTAT = ios, ERR = 901)
77901      IF( ios /= 0 ) CALL ctl_nam ( ios , 'namsbc_ana in reference namelist', lwp )
78
79         REWIND( numnam_cfg )              ! Namelist namsbc_ana in configuration namelist : Analytical surface fluxes
80         READ  ( numnam_cfg, namsbc_ana, IOSTAT = ios, ERR = 902 )
81902      IF( ios /= 0 ) CALL ctl_nam ( ios , 'namsbc_ana in configuration namelist', lwp )
82         IF(lwm) WRITE ( numond, namsbc_ana )
83         !
84         IF(lwp) WRITE(numout,*)' '
85         IF(lwp) WRITE(numout,*)' sbc_ana : Constant surface fluxes read in namsbc_ana namelist'
86         IF(lwp) WRITE(numout,*)' ~~~~~~~ '
87         IF(lwp) WRITE(numout,*)'              spin up of the stress  nn_tau000 = ', nn_tau000, ' time-steps'
88         IF(lwp) WRITE(numout,*)'              constant i-stress      rn_utau0  = ', rn_utau0 , ' N/m2'
89         IF(lwp) WRITE(numout,*)'              constant j-stress      rn_vtau0  = ', rn_vtau0 , ' N/m2'
90         IF(lwp) WRITE(numout,*)'              non solar heat flux    rn_qns0   = ', rn_qns0  , ' W/m2'
91         IF(lwp) WRITE(numout,*)'              solar heat flux        rn_qsr0   = ', rn_qsr0  , ' W/m2'
92         IF(lwp) WRITE(numout,*)'              net heat flux          rn_emp0   = ', rn_emp0  , ' Kg/m2/s'
93         !
94         nn_tau000 = MAX( nn_tau000, 1 )     ! must be >= 1
95         !
96         utau(:,:) = rn_utau0
97         vtau(:,:) = rn_vtau0
98         taum(:,:) = SQRT ( rn_utau0 * rn_utau0 + rn_vtau0 * rn_vtau0 )
99         wndm(:,:) = SQRT ( taum(1,1) /  ( zrhoa * zcdrag ) )
100         !
101         emp (:,:) = rn_emp0
102         sfx (:,:) = 0.0_wp
103         qns (:,:) = rn_qns0 - emp(:,:) * sst_m(:,:) * rcp      ! including heat content associated with mass flux at SST
104         qsr (:,:) = rn_qsr0
105         !         
106      ENDIF
107
108      IF( MOD( kt - 1, nn_fsbc ) == 0 ) THEN 
109         !
110         IF( kt <= nn_tau000 ) THEN       ! Increase the stress to its nominal value
111            !                             ! during the first nn_tau000 time-steps
112            zfact = 0.5 * (  1. - COS( rpi * REAL( kt, wp ) / REAL( nn_tau000, wp ) )  )
113            zcoef = 1. / ( zrhoa * zcdrag ) 
114            ztx   = zfact * rn_utau0
115            zty   = zfact * rn_vtau0
116            zmod  = SQRT( ztx * ztx + zty * zty )
117            utau(:,:) = ztx
118            vtau(:,:) = zty
119            taum(:,:) = zmod
120            zmod = SQRT( zmod * zcoef )
121            wndm(:,:) = zmod
122         ENDIF
123         !                                ! update heat and fresh water fluxes
124         !                                ! as they may have been changed by sbcssr module
125         emp (:,:) = rn_emp0              ! NB: qns changes with SST if emp /= 0
126         sfx (:,:) = 0._wp
127         qns (:,:) = rn_qns0 - emp(:,:) * sst_m(:,:) * rcp
128         qsr (:,:) = rn_qsr0
129         !
130      ENDIF
131      !
132   END SUBROUTINE sbc_ana
133
134
135   SUBROUTINE sbc_gyre( kt )
136      !!---------------------------------------------------------------------
137      !!                    ***  ROUTINE sbc_ana ***
138      !!             
139      !! ** Purpose :   provide at each time-step the GYRE surface boundary
140      !!              condition, i.e. the momentum, heat and freshwater fluxes.
141      !!
142      !! ** Method  :   analytical seasonal cycle for GYRE configuration.
143      !!                CAUTION : never mask the surface stress field !
144      !!
145      !! ** Action  : - set the ocean surface boundary condition, i.e.   
146      !!                   utau, vtau, taum, wndm, qns, qsr, emp, sfx
147      !!
148      !! Reference : Hazeleger, W., and S. Drijfhout, JPO, 30, 677-695, 2000.
149      !!----------------------------------------------------------------------
150      INTEGER, INTENT(in) ::   kt          ! ocean time step
151      !!
152      INTEGER  ::   ji, jj                 ! dummy loop indices
153      INTEGER  ::   zyear0                 ! initial year
154      INTEGER  ::   zmonth0                ! initial month
155      INTEGER  ::   zday0                  ! initial day
156      INTEGER  ::   zday_year0             ! initial day since january 1st
157      REAL(wp) ::   ztau     , ztau_sais   ! wind intensity and of the seasonal cycle
158      REAL(wp) ::   ztime                  ! time in hour
159      REAL(wp) ::   ztimemax , ztimemin    ! 21th June, and 21th decem. if date0 = 1st january
160      REAL(wp) ::   ztimemax1, ztimemin1   ! 21th June, and 21th decem. if date0 = 1st january
161      REAL(wp) ::   ztimemax2, ztimemin2   ! 21th June, and 21th decem. if date0 = 1st january
162      REAL(wp) ::   ztaun                  ! intensity
163      REAL(wp) ::   zemp_s, zemp_n, zemp_sais, ztstar
164      REAL(wp) ::   zcos_sais1, zcos_sais2, ztrp, zconv, t_star
165      REAL(wp) ::   zsumemp, zsurf
166      REAL(wp) ::   zrhoa  = 1.22         ! Air density kg/m3
167      REAL(wp) ::   zcdrag = 1.5e-3       ! drag coefficient
168      REAL(wp) ::   ztx, zty, zmod, zcoef ! temporary variables
169      REAL(wp) ::   zyydd                 ! number of days in one year
170      !!---------------------------------------------------------------------
171      zyydd = REAL(nyear_len(1),wp)
172
173      ! ---------------------------- !
174      !  heat and freshwater fluxes  !
175      ! ---------------------------- !
176      !same temperature, E-P as in HAZELEGER 2000
177
178      zyear0     =   ndate0 / 10000                             ! initial year
179      zmonth0    = ( ndate0 - zyear0 * 10000 ) / 100            ! initial month
180      zday0      =   ndate0 - zyear0 * 10000 - zmonth0 * 100    ! initial day betwen 1 and 30
181      zday_year0 = ( zmonth0 - 1 ) * 30.+zday0                  ! initial day betwen 1 and 360
182
183      ! current day (in hours) since january the 1st of the current year
184      ztime = REAL( kt ) * rdt / (rmmss * rhhmm)   &       !  total incrementation (in hours)
185         &      - (nyear  - 1) * rjjhh * zyydd             !  minus years since beginning of experiment (in hours)
186
187      ztimemax1 = ((5.*30.)+21.)* 24.                      ! 21th june     at 24h in hours
188      ztimemin1 = ztimemax1 + rjjhh * zyydd / 2            ! 21th december        in hours
189      ztimemax2 = ((6.*30.)+21.)* 24.                      ! 21th july     at 24h in hours
190      ztimemin2 = ztimemax2 - rjjhh * zyydd / 2            ! 21th january         in hours
191      !                                                    ! NB: rjjhh * zyydd / 4 = one seasonal cycle in hours
192
193      ! amplitudes
194      zemp_S    = 0.7       ! intensity of COS in the South
195      zemp_N    = 0.8       ! intensity of COS in the North
196      zemp_sais = 0.1
197      zTstar    = 28.3      ! intemsity from 28.3 a -5 deg
198
199      ! 1/2 period between 21th June and 21th December and between 21th July and 21th January
200      zcos_sais1 = COS( (ztime - ztimemax1) / (ztimemin1 - ztimemax1) * rpi ) 
201      zcos_sais2 = COS( (ztime - ztimemax2) / (ztimemax2 - ztimemin2) * rpi )
202
203      ztrp= - 40.e0        ! retroaction term on heat fluxes (W/m2/K)
204      zconv = 3.16e-5      ! convertion factor: 1 m/yr => 3.16e-5 mm/s
205!$OMP PARALLEL DO schedule(static) private(jj, ji, t_star)
206      DO jj = 1, jpj
207         DO ji = 1, jpi
208            ! domain from 15 deg to 50 deg between 27 and 28  degC at 15N, -3
209            ! and 13 degC at 50N 53.5 + or - 11 = 1/4 period :
210            ! 64.5 in summer, 42.5 in winter
211            t_star = zTstar * ( 1 + 1. / 50. * zcos_sais2 )                &
212               &                    * COS( rpi * (gphit(ji,jj) - 5.)               &
213               &                    / ( 53.5 * ( 1 + 11 / 53.5 * zcos_sais2 ) * 2.) )
214            ! 23.5 deg : tropics
215            qsr (ji,jj) =  230 * COS( 3.1415 * ( gphit(ji,jj) - 23.5 * zcos_sais1 ) / ( 0.9 * 180 ) )
216            qns (ji,jj) = ztrp * ( tsb(ji,jj,1,jp_tem) - t_star ) - qsr(ji,jj)
217            IF( gphit(ji,jj) >= 14.845 .AND. 37.2 >= gphit(ji,jj) ) THEN    ! zero at 37.8 deg, max at 24.6 deg
218               emp  (ji,jj) =   zemp_S * zconv   &
219                  &         * SIN( rpi / 2 * (gphit(ji,jj) - 37.2) / (24.6 - 37.2) )  &
220                  &         * ( 1 - zemp_sais / zemp_S * zcos_sais1)
221            ELSE
222               emp (ji,jj) =  - zemp_N * zconv   &
223                  &         * SIN( rpi / 2 * (gphit(ji,jj) - 37.2) / (46.8 - 37.2) )  &
224                  &         * ( 1 - zemp_sais / zemp_N * zcos_sais1 )
225            ENDIF
226         END DO
227      END DO
228
229      ! Compute the emp flux such as its integration on the whole domain at each time is zero
230      IF( nbench /= 1 ) THEN
231         zsumemp = GLOB_SUM( emp(:,:) ) 
232         zsurf   = GLOB_SUM( tmask(:,:,1) ) 
233         ! Default GYRE configuration
234         zsumemp = zsumemp / zsurf
235      ELSE
236         ! Benchmark GYRE configuration (to allow the bit to bit comparison between Mpp/Mono case)
237         zsumemp = 0.e0   ;    zsurf = 0.e0
238      ENDIF
239
240      ! freshwater (mass flux) and update of qns with heat content of emp
241!$OMP PARALLEL WORKSHARE
242      emp (:,:) = emp(:,:) - zsumemp * tmask(:,:,1)        ! freshwater flux (=0 in domain average)
243      sfx (:,:) = 0.0_wp                                   ! no salt flux
244      qns (:,:) = qns(:,:) - emp(:,:) * sst_m(:,:) * rcp   ! evap and precip are at SST
245!$OMP END PARALLEL WORKSHARE
246
247      ! ---------------------------- !
248      !       momentum fluxes        !
249      ! ---------------------------- !
250      ! same wind as in Wico
251      !test date0 : ndate0 = 010203
252      zyear0  =   ndate0 / 10000
253      zmonth0 = ( ndate0 - zyear0 * 10000 ) / 100
254      zday0   =   ndate0 - zyear0 * 10000 - zmonth0 * 100
255      !Calculates nday_year, day since january 1st
256      zday_year0 = (zmonth0-1)*30.+zday0
257
258      !accumulates days of previous months of this year
259      ! day (in hours) since january the 1st
260      ztime = FLOAT( kt ) * rdt / (rmmss * rhhmm)  &  ! incrementation in hour
261         &     - (nyear - 1) * rjjhh * zyydd          !  - nber of hours the precedent years
262      ztimemax = ((5.*30.)+21.)* 24.               ! 21th june     in hours
263      ztimemin = ztimemax + rjjhh * zyydd / 2      ! 21th december in hours
264      !                                            ! NB: rjjhh * zyydd / 4 = 1 seasonal cycle in hours
265
266      ! mean intensity at 0.105 ; srqt(2) because projected with 45deg angle
267      ztau = 0.105 / SQRT( 2. )
268      ! seasonal oscillation intensity
269      ztau_sais = 0.015
270      ztaun = ztau - ztau_sais * COS( (ztime - ztimemax) / (ztimemin - ztimemax) * rpi )
271      ! module of wind stress and wind speed at T-point
272      zcoef = 1. / ( zrhoa * zcdrag ) 
273!$OMP PARALLEL
274!$OMP DO schedule(static) private(jj, ji)
275      DO jj = 1, jpj
276         DO ji = 1, jpi
277           ! domain from 15deg to 50deg and 1/2 period along 14deg
278           ! so 5/4 of half period with seasonal cycle
279           utau(ji,jj) = - ztaun * SIN( rpi * (gphiu(ji,jj) - 15.) / (29.-15.) )
280           vtau(ji,jj) =   ztaun * SIN( rpi * (gphiv(ji,jj) - 15.) / (29.-15.) )
281         END DO
282      END DO
283
284!$OMP DO schedule(static) private(jj, ji, ztx, zty, zmod)
285      DO jj = 2, jpjm1
286         DO ji = fs_2, fs_jpim1   ! vect. opt.
287            ztx = utau(ji-1,jj  ) + utau(ji,jj) 
288            zty = vtau(ji  ,jj-1) + vtau(ji,jj) 
289            zmod = 0.5 * SQRT( ztx * ztx + zty * zty )
290            taum(ji,jj) = zmod
291            wndm(ji,jj) = SQRT( zmod * zcoef )
292         END DO
293      END DO
294!$OMP END DO NOWAIT
295!$OMP END PARALLEL
296      CALL lbc_lnk( taum(:,:), 'T', 1. )   ;   CALL lbc_lnk( wndm(:,:), 'T', 1. )
297
298      ! ---------------------------------- !
299      !  control print at first time-step  !
300      ! ---------------------------------- !
301      IF( kt == nit000 .AND. lwp ) THEN
302         WRITE(numout,*)
303         WRITE(numout,*)'sbc_gyre : analytical surface fluxes for GYRE configuration'               
304         WRITE(numout,*)'~~~~~~~~ ' 
305         WRITE(numout,*)'           nyear      = ', nyear
306         WRITE(numout,*)'           nmonth     = ', nmonth
307         WRITE(numout,*)'           nday       = ', nday
308         WRITE(numout,*)'           nday_year  = ', nday_year
309         WRITE(numout,*)'           ztime      = ', ztime
310         WRITE(numout,*)'           ztimemax   = ', ztimemax
311         WRITE(numout,*)'           ztimemin   = ', ztimemin
312         WRITE(numout,*)'           ztimemax1  = ', ztimemax1
313         WRITE(numout,*)'           ztimemin1  = ', ztimemin1
314         WRITE(numout,*)'           ztimemax2  = ', ztimemax2
315         WRITE(numout,*)'           ztimemin2  = ', ztimemin2
316         WRITE(numout,*)'           zyear0     = ', zyear0
317         WRITE(numout,*)'           zmonth0    = ', zmonth0
318         WRITE(numout,*)'           zday0      = ', zday0
319         WRITE(numout,*)'           zday_year0 = ', zday_year0
320         WRITE(numout,*)'           zyydd      = ', zyydd
321         WRITE(numout,*)'           zemp_S     = ', zemp_S
322         WRITE(numout,*)'           zemp_N     = ', zemp_N
323         WRITE(numout,*)'           zemp_sais  = ', zemp_sais
324         WRITE(numout,*)'           zTstar     = ', zTstar
325         WRITE(numout,*)'           zsumemp    = ', zsumemp
326         WRITE(numout,*)'           zsurf      = ', zsurf
327         WRITE(numout,*)'           ztrp       = ', ztrp
328         WRITE(numout,*)'           zconv      = ', zconv
329         WRITE(numout,*)'           ndastp     = ', ndastp
330         WRITE(numout,*)'           adatrj     = ', adatrj
331      ENDIF
332      !
333   END SUBROUTINE sbc_gyre
334
335   !!======================================================================
336END MODULE sbcana
Note: See TracBrowser for help on using the repository browser.