New URL for NEMO forge!   http://forge.nemo-ocean.eu

Since March 2022 along with NEMO 4.2 release, the code development moved to a self-hosted GitLab.
This present forge is now archived and remained online for history.
zpshde.F90 in branches/2016/dev_r6519_HPC_4/NEMOGCM/NEMO/OPA_SRC/TRA – NEMO

source: branches/2016/dev_r6519_HPC_4/NEMOGCM/NEMO/OPA_SRC/TRA/zpshde.F90 @ 7037

Last change on this file since 7037 was 7037, checked in by mocavero, 8 years ago

ORCA2_LIM_PISCES hybrid version update
  • Property svn:keywords set to Id
File size: 25.1 KB
Line 
1MODULE zpshde
2   !!======================================================================
3   !!                       ***  MODULE zpshde   ***
4   !! z-coordinate + partial step : Horizontal Derivative at ocean bottom level
5   !!======================================================================
6   !! History :  OPA  !  2002-04  (A. Bozec)  Original code
7   !!   NEMO     1.0  !  2002-08  (G. Madec E. Durand)  Optimization and Free form
8   !!             -   !  2004-03  (C. Ethe)  adapted for passive tracers
9   !!            3.3  !  2010-05  (C. Ethe, G. Madec)  merge TRC-TRA
10   !!            3.6  !  2014-11  (P. Mathiot) Add zps_hde_isf (needed to open a cavity)
11   !!======================================================================
12   
13   !!----------------------------------------------------------------------
14   !!   zps_hde      :  Horizontal DErivative of T, S and rd at the last
15   !!                   ocean level (Z-coord. with Partial Steps)
16   !!----------------------------------------------------------------------
17   USE oce             ! ocean: dynamics and tracers variables
18   USE dom_oce         ! domain: ocean variables
19   USE phycst          ! physical constants
20   USE eosbn2          ! ocean equation of state
21   USE in_out_manager  ! I/O manager
22   USE lbclnk          ! lateral boundary conditions (or mpp link)
23   USE lib_mpp         ! MPP library
24   USE wrk_nemo        ! Memory allocation
25   USE timing          ! Timing
26
27   IMPLICIT NONE
28   PRIVATE
29
30   PUBLIC   zps_hde     ! routine called by step.F90
31   PUBLIC   zps_hde_isf ! routine called by step.F90
32
33   !! * Substitutions
34#  include "vectopt_loop_substitute.h90"
35   !!----------------------------------------------------------------------
36   !! NEMO/OPA 3.3 , NEMO Consortium (2010)
37   !! $Id$
38   !! Software governed by the CeCILL licence     (NEMOGCM/NEMO_CeCILL.txt)
39   !!----------------------------------------------------------------------
40CONTAINS
41
42   SUBROUTINE zps_hde( kt, kjpt, pta, pgtu, pgtv,   &
43      &                          prd, pgru, pgrv    )
44      !!----------------------------------------------------------------------
45      !!                     ***  ROUTINE zps_hde  ***
46      !!                   
47      !! ** Purpose :   Compute the horizontal derivative of T, S and rho
48      !!      at u- and v-points with a linear interpolation for z-coordinate
49      !!      with partial steps.
50      !!
51      !! ** Method  :   In z-coord with partial steps, scale factors on last
52      !!      levels are different for each grid point, so that T, S and rd
53      !!      points are not at the same depth as in z-coord. To have horizontal
54      !!      gradients again, we interpolate T and S at the good depth :
55      !!      Linear interpolation of T, S   
56      !!         Computation of di(tb) and dj(tb) by vertical interpolation:
57      !!          di(t) = t~ - t(i,j,k) or t(i+1,j,k) - t~
58      !!          dj(t) = t~ - t(i,j,k) or t(i,j+1,k) - t~
59      !!         This formulation computes the two cases:
60      !!                 CASE 1                   CASE 2 
61      !!         k-1  ___ ___________   k-1   ___ ___________
62      !!                    Ti  T~                  T~  Ti+1
63      !!                  _____                        _____
64      !!         k        |   |Ti+1     k           Ti |   |
65      !!                  |   |____                ____|   |
66      !!              ___ |   |   |           ___  |   |   |
67      !!                 
68      !!      case 1->   e3w(i+1) >= e3w(i) ( and e3w(j+1) >= e3w(j) ) then
69      !!          t~ = t(i+1,j  ,k) + (e3w(i+1) - e3w(i)) * dk(Ti+1)/e3w(i+1)
70      !!        ( t~ = t(i  ,j+1,k) + (e3w(j+1) - e3w(j)) * dk(Tj+1)/e3w(j+1)  )
71      !!          or
72      !!      case 2->   e3w(i+1) <= e3w(i) ( and e3w(j+1) <= e3w(j) ) then
73      !!          t~ = t(i,j,k) + (e3w(i) - e3w(i+1)) * dk(Ti)/e3w(i )
74      !!        ( t~ = t(i,j,k) + (e3w(j) - e3w(j+1)) * dk(Tj)/e3w(j ) )
75      !!          Idem for di(s) and dj(s)         
76      !!
77      !!      For rho, we call eos which will compute rd~(t~,s~) at the right
78      !!      depth zh from interpolated T and S for the different formulations
79      !!      of the equation of state (eos).
80      !!      Gradient formulation for rho :
81      !!          di(rho) = rd~ - rd(i,j,k)   or   rd(i+1,j,k) - rd~
82      !!
83      !! ** Action  : compute for top interfaces
84      !!              - pgtu, pgtv: horizontal gradient of tracer at u- & v-points
85      !!              - pgru, pgrv: horizontal gradient of rho (if present) at u- & v-points
86      !!----------------------------------------------------------------------
87      INTEGER                              , INTENT(in   )           ::  kt          ! ocean time-step index
88      INTEGER                              , INTENT(in   )           ::  kjpt        ! number of tracers
89      REAL(wp), DIMENSION(jpi,jpj,jpk,kjpt), INTENT(in   )           ::  pta         ! 4D tracers fields
90      REAL(wp), DIMENSION(jpi,jpj,    kjpt), INTENT(  out)           ::  pgtu, pgtv  ! hor. grad. of ptra at u- & v-pts
91      REAL(wp), DIMENSION(jpi,jpj,jpk     ), INTENT(in   ), OPTIONAL ::  prd         ! 3D density anomaly fields
92      REAL(wp), DIMENSION(jpi,jpj         ), INTENT(  out), OPTIONAL ::  pgru, pgrv  ! hor. grad of prd at u- & v-pts (bottom)
93      !
94      INTEGER  ::   ji, jj, jn                  ! Dummy loop indices
95      INTEGER  ::   iku, ikv, ikum1, ikvm1      ! partial step level (ocean bottom level) at u- and v-points
96      REAL(wp) ::   ze3wu, ze3wv, zmaxu, zmaxv  ! local scalars
97      REAL(wp), DIMENSION(jpi,jpj)      ::   zri, zrj, zhi, zhj   ! NB: 3rd dim=1 to use eos
98      REAL(wp), DIMENSION(jpi,jpj,kjpt) ::   zti, ztj             !
99      !!----------------------------------------------------------------------
100      !
101      IF( nn_timing == 1 )   CALL timing_start( 'zps_hde')
102      !
103!$OMP PARALLEL
104!$OMP WORKSHARE
105      pgtu(:,:,:)=0._wp   ;   zti (:,:,:)=0._wp   ;   zhi (:,:  )=0._wp
106      pgtv(:,:,:)=0._wp   ;   ztj (:,:,:)=0._wp   ;   zhj (:,:  )=0._wp
107!$OMP END WORKSHARE
108      !
109      DO jn = 1, kjpt      !==   Interpolation of tracers at the last ocean level   ==!
110         !
111!$OMP DO schedule(static) private(jj,ji,iku,ikv,ze3wu,ze3wv,zmaxu,zmaxv)
112         DO jj = 1, jpjm1
113            DO ji = 1, jpim1
114               iku = mbku(ji,jj)   ;   ikum1 = MAX( iku - 1 , 1 )    ! last and before last ocean level at u- & v-points
115               ikv = mbkv(ji,jj)   ;   ikvm1 = MAX( ikv - 1 , 1 )    ! if level first is a p-step, ik.m1=1
116!!gm BUG ? when applied to before fields, e3w_b should be used....
117               ze3wu = e3w_n(ji+1,jj  ,iku) - e3w_n(ji,jj,iku)
118               ze3wv = e3w_n(ji  ,jj+1,ikv) - e3w_n(ji,jj,ikv)
119               !
120               ! i- direction
121               IF( ze3wu >= 0._wp ) THEN      ! case 1
122                  zmaxu =  ze3wu / e3w_n(ji+1,jj,iku)
123                  ! interpolated values of tracers
124                  zti (ji,jj,jn) = pta(ji+1,jj,iku,jn) + zmaxu * ( pta(ji+1,jj,ikum1,jn) - pta(ji+1,jj,iku,jn) )
125                  ! gradient of  tracers
126                  pgtu(ji,jj,jn) = umask(ji,jj,1) * ( zti(ji,jj,jn) - pta(ji,jj,iku,jn) )
127               ELSE                           ! case 2
128                  zmaxu = -ze3wu / e3w_n(ji,jj,iku)
129                  ! interpolated values of tracers
130                  zti (ji,jj,jn) = pta(ji,jj,iku,jn) + zmaxu * ( pta(ji,jj,ikum1,jn) - pta(ji,jj,iku,jn) )
131                  ! gradient of tracers
132                  pgtu(ji,jj,jn) = umask(ji,jj,1) * ( pta(ji+1,jj,iku,jn) - zti(ji,jj,jn) )
133               ENDIF
134               !
135               ! j- direction
136               IF( ze3wv >= 0._wp ) THEN      ! case 1
137                  zmaxv =  ze3wv / e3w_n(ji,jj+1,ikv)
138                  ! interpolated values of tracers
139                  ztj (ji,jj,jn) = pta(ji,jj+1,ikv,jn) + zmaxv * ( pta(ji,jj+1,ikvm1,jn) - pta(ji,jj+1,ikv,jn) )
140                  ! gradient of tracers
141                  pgtv(ji,jj,jn) = vmask(ji,jj,1) * ( ztj(ji,jj,jn) - pta(ji,jj,ikv,jn) )
142               ELSE                           ! case 2
143                  zmaxv =  -ze3wv / e3w_n(ji,jj,ikv)
144                  ! interpolated values of tracers
145                  ztj (ji,jj,jn) = pta(ji,jj,ikv,jn) + zmaxv * ( pta(ji,jj,ikvm1,jn) - pta(ji,jj,ikv,jn) )
146                  ! gradient of tracers
147                  pgtv(ji,jj,jn) = vmask(ji,jj,1) * ( pta(ji,jj+1,ikv,jn) - ztj(ji,jj,jn) )
148               ENDIF
149            END DO
150         END DO
151!$OMP END DO
152!$OMP SINGLE
153         CALL lbc_lnk( pgtu(:,:,jn), 'U', -1. )   ;   CALL lbc_lnk( pgtv(:,:,jn), 'V', -1. )   ! Lateral boundary cond.
154!$OMP END SINGLE
155         !
156      END DO
157!$OMP END PARALLEL
158      !               
159      IF( PRESENT( prd ) ) THEN    !==  horizontal derivative of density anomalies (rd)  ==!    (optional part)
160!$OMP PARALLEL
161!$OMP WORKSHARE
162         pgru(:,:) = 0._wp
163         pgrv(:,:) = 0._wp                ! depth of the partial step level
164!$OMP END WORKSHARE NOWAIT
165!$OMP DO schedule(static) private(jj,ji,iku,ikv,ze3wu,ze3wv)
166         DO jj = 1, jpjm1
167            DO ji = 1, jpim1
168               iku = mbku(ji,jj)
169               ikv = mbkv(ji,jj)
170               ze3wu  = e3w_n(ji+1,jj  ,iku) - e3w_n(ji,jj,iku)
171               ze3wv  = e3w_n(ji  ,jj+1,ikv) - e3w_n(ji,jj,ikv)
172               IF( ze3wu >= 0._wp ) THEN   ;   zhi(ji,jj) = gdept_n(ji  ,jj,iku)     ! i-direction: case 1
173               ELSE                        ;   zhi(ji,jj) = gdept_n(ji+1,jj,iku)     ! -     -      case 2
174               ENDIF
175               IF( ze3wv >= 0._wp ) THEN   ;   zhj(ji,jj) = gdept_n(ji,jj  ,ikv)     ! j-direction: case 1
176               ELSE                        ;   zhj(ji,jj) = gdept_n(ji,jj+1,ikv)     ! -     -      case 2
177               ENDIF
178            END DO
179         END DO
180!$OMP END DO NOWAIT
181!$OMP END PARALLEL
182         !
183         CALL eos( zti, zhi, zri )        ! interpolated density from zti, ztj
184         CALL eos( ztj, zhj, zrj )        ! at the partial step depth output in  zri, zrj
185         !
186!$OMP PARALLEL DO schedule(static) private(jj,ji,iku,ikv,ze3wu,ze3wv)
187         DO jj = 1, jpjm1                 ! Gradient of density at the last level
188            DO ji = 1, jpim1
189               iku = mbku(ji,jj)
190               ikv = mbkv(ji,jj)
191               ze3wu  = e3w_n(ji+1,jj  ,iku) - e3w_n(ji,jj,iku)
192               ze3wv  = e3w_n(ji  ,jj+1,ikv) - e3w_n(ji,jj,ikv)
193               IF( ze3wu >= 0._wp ) THEN   ;   pgru(ji,jj) = umask(ji,jj,1) * ( zri(ji  ,jj    ) - prd(ji,jj,iku) )   ! i: 1
194               ELSE                        ;   pgru(ji,jj) = umask(ji,jj,1) * ( prd(ji+1,jj,iku) - zri(ji,jj    ) )   ! i: 2
195               ENDIF
196               IF( ze3wv >= 0._wp ) THEN   ;   pgrv(ji,jj) = vmask(ji,jj,1) * ( zrj(ji,jj      ) - prd(ji,jj,ikv) )   ! j: 1
197               ELSE                        ;   pgrv(ji,jj) = vmask(ji,jj,1) * ( prd(ji,jj+1,ikv) - zrj(ji,jj    ) )   ! j: 2
198               ENDIF
199            END DO
200         END DO
201         CALL lbc_lnk( pgru , 'U', -1. )   ;   CALL lbc_lnk( pgrv , 'V', -1. )   ! Lateral boundary conditions
202         !
203      END IF
204      !
205      IF( nn_timing == 1 )   CALL timing_stop( 'zps_hde')
206      !
207   END SUBROUTINE zps_hde
208   !
209   SUBROUTINE zps_hde_isf( kt, kjpt, pta, pgtu, pgtv, pgtui, pgtvi,  &
210      &                          prd, pgru, pgrv, pgrui, pgrvi )
211      !!----------------------------------------------------------------------
212      !!                     ***  ROUTINE zps_hde_isf  ***
213      !!                   
214      !! ** Purpose :   Compute the horizontal derivative of T, S and rho
215      !!      at u- and v-points with a linear interpolation for z-coordinate
216      !!      with partial steps for top (ice shelf) and bottom.
217      !!
218      !! ** Method  :   In z-coord with partial steps, scale factors on last
219      !!      levels are different for each grid point, so that T, S and rd
220      !!      points are not at the same depth as in z-coord. To have horizontal
221      !!      gradients again, we interpolate T and S at the good depth :
222      !!      For the bottom case:
223      !!      Linear interpolation of T, S   
224      !!         Computation of di(tb) and dj(tb) by vertical interpolation:
225      !!          di(t) = t~ - t(i,j,k) or t(i+1,j,k) - t~
226      !!          dj(t) = t~ - t(i,j,k) or t(i,j+1,k) - t~
227      !!         This formulation computes the two cases:
228      !!                 CASE 1                   CASE 2 
229      !!         k-1  ___ ___________   k-1   ___ ___________
230      !!                    Ti  T~                  T~  Ti+1
231      !!                  _____                        _____
232      !!         k        |   |Ti+1     k           Ti |   |
233      !!                  |   |____                ____|   |
234      !!              ___ |   |   |           ___  |   |   |
235      !!                 
236      !!      case 1->   e3w(i+1) >= e3w(i) ( and e3w(j+1) >= e3w(j) ) then
237      !!          t~ = t(i+1,j  ,k) + (e3w(i+1) - e3w(i)) * dk(Ti+1)/e3w(i+1)
238      !!        ( t~ = t(i  ,j+1,k) + (e3w(j+1) - e3w(j)) * dk(Tj+1)/e3w(j+1)  )
239      !!          or
240      !!      case 2->   e3w(i+1) <= e3w(i) ( and e3w(j+1) <= e3w(j) ) then
241      !!          t~ = t(i,j,k) + (e3w(i) - e3w(i+1)) * dk(Ti)/e3w(i )
242      !!        ( t~ = t(i,j,k) + (e3w(j) - e3w(j+1)) * dk(Tj)/e3w(j ) )
243      !!          Idem for di(s) and dj(s)         
244      !!
245      !!      For rho, we call eos which will compute rd~(t~,s~) at the right
246      !!      depth zh from interpolated T and S for the different formulations
247      !!      of the equation of state (eos).
248      !!      Gradient formulation for rho :
249      !!          di(rho) = rd~ - rd(i,j,k)   or   rd(i+1,j,k) - rd~
250      !!
251      !!      For the top case (ice shelf): As for the bottom case but upside down
252      !!
253      !! ** Action  : compute for top and bottom interfaces
254      !!              - pgtu, pgtv, pgtui, pgtvi: horizontal gradient of tracer at u- & v-points
255      !!              - pgru, pgrv, pgrui, pgtvi: horizontal gradient of rho (if present) at u- & v-points
256      !!----------------------------------------------------------------------
257      INTEGER                              , INTENT(in   )           ::  kt           ! ocean time-step index
258      INTEGER                              , INTENT(in   )           ::  kjpt         ! number of tracers
259      REAL(wp), DIMENSION(jpi,jpj,jpk,kjpt), INTENT(in   )           ::  pta          ! 4D tracers fields
260      REAL(wp), DIMENSION(jpi,jpj,    kjpt), INTENT(  out)           ::  pgtu, pgtv   ! hor. grad. of ptra at u- & v-pts
261      REAL(wp), DIMENSION(jpi,jpj,    kjpt), INTENT(  out)           ::  pgtui, pgtvi ! hor. grad. of stra at u- & v-pts (ISF)
262      REAL(wp), DIMENSION(jpi,jpj,jpk     ), INTENT(in   ), OPTIONAL ::  prd          ! 3D density anomaly fields
263      REAL(wp), DIMENSION(jpi,jpj         ), INTENT(  out), OPTIONAL ::  pgru, pgrv   ! hor. grad of prd at u- & v-pts (bottom)
264      REAL(wp), DIMENSION(jpi,jpj         ), INTENT(  out), OPTIONAL ::  pgrui, pgrvi ! hor. grad of prd at u- & v-pts (top)
265      !
266      INTEGER  ::   ji, jj, jn      ! Dummy loop indices
267      INTEGER  ::   iku, ikv, ikum1, ikvm1,ikup1, ikvp1   ! partial step level (ocean bottom level) at u- and v-points
268      REAL(wp) ::  ze3wu, ze3wv, zmaxu, zmaxv             ! temporary scalars
269      REAL(wp), DIMENSION(jpi,jpj)      ::  zri, zrj, zhi, zhj   ! NB: 3rd dim=1 to use eos
270      REAL(wp), DIMENSION(jpi,jpj,kjpt) ::  zti, ztj             !
271      !!----------------------------------------------------------------------
272      !
273      IF( nn_timing == 1 )  CALL timing_start( 'zps_hde_isf')
274      !
275      pgtu (:,:,:) = 0._wp   ;   pgtv (:,:,:) =0._wp
276      pgtui(:,:,:) = 0._wp   ;   pgtvi(:,:,:) =0._wp
277      zti  (:,:,:) = 0._wp   ;   ztj  (:,:,:) =0._wp
278      zhi  (:,:  ) = 0._wp   ;   zhj  (:,:  ) =0._wp
279      !
280      DO jn = 1, kjpt      !==   Interpolation of tracers at the last ocean level   ==!
281         !
282         DO jj = 1, jpjm1
283            DO ji = 1, jpim1
284
285               iku = mbku(ji,jj); ikum1 = MAX( iku - 1 , 1 )    ! last and before last ocean level at u- & v-points
286               ikv = mbkv(ji,jj); ikvm1 = MAX( ikv - 1 , 1 )    ! if level first is a p-step, ik.m1=1
287               ze3wu = gdept_n(ji+1,jj,iku) - gdept_n(ji,jj,iku)
288               ze3wv = gdept_n(ji,jj+1,ikv) - gdept_n(ji,jj,ikv)
289               !
290               ! i- direction
291               IF( ze3wu >= 0._wp ) THEN      ! case 1
292                  zmaxu =  ze3wu / e3w_n(ji+1,jj,iku)
293                  ! interpolated values of tracers
294                  zti (ji,jj,jn) = pta(ji+1,jj,iku,jn) + zmaxu * ( pta(ji+1,jj,ikum1,jn) - pta(ji+1,jj,iku,jn) )
295                  ! gradient of  tracers
296                  pgtu(ji,jj,jn) = ssumask(ji,jj) * ( zti(ji,jj,jn) - pta(ji,jj,iku,jn) )
297               ELSE                           ! case 2
298                  zmaxu = -ze3wu / e3w_n(ji,jj,iku)
299                  ! interpolated values of tracers
300                  zti (ji,jj,jn) = pta(ji,jj,iku,jn) + zmaxu * ( pta(ji,jj,ikum1,jn) - pta(ji,jj,iku,jn) )
301                  ! gradient of tracers
302                  pgtu(ji,jj,jn) = ssumask(ji,jj) * ( pta(ji+1,jj,iku,jn) - zti(ji,jj,jn) )
303               ENDIF
304               !
305               ! j- direction
306               IF( ze3wv >= 0._wp ) THEN      ! case 1
307                  zmaxv =  ze3wv / e3w_n(ji,jj+1,ikv)
308                  ! interpolated values of tracers
309                  ztj (ji,jj,jn) = pta(ji,jj+1,ikv,jn) + zmaxv * ( pta(ji,jj+1,ikvm1,jn) - pta(ji,jj+1,ikv,jn) )
310                  ! gradient of tracers
311                  pgtv(ji,jj,jn) = ssvmask(ji,jj) * ( ztj(ji,jj,jn) - pta(ji,jj,ikv,jn) )
312               ELSE                           ! case 2
313                  zmaxv =  -ze3wv / e3w_n(ji,jj,ikv)
314                  ! interpolated values of tracers
315                  ztj (ji,jj,jn) = pta(ji,jj,ikv,jn) + zmaxv * ( pta(ji,jj,ikvm1,jn) - pta(ji,jj,ikv,jn) )
316                  ! gradient of tracers
317                  pgtv(ji,jj,jn) = ssvmask(ji,jj) * ( pta(ji,jj+1,ikv,jn) - ztj(ji,jj,jn) )
318               ENDIF
319
320            END DO
321         END DO
322         CALL lbc_lnk( pgtu(:,:,jn), 'U', -1. )   ;   CALL lbc_lnk( pgtv(:,:,jn), 'V', -1. )   ! Lateral boundary cond.
323         !
324      END DO
325
326      ! horizontal derivative of density anomalies (rd)
327      IF( PRESENT( prd ) ) THEN         ! depth of the partial step level
328         pgru(:,:)=0.0_wp   ; pgrv(:,:)=0.0_wp ; 
329         !
330         DO jj = 1, jpjm1
331            DO ji = 1, jpim1
332
333               iku = mbku(ji,jj)
334               ikv = mbkv(ji,jj)
335               ze3wu = gdept_n(ji+1,jj,iku) - gdept_n(ji,jj,iku)
336               ze3wv = gdept_n(ji,jj+1,ikv) - gdept_n(ji,jj,ikv)
337               !
338               IF( ze3wu >= 0._wp ) THEN   ;   zhi(ji,jj) = gdept_n(ji  ,jj,iku)    ! i-direction: case 1
339               ELSE                        ;   zhi(ji,jj) = gdept_n(ji+1,jj,iku)    ! -     -      case 2
340               ENDIF
341               IF( ze3wv >= 0._wp ) THEN   ;   zhj(ji,jj) = gdept_n(ji,jj  ,ikv)    ! j-direction: case 1
342               ELSE                        ;   zhj(ji,jj) = gdept_n(ji,jj+1,ikv)    ! -     -      case 2
343               ENDIF
344
345            END DO
346         END DO
347
348         ! Compute interpolated rd from zti, ztj for the 2 cases at the depth of the partial
349         ! step and store it in  zri, zrj for each  case
350         CALL eos( zti, zhi, zri )
351         CALL eos( ztj, zhj, zrj )
352
353         DO jj = 1, jpjm1                 ! Gradient of density at the last level
354            DO ji = 1, jpim1
355               iku = mbku(ji,jj)
356               ikv = mbkv(ji,jj)
357               ze3wu = gdept_n(ji+1,jj,iku) - gdept_n(ji,jj,iku)
358               ze3wv = gdept_n(ji,jj+1,ikv) - gdept_n(ji,jj,ikv)
359
360               IF( ze3wu >= 0._wp ) THEN   ;   pgru(ji,jj) = ssumask(ji,jj) * ( zri(ji  ,jj    ) - prd(ji,jj,iku) )   ! i: 1
361               ELSE                        ;   pgru(ji,jj) = ssumask(ji,jj) * ( prd(ji+1,jj,iku) - zri(ji,jj    ) )   ! i: 2
362               ENDIF
363               IF( ze3wv >= 0._wp ) THEN   ;   pgrv(ji,jj) = ssvmask(ji,jj) * ( zrj(ji,jj      ) - prd(ji,jj,ikv) )   ! j: 1
364               ELSE                        ;   pgrv(ji,jj) = ssvmask(ji,jj) * ( prd(ji,jj+1,ikv) - zrj(ji,jj    ) )   ! j: 2
365               ENDIF
366
367            END DO
368         END DO
369
370         CALL lbc_lnk( pgru , 'U', -1. )   ;   CALL lbc_lnk( pgrv , 'V', -1. )   ! Lateral boundary conditions
371         !
372      END IF
373      !
374      !     !==  (ISH)  compute grui and gruvi  ==!
375      !
376      DO jn = 1, kjpt      !==   Interpolation of tracers at the last ocean level   ==!            !
377         DO jj = 1, jpjm1
378            DO ji = 1, jpim1
379               iku = miku(ji,jj); ikup1 = miku(ji,jj) + 1
380               ikv = mikv(ji,jj); ikvp1 = mikv(ji,jj) + 1
381               !
382               ! (ISF) case partial step top and bottom in adjacent cell in vertical
383               ! cannot used e3w because if 2 cell water column, we have ps at top and bottom
384               ! in this case e3w(i,j) - e3w(i,j+1) is not the distance between Tj~ and Tj
385               ! the only common depth between cells (i,j) and (i,j+1) is gdepw_0
386               ze3wu  =  gdept_n(ji,jj,iku) - gdept_n(ji+1,jj,iku)
387               ze3wv  =  gdept_n(ji,jj,ikv) - gdept_n(ji,jj+1,ikv) 
388
389               ! i- direction
390               IF( ze3wu >= 0._wp ) THEN      ! case 1
391                  zmaxu = ze3wu / e3w_n(ji+1,jj,ikup1)
392                  ! interpolated values of tracers
393                  zti(ji,jj,jn) = pta(ji+1,jj,iku,jn) + zmaxu * ( pta(ji+1,jj,ikup1,jn) - pta(ji+1,jj,iku,jn) )
394                  ! gradient of tracers
395                  pgtui(ji,jj,jn) = ssumask(ji,jj) * ( zti(ji,jj,jn) - pta(ji,jj,iku,jn) )
396               ELSE                           ! case 2
397                  zmaxu = - ze3wu / e3w_n(ji,jj,ikup1)
398                  ! interpolated values of tracers
399                  zti(ji,jj,jn) = pta(ji,jj,iku,jn) + zmaxu * ( pta(ji,jj,ikup1,jn) - pta(ji,jj,iku,jn) )
400                  ! gradient of  tracers
401                  pgtui(ji,jj,jn) = ssumask(ji,jj) * ( pta(ji+1,jj,iku,jn) - zti(ji,jj,jn) )
402               ENDIF
403               !
404               ! j- direction
405               IF( ze3wv >= 0._wp ) THEN      ! case 1
406                  zmaxv =  ze3wv / e3w_n(ji,jj+1,ikvp1)
407                  ! interpolated values of tracers
408                  ztj(ji,jj,jn) = pta(ji,jj+1,ikv,jn) + zmaxv * ( pta(ji,jj+1,ikvp1,jn) - pta(ji,jj+1,ikv,jn) )
409                  ! gradient of tracers
410                  pgtvi(ji,jj,jn) = ssvmask(ji,jj) * ( ztj(ji,jj,jn) - pta(ji,jj,ikv,jn) )
411               ELSE                           ! case 2
412                  zmaxv =  - ze3wv / e3w_n(ji,jj,ikvp1)
413                  ! interpolated values of tracers
414                  ztj(ji,jj,jn) = pta(ji,jj,ikv,jn) + zmaxv * ( pta(ji,jj,ikvp1,jn) - pta(ji,jj,ikv,jn) )
415                  ! gradient of tracers
416                  pgtvi(ji,jj,jn) = ssvmask(ji,jj) * ( pta(ji,jj+1,ikv,jn) - ztj(ji,jj,jn) )
417               ENDIF
418
419            END DO
420         END DO
421         CALL lbc_lnk( pgtui(:,:,jn), 'U', -1. ); CALL lbc_lnk( pgtvi(:,:,jn), 'V', -1. )   ! Lateral boundary cond.
422         !
423      END DO
424
425      IF( PRESENT( prd ) ) THEN    !==  horizontal derivative of density anomalies (rd)  ==!    (optional part)
426         !
427         pgrui(:,:)  =0.0_wp; pgrvi(:,:)  =0.0_wp;
428         DO jj = 1, jpjm1
429            DO ji = 1, jpim1
430
431               iku = miku(ji,jj)
432               ikv = mikv(ji,jj)
433               ze3wu  =  gdept_n(ji,jj,iku) - gdept_n(ji+1,jj,iku)
434               ze3wv  =  gdept_n(ji,jj,ikv) - gdept_n(ji,jj+1,ikv) 
435               !
436               IF( ze3wu >= 0._wp ) THEN   ;   zhi(ji,jj) = gdept_n(ji  ,jj,iku)    ! i-direction: case 1
437               ELSE                        ;   zhi(ji,jj) = gdept_n(ji+1,jj,iku)    ! -     -      case 2
438               ENDIF
439
440               IF( ze3wv >= 0._wp ) THEN   ;   zhj(ji,jj) = gdept_n(ji,jj  ,ikv)    ! j-direction: case 1
441               ELSE                        ;   zhj(ji,jj) = gdept_n(ji,jj+1,ikv)    ! -     -      case 2
442               ENDIF
443
444            END DO
445         END DO
446         !
447         CALL eos( zti, zhi, zri )        ! interpolated density from zti, ztj
448         CALL eos( ztj, zhj, zrj )        ! at the partial step depth output in  zri, zrj
449         !
450         DO jj = 1, jpjm1                 ! Gradient of density at the last level
451            DO ji = 1, jpim1
452               iku = miku(ji,jj) 
453               ikv = mikv(ji,jj) 
454               ze3wu  =  gdept_n(ji,jj,iku) - gdept_n(ji+1,jj,iku)
455               ze3wv  =  gdept_n(ji,jj,ikv) - gdept_n(ji,jj+1,ikv) 
456
457               IF( ze3wu >= 0._wp ) THEN ; pgrui(ji,jj) = ssumask(ji,jj) * ( zri(ji  ,jj      ) - prd(ji,jj,iku) ) ! i: 1
458               ELSE                      ; pgrui(ji,jj) = ssumask(ji,jj) * ( prd(ji+1,jj  ,iku) - zri(ji,jj    ) ) ! i: 2
459               ENDIF
460               IF( ze3wv >= 0._wp ) THEN ; pgrvi(ji,jj) = ssvmask(ji,jj) * ( zrj(ji  ,jj      ) - prd(ji,jj,ikv) ) ! j: 1
461               ELSE                      ; pgrvi(ji,jj) = ssvmask(ji,jj) * ( prd(ji  ,jj+1,ikv) - zrj(ji,jj    ) ) ! j: 2
462               ENDIF
463
464            END DO
465         END DO
466         CALL lbc_lnk( pgrui   , 'U', -1. ); CALL lbc_lnk( pgrvi   , 'V', -1. )   ! Lateral boundary conditions
467         !
468      END IF 
469      !
470      IF( nn_timing == 1 )   CALL timing_stop( 'zps_hde_isf')
471      !
472   END SUBROUTINE zps_hde_isf
473   !!======================================================================
474END MODULE zpshde
Note: See TracBrowser for help on using the repository browser.