New URL for NEMO forge!   http://forge.nemo-ocean.eu

Since March 2022 along with NEMO 4.2 release, the code development moved to a self-hosted GitLab.
This present forge is now archived and remained online for history.
p4zlys.F90 in branches/2016/dev_r6519_HPC_4/NEMOGCM/NEMO/TOP_SRC/PISCES/P4Z – NEMO

source: branches/2016/dev_r6519_HPC_4/NEMOGCM/NEMO/TOP_SRC/PISCES/P4Z/p4zlys.F90 @ 7037

Last change on this file since 7037 was 7037, checked in by mocavero, 8 years ago

ORCA2_LIM_PISCES hybrid version update
File size: 10.7 KB
Line 
1MODULE p4zlys
2   !!======================================================================
3   !!                         ***  MODULE p4zlys  ***
4   !! TOP :   PISCES
5   !!======================================================================
6   !! History :    -   !  1988-07  (E. MAIER-REIMER) Original code
7   !!              -   !  1998     (O. Aumont) additions
8   !!              -   !  1999     (C. Le Quere) modifications
9   !!             1.0  !  2004     (O. Aumont) modifications
10   !!             2.0  !  2007-12  (C. Ethe, G. Madec)  F90
11   !!                  !  2011-02  (J. Simeon, J. Orr)  Calcon salinity dependence
12   !!             3.4  !  2011-06  (O. Aumont, C. Ethe) Improvment of calcite dissolution
13   !!----------------------------------------------------------------------
14#if defined key_pisces
15   !!----------------------------------------------------------------------
16   !!   'key_pisces'                                       PISCES bio-model
17   !!----------------------------------------------------------------------
18   !!   p4z_lys        :   Compute the CaCO3 dissolution
19   !!   p4z_lys_init   :   Read the namelist parameters
20   !!----------------------------------------------------------------------
21   USE oce_trc         !  shared variables between ocean and passive tracers
22   USE trc             !  passive tracers common variables
23   USE sms_pisces      !  PISCES Source Minus Sink variables
24   USE prtctl_trc      !  print control for debugging
25   USE iom             !  I/O manager
26
27   IMPLICIT NONE
28   PRIVATE
29
30   PUBLIC   p4z_lys         ! called in trcsms_pisces.F90
31   PUBLIC   p4z_lys_init    ! called in trcsms_pisces.F90
32
33   !! * Shared module variables
34   REAL(wp), PUBLIC :: kdca !: diss. rate constant calcite
35   REAL(wp), PUBLIC :: nca  !: order of reaction for calcite dissolution
36
37   !! * Module variables
38   REAL(wp) :: calcon = 1.03E-2           !: mean calcite concentration [Ca2+] in sea water [mole/kg solution]
39 
40   INTEGER  :: rmtss                      !: number of seconds per month
41
42   !!----------------------------------------------------------------------
43   !! NEMO/TOP 3.3 , NEMO Consortium (2010)
44   !! $Id: p4zlys.F90 3321 2012-03-05 17:10:55Z cetlod $
45   !! Software governed by the CeCILL licence (NEMOGCM/NEMO_CeCILL.txt)
46   !!----------------------------------------------------------------------
47
48CONTAINS
49
50   SUBROUTINE p4z_lys( kt, knt )
51      !!---------------------------------------------------------------------
52      !!                     ***  ROUTINE p4z_lys  ***
53      !!
54      !! ** Purpose :   CALCULATES DEGREE OF CACO3 SATURATION IN THE WATER
55      !!                COLUMN, DISSOLUTION/PRECIPITATION OF CACO3 AND LOSS
56      !!                OF CACO3 TO THE CACO3 SEDIMENT POOL.
57      !!
58      !! ** Method  : - ???
59      !!---------------------------------------------------------------------
60      !
61      INTEGER, INTENT(in) ::   kt, knt ! ocean time step
62      INTEGER  ::   ji, jj, jk, jn
63      REAL(wp) ::   zalk, zdic, zph, zah2
64      REAL(wp) ::   zdispot, zfact, zcalcon, zalka, zaldi
65      REAL(wp) ::   zomegaca, zexcess, zexcess0
66      CHARACTER (len=25) :: charout
67      REAL(wp), POINTER, DIMENSION(:,:,:) :: zco3, zcaldiss   
68      !!---------------------------------------------------------------------
69      !
70      IF( nn_timing == 1 )  CALL timing_start('p4z_lys')
71      !
72      CALL wrk_alloc( jpi, jpj, jpk, zco3, zcaldiss )
73      !
74
75!$OMP PARALLEL
76!$OMP WORKSHARE
77      zco3    (:,:,:) = 0.
78      zcaldiss(:,:,:) = 0.
79!$OMP END WORKSHARE
80      !     -------------------------------------------
81      !     COMPUTE [CO3--] and [H+] CONCENTRATIONS
82      !     -------------------------------------------
83     
84      DO jn = 1, 5                               !  BEGIN OF ITERATION
85         !
86!$OMP DO schedule(static) private(jk, jj, ji, zfact, zph, zdic, zalka, zalk, zaldi, zah2)
87         DO jk = 1, jpkm1
88            DO jj = 1, jpj
89               DO ji = 1, jpi
90                  zfact = rhop(ji,jj,jk) / 1000. + rtrn
91                  zph  = hi(ji,jj,jk) * tmask(ji,jj,jk) / zfact + ( 1.-tmask(ji,jj,jk) ) * 1.e-9 ! [H+]
92                  zdic  = trb(ji,jj,jk,jpdic) / zfact
93                  zalka = trb(ji,jj,jk,jptal) / zfact
94                  ! CALCULATE [ALK]([CO3--], [HCO3-])
95                  zalk  = zalka - ( akw3(ji,jj,jk) / zph - zph / ( aphscale(ji,jj,jk) + rtrn )  &
96                  &       + borat(ji,jj,jk) / ( 1. + zph / akb3(ji,jj,jk) ) )
97                  ! CALCULATE [H+] and [CO3--]
98                  zaldi = zdic - zalk
99                  zah2  = SQRT( zaldi * zaldi + 4.* ( zalk * ak23(ji,jj,jk) / ak13(ji,jj,jk) ) * ( zdic + zaldi ) )
100                  zah2  = 0.5 * ak13(ji,jj,jk) / zalk * ( zaldi + zah2 )
101                  !
102                  zco3(ji,jj,jk) = zalk / ( 2. + zah2 / ak23(ji,jj,jk) ) * zfact
103                  hi(ji,jj,jk)   = zah2 * zfact
104               END DO
105            END DO
106         END DO
107         !
108      END DO 
109
110      !     ---------------------------------------------------------
111      !        CALCULATE DEGREE OF CACO3 SATURATION AND CORRESPONDING
112      !        DISSOLOUTION AND PRECIPITATION OF CACO3 (BE AWARE OF
113      !        MGCO3)
114      !     ---------------------------------------------------------
115
116!$OMP DO schedule(static) private(jk, jj, ji, zcalcon, zfact, zomegaca, zexcess0, zexcess, zdispot)
117      DO jk = 1, jpkm1
118         DO jj = 1, jpj
119            DO ji = 1, jpi
120
121               ! DEVIATION OF [CO3--] FROM SATURATION VALUE
122               ! Salinity dependance in zomegaca and divide by rhop/1000 to have good units
123               zcalcon  = calcon * ( tsn(ji,jj,jk,jp_sal) / 35._wp )
124               zfact    = rhop(ji,jj,jk) / 1000._wp
125               zomegaca = ( zcalcon * zco3(ji,jj,jk) * zfact ) / aksp(ji,jj,jk) 
126
127               ! SET DEGREE OF UNDER-/SUPERSATURATION
128               excess(ji,jj,jk) = 1._wp - zomegaca
129               zexcess0 = MAX( 0., excess(ji,jj,jk) )
130               zexcess  = zexcess0**nca
131
132               ! AMOUNT CACO3 (12C) THAT RE-ENTERS SOLUTION
133               !       (ACCORDING TO THIS FORMULATION ALSO SOME PARTICULATE
134               !       CACO3 GETS DISSOLVED EVEN IN THE CASE OF OVERSATURATION)
135               zdispot = kdca * zexcess * trb(ji,jj,jk,jpcal)
136# if defined key_degrad
137               zdispot = zdispot * facvol(ji,jj,jk)
138# endif
139              !  CHANGE OF [CO3--] , [ALK], PARTICULATE [CACO3],
140              !       AND [SUM(CO2)] DUE TO CACO3 DISSOLUTION/PRECIPITATION
141              zcaldiss(ji,jj,jk)  = zdispot * rfact2 / rmtss ! calcite dissolution
142              zco3(ji,jj,jk)      = zco3(ji,jj,jk) + zcaldiss(ji,jj,jk)
143              !
144              tra(ji,jj,jk,jptal) = tra(ji,jj,jk,jptal) + 2. * zcaldiss(ji,jj,jk)
145              tra(ji,jj,jk,jpcal) = tra(ji,jj,jk,jpcal) -      zcaldiss(ji,jj,jk)
146              tra(ji,jj,jk,jpdic) = tra(ji,jj,jk,jpdic) +      zcaldiss(ji,jj,jk)
147            END DO
148         END DO
149      END DO
150!$OMP END DO NOWAIT
151!$OMP END PARALLEL
152      !
153
154      IF( lk_iomput .AND. knt == nrdttrc ) THEN
155         IF( iom_use( "PH"     ) ) CALL iom_put( "PH"    , -1. * LOG10( hi(:,:,:) )          * tmask(:,:,:) )
156         IF( iom_use( "CO3"    ) ) CALL iom_put( "CO3"   , zco3(:,:,:) * 1.e+3               * tmask(:,:,:) )
157         IF( iom_use( "CO3sat" ) ) CALL iom_put( "CO3sat", aksp(:,:,:) * 1.e+3 / calcon      * tmask(:,:,:) )
158         IF( iom_use( "DCAL"   ) ) CALL iom_put( "DCAL"  , zcaldiss(:,:,:) * 1.e+3 * rfact2r   * tmask(:,:,:) )
159      ELSE
160         IF( ln_diatrc ) THEN
161!$OMP PARALLEL DO schedule(static) private(jk, jj, ji)
162         DO jk = 1, jpk
163            DO jj = 1, jpj
164               DO ji = 1, jpi
165                  trc3d(ji,jj,jk,jp_pcs0_3d    ) = -1. * LOG10( hi(ji,jj,jk) ) * tmask(ji,jj,jk)
166                  trc3d(ji,jj,jk,jp_pcs0_3d + 1) = zco3(ji,jj,jk)              * tmask(ji,jj,jk)
167                  trc3d(ji,jj,jk,jp_pcs0_3d + 2) = aksp(ji,jj,jk) / calcon     * tmask(ji,jj,jk)
168               END DO
169            END DO
170         END DO
171         ENDIF
172      ENDIF
173      !
174      IF(ln_ctl)   THEN  ! print mean trends (used for debugging)
175        WRITE(charout, FMT="('lys ')")
176        CALL prt_ctl_trc_info(charout)
177        CALL prt_ctl_trc(tab4d=tra, mask=tmask, clinfo=ctrcnm)
178      ENDIF
179      !
180      CALL wrk_dealloc( jpi, jpj, jpk, zco3, zcaldiss )
181      !
182      IF( nn_timing == 1 )  CALL timing_stop('p4z_lys')
183      !
184   END SUBROUTINE p4z_lys
185
186   SUBROUTINE p4z_lys_init
187
188      !!----------------------------------------------------------------------
189      !!                  ***  ROUTINE p4z_lys_init  ***
190      !!
191      !! ** Purpose :   Initialization of CaCO3 dissolution parameters
192      !!
193      !! ** Method  :   Read the nampiscal namelist and check the parameters
194      !!      called at the first timestep (nittrc000)
195      !!
196      !! ** input   :   Namelist nampiscal
197      !!
198      !!----------------------------------------------------------------------
199      INTEGER  ::  ji, jj, jk
200      INTEGER  ::  ios                 ! Local integer output status for namelist read
201      REAL(wp) ::  zcaralk, zbicarb, zco3
202      REAL(wp) ::  ztmas, ztmas1
203
204      NAMELIST/nampiscal/ kdca, nca
205      !!----------------------------------------------------------------------
206
207      REWIND( numnatp_ref )              ! Namelist nampiscal in reference namelist : Pisces CaCO3 dissolution
208      READ  ( numnatp_ref, nampiscal, IOSTAT = ios, ERR = 901)
209901   IF( ios /= 0 ) CALL ctl_nam ( ios , 'nampiscal in reference namelist', lwp )
210
211      REWIND( numnatp_cfg )              ! Namelist nampiscal in configuration namelist : Pisces CaCO3 dissolution
212      READ  ( numnatp_cfg, nampiscal, IOSTAT = ios, ERR = 902 )
213902   IF( ios /= 0 ) CALL ctl_nam ( ios , 'nampiscal in configuration namelist', lwp )
214      IF(lwm) WRITE ( numonp, nampiscal )
215
216      IF(lwp) THEN                         ! control print
217         WRITE(numout,*) ' '
218         WRITE(numout,*) ' Namelist parameters for CaCO3 dissolution, nampiscal'
219         WRITE(numout,*) ' ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~'
220         WRITE(numout,*) '    diss. rate constant calcite (per month)   kdca      =', kdca
221         WRITE(numout,*) '    order of reaction for calcite dissolution nca       =', nca
222      ENDIF
223
224      ! Number of seconds per month
225      rmtss =  nyear_len(1) * rday / raamo
226      !
227   END SUBROUTINE p4z_lys_init
228
229#else
230   !!======================================================================
231   !!  Dummy module :                                   No PISCES bio-model
232   !!======================================================================
233CONTAINS
234   SUBROUTINE p4z_lys( kt )                   ! Empty routine
235      INTEGER, INTENT( in ) ::   kt
236      WRITE(*,*) 'p4z_lys: You should not have seen this print! error?', kt
237   END SUBROUTINE p4z_lys
238#endif 
239   !!======================================================================
240END MODULE p4zlys
Note: See TracBrowser for help on using the repository browser.