New URL for NEMO forge!   http://forge.nemo-ocean.eu

Since March 2022 along with NEMO 4.2 release, the code development moved to a self-hosted GitLab.
This present forge is now archived and remained online for history.
sbcssm.F90 in branches/2016/dev_r6519_HPC_4/NEMOGCM/NEMO/OPA_SRC/SBC – NEMO

source: branches/2016/dev_r6519_HPC_4/NEMOGCM/NEMO/OPA_SRC/SBC/sbcssm.F90 @ 7047

Last change on this file since 7047 was 7047, checked in by mocavero, 7 years ago

workshare blocks update

  • Property svn:keywords set to Id
File size: 14.6 KB
Line 
1MODULE sbcssm
2   !!======================================================================
3   !!                       ***  MODULE  sbcssm  ***
4   !! Surface module :  provide time-mean ocean surface variables
5   !!======================================================================
6   !! History :  9.0  ! 2006-07  (G. Madec)  Original code
7   !!            3.3  ! 2010-10  (C. Bricaud, G. Madec)  add the Patm forcing for sea-ice
8   !!            3.7  ! 2015-11  (G. Madec)  non linear free surface by default: e3t_m always computed
9   !!----------------------------------------------------------------------
10
11   !!----------------------------------------------------------------------
12   !!   sbc_ssm       : calculate sea surface mean currents, temperature, 
13   !!                   and salinity over nn_fsbc time-step
14   !!----------------------------------------------------------------------
15   USE oce            ! ocean dynamics and tracers
16   USE dom_oce        ! ocean space and time domain
17   USE sbc_oce        ! surface boundary condition: ocean fields
18   USE sbcapr         ! surface boundary condition: atmospheric pressure
19   USE eosbn2         ! equation of state and related derivatives
20   !
21   USE in_out_manager ! I/O manager
22   USE prtctl         ! Print control
23   USE iom            ! IOM library
24
25   IMPLICIT NONE
26   PRIVATE
27
28   PUBLIC   sbc_ssm        ! routine called by step.F90
29   PUBLIC   sbc_ssm_init   ! routine called by sbcmod.F90
30
31   LOGICAL, SAVE ::   l_ssm_mean = .FALSE.   ! keep track of whether means have been read from restart file
32   
33   !!----------------------------------------------------------------------
34   !! NEMO/OPA 3.3 , NEMO Consortium (2010)
35   !! $Id$
36   !! Software governed by the CeCILL licence     (NEMOGCM/NEMO_CeCILL.txt)
37   !!----------------------------------------------------------------------
38CONTAINS
39
40   SUBROUTINE sbc_ssm( kt )
41      !!---------------------------------------------------------------------
42      !!                     ***  ROUTINE sbc_oce  ***
43      !!                     
44      !! ** Purpose :   provide ocean surface variable to sea-surface boundary
45      !!                condition computation
46      !!               
47      !! ** Method  :   compute mean surface velocity (2 components at U and
48      !!      V-points) [m/s], temperature [Celcius] and salinity [psu] over
49      !!      the periode (kt - nn_fsbc) to kt
50      !!         Note that the inverse barometer ssh (i.e. ssh associated with Patm)
51      !!      is add to ssh_m when ln_apr_dyn = T. Required for sea-ice dynamics.
52      !!---------------------------------------------------------------------
53      INTEGER, INTENT(in) ::   kt   ! ocean time step
54      !
55      INTEGER  ::   ji, jj               ! loop index
56      REAL(wp) ::   zcoef, zf_sbc       ! local scalar
57      REAL(wp), DIMENSION(jpi,jpj,jpts) :: zts
58      !!---------------------------------------------------------------------
59      !
60      !                                        !* surface T-, U-, V- ocean level variables (T, S, depth, velocity)
61!$OMP PARALLEL DO schedule(static) private(jj, ji)
62      DO jj = 1, jpj
63         DO ji = 1, jpi
64            zts(ji,jj,jp_tem) = tsn(ji,jj,mikt(ji,jj),jp_tem)
65            zts(ji,jj,jp_sal) = tsn(ji,jj,mikt(ji,jj),jp_sal)
66         END DO
67      END DO
68      !
69      IF( nn_fsbc == 1 ) THEN                             !   Instantaneous surface fields        !
70         !                                                ! ---------------------------------------- !
71!$OMP PARALLEL WORKSHARE
72         ssu_m(:,:) = ub(:,:,1)
73         ssv_m(:,:) = vb(:,:,1)
74!$OMP END PARALLEL WORKSHARE
75         IF( l_useCT )  THEN
76           sst_m(:,:) = eos_pt_from_ct( zts(:,:,jp_tem), zts(:,:,jp_sal) )
77         ELSE                   
78!$OMP PARALLEL WORKSHARE
79           sst_m(:,:) = zts(:,:,jp_tem)
80!$OMP END PARALLEL WORKSHARE
81         ENDIF
82!$OMP PARALLEL WORKSHARE
83         sss_m(:,:) = zts(:,:,jp_sal)
84!$OMP END PARALLEL WORKSHARE
85         !                          ! removed inverse barometer ssh when Patm forcing is used (for sea-ice dynamics)
86         IF( ln_apr_dyn ) THEN 
87!$OMP PARALLEL WORKSHARE
88           ssh_m(:,:) = sshn(:,:) - 0.5 * ( ssh_ib(:,:) + ssh_ibb(:,:) )
89!$OMP END PARALLEL WORKSHARE
90         ELSE                   
91!$OMP PARALLEL WORKSHARE
92           ssh_m(:,:) = sshn(:,:)
93!$OMP END PARALLEL WORKSHARE
94         ENDIF
95         !
96!$OMP PARALLEL WORKSHARE
97         e3t_m(:,:) = e3t_n(:,:,1)
98         !
99         frq_m(:,:) = fraqsr_1lev(:,:)
100!$OMP END PARALLEL WORKSHARE
101         !
102      ELSE
103         !                                                ! ----------------------------------------------- !
104         IF( kt == nit000 .AND. .NOT. l_ssm_mean ) THEN   !   Initialisation: 1st time-step, no input means !
105            !                                             ! ----------------------------------------------- !
106            IF(lwp) WRITE(numout,*)
107            IF(lwp) WRITE(numout,*) '~~~~~~~   mean fields initialised to instantaneous values'
108            zcoef = REAL( nn_fsbc - 1, wp )
109!$OMP PARALLEL WORKSHARE
110            ssu_m(:,:) = zcoef * ub(:,:,1)
111            ssv_m(:,:) = zcoef * vb(:,:,1)
112!$OMP END PARALLEL WORKSHARE
113            IF( l_useCT )  THEN
114              sst_m(:,:) = zcoef * eos_pt_from_ct( zts(:,:,jp_tem), zts(:,:,jp_sal) )
115            ELSE                   
116!$OMP PARALLEL WORKSHARE
117              sst_m(:,:) = zcoef * zts(:,:,jp_tem)
118!$OMP END PARALLEL WORKSHARE
119            ENDIF
120!$OMP PARALLEL WORKSHARE
121            sss_m(:,:) = zcoef * zts(:,:,jp_sal)
122!$OMP END PARALLEL WORKSHARE
123            !                          ! removed inverse barometer ssh when Patm forcing is used (for sea-ice dynamics)
124            IF( ln_apr_dyn ) THEN   
125!$OMP PARALLEL WORKSHARE
126              ssh_m(:,:) = zcoef * ( sshn(:,:) - 0.5 * ( ssh_ib(:,:) + ssh_ibb(:,:) ) )
127!$OMP END PARALLEL WORKSHARE
128            ELSE                   
129!$OMP PARALLEL WORKSHARE
130              ssh_m(:,:) = zcoef * sshn(:,:)
131!$OMP END PARALLEL WORKSHARE
132            ENDIF
133            !
134!$OMP PARALLEL WORKSHARE
135            e3t_m(:,:) = zcoef * e3t_n(:,:,1)
136            !
137            frq_m(:,:) = zcoef * fraqsr_1lev(:,:)
138!$OMP END PARALLEL WORKSHARE
139            !                                             ! ---------------------------------------- !
140         ELSEIF( MOD( kt - 2 , nn_fsbc ) == 0 ) THEN      !   Initialisation: New mean computation   !
141            !                                             ! ---------------------------------------- !
142!$OMP PARALLEL WORKSHARE
143            ssu_m(:,:) = 0._wp     ! reset to zero ocean mean sbc fields
144            ssv_m(:,:) = 0._wp
145            sst_m(:,:) = 0._wp
146            sss_m(:,:) = 0._wp
147            ssh_m(:,:) = 0._wp
148            e3t_m(:,:) = 0._wp
149            frq_m(:,:) = 0._wp
150!$OMP END PARALLEL WORKSHARE
151         ENDIF
152         !                                                ! ---------------------------------------- !
153         !                                                !        Cumulate at each time step        !
154         !                                                ! ---------------------------------------- !
155!$OMP PARALLEL WORKSHARE
156         ssu_m(:,:) = ssu_m(:,:) + ub(:,:,1)
157         ssv_m(:,:) = ssv_m(:,:) + vb(:,:,1)
158!$OMP END PARALLEL WORKSHARE
159         IF( l_useCT )  THEN   
160           sst_m(:,:) = sst_m(:,:) + eos_pt_from_ct( zts(:,:,jp_tem), zts(:,:,jp_sal) )
161         ELSE                   
162!$OMP PARALLEL WORKSHARE
163           sst_m(:,:) = sst_m(:,:) + zts(:,:,jp_tem)
164!$OMP END PARALLEL WORKSHARE
165         ENDIF
166!$OMP PARALLEL WORKSHARE
167         sss_m(:,:) = sss_m(:,:) + zts(:,:,jp_sal)
168!$OMP END PARALLEL WORKSHARE
169         !                          ! removed inverse barometer ssh when Patm forcing is used (for sea-ice dynamics)
170         IF( ln_apr_dyn ) THEN   
171!$OMP PARALLEL WORKSHARE
172           ssh_m(:,:) = ssh_m(:,:) + sshn(:,:) - 0.5 * ( ssh_ib(:,:) + ssh_ibb(:,:) )
173!$OMP END PARALLEL WORKSHARE
174         ELSE                   
175!$OMP PARALLEL WORKSHARE
176           ssh_m(:,:) = ssh_m(:,:) + sshn(:,:)
177!$OMP END PARALLEL WORKSHARE
178         ENDIF
179         !
180!$OMP PARALLEL WORKSHARE
181         e3t_m(:,:) = e3t_m(:,:) + e3t_n(:,:,1)
182         !
183         frq_m(:,:) = frq_m(:,:) + fraqsr_1lev(:,:)
184!$OMP END PARALLEL WORKSHARE
185
186         !                                                ! ---------------------------------------- !
187         IF( MOD( kt - 1 , nn_fsbc ) == 0 ) THEN          !   Mean value at each nn_fsbc time-step   !
188            !                                             ! ---------------------------------------- !
189            zcoef = 1. / REAL( nn_fsbc, wp )
190!$OMP PARALLEL WORKSHARE
191            sst_m(:,:) = sst_m(:,:) * zcoef     ! mean SST             [Celcius]
192            sss_m(:,:) = sss_m(:,:) * zcoef     ! mean SSS             [psu]
193            ssu_m(:,:) = ssu_m(:,:) * zcoef     ! mean suface current  [m/s]
194            ssv_m(:,:) = ssv_m(:,:) * zcoef     !
195            ssh_m(:,:) = ssh_m(:,:) * zcoef     ! mean SSH             [m]
196            e3t_m(:,:) = e3t_m(:,:) * zcoef     ! mean vertical scale factor [m]
197            frq_m(:,:) = frq_m(:,:) * zcoef     ! mean fraction of solar net radiation absorbed in the 1st T level [-]
198!$OMP END PARALLEL WORKSHARE
199            !
200         ENDIF
201         !                                                ! ---------------------------------------- !
202         IF( lrst_oce ) THEN                              !      Write in the ocean restart file     !
203            !                                             ! ---------------------------------------- !
204            IF(lwp) WRITE(numout,*)
205            IF(lwp) WRITE(numout,*) 'sbc_ssm : sea surface mean fields written in ocean restart file ',   &
206               &                    'at it= ', kt,' date= ', ndastp
207            IF(lwp) WRITE(numout,*) '~~~~~~~'
208            zf_sbc = REAL( nn_fsbc, wp )
209            CALL iom_rstput( kt, nitrst, numrow, 'nn_fsbc', zf_sbc )    ! sbc frequency
210            CALL iom_rstput( kt, nitrst, numrow, 'ssu_m'  , ssu_m  )    ! sea surface mean fields
211            CALL iom_rstput( kt, nitrst, numrow, 'ssv_m'  , ssv_m  )
212            CALL iom_rstput( kt, nitrst, numrow, 'sst_m'  , sst_m  )
213            CALL iom_rstput( kt, nitrst, numrow, 'sss_m'  , sss_m  )
214            CALL iom_rstput( kt, nitrst, numrow, 'ssh_m'  , ssh_m  )
215            CALL iom_rstput( kt, nitrst, numrow, 'e3t_m'  , e3t_m  )
216            CALL iom_rstput( kt, nitrst, numrow, 'frq_m'  , frq_m  )
217            !
218         ENDIF
219         !
220      ENDIF
221      !
222      IF( MOD( kt - 1 , nn_fsbc ) == 0 ) THEN          !   Mean value at each nn_fsbc time-step   !
223         CALL iom_put( 'ssu_m', ssu_m )
224         CALL iom_put( 'ssv_m', ssv_m )
225         CALL iom_put( 'sst_m', sst_m )
226         CALL iom_put( 'sss_m', sss_m )
227         CALL iom_put( 'ssh_m', ssh_m )
228         CALL iom_put( 'e3t_m', e3t_m )
229         CALL iom_put( 'frq_m', frq_m )
230      ENDIF
231      !
232   END SUBROUTINE sbc_ssm
233
234
235   SUBROUTINE sbc_ssm_init
236      !!----------------------------------------------------------------------
237      !!                  ***  ROUTINE sbc_ssm_init  ***
238      !!
239      !! ** Purpose :   Initialisation of the sbc data
240      !!
241      !! ** Action  : - read parameters
242      !!----------------------------------------------------------------------
243      REAL(wp) ::   zcoef, zf_sbc   ! local scalar
244      !!----------------------------------------------------------------------
245      !
246      IF( nn_fsbc == 1 ) THEN
247         !
248         IF(lwp) WRITE(numout,*)
249         IF(lwp) WRITE(numout,*) 'sbc_ssm : sea surface mean fields, nn_fsbc=1 : instantaneous values'
250         IF(lwp) WRITE(numout,*) '~~~~~~~ '
251         !
252      ELSE
253         !               
254         IF(lwp) WRITE(numout,*)
255         IF(lwp) WRITE(numout,*) 'sbc_ssm : sea surface mean fields'
256         IF(lwp) WRITE(numout,*) '~~~~~~~ '
257         !
258         IF( ln_rstart .AND. iom_varid( numror, 'nn_fsbc', ldstop = .FALSE. ) > 0 ) THEN
259            l_ssm_mean = .TRUE.
260            CALL iom_get( numror               , 'nn_fsbc', zf_sbc )    ! sbc frequency of previous run
261            CALL iom_get( numror, jpdom_autoglo, 'ssu_m'  , ssu_m  )    ! sea surface mean velocity    (U-point)
262            CALL iom_get( numror, jpdom_autoglo, 'ssv_m'  , ssv_m  )    !   "         "    velocity    (V-point)
263            CALL iom_get( numror, jpdom_autoglo, 'sst_m'  , sst_m  )    !   "         "    temperature (T-point)
264            CALL iom_get( numror, jpdom_autoglo, 'sss_m'  , sss_m  )    !   "         "    salinity    (T-point)
265            CALL iom_get( numror, jpdom_autoglo, 'ssh_m'  , ssh_m  )    !   "         "    height      (T-point)
266            CALL iom_get( numror, jpdom_autoglo, 'e3t_m'  , e3t_m  )    ! 1st level thickness          (T-point)
267            ! fraction of solar net radiation absorbed in 1st T level
268            IF( iom_varid( numror, 'frq_m', ldstop = .FALSE. ) > 0 ) THEN
269               CALL iom_get( numror, jpdom_autoglo, 'frq_m'  , frq_m  )
270            ELSE
271!$OMP PARALLEL WORKSHARE
272               frq_m(:,:) = 1._wp   ! default definition
273!$OMP END PARALLEL WORKSHARE
274            ENDIF
275            !
276            IF( zf_sbc /= REAL( nn_fsbc, wp ) ) THEN      ! nn_fsbc has changed between 2 runs
277               IF(lwp) WRITE(numout,*) '~~~~~~~   restart with a change in the frequency of mean ',   &
278                  &                    'from ', zf_sbc, ' to ', nn_fsbc 
279               zcoef = REAL( nn_fsbc - 1, wp ) / zf_sbc 
280!$OMP PARALLEL WORKSHARE
281               ssu_m(:,:) = zcoef * ssu_m(:,:) 
282               ssv_m(:,:) = zcoef * ssv_m(:,:)
283               sst_m(:,:) = zcoef * sst_m(:,:)
284               sss_m(:,:) = zcoef * sss_m(:,:)
285               ssh_m(:,:) = zcoef * ssh_m(:,:)
286               e3t_m(:,:) = zcoef * e3t_m(:,:)
287               frq_m(:,:) = zcoef * frq_m(:,:)
288!$OMP END PARALLEL WORKSHARE
289            ELSE
290               IF(lwp) WRITE(numout,*) '~~~~~~~   mean fields read in the ocean restart file'
291            ENDIF
292         ENDIF
293      ENDIF
294      !
295      IF( .NOT. l_ssm_mean ) THEN   ! default initialisation. needed by lim_istate
296         !
297         IF(lwp) WRITE(numout,*) '          default initialisation of ss?_m arrays'
298!$OMP PARALLEL WORKSHARE
299         ssu_m(:,:) = ub(:,:,1)
300         ssv_m(:,:) = vb(:,:,1)
301!$OMP END PARALLEL WORKSHARE
302         IF( l_useCT )  THEN    ;   sst_m(:,:) = eos_pt_from_ct( tsn(:,:,1,jp_tem), tsn(:,:,1,jp_sal) )
303         ELSE                    ;   sst_m(:,:) = tsn(:,:,1,jp_tem)
304         ENDIF
305!$OMP PARALLEL WORKSHARE
306         sss_m(:,:) = tsn  (:,:,1,jp_sal)
307         ssh_m(:,:) = sshn (:,:)
308         e3t_m(:,:) = e3t_n(:,:,1)
309         frq_m(:,:) = 1._wp
310!$OMP END PARALLEL WORKSHARE
311         !
312      ENDIF
313      !
314   END SUBROUTINE sbc_ssm_init
315
316   !!======================================================================
317END MODULE sbcssm
Note: See TracBrowser for help on using the repository browser.