New URL for NEMO forge!   http://forge.nemo-ocean.eu

Since March 2022 along with NEMO 4.2 release, the code development moved to a self-hosted GitLab.
This present forge is now archived and remained online for history.
p4zsed.F90 in branches/2016/dev_r6519_HPC_4/NEMOGCM/NEMO/TOP_SRC/PISCES/P4Z – NEMO

source: branches/2016/dev_r6519_HPC_4/NEMOGCM/NEMO/TOP_SRC/PISCES/P4Z/p4zsed.F90 @ 7037

Last change on this file since 7037 was 7037, checked in by mocavero, 8 years ago

ORCA2_LIM_PISCES hybrid version update
  • Property svn:keywords set to Id
File size: 22.2 KB
Line 
1MODULE p4zsed
2   !!======================================================================
3   !!                         ***  MODULE p4sed  ***
4   !! TOP :   PISCES Compute loss of organic matter in the sediments
5   !!======================================================================
6   !! History :   1.0  !  2004-03 (O. Aumont) Original code
7   !!             2.0  !  2007-12 (C. Ethe, G. Madec)  F90
8   !!             3.4  !  2011-06 (C. Ethe) USE of fldread
9   !!             3.5  !  2012-07 (O. Aumont) improvment of river input of nutrients
10   !!----------------------------------------------------------------------
11#if defined key_pisces
12   !!----------------------------------------------------------------------
13   !!   'key_pisces'                                       PISCES bio-model
14   !!----------------------------------------------------------------------
15   !!   p4z_sed        :  Compute loss of organic matter in the sediments
16   !!----------------------------------------------------------------------
17   USE oce_trc         !  shared variables between ocean and passive tracers
18   USE trc             !  passive tracers common variables
19   USE sms_pisces      !  PISCES Source Minus Sink variables
20   USE p4zsink         !  vertical flux of particulate matter due to sinking
21   USE p4zopt          !  optical model
22   USE p4zlim          !  Co-limitations of differents nutrients
23   USE p4zsbc          !  External source of nutrients
24   USE p4zint          !  interpolation and computation of various fields
25   USE iom             !  I/O manager
26   USE prtctl_trc      !  print control for debugging
27
28   IMPLICIT NONE
29   PRIVATE
30
31   PUBLIC   p4z_sed 
32   PUBLIC   p4z_sed_alloc
33 
34   REAL(wp), PUBLIC, ALLOCATABLE, SAVE, DIMENSION(:,:,:) :: nitrpot    !: Nitrogen fixation
35   REAL(wp), PUBLIC, ALLOCATABLE, SAVE, DIMENSION(:,:  ) :: sdenit     !: Nitrate reduction in the sediments
36   REAL(wp) :: r1_rday                  !: inverse of rday
37
38   !!----------------------------------------------------------------------
39   !! NEMO/TOP 3.3 , NEMO Consortium (2010)
40   !! $Id$
41   !! Software governed by the CeCILL licence (NEMOGCM/NEMO_CeCILL.txt)
42   !!----------------------------------------------------------------------
43CONTAINS
44
45   SUBROUTINE p4z_sed( kt, knt )
46      !!---------------------------------------------------------------------
47      !!                     ***  ROUTINE p4z_sed  ***
48      !!
49      !! ** Purpose :   Compute loss of organic matter in the sediments. This
50      !!              is by no way a sediment model. The loss is simply
51      !!              computed to balance the inout from rivers and dust
52      !!
53      !! ** Method  : - ???
54      !!---------------------------------------------------------------------
55      !
56      INTEGER, INTENT(in) ::   kt, knt ! ocean time step
57      INTEGER  ::   ji, jj, jk, ikt
58#if ! defined key_sed
59      REAL(wp) ::   zsumsedsi, zsumsedpo4, zsumsedcal
60      REAL(wp) ::   zrivalk, zrivsil, zrivno3
61#endif
62      REAL(wp) ::  zwflux, zfminus, zfplus
63      REAL(wp) ::  zlim, zfact, zfactcal
64      REAL(wp) ::  zo2, zno3, zflx, zpdenit, z1pdenit, zdenitt, zolimit
65      REAL(wp) ::  zsiloss, zcaloss, zws3, zws4, zwsc, zdep, zwstpoc
66      REAL(wp) ::  ztrfer, ztrpo4, zwdust, zlight
67      !
68      CHARACTER (len=25) :: charout
69      REAL(wp), POINTER, DIMENSION(:,:  ) :: zpdep, zsidep, zwork1, zwork2, zwork3
70      REAL(wp), POINTER, DIMENSION(:,:  ) :: zdenit2d, zironice, zbureff
71      REAL(wp), POINTER, DIMENSION(:,:  ) :: zwsbio3, zwsbio4, zwscal
72      REAL(wp), POINTER, DIMENSION(:,:,:) :: zirondep, zsoufer
73      !!---------------------------------------------------------------------
74      !
75      IF( nn_timing == 1 )  CALL timing_start('p4z_sed')
76      !
77      IF( kt == nittrc000 .AND. knt == 1 )   r1_rday  = 1. / rday
78      !
79      ! Allocate temporary workspace
80      CALL wrk_alloc( jpi, jpj, zdenit2d, zwork1, zwork2, zwork3, zbureff )
81      CALL wrk_alloc( jpi, jpj, zwsbio3, zwsbio4, zwscal )
82      CALL wrk_alloc( jpi, jpj, jpk, zsoufer )
83
84!$OMP PARALLEL WORKSHARE
85      zdenit2d(:,:) = 0.e0
86      zbureff (:,:) = 0.e0
87      zwork1  (:,:) = 0.e0
88      zwork2  (:,:) = 0.e0
89      zwork3  (:,:) = 0.e0
90!$OMP END PARALLEL WORKSHARE
91
92      ! Iron input/uptake due to sea ice : Crude parameterization based on Lancelot et al.
93      ! ----------------------------------------------------
94      IF( ln_ironice ) THEN 
95         !                                             
96         CALL wrk_alloc( jpi, jpj, zironice )
97!$OMP PARALLEL
98!$OMP DO schedule(static) private(jj,ji,zdep,zwflux,zfminus,zfplus)
99         DO jj = 1, jpj
100            DO ji = 1, jpi
101               zdep    = rfact2 / e3t_n(ji,jj,1)
102               zwflux  = fmmflx(ji,jj) / 1000._wp
103               zfminus = MIN( 0._wp, -zwflux ) * trb(ji,jj,1,jpfer) * zdep
104               zfplus  = MAX( 0._wp, -zwflux ) * icefeinput * zdep
105               zironice(ji,jj) =  zfplus + zfminus
106            END DO
107         END DO
108         !
109!$OMP WORKSHARE
110         tra(:,:,1,jpfer) = tra(:,:,1,jpfer) + zironice(:,:) 
111!$OMP END WORKSHARE NOWAIT
112!$OMP END PARALLEL
113         !
114         IF( lk_iomput .AND. knt == nrdttrc .AND. iom_use( "Ironice" ) )   &
115            &   CALL iom_put( "Ironice", zironice(:,:) * 1.e+3 * rfact2r * e3t_n(:,:,1) * tmask(:,:,1) ) ! iron flux from ice
116         !
117         CALL wrk_dealloc( jpi, jpj, zironice )
118         !                                             
119      ENDIF
120
121      ! Add the external input of nutrients from dust deposition
122      ! ----------------------------------------------------------
123      IF( ln_dust ) THEN
124         !                                             
125         CALL wrk_alloc( jpi, jpj,      zpdep, zsidep )
126         CALL wrk_alloc( jpi, jpj, jpk, zirondep      )
127         !                                              ! Iron and Si deposition at the surface
128         IF( ln_solub ) THEN
129!$OMP PARALLEL WORKSHARE
130            zirondep(:,:,1) = solub(:,:) * dust(:,:) * mfrac * rfact2 / e3t_n(:,:,1) / 55.85 + 3.e-10 * r1_ryyss
131!$OMP END PARALLEL WORKSHARE
132         ELSE
133!$OMP PARALLEL WORKSHARE
134            zirondep(:,:,1) = dustsolub  * dust(:,:) * mfrac * rfact2 / e3t_n(:,:,1) / 55.85 + 3.e-10 * r1_ryyss
135!$OMP END PARALLEL WORKSHARE
136         ENDIF
137!$OMP PARALLEL WORKSHARE
138         zsidep(:,:) = 8.8 * 0.075 * dust(:,:) * mfrac * rfact2 / e3t_n(:,:,1) / 28.1
139         zpdep (:,:) = 0.1 * 0.021 * dust(:,:) * mfrac * rfact2 / e3t_n(:,:,1) / 31. / po4r
140!$OMP END PARALLEL WORKSHARE
141         !                                              ! Iron solubilization of particles in the water column
142         !                                              ! dust in kg/m2/s ---> 1/55.85 to put in mol/Fe ;  wdust in m/j
143         zwdust = 0.03 * rday / ( wdust * 55.85 ) / ( 270. * rday )
144!$OMP DO schedule(static) private(jk)
145         DO jk = 2, jpkm1
146            zirondep(:,:,jk) = dust(:,:) * mfrac * zwdust * rfact2 * EXP( -gdept_n(:,:,jk) / 540. )
147         END DO
148         !                                              ! Iron solubilization of particles in the water column
149!$OMP PARALLEL
150!$OMP WORKSHARE
151         tra(:,:,1,jppo4) = tra(:,:,1,jppo4) + zpdep   (:,:)
152         tra(:,:,1,jpsil) = tra(:,:,1,jpsil) + zsidep  (:,:)
153         tra(:,:,:,jpfer) = tra(:,:,:,jpfer) + zirondep(:,:,:) 
154!$OMP END WORKSHARE
155!$OMP END PARALLEL
156         !
157         IF( lk_iomput ) THEN
158            IF( knt == nrdttrc ) THEN
159                IF( iom_use( "Irondep" ) )   &
160                &  CALL iom_put( "Irondep", zirondep(:,:,1) * 1.e+3 * rfact2r * e3t_n(:,:,1) * tmask(:,:,1) ) ! surface downward dust depo of iron
161                IF( iom_use( "pdust" ) )   &
162                &  CALL iom_put( "pdust"  , dust(:,:) / ( wdust * rday )  * tmask(:,:,1) ) ! dust concentration at surface
163            ENDIF
164         ELSE                                   
165            IF( ln_diatrc )  THEN
166!$OMP PARALLEL WORKSHARE
167             trc2d(:,:,jp_pcs0_2d + 11) = zirondep(:,:,1) * 1.e+3 * rfact2r * e3t_n(:,:,1) * tmask(:,:,1)
168!$OMP END PARALLEL WORKSHARE
169            ENDIF
170         ENDIF
171         CALL wrk_dealloc( jpi, jpj,      zpdep, zsidep )
172         CALL wrk_dealloc( jpi, jpj, jpk, zirondep      )
173         !                                             
174      ENDIF
175     
176      ! Add the external input of nutrients from river
177      ! ----------------------------------------------------------
178      IF( ln_river ) THEN
179!$OMP DO schedule(static) private(jj,ji,jk)
180         DO jj = 1, jpj
181            DO ji = 1, jpi
182               DO jk = 1, nk_rnf(ji,jj)
183                  tra(ji,jj,jk,jppo4) = tra(ji,jj,jk,jppo4) +  rivdip(ji,jj) * rfact2
184                  tra(ji,jj,jk,jpno3) = tra(ji,jj,jk,jpno3) +  rivdin(ji,jj) * rfact2
185                  tra(ji,jj,jk,jpfer) = tra(ji,jj,jk,jpfer) +  rivdic(ji,jj) * 5.e-5 * rfact2
186                  tra(ji,jj,jk,jpsil) = tra(ji,jj,jk,jpsil) +  rivdsi(ji,jj) * rfact2
187                  tra(ji,jj,jk,jpdic) = tra(ji,jj,jk,jpdic) +  rivdic(ji,jj) * rfact2
188                  tra(ji,jj,jk,jptal) = tra(ji,jj,jk,jptal) +  ( rivalk(ji,jj) - rno3 * rivdin(ji,jj) ) * rfact2
189               ENDDO
190            ENDDO
191         ENDDO
192      ENDIF
193     
194      ! Add the external input of nutrients from nitrogen deposition
195      ! ----------------------------------------------------------
196      IF( ln_ndepo ) THEN
197!$OMP PARALLEL WORKSHARE
198         tra(:,:,1,jpno3) = tra(:,:,1,jpno3) + nitdep(:,:) * rfact2
199         tra(:,:,1,jptal) = tra(:,:,1,jptal) - rno3 * nitdep(:,:) * rfact2
200!$OMP END PARALLEL WORKSHARE
201      ENDIF
202
203      ! Add the external input of iron from sediment mobilization
204      ! ------------------------------------------------------
205      IF( ln_ironsed ) THEN
206!$OMP PARALLEL WORKSHARE
207         tra(:,:,:,jpfer) = tra(:,:,:,jpfer) + ironsed(:,:,:) * rfact2
208!$OMP END PARALLEL WORKSHARE
209         !
210         IF( lk_iomput .AND. knt == nrdttrc .AND. iom_use( "Ironsed" ) )   &
211            &   CALL iom_put( "Ironsed", ironsed(:,:,:) * 1.e+3 * tmask(:,:,:) ) ! iron inputs from sediments
212      ENDIF
213
214      ! Add the external input of iron from hydrothermal vents
215      ! ------------------------------------------------------
216      IF( ln_hydrofe ) THEN
217!$OMP PARALLEL WORKSHARE
218         tra(:,:,:,jpfer) = tra(:,:,:,jpfer) + hydrofe(:,:,:) * rfact2
219!$OMP END PARALLEL WORKSHARE
220         !
221         IF( lk_iomput .AND. knt == nrdttrc .AND. iom_use( "HYDR" ) )   &
222            &   CALL iom_put( "HYDR", hydrofe(:,:,:) * 1.e+3 * tmask(:,:,:) ) ! hydrothermal iron input
223      ENDIF
224
225      ! OA: Warning, the following part is necessary, especially with Kriest
226      ! to avoid CFL problems above the sediments
227      ! --------------------------------------------------------------------
228!$OMP PARALLEL
229!$OMP DO schedule(static) private(jj,ji,ikt,zdep)
230      DO jj = 1, jpj
231         DO ji = 1, jpi
232            ikt  = mbkt(ji,jj)
233            zdep = e3t_n(ji,jj,ikt) / xstep
234            zwsbio4(ji,jj) = MIN( 0.99 * zdep, wsbio4(ji,jj,ikt) )
235            zwscal (ji,jj) = MIN( 0.99 * zdep, wscal (ji,jj,ikt) )
236            zwsbio3(ji,jj) = MIN( 0.99 * zdep, wsbio3(ji,jj,ikt) )
237         END DO
238      END DO
239
240#if ! defined key_sed
241      ! Computation of the sediment denitrification proportion: The metamodel from midlleburg (2006) is being used
242      ! Computation of the fraction of organic matter that is permanently buried from Dunne's model
243      ! -------------------------------------------------------
244!$OMP DO schedule(static) private(jj,ji,ikt,zflx,zo2,zno3,zdep)
245      DO jj = 1, jpj
246         DO ji = 1, jpi
247           IF( tmask(ji,jj,1) == 1 ) THEN
248              ikt = mbkt(ji,jj)
249# if defined key_kriest
250              zflx =    trb(ji,jj,ikt,jppoc) * zwsbio3(ji,jj)    * 1E3 * 1E6 / 1E4
251# else
252              zflx = (  trb(ji,jj,ikt,jpgoc) * zwsbio4(ji,jj)   &
253                &     + trb(ji,jj,ikt,jppoc) * zwsbio3(ji,jj) )  * 1E3 * 1E6 / 1E4
254#endif
255              zflx  = LOG10( MAX( 1E-3, zflx ) )
256              zo2   = LOG10( MAX( 10. , trb(ji,jj,ikt,jpoxy) * 1E6 ) )
257              zno3  = LOG10( MAX( 1.  , trb(ji,jj,ikt,jpno3) * 1E6 * rno3 ) )
258              zdep  = LOG10( gdepw_n(ji,jj,ikt+1) )
259              zdenit2d(ji,jj) = -2.2567 - 1.185 * zflx - 0.221 * zflx**2 - 0.3995 * zno3 * zo2 + 1.25 * zno3    &
260              &                + 0.4721 * zo2 - 0.0996 * zdep + 0.4256 * zflx * zo2
261              zdenit2d(ji,jj) = 10.0**( zdenit2d(ji,jj) )
262              !
263              zflx = (  trb(ji,jj,ikt,jpgoc) * zwsbio4(ji,jj)   &
264                &     + trb(ji,jj,ikt,jppoc) * zwsbio3(ji,jj) ) * 1E6
265              zbureff(ji,jj) = 0.013 + 0.53 * zflx**2 / ( 7.0 + zflx )**2
266           ENDIF
267         END DO
268      END DO 
269
270      ! Loss of biogenic silicon, Caco3 organic carbon in the sediments.
271      ! First, the total loss is computed.
272      ! The factor for calcite comes from the alkalinity effect
273      ! -------------------------------------------------------------
274!$OMP DO schedule(static) private(jj,ji,ikt,zfactcal)
275      DO jj = 1, jpj
276         DO ji = 1, jpi
277            IF( tmask(ji,jj,1) == 1 ) THEN
278               ikt = mbkt(ji,jj) 
279# if defined key_kriest
280               zwork1(ji,jj) = trb(ji,jj,ikt,jpgsi) * zwscal (ji,jj)
281               zwork2(ji,jj) = trb(ji,jj,ikt,jppoc) * zwsbio3(ji,jj)
282# else
283               zwork1(ji,jj) = trb(ji,jj,ikt,jpgsi) * zwsbio4(ji,jj)
284               zwork2(ji,jj) = trb(ji,jj,ikt,jpgoc) * zwsbio4(ji,jj) + trb(ji,jj,ikt,jppoc) * zwsbio3(ji,jj) 
285# endif
286               ! For calcite, burial efficiency is made a function of saturation
287               zfactcal      = MIN( excess(ji,jj,ikt), 0.2 )
288               zfactcal      = MIN( 1., 1.3 * ( 0.2 - zfactcal ) / ( 0.4 - zfactcal ) )
289               zwork3(ji,jj) = trb(ji,jj,ikt,jpcal) * zwscal(ji,jj) * 2.e0 * zfactcal
290            ENDIF
291         END DO
292      END DO
293
294!$OMP SINGLE
295      zsumsedsi  = glob_sum( zwork1(:,:) * e1e2t(:,:) ) * r1_rday
296      zsumsedpo4 = glob_sum( zwork2(:,:) * e1e2t(:,:) ) * r1_rday
297      zsumsedcal = glob_sum( zwork3(:,:) * e1e2t(:,:) ) * r1_rday
298#endif
299
300      ! This loss is scaled at each bottom grid cell for equilibrating the total budget of silica in the ocean.
301      ! Thus, the amount of silica lost in the sediments equal the supply at the surface (dust+rivers)
302      ! ------------------------------------------------------
303#if ! defined key_sed
304      zrivsil =  1._wp - ( sumdepsi + rivdsiinput * r1_ryyss ) / ( zsumsedsi + rtrn )
305#endif
306!$OMP END SINGLE
307
308!$OMP DO schedule(static) private(jj,ji,ikt,zdep,zws4,zwsc,zsiloss,zcaloss,zfactcal,zrivalk)
309      DO jj = 1, jpj
310         DO ji = 1, jpi
311            ikt  = mbkt(ji,jj)
312            zdep = xstep / e3t_n(ji,jj,ikt) 
313            zws4 = zwsbio4(ji,jj) * zdep
314            zwsc = zwscal (ji,jj) * zdep
315# if defined key_kriest
316            zsiloss = trb(ji,jj,ikt,jpgsi) * zws4
317# else
318            zsiloss = trb(ji,jj,ikt,jpgsi) * zwsc
319# endif
320            zcaloss = trb(ji,jj,ikt,jpcal) * zwsc
321            !
322            tra(ji,jj,ikt,jpgsi) = tra(ji,jj,ikt,jpgsi) - zsiloss
323            tra(ji,jj,ikt,jpcal) = tra(ji,jj,ikt,jpcal) - zcaloss
324#if ! defined key_sed
325            tra(ji,jj,ikt,jpsil) = tra(ji,jj,ikt,jpsil) + zsiloss * zrivsil 
326            zfactcal = MIN( excess(ji,jj,ikt), 0.2 )
327            zfactcal = MIN( 1., 1.3 * ( 0.2 - zfactcal ) / ( 0.4 - zfactcal ) )
328            zrivalk  =  1._wp - ( rivalkinput * r1_ryyss ) * zfactcal / ( zsumsedcal + rtrn )
329            tra(ji,jj,ikt,jptal) =  tra(ji,jj,ikt,jptal) + zcaloss * zrivalk * 2.0
330            tra(ji,jj,ikt,jpdic) =  tra(ji,jj,ikt,jpdic) + zcaloss * zrivalk
331#endif
332         END DO
333      END DO
334
335!$OMP DO schedule(static) private(jj,ji,ikt,zdep,zws3,zws4,zrivno3,zwstpoc,zpdenit,z1pdenit,zolimit,zdenitt)
336      DO jj = 1, jpj
337         DO ji = 1, jpi
338            ikt  = mbkt(ji,jj)
339            zdep = xstep / e3t_n(ji,jj,ikt) 
340            zws4 = zwsbio4(ji,jj) * zdep
341            zws3 = zwsbio3(ji,jj) * zdep
342            zrivno3 = 1. - zbureff(ji,jj)
343# if ! defined key_kriest
344            tra(ji,jj,ikt,jpgoc) = tra(ji,jj,ikt,jpgoc) - trb(ji,jj,ikt,jpgoc) * zws4 
345            tra(ji,jj,ikt,jppoc) = tra(ji,jj,ikt,jppoc) - trb(ji,jj,ikt,jppoc) * zws3
346            tra(ji,jj,ikt,jpbfe) = tra(ji,jj,ikt,jpbfe) - trb(ji,jj,ikt,jpbfe) * zws4
347            tra(ji,jj,ikt,jpsfe) = tra(ji,jj,ikt,jpsfe) - trb(ji,jj,ikt,jpsfe) * zws3
348            zwstpoc              = trb(ji,jj,ikt,jpgoc) * zws4 + trb(ji,jj,ikt,jppoc) * zws3
349# else
350            tra(ji,jj,ikt,jpnum) = tra(ji,jj,ikt,jpnum) - trb(ji,jj,ikt,jpnum) * zws4 
351            tra(ji,jj,ikt,jppoc) = tra(ji,jj,ikt,jppoc) - trb(ji,jj,ikt,jppoc) * zws3
352            tra(ji,jj,ikt,jpsfe) = tra(ji,jj,ikt,jpsfe) - trb(ji,jj,ikt,jpsfe) * zws3
353            zwstpoc = trb(ji,jj,ikt,jppoc) * zws3 
354# endif
355
356#if ! defined key_sed
357            ! The 0.5 factor in zpdenit and zdenitt is to avoid negative NO3 concentration after both denitrification
358            ! in the sediments and just above the sediments. Not very clever, but simpliest option.
359            zpdenit  = MIN( 0.5 * ( trb(ji,jj,ikt,jpno3) - rtrn ) / rdenit, zdenit2d(ji,jj) * zwstpoc * zrivno3 )
360            z1pdenit = zwstpoc * zrivno3 - zpdenit
361            zolimit = MIN( ( trb(ji,jj,ikt,jpoxy) - rtrn ) / o2ut, z1pdenit * ( 1.- nitrfac(ji,jj,ikt) ) )
362            zdenitt = MIN(  0.5 * ( trb(ji,jj,ikt,jpno3) - rtrn ) / rdenit, z1pdenit * nitrfac(ji,jj,ikt) )
363            tra(ji,jj,ikt,jpdoc) = tra(ji,jj,ikt,jpdoc) + z1pdenit - zolimit - zdenitt
364            tra(ji,jj,ikt,jppo4) = tra(ji,jj,ikt,jppo4) + zpdenit + zolimit + zdenitt
365            tra(ji,jj,ikt,jpnh4) = tra(ji,jj,ikt,jpnh4) + zpdenit + zolimit + zdenitt
366            tra(ji,jj,ikt,jpno3) = tra(ji,jj,ikt,jpno3) - rdenit * (zpdenit + zdenitt)
367            tra(ji,jj,ikt,jpoxy) = tra(ji,jj,ikt,jpoxy) - zolimit * o2ut
368            tra(ji,jj,ikt,jptal) = tra(ji,jj,ikt,jptal) + rno3 * (zolimit + (1.+rdenit) * (zpdenit + zdenitt) )
369            tra(ji,jj,ikt,jpdic) = tra(ji,jj,ikt,jpdic) + zpdenit + zolimit + zdenitt
370            sdenit(ji,jj) = rdenit * zpdenit * e3t_n(ji,jj,ikt)
371#endif
372         END DO
373      END DO
374!$OMP END DO NOWAIT
375      ! Nitrogen fixation process
376      ! Small source iron from particulate inorganic iron
377      !-----------------------------------
378!$OMP DO schedule(static) private(jk,jj,ji,zlim,zfact,ztrfer,ztrpo4,zlight)
379      DO jk = 1, jpkm1
380         DO jj = 1, jpj
381            DO ji = 1, jpi
382               !                      ! Potential nitrogen fixation dependant on temperature and iron
383               zlim = ( 1.- xnanono3(ji,jj,jk) - xnanonh4(ji,jj,jk) )
384               IF( zlim <= 0.2 )   zlim = 0.01
385#if defined key_degrad
386               zfact = zlim * rfact2 * facvol(ji,jj,jk)
387#else
388               zfact = zlim * rfact2
389#endif
390               ztrfer = biron(ji,jj,jk)       / ( concfediaz + biron(ji,jj,jk)       )
391               ztrpo4 = trb  (ji,jj,jk,jppo4) / ( concnnh4   + trb  (ji,jj,jk,jppo4) ) 
392               zlight =  ( 1.- EXP( -etot_ndcy(ji,jj,jk) / diazolight ) ) 
393               nitrpot(ji,jj,jk) =  MAX( 0.e0, ( 0.6 * tgfunc(ji,jj,jk) - 2.15 ) * r1_rday )   &
394                 &         *  zfact * MIN( ztrfer, ztrpo4 ) * zlight
395               zsoufer(ji,jj,jk) = zlight * 2E-11 / (2E-11 + biron(ji,jj,jk))
396            END DO
397         END DO
398      END DO
399
400      ! Nitrogen change due to nitrogen fixation
401      ! ----------------------------------------
402!$OMP DO schedule(static) private(jk,jj,ji,zfact)
403      DO jk = 1, jpkm1
404         DO jj = 1, jpj
405            DO ji = 1, jpi
406               zfact = nitrpot(ji,jj,jk) * nitrfix
407               tra(ji,jj,jk,jpnh4) = tra(ji,jj,jk,jpnh4) +             zfact
408               tra(ji,jj,jk,jptal) = tra(ji,jj,jk,jptal) + rno3      * zfact
409               tra(ji,jj,jk,jpoxy) = tra(ji,jj,jk,jpoxy) + o2nit     * zfact 
410               tra(ji,jj,jk,jppo4) = tra(ji,jj,jk,jppo4) + concdnh4 / ( concdnh4 + trb(ji,jj,jk,jppo4) ) &
411               &                     * 0.002 * trb(ji,jj,jk,jpdoc) * xstep
412               tra(ji,jj,jk,jpfer) = tra(ji,jj,jk,jpfer) + 0.002 * 4E-10 * zsoufer(ji,jj,jk) * xstep
413           END DO
414         END DO
415      END DO
416!$OMP END DO NOWAIT
417!$OMP END PARALLEL
418
419      IF( lk_iomput ) THEN
420         IF( knt == nrdttrc ) THEN
421            zfact = 1.e+3 * rfact2r * rno3  !  conversion from molC/l/kt  to molN/m3/s
422            IF( iom_use("Nfix"   ) ) CALL iom_put( "Nfix", nitrpot(:,:,:) * nitrfix * zfact * tmask(:,:,:) )  ! nitrogen fixation
423            IF( iom_use("INTNFIX") ) THEN   ! nitrogen fixation rate in ocean ( vertically integrated )
424               zwork1(:,:) = 0.
425               DO jk = 1, jpkm1
426!$OMP PARALLEL DO schedule(static) private(jj,ji)
427                  DO jj = 1, jpj
428                     DO ji = 1, jpi
429                        zwork1(ji,jj) = zwork1(ji,jj) + nitrpot(ji,jj,jk) * nitrfix * zfact * e3t_n(ji,jj,jk) * tmask(ji,jj,jk)
430                     END DO
431                  END DO
432               ENDDO
433               CALL iom_put( "INTNFIX" , zwork1 ) 
434            ENDIF
435         ENDIF
436      ELSE
437         IF( ln_diatrc )  &
438            &  trc2d(:,:,jp_pcs0_2d + 12) = nitrpot(:,:,1) * nitrfix * rno3 * 1.e+3 * rfact2r * e3t_n(:,:,1) * tmask(:,:,1)
439      ENDIF
440      !
441      IF(ln_ctl) THEN  ! print mean trends (USEd for debugging)
442         WRITE(charout, fmt="('sed ')")
443         CALL prt_ctl_trc_info(charout)
444         CALL prt_ctl_trc(tab4d=tra, mask=tmask, clinfo=ctrcnm)
445      ENDIF
446      !
447      CALL wrk_dealloc( jpi, jpj, zdenit2d, zwork1, zwork2, zwork3, zbureff )
448      CALL wrk_dealloc( jpi, jpj, zwsbio3, zwsbio4, zwscal )
449      CALL wrk_dealloc( jpi, jpj, jpk, zsoufer )
450      !
451      IF( nn_timing == 1 )  CALL timing_stop('p4z_sed')
452      !
453 9100  FORMAT(i8,3f10.5)
454      !
455   END SUBROUTINE p4z_sed
456
457
458   INTEGER FUNCTION p4z_sed_alloc()
459      !!----------------------------------------------------------------------
460      !!                     ***  ROUTINE p4z_sed_alloc  ***
461      !!----------------------------------------------------------------------
462      ALLOCATE( nitrpot(jpi,jpj,jpk), sdenit(jpi,jpj), STAT=p4z_sed_alloc )
463      !
464      IF( p4z_sed_alloc /= 0 )   CALL ctl_warn('p4z_sed_alloc: failed to allocate arrays')
465      !
466   END FUNCTION p4z_sed_alloc
467
468
469#else
470   !!======================================================================
471   !!  Dummy module :                                   No PISCES bio-model
472   !!======================================================================
473CONTAINS
474   SUBROUTINE p4z_sed                         ! Empty routine
475   END SUBROUTINE p4z_sed
476#endif 
477
478   !!======================================================================
479END MODULE p4zsed
Note: See TracBrowser for help on using the repository browser.