New URL for NEMO forge!   http://forge.nemo-ocean.eu

Since March 2022 along with NEMO 4.2 release, the code development moved to a self-hosted GitLab.
This present forge is now archived and remained online for history.
p4zmort.F90 in branches/2016/dev_r6519_HPC_4/NEMOGCM/NEMO/TOP_SRC/PISCES/P4Z – NEMO

source: branches/2016/dev_r6519_HPC_4/NEMOGCM/NEMO/TOP_SRC/PISCES/P4Z/p4zmort.F90 @ 7037

Last change on this file since 7037 was 7037, checked in by mocavero, 8 years ago

ORCA2_LIM_PISCES hybrid version update
  • Property svn:keywords set to Id
File size: 12.9 KB
Line 
1MODULE p4zmort
2   !!======================================================================
3   !!                         ***  MODULE p4zmort  ***
4   !! TOP :   PISCES Compute the mortality terms for phytoplankton
5   !!======================================================================
6   !! History :   1.0  !  2002     (O. Aumont)  Original code
7   !!             2.0  !  2007-12  (C. Ethe, G. Madec)  F90
8   !!----------------------------------------------------------------------
9#if defined key_pisces
10   !!----------------------------------------------------------------------
11   !!   'key_pisces'                                       PISCES bio-model
12   !!----------------------------------------------------------------------
13   !!   p4z_mort       :   Compute the mortality terms for phytoplankton
14   !!   p4z_mort_init  :   Initialize the mortality params for phytoplankton
15   !!----------------------------------------------------------------------
16   USE oce_trc         !  shared variables between ocean and passive tracers
17   USE trc             !  passive tracers common variables
18   USE sms_pisces      !  PISCES Source Minus Sink variables
19   USE p4zsink         !  vertical flux of particulate matter due to sinking
20   USE p4zprod         !  Primary productivity
21   USE prtctl_trc      !  print control for debugging
22
23   IMPLICIT NONE
24   PRIVATE
25
26   PUBLIC   p4z_mort   
27   PUBLIC   p4z_mort_init   
28
29   !! * Shared module variables
30   REAL(wp), PUBLIC :: wchl    !:
31   REAL(wp), PUBLIC :: wchld   !:
32   REAL(wp), PUBLIC :: wchldm  !:
33   REAL(wp), PUBLIC :: mprat   !:
34   REAL(wp), PUBLIC :: mprat2  !:
35
36
37   !!----------------------------------------------------------------------
38   !! NEMO/TOP 3.3 , NEMO Consortium (2010)
39   !! $Id$
40   !! Software governed by the CeCILL licence (NEMOGCM/NEMO_CeCILL.txt)
41   !!----------------------------------------------------------------------
42
43CONTAINS
44
45   SUBROUTINE p4z_mort( kt )
46      !!---------------------------------------------------------------------
47      !!                     ***  ROUTINE p4z_mort  ***
48      !!
49      !! ** Purpose :   Calls the different subroutine to initialize and compute
50      !!                the different phytoplankton mortality terms
51      !!
52      !! ** Method  : - ???
53      !!---------------------------------------------------------------------
54      INTEGER, INTENT(in) ::   kt ! ocean time step
55      !!---------------------------------------------------------------------
56
57      CALL p4z_nano            ! nanophytoplankton
58
59      CALL p4z_diat            ! diatoms
60
61   END SUBROUTINE p4z_mort
62
63
64   SUBROUTINE p4z_nano
65      !!---------------------------------------------------------------------
66      !!                     ***  ROUTINE p4z_nano  ***
67      !!
68      !! ** Purpose :   Compute the mortality terms for nanophytoplankton
69      !!
70      !! ** Method  : - ???
71      !!---------------------------------------------------------------------
72      INTEGER  :: ji, jj, jk
73      REAL(wp) :: zsizerat, zcompaph
74      REAL(wp) :: zfactfe, zfactch, zprcaca, zfracal
75      REAL(wp) :: ztortp , zrespp , zmortp , zstep
76      CHARACTER (len=25) :: charout
77      !!---------------------------------------------------------------------
78      !
79      IF( nn_timing == 1 )  CALL timing_start('p4z_nano')
80      !
81!$OMP PARALLEL
82!$OMP WORKSHARE
83      prodcal(:,:,:) = 0.  !: calcite production variable set to zero
84!$OMP END WORKSHARE
85!$OMP DO schedule(static) private(jk,jj,ji,zcompaph,zstep,zsizerat,zrespp,ztortp,zmortp,zfactfe,zfactch,zprcaca,zfracal)
86      DO jk = 1, jpkm1
87         DO jj = 1, jpj
88            DO ji = 1, jpi
89               zcompaph = MAX( ( trb(ji,jj,jk,jpphy) - 1e-8 ), 0.e0 )
90               zstep    = xstep
91# if defined key_degrad
92               zstep    = zstep * facvol(ji,jj,jk)
93# endif
94               !     When highly limited by macronutrients, very small cells
95               !     dominate the community. As a consequence, aggregation
96               !     due to turbulence is negligible. Mortality is also set
97               !     to 0
98               zsizerat = MIN(1., MAX( 0., (quotan(ji,jj,jk) - 0.2) / 0.3) ) * trb(ji,jj,jk,jpphy)
99               !     Squared mortality of Phyto similar to a sedimentation term during
100               !     blooms (Doney et al. 1996)
101               zrespp = wchl * 1.e6 * zstep * xdiss(ji,jj,jk) * zcompaph * zsizerat 
102
103               !     Phytoplankton mortality. This mortality loss is slightly
104               !     increased when nutrients are limiting phytoplankton growth
105               !     as observed for instance in case of iron limitation.
106               ztortp = mprat * xstep * zcompaph / ( xkmort + trb(ji,jj,jk,jpphy) ) * zsizerat
107
108               zmortp = zrespp + ztortp
109
110               !   Update the arrays TRA which contains the biological sources and sinks
111
112               zfactfe = trb(ji,jj,jk,jpnfe)/(trb(ji,jj,jk,jpphy)+rtrn)
113               zfactch = trb(ji,jj,jk,jpnch)/(trb(ji,jj,jk,jpphy)+rtrn)
114               tra(ji,jj,jk,jpphy) = tra(ji,jj,jk,jpphy) - zmortp
115               tra(ji,jj,jk,jpnch) = tra(ji,jj,jk,jpnch) - zmortp * zfactch
116               tra(ji,jj,jk,jpnfe) = tra(ji,jj,jk,jpnfe) - zmortp * zfactfe
117               zprcaca = xfracal(ji,jj,jk) * zmortp
118               !
119               prodcal(ji,jj,jk) = prodcal(ji,jj,jk) + zprcaca  ! prodcal=prodcal(nanophy)+prodcal(microzoo)+prodcal(mesozoo)
120               !
121               zfracal = 0.5 * xfracal(ji,jj,jk)
122               tra(ji,jj,jk,jpdic) = tra(ji,jj,jk,jpdic) - zprcaca
123               tra(ji,jj,jk,jptal) = tra(ji,jj,jk,jptal) - 2. * zprcaca
124               tra(ji,jj,jk,jpcal) = tra(ji,jj,jk,jpcal) + zprcaca
125#if defined key_kriest
126               tra(ji,jj,jk,jppoc) = tra(ji,jj,jk,jppoc) + zmortp
127               tra(ji,jj,jk,jpnum) = tra(ji,jj,jk,jpnum) + ztortp * xkr_dnano + zrespp * xkr_ddiat
128               tra(ji,jj,jk,jpsfe) = tra(ji,jj,jk,jpsfe) + zmortp * zfactfe
129#else
130               tra(ji,jj,jk,jpgoc) = tra(ji,jj,jk,jpgoc) + zfracal * zmortp
131               tra(ji,jj,jk,jppoc) = tra(ji,jj,jk,jppoc) + ( 1. - zfracal ) * zmortp
132               tra(ji,jj,jk,jpsfe) = tra(ji,jj,jk,jpsfe) + ( 1. - zfracal ) * zmortp * zfactfe
133               tra(ji,jj,jk,jpbfe) = tra(ji,jj,jk,jpbfe) + zfracal * zmortp * zfactfe
134#endif
135            END DO
136         END DO
137      END DO
138!$OMP END DO NOWAIT
139!$OMP END PARALLEL
140      !
141       IF(ln_ctl)   THEN  ! print mean trends (used for debugging)
142         WRITE(charout, FMT="('nano')")
143         CALL prt_ctl_trc_info(charout)
144         CALL prt_ctl_trc(tab4d=tra, mask=tmask, clinfo=ctrcnm)
145       ENDIF
146      !
147      IF( nn_timing == 1 )  CALL timing_stop('p4z_nano')
148      !
149   END SUBROUTINE p4z_nano
150
151   SUBROUTINE p4z_diat
152      !!---------------------------------------------------------------------
153      !!                     ***  ROUTINE p4z_diat  ***
154      !!
155      !! ** Purpose :   Compute the mortality terms for diatoms
156      !!
157      !! ** Method  : - ???
158      !!---------------------------------------------------------------------
159      INTEGER  ::  ji, jj, jk
160      REAL(wp) ::  zfactfe,zfactsi,zfactch, zcompadi
161      REAL(wp) ::  zrespp2, ztortp2, zmortp2, zstep
162      REAL(wp) ::  zlim2, zlim1
163      CHARACTER (len=25) :: charout
164      !!---------------------------------------------------------------------
165      !
166      IF( nn_timing == 1 )  CALL timing_start('p4z_diat')
167      !
168
169      !    Aggregation term for diatoms is increased in case of nutrient
170      !    stress as observed in reality. The stressed cells become more
171      !    sticky and coagulate to sink quickly out of the euphotic zone
172      !     ------------------------------------------------------------
173
174!$OMP PARALLEL DO schedule(static) private(jk,jj,ji,zcompadi,zstep,zlim2,zlim1,zrespp2,ztortp2,zmortp2,zfactfe,zfactch,zfactsi)
175      DO jk = 1, jpkm1
176         DO jj = 1, jpj
177            DO ji = 1, jpi
178
179               zcompadi = MAX( ( trb(ji,jj,jk,jpdia) - 1e-9), 0. )
180
181               !    Aggregation term for diatoms is increased in case of nutrient
182               !    stress as observed in reality. The stressed cells become more
183               !    sticky and coagulate to sink quickly out of the euphotic zone
184               !     ------------------------------------------------------------
185               zstep   = xstep
186# if defined key_degrad
187               zstep = zstep * facvol(ji,jj,jk)
188# endif
189               !  Phytoplankton respiration
190               !     ------------------------
191               zlim2   = xlimdia(ji,jj,jk) * xlimdia(ji,jj,jk)
192               zlim1   = 0.25 * ( 1. - zlim2 ) / ( 0.25 + zlim2 ) 
193               zrespp2 = 1.e6 * zstep * (  wchld + wchldm * zlim1 ) * xdiss(ji,jj,jk) * zcompadi * trb(ji,jj,jk,jpdia)
194
195               !     Phytoplankton mortality.
196               !     ------------------------
197               ztortp2 = mprat2 * zstep * trb(ji,jj,jk,jpdia)  / ( xkmort + trb(ji,jj,jk,jpdia) ) * zcompadi 
198
199               zmortp2 = zrespp2 + ztortp2
200
201               !   Update the arrays tra which contains the biological sources and sinks
202               !   ---------------------------------------------------------------------
203               zfactch = trb(ji,jj,jk,jpdch) / ( trb(ji,jj,jk,jpdia) + rtrn )
204               zfactfe = trb(ji,jj,jk,jpdfe) / ( trb(ji,jj,jk,jpdia) + rtrn )
205               zfactsi = trb(ji,jj,jk,jpdsi) / ( trb(ji,jj,jk,jpdia) + rtrn )
206               tra(ji,jj,jk,jpdia) = tra(ji,jj,jk,jpdia) - zmortp2 
207               tra(ji,jj,jk,jpdch) = tra(ji,jj,jk,jpdch) - zmortp2 * zfactch
208               tra(ji,jj,jk,jpdfe) = tra(ji,jj,jk,jpdfe) - zmortp2 * zfactfe
209               tra(ji,jj,jk,jpdsi) = tra(ji,jj,jk,jpdsi) - zmortp2 * zfactsi
210               tra(ji,jj,jk,jpgsi) = tra(ji,jj,jk,jpgsi) + zmortp2 * zfactsi
211#if defined key_kriest
212               tra(ji,jj,jk,jppoc) = tra(ji,jj,jk,jppoc) + zmortp2 
213               tra(ji,jj,jk,jpnum) = tra(ji,jj,jk,jpnum) + ztortp2 * xkr_ddiat + zrespp2 * xkr_daggr
214               tra(ji,jj,jk,jpsfe) = tra(ji,jj,jk,jpsfe) + zmortp2 * zfactfe
215#else
216               tra(ji,jj,jk,jpgoc) = tra(ji,jj,jk,jpgoc) + zrespp2 + 0.5 * ztortp2
217               tra(ji,jj,jk,jppoc) = tra(ji,jj,jk,jppoc) + 0.5 * ztortp2
218               tra(ji,jj,jk,jpsfe) = tra(ji,jj,jk,jpsfe) + 0.5 * ztortp2 * zfactfe
219               tra(ji,jj,jk,jpbfe) = tra(ji,jj,jk,jpbfe) + ( zrespp2 + 0.5 * ztortp2 ) * zfactfe
220#endif
221            END DO
222         END DO
223      END DO
224      !
225      IF(ln_ctl)   THEN  ! print mean trends (used for debugging)
226         WRITE(charout, FMT="('diat')")
227         CALL prt_ctl_trc_info(charout)
228         CALL prt_ctl_trc(tab4d=tra, mask=tmask, clinfo=ctrcnm)
229      ENDIF
230      !
231      IF( nn_timing == 1 )  CALL timing_stop('p4z_diat')
232      !
233   END SUBROUTINE p4z_diat
234
235   SUBROUTINE p4z_mort_init
236
237      !!----------------------------------------------------------------------
238      !!                  ***  ROUTINE p4z_mort_init  ***
239      !!
240      !! ** Purpose :   Initialization of phytoplankton parameters
241      !!
242      !! ** Method  :   Read the nampismort namelist and check the parameters
243      !!      called at the first timestep
244      !!
245      !! ** input   :   Namelist nampismort
246      !!
247      !!----------------------------------------------------------------------
248
249      NAMELIST/nampismort/ wchl, wchld, wchldm, mprat, mprat2
250      INTEGER :: ios                 ! Local integer output status for namelist read
251
252      REWIND( numnatp_ref )              ! Namelist nampismort in reference namelist : Pisces phytoplankton
253      READ  ( numnatp_ref, nampismort, IOSTAT = ios, ERR = 901)
254901   IF( ios /= 0 ) CALL ctl_nam ( ios , 'nampismort in reference namelist', lwp )
255
256      REWIND( numnatp_cfg )              ! Namelist nampismort in configuration namelist : Pisces phytoplankton
257      READ  ( numnatp_cfg, nampismort, IOSTAT = ios, ERR = 902 )
258902   IF( ios /= 0 ) CALL ctl_nam ( ios , 'nampismort in configuration namelist', lwp )
259      IF(lwm) WRITE ( numonp, nampismort )
260
261      IF(lwp) THEN                         ! control print
262         WRITE(numout,*) ' '
263         WRITE(numout,*) ' Namelist parameters for phytoplankton mortality, nampismort'
264         WRITE(numout,*) ' ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~'
265         WRITE(numout,*) '    quadratic mortality of phytoplankton      wchl      =', wchl
266         WRITE(numout,*) '    maximum quadratic mortality of diatoms    wchld     =', wchld
267         WRITE(numout,*) '    maximum quadratic mortality of diatoms    wchldm    =', wchldm
268         WRITE(numout,*) '    phytoplankton mortality rate              mprat     =', mprat
269         WRITE(numout,*) '    Diatoms mortality rate                    mprat2    =', mprat2
270      ENDIF
271
272   END SUBROUTINE p4z_mort_init
273
274#else
275   !!======================================================================
276   !!  Dummy module :                                   No PISCES bio-model
277   !!======================================================================
278CONTAINS
279   SUBROUTINE p4z_mort                    ! Empty routine
280   END SUBROUTINE p4z_mort
281#endif 
282
283   !!======================================================================
284END MODULE p4zmort
Note: See TracBrowser for help on using the repository browser.