| 1 | MODULE trabbc |
|---|
| 2 | !!============================================================================== |
|---|
| 3 | !! *** MODULE trabbc *** |
|---|
| 4 | !! Ocean active tracers: bottom boundary condition (geothermal heat flux) |
|---|
| 5 | !!============================================================================== |
|---|
| 6 | !! History : OPA ! 1999-10 (G. Madec) original code |
|---|
| 7 | !! NEMO 1.0 ! 2002-08 (G. Madec) free form + modules |
|---|
| 8 | !! - ! 2002-11 (A. Bozec) tra_bbc_init: original code |
|---|
| 9 | !! 3.3 ! 2010-10 (G. Madec) dynamical allocation + suppression of key_trabbc |
|---|
| 10 | !! - ! 2010-11 (G. Madec) use mbkt array (deepest ocean t-level) |
|---|
| 11 | !!---------------------------------------------------------------------- |
|---|
| 12 | |
|---|
| 13 | !!---------------------------------------------------------------------- |
|---|
| 14 | !! tra_bbc : update the tracer trend at ocean bottom |
|---|
| 15 | !! tra_bbc_init : initialization of geothermal heat flux trend |
|---|
| 16 | !!---------------------------------------------------------------------- |
|---|
| 17 | USE oce ! ocean variables |
|---|
| 18 | USE dom_oce ! domain: ocean |
|---|
| 19 | USE phycst ! physical constants |
|---|
| 20 | USE trd_oce ! trends: ocean variables |
|---|
| 21 | USE trdtra ! trends manager: tracers |
|---|
| 22 | ! |
|---|
| 23 | USE in_out_manager ! I/O manager |
|---|
| 24 | USE iom ! xIOS |
|---|
| 25 | USE fldread ! read input fields |
|---|
| 26 | USE lbclnk ! ocean lateral boundary conditions (or mpp link) |
|---|
| 27 | USE lib_mpp ! distributed memory computing library |
|---|
| 28 | USE prtctl ! Print control |
|---|
| 29 | USE wrk_nemo ! Memory Allocation |
|---|
| 30 | USE timing ! Timing |
|---|
| 31 | |
|---|
| 32 | IMPLICIT NONE |
|---|
| 33 | PRIVATE |
|---|
| 34 | |
|---|
| 35 | PUBLIC tra_bbc ! routine called by step.F90 |
|---|
| 36 | PUBLIC tra_bbc_init ! routine called by opa.F90 |
|---|
| 37 | |
|---|
| 38 | ! !!* Namelist nambbc: bottom boundary condition * |
|---|
| 39 | LOGICAL, PUBLIC :: ln_trabbc !: Geothermal heat flux flag |
|---|
| 40 | INTEGER :: nn_geoflx ! Geothermal flux (=1:constant flux, =2:read in file ) |
|---|
| 41 | REAL(wp) :: rn_geoflx_cst ! Constant value of geothermal heat flux |
|---|
| 42 | |
|---|
| 43 | REAL(wp), PUBLIC , ALLOCATABLE, DIMENSION(:,:) :: qgh_trd0 ! geothermal heating trend |
|---|
| 44 | |
|---|
| 45 | TYPE(FLD), ALLOCATABLE, DIMENSION(:) :: sf_qgh ! structure of input qgh (file informations, fields read) |
|---|
| 46 | |
|---|
| 47 | !!---------------------------------------------------------------------- |
|---|
| 48 | !! NEMO/OPA 3.3 , NEMO Consortium (2010) |
|---|
| 49 | !! $Id$ |
|---|
| 50 | !! Software governed by the CeCILL licence (NEMOGCM/NEMO_CeCILL.txt) |
|---|
| 51 | !!---------------------------------------------------------------------- |
|---|
| 52 | CONTAINS |
|---|
| 53 | |
|---|
| 54 | SUBROUTINE tra_bbc( kt ) |
|---|
| 55 | !!---------------------------------------------------------------------- |
|---|
| 56 | !! *** ROUTINE tra_bbc *** |
|---|
| 57 | !! |
|---|
| 58 | !! ** Purpose : Compute the bottom boundary contition on temperature |
|---|
| 59 | !! associated with geothermal heating and add it to the |
|---|
| 60 | !! general trend of temperature equations. |
|---|
| 61 | !! |
|---|
| 62 | !! ** Method : The geothermal heat flux set to its constant value of |
|---|
| 63 | !! 86.4 mW/m2 (Stein and Stein 1992, Huang 1999). |
|---|
| 64 | !! The temperature trend associated to this heat flux through the |
|---|
| 65 | !! ocean bottom can be computed once and is added to the temperature |
|---|
| 66 | !! trend juste above the bottom at each time step: |
|---|
| 67 | !! ta = ta + Qsf / (rau0 rcp e3T) for k= mbkt |
|---|
| 68 | !! Where Qsf is the geothermal heat flux. |
|---|
| 69 | !! |
|---|
| 70 | !! ** Action : - update the temperature trends with geothermal heating trend |
|---|
| 71 | !! - send the trend for further diagnostics (ln_trdtra=T) |
|---|
| 72 | !! |
|---|
| 73 | !! References : Stein, C. A., and S. Stein, 1992, Nature, 359, 123-129. |
|---|
| 74 | !! Emile-Geay and Madec, 2009, Ocean Science. |
|---|
| 75 | !!---------------------------------------------------------------------- |
|---|
| 76 | INTEGER, INTENT(in) :: kt ! ocean time-step index |
|---|
| 77 | ! |
|---|
| 78 | INTEGER :: ji, jj ! dummy loop indices |
|---|
| 79 | REAL(wp), POINTER, DIMENSION(:,:,:) :: ztrdt |
|---|
| 80 | !!---------------------------------------------------------------------- |
|---|
| 81 | ! |
|---|
| 82 | IF( nn_timing == 1 ) CALL timing_start('tra_bbc') |
|---|
| 83 | ! |
|---|
| 84 | IF( l_trdtra ) THEN ! Save the input temperature trend |
|---|
| 85 | CALL wrk_alloc( jpi,jpj,jpk, ztrdt ) |
|---|
| 86 | !$OMP PARALLEL WORKSHARE |
|---|
| 87 | ztrdt(:,:,:) = tsa(:,:,:,jp_tem) |
|---|
| 88 | !$OMP END PARALLEL WORKSHARE |
|---|
| 89 | ENDIF |
|---|
| 90 | ! ! Add the geothermal trend on temperature |
|---|
| 91 | !$OMP PARALLEL DO schedule(static) private(jj, ji) |
|---|
| 92 | DO jj = 2, jpjm1 |
|---|
| 93 | DO ji = 2, jpim1 |
|---|
| 94 | tsa(ji,jj,mbkt(ji,jj),jp_tem) = tsa(ji,jj,mbkt(ji,jj),jp_tem) + qgh_trd0(ji,jj) / e3t_n(ji,jj,mbkt(ji,jj)) |
|---|
| 95 | END DO |
|---|
| 96 | END DO |
|---|
| 97 | ! |
|---|
| 98 | CALL lbc_lnk( tsa(:,:,:,jp_tem) , 'T', 1. ) |
|---|
| 99 | ! |
|---|
| 100 | IF( l_trdtra ) THEN ! Send the trend for diagnostics |
|---|
| 101 | !$OMP PARALLEL WORKSHARE |
|---|
| 102 | ztrdt(:,:,:) = tsa(:,:,:,jp_tem) - ztrdt(:,:,:) |
|---|
| 103 | !$OMP END PARALLEL WORKSHARE |
|---|
| 104 | CALL trd_tra( kt, 'TRA', jp_tem, jptra_bbc, ztrdt ) |
|---|
| 105 | CALL wrk_dealloc( jpi,jpj,jpk, ztrdt ) |
|---|
| 106 | ENDIF |
|---|
| 107 | ! |
|---|
| 108 | IF(ln_ctl) CALL prt_ctl( tab3d_1=tsa(:,:,:,jp_tem), clinfo1=' bbc - Ta: ', mask1=tmask, clinfo3='tra-ta' ) |
|---|
| 109 | ! |
|---|
| 110 | IF( nn_timing == 1 ) CALL timing_stop('tra_bbc') |
|---|
| 111 | ! |
|---|
| 112 | END SUBROUTINE tra_bbc |
|---|
| 113 | |
|---|
| 114 | |
|---|
| 115 | SUBROUTINE tra_bbc_init |
|---|
| 116 | !!---------------------------------------------------------------------- |
|---|
| 117 | !! *** ROUTINE tra_bbc_init *** |
|---|
| 118 | !! |
|---|
| 119 | !! ** Purpose : Compute once for all the trend associated with geothermal |
|---|
| 120 | !! heating that will be applied at each time step at the |
|---|
| 121 | !! last ocean level |
|---|
| 122 | !! |
|---|
| 123 | !! ** Method : Read the nambbc namelist and check the parameters. |
|---|
| 124 | !! |
|---|
| 125 | !! ** Input : - Namlist nambbc |
|---|
| 126 | !! - NetCDF file : geothermal_heating.nc ( if necessary ) |
|---|
| 127 | !! |
|---|
| 128 | !! ** Action : - read/fix the geothermal heat qgh_trd0 |
|---|
| 129 | !!---------------------------------------------------------------------- |
|---|
| 130 | INTEGER :: ji, jj ! dummy loop indices |
|---|
| 131 | INTEGER :: inum ! temporary logical unit |
|---|
| 132 | INTEGER :: ios ! Local integer output status for namelist read |
|---|
| 133 | INTEGER :: ierror ! local integer |
|---|
| 134 | ! |
|---|
| 135 | TYPE(FLD_N) :: sn_qgh ! informations about the geotherm. field to be read |
|---|
| 136 | CHARACTER(len=256) :: cn_dir ! Root directory for location of ssr files |
|---|
| 137 | ! |
|---|
| 138 | NAMELIST/nambbc/ln_trabbc, nn_geoflx, rn_geoflx_cst, sn_qgh, cn_dir |
|---|
| 139 | !!---------------------------------------------------------------------- |
|---|
| 140 | ! |
|---|
| 141 | REWIND( numnam_ref ) ! Namelist nambbc in reference namelist : Bottom momentum boundary condition |
|---|
| 142 | READ ( numnam_ref, nambbc, IOSTAT = ios, ERR = 901) |
|---|
| 143 | 901 IF( ios /= 0 ) CALL ctl_nam ( ios , 'nambbc in reference namelist', lwp ) |
|---|
| 144 | ! |
|---|
| 145 | REWIND( numnam_cfg ) ! Namelist nambbc in configuration namelist : Bottom momentum boundary condition |
|---|
| 146 | READ ( numnam_cfg, nambbc, IOSTAT = ios, ERR = 902 ) |
|---|
| 147 | 902 IF( ios /= 0 ) CALL ctl_nam ( ios , 'nambbc in configuration namelist', lwp ) |
|---|
| 148 | IF(lwm) WRITE ( numond, nambbc ) |
|---|
| 149 | ! |
|---|
| 150 | IF(lwp) THEN ! Control print |
|---|
| 151 | WRITE(numout,*) |
|---|
| 152 | WRITE(numout,*) 'tra_bbc : Bottom Boundary Condition (bbc), apply a Geothermal heating' |
|---|
| 153 | WRITE(numout,*) '~~~~~~~ ' |
|---|
| 154 | WRITE(numout,*) ' Namelist nambbc : set bbc parameters' |
|---|
| 155 | WRITE(numout,*) ' Apply a geothermal heating at ocean bottom ln_trabbc = ', ln_trabbc |
|---|
| 156 | WRITE(numout,*) ' type of geothermal flux nn_geoflx = ', nn_geoflx |
|---|
| 157 | WRITE(numout,*) ' Constant geothermal flux value rn_geoflx_cst = ', rn_geoflx_cst |
|---|
| 158 | WRITE(numout,*) |
|---|
| 159 | ENDIF |
|---|
| 160 | ! |
|---|
| 161 | IF( ln_trabbc ) THEN !== geothermal heating ==! |
|---|
| 162 | ! |
|---|
| 163 | ALLOCATE( qgh_trd0(jpi,jpj) ) ! allocation |
|---|
| 164 | ! |
|---|
| 165 | SELECT CASE ( nn_geoflx ) ! geothermal heat flux / (rauO * Cp) |
|---|
| 166 | ! |
|---|
| 167 | CASE ( 1 ) !* constant flux |
|---|
| 168 | IF(lwp) WRITE(numout,*) ' *** constant heat flux = ', rn_geoflx_cst |
|---|
| 169 | qgh_trd0(:,:) = r1_rau0_rcp * rn_geoflx_cst |
|---|
| 170 | ! |
|---|
| 171 | CASE ( 2 ) !* variable geothermal heat flux : read the geothermal fluxes in mW/m2 |
|---|
| 172 | IF(lwp) WRITE(numout,*) ' *** variable geothermal heat flux' |
|---|
| 173 | ! |
|---|
| 174 | ALLOCATE( sf_qgh(1), STAT=ierror ) |
|---|
| 175 | IF( ierror > 0 ) THEN |
|---|
| 176 | CALL ctl_stop( 'tra_bbc_init: unable to allocate sf_qgh structure' ) ; |
|---|
| 177 | RETURN |
|---|
| 178 | ENDIF |
|---|
| 179 | ALLOCATE( sf_qgh(1)%fnow(jpi,jpj,1) ) |
|---|
| 180 | IF( sn_qgh%ln_tint )ALLOCATE( sf_qgh(1)%fdta(jpi,jpj,1,2) ) |
|---|
| 181 | ! fill sf_chl with sn_chl and control print |
|---|
| 182 | CALL fld_fill( sf_qgh, (/ sn_qgh /), cn_dir, 'tra_bbc_init', & |
|---|
| 183 | & 'bottom temperature boundary condition', 'nambbc' ) |
|---|
| 184 | |
|---|
| 185 | CALL fld_read( nit000, 1, sf_qgh ) ! Read qgh data |
|---|
| 186 | qgh_trd0(:,:) = r1_rau0_rcp * sf_qgh(1)%fnow(:,:,1) * 1.e-3 ! conversion in W/m2 |
|---|
| 187 | ! |
|---|
| 188 | CASE DEFAULT |
|---|
| 189 | WRITE(ctmp1,*) ' bad flag value for nn_geoflx = ', nn_geoflx |
|---|
| 190 | CALL ctl_stop( ctmp1 ) |
|---|
| 191 | END SELECT |
|---|
| 192 | ! |
|---|
| 193 | ELSE |
|---|
| 194 | IF(lwp) WRITE(numout,*) ' *** no geothermal heat flux' |
|---|
| 195 | ENDIF |
|---|
| 196 | ! |
|---|
| 197 | END SUBROUTINE tra_bbc_init |
|---|
| 198 | |
|---|
| 199 | !!====================================================================== |
|---|
| 200 | END MODULE trabbc |
|---|
