New URL for NEMO forge!   http://forge.nemo-ocean.eu

Since March 2022 along with NEMO 4.2 release, the code development moved to a self-hosted GitLab.
This present forge is now archived and remained online for history.
sbcssm.F90 in branches/2016/dev_r6519_HPC_4/NEMOGCM/NEMO/OPA_SRC/SBC – NEMO

source: branches/2016/dev_r6519_HPC_4/NEMOGCM/NEMO/OPA_SRC/SBC/sbcssm.F90 @ 6748

Last change on this file since 6748 was 6748, checked in by mocavero, 8 years ago

GYRE hybrid parallelization
  • Property svn:keywords set to Id
File size: 14.3 KB
Line 
1MODULE sbcssm
2   !!======================================================================
3   !!                       ***  MODULE  sbcssm  ***
4   !! Surface module :  provide time-mean ocean surface variables
5   !!======================================================================
6   !! History :  9.0  ! 2006-07  (G. Madec)  Original code
7   !!            3.3  ! 2010-10  (C. Bricaud, G. Madec)  add the Patm forcing for sea-ice
8   !!            3.7  ! 2015-11  (G. Madec)  non linear free surface by default: e3t_m always computed
9   !!----------------------------------------------------------------------
10
11   !!----------------------------------------------------------------------
12   !!   sbc_ssm       : calculate sea surface mean currents, temperature, 
13   !!                   and salinity over nn_fsbc time-step
14   !!----------------------------------------------------------------------
15   USE oce            ! ocean dynamics and tracers
16   USE dom_oce        ! ocean space and time domain
17   USE sbc_oce        ! surface boundary condition: ocean fields
18   USE sbcapr         ! surface boundary condition: atmospheric pressure
19   USE eosbn2         ! equation of state and related derivatives
20   !
21   USE in_out_manager ! I/O manager
22   USE prtctl         ! Print control
23   USE iom            ! IOM library
24
25   IMPLICIT NONE
26   PRIVATE
27
28   PUBLIC   sbc_ssm        ! routine called by step.F90
29   PUBLIC   sbc_ssm_init   ! routine called by sbcmod.F90
30
31   LOGICAL, SAVE ::   l_ssm_mean = .FALSE.   ! keep track of whether means have been read from restart file
32   
33   !!----------------------------------------------------------------------
34   !! NEMO/OPA 3.3 , NEMO Consortium (2010)
35   !! $Id$
36   !! Software governed by the CeCILL licence     (NEMOGCM/NEMO_CeCILL.txt)
37   !!----------------------------------------------------------------------
38CONTAINS
39
40   SUBROUTINE sbc_ssm( kt )
41      !!---------------------------------------------------------------------
42      !!                     ***  ROUTINE sbc_oce  ***
43      !!                     
44      !! ** Purpose :   provide ocean surface variable to sea-surface boundary
45      !!                condition computation
46      !!               
47      !! ** Method  :   compute mean surface velocity (2 components at U and
48      !!      V-points) [m/s], temperature [Celcius] and salinity [psu] over
49      !!      the periode (kt - nn_fsbc) to kt
50      !!         Note that the inverse barometer ssh (i.e. ssh associated with Patm)
51      !!      is add to ssh_m when ln_apr_dyn = T. Required for sea-ice dynamics.
52      !!---------------------------------------------------------------------
53      INTEGER, INTENT(in) ::   kt   ! ocean time step
54      !
55      INTEGER  ::   ji, jj               ! loop index
56      REAL(wp) ::   zcoef, zf_sbc       ! local scalar
57      REAL(wp), DIMENSION(jpi,jpj,jpts) :: zts
58      !!---------------------------------------------------------------------
59      !
60      !                                        !* surface T-, U-, V- ocean level variables (T, S, depth, velocity)
61!$OMP PARALLEL DO schedule(static) private(jj, ji)
62      DO jj = 1, jpj
63         DO ji = 1, jpi
64            zts(ji,jj,jp_tem) = tsn(ji,jj,mikt(ji,jj),jp_tem)
65            zts(ji,jj,jp_sal) = tsn(ji,jj,mikt(ji,jj),jp_sal)
66         END DO
67      END DO
68      !
69      IF( nn_fsbc == 1 ) THEN                             !   Instantaneous surface fields        !
70         !                                                ! ---------------------------------------- !
71!$OMP PARALLEL WORKSHARE
72         ssu_m(:,:) = ub(:,:,1)
73         ssv_m(:,:) = vb(:,:,1)
74!$OMP END PARALLEL WORKSHARE
75         IF( l_useCT )  THEN    ;   sst_m(:,:) = eos_pt_from_ct( zts(:,:,jp_tem), zts(:,:,jp_sal) )
76         ELSE                    ;   sst_m(:,:) = zts(:,:,jp_tem)
77         ENDIF
78!$OMP PARALLEL WORKSHARE
79         sss_m(:,:) = zts(:,:,jp_sal)
80!$OMP END PARALLEL WORKSHARE
81         !                          ! removed inverse barometer ssh when Patm forcing is used (for sea-ice dynamics)
82         IF( ln_apr_dyn ) THEN 
83!$OMP PARALLEL WORKSHARE
84   ssh_m(:,:) = sshn(:,:) - 0.5 * ( ssh_ib(:,:) + ssh_ibb(:,:) )
85!$OMP END PARALLEL WORKSHARE
86         ELSE                   
87!$OMP PARALLEL WORKSHARE
88   ssh_m(:,:) = sshn(:,:)
89!$OMP END PARALLEL WORKSHARE
90         ENDIF
91         !
92!$OMP PARALLEL WORKSHARE
93         e3t_m(:,:) = e3t_n(:,:,1)
94         !
95         frq_m(:,:) = fraqsr_1lev(:,:)
96!$OMP END PARALLEL WORKSHARE
97         !
98      ELSE
99         !                                                ! ----------------------------------------------- !
100         IF( kt == nit000 .AND. .NOT. l_ssm_mean ) THEN   !   Initialisation: 1st time-step, no input means !
101            !                                             ! ----------------------------------------------- !
102            IF(lwp) WRITE(numout,*)
103            IF(lwp) WRITE(numout,*) '~~~~~~~   mean fields initialised to instantaneous values'
104            zcoef = REAL( nn_fsbc - 1, wp )
105!$OMP PARALLEL WORKSHARE
106            ssu_m(:,:) = zcoef * ub(:,:,1)
107            ssv_m(:,:) = zcoef * vb(:,:,1)
108!$OMP END PARALLEL WORKSHARE
109            IF( l_useCT )  THEN    ;   sst_m(:,:) = zcoef * eos_pt_from_ct( zts(:,:,jp_tem), zts(:,:,jp_sal) )
110            ELSE                    ;   sst_m(:,:) = zcoef * zts(:,:,jp_tem)
111            ENDIF
112!$OMP PARALLEL WORKSHARE
113            sss_m(:,:) = zcoef * zts(:,:,jp_sal)
114!$OMP END PARALLEL WORKSHARE
115            !                          ! removed inverse barometer ssh when Patm forcing is used (for sea-ice dynamics)
116            IF( ln_apr_dyn ) THEN   
117!$OMP PARALLEL WORKSHARE
118   ssh_m(:,:) = zcoef * ( sshn(:,:) - 0.5 * ( ssh_ib(:,:) + ssh_ibb(:,:) ) )
119!$OMP END PARALLEL WORKSHARE
120            ELSE                   
121!$OMP PARALLEL WORKSHARE
122   ssh_m(:,:) = zcoef * sshn(:,:)
123!$OMP END PARALLEL WORKSHARE
124            ENDIF
125            !
126!$OMP PARALLEL WORKSHARE
127            e3t_m(:,:) = zcoef * e3t_n(:,:,1)
128            !
129            frq_m(:,:) = zcoef * fraqsr_1lev(:,:)
130!$OMP END PARALLEL WORKSHARE
131            !                                             ! ---------------------------------------- !
132         ELSEIF( MOD( kt - 2 , nn_fsbc ) == 0 ) THEN      !   Initialisation: New mean computation   !
133            !                                             ! ---------------------------------------- !
134!$OMP PARALLEL WORKSHARE
135            ssu_m(:,:) = 0._wp     ! reset to zero ocean mean sbc fields
136            ssv_m(:,:) = 0._wp
137            sst_m(:,:) = 0._wp
138            sss_m(:,:) = 0._wp
139            ssh_m(:,:) = 0._wp
140            e3t_m(:,:) = 0._wp
141            frq_m(:,:) = 0._wp
142!$OMP END PARALLEL WORKSHARE
143         ENDIF
144         !                                                ! ---------------------------------------- !
145         !                                                !        Cumulate at each time step        !
146         !                                                ! ---------------------------------------- !
147!$OMP PARALLEL WORKSHARE
148         ssu_m(:,:) = ssu_m(:,:) + ub(:,:,1)
149         ssv_m(:,:) = ssv_m(:,:) + vb(:,:,1)
150!$OMP END PARALLEL WORKSHARE
151         IF( l_useCT )  THEN    ;   sst_m(:,:) = sst_m(:,:) + eos_pt_from_ct( zts(:,:,jp_tem), zts(:,:,jp_sal) )
152         ELSE                    ;   sst_m(:,:) = sst_m(:,:) + zts(:,:,jp_tem)
153         ENDIF
154!$OMP PARALLEL WORKSHARE
155         sss_m(:,:) = sss_m(:,:) + zts(:,:,jp_sal)
156!$OMP END PARALLEL WORKSHARE
157         !                          ! removed inverse barometer ssh when Patm forcing is used (for sea-ice dynamics)
158         IF( ln_apr_dyn ) THEN   
159!$OMP PARALLEL WORKSHARE
160   ssh_m(:,:) = ssh_m(:,:) + sshn(:,:) - 0.5 * ( ssh_ib(:,:) + ssh_ibb(:,:) )
161!$OMP END PARALLEL WORKSHARE
162         ELSE                   
163!$OMP PARALLEL WORKSHARE
164   ssh_m(:,:) = ssh_m(:,:) + sshn(:,:)
165!$OMP END PARALLEL WORKSHARE
166         ENDIF
167         !
168!$OMP PARALLEL WORKSHARE
169         e3t_m(:,:) = e3t_m(:,:) + e3t_n(:,:,1)
170         !
171         frq_m(:,:) = frq_m(:,:) + fraqsr_1lev(:,:)
172!$OMP END PARALLEL WORKSHARE
173
174         !                                                ! ---------------------------------------- !
175         IF( MOD( kt - 1 , nn_fsbc ) == 0 ) THEN          !   Mean value at each nn_fsbc time-step   !
176            !                                             ! ---------------------------------------- !
177            zcoef = 1. / REAL( nn_fsbc, wp )
178!$OMP PARALLEL WORKSHARE
179            sst_m(:,:) = sst_m(:,:) * zcoef     ! mean SST             [Celcius]
180            sss_m(:,:) = sss_m(:,:) * zcoef     ! mean SSS             [psu]
181            ssu_m(:,:) = ssu_m(:,:) * zcoef     ! mean suface current  [m/s]
182            ssv_m(:,:) = ssv_m(:,:) * zcoef     !
183            ssh_m(:,:) = ssh_m(:,:) * zcoef     ! mean SSH             [m]
184            e3t_m(:,:) = e3t_m(:,:) * zcoef     ! mean vertical scale factor [m]
185            frq_m(:,:) = frq_m(:,:) * zcoef     ! mean fraction of solar net radiation absorbed in the 1st T level [-]
186!$OMP END PARALLEL WORKSHARE
187            !
188         ENDIF
189         !                                                ! ---------------------------------------- !
190         IF( lrst_oce ) THEN                              !      Write in the ocean restart file     !
191            !                                             ! ---------------------------------------- !
192            IF(lwp) WRITE(numout,*)
193            IF(lwp) WRITE(numout,*) 'sbc_ssm : sea surface mean fields written in ocean restart file ',   &
194               &                    'at it= ', kt,' date= ', ndastp
195            IF(lwp) WRITE(numout,*) '~~~~~~~'
196            zf_sbc = REAL( nn_fsbc, wp )
197            CALL iom_rstput( kt, nitrst, numrow, 'nn_fsbc', zf_sbc )    ! sbc frequency
198            CALL iom_rstput( kt, nitrst, numrow, 'ssu_m'  , ssu_m  )    ! sea surface mean fields
199            CALL iom_rstput( kt, nitrst, numrow, 'ssv_m'  , ssv_m  )
200            CALL iom_rstput( kt, nitrst, numrow, 'sst_m'  , sst_m  )
201            CALL iom_rstput( kt, nitrst, numrow, 'sss_m'  , sss_m  )
202            CALL iom_rstput( kt, nitrst, numrow, 'ssh_m'  , ssh_m  )
203            CALL iom_rstput( kt, nitrst, numrow, 'e3t_m'  , e3t_m  )
204            CALL iom_rstput( kt, nitrst, numrow, 'frq_m'  , frq_m  )
205            !
206         ENDIF
207         !
208      ENDIF
209      !
210      IF( MOD( kt - 1 , nn_fsbc ) == 0 ) THEN          !   Mean value at each nn_fsbc time-step   !
211         CALL iom_put( 'ssu_m', ssu_m )
212         CALL iom_put( 'ssv_m', ssv_m )
213         CALL iom_put( 'sst_m', sst_m )
214         CALL iom_put( 'sss_m', sss_m )
215         CALL iom_put( 'ssh_m', ssh_m )
216         CALL iom_put( 'e3t_m', e3t_m )
217         CALL iom_put( 'frq_m', frq_m )
218      ENDIF
219      !
220   END SUBROUTINE sbc_ssm
221
222
223   SUBROUTINE sbc_ssm_init
224      !!----------------------------------------------------------------------
225      !!                  ***  ROUTINE sbc_ssm_init  ***
226      !!
227      !! ** Purpose :   Initialisation of the sbc data
228      !!
229      !! ** Action  : - read parameters
230      !!----------------------------------------------------------------------
231      REAL(wp) ::   zcoef, zf_sbc   ! local scalar
232      !!----------------------------------------------------------------------
233      !
234      IF( nn_fsbc == 1 ) THEN
235         !
236         IF(lwp) WRITE(numout,*)
237         IF(lwp) WRITE(numout,*) 'sbc_ssm : sea surface mean fields, nn_fsbc=1 : instantaneous values'
238         IF(lwp) WRITE(numout,*) '~~~~~~~ '
239         !
240      ELSE
241         !               
242         IF(lwp) WRITE(numout,*)
243         IF(lwp) WRITE(numout,*) 'sbc_ssm : sea surface mean fields'
244         IF(lwp) WRITE(numout,*) '~~~~~~~ '
245         !
246         IF( ln_rstart .AND. iom_varid( numror, 'nn_fsbc', ldstop = .FALSE. ) > 0 ) THEN
247            l_ssm_mean = .TRUE.
248            CALL iom_get( numror               , 'nn_fsbc', zf_sbc )    ! sbc frequency of previous run
249            CALL iom_get( numror, jpdom_autoglo, 'ssu_m'  , ssu_m  )    ! sea surface mean velocity    (U-point)
250            CALL iom_get( numror, jpdom_autoglo, 'ssv_m'  , ssv_m  )    !   "         "    velocity    (V-point)
251            CALL iom_get( numror, jpdom_autoglo, 'sst_m'  , sst_m  )    !   "         "    temperature (T-point)
252            CALL iom_get( numror, jpdom_autoglo, 'sss_m'  , sss_m  )    !   "         "    salinity    (T-point)
253            CALL iom_get( numror, jpdom_autoglo, 'ssh_m'  , ssh_m  )    !   "         "    height      (T-point)
254            CALL iom_get( numror, jpdom_autoglo, 'e3t_m'  , e3t_m  )    ! 1st level thickness          (T-point)
255            ! fraction of solar net radiation absorbed in 1st T level
256            IF( iom_varid( numror, 'frq_m', ldstop = .FALSE. ) > 0 ) THEN
257               CALL iom_get( numror, jpdom_autoglo, 'frq_m'  , frq_m  )
258            ELSE
259               frq_m(:,:) = 1._wp   ! default definition
260            ENDIF
261            !
262            IF( zf_sbc /= REAL( nn_fsbc, wp ) ) THEN      ! nn_fsbc has changed between 2 runs
263               IF(lwp) WRITE(numout,*) '~~~~~~~   restart with a change in the frequency of mean ',   &
264                  &                    'from ', zf_sbc, ' to ', nn_fsbc 
265               zcoef = REAL( nn_fsbc - 1, wp ) / zf_sbc 
266!$OMP PARALLEL WORKSHARE
267               ssu_m(:,:) = zcoef * ssu_m(:,:) 
268               ssv_m(:,:) = zcoef * ssv_m(:,:)
269               sst_m(:,:) = zcoef * sst_m(:,:)
270               sss_m(:,:) = zcoef * sss_m(:,:)
271               ssh_m(:,:) = zcoef * ssh_m(:,:)
272               e3t_m(:,:) = zcoef * e3t_m(:,:)
273               frq_m(:,:) = zcoef * frq_m(:,:)
274!$OMP END PARALLEL WORKSHARE
275            ELSE
276               IF(lwp) WRITE(numout,*) '~~~~~~~   mean fields read in the ocean restart file'
277            ENDIF
278         ENDIF
279      ENDIF
280      !
281      IF( .NOT. l_ssm_mean ) THEN   ! default initialisation. needed by lim_istate
282         !
283         IF(lwp) WRITE(numout,*) '          default initialisation of ss?_m arrays'
284!$OMP PARALLEL WORKSHARE
285         ssu_m(:,:) = ub(:,:,1)
286         ssv_m(:,:) = vb(:,:,1)
287!$OMP END PARALLEL WORKSHARE
288         IF( l_useCT )  THEN    ;   sst_m(:,:) = eos_pt_from_ct( tsn(:,:,1,jp_tem), tsn(:,:,1,jp_sal) )
289         ELSE                    ;   sst_m(:,:) = tsn(:,:,1,jp_tem)
290         ENDIF
291!$OMP PARALLEL WORKSHARE
292         sss_m(:,:) = tsn  (:,:,1,jp_sal)
293         ssh_m(:,:) = sshn (:,:)
294         e3t_m(:,:) = e3t_n(:,:,1)
295         frq_m(:,:) = 1._wp
296!$OMP END PARALLEL WORKSHARE
297         !
298      ENDIF
299      !
300   END SUBROUTINE sbc_ssm_init
301
302   !!======================================================================
303END MODULE sbcssm
Note: See TracBrowser for help on using the repository browser.