New URL for NEMO forge!   http://forge.nemo-ocean.eu

Since March 2022 along with NEMO 4.2 release, the code development moved to a self-hosted GitLab.
This present forge is now archived and remained online for history.
trasbc.F90 in branches/2016/dev_r6519_HPC_4/NEMOGCM/NEMO/OPA_SRC/TRA – NEMO

source: branches/2016/dev_r6519_HPC_4/NEMOGCM/NEMO/OPA_SRC/TRA/trasbc.F90 @ 6748

Last change on this file since 6748 was 6748, checked in by mocavero, 8 years ago

GYRE hybrid parallelization

  • Property svn:keywords set to Id
File size: 12.7 KB
Line 
1MODULE trasbc
2   !!==============================================================================
3   !!                       ***  MODULE  trasbc  ***
4   !! Ocean active tracers:  surface boundary condition
5   !!==============================================================================
6   !! History :  OPA  !  1998-10  (G. Madec, G. Roullet, M. Imbard)  Original code
7   !!            8.2  !  2001-02  (D. Ludicone)  sea ice and free surface
8   !!  NEMO      1.0  !  2002-06  (G. Madec)  F90: Free form and module
9   !!            3.3  !  2010-04  (M. Leclair, G. Madec)  Forcing averaged over 2 time steps
10   !!             -   !  2010-09  (C. Ethe, G. Madec) Merge TRA-TRC
11   !!            3.6  !  2014-11  (P. Mathiot) isf melting forcing
12   !!----------------------------------------------------------------------
13
14   !!----------------------------------------------------------------------
15   !!   tra_sbc       : update the tracer trend at ocean surface
16   !!----------------------------------------------------------------------
17   USE oce            ! ocean dynamics and active tracers
18   USE sbc_oce        ! surface boundary condition: ocean
19   USE dom_oce        ! ocean space domain variables
20   USE phycst         ! physical constant
21   USE eosbn2         ! Equation Of State
22   USE sbcmod         ! ln_rnf 
23   USE sbcrnf         ! River runoff 
24   USE sbcisf         ! Ice shelf   
25   USE iscplini       ! Ice sheet coupling
26   USE traqsr         ! solar radiation penetration
27   USE trd_oce        ! trends: ocean variables
28   USE trdtra         ! trends manager: tracers
29   !
30   USE in_out_manager ! I/O manager
31   USE prtctl         ! Print control
32   USE iom            ! xIOS server
33   USE lbclnk         ! ocean lateral boundary conditions (or mpp link)
34   USE wrk_nemo       ! Memory Allocation
35   USE timing         ! Timing
36
37   IMPLICIT NONE
38   PRIVATE
39
40   PUBLIC   tra_sbc   ! routine called by step.F90
41
42   !! * Substitutions
43#  include "vectopt_loop_substitute.h90"
44   !!----------------------------------------------------------------------
45   !! NEMO/OPA 3.7 , NEMO Consortium (2014)
46   !! $Id$
47   !! Software governed by the CeCILL licence     (NEMOGCM/NEMO_CeCILL.txt)
48   !!----------------------------------------------------------------------
49CONTAINS
50
51   SUBROUTINE tra_sbc ( kt )
52      !!----------------------------------------------------------------------
53      !!                  ***  ROUTINE tra_sbc  ***
54      !!                   
55      !! ** Purpose :   Compute the tracer surface boundary condition trend of
56      !!      (flux through the interface, concentration/dilution effect)
57      !!      and add it to the general trend of tracer equations.
58      !!
59      !! ** Method :   The (air+ice)-sea flux has two components:
60      !!      (1) Fext, external forcing (i.e. flux through the (air+ice)-sea interface);
61      !!      (2) Fwe , tracer carried with the water that is exchanged with air+ice.
62      !!               The input forcing fields (emp, rnf, sfx, isf) contain Fext+Fwe,
63      !!             they are simply added to the tracer trend (tsa).
64      !!               In linear free surface case (ln_linssh=T), the volume of the
65      !!             ocean does not change with the water exchanges at the (air+ice)-sea
66      !!             interface. Therefore another term has to be added, to mimic the
67      !!             concentration/dilution effect associated with water exchanges.
68      !!
69      !! ** Action  : - Update tsa with the surface boundary condition trend
70      !!              - send trends to trdtra module for further diagnostics(l_trdtra=T)
71      !!----------------------------------------------------------------------
72      INTEGER, INTENT(in) ::   kt   ! ocean time-step index
73      !
74      INTEGER  ::   ji, jj, jk, jn        ! dummy loop indices 
75      INTEGER  ::   ikt, ikb              ! local integers
76      REAL(wp) ::   zfact, z1_e3t, zdep   ! local scalar
77      REAL(wp), POINTER, DIMENSION(:,:,:) ::  ztrdt, ztrds
78      !!----------------------------------------------------------------------
79      !
80      IF( nn_timing == 1 )  CALL timing_start('tra_sbc')
81      !
82      IF( kt == nit000 ) THEN
83         IF(lwp) WRITE(numout,*)
84         IF(lwp) WRITE(numout,*) 'tra_sbc : TRAcer Surface Boundary Condition'
85         IF(lwp) WRITE(numout,*) '~~~~~~~ '
86      ENDIF
87      !
88      IF( l_trdtra ) THEN                    !* Save ta and sa trends
89         CALL wrk_alloc( jpi, jpj, jpk, ztrdt, ztrds ) 
90!$OMP PARALLEL WORKSHARE
91         ztrdt(:,:,:) = tsa(:,:,:,jp_tem)
92         ztrds(:,:,:) = tsa(:,:,:,jp_sal)
93!$OMP END PARALLEL WORKSHARE
94      ENDIF
95      !
96!!gm  This should be moved into sbcmod.F90 module ? (especially now that ln_traqsr is read in namsbc namelist)
97      IF( .NOT.ln_traqsr ) THEN     ! no solar radiation penetration
98!$OMP PARALLEL WORKSHARE
99         qns(:,:) = qns(:,:) + qsr(:,:)      ! total heat flux in qns
100         qsr(:,:) = 0._wp                     ! qsr set to zero
101!$OMP END PARALLEL WORKSHARE
102      ENDIF
103
104      !----------------------------------------
105      !        EMP, SFX and QNS effects
106      !----------------------------------------
107      !                             !==  Set before sbc tracer content fields  ==!
108      IF( kt == nit000 ) THEN             !* 1st time-step
109         IF( ln_rstart .AND.    &               ! Restart: read in restart file
110              & iom_varid( numror, 'sbc_hc_b', ldstop = .FALSE. ) > 0 ) THEN
111            IF(lwp) WRITE(numout,*) '          nit000-1 sbc tracer content field read in the restart file'
112            zfact = 0.5_wp
113            CALL iom_get( numror, jpdom_autoglo, 'sbc_hc_b', sbc_tsc_b(:,:,jp_tem) )   ! before heat content sbc trend
114            CALL iom_get( numror, jpdom_autoglo, 'sbc_sc_b', sbc_tsc_b(:,:,jp_sal) )   ! before salt content sbc trend
115         ELSE                                   ! No restart or restart not found: Euler forward time stepping
116            zfact = 1._wp
117!$OMP PARALLEL WORKSHARE
118            sbc_tsc_b(:,:,:) = 0._wp
119!$OMP END PARALLEL WORKSHARE
120         ENDIF
121      ELSE                                !* other time-steps: swap of forcing fields
122         zfact = 0.5_wp
123!$OMP PARALLEL WORKSHARE
124         sbc_tsc_b(:,:,:) = sbc_tsc(:,:,:)
125!$OMP END PARALLEL WORKSHARE
126      ENDIF
127      !                             !==  Now sbc tracer content fields  ==!
128!$OMP PARALLEL DO schedule(static) private(jj, ji)
129      DO jj = 2, jpj
130         DO ji = fs_2, fs_jpim1   ! vector opt.
131            sbc_tsc(ji,jj,jp_tem) = r1_rau0_rcp * qns(ji,jj)   ! non solar heat flux
132            sbc_tsc(ji,jj,jp_sal) = r1_rau0     * sfx(ji,jj)   ! salt flux due to freezing/melting
133         END DO
134      END DO
135      IF( ln_linssh ) THEN                !* linear free surface 
136!$OMP PARALLEL DO schedule(static) private(jj, ji)
137         DO jj = 2, jpj                         !==>> add concentration/dilution effect due to constant volume cell
138            DO ji = fs_2, fs_jpim1   ! vector opt.
139               sbc_tsc(ji,jj,jp_tem) = sbc_tsc(ji,jj,jp_tem) + r1_rau0 * emp(ji,jj) * tsn(ji,jj,1,jp_tem)
140               sbc_tsc(ji,jj,jp_sal) = sbc_tsc(ji,jj,jp_sal) + r1_rau0 * emp(ji,jj) * tsn(ji,jj,1,jp_sal)
141            END DO
142         END DO                                 !==>> output c./d. term
143         IF( iom_use('emp_x_sst') )   CALL iom_put( "emp_x_sst", emp (:,:) * tsn(:,:,1,jp_tem) )
144         IF( iom_use('emp_x_sss') )   CALL iom_put( "emp_x_sss", emp (:,:) * tsn(:,:,1,jp_sal) )
145      ENDIF
146      !
147      DO jn = 1, jpts               !==  update tracer trend  ==!
148!$OMP PARALLEL DO schedule(static) private(jj, ji)
149         DO jj = 2, jpj
150            DO ji = fs_2, fs_jpim1   ! vector opt. 
151               tsa(ji,jj,1,jn) = tsa(ji,jj,1,jn) + zfact * ( sbc_tsc_b(ji,jj,jn) + sbc_tsc(ji,jj,jn) ) / e3t_n(ji,jj,1)
152            END DO
153         END DO
154      END DO
155      !                 
156      IF( lrst_oce ) THEN           !==  write sbc_tsc in the ocean restart file  ==!
157         CALL iom_rstput( kt, nitrst, numrow, 'sbc_hc_b', sbc_tsc(:,:,jp_tem) )
158         CALL iom_rstput( kt, nitrst, numrow, 'sbc_sc_b', sbc_tsc(:,:,jp_sal) )
159      ENDIF
160      !
161      !----------------------------------------
162      !       Ice Shelf effects (ISF)
163      !     tbl treated as in Losh (2008) JGR
164      !----------------------------------------
165      !
166!!gm BUG ?   Why no differences between non-linear and linear free surface ?
167!!gm         probably taken into account in r1_hisf_tbl : to be verified
168      IF( ln_isf ) THEN
169         zfact = 0.5_wp
170         DO jj = 2, jpj
171            DO ji = fs_2, fs_jpim1
172               !
173               ikt = misfkt(ji,jj)
174               ikb = misfkb(ji,jj)
175               !
176               ! level fully include in the ice shelf boundary layer
177               ! sign - because fwf sign of evapo (rnf sign of precip)
178               DO jk = ikt, ikb - 1
179               ! compute trend
180                  tsa(ji,jj,jk,jp_tem) = tsa(ji,jj,jk,jp_tem)                                                &
181                     &           + zfact * ( risf_tsc_b(ji,jj,jp_tem) + risf_tsc(ji,jj,jp_tem) )             &
182                     &           * r1_hisf_tbl(ji,jj)
183               END DO
184   
185               ! level partially include in ice shelf boundary layer
186               ! compute trend
187               tsa(ji,jj,ikb,jp_tem) = tsa(ji,jj,ikb,jp_tem)                                                 &
188                  &              + zfact * ( risf_tsc_b(ji,jj,jp_tem) + risf_tsc(ji,jj,jp_tem) )             &
189                  &              * r1_hisf_tbl(ji,jj) * ralpha(ji,jj)
190
191            END DO
192         END DO
193         IF( lrst_oce ) THEN
194            CALL iom_rstput( kt, nitrst, numrow, 'fwf_isf_b', fwfisf  (:,:)        )
195            CALL iom_rstput( kt, nitrst, numrow, 'isf_hc_b' , risf_tsc(:,:,jp_tem) )
196            CALL iom_rstput( kt, nitrst, numrow, 'isf_sc_b' , risf_tsc(:,:,jp_sal) )
197         ENDIF
198      END IF
199      !
200      !----------------------------------------
201      !        River Runoff effects
202      !----------------------------------------
203      !
204      IF( ln_rnf ) THEN         ! input of heat and salt due to river runoff
205         zfact = 0.5_wp
206         DO jj = 2, jpj 
207            DO ji = fs_2, fs_jpim1
208               IF( rnf(ji,jj) /= 0._wp ) THEN
209                  zdep = zfact / h_rnf(ji,jj)
210                  DO jk = 1, nk_rnf(ji,jj)
211                                        tsa(ji,jj,jk,jp_tem) = tsa(ji,jj,jk,jp_tem)                                 &
212                                           &                 +  ( rnf_tsc_b(ji,jj,jp_tem) + rnf_tsc(ji,jj,jp_tem) ) * zdep
213                     IF( ln_rnf_sal )   tsa(ji,jj,jk,jp_sal) = tsa(ji,jj,jk,jp_sal)                                 &
214                                           &                 +  ( rnf_tsc_b(ji,jj,jp_sal) + rnf_tsc(ji,jj,jp_sal) ) * zdep 
215                  END DO
216               ENDIF
217            END DO 
218         END DO 
219      ENDIF
220
221      IF( iom_use('rnf_x_sst') )   CALL iom_put( "rnf_x_sst", rnf*tsn(:,:,1,jp_tem) )   ! runoff term on sst
222      IF( iom_use('rnf_x_sss') )   CALL iom_put( "rnf_x_sss", rnf*tsn(:,:,1,jp_sal) )   ! runoff term on sss
223
224      !
225      !----------------------------------------
226      !        Ice Sheet coupling imbalance correction to have conservation
227      !----------------------------------------
228      !
229      IF( ln_iscpl .AND. ln_hsb) THEN         ! input of heat and salt due to river runoff
230!$OMP PARALLEL DO schedule(static) private(jk, jj, ji, zdep)
231         DO jk = 1,jpk
232            DO jj = 2, jpj 
233               DO ji = fs_2, fs_jpim1
234                  zdep = 1._wp / e3t_n(ji,jj,jk) 
235                  tsa(ji,jj,jk,jp_tem) = tsa(ji,jj,jk,jp_tem) - htsc_iscpl(ji,jj,jk,jp_tem)                       &
236                      &                                         * zdep
237                  tsa(ji,jj,jk,jp_sal) = tsa(ji,jj,jk,jp_sal) - htsc_iscpl(ji,jj,jk,jp_sal)                       &
238                      &                                         * zdep 
239               END DO 
240            END DO 
241         END DO
242      ENDIF
243
244      IF( l_trdtra )   THEN                      ! save the horizontal diffusive trends for further diagnostics
245!$OMP PARALLEL WORKSHARE
246         ztrdt(:,:,:) = tsa(:,:,:,jp_tem) - ztrdt(:,:,:)
247         ztrds(:,:,:) = tsa(:,:,:,jp_sal) - ztrds(:,:,:)
248!$OMP END PARALLEL WORKSHARE
249         CALL trd_tra( kt, 'TRA', jp_tem, jptra_nsr, ztrdt )
250         CALL trd_tra( kt, 'TRA', jp_sal, jptra_nsr, ztrds )
251         CALL wrk_dealloc( jpi, jpj, jpk, ztrdt, ztrds ) 
252      ENDIF
253      !
254      IF(ln_ctl)   CALL prt_ctl( tab3d_1=tsa(:,:,:,jp_tem), clinfo1=' sbc  - Ta: ', mask1=tmask,   &
255         &                       tab3d_2=tsa(:,:,:,jp_sal), clinfo2=       ' Sa: ', mask2=tmask, clinfo3='tra' )
256      !
257      IF( nn_timing == 1 )  CALL timing_stop('tra_sbc')
258      !
259   END SUBROUTINE tra_sbc
260
261   !!======================================================================
262END MODULE trasbc
Note: See TracBrowser for help on using the repository browser.