New URL for NEMO forge! http://forge.nemo-ocean.eu

Since March 2022 along with NEMO 4.2 release, the code development moved to a self-hosted GitLab.
This present forge is now archived and remained online for history.

sbcrnf.F90 in branches/2016/dev_r6519_HPC_4/NEMOGCM/NEMO/OPA_SRC/SBC – NEMO

Context Navigation

source: branches/2016/dev_r6519_HPC_4/NEMOGCM/NEMO/OPA_SRC/SBC/sbcrnf.F90 @ 7037

Last change on this file since 7037 was 7037, checked in by mocavero, 8 years ago
ORCA2_LIM_PISCES hybrid version update
Property svn:keywords set to `Id`
File size: 29.5 KB

Line
1	MODULE sbcrnf
2	!!======================================================================
3	!! * MODULE sbcrnf *
4	!! Ocean forcing: river runoff
5	!!=====================================================================
6	!! History : OPA ! 2000-11 (R. Hordoir, E. Durand) NetCDF FORMAT
7	!! NEMO 1.0 ! 2002-09 (G. Madec) F90: Free form and module
8	!! 3.0 ! 2006-07 (G. Madec) Surface module
9	!! 3.2 ! 2009-04 (B. Lemaire) Introduce iom_put
10	!! 3.3 ! 2010-10 (R. Furner, G. Madec) runoff distributed over ocean levels
11	!!----------------------------------------------------------------------
12
13	!!----------------------------------------------------------------------
14	!! sbc_rnf : monthly runoffs read in a NetCDF file
15	!! sbc_rnf_init : runoffs initialisation
16	!! rnf_mouth : set river mouth mask
17	!!----------------------------------------------------------------------
18	USE dom_oce ! ocean space and time domain
19	USE phycst ! physical constants
20	USE sbc_oce ! surface boundary condition variables
21	USE sbcisf ! PM we could remove it I think
22	USE closea ! closed seas
23	USE eosbn2 ! Equation Of State
24	!
25	USE in_out_manager ! I/O manager
26	USE fldread ! read input field at current time step
27	USE iom ! I/O module
28	USE lib_mpp ! MPP library
29	USE wrk_nemo ! Memory allocation
30
31	IMPLICIT NONE
32	PRIVATE
33
34	PUBLIC sbc_rnf ! called in sbcmod module
35	PUBLIC sbc_rnf_div ! called in divhor module
36	PUBLIC sbc_rnf_alloc ! called in sbcmod module
37	PUBLIC sbc_rnf_init ! called in sbcmod module
38
39	! !!* namsbc_rnf namelist *
40	CHARACTER(len=100) :: cn_dir !: Root directory for location of rnf files
41	LOGICAL :: ln_rnf_depth !: depth river runoffs attribute specified in a file
42	LOGICAL :: ln_rnf_depth_ini !: depth river runoffs computed at the initialisation
43	REAL(wp) :: rn_rnf_max !: maximum value of the runoff climatologie (ln_rnf_depth_ini =T)
44	REAL(wp) :: rn_dep_max !: depth over which runoffs is spread (ln_rnf_depth_ini =T)
45	INTEGER :: nn_rnf_depth_file !: create (=1) a runoff depth file or not (=0)
46	LOGICAL :: ln_rnf_tem !: temperature river runoffs attribute specified in a file
47	LOGICAL , PUBLIC :: ln_rnf_sal !: salinity river runoffs attribute specified in a file
48	TYPE(FLD_N) , PUBLIC :: sn_rnf !: information about the runoff file to be read
49	TYPE(FLD_N) :: sn_cnf !: information about the runoff mouth file to be read
50	TYPE(FLD_N) :: sn_s_rnf !: information about the salinities of runoff file to be read
51	TYPE(FLD_N) :: sn_t_rnf !: information about the temperatures of runoff file to be read
52	TYPE(FLD_N) :: sn_dep_rnf !: information about the depth which river inflow affects
53	LOGICAL , PUBLIC :: ln_rnf_mouth !: specific treatment in mouths vicinity
54	REAL(wp) :: rn_hrnf !: runoffs, depth over which enhanced vertical mixing is used
55	REAL(wp) , PUBLIC :: rn_avt_rnf !: runoffs, value of the additional vertical mixing coef. [m2/s]
56	REAL(wp) , PUBLIC :: rn_rfact !: multiplicative factor for runoff
57
58	LOGICAL , PUBLIC :: l_rnfcpl = .false. !: runoffs recieved from oasis
59	INTEGER , PUBLIC :: nkrnf = 0 !: nb of levels over which Kz is increased at river mouths
60
61	REAL(wp), PUBLIC, ALLOCATABLE, SAVE, DIMENSION(:,:) :: rnfmsk !: river mouth mask (hori.)
62	REAL(wp), PUBLIC, ALLOCATABLE, SAVE, DIMENSION(:) :: rnfmsk_z !: river mouth mask (vert.)
63	REAL(wp), PUBLIC, ALLOCATABLE, SAVE, DIMENSION(:,:) :: h_rnf !: depth of runoff in m
64	INTEGER, PUBLIC, ALLOCATABLE, SAVE, DIMENSION(:,:) :: nk_rnf !: depth of runoff in model levels
65	REAL(wp), PUBLIC, ALLOCATABLE, SAVE, DIMENSION(:,:,:) :: rnf_tsc_b, rnf_tsc !: before and now T & S runoff contents [K.m/s & PSU.m/s]
66
67	TYPE(FLD), ALLOCATABLE, DIMENSION(:) :: sf_rnf ! structure: river runoff (file information, fields read)
68	TYPE(FLD), ALLOCATABLE, DIMENSION(:) :: sf_s_rnf ! structure: river runoff salinity (file information, fields read)
69	TYPE(FLD), ALLOCATABLE, DIMENSION(:) :: sf_t_rnf ! structure: river runoff temperature (file information, fields read)
70
71	!!----------------------------------------------------------------------
72	!! NEMO/OPA 3.3 , NEMO Consortium (2010)
73	!! $Id$
74	!! Software governed by the CeCILL licence (NEMOGCM/NEMO_CeCILL.txt)
75	!!----------------------------------------------------------------------
76	CONTAINS
77
78	INTEGER FUNCTION sbc_rnf_alloc()
79	!!----------------------------------------------------------------------
80	!! * ROUTINE sbc_rnf_alloc *
81	!!----------------------------------------------------------------------
82	ALLOCATE( rnfmsk(jpi,jpj) , rnfmsk_z(jpk) , &
83	& h_rnf (jpi,jpj) , nk_rnf (jpi,jpj) , &
84	& rnf_tsc_b(jpi,jpj,jpts) , rnf_tsc (jpi,jpj,jpts) , STAT=sbc_rnf_alloc )
85	!
86	IF( lk_mpp ) CALL mpp_sum ( sbc_rnf_alloc )
87	IF( sbc_rnf_alloc > 0 ) CALL ctl_warn('sbc_rnf_alloc: allocation of arrays failed')
88	END FUNCTION sbc_rnf_alloc
89
90
91	SUBROUTINE sbc_rnf( kt )
92	!!----------------------------------------------------------------------
93	!! * ROUTINE sbc_rnf *
94	!!
95	!! ** Purpose : Introduce a climatological run off forcing
96	!!
97	!! ** Method : Set each river mouth with a monthly climatology
98	!! provided from different data.
99	!! CAUTION : upward water flux, runoff forced to be < 0
100	!!
101	!! ** Action : runoff updated runoff field at time-step kt
102	!!----------------------------------------------------------------------
103	INTEGER, INTENT(in) :: kt ! ocean time step
104	!
105	INTEGER :: ji, jj ! dummy loop indices
106	INTEGER :: z_err = 0 ! dummy integer for error handling
107	!!----------------------------------------------------------------------
108	REAL(wp), DIMENSION(:,:), POINTER :: ztfrz ! freezing point used for temperature correction
109	!
110	CALL wrk_alloc( jpi,jpj, ztfrz)
111	!
112	! !-------------------!
113	! ! Update runoff !
114	! !-------------------!
115	!
116	IF( .NOT. l_rnfcpl ) CALL fld_read ( kt, nn_fsbc, sf_rnf ) ! Read Runoffs data and provide it at kt
117	IF( ln_rnf_tem ) CALL fld_read ( kt, nn_fsbc, sf_t_rnf ) ! idem for runoffs temperature if required
118	IF( ln_rnf_sal ) CALL fld_read ( kt, nn_fsbc, sf_s_rnf ) ! idem for runoffs salinity if required
119	!
120	IF( MOD( kt - 1, nn_fsbc ) == 0 ) THEN
121	!
122	IF( .NOT. l_rnfcpl ) rnf(:,:) = rn_rfact * ( sf_rnf(1)%fnow(:,:,1) ) ! updated runoff value at time step kt
123	!
124	! ! set temperature & salinity content of runoffs
125	IF( ln_rnf_tem ) THEN ! use runoffs temperature data
126	!$OMP PARALLEL WORKSHARE
127	rnf_tsc(:,:,jp_tem) = ( sf_t_rnf(1)%fnow(:,:,1) ) * rnf(:,:) * r1_rau0
128	!$OMP END PARALLEL WORKSHARE
129	CALL eos_fzp( sss_m(:,:), ztfrz(:,:) )
130	!$OMP PARALLEL WORKSHARE
131	WHERE( sf_t_rnf(1)%fnow(:,:,1) == -999._wp ) ! if missing data value use SST as runoffs temperature
132	rnf_tsc(:,:,jp_tem) = sst_m(:,:) * rnf(:,:) * r1_rau0
133	END WHERE
134	WHERE( sf_t_rnf(1)%fnow(:,:,1) == -222._wp ) ! where fwf comes from melting of ice shelves or iceberg
135	rnf_tsc(:,:,jp_tem) = ztfrz(:,:) * rnf(:,:) * r1_rau0 - rnf(:,:) * rlfusisf * r1_rau0_rcp
136	END WHERE
137	!$OMP END PARALLEL WORKSHARE
138	ELSE ! use SST as runoffs temperature
139	!$OMP PARALLEL WORKSHARE
140	rnf_tsc(:,:,jp_tem) = sst_m(:,:) * rnf(:,:) * r1_rau0
141	!$OMP END PARALLEL WORKSHARE
142	ENDIF
143	! ! use runoffs salinity data
144	IF( ln_rnf_sal ) THEN
145	!$OMP PARALLEL WORKSHARE
146	rnf_tsc(:,:,jp_sal) = ( sf_s_rnf(1)%fnow(:,:,1) ) * rnf(:,:) * r1_rau0
147	!$OMP END PARALLEL WORKSHARE
148	END IF
149	! ! else use S=0 for runoffs (done one for all in the init)
150	CALL iom_put( "runoffs", rnf ) ! output runoffs arrays
151	ENDIF
152	!
153	! ! ---------------------------------------- !
154	IF( kt == nit000 ) THEN ! set the forcing field at nit000 - 1 !
155	! ! ---------------------------------------- !
156	IF( ln_rstart .AND. & !* Restart: read in restart file
157	& iom_varid( numror, 'rnf_b', ldstop = .FALSE. ) > 0 ) THEN
158	IF(lwp) WRITE(numout,*) ' nit000-1 runoff forcing fields red in the restart file'
159	CALL iom_get( numror, jpdom_autoglo, 'rnf_b', rnf_b ) ! before runoff
160	CALL iom_get( numror, jpdom_autoglo, 'rnf_hc_b', rnf_tsc_b(:,:,jp_tem) ) ! before heat content of runoff
161	CALL iom_get( numror, jpdom_autoglo, 'rnf_sc_b', rnf_tsc_b(:,:,jp_sal) ) ! before salinity content of runoff
162	ELSE !* no restart: set from nit000 values
163	IF(lwp) WRITE(numout,*) ' nit000-1 runoff forcing fields set to nit000'
164	!$OMP PARALLEL WORKSHARE
165	rnf_b (:,: ) = rnf (:,: )
166	rnf_tsc_b(:,:,:) = rnf_tsc(:,:,:)
167	!$OMP END PARALLEL WORKSHARE
168	ENDIF
169	ENDIF
170	! ! ---------------------------------------- !
171	IF( lrst_oce ) THEN ! Write in the ocean restart file !
172	! ! ---------------------------------------- !
173	IF(lwp) WRITE(numout,*)
174	IF(lwp) WRITE(numout,*) 'sbcrnf : runoff forcing fields written in ocean restart file ', &
175	& 'at it= ', kt,' date= ', ndastp
176	IF(lwp) WRITE(numout,*) '~~~~'
177	CALL iom_rstput( kt, nitrst, numrow, 'rnf_b' , rnf )
178	CALL iom_rstput( kt, nitrst, numrow, 'rnf_hc_b', rnf_tsc(:,:,jp_tem) )
179	CALL iom_rstput( kt, nitrst, numrow, 'rnf_sc_b', rnf_tsc(:,:,jp_sal) )
180	ENDIF
181	!
182	CALL wrk_dealloc( jpi,jpj, ztfrz)
183	!
184	END SUBROUTINE sbc_rnf
185
186
187	SUBROUTINE sbc_rnf_div( phdivn )
188	!!----------------------------------------------------------------------
189	!! * ROUTINE sbc_rnf *
190	!!
191	!! ** Purpose : update the horizontal divergence with the runoff inflow
192	!!
193	!! ** Method :
194	!! CAUTION : rnf is positive (inflow) decreasing the
195	!! divergence and expressed in m/s
196	!!
197	!! ** Action : phdivn decreased by the runoff inflow
198	!!----------------------------------------------------------------------
199	REAL(wp), DIMENSION(:,:,:), INTENT(inout) :: phdivn ! horizontal divergence
200	!!
201	INTEGER :: ji, jj, jk ! dummy loop indices
202	REAL(wp) :: zfact ! local scalar
203	!!----------------------------------------------------------------------
204	!
205	zfact = 0.5_wp
206	!
207	IF( ln_rnf_depth .OR. ln_rnf_depth_ini ) THEN !== runoff distributed over several levels ==!
208	IF( ln_linssh ) THEN !* constant volume case : just apply the runoff input flow
209	DO jj = 1, jpj
210	DO ji = 1, jpi
211	!$OMP PARALLEL DO schedule(static) private(jk)
212	DO jk = 1, nk_rnf(ji,jj)
213	phdivn(ji,jj,jk) = phdivn(ji,jj,jk) - ( rnf(ji,jj) + rnf_b(ji,jj) ) * zfact * r1_rau0 / h_rnf(ji,jj)
214	END DO
215	END DO
216	END DO
217	ELSE !* variable volume case
218	!$OMP PARALLEL
219	DO jj = 1, jpj ! update the depth over which runoffs are distributed
220	DO ji = 1, jpi
221	h_rnf(ji,jj) = 0._wp
222	!$OMP DO schedule(static) private(jk)
223	DO jk = 1, nk_rnf(ji,jj) ! recalculates h_rnf to be the depth in metres
224	h_rnf(ji,jj) = h_rnf(ji,jj) + e3t_n(ji,jj,jk) ! to the bottom of the relevant grid box
225	END DO
226	! ! apply the runoff input flow
227	!$OMP DO schedule(static) private(jk)
228	DO jk = 1, nk_rnf(ji,jj)
229	phdivn(ji,jj,jk) = phdivn(ji,jj,jk) - ( rnf(ji,jj) + rnf_b(ji,jj) ) * zfact * r1_rau0 / h_rnf(ji,jj)
230	END DO
231	!$OMP END DO NOWAIT
232	END DO
233	END DO
234	!$OMP END PARALLEL
235	ENDIF
236	ELSE !== runoff put only at the surface ==!
237	!$OMP PARALLEL WORKSHARE
238	h_rnf (:,:) = e3t_n (:,:,1) ! update h_rnf to be depth of top box
239	phdivn(:,:,1) = phdivn(:,:,1) - ( rnf(:,:) + rnf_b(:,:) ) * zfact * r1_rau0 / e3t_n(:,:,1)
240	!$OMP END PARALLEL WORKSHARE
241	ENDIF
242	!
243	END SUBROUTINE sbc_rnf_div
244
245
246	SUBROUTINE sbc_rnf_init
247	!!----------------------------------------------------------------------
248	!! * ROUTINE sbc_rnf_init *
249	!!
250	!! ** Purpose : Initialisation of the runoffs if (ln_rnf=T)
251	!!
252	!! ** Method : - read the runoff namsbc_rnf namelist
253	!!
254	!! ** Action : - read parameters
255	!!----------------------------------------------------------------------
256	CHARACTER(len=32) :: rn_dep_file ! runoff file name
257	INTEGER :: ji, jj, jk, jm ! dummy loop indices
258	INTEGER :: ierror, inum ! temporary integer
259	INTEGER :: ios ! Local integer output status for namelist read
260	INTEGER :: nbrec ! temporary integer
261	REAL(wp) :: zacoef
262	REAL(wp), DIMENSION(12) :: zrec ! times records
263	REAL(wp), DIMENSION(:,:,:), ALLOCATABLE :: zrnfcl
264	REAL(wp), DIMENSION(:,: ), ALLOCATABLE :: zrnf
265	!
266	NAMELIST/namsbc_rnf/ cn_dir , ln_rnf_depth, ln_rnf_tem, ln_rnf_sal, &
267	& sn_rnf, sn_cnf , sn_s_rnf , sn_t_rnf , sn_dep_rnf, &
268	& ln_rnf_mouth , rn_hrnf , rn_avt_rnf, rn_rfact, &
269	& ln_rnf_depth_ini , rn_dep_max , rn_rnf_max, nn_rnf_depth_file
270	!!----------------------------------------------------------------------
271	!
272	! !== allocate runoff arrays
273	IF( sbc_rnf_alloc() /= 0 ) CALL ctl_stop( 'STOP', 'sbc_rnf_alloc : unable to allocate arrays' )
274	!
275	IF( .NOT. ln_rnf ) THEN ! no specific treatment in vicinity of river mouths
276	ln_rnf_mouth = .FALSE. ! default definition needed for example by sbc_ssr or by tra_adv_muscl
277	nkrnf = 0
278	!$OMP PARALLEL WORKSHARE
279	rnf (:,:) = 0.0_wp
280	rnf_b (:,:) = 0.0_wp
281	rnfmsk (:,:) = 0.0_wp
282	rnfmsk_z(:) = 0.0_wp
283	!$OMP END PARALLEL WORKSHARE
284	RETURN
285	ENDIF
286	!
287	! ! ============
288	! ! Namelist
289	! ! ============
290	!
291	REWIND( numnam_ref ) ! Namelist namsbc_rnf in reference namelist : Runoffs
292	READ ( numnam_ref, namsbc_rnf, IOSTAT = ios, ERR = 901)
293	901 IF( ios /= 0 ) CALL ctl_nam ( ios , 'namsbc_rnf in reference namelist', lwp )
294
295	REWIND( numnam_cfg ) ! Namelist namsbc_rnf in configuration namelist : Runoffs
296	READ ( numnam_cfg, namsbc_rnf, IOSTAT = ios, ERR = 902 )
297	902 IF( ios /= 0 ) CALL ctl_nam ( ios , 'namsbc_rnf in configuration namelist', lwp )
298	IF(lwm) WRITE ( numond, namsbc_rnf )
299	!
300	! ! Control print
301	IF(lwp) THEN
302	WRITE(numout,*)
303	WRITE(numout,*) 'sbc_rnf : runoff '
304	WRITE(numout,*) '~~~~~~~ '
305	WRITE(numout,*) ' Namelist namsbc_rnf'
306	WRITE(numout,*) ' specific river mouths treatment ln_rnf_mouth = ', ln_rnf_mouth
307	WRITE(numout,*) ' river mouth additional Kz rn_avt_rnf = ', rn_avt_rnf
308	WRITE(numout,*) ' depth of river mouth additional mixing rn_hrnf = ', rn_hrnf
309	WRITE(numout,*) ' multiplicative factor for runoff rn_rfact = ', rn_rfact
310	ENDIF
311	! ! ==================
312	! ! Type of runoff
313	! ! ==================
314	!
315	IF( .NOT. l_rnfcpl ) THEN
316	ALLOCATE( sf_rnf(1), STAT=ierror ) ! Create sf_rnf structure (runoff inflow)
317	IF(lwp) WRITE(numout,*)
318	IF(lwp) WRITE(numout,*) ' runoffs inflow read in a file'
319	IF( ierror > 0 ) THEN
320	CALL ctl_stop( 'sbc_rnf: unable to allocate sf_rnf structure' ) ; RETURN
321	ENDIF
322	ALLOCATE( sf_rnf(1)%fnow(jpi,jpj,1) )
323	IF( sn_rnf%ln_tint ) ALLOCATE( sf_rnf(1)%fdta(jpi,jpj,1,2) )
324	CALL fld_fill( sf_rnf, (/ sn_rnf /), cn_dir, 'sbc_rnf_init', 'read runoffs data', 'namsbc_rnf' )
325	ENDIF
326	!
327	IF( ln_rnf_tem ) THEN ! Create (if required) sf_t_rnf structure
328	IF(lwp) WRITE(numout,*)
329	IF(lwp) WRITE(numout,*) ' runoffs temperatures read in a file'
330	ALLOCATE( sf_t_rnf(1), STAT=ierror )
331	IF( ierror > 0 ) THEN
332	CALL ctl_stop( 'sbc_rnf_init: unable to allocate sf_t_rnf structure' ) ; RETURN
333	ENDIF
334	ALLOCATE( sf_t_rnf(1)%fnow(jpi,jpj,1) )
335	IF( sn_t_rnf%ln_tint ) ALLOCATE( sf_t_rnf(1)%fdta(jpi,jpj,1,2) )
336	CALL fld_fill (sf_t_rnf, (/ sn_t_rnf /), cn_dir, 'sbc_rnf_init', 'read runoff temperature data', 'namsbc_rnf' )
337	ENDIF
338	!
339	IF( ln_rnf_sal ) THEN ! Create (if required) sf_s_rnf and sf_t_rnf structures
340	IF(lwp) WRITE(numout,*)
341	IF(lwp) WRITE(numout,*) ' runoffs salinities read in a file'
342	ALLOCATE( sf_s_rnf(1), STAT=ierror )
343	IF( ierror > 0 ) THEN
344	CALL ctl_stop( 'sbc_rnf_init: unable to allocate sf_s_rnf structure' ) ; RETURN
345	ENDIF
346	ALLOCATE( sf_s_rnf(1)%fnow(jpi,jpj,1) )
347	IF( sn_s_rnf%ln_tint ) ALLOCATE( sf_s_rnf(1)%fdta(jpi,jpj,1,2) )
348	CALL fld_fill (sf_s_rnf, (/ sn_s_rnf /), cn_dir, 'sbc_rnf_init', 'read runoff salinity data', 'namsbc_rnf' )
349	ENDIF
350	!
351	IF( ln_rnf_depth ) THEN ! depth of runoffs set from a file
352	IF(lwp) WRITE(numout,*)
353	IF(lwp) WRITE(numout,*) ' runoffs depth read in a file'
354	rn_dep_file = TRIM( cn_dir )//TRIM( sn_dep_rnf%clname )
355	IF( .NOT. sn_dep_rnf%ln_clim ) THEN ; WRITE(rn_dep_file, '(a,"_y",i4)' ) TRIM( rn_dep_file ), nyear ! add year
356	IF( sn_dep_rnf%cltype == 'monthly' ) WRITE(rn_dep_file, '(a,"m",i2)' ) TRIM( rn_dep_file ), nmonth ! add month
357	ENDIF
358	CALL iom_open ( rn_dep_file, inum ) ! open file
359	CALL iom_get ( inum, jpdom_data, sn_dep_rnf%clvar, h_rnf ) ! read the river mouth array
360	CALL iom_close( inum ) ! close file
361	!
362	nk_rnf(:,:) = 0 ! set the number of level over which river runoffs are applied
363	DO jj = 1, jpj
364	DO ji = 1, jpi
365	IF( h_rnf(ji,jj) > 0._wp ) THEN
366	jk = 2
367	DO WHILE ( jk /= mbkt(ji,jj) .AND. gdept_0(ji,jj,jk) < h_rnf(ji,jj) ) ; jk = jk + 1
368	END DO
369	nk_rnf(ji,jj) = jk
370	ELSEIF( h_rnf(ji,jj) == -1._wp ) THEN ; nk_rnf(ji,jj) = 1
371	ELSEIF( h_rnf(ji,jj) == -999._wp ) THEN ; nk_rnf(ji,jj) = mbkt(ji,jj)
372	ELSE
373	CALL ctl_stop( 'sbc_rnf_init: runoff depth not positive, and not -999 or -1, rnf value in file fort.999' )
374	WRITE(999,*) 'ji, jj, h_rnf(ji,jj) :', ji, jj, h_rnf(ji,jj)
375	ENDIF
376	END DO
377	END DO
378	DO jj = 1, jpj ! set the associated depth
379	DO ji = 1, jpi
380	h_rnf(ji,jj) = 0._wp
381	!$OMP PARALLEL DO schedule(static) private(jk)
382	DO jk = 1, nk_rnf(ji,jj)
383	h_rnf(ji,jj) = h_rnf(ji,jj) + e3t_n(ji,jj,jk)
384	END DO
385	END DO
386	END DO
387	!
388	ELSE IF( ln_rnf_depth_ini ) THEN ! runoffs applied at the surface
389	!
390	IF(lwp) WRITE(numout,*)
391	IF(lwp) WRITE(numout,*) ' depth of runoff computed once from max value of runoff'
392	IF(lwp) WRITE(numout,*) ' max value of the runoff climatologie (over global domain) rn_rnf_max = ', rn_rnf_max
393	IF(lwp) WRITE(numout,*) ' depth over which runoffs is spread rn_dep_max = ', rn_dep_max
394	IF(lwp) WRITE(numout,*) ' create (=1) a runoff depth file or not (=0) nn_rnf_depth_file = ', nn_rnf_depth_file
395
396	CALL iom_open( TRIM( sn_rnf%clname ), inum ) ! open runoff file
397	CALL iom_gettime( inum, zrec, kntime=nbrec)
398	ALLOCATE( zrnfcl(jpi,jpj,nbrec) ) ; ALLOCATE( zrnf(jpi,jpj) )
399	DO jm = 1, nbrec
400	CALL iom_get( inum, jpdom_data, TRIM( sn_rnf%clvar ), zrnfcl(:,:,jm), jm )
401	END DO
402	CALL iom_close( inum )
403	zrnf(:,:) = MAXVAL( zrnfcl(:,:,:), DIM=3 ) ! maximum value in time
404	DEALLOCATE( zrnfcl )
405	!
406	h_rnf(:,:) = 1.
407	!
408	zacoef = rn_dep_max / rn_rnf_max ! coef of linear relation between runoff and its depth (150m for max of runoff)
409	!
410	WHERE( zrnf(:,:) > 0._wp ) h_rnf(:,:) = zacoef * zrnf(:,:) ! compute depth for all runoffs
411	!
412	DO jj = 1, jpj ! take in account min depth of ocean rn_hmin
413	DO ji = 1, jpi
414	IF( zrnf(ji,jj) > 0._wp ) THEN
415	jk = mbkt(ji,jj)
416	h_rnf(ji,jj) = MIN( h_rnf(ji,jj), gdept_0(ji,jj,jk ) )
417	ENDIF
418	END DO
419	END DO
420	!
421	nk_rnf(:,:) = 0 ! number of levels on which runoffs are distributed
422	DO jj = 1, jpj
423	DO ji = 1, jpi
424	IF( zrnf(ji,jj) > 0._wp ) THEN
425	jk = 2
426	DO WHILE ( jk /= mbkt(ji,jj) .AND. gdept_0(ji,jj,jk) < h_rnf(ji,jj) ) ; jk = jk + 1
427	END DO
428	nk_rnf(ji,jj) = jk
429	ELSE
430	nk_rnf(ji,jj) = 1
431	ENDIF
432	END DO
433	END DO
434	!
435	DEALLOCATE( zrnf )
436	!
437	DO jj = 1, jpj ! set the associated depth
438	DO ji = 1, jpi
439	h_rnf(ji,jj) = 0._wp
440	!$OMP PARALLEL DO schedule(static) private(jk)
441	DO jk = 1, nk_rnf(ji,jj)
442	h_rnf(ji,jj) = h_rnf(ji,jj) + e3t_n(ji,jj,jk)
443	END DO
444	END DO
445	END DO
446	!
447	IF( nn_rnf_depth_file == 1 ) THEN ! save output nb levels for runoff
448	IF(lwp) WRITE(numout,*) ' create runoff depht file'
449	CALL iom_open ( TRIM( sn_dep_rnf%clname ), inum, ldwrt = .TRUE., kiolib = jprstlib )
450	CALL iom_rstput( 0, 0, inum, 'rodepth', h_rnf )
451	CALL iom_close ( inum )
452	ENDIF
453	ELSE ! runoffs applied at the surface
454	nk_rnf(:,:) = 1
455	h_rnf (:,:) = e3t_n(:,:,1)
456	ENDIF
457	!
458	!$OMP PARALLEL WORKSHARE
459	rnf(:,:) = 0._wp ! runoff initialisation
460	rnf_tsc(:,:,:) = 0._wp ! runoffs temperature & salinty contents initilisation
461	!$OMP END PARALLEL WORKSHARE
462	!
463	! ! ========================
464	! ! River mouth vicinity
465	! ! ========================
466	!
467	IF( ln_rnf_mouth ) THEN ! Specific treatment in vicinity of river mouths :
468	! ! - Increase Kz in surface layers ( rn_hrnf > 0 )
469	! ! - set to zero SSS damping (ln_ssr=T)
470	! ! - mixed upstream-centered (ln_traadv_cen2=T)
471	!
472	IF ( ln_rnf_depth ) CALL ctl_warn( 'sbc_rnf_init: increased mixing turned on but effects may already', &
473	& 'be spread through depth by ln_rnf_depth' )
474	!
475	nkrnf = 0 ! Number of level over which Kz increase
476	IF( rn_hrnf > 0._wp ) THEN
477	nkrnf = 2
478	DO WHILE( nkrnf /= jpkm1 .AND. gdepw_1d(nkrnf+1) < rn_hrnf ) ; nkrnf = nkrnf + 1
479	END DO
480	IF( ln_sco ) CALL ctl_warn( 'sbc_rnf: number of levels over which Kz is increased is computed for zco...' )
481	ENDIF
482	IF(lwp) WRITE(numout,*)
483	IF(lwp) WRITE(numout,*) ' Specific treatment used in vicinity of river mouths :'
484	IF(lwp) WRITE(numout,*) ' - Increase Kz in surface layers (if rn_hrnf > 0 )'
485	IF(lwp) WRITE(numout,*) ' by ', rn_avt_rnf,' m2/s over ', nkrnf, ' w-levels'
486	IF(lwp) WRITE(numout,*) ' - set to zero SSS damping (if ln_ssr=T)'
487	IF(lwp) WRITE(numout,*) ' - mixed upstream-centered (if ln_traadv_cen2=T)'
488	!
489	CALL rnf_mouth ! set river mouth mask
490	!
491	ELSE ! No treatment at river mouths
492	IF(lwp) WRITE(numout,*)
493	IF(lwp) WRITE(numout,*) ' No specific treatment at river mouths'
494	rnfmsk (:,:) = 0._wp
495	rnfmsk_z(:) = 0._wp
496	nkrnf = 0
497	ENDIF
498	!
499	END SUBROUTINE sbc_rnf_init
500
501
502	SUBROUTINE rnf_mouth
503	!!----------------------------------------------------------------------
504	!! * ROUTINE rnf_mouth *
505	!!
506	!! ** Purpose : define the river mouths mask
507	!!
508	!! ** Method : read the river mouth mask (=0/1) in the river runoff
509	!! climatological file. Defined a given vertical structure.
510	!! CAUTION, the vertical structure is hard coded on the
511	!! first 5 levels.
512	!! This fields can be used to:
513	!! - set an upstream advection scheme
514	!! (ln_rnf_mouth=T and ln_traadv_cen2=T)
515	!! - increase vertical on the top nn_krnf vertical levels
516	!! at river runoff input grid point (nn_krnf>=2, see step.F90)
517	!! - set to zero SSS restoring flux at river mouth grid points
518	!!
519	!! ** Action : rnfmsk set to 1 at river runoff input, 0 elsewhere
520	!! rnfmsk_z vertical structure
521	!!----------------------------------------------------------------------
522	INTEGER :: inum ! temporary integers
523	CHARACTER(len=140) :: cl_rnfile ! runoff file name
524	!!----------------------------------------------------------------------
525	!
526	IF(lwp) WRITE(numout,*)
527	IF(lwp) WRITE(numout,*) 'rnf_mouth : river mouth mask'
528	IF(lwp) WRITE(numout,*) '~~~~~~~~~ '
529	!
530	cl_rnfile = TRIM( cn_dir )//TRIM( sn_cnf%clname )
531	IF( .NOT. sn_cnf%ln_clim ) THEN ; WRITE(cl_rnfile, '(a,"_y",i4)' ) TRIM( cl_rnfile ), nyear ! add year
532	IF( sn_cnf%cltype == 'monthly' ) WRITE(cl_rnfile, '(a,"m",i2)' ) TRIM( cl_rnfile ), nmonth ! add month
533	ENDIF
534	!
535	! horizontal mask (read in NetCDF file)
536	CALL iom_open ( cl_rnfile, inum ) ! open file
537	CALL iom_get ( inum, jpdom_data, sn_cnf%clvar, rnfmsk ) ! read the river mouth array
538	CALL iom_close( inum ) ! close file
539	!
540	IF( nn_closea == 1 ) CALL clo_rnf( rnfmsk ) ! closed sea inflow set as ruver mouth
541	!
542	rnfmsk_z(:) = 0._wp ! vertical structure
543	rnfmsk_z(1) = 1.0
544	rnfmsk_z(2) = 1.0 ! **********
545	rnfmsk_z(3) = 0.5 ! HARD CODED on the 5 first levels
546	rnfmsk_z(4) = 0.25 ! **********
547	rnfmsk_z(5) = 0.125
548	!
549	END SUBROUTINE rnf_mouth
550
551	!!======================================================================
552	END MODULE sbcrnf

Note: See TracBrowser for help on using the repository browser.

Download in other formats: