New URL for NEMO forge!   http://forge.nemo-ocean.eu

Since March 2022 along with NEMO 4.2 release, the code development moved to a self-hosted GitLab.
This present forge is now archived and remained online for history.
trcadv.F90 in branches/2016/dev_r6519_HPC_4/NEMOGCM/NEMO/TOP_SRC/TRP – NEMO

source: branches/2016/dev_r6519_HPC_4/NEMOGCM/NEMO/TOP_SRC/TRP/trcadv.F90 @ 7037

Last change on this file since 7037 was 7037, checked in by mocavero, 8 years ago

ORCA2_LIM_PISCES hybrid version update
  • Property svn:keywords set to Id
File size: 15.3 KB
Line 
1MODULE trcadv
2   !!==============================================================================
3   !!                       ***  MODULE  trcadv  ***
4   !! Ocean passive tracers:  advection trend
5   !!==============================================================================
6   !! History :  2.0  !  2005-11  (G. Madec)  Original code
7   !!            3.0  !  2010-06  (C. Ethe)   Adapted to passive tracers
8   !!            3.7  !  2014-05  (G. Madec, C. Ethe)  Add 2nd/4th order cases for CEN and FCT schemes
9   !!----------------------------------------------------------------------
10#if defined key_top
11   !!----------------------------------------------------------------------
12   !!   'key_top'                                                TOP models
13   !!----------------------------------------------------------------------
14   !!   trc_adv       : compute ocean tracer advection trend
15   !!   trc_adv_ini   : control the different options of advection scheme
16   !!----------------------------------------------------------------------
17   USE oce_trc        ! ocean dynamics and active tracers
18   USE trc            ! ocean passive tracers variables
19   USE traadv_cen     ! centered scheme           (tra_adv_cen  routine)
20   USE traadv_fct     ! FCT      scheme           (tra_adv_fct  routine)
21   USE traadv_mus     ! MUSCL    scheme           (tra_adv_mus  routine)
22   USE traadv_ubs     ! UBS      scheme           (tra_adv_ubs  routine)
23   USE traadv_qck     ! QUICKEST scheme           (tra_adv_qck  routine)
24   USE traadv_mle     ! ML eddy induced velocity  (tra_adv_mle  routine)
25   USE ldftra         ! lateral diffusion coefficient on tracers
26   USE ldfslp         ! Lateral diffusion: slopes of neutral surfaces
27   !
28   USE prtctl_trc     ! Print control
29
30   IMPLICIT NONE
31   PRIVATE
32
33   PUBLIC   trc_adv       
34   PUBLIC   trc_adv_ini 
35
36   !                            !!* Namelist namtrc_adv *
37   LOGICAL ::   ln_trcadv_cen    ! centered scheme flag
38   INTEGER ::      nn_cen_h, nn_cen_v   ! =2/4 : horizontal and vertical choices of the order of CEN scheme
39   LOGICAL ::   ln_trcadv_fct    ! FCT scheme flag
40   INTEGER ::      nn_fct_h, nn_fct_v   ! =2/4 : horizontal and vertical choices of the order of FCT scheme
41   INTEGER ::      nn_fct_zts           ! >=1 : 2nd order FCT with vertical sub-timestepping
42   LOGICAL ::   ln_trcadv_mus    ! MUSCL scheme flag
43   LOGICAL ::      ln_mus_ups           ! use upstream scheme in vivcinity of river mouths
44   LOGICAL ::   ln_trcadv_ubs    ! UBS scheme flag
45   INTEGER ::      nn_ubs_v             ! =2/4 : vertical choice of the order of UBS scheme
46   LOGICAL ::   ln_trcadv_qck    ! QUICKEST scheme flag
47
48   !                                        ! choices of advection scheme:
49   INTEGER, PARAMETER ::   np_NO_adv  = 0   ! no T-S advection
50   INTEGER, PARAMETER ::   np_CEN     = 1   ! 2nd/4th order centered scheme
51   INTEGER, PARAMETER ::   np_FCT     = 2   ! 2nd/4th order Flux Corrected Transport scheme
52   INTEGER, PARAMETER ::   np_FCT_zts = 3   ! 2nd order FCT scheme with vertical sub-timestepping
53   INTEGER, PARAMETER ::   np_MUS     = 4   ! MUSCL scheme
54   INTEGER, PARAMETER ::   np_UBS     = 5   ! 3rd order Upstream Biased Scheme
55   INTEGER, PARAMETER ::   np_QCK     = 6   ! QUICK scheme
56
57   INTEGER ::              nadv             ! chosen advection scheme
58   !
59   REAL(wp) ::   r2dttrc  ! vertical profile time-step, = 2 rdt
60   !                                                    ! except at nitrrc000 (=rdt) if neuler=0
61
62   !! * Substitutions
63#  include "vectopt_loop_substitute.h90"
64   !!----------------------------------------------------------------------
65   !! NEMO/TOP 3.7 , NEMO Consortium (2015)
66   !! $Id$
67   !! Software governed by the CeCILL licence (NEMOGCM/NEMO_CeCILL.txt)
68   !!----------------------------------------------------------------------
69CONTAINS
70
71   SUBROUTINE trc_adv( kt )
72      !!----------------------------------------------------------------------
73      !!                  ***  ROUTINE trc_adv  ***
74      !!
75      !! ** Purpose :   compute the ocean tracer advection trend.
76      !!
77      !! ** Method  : - Update the tracer with the advection term following nadv
78      !!----------------------------------------------------------------------
79      INTEGER, INTENT(in) ::   kt   ! ocean time-step index
80      !
81      INTEGER ::   jk   ! dummy loop index
82      CHARACTER (len=22) ::   charout
83      REAL(wp), POINTER, DIMENSION(:,:,:) :: zun, zvn, zwn  ! effective velocity
84      !!----------------------------------------------------------------------
85      !
86      IF( nn_timing == 1 )   CALL timing_start('trc_adv')
87      !
88      CALL wrk_alloc( jpi,jpj,jpk,   zun, zvn, zwn )
89      !
90      IF( ( neuler == 0 .AND. kt == nittrc000 ) .OR. ln_top_euler ) THEN     ! at nittrc000
91         r2dttrc =  rdttrc           ! = rdttrc (use or restarting with Euler time stepping)
92      ELSEIF( kt <= nittrc000 + nn_dttrc ) THEN          ! at nittrc000 or nittrc000+1
93         r2dttrc = 2. * rdttrc       ! = 2 rdttrc (leapfrog)
94      ENDIF
95      !                                               !==  effective transport  ==!
96!$OMP PARALLEL DO schedule(static) private(jk)
97      DO jk = 1, jpkm1
98         zun(:,:,jk) = e2u  (:,:) * e3u_n(:,:,jk) * un(:,:,jk)                   ! eulerian transport
99         zvn(:,:,jk) = e1v  (:,:) * e3v_n(:,:,jk) * vn(:,:,jk)
100         zwn(:,:,jk) = e1e2t(:,:)                 * wn(:,:,jk)
101      END DO
102      !
103      IF( ln_vvl_ztilde .OR. ln_vvl_layer ) THEN                                 ! add z-tilde and/or vvl corrections
104!$OMP PARALLEL WORKSHARE
105         zun(:,:,:) = zun(:,:,:) + un_td(:,:,:)
106         zvn(:,:,:) = zvn(:,:,:) + vn_td(:,:,:)
107!$OMP END PARALLEL WORKSHARE
108      ENDIF
109      !
110      IF( ln_ldfeiv .AND. .NOT. ln_traldf_triad )   & 
111         &              CALL ldf_eiv_trp( kt, nittrc000, zun, zvn, zwn, 'TRC' )  ! add the eiv transport
112      !
113      IF( ln_mle    )   CALL tra_adv_mle( kt, nittrc000, zun, zvn, zwn, 'TRC' )  ! add the mle transport
114      !
115!$OMP PARALLEL WORKSHARE
116      zun(:,:,jpk) = 0._wp                                                       ! no transport trough the bottom
117      zvn(:,:,jpk) = 0._wp
118      zwn(:,:,jpk) = 0._wp
119!$OMP END PARALLEL WORKSHARE
120      !
121      !
122      SELECT CASE ( nadv )                      !==  compute advection trend and add it to general trend  ==!
123      !
124      CASE ( np_CEN )                                    ! Centered : 2nd / 4th order
125         CALL tra_adv_cen    ( kt, nittrc000,'TRC',       zun, zvn, zwn     , trn, tra, jptra, nn_cen_h, nn_cen_v )
126      CASE ( np_FCT )                                    ! FCT      : 2nd / 4th order
127         CALL tra_adv_fct    ( kt, nittrc000,'TRC', r2dttrc, zun, zvn, zwn, trb, trn, tra, jptra, nn_fct_h, nn_fct_v )
128      CASE ( np_FCT_zts )                                ! 2nd order FCT with vertical time-splitting
129         CALL tra_adv_fct_zts( kt, nittrc000,'TRC', r2dttrc, zun, zvn, zwn, trb, trn, tra, jptra        , nn_fct_zts )
130      CASE ( np_MUS )                                    ! MUSCL
131         CALL tra_adv_mus    ( kt, nittrc000,'TRC', r2dttrc, zun, zvn, zwn, trb,      tra, jptra        , ln_mus_ups ) 
132      CASE ( np_UBS )                                    ! UBS
133         CALL tra_adv_ubs    ( kt, nittrc000,'TRC', r2dttrc, zun, zvn, zwn, trb, trn, tra, jptra        , nn_ubs_v   )
134      CASE ( np_QCK )                                    ! QUICKEST
135         CALL tra_adv_qck    ( kt, nittrc000,'TRC', r2dttrc, zun, zvn, zwn, trb, trn, tra, jptra                     )
136      !
137      END SELECT
138      !                 
139      IF( ln_ctl )   THEN                             !== print mean trends (used for debugging)
140         WRITE(charout, FMT="('adv ')")  ;  CALL prt_ctl_trc_info(charout)
141                                            CALL prt_ctl_trc( tab4d=tra, mask=tmask, clinfo=ctrcnm, clinfo2='trd' )
142      END IF
143      !
144      CALL wrk_dealloc( jpi,jpj,jpk,   zun, zvn, zwn )
145      !
146      IF( nn_timing == 1 )  CALL timing_stop('trc_adv')
147      !
148   END SUBROUTINE trc_adv
149
150
151   SUBROUTINE trc_adv_ini
152      !!---------------------------------------------------------------------
153      !!                  ***  ROUTINE trc_adv_ini  ***
154      !!               
155      !! ** Purpose : Control the consistency between namelist options for
156      !!              passive tracer advection schemes and set nadv
157      !!----------------------------------------------------------------------
158      INTEGER ::   ioptio
159      INTEGER ::  ios                 ! Local integer output status for namelist read
160      !!
161      NAMELIST/namtrc_adv/ ln_trcadv_cen, nn_cen_h, nn_cen_v,               &   ! CEN
162         &                 ln_trcadv_fct, nn_fct_h, nn_fct_v, nn_fct_zts,   &   ! FCT
163         &                 ln_trcadv_mus,                     ln_mus_ups,   &   ! MUSCL
164         &                 ln_trcadv_ubs,           nn_ubs_v,               &   ! UBS
165         &                 ln_trcadv_qck                                        ! QCK
166      !!----------------------------------------------------------------------
167      !
168      REWIND( numnat_ref )              !  namtrc_adv in reference namelist
169      READ  ( numnat_ref, namtrc_adv, IOSTAT = ios, ERR = 901)
170901   IF( ios /= 0 ) CALL ctl_nam ( ios , 'namtrc_adv in reference namelist', lwp )
171
172      REWIND( numnat_cfg )              ! namtrc_adv in configuration namelist
173      READ  ( numnat_cfg, namtrc_adv, IOSTAT = ios, ERR = 902 )
174902   IF( ios /= 0 ) CALL ctl_nam ( ios , 'namtrc_adv in configuration namelist', lwp )
175      IF(lwm) WRITE ( numont, namtrc_adv )
176
177      IF(lwp) THEN                    ! Namelist print
178         WRITE(numout,*)
179         WRITE(numout,*) 'trc_adv_ini : choice/control of the tracer advection scheme'
180         WRITE(numout,*) '~~~~~~~~~~~'
181         WRITE(numout,*) '   Namelist namtrc_adv : chose a advection scheme for tracers'
182         WRITE(numout,*) '      centered scheme                           ln_trcadv_cen = ', ln_trcadv_cen
183         WRITE(numout,*) '            horizontal 2nd/4th order               nn_cen_h   = ', nn_fct_h
184         WRITE(numout,*) '            vertical   2nd/4th order               nn_cen_v   = ', nn_fct_v
185         WRITE(numout,*) '      Flux Corrected Transport scheme           ln_trcadv_fct = ', ln_trcadv_fct
186         WRITE(numout,*) '            horizontal 2nd/4th order               nn_fct_h   = ', nn_fct_h
187         WRITE(numout,*) '            vertical   2nd/4th order               nn_fct_v   = ', nn_fct_v
188         WRITE(numout,*) '            2nd order + vertical sub-timestepping  nn_fct_zts = ', nn_fct_zts
189         WRITE(numout,*) '      MUSCL scheme                              ln_trcadv_mus = ', ln_trcadv_mus
190         WRITE(numout,*) '            + upstream scheme near river mouths    ln_mus_ups = ', ln_mus_ups
191         WRITE(numout,*) '      UBS scheme                                ln_trcadv_ubs = ', ln_trcadv_ubs
192         WRITE(numout,*) '            vertical   2nd/4th order               nn_ubs_v   = ', nn_ubs_v
193         WRITE(numout,*) '      QUICKEST scheme                           ln_trcadv_qck = ', ln_trcadv_qck
194      ENDIF
195      !
196
197      ioptio = 0                       !==  Parameter control  ==!
198      IF( ln_trcadv_cen )   ioptio = ioptio + 1
199      IF( ln_trcadv_fct )   ioptio = ioptio + 1
200      IF( ln_trcadv_mus )   ioptio = ioptio + 1
201      IF( ln_trcadv_ubs )   ioptio = ioptio + 1
202      IF( ln_trcadv_qck )   ioptio = ioptio + 1
203
204      !
205      IF( ioptio == 0 ) THEN
206         nadv = np_NO_adv
207         CALL ctl_warn( 'trc_adv_init: You are running without tracer advection.' )
208      ENDIF
209      IF( ioptio /= 1 )   CALL ctl_stop( 'Choose ONE advection scheme in namelist namtrc_adv' )
210      !
211      IF( ln_trcadv_cen .AND. ( nn_cen_h /= 2 .AND. nn_cen_h /= 4 )   &
212                        .AND. ( nn_cen_v /= 2 .AND. nn_cen_v /= 4 )   ) THEN
213        CALL ctl_stop( 'trc_adv_init: CEN scheme, choose 2nd or 4th order' )
214      ENDIF
215      IF( ln_trcadv_fct .AND. ( nn_fct_h /= 2 .AND. nn_fct_h /= 4 )   &
216                        .AND. ( nn_fct_v /= 2 .AND. nn_fct_v /= 4 )   ) THEN
217        CALL ctl_stop( 'trc_adv_init: FCT scheme, choose 2nd or 4th order' )
218      ENDIF
219      IF( ln_trcadv_fct .AND. nn_fct_zts > 0 ) THEN
220         IF( nn_fct_h == 4 ) THEN
221            nn_fct_h = 2
222            CALL ctl_stop( 'trc_adv_init: force 2nd order FCT scheme, 4th order does not exist with sub-timestepping' )
223         ENDIF
224         IF( .NOT.ln_linssh ) THEN
225            CALL ctl_stop( 'trc_adv_init: vertical sub-timestepping not allow in non-linear free surface' )
226         ENDIF
227         IF( nn_fct_zts == 1 )   CALL ctl_warn( 'trc_adv_init: FCT with ONE sub-timestep = FCT without sub-timestep' )
228      ENDIF
229      IF( ln_trcadv_ubs .AND. ( nn_ubs_v /= 2 .AND. nn_ubs_v /= 4 )   ) THEN
230        CALL ctl_stop( 'trc_adv_init: UBS scheme, choose 2nd or 4th order' )
231      ENDIF
232      IF( ln_trcadv_ubs .AND. nn_ubs_v == 4 ) THEN
233         CALL ctl_warn( 'trc_adv_init: UBS scheme, only 2nd FCT scheme available on the vertical. It will be used' )
234      ENDIF
235      IF( ln_isfcav ) THEN                                                       ! ice-shelf cavities
236         IF(  ln_trcadv_cen .AND. nn_cen_v /= 4    .OR.   &                            ! NO 4th order with ISF
237            & ln_trcadv_fct .AND. nn_fct_v /= 4   )   CALL ctl_stop( 'tra_adv_init: 4th order COMPACT scheme not allowed with ISF' )
238      ENDIF
239      !
240      !                                !==  used advection scheme  ==!
241      !                                      ! set nadv
242      IF( ln_trcadv_cen                      )   nadv = np_CEN
243      IF( ln_trcadv_fct                      )   nadv = np_FCT
244      IF( ln_trcadv_fct .AND. nn_fct_zts > 0 )   nadv = np_FCT_zts
245      IF( ln_trcadv_mus                      )   nadv = np_MUS
246      IF( ln_trcadv_ubs                      )   nadv = np_UBS
247      IF( ln_trcadv_qck                      )   nadv = np_QCK
248      !
249      IF(lwp) THEN                   ! Print the choice
250         WRITE(numout,*)
251         IF( nadv == np_NO_adv  )   WRITE(numout,*) '         NO passive tracer advection'
252         IF( nadv == np_CEN     )   WRITE(numout,*) '         CEN      scheme is used. Horizontal order: ', nn_cen_h,   &
253            &                                                                        ' Vertical   order: ', nn_cen_v
254         IF( nadv == np_FCT     )   WRITE(numout,*) '         FCT      scheme is used. Horizontal order: ', nn_fct_h,   &
255            &                                                                       ' Vertical   order: ', nn_fct_v
256         IF( nadv == np_FCT_zts )   WRITE(numout,*) '         use 2nd order FCT with ', nn_fct_zts,'vertical sub-timestepping'
257         IF( nadv == np_MUS     )   WRITE(numout,*) '         MUSCL    scheme is used'
258         IF( nadv == np_UBS     )   WRITE(numout,*) '         UBS      scheme is used'
259         IF( nadv == np_QCK     )   WRITE(numout,*) '         QUICKEST scheme is used'
260      ENDIF
261      !
262   END SUBROUTINE trc_adv_ini
263   
264#else
265   !!----------------------------------------------------------------------
266   !!   Default option                                         Empty module
267   !!----------------------------------------------------------------------
268CONTAINS
269   SUBROUTINE trc_adv( kt )
270      INTEGER, INTENT(in) :: kt
271      WRITE(*,*) 'trc_adv: You should not have seen this print! error?', kt
272   END SUBROUTINE trc_adv
273#endif
274
275  !!======================================================================
276END MODULE trcadv
Note: See TracBrowser for help on using the repository browser.