New URL for NEMO forge!   http://forge.nemo-ocean.eu

Since March 2022 along with NEMO 4.2 release, the code development moved to a self-hosted GitLab.
This present forge is now archived and remained online for history.
traadv_mus.F90 in branches/2016/dev_r6519_HPC_4/NEMOGCM/NEMO/OPA_SRC/TRA – NEMO

source: branches/2016/dev_r6519_HPC_4/NEMOGCM/NEMO/OPA_SRC/TRA/traadv_mus.F90 @ 7037

Last change on this file since 7037 was 7037, checked in by mocavero, 8 years ago

ORCA2_LIM_PISCES hybrid version update
  • Property svn:keywords set to Id
File size: 16.0 KB
Line 
1MODULE traadv_mus
2   !!======================================================================
3   !!                       ***  MODULE  traadv_mus  ***
4   !! Ocean  tracers:  horizontal & vertical advective trend
5   !!======================================================================
6   !! History :       !  2000-06  (A.Estublier)  for passive tracers
7   !!                 !  2001-08  (E.Durand, G.Madec)  adapted for T & S
8   !!   NEMO     1.0  !  2002-06  (G. Madec)  F90: Free form and module
9   !!            3.2  !  2010-05  (C. Ethe, G. Madec)  merge TRC-TRA + switch from velocity to transport
10   !!            3.4  !  2012-06  (P. Oddo, M. Vichi) include the upstream where needed
11   !!            3.7  !  2015-09  (G. Madec) add the ice-shelf cavities boundary condition
12   !!----------------------------------------------------------------------
13
14   !!----------------------------------------------------------------------
15   !!   tra_adv_mus   : update the tracer trend with the horizontal
16   !!                   and vertical advection trends using MUSCL scheme
17   !!----------------------------------------------------------------------
18   USE oce            ! ocean dynamics and active tracers
19   USE trc_oce        ! share passive tracers/Ocean variables
20   USE dom_oce        ! ocean space and time domain
21   USE trd_oce        ! trends: ocean variables
22   USE trdtra         ! tracers trends manager
23   USE sbcrnf         ! river runoffs
24   USE diaptr         ! poleward transport diagnostics
25   !
26   USE wrk_nemo       ! Memory Allocation
27   USE timing         ! Timing
28   USE lib_fortran    ! Fortran utilities (allows no signed zero when 'key_nosignedzero' defined) 
29   USE in_out_manager ! I/O manager
30   USE lib_mpp        ! distribued memory computing
31   USE lbclnk         ! ocean lateral boundary condition (or mpp link)
32
33   IMPLICIT NONE
34   PRIVATE
35
36   PUBLIC   tra_adv_mus   ! routine called by traadv.F90
37   
38   REAL(wp), ALLOCATABLE, SAVE, DIMENSION(:,:)   ::   upsmsk   !: mixed upstream/centered scheme near some straits
39   !                                                           !  and in closed seas (orca 2 and 4 configurations)
40   REAL(wp), ALLOCATABLE, SAVE, DIMENSION(:,:,:) ::   xind     !: mixed upstream/centered index
41   
42   !! * Substitutions
43#  include "vectopt_loop_substitute.h90"
44   !!----------------------------------------------------------------------
45   !! NEMO/OPA 3.3 , NEMO Consortium (2010)
46   !! $Id$
47   !! Software governed by the CeCILL licence     (NEMOGCM/NEMO_CeCILL.txt)
48   !!----------------------------------------------------------------------
49CONTAINS
50
51   SUBROUTINE tra_adv_mus( kt, kit000, cdtype, p2dt, pun, pvn, pwn,             &
52      &                                              ptb, pta, kjpt, ld_msc_ups )
53      !!----------------------------------------------------------------------
54      !!                    ***  ROUTINE tra_adv_mus  ***
55      !!
56      !! ** Purpose :   Compute the now trend due to total advection of tracers
57      !!              using a MUSCL scheme (Monotone Upstream-centered Scheme for
58      !!              Conservation Laws) and add it to the general tracer trend.
59      !!
60      !! ** Method  : MUSCL scheme plus centered scheme at ocean boundaries
61      !!              ld_msc_ups=T :
62      !!
63      !! ** Action : - update pta  with the now advective tracer trends
64      !!             - send trends to trdtra module for further diagnostcs (l_trdtra=T)
65      !!             - htr_adv, str_adv : poleward advective heat and salt transport (ln_diaptr=T)
66      !!
67      !! References : Estubier, A., and M. Levy, Notes Techn. Pole de Modelisation
68      !!              IPSL, Sept. 2000 (http://www.lodyc.jussieu.fr/opa)
69      !!----------------------------------------------------------------------
70      INTEGER                              , INTENT(in   ) ::   kt              ! ocean time-step index
71      INTEGER                              , INTENT(in   ) ::   kit000          ! first time step index
72      CHARACTER(len=3)                     , INTENT(in   ) ::   cdtype          ! =TRA or TRC (tracer indicator)
73      INTEGER                              , INTENT(in   ) ::   kjpt            ! number of tracers
74      LOGICAL                              , INTENT(in   ) ::   ld_msc_ups      ! use upstream scheme within muscl
75      REAL(wp)                             , INTENT(in   ) ::   p2dt            ! tracer time-step
76      REAL(wp), DIMENSION(jpi,jpj,jpk     ), INTENT(in   ) ::   pun, pvn, pwn   ! 3 ocean velocity components
77      REAL(wp), DIMENSION(jpi,jpj,jpk,kjpt), INTENT(in   ) ::   ptb             ! before tracer field
78      REAL(wp), DIMENSION(jpi,jpj,jpk,kjpt), INTENT(inout) ::   pta             ! tracer trend
79      !
80      INTEGER  ::   ji, jj, jk, jn       ! dummy loop indices
81      INTEGER  ::   ierr                 ! local integer
82      REAL(wp) ::   zu, z0u, zzwx, zw    ! local scalars
83      REAL(wp) ::   zv, z0v, zzwy, z0w   !   -      -
84      REAL(wp) ::   zalpha               !   -      -
85      REAL(wp), POINTER, DIMENSION(:,:,:) ::   zslpx, zslpy   ! 3D workspace
86      REAL(wp), POINTER, DIMENSION(:,:,:) ::   zwx  , zwy     ! -      -
87      !!----------------------------------------------------------------------
88      !
89      IF( nn_timing == 1 )  CALL timing_start('tra_adv_mus')
90      !
91      CALL wrk_alloc( jpi,jpj,jpk,   zslpx, zslpy, zwx, zwy )
92      !
93      IF( kt == kit000 )  THEN
94         IF(lwp) WRITE(numout,*)
95         IF(lwp) WRITE(numout,*) 'tra_adv : MUSCL advection scheme on ', cdtype
96         IF(lwp) WRITE(numout,*) '        : mixed up-stream           ', ld_msc_ups
97         IF(lwp) WRITE(numout,*) '~~~~~~~'
98         IF(lwp) WRITE(numout,*)
99         !
100         ! Upstream / MUSCL scheme indicator
101         !
102         ALLOCATE( xind(jpi,jpj,jpk), STAT=ierr )
103!$OMP PARALLEL WORKSHARE
104         xind(:,:,:) = 1._wp              ! set equal to 1 where up-stream is not needed
105!$OMP END PARALLEL WORKSHARE
106         !
107         IF( ld_msc_ups ) THEN            ! define the upstream indicator (if asked)
108            ALLOCATE( upsmsk(jpi,jpj), STAT=ierr )
109!$OMP PARALLEL
110!$OMP WORKSHARE
111            upsmsk(:,:) = 0._wp                             ! not upstream by default
112!$OMP END WORKSHARE
113            !
114!$OMP DO schedule(static) private(jk)
115            DO jk = 1, jpkm1
116               xind(:,:,jk) = 1._wp                              &                 ! =>1 where up-stream is not needed
117                  &         - MAX ( rnfmsk(:,:) * rnfmsk_z(jk),  &                 ! =>0 near runoff mouths (& closed sea outflows)
118                  &                 upsmsk(:,:)                ) * tmask(:,:,jk)   ! =>0 in some user defined area
119            END DO
120!$OMP END DO NOWAIT
121!$OMP END PARALLEL
122         ENDIF 
123         !
124      ENDIF 
125      !     
126      DO jn = 1, kjpt            !==  loop over the tracers  ==!
127         !
128         !                          !* Horizontal advective fluxes
129         !
130         !                                !-- first guess of the slopes
131!$OMP PARALLEL
132!$OMP WORKSHARE
133         zwx(:,:,jpk) = 0._wp                   ! bottom values
134         zwy(:,:,jpk) = 0._wp
135!$OMP END WORKSHARE
136!$OMP DO schedule(static) private(jk, jj, ji)
137         DO jk = 1, jpkm1                       ! interior values
138            DO jj = 1, jpjm1     
139               DO ji = 1, fs_jpim1   ! vector opt.
140                  zwx(ji,jj,jk) = umask(ji,jj,jk) * ( ptb(ji+1,jj,jk,jn) - ptb(ji,jj,jk,jn) )
141                  zwy(ji,jj,jk) = vmask(ji,jj,jk) * ( ptb(ji,jj+1,jk,jn) - ptb(ji,jj,jk,jn) )
142               END DO
143           END DO
144         END DO
145!$OMP END DO NOWAIT
146!$OMP END PARALLEL
147         CALL lbc_lnk( zwx, 'U', -1. )          ! lateral boundary conditions   (changed sign)
148         CALL lbc_lnk( zwy, 'V', -1. )
149         !                                !-- Slopes of tracer
150!$OMP PARALLEL
151!$OMP WORKSHARE
152         zslpx(:,:,jpk) = 0._wp                 ! bottom values
153         zslpy(:,:,jpk) = 0._wp
154!$OMP END WORKSHARE
155!$OMP DO schedule(static) private(jk, jj, ji)
156         DO jk = 1, jpkm1                       ! interior values
157            DO jj = 2, jpj
158               DO ji = fs_2, jpi   ! vector opt.
159                  zslpx(ji,jj,jk) =                    ( zwx(ji,jj,jk) + zwx(ji-1,jj  ,jk) )   &
160                     &            * ( 0.25 + SIGN( 0.25, zwx(ji,jj,jk) * zwx(ji-1,jj  ,jk) ) )
161                  zslpy(ji,jj,jk) =                    ( zwy(ji,jj,jk) + zwy(ji  ,jj-1,jk) )   &
162                     &            * ( 0.25 + SIGN( 0.25, zwy(ji,jj,jk) * zwy(ji  ,jj-1,jk) ) )
163               END DO
164            END DO
165         END DO
166         !
167!$OMP DO schedule(static) private(jk, jj, ji)
168         DO jk = 1, jpkm1                 !-- Slopes limitation
169            DO jj = 2, jpj
170               DO ji = fs_2, jpi   ! vector opt.
171                  zslpx(ji,jj,jk) = SIGN( 1., zslpx(ji,jj,jk) ) * MIN(    ABS( zslpx(ji  ,jj,jk) ),   &
172                     &                                                 2.*ABS( zwx  (ji-1,jj,jk) ),   &
173                     &                                                 2.*ABS( zwx  (ji  ,jj,jk) ) )
174                  zslpy(ji,jj,jk) = SIGN( 1., zslpy(ji,jj,jk) ) * MIN(    ABS( zslpy(ji,jj  ,jk) ),   &
175                     &                                                 2.*ABS( zwy  (ji,jj-1,jk) ),   &
176                     &                                                 2.*ABS( zwy  (ji,jj  ,jk) ) )
177               END DO
178           END DO
179         END DO
180         !
181!$OMP DO schedule(static) private(jk, jj, ji, z0u, zalpha, zu, zv, zzwx, zzwy, z0v)
182         DO jk = 1, jpkm1                 !-- MUSCL horizontal advective fluxes
183            DO jj = 2, jpjm1
184               DO ji = fs_2, fs_jpim1   ! vector opt.
185                  ! MUSCL fluxes
186                  z0u = SIGN( 0.5, pun(ji,jj,jk) )
187                  zalpha = 0.5 - z0u
188                  zu  = z0u - 0.5 * pun(ji,jj,jk) * p2dt * r1_e1e2u(ji,jj) / e3u_n(ji,jj,jk)
189                  zzwx = ptb(ji+1,jj,jk,jn) + xind(ji,jj,jk) * zu * zslpx(ji+1,jj,jk)
190                  zzwy = ptb(ji  ,jj,jk,jn) + xind(ji,jj,jk) * zu * zslpx(ji  ,jj,jk)
191                  zwx(ji,jj,jk) = pun(ji,jj,jk) * ( zalpha * zzwx + (1.-zalpha) * zzwy )
192                  !
193                  z0v = SIGN( 0.5, pvn(ji,jj,jk) )
194                  zalpha = 0.5 - z0v
195                  zv  = z0v - 0.5 * pvn(ji,jj,jk) * p2dt * r1_e1e2v(ji,jj) / e3v_n(ji,jj,jk)
196                  zzwx = ptb(ji,jj+1,jk,jn) + xind(ji,jj,jk) * zv * zslpy(ji,jj+1,jk)
197                  zzwy = ptb(ji,jj  ,jk,jn) + xind(ji,jj,jk) * zv * zslpy(ji,jj  ,jk)
198                  zwy(ji,jj,jk) = pvn(ji,jj,jk) * ( zalpha * zzwx + (1.-zalpha) * zzwy )
199               END DO
200            END DO
201         END DO
202!$OMP END DO NOWAIT
203!$OMP END PARALLEL
204         CALL lbc_lnk( zwx, 'U', -1. )   ;   CALL lbc_lnk( zwy, 'V', -1. )   ! lateral boundary conditions   (changed sign)
205         !
206!$OMP PARALLEL DO schedule(static) private(jk, jj, ji)
207         DO jk = 1, jpkm1                 !-- Tracer advective trend
208            DO jj = 2, jpjm1     
209               DO ji = fs_2, fs_jpim1   ! vector opt.
210                  pta(ji,jj,jk,jn) = pta(ji,jj,jk,jn) - ( zwx(ji,jj,jk) - zwx(ji-1,jj  ,jk  )       &
211                  &                                     + zwy(ji,jj,jk) - zwy(ji  ,jj-1,jk  ) )     &
212                  &                                   * r1_e1e2t(ji,jj) / e3t_n(ji,jj,jk)
213               END DO
214           END DO
215         END DO       
216         !                                ! trend diagnostics
217         IF( ( cdtype == 'TRA' .AND. l_trdtra ) .OR.   &
218            &( cdtype == 'TRC' .AND. l_trdtrc )      )  THEN
219            CALL trd_tra( kt, cdtype, jn, jptra_xad, zwx, pun, ptb(:,:,:,jn) )
220            CALL trd_tra( kt, cdtype, jn, jptra_yad, zwy, pvn, ptb(:,:,:,jn) )
221         END IF
222         !                                ! "Poleward" heat and salt transports
223         IF( cdtype == 'TRA' .AND. ln_diaptr ) THEN 
224            IF( jn == jp_tem )  htr_adv(:) = ptr_sj( zwy(:,:,:) )
225            IF( jn == jp_sal )  str_adv(:) = ptr_sj( zwy(:,:,:) )
226         ENDIF
227         !
228         !                          !* Vertical advective fluxes
229         !
230         !                                !-- first guess of the slopes
231!$OMP PARALLEL
232!$OMP WORKSHARE
233         zwx(:,:, 1 ) = 0._wp                   ! surface & bottom boundary conditions
234         zwx(:,:,jpk) = 0._wp
235!$OMP END WORKSHARE
236!$OMP DO schedule(static) private(jk)
237         DO jk = 2, jpkm1                       ! interior values
238            zwx(:,:,jk) = tmask(:,:,jk) * ( ptb(:,:,jk-1,jn) - ptb(:,:,jk,jn) )
239         END DO
240         !                                !-- Slopes of tracer
241!$OMP END DO NOWAIT
242!$OMP WORKSHARE
243         zslpx(:,:,1) = 0._wp                   ! surface values
244!$OMP END WORKSHARE
245!$OMP DO schedule(static) private(jk, jj, ji)
246         DO jk = 2, jpkm1                       ! interior value
247            DO jj = 1, jpj
248               DO ji = 1, jpi
249                  zslpx(ji,jj,jk) =                     ( zwx(ji,jj,jk) + zwx(ji,jj,jk+1) )  &
250                     &            * (  0.25 + SIGN( 0.25, zwx(ji,jj,jk) * zwx(ji,jj,jk+1) )  )
251               END DO
252            END DO
253         END DO
254!$OMP DO schedule(static) private(jk, jj, ji)
255         DO jk = 2, jpkm1                 !-- Slopes limitation
256            DO jj = 1, jpj                      ! interior values
257               DO ji = 1, jpi
258                  zslpx(ji,jj,jk) = SIGN( 1., zslpx(ji,jj,jk) ) * MIN(    ABS( zslpx(ji,jj,jk  ) ),   &
259                     &                                                 2.*ABS( zwx  (ji,jj,jk+1) ),   &
260                     &                                                 2.*ABS( zwx  (ji,jj,jk  ) )  )
261               END DO
262            END DO
263         END DO
264!$OMP DO schedule(static) private(jk, jj, ji, z0w, zalpha, zw, zzwx, zzwy)
265         DO jk = 1, jpk-2                 !-- vertical advective flux
266            DO jj = 2, jpjm1     
267               DO ji = fs_2, fs_jpim1   ! vector opt.
268                  z0w = SIGN( 0.5, pwn(ji,jj,jk+1) )
269                  zalpha = 0.5 + z0w
270                  zw  = z0w - 0.5 * pwn(ji,jj,jk+1) * p2dt * r1_e1e2t(ji,jj) / e3w_n(ji,jj,jk+1)
271                  zzwx = ptb(ji,jj,jk+1,jn) + xind(ji,jj,jk) * zw * zslpx(ji,jj,jk+1)
272                  zzwy = ptb(ji,jj,jk  ,jn) + xind(ji,jj,jk) * zw * zslpx(ji,jj,jk  )
273                  zwx(ji,jj,jk+1) = pwn(ji,jj,jk+1) * ( zalpha * zzwx + (1.-zalpha) * zzwy ) * wmask(ji,jj,jk)
274               END DO
275            END DO
276         END DO
277!$OMP END DO NOWAIT
278!$OMP END PARALLEL
279         IF( ln_linssh ) THEN                   ! top values, linear free surface only
280            IF( ln_isfcav ) THEN                      ! ice-shelf cavities (top of the ocean)
281!$OMP PARALLEL DO schedule(static) private(jj, ji)
282               DO jj = 1, jpj
283                  DO ji = 1, jpi
284                     zwx(ji,jj, mikt(ji,jj) ) = pwn(ji,jj,mikt(ji,jj)) * ptb(ji,jj,mikt(ji,jj),jn)
285                  END DO
286               END DO   
287            ELSE                                      ! no cavities: only at the ocean surface
288!$OMP PARALLEL WORKSHARE
289               zwx(:,:,1) = pwn(:,:,1) * ptb(:,:,1,jn)
290!$OMP END PARALLEL WORKSHARE
291            ENDIF
292         ENDIF
293         !
294!$OMP PARALLEL DO schedule(static) private(jk, jj, ji)
295         DO jk = 1, jpkm1                 !-- vertical advective trend
296            DO jj = 2, jpjm1     
297               DO ji = fs_2, fs_jpim1   ! vector opt.
298                  pta(ji,jj,jk,jn) =  pta(ji,jj,jk,jn) - ( zwx(ji,jj,jk) - zwx(ji,jj,jk+1) ) * r1_e1e2t(ji,jj) / e3t_n(ji,jj,jk)
299               END DO
300            END DO
301         END DO
302         !                                ! send trends for diagnostic
303         IF( ( cdtype == 'TRA' .AND. l_trdtra ) .OR.     &
304            &( cdtype == 'TRC' .AND. l_trdtrc )      )   &
305            CALL trd_tra( kt, cdtype, jn, jptra_zad, zwx, pwn, ptb(:,:,:,jn) )
306         !
307      END DO                     ! end of tracer loop
308      !
309      CALL wrk_dealloc( jpi,jpj,jpk,   zslpx, zslpy, zwx, zwy )
310      !
311      IF( nn_timing == 1 )  CALL timing_stop('tra_adv_mus')
312      !
313   END SUBROUTINE tra_adv_mus
314
315   !!======================================================================
316END MODULE traadv_mus
Note: See TracBrowser for help on using the repository browser.