| 1 | MODULE p4zche |
|---|
| 2 | !!====================================================================== |
|---|
| 3 | !! *** MODULE p4zche *** |
|---|
| 4 | !! TOP : PISCES Sea water chemistry computed following OCMIP protocol |
|---|
| 5 | !!====================================================================== |
|---|
| 6 | !! History : OPA ! 1988 (E. Maier-Reimer) Original code |
|---|
| 7 | !! - ! 1998 (O. Aumont) addition |
|---|
| 8 | !! - ! 1999 (C. Le Quere) modification |
|---|
| 9 | !! NEMO 1.0 ! 2004 (O. Aumont) modification |
|---|
| 10 | !! - ! 2006 (R. Gangsto) modification |
|---|
| 11 | !! 2.0 ! 2007-12 (C. Ethe, G. Madec) F90 |
|---|
| 12 | !! ! 2011-02 (J. Simeon, J.Orr ) update O2 solubility constants |
|---|
| 13 | !!---------------------------------------------------------------------- |
|---|
| 14 | #if defined key_pisces |
|---|
| 15 | !!---------------------------------------------------------------------- |
|---|
| 16 | !! 'key_pisces' PISCES bio-model |
|---|
| 17 | !!---------------------------------------------------------------------- |
|---|
| 18 | !! p4z_che : Sea water chemistry computed following OCMIP protocol |
|---|
| 19 | !!---------------------------------------------------------------------- |
|---|
| 20 | USE oce_trc ! shared variables between ocean and passive tracers |
|---|
| 21 | USE trc ! passive tracers common variables |
|---|
| 22 | USE sms_pisces ! PISCES Source Minus Sink variables |
|---|
| 23 | USE lib_mpp ! MPP library |
|---|
| 24 | |
|---|
| 25 | IMPLICIT NONE |
|---|
| 26 | PRIVATE |
|---|
| 27 | |
|---|
| 28 | PUBLIC p4z_che ! |
|---|
| 29 | PUBLIC p4z_che_alloc ! |
|---|
| 30 | |
|---|
| 31 | REAL(wp), PUBLIC, ALLOCATABLE, SAVE, DIMENSION(:,:,:) :: sio3eq ! chemistry of Si |
|---|
| 32 | REAL(wp), PUBLIC, ALLOCATABLE, SAVE, DIMENSION(:,:,:) :: fekeq ! chemistry of Fe |
|---|
| 33 | REAL(wp), PUBLIC, ALLOCATABLE, SAVE, DIMENSION(:,:) :: chemc ! Solubilities of O2 and CO2 |
|---|
| 34 | REAL(wp), PUBLIC, ALLOCATABLE, SAVE, DIMENSION(:,:,:) :: chemo2 ! Solubilities of O2 and CO2 |
|---|
| 35 | |
|---|
| 36 | REAL(wp), PUBLIC :: atcox = 0.20946 ! units atm |
|---|
| 37 | |
|---|
| 38 | REAL(wp) :: salchl = 1. / 1.80655 ! conversion factor for salinity --> chlorinity (Wooster et al. 1969) |
|---|
| 39 | REAL(wp) :: o2atm = 1. / ( 1000. * 0.20946 ) |
|---|
| 40 | |
|---|
| 41 | REAL(wp) :: akcc1 = -171.9065 ! coeff. for apparent solubility equilibrium |
|---|
| 42 | REAL(wp) :: akcc2 = -0.077993 ! Millero et al. 1995 from Mucci 1983 |
|---|
| 43 | REAL(wp) :: akcc3 = 2839.319 |
|---|
| 44 | REAL(wp) :: akcc4 = 71.595 |
|---|
| 45 | REAL(wp) :: akcc5 = -0.77712 |
|---|
| 46 | REAL(wp) :: akcc6 = 0.00284263 |
|---|
| 47 | REAL(wp) :: akcc7 = 178.34 |
|---|
| 48 | REAL(wp) :: akcc8 = -0.07711 |
|---|
| 49 | REAL(wp) :: akcc9 = 0.0041249 |
|---|
| 50 | |
|---|
| 51 | REAL(wp) :: rgas = 83.143 ! universal gas constants |
|---|
| 52 | REAL(wp) :: oxyco = 1. / 22.4144 ! converts from liters of an ideal gas to moles |
|---|
| 53 | |
|---|
| 54 | REAL(wp) :: bor1 = 0.00023 ! borat constants |
|---|
| 55 | REAL(wp) :: bor2 = 1. / 10.82 |
|---|
| 56 | |
|---|
| 57 | REAL(wp) :: ca0 = -162.8301 ! WEISS & PRICE 1980, units mol/(kg atm) |
|---|
| 58 | REAL(wp) :: ca1 = 218.2968 |
|---|
| 59 | REAL(wp) :: ca2 = 90.9241 |
|---|
| 60 | REAL(wp) :: ca3 = -1.47696 |
|---|
| 61 | REAL(wp) :: ca4 = 0.025695 |
|---|
| 62 | REAL(wp) :: ca5 = -0.025225 |
|---|
| 63 | REAL(wp) :: ca6 = 0.0049867 |
|---|
| 64 | |
|---|
| 65 | REAL(wp) :: c10 = -3670.7 ! Coeff. for 1. dissoc. of carbonic acid (Edmond and Gieskes, 1970) |
|---|
| 66 | REAL(wp) :: c11 = 62.008 |
|---|
| 67 | REAL(wp) :: c12 = -9.7944 |
|---|
| 68 | REAL(wp) :: c13 = 0.0118 |
|---|
| 69 | REAL(wp) :: c14 = -0.000116 |
|---|
| 70 | |
|---|
| 71 | REAL(wp) :: c20 = -1394.7 ! coeff. for 2. dissoc. of carbonic acid (Millero, 1995) |
|---|
| 72 | REAL(wp) :: c21 = -4.777 |
|---|
| 73 | REAL(wp) :: c22 = 0.0184 |
|---|
| 74 | REAL(wp) :: c23 = -0.000118 |
|---|
| 75 | |
|---|
| 76 | REAL(wp) :: st1 = 0.14 ! constants for calculate concentrations for sulfate |
|---|
| 77 | REAL(wp) :: st2 = 1./96.062 ! (Morris & Riley 1966) |
|---|
| 78 | |
|---|
| 79 | REAL(wp) :: ft1 = 0.000067 ! constants for calculate concentrations for fluorides |
|---|
| 80 | REAL(wp) :: ft2 = 1./18.9984 ! (Dickson & Riley 1979 ) |
|---|
| 81 | |
|---|
| 82 | ! ! volumetric solubility constants for o2 in ml/L |
|---|
| 83 | REAL(wp) :: ox0 = 2.00856 ! from Table 1 for Eq 8 of Garcia and Gordon, 1992. |
|---|
| 84 | REAL(wp) :: ox1 = 3.22400 ! corrects for moisture and fugacity, but not total atmospheric pressure |
|---|
| 85 | REAL(wp) :: ox2 = 3.99063 ! Original PISCES code noted this was a solubility, but |
|---|
| 86 | REAL(wp) :: ox3 = 4.80299 ! was in fact a bunsen coefficient with units L-O2/(Lsw atm-O2) |
|---|
| 87 | REAL(wp) :: ox4 = 9.78188e-1 ! Hence, need to divide EXP( zoxy ) by 1000, ml-O2 => L-O2 |
|---|
| 88 | REAL(wp) :: ox5 = 1.71069 ! and atcox = 0.20946 to add the 1/atm dimension. |
|---|
| 89 | REAL(wp) :: ox6 = -6.24097e-3 |
|---|
| 90 | REAL(wp) :: ox7 = -6.93498e-3 |
|---|
| 91 | REAL(wp) :: ox8 = -6.90358e-3 |
|---|
| 92 | REAL(wp) :: ox9 = -4.29155e-3 |
|---|
| 93 | REAL(wp) :: ox10 = -3.11680e-7 |
|---|
| 94 | |
|---|
| 95 | ! ! coeff. for seawater pressure correction : millero 95 |
|---|
| 96 | ! ! AGRIF doesn't like the DATA instruction |
|---|
| 97 | REAL(wp) :: devk11 = -25.5 |
|---|
| 98 | REAL(wp) :: devk12 = -15.82 |
|---|
| 99 | REAL(wp) :: devk13 = -29.48 |
|---|
| 100 | REAL(wp) :: devk14 = -25.60 |
|---|
| 101 | REAL(wp) :: devk15 = -48.76 |
|---|
| 102 | ! |
|---|
| 103 | REAL(wp) :: devk21 = 0.1271 |
|---|
| 104 | REAL(wp) :: devk22 = -0.0219 |
|---|
| 105 | REAL(wp) :: devk23 = 0.1622 |
|---|
| 106 | REAL(wp) :: devk24 = 0.2324 |
|---|
| 107 | REAL(wp) :: devk25 = 0.5304 |
|---|
| 108 | ! |
|---|
| 109 | REAL(wp) :: devk31 = 0. |
|---|
| 110 | REAL(wp) :: devk32 = 0. |
|---|
| 111 | REAL(wp) :: devk33 = 2.608E-3 |
|---|
| 112 | REAL(wp) :: devk34 = -3.6246E-3 |
|---|
| 113 | REAL(wp) :: devk35 = 0. |
|---|
| 114 | ! |
|---|
| 115 | REAL(wp) :: devk41 = -3.08E-3 |
|---|
| 116 | REAL(wp) :: devk42 = 1.13E-3 |
|---|
| 117 | REAL(wp) :: devk43 = -2.84E-3 |
|---|
| 118 | REAL(wp) :: devk44 = -5.13E-3 |
|---|
| 119 | REAL(wp) :: devk45 = -11.76E-3 |
|---|
| 120 | ! |
|---|
| 121 | REAL(wp) :: devk51 = 0.0877E-3 |
|---|
| 122 | REAL(wp) :: devk52 = -0.1475E-3 |
|---|
| 123 | REAL(wp) :: devk53 = 0. |
|---|
| 124 | REAL(wp) :: devk54 = 0.0794E-3 |
|---|
| 125 | REAL(wp) :: devk55 = 0.3692E-3 |
|---|
| 126 | |
|---|
| 127 | !!---------------------------------------------------------------------- |
|---|
| 128 | !! NEMO/TOP 3.3 , NEMO Consortium (2010) |
|---|
| 129 | !! $Id$ |
|---|
| 130 | !! Software governed by the CeCILL licence (NEMOGCM/NEMO_CeCILL.txt) |
|---|
| 131 | !!---------------------------------------------------------------------- |
|---|
| 132 | CONTAINS |
|---|
| 133 | |
|---|
| 134 | SUBROUTINE p4z_che |
|---|
| 135 | !!--------------------------------------------------------------------- |
|---|
| 136 | !! *** ROUTINE p4z_che *** |
|---|
| 137 | !! |
|---|
| 138 | !! ** Purpose : Sea water chemistry computed following OCMIP protocol |
|---|
| 139 | !! |
|---|
| 140 | !! ** Method : - ... |
|---|
| 141 | !!--------------------------------------------------------------------- |
|---|
| 142 | INTEGER :: ji, jj, jk |
|---|
| 143 | REAL(wp) :: ztkel, zt , zt2 , zsal , zsal2 , zbuf1 , zbuf2 |
|---|
| 144 | REAL(wp) :: ztgg , ztgg2, ztgg3 , ztgg4 , ztgg5 |
|---|
| 145 | REAL(wp) :: zpres, ztc , zcl , zcpexp, zoxy , zcpexp2 |
|---|
| 146 | REAL(wp) :: zsqrt, ztr , zlogt , zcek1 |
|---|
| 147 | REAL(wp) :: zis , zis2 , zsal15, zisqrt |
|---|
| 148 | REAL(wp) :: zckb , zck1 , zck2 , zckw , zak1 , zak2 , zakb , zaksp0, zakw |
|---|
| 149 | REAL(wp) :: zst , zft , zcks , zckf , zaksp1 |
|---|
| 150 | !!--------------------------------------------------------------------- |
|---|
| 151 | ! |
|---|
| 152 | IF( nn_timing == 1 ) CALL timing_start('p4z_che') |
|---|
| 153 | ! |
|---|
| 154 | ! CHEMICAL CONSTANTS - SURFACE LAYER |
|---|
| 155 | ! ---------------------------------- |
|---|
| 156 | !$OMP PARALLEL |
|---|
| 157 | !$OMP DO schedule(static) private(jj,ji,ztkel,zt,zt2,zsal,zsal2,zlogt,zcek1) |
|---|
| 158 | DO jj = 1, jpj |
|---|
| 159 | DO ji = 1, jpi |
|---|
| 160 | ! ! SET ABSOLUTE TEMPERATURE |
|---|
| 161 | ztkel = tsn(ji,jj,1,jp_tem) + 273.15 |
|---|
| 162 | zt = ztkel * 0.01 |
|---|
| 163 | zt2 = zt * zt |
|---|
| 164 | zsal = tsn(ji,jj,1,jp_sal) + ( 1.- tmask(ji,jj,1) ) * 35. |
|---|
| 165 | zsal2 = zsal * zsal |
|---|
| 166 | zlogt = LOG( zt ) |
|---|
| 167 | ! ! LN(K0) OF SOLUBILITY OF CO2 (EQ. 12, WEISS, 1980) |
|---|
| 168 | ! ! AND FOR THE ATMOSPHERE FOR NON IDEAL GAS |
|---|
| 169 | zcek1 = ca0 + ca1 / zt + ca2 * zlogt + ca3 * zt2 + zsal * ( ca4 + ca5 * zt + ca6 * zt2 ) |
|---|
| 170 | ! ! SET SOLUBILITIES OF O2 AND CO2 |
|---|
| 171 | chemc(ji,jj) = EXP( zcek1 ) * 1.e-6 * rhop(ji,jj,1) / 1000. ! mol/(L uatm) |
|---|
| 172 | ! |
|---|
| 173 | END DO |
|---|
| 174 | END DO |
|---|
| 175 | |
|---|
| 176 | ! OXYGEN SOLUBILITY - DEEP OCEAN |
|---|
| 177 | ! ------------------------------- |
|---|
| 178 | !$OMP DO schedule(static) private(jk,jj,ji,ztkel,zsal,zsal2,ztgg,ztgg2,ztgg3,ztgg4,ztgg5,zoxy) |
|---|
| 179 | DO jk = 1, jpk |
|---|
| 180 | DO jj = 1, jpj |
|---|
| 181 | DO ji = 1, jpi |
|---|
| 182 | ztkel = tsn(ji,jj,jk,jp_tem) + 273.15 |
|---|
| 183 | zsal = tsn(ji,jj,jk,jp_sal) + ( 1.- tmask(ji,jj,jk) ) * 35. |
|---|
| 184 | zsal2 = zsal * zsal |
|---|
| 185 | ztgg = LOG( ( 298.15 - tsn(ji,jj,jk,jp_tem) ) / ztkel ) ! Set the GORDON & GARCIA scaled temperature |
|---|
| 186 | ztgg2 = ztgg * ztgg |
|---|
| 187 | ztgg3 = ztgg2 * ztgg |
|---|
| 188 | ztgg4 = ztgg3 * ztgg |
|---|
| 189 | ztgg5 = ztgg4 * ztgg |
|---|
| 190 | zoxy = ox0 + ox1 * ztgg + ox2 * ztgg2 + ox3 * ztgg3 + ox4 * ztgg4 + ox5 * ztgg5 & |
|---|
| 191 | + zsal * ( ox6 + ox7 * ztgg + ox8 * ztgg2 + ox9 * ztgg3 ) + ox10 * zsal2 |
|---|
| 192 | chemo2(ji,jj,jk) = ( EXP( zoxy ) * o2atm ) * oxyco * atcox ! mol/(L atm) |
|---|
| 193 | END DO |
|---|
| 194 | END DO |
|---|
| 195 | END DO |
|---|
| 196 | |
|---|
| 197 | |
|---|
| 198 | |
|---|
| 199 | ! CHEMICAL CONSTANTS - DEEP OCEAN |
|---|
| 200 | ! ------------------------------- |
|---|
| 201 | !$OMP DO schedule(static) private(jk,jj,ji,zpres,ztkel,zsal,zsqrt,zsal15,zlogt,ztr,zis,zis2,zisqrt,ztc,zcl,zst,zft,zcks,zckf,zckb,zck1,zck2,zckw,zaksp0,zak1,zak2,zakb,zakw,zaksp1,zcpexp,zcpexp2,zbuf1,zbuf2) |
|---|
| 202 | DO jk = 1, jpk |
|---|
| 203 | DO jj = 1, jpj |
|---|
| 204 | DO ji = 1, jpi |
|---|
| 205 | |
|---|
| 206 | ! SET PRESSION |
|---|
| 207 | zpres = 1.025e-1 * gdept_n(ji,jj,jk) |
|---|
| 208 | |
|---|
| 209 | ! SET ABSOLUTE TEMPERATURE |
|---|
| 210 | ztkel = tsn(ji,jj,jk,jp_tem) + 273.15 |
|---|
| 211 | zsal = tsn(ji,jj,jk,jp_sal) + ( 1.-tmask(ji,jj,jk) ) * 35. |
|---|
| 212 | zsqrt = SQRT( zsal ) |
|---|
| 213 | zsal15 = zsqrt * zsal |
|---|
| 214 | zlogt = LOG( ztkel ) |
|---|
| 215 | ztr = 1. / ztkel |
|---|
| 216 | zis = 19.924 * zsal / ( 1000.- 1.005 * zsal ) |
|---|
| 217 | zis2 = zis * zis |
|---|
| 218 | zisqrt = SQRT( zis ) |
|---|
| 219 | ztc = tsn(ji,jj,jk,jp_tem) + ( 1.- tmask(ji,jj,jk) ) * 20. |
|---|
| 220 | |
|---|
| 221 | ! CHLORINITY (WOOSTER ET AL., 1969) |
|---|
| 222 | zcl = zsal * salchl |
|---|
| 223 | |
|---|
| 224 | ! TOTAL SULFATE CONCENTR. [MOLES/kg soln] |
|---|
| 225 | zst = st1 * zcl * st2 |
|---|
| 226 | |
|---|
| 227 | ! TOTAL FLUORIDE CONCENTR. [MOLES/kg soln] |
|---|
| 228 | zft = ft1 * zcl * ft2 |
|---|
| 229 | |
|---|
| 230 | ! DISSOCIATION CONSTANT FOR SULFATES on free H scale (Dickson 1990) |
|---|
| 231 | zcks = EXP(-4276.1 * ztr + 141.328 - 23.093 * zlogt & |
|---|
| 232 | & + (-13856. * ztr + 324.57 - 47.986 * zlogt) * zisqrt & |
|---|
| 233 | & + (35474. * ztr - 771.54 + 114.723 * zlogt) * zis & |
|---|
| 234 | & - 2698. * ztr * zis**1.5 + 1776.* ztr * zis2 & |
|---|
| 235 | & + LOG(1.0 - 0.001005 * zsal)) |
|---|
| 236 | ! |
|---|
| 237 | aphscale(ji,jj,jk) = ( 1. + zst / zcks ) |
|---|
| 238 | |
|---|
| 239 | ! DISSOCIATION CONSTANT FOR FLUORIDES on free H scale (Dickson and Riley 79) |
|---|
| 240 | zckf = EXP( 1590.2*ztr - 12.641 + 1.525*zisqrt & |
|---|
| 241 | & + LOG(1.0d0 - 0.001005d0*zsal) & |
|---|
| 242 | & + LOG(1.0d0 + zst/zcks)) |
|---|
| 243 | |
|---|
| 244 | ! DISSOCIATION CONSTANT FOR CARBONATE AND BORATE |
|---|
| 245 | zckb= (-8966.90 - 2890.53*zsqrt - 77.942*zsal & |
|---|
| 246 | & + 1.728*zsal15 - 0.0996*zsal*zsal)*ztr & |
|---|
| 247 | & + (148.0248 + 137.1942*zsqrt + 1.62142*zsal) & |
|---|
| 248 | & + (-24.4344 - 25.085*zsqrt - 0.2474*zsal) & |
|---|
| 249 | & * zlogt + 0.053105*zsqrt*ztkel |
|---|
| 250 | |
|---|
| 251 | |
|---|
| 252 | zck1 = c10 * ztr + c11 + c12 * zlogt + c13 * zsal + c14 * zsal * zsal |
|---|
| 253 | zck2 = c20 * ztr + c21 + c22 * zsal + c23 * zsal**2 |
|---|
| 254 | |
|---|
| 255 | ! PKW (H2O) (DICKSON AND RILEY, 1979) |
|---|
| 256 | zckw = -13847.26*ztr + 148.9652 - 23.6521 * zlogt & |
|---|
| 257 | & + (118.67*ztr - 5.977 + 1.0495 * zlogt) & |
|---|
| 258 | & * zsqrt - 0.01615 * zsal |
|---|
| 259 | |
|---|
| 260 | ! APPARENT SOLUBILITY PRODUCT K'SP OF CALCITE IN SEAWATER |
|---|
| 261 | ! (S=27-43, T=2-25 DEG C) at pres =0 (atmos. pressure) (MUCCI 1983) |
|---|
| 262 | zaksp0 = akcc1 + akcc2 * ztkel + akcc3 * ztr + akcc4 * LOG10( ztkel ) & |
|---|
| 263 | & + ( akcc5 + akcc6 * ztkel + akcc7 * ztr ) * zsqrt + akcc8 * zsal + akcc9 * zsal15 |
|---|
| 264 | |
|---|
| 265 | ! K1, K2 OF CARBONIC ACID, KB OF BORIC ACID, KW (H2O) (LIT.?) |
|---|
| 266 | zak1 = 10**(zck1) |
|---|
| 267 | zak2 = 10**(zck2) |
|---|
| 268 | zakb = EXP( zckb ) |
|---|
| 269 | zakw = EXP( zckw ) |
|---|
| 270 | zaksp1 = 10**(zaksp0) |
|---|
| 271 | |
|---|
| 272 | ! FORMULA FOR CPEXP AFTER EDMOND & GIESKES (1970) |
|---|
| 273 | ! (REFERENCE TO CULBERSON & PYTKOQICZ (1968) AS MADE |
|---|
| 274 | ! IN BROECKER ET AL. (1982) IS INCORRECT; HERE RGAS IS |
|---|
| 275 | ! TAKEN TENFOLD TO CORRECT FOR THE NOTATION OF pres IN |
|---|
| 276 | ! DBAR INSTEAD OF BAR AND THE EXPRESSION FOR CPEXP IS |
|---|
| 277 | ! MULTIPLIED BY LN(10.) TO ALLOW USE OF EXP-FUNCTION |
|---|
| 278 | ! WITH BASIS E IN THE FORMULA FOR AKSPP (CF. EDMOND |
|---|
| 279 | ! & GIESKES (1970), P. 1285-1286 (THE SMALL |
|---|
| 280 | ! FORMULA ON P. 1286 IS RIGHT AND CONSISTENT WITH THE |
|---|
| 281 | ! SIGN IN PARTIAL MOLAR VOLUME CHANGE AS SHOWN ON P. 1285)) |
|---|
| 282 | zcpexp = zpres /(rgas*ztkel) |
|---|
| 283 | zcpexp2 = zpres * zpres/(rgas*ztkel) |
|---|
| 284 | |
|---|
| 285 | ! KB OF BORIC ACID, K1,K2 OF CARBONIC ACID PRESSURE |
|---|
| 286 | ! CORRECTION AFTER CULBERSON AND PYTKOWICZ (1968) |
|---|
| 287 | ! (CF. BROECKER ET AL., 1982) |
|---|
| 288 | |
|---|
| 289 | zbuf1 = - ( devk11 + devk21 * ztc + devk31 * ztc * ztc ) |
|---|
| 290 | zbuf2 = 0.5 * ( devk41 + devk51 * ztc ) |
|---|
| 291 | ak13(ji,jj,jk) = zak1 * EXP( zbuf1 * zcpexp + zbuf2 * zcpexp2 ) |
|---|
| 292 | |
|---|
| 293 | zbuf1 = - ( devk12 + devk22 * ztc + devk32 * ztc * ztc ) |
|---|
| 294 | zbuf2 = 0.5 * ( devk42 + devk52 * ztc ) |
|---|
| 295 | ak23(ji,jj,jk) = zak2 * EXP( zbuf1 * zcpexp + zbuf2 * zcpexp2 ) |
|---|
| 296 | |
|---|
| 297 | zbuf1 = - ( devk13 + devk23 * ztc + devk33 * ztc * ztc ) |
|---|
| 298 | zbuf2 = 0.5 * ( devk43 + devk53 * ztc ) |
|---|
| 299 | akb3(ji,jj,jk) = zakb * EXP( zbuf1 * zcpexp + zbuf2 * zcpexp2 ) |
|---|
| 300 | |
|---|
| 301 | zbuf1 = - ( devk14 + devk24 * ztc + devk34 * ztc * ztc ) |
|---|
| 302 | zbuf2 = 0.5 * ( devk44 + devk54 * ztc ) |
|---|
| 303 | akw3(ji,jj,jk) = zakw * EXP( zbuf1 * zcpexp + zbuf2 * zcpexp2 ) |
|---|
| 304 | |
|---|
| 305 | |
|---|
| 306 | ! APPARENT SOLUBILITY PRODUCT K'SP OF CALCITE |
|---|
| 307 | ! AS FUNCTION OF PRESSURE FOLLOWING MILLERO |
|---|
| 308 | ! (P. 1285) AND BERNER (1976) |
|---|
| 309 | zbuf1 = - ( devk15 + devk25 * ztc + devk35 * ztc * ztc ) |
|---|
| 310 | zbuf2 = 0.5 * ( devk45 + devk55 * ztc ) |
|---|
| 311 | aksp(ji,jj,jk) = zaksp1 * EXP( zbuf1 * zcpexp + zbuf2 * zcpexp2 ) |
|---|
| 312 | |
|---|
| 313 | ! TOTAL BORATE CONCENTR. [MOLES/L] |
|---|
| 314 | borat(ji,jj,jk) = bor1 * zcl * bor2 |
|---|
| 315 | |
|---|
| 316 | ! Iron and SIO3 saturation concentration from ... |
|---|
| 317 | sio3eq(ji,jj,jk) = EXP( LOG( 10.) * ( 6.44 - 968. / ztkel ) ) * 1.e-6 |
|---|
| 318 | fekeq (ji,jj,jk) = 10**( 17.27 - 1565.7 / ( 273.15 + ztc ) ) |
|---|
| 319 | |
|---|
| 320 | END DO |
|---|
| 321 | END DO |
|---|
| 322 | END DO |
|---|
| 323 | !$OMP END DO NOWAIT |
|---|
| 324 | !$OMP END PARALLEL |
|---|
| 325 | ! |
|---|
| 326 | IF( nn_timing == 1 ) CALL timing_stop('p4z_che') |
|---|
| 327 | ! |
|---|
| 328 | END SUBROUTINE p4z_che |
|---|
| 329 | |
|---|
| 330 | |
|---|
| 331 | INTEGER FUNCTION p4z_che_alloc() |
|---|
| 332 | !!---------------------------------------------------------------------- |
|---|
| 333 | !! *** ROUTINE p4z_che_alloc *** |
|---|
| 334 | !!---------------------------------------------------------------------- |
|---|
| 335 | ALLOCATE( sio3eq(jpi,jpj,jpk), fekeq(jpi,jpj,jpk), chemc(jpi,jpj), chemo2(jpi,jpj,jpk), & |
|---|
| 336 | & STAT=p4z_che_alloc ) |
|---|
| 337 | ! |
|---|
| 338 | IF( p4z_che_alloc /= 0 ) CALL ctl_warn('p4z_che_alloc : failed to allocate arrays.') |
|---|
| 339 | ! |
|---|
| 340 | END FUNCTION p4z_che_alloc |
|---|
| 341 | |
|---|
| 342 | #else |
|---|
| 343 | !!====================================================================== |
|---|
| 344 | !! Dummy module : No PISCES bio-model |
|---|
| 345 | !!====================================================================== |
|---|
| 346 | CONTAINS |
|---|
| 347 | SUBROUTINE p4z_che( kt ) ! Empty routine |
|---|
| 348 | INTEGER, INTENT(in) :: kt |
|---|
| 349 | WRITE(*,*) 'p4z_che: You should not have seen this print! error?', kt |
|---|
| 350 | END SUBROUTINE p4z_che |
|---|
| 351 | #endif |
|---|
| 352 | |
|---|
| 353 | !!====================================================================== |
|---|
| 354 | END MODULE p4zche |
|---|
