| 1 | MODULE sbcice_lim_2 |
|---|
| 2 | !!====================================================================== |
|---|
| 3 | !! *** MODULE sbcice_lim_2 *** |
|---|
| 4 | !! Surface module : update surface ocean boundary condition over ice covered area using LIM sea-ice model |
|---|
| 5 | !! Sea-Ice model : LIM-2 Sea ice model time-stepping |
|---|
| 6 | !!====================================================================== |
|---|
| 7 | !! History : 1.0 ! 06-2006 (G. Madec) from icestp_2.F90 |
|---|
| 8 | !! 3.0 ! 08-2008 (S. Masson, E. .... ) coupled interface |
|---|
| 9 | !! 3.3 ! 05-2009 (G.Garric) addition of the lim2_evp case |
|---|
| 10 | !!---------------------------------------------------------------------- |
|---|
| 11 | #if defined key_lim2 |
|---|
| 12 | !!---------------------------------------------------------------------- |
|---|
| 13 | !! 'key_lim2' : LIM-2 sea-ice model |
|---|
| 14 | !!---------------------------------------------------------------------- |
|---|
| 15 | !! sbc_ice_lim_2 : sea-ice model time-stepping and update ocean sbc over ice-covered area |
|---|
| 16 | !!---------------------------------------------------------------------- |
|---|
| 17 | USE oce ! ocean dynamics and tracers |
|---|
| 18 | USE dom_oce ! ocean space and time domain |
|---|
| 19 | USE ice_2 |
|---|
| 20 | USE par_ice_2 |
|---|
| 21 | USE iceini_2 |
|---|
| 22 | USE dom_ice_2 |
|---|
| 23 | |
|---|
| 24 | USE sbc_oce ! Surface boundary condition: ocean fields |
|---|
| 25 | USE sbc_ice ! Surface boundary condition: ice fields |
|---|
| 26 | USE sbcblk_core ! Surface boundary condition: CORE bulk |
|---|
| 27 | USE sbcblk_clio ! Surface boundary condition: CLIO bulk |
|---|
| 28 | USE sbccpl ! Surface boundary condition: coupled interface |
|---|
| 29 | USE albedo |
|---|
| 30 | |
|---|
| 31 | USE phycst ! Define parameters for the routines |
|---|
| 32 | USE eosbn2 ! equation of state |
|---|
| 33 | USE limdyn_2 |
|---|
| 34 | USE limtrp_2 |
|---|
| 35 | USE limdmp_2 |
|---|
| 36 | USE limthd_2 |
|---|
| 37 | USE limsbc_2 ! sea surface boundary condition |
|---|
| 38 | USE limdia_2 |
|---|
| 39 | USE limwri_2 |
|---|
| 40 | USE limrst_2 |
|---|
| 41 | |
|---|
| 42 | USE c1d ! 1D vertical configuration |
|---|
| 43 | |
|---|
| 44 | USE lbclnk ! lateral boundary condition - MPP link |
|---|
| 45 | USE lib_mpp ! MPP library |
|---|
| 46 | USE wrk_nemo ! work arrays |
|---|
| 47 | USE iom ! I/O manager library |
|---|
| 48 | USE in_out_manager ! I/O manager |
|---|
| 49 | USE prtctl ! Print control |
|---|
| 50 | |
|---|
| 51 | # if defined key_agrif |
|---|
| 52 | USE agrif_ice |
|---|
| 53 | USE agrif_lim2_update |
|---|
| 54 | # endif |
|---|
| 55 | |
|---|
| 56 | #if defined key_bdy |
|---|
| 57 | USE bdyice_lim ! unstructured open boundary data (bdy_ice_lim routine) |
|---|
| 58 | #endif |
|---|
| 59 | |
|---|
| 60 | IMPLICIT NONE |
|---|
| 61 | PRIVATE |
|---|
| 62 | |
|---|
| 63 | PUBLIC sbc_ice_lim_2 ! routine called by sbcmod.F90 |
|---|
| 64 | |
|---|
| 65 | !! * Substitutions |
|---|
| 66 | # include "vectopt_loop_substitute.h90" |
|---|
| 67 | !!---------------------------------------------------------------------- |
|---|
| 68 | !! NEMO/OPA 3.3 , NEMO Consortium (2010) |
|---|
| 69 | !! $Id$ |
|---|
| 70 | !! Software governed by the CeCILL licence (NEMOGCM/NEMO_CeCILL.txt) |
|---|
| 71 | !!---------------------------------------------------------------------- |
|---|
| 72 | CONTAINS |
|---|
| 73 | |
|---|
| 74 | SUBROUTINE sbc_ice_lim_2( kt, ksbc ) |
|---|
| 75 | !!--------------------------------------------------------------------- |
|---|
| 76 | !! *** ROUTINE sbc_ice_lim_2 *** |
|---|
| 77 | !! |
|---|
| 78 | !! ** Purpose : update the ocean surface boundary condition via the |
|---|
| 79 | !! Louvain la Neuve Sea Ice Model time stepping |
|---|
| 80 | !! |
|---|
| 81 | !! ** Method : ice model time stepping |
|---|
| 82 | !! - call the ice dynamics routine |
|---|
| 83 | !! - call the ice advection/diffusion routine |
|---|
| 84 | !! - call the ice thermodynamics routine |
|---|
| 85 | !! - call the routine that computes mass and |
|---|
| 86 | !! heat fluxes at the ice/ocean interface |
|---|
| 87 | !! - save the outputs |
|---|
| 88 | !! - save the outputs for restart when necessary |
|---|
| 89 | !! |
|---|
| 90 | !! ** Action : - time evolution of the LIM sea-ice model |
|---|
| 91 | !! - update all sbc variables below sea-ice: |
|---|
| 92 | !! utau, vtau, taum, wndm, qns , qsr, emp , sfx |
|---|
| 93 | !!--------------------------------------------------------------------- |
|---|
| 94 | INTEGER, INTENT(in) :: kt ! ocean time step |
|---|
| 95 | INTEGER, INTENT(in) :: ksbc ! type of sbc ( =3 CLIO bulk ; =4 CORE bulk ; =5 coupled ) |
|---|
| 96 | !! |
|---|
| 97 | INTEGER :: ji, jj ! dummy loop indices |
|---|
| 98 | REAL(wp), DIMENSION(:,:,:), POINTER :: zalb_os ! ice albedo under overcast sky |
|---|
| 99 | REAL(wp), DIMENSION(:,:,:), POINTER :: zalb_cs ! ice albedo under clear sky |
|---|
| 100 | REAL(wp), DIMENSION(:,:,:), POINTER :: zalb_ice ! mean ice albedo |
|---|
| 101 | REAL(wp), DIMENSION(:,:,:), POINTER :: zsist ! ice surface temperature (K) |
|---|
| 102 | REAL(wp), DIMENSION(:,: ), POINTER :: zutau_ice, zvtau_ice |
|---|
| 103 | !!---------------------------------------------------------------------- |
|---|
| 104 | |
|---|
| 105 | IF( kt == nit000 ) THEN |
|---|
| 106 | IF(lwp) WRITE(numout,*) |
|---|
| 107 | IF(lwp) WRITE(numout,*) 'sbc_ice_lim_2 : update ocean surface boudary condition' |
|---|
| 108 | IF(lwp) WRITE(numout,*) '~~~~~~~~~~~~~ via Louvain la Neuve Ice Model (LIM) time stepping' |
|---|
| 109 | ! |
|---|
| 110 | CALL ice_init_2 |
|---|
| 111 | ! |
|---|
| 112 | # if defined key_agrif |
|---|
| 113 | IF( .NOT. Agrif_Root() ) CALL Agrif_InitValues_cont_lim2 ! AGRIF: set the meshes |
|---|
| 114 | # endif |
|---|
| 115 | ENDIF |
|---|
| 116 | |
|---|
| 117 | ! !----------------------! |
|---|
| 118 | IF( MOD( kt-1, nn_fsbc ) == 0 ) THEN ! Ice time-step only ! |
|---|
| 119 | ! !----------------------! |
|---|
| 120 | # if defined key_agrif |
|---|
| 121 | IF( .NOT. Agrif_Root() ) lim_nbstep = MOD(lim_nbstep,Agrif_rhot()& |
|---|
| 122 | &*Agrif_PArent(nn_fsbc)/REAL(nn_fsbc)) + 1 |
|---|
| 123 | # endif |
|---|
| 124 | |
|---|
| 125 | CALL wrk_alloc( jpi,jpj , zutau_ice, zvtau_ice) |
|---|
| 126 | CALL wrk_alloc( jpi,jpj,1, zalb_os, zalb_cs, zalb_ice, zsist ) |
|---|
| 127 | |
|---|
| 128 | ! Bulk Formulea ! |
|---|
| 129 | !----------------! |
|---|
| 130 | ! ... mean surface ocean current at ice dynamics point |
|---|
| 131 | SELECT CASE( cp_ice_msh ) |
|---|
| 132 | CASE( 'I' ) !== B-grid ice dynamics : I-point (i.e. F-point with sea-ice indexation) |
|---|
| 133 | !$OMP PARALLEL DO schedule(static) private(jj, ji) |
|---|
| 134 | DO jj = 2, jpj |
|---|
| 135 | DO ji = 2, jpi ! NO vector opt. possible |
|---|
| 136 | u_oce(ji,jj) = 0.5_wp * ( ssu_m(ji-1,jj ) * umask(ji-1,jj ,1) & |
|---|
| 137 | & + ssu_m(ji-1,jj-1) * umask(ji-1,jj-1,1) ) * tmu(ji,jj) |
|---|
| 138 | v_oce(ji,jj) = 0.5_wp * ( ssv_m(ji ,jj-1) * vmask(ji ,jj-1,1) & |
|---|
| 139 | & + ssv_m(ji-1,jj-1) * vmask(ji-1,jj-1,1) ) * tmu(ji,jj) |
|---|
| 140 | END DO |
|---|
| 141 | END DO |
|---|
| 142 | CALL lbc_lnk( u_oce, 'I', -1. ) ! I-point (i.e. F-point with ice indices) |
|---|
| 143 | CALL lbc_lnk( v_oce, 'I', -1. ) ! I-point (i.e. F-point with ice indices) |
|---|
| 144 | ! |
|---|
| 145 | CASE( 'C' ) !== C-grid ice dynamics : U & V-points (same as ocean) |
|---|
| 146 | !$OMP PARALLEL WORKSHARE |
|---|
| 147 | u_oce(:,:) = ssu_m(:,:) * umask(:,:,1) ! mean surface ocean current at ice velocity point |
|---|
| 148 | v_oce(:,:) = ssv_m(:,:) * vmask(:,:,1) |
|---|
| 149 | !$OMP END PARALLEL WORKSHARE |
|---|
| 150 | ! |
|---|
| 151 | END SELECT |
|---|
| 152 | |
|---|
| 153 | ! ... masked sea surface freezing temperature [Kelvin] (set to rt0 over land) |
|---|
| 154 | CALL eos_fzp( sss_m(:,:), tfu(:,:) ) |
|---|
| 155 | !$OMP PARALLEL WORKSHARE |
|---|
| 156 | tfu(:,:) = tfu(:,:) + rt0 |
|---|
| 157 | |
|---|
| 158 | zsist (:,:,1) = sist (:,:) + rt0 * ( 1. - tmask(:,:,1) ) |
|---|
| 159 | !$OMP END PARALLEL WORKSHARE |
|---|
| 160 | |
|---|
| 161 | ! Ice albedo |
|---|
| 162 | |
|---|
| 163 | CALL albedo_ice( zsist, reshape( hicif, (/jpi,jpj,1/) ), & |
|---|
| 164 | reshape( hsnif, (/jpi,jpj,1/) ), & |
|---|
| 165 | zalb_cs, zalb_os ) |
|---|
| 166 | |
|---|
| 167 | SELECT CASE( ksbc ) |
|---|
| 168 | CASE( jp_core , jp_purecpl ) ! CORE and COUPLED bulk formulations |
|---|
| 169 | |
|---|
| 170 | ! albedo depends on cloud fraction because of non-linear spectral effects |
|---|
| 171 | !$OMP PARALLEL WORKSHARE |
|---|
| 172 | zalb_ice(:,:,:) = ( 1. - cldf_ice ) * zalb_cs(:,:,:) + cldf_ice * zalb_os(:,:,:) |
|---|
| 173 | !$OMP END PARALLEL WORKSHARE |
|---|
| 174 | ! In CLIO the cloud fraction is read in the climatology and the all-sky albedo |
|---|
| 175 | ! (zalb_ice) is computed within the bulk routine |
|---|
| 176 | |
|---|
| 177 | END SELECT |
|---|
| 178 | |
|---|
| 179 | ! ... Sea-ice surface boundary conditions output from bulk formulae : |
|---|
| 180 | ! - utau_ice ! surface ice stress i-component (I-point) [N/m2] |
|---|
| 181 | ! - vtau_ice ! surface ice stress j-component (I-point) [N/m2] |
|---|
| 182 | ! - qns_ice ! non solar heat flux over ice (T-point) [W/m2] |
|---|
| 183 | ! - qsr_ice ! solar heat flux over ice (T-point) [W/m2] |
|---|
| 184 | ! - qla_ice ! latent heat flux over ice (T-point) [W/m2] |
|---|
| 185 | ! - dqns_ice ! non solar heat sensistivity (T-point) [W/m2] |
|---|
| 186 | ! - dqla_ice ! latent heat sensistivity (T-point) [W/m2] |
|---|
| 187 | ! - tprecip ! total precipitation (T-point) [Kg/m2/s] |
|---|
| 188 | ! - sprecip ! solid precipitation (T-point) [Kg/m2/s] |
|---|
| 189 | ! - fr1_i0 ! 1sr fraction of qsr penetration in ice [%] |
|---|
| 190 | ! - fr2_i0 ! 2nd fraction of qsr penetration in ice [%] |
|---|
| 191 | ! |
|---|
| 192 | SELECT CASE( ksbc ) |
|---|
| 193 | CASE( jp_clio ) ! CLIO bulk formulation |
|---|
| 194 | ! CALL blk_ice_clio( zsist, zalb_cs , zalb_os , zalb_ice , & |
|---|
| 195 | ! & utau_ice , vtau_ice , qns_ice , qsr_ice, & |
|---|
| 196 | ! & qla_ice , dqns_ice , dqla_ice , & |
|---|
| 197 | ! & tprecip , sprecip , & |
|---|
| 198 | ! & fr1_i0 , fr2_i0 , cp_ice_msh , jpl ) |
|---|
| 199 | CALL blk_ice_clio_tau |
|---|
| 200 | CALL blk_ice_clio_flx( zsist, zalb_cs, zalb_os, zalb_ice ) |
|---|
| 201 | |
|---|
| 202 | CASE( jp_core ) ! CORE bulk formulation |
|---|
| 203 | CALL blk_ice_core_tau |
|---|
| 204 | CALL blk_ice_core_flx( zsist, zalb_ice ) |
|---|
| 205 | |
|---|
| 206 | CASE( jp_purecpl ) ! Coupled formulation : atmosphere-ice stress only (fluxes provided after ice dynamics) |
|---|
| 207 | CALL sbc_cpl_ice_tau( utau_ice , vtau_ice ) |
|---|
| 208 | END SELECT |
|---|
| 209 | |
|---|
| 210 | IF( ln_mixcpl) THEN |
|---|
| 211 | CALL sbc_cpl_ice_tau( zutau_ice , zvtau_ice ) |
|---|
| 212 | !$OMP PARALLEL WORKSHARE |
|---|
| 213 | utau_ice(:,:) = utau_ice(:,:) * xcplmask(:,:,0) + zutau_ice(:,:) * ( 1. - xcplmask(:,:,0) ) |
|---|
| 214 | vtau_ice(:,:) = vtau_ice(:,:) * xcplmask(:,:,0) + zvtau_ice(:,:) * ( 1. - xcplmask(:,:,0) ) |
|---|
| 215 | !$OMP END PARALLEL WORKSHARE |
|---|
| 216 | ENDIF |
|---|
| 217 | |
|---|
| 218 | CALL iom_put( 'utau_ice', utau_ice ) ! Wind stress over ice along i-axis at I-point |
|---|
| 219 | CALL iom_put( 'vtau_ice', vtau_ice ) ! Wind stress over ice along j-axis at I-point |
|---|
| 220 | |
|---|
| 221 | IF(ln_ctl) THEN ! print mean trends (used for debugging) |
|---|
| 222 | CALL prt_ctl_info( 'Ice Forcings ' ) |
|---|
| 223 | CALL prt_ctl( tab2d_1=tprecip ,clinfo1=' sbc_ice_lim: precip : ', tab2d_2=sprecip , clinfo2=' Snow : ' ) |
|---|
| 224 | CALL prt_ctl( tab2d_1=utau_ice,clinfo1=' sbc_ice_lim: utau_ice: ', tab2d_2=vtau_ice, clinfo2=' vtau_ice: ' ) |
|---|
| 225 | CALL prt_ctl( tab2d_1=sst_m ,clinfo1=' sbc_ice_lim: sst : ', tab2d_2=sss_m , clinfo2=' sss : ' ) |
|---|
| 226 | CALL prt_ctl( tab2d_1=u_oce ,clinfo1=' sbc_ice_lim: u_io : ', tab2d_2=v_oce , clinfo2=' v_io : ' ) |
|---|
| 227 | CALL prt_ctl( tab2d_1=hsnif ,clinfo1=' sbc_ice_lim: hsnif 1: ', tab2d_2=hicif , clinfo2=' hicif : ' ) |
|---|
| 228 | CALL prt_ctl( tab2d_1=frld ,clinfo1=' sbc_ice_lim: frld 1: ', tab2d_2=sist , clinfo2=' sist : ' ) |
|---|
| 229 | ENDIF |
|---|
| 230 | |
|---|
| 231 | ! ---------------- ! |
|---|
| 232 | ! Ice model step ! |
|---|
| 233 | ! ---------------- ! |
|---|
| 234 | numit = numit + nn_fsbc ! Ice model time step |
|---|
| 235 | |
|---|
| 236 | CALL lim_rst_opn_2 ( kt ) ! Open Ice restart file |
|---|
| 237 | IF( .NOT. lk_c1d ) THEN ! Ice dynamics & transport (except in 1D case) |
|---|
| 238 | CALL lim_dyn_2 ( kt ) ! Ice dynamics ( rheology/dynamics ) |
|---|
| 239 | CALL lim_trp_2 ( kt ) ! Ice transport ( Advection/diffusion ) |
|---|
| 240 | IF( ln_limdmp ) CALL lim_dmp_2 ( kt ) ! Ice damping |
|---|
| 241 | #if defined key_bdy |
|---|
| 242 | CALL bdy_ice_lim( kt ) ! bdy ice thermo |
|---|
| 243 | #endif |
|---|
| 244 | END IF |
|---|
| 245 | ! ! Ice surface fluxes in coupled mode |
|---|
| 246 | IF( ln_cpl ) THEN ! pure coupled and mixed forced-coupled configurations |
|---|
| 247 | a_i(:,:,1)=fr_i |
|---|
| 248 | CALL sbc_cpl_ice_flx( frld, & |
|---|
| 249 | ! optional arguments, used only in 'mixed oce-ice' case |
|---|
| 250 | & palbi=zalb_ice, psst=sst_m, pist=zsist ) |
|---|
| 251 | sprecip(:,:) = - emp_ice(:,:) ! Ugly patch, WARNING, in coupled mode, sublimation included in snow (parsub = 0.) |
|---|
| 252 | ENDIF |
|---|
| 253 | CALL lim_thd_2 ( kt ) ! Ice thermodynamics |
|---|
| 254 | CALL lim_sbc_flx_2 ( kt ) ! update surface ocean mass, heat & salt fluxes |
|---|
| 255 | |
|---|
| 256 | IF( .NOT. lk_mpp )THEN |
|---|
| 257 | IF( MOD( kt+nn_fsbc-1, ninfo ) == 0 .OR. ntmoy == 1 ) & |
|---|
| 258 | & CALL lim_dia_2 ( kt ) ! Ice Diagnostics |
|---|
| 259 | ENDIF |
|---|
| 260 | # if ! defined key_iomput |
|---|
| 261 | CALL lim_wri_2 ( kt ) ! Ice outputs |
|---|
| 262 | # endif |
|---|
| 263 | IF( lrst_ice ) CALL lim_rst_write_2( kt ) ! Ice restart file |
|---|
| 264 | ! |
|---|
| 265 | # if defined key_agrif && defined key_lim2 |
|---|
| 266 | IF( .NOT. Agrif_Root() ) CALL agrif_update_lim2( kt ) |
|---|
| 267 | # endif |
|---|
| 268 | ! |
|---|
| 269 | CALL wrk_dealloc( jpi,jpj , zutau_ice, zvtau_ice) |
|---|
| 270 | CALL wrk_dealloc( jpi,jpj,1, zalb_os, zalb_cs, zalb_ice, zsist ) |
|---|
| 271 | ! |
|---|
| 272 | ENDIF ! End sea-ice time step only |
|---|
| 273 | ! |
|---|
| 274 | ! !--------------------------! |
|---|
| 275 | ! ! at all ocean time step ! |
|---|
| 276 | ! !--------------------------! |
|---|
| 277 | ! |
|---|
| 278 | ! ! Update surface ocean stresses (only in ice-dynamic case) |
|---|
| 279 | ! ! otherwise the atm.-ocean stresses are used everywhere |
|---|
| 280 | IF( ln_limdyn ) CALL lim_sbc_tau_2( kt, ub(:,:,1), vb(:,:,1) ) ! using before instantaneous surf. currents |
|---|
| 281 | ! |
|---|
| 282 | END SUBROUTINE sbc_ice_lim_2 |
|---|
| 283 | |
|---|
| 284 | #else |
|---|
| 285 | !!---------------------------------------------------------------------- |
|---|
| 286 | !! Default option Dummy module NO LIM 2.0 sea-ice model |
|---|
| 287 | !!---------------------------------------------------------------------- |
|---|
| 288 | CONTAINS |
|---|
| 289 | SUBROUTINE sbc_ice_lim_2 ( kt, ksbc ) ! Dummy routine |
|---|
| 290 | INTEGER, INTENT(in) :: kt, ksbc |
|---|
| 291 | WRITE(*,*) 'sbc_ice_lim_2: You should not have seen this print! error?', kt, ksbc |
|---|
| 292 | END SUBROUTINE sbc_ice_lim_2 |
|---|
| 293 | #endif |
|---|
| 294 | |
|---|
| 295 | !!====================================================================== |
|---|
| 296 | END MODULE sbcice_lim_2 |
|---|
